CMakeLists.txt

   1 # CMakeLists.txt
   2 #
   3 # Wireshark - Network traffic analyzer
   4 # By Gerald Combs <gerald@wireshark.org>
   5 # Copyright 1998 Gerald Combs
   6 #
   7 # SPDX-License-Identifier: GPL-2.0-or-later
   8 #
   9 if(DEFINED ENV{FORCE_CMAKE_NINJA_NON_VERBOSE})
  10         #
  11         # Forcibly unset CMAKE_VERBOSE_MAKEFILE,
  12         # to make *CERTAIN* that we don't do
  13         # anything verbose here!
  14         #
  15         unset(CMAKE_VERBOSE_MAKEFILE CACHE)
  16 endif()
  17
  18 # Needed for add_custom_command() WORKING_DIRECTORY generator expressions
  19 cmake_minimum_required(VERSION 3.13)
  20 if(POLICY CMP0083)
  21         cmake_policy(SET CMP0083 NEW)
  22 endif()
  23 if(POLICY CMP0135)
  24         cmake_policy(SET CMP0135 NEW)
  25 endif()
  26
  27 if(WIN32)
  28         if(DEFINED ENV{MSYSTEM})
  29                 set(_msystem $ENV{MSYSTEM})
  30                 set(_repository False)
  31                 message(STATUS "Using MSYS2 with MSYSTEM=${_msystem}")
  32         else()
  33                 set(_msystem False)
  34                 set(_repository True)
  35                 message(STATUS "Using 3rd party repository")
  36         endif()
  37         set(USE_MSYSTEM ${_msystem} CACHE INTERNAL "Use MSYS2 subsystem")
  38         set(HAVE_MSYSTEM ${USE_MSYSTEM}) # For config.h
  39         set(USE_REPOSITORY ${_repository} CACHE INTERNAL "Use Wireshark 3rd Party Repository")
  40 endif()
  41
  42 if(WIN32 AND NOT USE_MSYSTEM)
  43         set(_project_name Wireshark)
  44         set(_log_project_name Logray)
  45 else()
  46         set(_project_name wireshark)
  47         set(_log_project_name logray)
  48 endif()
  49
  50 project(${_project_name} C CXX)
  51
  52 # Updated by tools/make-version.py
  53 set(PROJECT_MAJOR_VERSION 4)
  54 set(PROJECT_MINOR_VERSION 1)
  55 set(PROJECT_PATCH_VERSION 0)
  56 set(PROJECT_BUILD_VERSION 0)
  57 set(PROJECT_VERSION_EXTENSION "")
  58
  59 if(DEFINED ENV{WIRESHARK_VERSION_EXTRA})
  60         set(PROJECT_VERSION_EXTENSION "$ENV{WIRESHARK_VERSION_EXTRA}")
  61 endif()
  62
  63 set(PROJECT_VERSION "${PROJECT_MAJOR_VERSION}.${PROJECT_MINOR_VERSION}.${PROJECT_PATCH_VERSION}${PROJECT_VERSION_EXTENSION}")
  64
  65 set(LOG_PROJECT_NAME ${_log_project_name})
  66 set(LOG_PROJECT_MAJOR_VERSION 0)
  67 set(LOG_PROJECT_MINOR_VERSION 8)
  68 set(LOG_PROJECT_PATCH_VERSION 3)
  69 set(LOG_PROJECT_VERSION "${LOG_PROJECT_MAJOR_VERSION}.${LOG_PROJECT_MINOR_VERSION}.${LOG_PROJECT_PATCH_VERSION}${PROJECT_VERSION_EXTENSION}")
  70
  71 include( CMakeOptions.txt )
  72
  73 # We require minimum C11
  74 set(CMAKE_C_STANDARD 11)
  75 set(CMAKE_C_STANDARD_REQUIRED ON)
  76
  77 # We require minimum C++11
  78 set(CMAKE_CXX_STANDARD 11)
  79 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  80 set(CMAKE_CXX_EXTENSIONS OFF)
  81
  82 message(STATUS "Generating build using CMake ${CMAKE_VERSION}")
  83
  84 if(USE_MSYSTEM)
  85         # Use the deprecated FindPythonInterp.cmake module to Work around bugs and odd behavior in MSYS2 CMake
  86         # searching in the wrong paths for python3.exe using FindPython3.cmake
  87         find_package(PythonInterp REQUIRED)
  88         set(Python3_EXECUTABLE ${PYTHON_EXECUTABLE} CACHE FILEPATH "")
  89 else()
  90         find_package(Python3 3.6 REQUIRED)
  91 endif()
  92
  93 # Set a default build type if none was specified
  94 set(_default_build_type "RelWithDebInfo")
  95 if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  96         set(CMAKE_BUILD_TYPE "${_default_build_type}" CACHE STRING "Choose the type of build." FORCE)
  97         # Set the possible values of build type for cmake-gui
  98         set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
  99 endif()
 100
 101 # Build type is ignored by multi-config generators.
 102 if (NOT CMAKE_CONFIGURATION_TYPES)
 103         message(STATUS "Using \"${CMAKE_GENERATOR}\" generator and build type \"${CMAKE_BUILD_TYPE}\"")
 104 else()
 105         message(STATUS "Using \"${CMAKE_GENERATOR}\" generator (multi-config)")
 106 endif()
 107
 108 #Where to find local cmake scripts
 109 set(WS_CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
 110 set(CMAKE_MODULE_PATH ${WS_CMAKE_MODULE_PATH})
 111
 112 # CMake >= 3.9.0 supports LTO/IPO.
 113 if (ENABLE_LTO)
 114         include(CheckIPOSupported)
 115         check_ipo_supported(RESULT lto_supported OUTPUT lto_output)
 116         if(lto_supported)
 117                 set(CMAKE_INTERPROCEDURAL_OPTIMIZATION_RELEASE TRUE)
 118                 message(STATUS "LTO/IPO is enabled for Release configuration")
 119         else()
 120                 message(STATUS "LTO/IPO requested but it is not supported by the compiler: ${lto_output}")
 121         endif()
 122 else()
 123         message(STATUS "LTO/IPO is not enabled")
 124 endif()
 125
 126 # If our target platform is enforced by our generator, set
 127 # WIRESHARK_TARGET_PLATFORM accordingly. Otherwise use
 128 # %WIRESHARK_TARGET_PLATFORM%.
 129
 130 # XXX We should probably consolidate WIRESHARK_TARGET_PLATFORM and
 131 # WIRESHARK_TARGET_PROCESSOR_ARCHITECTURE and just use "x64"
 132 # instead of "win64"
 133
 134 if(WIN32)
 135         if(DEFINED ENV{WIRESHARK_TARGET_PLATFORM})
 136                 string(TOLOWER $ENV{WIRESHARK_TARGET_PLATFORM} _target_platform)
 137                 set(WIRESHARK_TARGET_PLATFORM ${_target_platform})
 138         elseif(USE_MSYSTEM MATCHES "MINGW64|CLANG64|UCRT64")
 139                 # https://www.msys2.org/docs/environments
 140                 #    MSYS2 comes with different environments/subsystems and
 141                 #    the first thing you have to decide is which one to use.
 142                 #    The differences among the environments are mainly environment
 143                 #    variables, default compilers/linkers, architecture,
 144                 #    system libraries used etc. If you are unsure, go with UCRT64.
 145                 set(WIRESHARK_TARGET_PLATFORM win64)
 146         elseif(USE_MSYSTEM)
 147                 if($ENV{MSYSTEM_CARCH} MATCHES "x86_64")
 148                         set(WIRESHARK_TARGET_PLATFORM win64)
 149                 elseif($ENV{MSYSTEM_CARCH} MATCHES "i686")
 150                         set(WIRESHARK_TARGET_PLATFORM win32)
 151                 elseif($ENV{MSYSTEM_CARCH} MATCHES "aarch64")
 152                         set(WIRESHARK_TARGET_PLATFORM "arm64")
 153                 else()
 154                         set(WIRESHARK_TARGET_PLATFORM "$ENV{MSYSTEM_CARCH}")
 155                 endif()
 156         elseif($ENV{Platform} MATCHES arm64 OR CMAKE_GENERATOR_PLATFORM MATCHES arm64)
 157                 set(WIRESHARK_TARGET_PLATFORM arm64)
 158         elseif(CMAKE_CL_64 OR CMAKE_GENERATOR MATCHES Win64)
 159                 set(WIRESHARK_TARGET_PLATFORM win64)
 160         else()
 161                 message(WARNING "Assuming \"win64\" target platform")
 162                 set(WIRESHARK_TARGET_PLATFORM win64)
 163         endif()
 164
 165         set(WIRESHARK_TARGET_PROCESSOR_ARCHITECTURE ${WIRESHARK_TARGET_PLATFORM})
 166         if(WIRESHARK_TARGET_PLATFORM MATCHES "win64")
 167                 set(WIRESHARK_TARGET_PROCESSOR_ARCHITECTURE x64)
 168         elseif(WIRESHARK_TARGET_PLATFORM MATCHES "arm64")
 169             # Pass
 170         elseif(WIRESHARK_TARGET_PLATFORM MATCHES "win32")
 171                 message(FATAL_ERROR "Deprecated target platform ${WIRESHARK_TARGET_PLATFORM}. See https://gitlab.com/wireshark/wireshark/-/issues/17779 for details.")
 172         else()
 173                 message(FATAL_ERROR "Invalid target platform: ${WIRESHARK_TARGET_PLATFORM}")
 174         endif()
 175
 176         # Sanity check
 177         if(MSVC)
 178                 if(DEFINED ENV{PLATFORM})
 179                         string(TOLOWER $ENV{PLATFORM} _vs_platform)
 180                 else()
 181                         set(_vs_platform "[undefined]") # x86
 182                 endif()
 183                 if(
 184                         (_vs_platform STREQUAL "x64" AND NOT WIRESHARK_TARGET_PLATFORM STREQUAL "win64")
 185                         OR
 186                         (_vs_platform STREQUAL "[undefined]" AND NOT WIRESHARK_TARGET_PLATFORM STREQUAL "win32")
 187                 )
 188                         message(FATAL_ERROR "The PLATFORM environment variable (${_vs_platform})"
 189                                 " doesn't match the generator platform (${WIRESHARK_TARGET_PLATFORM})")
 190                 endif()
 191         endif()
 192         message(STATUS
 193                 "Building for ${WIRESHARK_TARGET_PLATFORM} \
 194 and CPU target ${WIRESHARK_TARGET_PROCESSOR_ARCHITECTURE}"
 195         )
 196
 197         if(NOT CMAKE_CROSSCOMPILING)
 198                 find_package(PowerShell REQUIRED)
 199         endif()
 200
 201         # Determine where the 3rd party libraries will be
 202         if(USE_REPOSITORY)
 203                 if( DEFINED ENV{WIRESHARK_LIB_DIR} )
 204                         # The buildbots set WIRESHARK_LIB_DIR but not WIRESHARK_BASE_DIR.
 205                         file( TO_CMAKE_PATH "$ENV{WIRESHARK_LIB_DIR}" _PROJECT_LIB_DIR )
 206                 elseif( DEFINED ENV{WIRESHARK_BASE_DIR} )
 207                         file( TO_CMAKE_PATH "$ENV{WIRESHARK_BASE_DIR}" _WS_BASE_DIR )
 208                         set( _PROJECT_LIB_DIR "${_WS_BASE_DIR}/wireshark-${WIRESHARK_TARGET_PLATFORM}-libs" )
 209                 else()
 210                         # Don't know what to do
 211                         message(FATAL_ERROR "Neither WIRESHARK_BASE_DIR or WIRESHARK_LIB_DIR are defined")
 212                 endif()
 213
 214                 # Download third-party libraries
 215                 file (TO_NATIVE_PATH ${CMAKE_SOURCE_DIR}/tools/win-setup.ps1 _win_setup)
 216                 file (TO_NATIVE_PATH ${_PROJECT_LIB_DIR} _ws_lib_dir)
 217                 file (TO_NATIVE_PATH ${CMAKE_COMMAND} _win_cmake_command)
 218
 219                 # Is it possible to have a one-time, non-cached option in CMake? If
 220                 # so, we could add a "-DFORCE_WIN_SETUP" which passes -Force to
 221                 # win-setup.ps1.
 222                 execute_process(
 223                         COMMAND ${POWERSHELL_COMMAND} "\"${_win_setup}\"" -Destination "${_ws_lib_dir}" -Platform ${WIRESHARK_TARGET_PLATFORM} -CMakeExecutable "\"${_win_cmake_command}\""
 224                         RESULT_VARIABLE _win_setup_failed
 225                         ERROR_VARIABLE _win_setup_error_output
 226                 )
 227                 if(_win_setup_failed)
 228                         message(FATAL_ERROR "Windows setup (win-setup.ps1) failed: ${_win_setup_error_output}.")
 229                 endif()
 230
 231                 set(EXTRA_INSTALLER_DIR ${_ws_lib_dir})
 232
 233                 # XXX Add a dependency on ${_ws_lib_dir}/current_tag.txt?
 234         else()
 235                 set(EXTRA_INSTALLER_DIR ${CMAKE_BINARY_DIR}/packaging/nsis)
 236         endif()
 237
 238         include(FetchContent)
 239         set(LIBS_URL "https://dev-libs.wireshark.org/windows/packages")
 240         file(TO_CMAKE_PATH ${EXTRA_INSTALLER_DIR} _file_download_dir)
 241
 242         # Download Npcap required by the Windows installer
 243         set(NPCAP_VERSION "1.75")
 244         set(NPCAP_SHA256 "9ac38dff01b48e18033e8a9015b27042ef847c8c84a9065961a30f8ae22d5245")
 245         set(NPCAP_FILENAME "npcap-${NPCAP_VERSION}.exe")
 246         set(NPCAP_URL "${LIBS_URL}/Npcap/${NPCAP_FILENAME}")
 247         FetchContent_Declare(Npcap
 248                 URL ${NPCAP_URL}
 249                 DOWNLOAD_DIR ${_file_download_dir}
 250                 URL_HASH SHA256=${NPCAP_SHA256}
 251                 DOWNLOAD_NO_EXTRACT True
 252         )
 253
 254         # Download USBPcap required by the Windows installer
 255         set(USBPCAP_VERSION "1.5.4.0")
 256         set(USBPCAP_SHA256 "87a7edf9bbbcf07b5f4373d9a192a6770d2ff3add7aa1e276e82e38582ccb622")
 257         set(USBPCAP_FILENAME "USBPcapSetup-${USBPCAP_VERSION}.exe")
 258         set(USBPCAP_URL "${LIBS_URL}/USBPcap/${USBPCAP_FILENAME}")
 259         FetchContent_Declare(USBPcap
 260                 URL ${USBPCAP_URL}
 261                 DOWNLOAD_DIR ${_file_download_dir}
 262                 URL_HASH SHA256=${USBPCAP_SHA256}
 263                 DOWNLOAD_NO_EXTRACT True
 264         )
 265 endif(WIN32)
 266
 267 include(UseCustomIncludes)
 268 ADD_CUSTOM_CMAKE_INCLUDE()
 269
 270 # Ensure that all executables and libraries end up in the same directory. Actual
 271 # files might end up in a configuration subdirectory, e.g. run/Debug or
 272 # run/Release. We try to set DATAFILE_DIR to actual location below.
 273 if(NOT ARCHIVE_OUTPUT_PATH)
 274         set(ARCHIVE_OUTPUT_PATH ${CMAKE_BINARY_DIR}/run CACHE INTERNAL
 275                    "Single output directory for building all archives.")
 276 endif()
 277 if(NOT EXECUTABLE_OUTPUT_PATH)
 278         set(EXECUTABLE_OUTPUT_PATH ${CMAKE_BINARY_DIR}/run CACHE INTERNAL
 279                    "Single output directory for building all executables.")
 280 endif()
 281 if(NOT LIBRARY_OUTPUT_PATH)
 282         set(LIBRARY_OUTPUT_PATH ${CMAKE_BINARY_DIR}/run CACHE INTERNAL
 283                    "Single output directory for building all libraries.")
 284 endif()
 285
 286 #
 287 # The release mode (CMAKE_BUILD_TYPE=release) defines NDEBUG for
 288 # the Unix Makefile generator.
 289 #
 290
 291 # Defines CMAKE_INSTALL_BINDIR, CMAKE_INSTALL_DATADIR, etc ...
 292 if(WIN32 AND NOT USE_MSYSTEM)
 293         # Override some values on Windows, to match the existing
 294         # convention of installing everything to a single root folder.
 295         set(CMAKE_INSTALL_BINDIR ".")
 296         set(CMAKE_INSTALL_LIBDIR ".")
 297         set(CMAKE_INSTALL_INCLUDEDIR "include")
 298         set(CMAKE_INSTALL_DATADIR ".")
 299         set(CMAKE_INSTALL_DOCDIR ".")
 300 else()
 301         # By default INSTALL_DATADIR is set to INSTALL_DATAROOTDIR, set the
 302         # proper value here.
 303         set(CMAKE_INSTALL_DATADIR "share/${PROJECT_NAME}"
 304                 CACHE PATH "Read-only architecture-independent data"
 305         )
 306 endif()
 307 include(GNUInstallDirs)
 308
 309 set(PROJECT_INSTALL_INCLUDEDIR "${CMAKE_INSTALL_INCLUDEDIR}/${PROJECT_NAME}")
 310
 311 # Make sure our executables can load our libraries if we install into
 312 # a non-default directory on Unix-like systems other than macOS.
 313 # https://gitlab.kitware.com/cmake/community/wikis/doc/cmake/RPATH-handling
 314 set(LIBRARY_INSTALL_RPATH "")
 315 set(EXECUTABLE_INSTALL_RPATH "")
 316 set(EXTCAP_INSTALL_RPATH "")
 317 if(NOT (WIN32 OR APPLE OR USE_STATIC))
 318         # Try to set a RPATH for installed binaries if the library directory is
 319         # not already included in the default search list.
 320         list(FIND CMAKE_C_IMPLICIT_LINK_DIRECTORIES "${CMAKE_INSTALL_FULL_LIBDIR}" IS_SYSTEM_DIR)
 321         if(IS_SYSTEM_DIR EQUAL -1)
 322                 # Some systems support $ORIGIN in RPATH to enable relocatable
 323                 # binaries. In other cases, only absolute paths can be used.
 324                 # https://www.lekensteyn.nl/rpath.html
 325                 #
 326                 # Also note that some systems (notably those using GNU libc)
 327                 # silently ignore $ORIGIN in RPATH for binaries that are
 328                 # setuid root or use privileged capabilities.
 329                 #
 330                 if(CMAKE_SYSTEM_NAME MATCHES "^(Linux|SunOS|FreeBSD)$")
 331                         set(_enable_rpath_origin TRUE)
 332                 else()
 333                         set(_enable_rpath_origin FALSE)
 334                 endif()
 335
 336                 # Provide a knob to optionally force absolute rpaths,
 337                 # to support old/buggy systems and as a user preference
 338                 # for hardening.
 339                 # XXX Should this be a CMake option?
 340                 set(ENABLE_RPATH_ORIGIN ${_enable_rpath_origin} CACHE BOOL
 341                         "Use $ORIGIN with INSTALL_RPATH")
 342                 mark_as_advanced(ENABLE_RPATH_ORIGIN)
 343
 344                 if(ENABLE_RPATH_ORIGIN)
 345                         set(LIBRARY_INSTALL_RPATH     "$ORIGIN")
 346                         set(EXECUTABLE_INSTALL_RPATH  "$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 347                         set(EXTCAP_INSTALL_RPATH      "$ORIGIN/../..")
 348                 else()
 349                         set(LIBRARY_INSTALL_RPATH     "${CMAKE_INSTALL_FULL_LIBDIR}")
 350                         set(EXECUTABLE_INSTALL_RPATH  "${CMAKE_INSTALL_FULL_LIBDIR}")
 351                         set(EXTCAP_INSTALL_RPATH      "${CMAKE_INSTALL_FULL_LIBDIR}")
 352                 endif()
 353                 # Include non-standard external libraries by default in RPATH.
 354                 if(NOT DEFINED CMAKE_INSTALL_RPATH_USE_LINK_PATH)
 355                         set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 356                 endif()
 357         endif()
 358 endif()
 359
 360 # Ensure that executables in the build directory always have the same RPATH.
 361 # This ensures relocatable binaries and reproducible builds (invariant of the
 362 # build directory location). (Requires CMake 3.14)
 363 set(CMAKE_BUILD_RPATH_USE_ORIGIN ON)
 364
 365 if(MSVC)
 366     # Linking with wsetargv.obj enables "wildcard expansion" of
 367     # command-line arguments.
 368     set(WILDCARD_OBJ wsetargv.obj)
 369 endif()
 370
 371 include(CheckSymbolExists)
 372
 373 #
 374 # Large file support on UN*X, a/k/a LFS.
 375 #
 376 # On Windows, we require _fseeki64() and _ftelli64().  Visual
 377 # Studio has had supported them since Visual Studio 2005/MSVCR80,
 378 # and we require newer versions, so we know we have them.
 379 #
 380 if(NOT MSVC)
 381         include(FindLFS)
 382         if(LFS_FOUND)
 383                 #
 384                 # Add the required #defines.
 385                 #
 386                 add_definitions(${LFS_DEFINITIONS})
 387         endif()
 388
 389         #
 390         # Check for fseeko as well.
 391         #
 392         include(FindFseeko)
 393         if(FSEEKO_FOUND)
 394                 set(HAVE_FSEEKO ON)
 395
 396                 #
 397                 # Add the required #defines.
 398                 #
 399                 add_definitions(${FSEEKO_DEFINITIONS})
 400         endif()
 401 endif()
 402
 403 # Banner shown at top right of Qt welcome screen.
 404 if(DEFINED ENV{WIRESHARK_VERSION_FLAVOR})
 405         set(VERSION_FLAVOR "$ENV{WIRESHARK_VERSION_FLAVOR}")
 406 else()
 407         set(VERSION_FLAVOR "Development Build")
 408 endif()
 409
 410 # Used in .rc files and manifests
 411 set(MANIFEST_PROCESSOR_ARCHITECTURE ${WIRESHARK_TARGET_PROCESSOR_ARCHITECTURE})
 412 if (MANIFEST_PROCESSOR_ARCHITECTURE MATCHES "x64")
 413         set(MANIFEST_PROCESSOR_ARCHITECTURE "amd64")
 414 endif()
 415 set(RC_VERSION ${PROJECT_MAJOR_VERSION},${PROJECT_MINOR_VERSION},${PROJECT_PATCH_VERSION},${PROJECT_BUILD_VERSION})
 416 set(LOG_RC_VERSION ${LOG_PROJECT_MAJOR_VERSION},${LOG_PROJECT_MINOR_VERSION},${PROJECT_PATCH_VERSION},${PROJECT_BUILD_VERSION})
 417
 418 message(STATUS "V: ${PROJECT_VERSION}, MaV: ${PROJECT_MAJOR_VERSION}, MiV: ${PROJECT_MINOR_VERSION}, PL: ${PROJECT_PATCH_VERSION}, EV: ${PROJECT_VERSION_EXTENSION}.")
 419
 420 include(UseLemon)
 421 include(UseMakePluginReg)
 422 include(UseMakeTaps)
 423 include(UseExecutableResources)
 424 include(UseAsn2Wrs)
 425
 426 # The following snippet has been taken from
 427 # https://github.com/USESystemEngineeringBV/cmake-eclipse-helper/wiki/HowToWorkaroundIndexer
 428 # The eclipse indexer otherwise assumes __cplusplus=199711L which will lead to broken
 429 # lookup tables for the epan libraries
 430 # Check if CXX flags have been set to c++11 -> Setup Eclipse Indexer correctly!
 431 # Also setup the project slightly different
 432 if(CMAKE_EXTRA_GENERATOR MATCHES "Eclipse CDT4")
 433         SET(CXX_ENABLED 0)
 434         LIST(LENGTH CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS LIST_LEN)
 435         if(LIST_LEN GREATER 0)
 436                 SET(CXX_ENABLED 1)
 437         endif()
 438         SET(C_ENABLED 0)
 439         LIST(LENGTH CMAKE_EXTRA_GENERATOR_C_SYSTEM_DEFINED_MACROS LIST_LEN)
 440         if(LIST_LEN GREATER 0)
 441                 SET(C_ENABLED 1)
 442         endif()
 443         if(C_ENABLED EQUAL 1 AND CXX_ENABLED EQUAL 1)
 444                 # Combined project (C and CXX). This will confuse the indexer. For that reason
 445                 # we unsert set the __cplusplus variable for the indexer
 446                 list(FIND CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS "__cplusplus" GEN_MACRO_INDEX)
 447                 if(GEN_MACRO_INDEX GREATER -1)
 448                         list(REMOVE_AT CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS ${GEN_MACRO_INDEX})
 449                         list(REMOVE_AT CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS ${GEN_MACRO_INDEX})
 450                 endif()
 451                 SET(CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS ${CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS} CACHE INTERNAL "")
 452         elseif((CXX_ENABLED EQUAL 1) AND (CMAKE_CXX_FLAGS MATCHES ".*-std=c\\+\\+11.*"))
 453                 #add_definitions (-D__cplusplus=201103L)
 454                 # CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS
 455                 list(FIND CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS "199711L" GEN_MACRO_INDEX)
 456                 if(GEN_MACRO_INDEX GREATER -1)
 457                         list(REMOVE_AT CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS ${GEN_MACRO_INDEX})
 458                         list(INSERT CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS ${GEN_MACRO_INDEX} "201103L")
 459                         SET(CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS ${CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS} CACHE INTERNAL "")
 460                 endif()
 461         endif()
 462 endif()
 463
 464 include_directories(
 465         ${CMAKE_BINARY_DIR}
 466         ${CMAKE_SOURCE_DIR}
 467         ${CMAKE_SOURCE_DIR}/include
 468 )
 469
 470 if( DUMPCAP_INSTALL_OPTION STREQUAL "suid" )
 471         set( DUMPCAP_SETUID "SETUID" )
 472 else()
 473         set( DUMPCAP_SETUID )
 474 endif()
 475 if( NOT CMAKE_SYSTEM_NAME STREQUAL "Linux" AND
 476         DUMPCAP_INSTALL_OPTION STREQUAL "capabilities" )
 477         message( WARNING "Capabilities are only supported on Linux" )
 478         set( DUMPCAP_INSTALL_OPTION )
 479 endif()
 480
 481 set(OSS_FUZZ OFF CACHE BOOL "Whether building for oss-fuzz")
 482 mark_as_advanced(OSS_FUZZ)
 483 if(OSS_FUZZ)
 484         if(ENABLE_FUZZER)
 485                 # In oss-fuzz mode, the fuzzing engine can be afl or libFuzzer.
 486                 message(FATAL_ERROR "Cannot force libFuzzer when using oss-fuzz")
 487         endif()
 488         # Must not depend on external dependencies so statically link all libs.
 489         set(USE_STATIC ON)
 490 endif()
 491
 492 if(USE_STATIC)
 493         set(CMAKE_FIND_LIBRARY_SUFFIXES ".a")
 494 endif()
 495
 496 #
 497 # Linking can consume a lot of memory, especially when built with ASAN and
 498 # static libraries (like oss-fuzz) or Debug mode. With Ninja, the number of
 499 # parallel linker processes is constrained by job parallelism (-j), but this can
 500 # be reduced further by setting "job pools" to a lower number.
 501 #
 502 if(CMAKE_MAKE_PROGRAM MATCHES "ninja" AND OSS_FUZZ)
 503         # Assume oss-fuzz linker jobs do not require more than 1.2G per task
 504         set(per_job_memory_mb 1200)
 505         cmake_host_system_information(RESULT total_memory_mb QUERY TOTAL_PHYSICAL_MEMORY)
 506         math(EXPR parallel_link_jobs "${total_memory_mb} / ${per_job_memory_mb}")
 507         if(parallel_link_jobs LESS 1)
 508                 set(parallel_link_jobs 1)
 509         endif()
 510         set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${parallel_link_jobs})
 511         set(CMAKE_JOB_POOL_LINK link_job_pool)
 512         message(STATUS "Ninja job pool size: ${parallel_link_jobs}")
 513 endif()
 514
 515 # Always enable position-independent code when compiling, even for
 516 # executables, so you can build position-independent executables.
 517 # -pie is added below for non-MSVC, but requires objects to be built with
 518 # -fPIC/-fPIE (so set CMAKE_POSITION_INDEPENDENT_CODE to enable that).
 519 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 520
 521 # Preprocessor definitions common to all compilers
 522 set_property(DIRECTORY
 523         PROPERTY COMPILE_DEFINITIONS
 524                 "G_DISABLE_DEPRECATED"
 525                 "G_DISABLE_SINGLE_INCLUDES"
 526                 $<$<OR:$<BOOL:${ENABLE_DEBUG}>,$<CONFIG:Debug>,$<CONFIG:RelWithDebInfo>>:WS_DEBUG>
 527                 $<$<OR:$<BOOL:${ENABLE_DEBUG_UTF_8}>,$<CONFIG:Debug>,$<CONFIG:RelWithDebInfo>>:WS_DEBUG_UTF_8>
 528 )
 529
 530 if(WIN32)
 531         #
 532         # NOTE: Because of the way Qt moc is including "config.h" (not as the
 533         # first header) this *MUST* be defined on the command line to precede
 534         # every included header and not trigger symbol redefinition errors.
 535         #
 536         add_definitions(
 537                 -DWIN32_LEAN_AND_MEAN
 538                 #
 539                 # Use Unicode in Windows runtime functions.
 540                 #
 541                 -DUNICODE
 542                 -D_UNICODE
 543                 #
 544                 # NOMINMAX keeps windows.h from defining "min" and "max" via windef.h.
 545                 # This avoids conflicts with the C++ standard library.
 546                 #
 547                 -DNOMINMAX
 548         )
 549 endif()
 550
 551 if(MINGW)
 552         add_definitions(
 553                 #
 554                 # Enable POSIX APIs. This will switch stdio to ANSI C functions and
 555                 # enable C99 conformant vsnprintf() among other things.
 556                 #
 557                 -D_POSIX
 558         )
 559         list(APPEND CMAKE_REQUIRED_DEFINITIONS -D_POSIX)
 560 endif()
 561
 562 if( CMAKE_C_COMPILER_ID MATCHES "MSVC")
 563         if (MSVC_VERSION LESS "1928")
 564                 message(FATAL_ERROR "Microsoft Visual Studio 2019 version 16.8 or later is required")
 565         endif()
 566         if (MSVC_VERSION GREATER_EQUAL "2000")
 567                 message(FATAL_ERROR "You are using an unsupported version of MSVC")
 568         endif()
 569
 570         add_definitions(
 571                 /D_CRT_SECURE_NO_DEPRECATE
 572                 # -DPSAPI_VERSION=1                 Programs that must run on earlier versions of Windows as well as Windows 7 and later
 573                 #                                   versions should always call this function as GetProcessMemoryInfo. To ensure correct
 574                 #                                   resolution of symbols, add Psapi.lib to the TARGETLIBS macro and compile the program
 575                 #                                   with -DPSAPI_VERSION=1.To use run-time dynamic linking, load Psapi.dll.
 576                 #                                   https://docs.microsoft.com/en-us/windows/win32/api/psapi/nf-psapi-getprocessmemoryinfo
 577                 # -D_ALLOW_KEYWORD_MACROS           For VS2012 onwards the, C++ STL does not permit macro redefinitions of keywords
 578                 #                                   (see https://docs.microsoft.com/en-us/previous-versions/visualstudio/visual-studio-2012/bb531344(v=vs.110))
 579                 #                                   This definition prevents the complaint about the redefinition of inline by WinPCap
 580                 #                                   in pcap-stdinc.h when compiling C++ files, e.g. the Qt UI
 581                 /DPSAPI_VERSION=1
 582                 /D_ALLOW_KEYWORD_MACROS
 583                 # Disable deprecation of POSIX function names.
 584                 # https://stackoverflow.com/questions/37845163/what-is-the-purpose-of-microsofts-underscore-c-functions
 585                 /D_CRT_NONSTDC_NO_WARNINGS
 586         )
 587
 588         if(NOT WIRESHARK_TARGET_PLATFORM STREQUAL "win64")
 589                 add_definitions("/D_BIND_TO_CURRENT_CRT_VERSION=1")
 590         endif()
 591
 592         set(LOCAL_CFLAGS
 593                 /MP
 594         )
 595
 596         set(WS_LINK_FLAGS "/LARGEADDRESSAWARE /MANIFEST:NO /INCREMENTAL:NO /RELEASE")
 597
 598         # To do: Add /external:... See https://devblogs.microsoft.com/cppblog/broken-warnings-theory/
 599         #
 600         # /diagnostics:caret                Place a caret under compilation issues similar to
 601         #                                   Clang and gcc.
 602         # /Zo                               Enhanced debugging of optimised code
 603         # /utf-8                            Set Source and Executable character sets to UTF-8
 604         #                                   VS2015(MSVC14): On by default when /Zi or /Z7 used.
 605         # /guard:cf                         Control Flow Guard (compile and link).
 606         #                                   See https://docs.microsoft.com/en-us/windows/win32/secbp/control-flow-guard
 607         #                                   Note: This requires CMake 3.9.0 or newer.
 608         #                                   https://gitlab.kitware.com/cmake/cmake/commit/f973d49ab9d4c59b93f6dac812a94bb130200836
 609         # /Qspectre                         Speculative execution attack mitigation
 610         #                                   See https://devblogs.microsoft.com/cppblog/spectre-mitigations-in-msvc/
 611         list(APPEND LOCAL_CFLAGS /diagnostics:caret /Zo /utf-8 /guard:cf)
 612         set(WS_LINK_FLAGS "${WS_LINK_FLAGS} /guard:cf")
 613         # /Qspectre is not available for VS2015 or older VS2017. Test for its availability.
 614         set(WIRESHARK_COMMON_FLAGS /Qspectre)
 615
 616         if(ENABLE_CODE_ANALYSIS)
 617                 # We should probably add a code_analysis.props file and use it to set
 618                 # CAExcludePath, otherwise we trigger on Qt's headers:
 619                 # https://stackoverflow.com/questions/59669026/how-to-add-property-to-affect-code-analysis-in-cmake
 620                 # https://gitlab.kitware.com/cmake/cmake/-/issues/19682
 621                 # For now, we set CAExcludePath=C:\Qt;%include% in the Visual Studio
 622                 # Code Analys builder's environment.
 623                 list(APPEND LOCAL_CFLAGS
 624                         /analyze:WX-
 625                         /analyze:log:format:sarif
 626                         )
 627         endif()
 628
 629         # Additional compiler warnings to be treated as "Level 3"
 630         # when compiling Wireshark sources. (Selected from "level 4" warnings).
 631         ## 4295: array is too small to include a terminating null character
 632         ## 4100: unreferenced formal parameter
 633         ## 4189: local variable is initialized but not referenced
 634         # Disable warnings about use of flexible array members:
 635         ## 4200: nonstandard extension used : zero-sized array in struct/union
 636         list(APPEND LOCAL_CFLAGS /w34295 /w34100 /w34189 /wd4200)
 637
 638         # MSVC 14.28 + C11 enables C5105, but older Windows SDKs aren't completely compatible.
 639         # Windows SDK 10.0.17763.0 generates syntax errors with C11 enabled.
 640         # The variable CMAKE_VS_WINDOWS_TARGET_PLATFORM_VERSION does not work with the Ninja generator. Presumably it requires a VS generator.
 641         if (CMAKE_GENERATOR MATCHES "Visual Studio")
 642                 if (CMAKE_VS_WINDOWS_TARGET_PLATFORM_VERSION VERSION_LESS 10.0.18362.0)
 643                         message(FATAL_ERROR "Windows SDK ${CMAKE_VS_WINDOWS_TARGET_PLATFORM_VERSION} doesn't support C11. Please make sure you're using 10.0.20348.0 or later.")
 644                 endif()
 645                 # Windows SDK 10.0.18362.0 to 10.0.19041.685 generate warning C5105 with C11 enabled.
 646                 if(CMAKE_VS_WINDOWS_TARGET_PLATFORM_VERSION VERSION_LESS 10.0.20348.0)
 647                         message(WARNING "Windows SDK ${CMAKE_VS_WINDOWS_TARGET_PLATFORM_VERSION} doesn't support C11. Please make sure you're using 10.0.20348.0 or later.")
 648                         ## 5105: macro expansion producing 'defined' has undefined behavior
 649                         list(APPEND LOCAL_CFLAGS /wd5105)
 650                 endif()
 651         endif()
 652
 653         # We've matched these to specific compiler versions using the
 654         # checks above. There's no need to pass them to check_c_compiler_flag
 655         # or check_cxx_compiler_flag, which can be slow.
 656         string(REPLACE ";" " " _flags "${LOCAL_CFLAGS}")
 657         set(CMAKE_C_FLAGS "${_flags} ${CMAKE_C_FLAGS}")
 658         set(CMAKE_CXX_FLAGS "${_flags} ${CMAKE_CXX_FLAGS}")
 659
 660 else() # ! MSVC
 661         if(APPLE)
 662                 # MIN_MACOS_VERSION is used to set LSMinimumSystemVersion
 663                 # in Info.plist, so start with something low.
 664                 set(MIN_MACOS_VERSION 10.10)
 665                 if(CMAKE_OSX_DEPLOYMENT_TARGET)
 666                         if(CMAKE_OSX_DEPLOYMENT_TARGET VERSION_LESS MIN_MACOS_VERSION)
 667                                 message(FATAL_ERROR "We don't support building for macOS < ${MIN_MACOS_VERSION}")
 668                         endif()
 669                         set(MIN_MACOS_VERSION ${CMAKE_OSX_DEPLOYMENT_TARGET})
 670                 endif()
 671         endif()
 672
 673         #
 674         # NOTE: Adding new warnings is a policy decision that can have far-reaching
 675         # implications for the project and each developers workflow. Modern
 676         # C compilers are on a race to add new warnings, not always sensibly.
 677         # They are opt-in so take a moment to fully consider the implications
 678         # of enabling the latest shiny new warning.
 679         # If in doubt ask on the Wireshark developer list (recommended).
 680         #
 681         list(APPEND WIRESHARK_COMMON_FLAGS
 682                 #
 683                 ### Flags common to C and C++ ###
 684                 #
 685                 # -O<X> and -g get set by the CMAKE_BUILD_TYPE
 686                 -Wall
 687                 -Wextra
 688                 -Wpointer-arith
 689                 -Wformat-security
 690                 -fno-strict-overflow
 691                 -fexcess-precision=fast # GCC-only
 692                 -Wvla
 693                 -Wattributes
 694                 -Wpragmas               # Clang-only
 695                 -Wheader-guard          # Clang-only
 696                 -Wcomma                 # Clang-only
 697                 -Wshorten-64-to-32      # Clang-only
 698                 -Wredundant-decls
 699                 -Wunreachable-code      # Clang-only
 700                 -Wdocumentation         # Clang-only
 701                 -Wlogical-op            # GCC-only
 702                 #
 703                 # Disable errors unconditionally for some static analysis warnings
 704                 # that are dormant at lower optimizations levels or active only in
 705                 # bleeding edge versions of a compiler and possibly also
 706                 # prone to false positives and compiler bugs. This is
 707                 # a big nuisance because the warning is dormant and a low
 708                 # priority target for action. That is very disruptive
 709                 # with -Werror enabled (the default on the master branch).
 710                 #
 711                 -Wno-error=stringop-overflow=
 712                 #
 713                 # XXX Now that we have a CI job with Release build type (using
 714                 # -O3 optimization level) the dormancy issue should be ameliorated
 715                 # so comment out these exceptions to re-evaluate the impact.
 716                 #-Wno-error=maybe-uninitialized
 717                 #-Wno-error=alloc-size-larger-than=
 718                 #
 719                 # Updating external dependencies can introduce new deprecations.
 720                 # Also fixing new internal deprecations takes time.
 721                 # We want to be able to build with -Werror in that case. New
 722                 # code should not introduce new deprecations in any case.
 723                 #
 724                 -Wno-error=deprecated-declarations
 725         )
 726
 727         if((NOT ENABLE_ASAN) AND (NOT ENABLE_TSAN) AND (NOT ENABLE_UBSAN) AND (NOT DISABLE_FRAME_LARGER_THAN_WARNING))
 728                 #
 729                 # Only do this if none of ASan, TSan, and UBSan are
 730                 # enabled; the instrumentation they add increases
 731                 # the stack usage - we only care about stack
 732                 # usage in normal operation.
 733                 #
 734                 list(APPEND WIRESHARK_COMMON_FLAGS
 735                         -Wframe-larger-than=32768
 736                 )
 737         endif()
 738
 739         list(APPEND WIRESHARK_C_ONLY_FLAGS
 740                 #
 741                 ### Flags for C only ###
 742                 #
 743                 #
 744                 # XXX - some versions of GCC, including the one in at
 745                 # least some Xcode versions that come with Mac OS X
 746                 # 10.5, complain about variables in function and
 747                 # function pointer *declarations* shadowing other
 748                 # variables.  The autoconf script checked for that; we
 749                 # don't.
 750                 -Wshadow
 751                 -Wold-style-definition
 752                 -Wstrict-prototypes
 753         )
 754
 755         #
 756         # The universal zero initializer (in C: struct s x = { 0 };) for
 757         # structures with multiple members is perfectly legal, but some older
 758         # compilers warn about it. Silence those older compilers.
 759         #
 760         if((CMAKE_C_COMPILER_ID STREQUAL "GNU" AND CMAKE_C_COMPILER_VERSION VERSION_LESS "5.1") OR
 761            (CMAKE_C_COMPILER_ID STREQUAL "Clang" AND CMAKE_C_COMPILER_VERSION VERSION_LESS "6.0") OR
 762            (CMAKE_C_COMPILER_ID STREQUAL "AppleClang" AND CMAKE_C_COMPILER_VERSION VERSION_LESS "12.0"))
 763                 if(NOT CMAKE_C_COMPILER_ID STREQUAL "GNU" OR CMAKE_C_COMPILER_VERSION VERSION_LESS "5.0")
 764                         list(APPEND WIRESHARK_C_ONLY_FLAGS -Wno-missing-field-initializers)
 765                 endif()
 766                 # Silence warnings for initialization of nested structs like
 767                 # struct { struct { int a, b; } s; int c; } v = { 0 };
 768                 list(APPEND WIRESHARK_C_ONLY_FLAGS -Wno-missing-braces)
 769         endif()
 770
 771         list(APPEND WIRESHARK_CXX_ONLY_FLAGS
 772                 #
 773                 ### Flags for C++ only ###
 774                 #
 775                 -Wextra-semi    # Clang-only
 776         )
 777
 778         #
 779         # Not all warnings are the same. They fall on a spectrum from "critical"
 780         # to "pedantic nonsense". These are warnings that realistically are worth
 781         # fixing eventually.
 782         #
 783         if(ENABLE_TODO_WARNINGS)
 784                 list(APPEND WIRESHARK_COMMON_FLAGS
 785                         #
 786                         # All the registration functions block these for now.
 787                         #
 788                         -Wmissing-prototypes
 789                         -Wmissing-declarations
 790                         #
 791                         # A bunch of "that might not work on SPARC" code blocks
 792                         # this one for now; some of it is code that *will* work
 793                         # on SPARC, such as casts of "struct sockaddr *" to
 794                         # "struct sockaddr_in *", which are required by some
 795                         # APIs such as getifaddrs().
 796                         #
 797                         -Wcast-align
 798                 )
 799         else()
 800                 list(APPEND WIRESHARK_COMMON_FLAGS
 801                         #
 802                         # Converting from g_printf() and g_snprintf() to stdio.h turns
 803                         # up many of these warnings. They will have to be handled later.
 804                         # It can be a lot of work to fix properly and none of them
 805                         # seem to flag very interesting issues.
 806                         #
 807                         -Wno-format-truncation # Enabled with -Wall
 808                 )
 809                 list(APPEND WIRESHARK_C_ONLY_FLAGS
 810                         -Wno-pointer-sign # Enabled with -Wall
 811                 )
 812         endif()
 813
 814         #
 815         # These are not enabled by default, because the warnings they
 816         # produce are very hard or impossible to eliminate.
 817         #
 818         if(ENABLE_PEDANTIC_COMPILER_WARNINGS)
 819                 list(APPEND WIRESHARK_COMMON_FLAGS
 820                         # The following are for C and C++
 821                         -Wpedantic
 822                         -Wno-overlength-strings
 823                         -Wno-long-long
 824                         #
 825                         # As we use variadic macros, we don't want warnings
 826                         # about them, even with -Wpedantic.
 827                         #
 828                         -Wno-variadic-macros
 829                         #
 830                         # Various code blocks this one.
 831                         #
 832                         -Woverflow
 833                         -fstrict-overflow -Wstrict-overflow=4
 834                         #
 835                         # Due to various places where APIs we don't control
 836                         # require us to cast away constness, we can probably
 837                         # never enable this one with -Werror.
 838                         #
 839                         -Wcast-qual
 840                         #
 841                         # Doesn't warn of interesting issues. Usually the
 842                         # duplicated branches are protocol constants that
 843                         # happen to be equal and are relevant for documentation
 844                         # and readability and are trivially optimized by the
 845                         # compiler.
 846                         #
 847                         -Wduplicated-branches           # GCC-only
 848                         #
 849                         # No longer supported by El Capitan clang on C++
 850                         # XXX - is this one of those where CMake's check
 851                         # doesn't fail, so it won't reject this?
 852                         #
 853                         -fno-delete-null-pointer-checks
 854                 )
 855
 856                 #
 857                 # Some loops are safe, but it's hard to convince the compiler of
 858                 # that. Always disable the warning on GCC 7 due to a bug that
 859                 # cause lots of false positives.
 860                 # https://gcc.gnu.org/bugzilla/show_bug.cgi?id=81408
 861                 #
 862                 if(CMAKE_C_COMPILER_ID STREQUAL "GNU" AND NOT CMAKE_C_COMPILER_VERSION MATCHES "^7\\.")
 863                         list(APPEND WIRESHARK_COMMON_FLAGS -Wunsafe-loop-optimizations)
 864                 endif()
 865
 866                 list(APPEND WIRESHARK_C_ONLY_FLAGS
 867                         # The following are C only, not C++
 868                         #
 869                         # Due to various places where APIs we don't control
 870                         # require us to cast away constness, we can probably
 871                         # never enable this one with -Werror.
 872                         #
 873                         -Wbad-function-cast
 874                 )
 875
 876                 list(APPEND WIRESHARK_CXX_ONLY_FLAGS
 877                 )
 878         endif()
 879
 880         if(ENABLE_COMPILER_COLOR_DIAGNOSTICS)
 881                 if(CMAKE_C_COMPILER_ID MATCHES "Clang")
 882                         set(WIRESHARK_COMMON_FLAGS ${WIRESHARK_COMMON_FLAGS}
 883                                 -fcolor-diagnostics
 884                         )
 885                 elseif(CMAKE_C_COMPILER_ID MATCHES "GNU")
 886                         set(WIRESHARK_COMMON_FLAGS ${WIRESHARK_COMMON_FLAGS}
 887                                 -fdiagnostics-color=always
 888                         )
 889                 endif()
 890         endif()
 891
 892         set(WIRESHARK_LD_FLAGS
 893                 # See also CheckCLinkerFlag.cmake
 894                 -Wl,--as-needed
 895                 # -flto
 896                 # -fwhopr
 897                 # -fwhole-program
 898         )
 899 endif() # ! MSVC
 900
 901 # Counterhack to work around some cache magic in CHECK_C_SOURCE_COMPILES
 902 include(CheckCCompilerFlag)
 903 include(CheckCXXCompilerFlag)
 904
 905 if(ENABLE_STATIC)
 906         set(BUILD_SHARED_LIBS 0)
 907 else()
 908         set(BUILD_SHARED_LIBS 1)
 909 endif()
 910
 911 function(test_compiler_flag _lang _this_flag _valid_flags_var)
 912         string(MAKE_C_IDENTIFIER "${_lang}${_this_flag}_VALID" _flag_var)
 913         set(_test_flags "${${_valid_flags_var}} ${_this_flag}")
 914         if(_lang STREQUAL "C")
 915                 check_c_compiler_flag("${_test_flags}" ${_flag_var})
 916         elseif(_lang STREQUAL "CXX")
 917                 check_cxx_compiler_flag("${_test_flags}" ${_flag_var})
 918         else()
 919                 message(FATAL_ERROR "Language must be C or CXX")
 920         endif()
 921         if (${_flag_var})
 922                 set(${_valid_flags_var} "${_test_flags}" PARENT_SCOPE)
 923         endif()
 924 endfunction()
 925
 926 foreach(THIS_FLAG ${WIRESHARK_COMMON_FLAGS} ${WIRESHARK_C_ONLY_FLAGS})
 927         test_compiler_flag(C ${THIS_FLAG} ADDED_CMAKE_C_FLAGS)
 928 endforeach()
 929 set(CMAKE_C_FLAGS "${ADDED_CMAKE_C_FLAGS} ${CMAKE_C_FLAGS}")
 930
 931 foreach(THIS_FLAG ${WIRESHARK_COMMON_FLAGS} ${WIRESHARK_CXX_ONLY_FLAGS})
 932         test_compiler_flag(CXX ${THIS_FLAG} ADDED_CMAKE_CXX_FLAGS)
 933 endforeach()
 934 set(CMAKE_CXX_FLAGS "${ADDED_CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 935
 936 # Strips the source and build directory prefix from the __FILE__ macro to ensure
 937 # reproducible builds. Supported since GCC 8, Clang support is pending.
 938 if(CMAKE_C_COMPILER_ID MATCHES "GNU" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 939         # If the build dir is within the source dir, CMake will use something
 940         # like ../epan/dfilter/semcheck.c. Map these relative paths in addition
 941         # to CMAKE_BINARY_DIR since compile_commands.json uses absolute paths.
 942         file(RELATIVE_PATH _relative_source_dir "${CMAKE_BINARY_DIR}" "${CMAKE_SOURCE_DIR}")
 943         string(REGEX REPLACE "/$" "" _relative_source_dir "${_relative_source_dir}")
 944
 945         check_c_compiler_flag(-fmacro-prefix-map=old=new C_fmacro_prefix_map_old_new_VALID)
 946         check_cxx_compiler_flag(-fmacro-prefix-map=old=new CXX_fmacro_prefix_map_old_new_VALID)
 947         foreach(_lang C CXX)
 948                 if(${_lang}_fmacro_prefix_map_old_new_VALID)
 949                         set(_flags CMAKE_${_lang}_FLAGS)
 950                         set(${_flags} "${${_flags}} -fmacro-prefix-map=${CMAKE_SOURCE_DIR}/=")
 951                         set(${_flags} "${${_flags}} -fmacro-prefix-map=${CMAKE_BINARY_DIR}/=")
 952                         if(_relative_source_dir MATCHES "\\.\\.$")
 953                                 set(${_flags} "${${_flags}} -fmacro-prefix-map=${_relative_source_dir}/=")
 954                         endif()
 955                 endif()
 956         endforeach()
 957 endif()
 958
 959 include(CMakePushCheckState)
 960
 961 if(ENABLE_ASAN)
 962         # Available since MSVC 2019 version 16.9
 963         cmake_push_check_state()
 964         set(ASAN_FLAG "-fsanitize=address")
 965         set(CMAKE_REQUIRED_FLAGS ${ASAN_FLAG})
 966         check_c_compiler_flag(${ASAN_FLAG} C__fsanitize_address_VALID)
 967         check_cxx_compiler_flag(${ASAN_FLAG} CXX__fsanitize_address_VALID)
 968         cmake_pop_check_state()
 969         if(NOT C__fsanitize_address_VALID OR NOT CXX__fsanitize_address_VALID)
 970                 message(FATAL_ERROR "ENABLE_ASAN was requested, but not supported!")
 971         endif()
 972         add_compile_options(${ASAN_FLAG})
 973         if (MSVC)
 974                 # Using ASAN makes some of our code require object files with
 975                 # a 32-bit index to the section table instead of 16-bit.
 976                 # This makes the .obj files slightly larger (~2%) and makes
 977                 # it so that Microsoft linkers prior to MSVC 2005 can't read
 978                 # the files, but those are too old anyway.
 979                 add_compile_options(/bigobj)
 980                 # The Microsoft LINK linker doesn't recognize or need the
 981                 # ASAN flag, and will give a LNK4044 warning.
 982         else()
 983                 # Clang/gcc need the flag added to the linker
 984                 # add_link_options since CMake 3.13 (our minimum)
 985                 add_link_options(${ASAN_FLAG})
 986         endif()
 987         # Disable ASAN for build-time tools, e.g. lemon
 988         # (MSVC doesn't support this flag)
 989         check_c_compiler_flag(-fno-sanitize=all C__fno_sanitize_all_VALID)
 990         if(C__fno_sanitize_all_VALID)
 991                 set(NO_SANITIZE_CFLAGS "-fno-sanitize=all")
 992                 set(NO_SANITIZE_LDFLAGS "-fno-sanitize=all")
 993         endif()
 994 endif()
 995
 996 if(ENABLE_TSAN)
 997         # Available since Clang >= 3.2 and GCC >= 4.8
 998         cmake_push_check_state()
 999         set(CMAKE_REQUIRED_LIBRARIES "-fsanitize=thread")
1000         check_c_compiler_flag(-fsanitize=thread C__fsanitize_thread_VALID)
1001         check_cxx_compiler_flag(-fsanitize=thread CXX__fsanitize_thread_VALID)
1002         cmake_pop_check_state()
1003         if(NOT C__fsanitize_thread_VALID OR NOT CXX__fsanitize_thread_VALID)
1004                 message(FATAL_ERROR "ENABLE_TSAN was requested, but not supported!")
1005         endif()
1006         set(CMAKE_C_FLAGS "-fsanitize=thread ${CMAKE_C_FLAGS}")
1007         set(CMAKE_CXX_FLAGS "-fsanitize=thread ${CMAKE_CXX_FLAGS}")
1008         set(WS_LINK_FLAGS "-fsanitize=thread ${WS_LINK_FLAGS}")
1009 endif()
1010
1011 if(ENABLE_UBSAN)
1012         # Available since Clang >= 3.3 and GCC >= 4.9
1013         cmake_push_check_state()
1014         set(CMAKE_REQUIRED_LIBRARIES "-fsanitize=undefined")
1015         check_c_compiler_flag(-fsanitize=undefined C__fsanitize_undefined_VALID)
1016         check_cxx_compiler_flag(-fsanitize=undefined CXX__fsanitize_undefined_VALID)
1017         cmake_pop_check_state()
1018         if(NOT C__fsanitize_undefined_VALID OR NOT CXX__fsanitize_undefined_VALID)
1019                 message(FATAL_ERROR "ENABLE_UBSAN was requested, but not supported!")
1020         endif()
1021         set(CMAKE_C_FLAGS "-fsanitize=undefined ${CMAKE_C_FLAGS}")
1022         set(CMAKE_CXX_FLAGS "-fsanitize=undefined ${CMAKE_CXX_FLAGS}")
1023 endif()
1024
1025 if(ENABLE_FUZZER)
1026         # Available since Clang >= 6
1027         # Will enable coverage flags which can be used by the fuzzshark target.
1028         cmake_push_check_state()
1029         set(CMAKE_REQUIRED_LIBRARIES "-fsanitize=fuzzer-no-link")
1030         check_c_compiler_flag(-fsanitize=fuzzer C__fsanitize_fuzzer_no_link_VALID)
1031         check_cxx_compiler_flag(-fsanitize=fuzzer CXX__fsanitize_fuzzer_no_link_VALID)
1032         cmake_pop_check_state()
1033         if(NOT C__fsanitize_fuzzer_no_link_VALID OR NOT CXX__fsanitize_fuzzer_no_link_VALID)
1034                 message(FATAL_ERROR "ENABLE_FUZZER was requested, but not supported!")
1035         endif()
1036         set(CMAKE_C_FLAGS "-fsanitize=fuzzer-no-link ${CMAKE_C_FLAGS}")
1037         set(CMAKE_CXX_FLAGS "-fsanitize=fuzzer-no-link ${CMAKE_CXX_FLAGS}")
1038 endif()
1039
1040 if(MSVC)
1041         if(ENABLE_VLD)
1042                 include(FindVLD)
1043                 if(NOT VLD_FOUND)
1044                         message(FATAL_ERROR "ENABLE_VLD was requested, but not found!")
1045                 endif()
1046                 message(STATUS "Enabling Visual Leak Detector in Debug configuration")
1047                 set(WS_MSVC_DEBUG_LINK_FLAGS ${VLD_LINK_FLAGS})
1048         endif()
1049 endif()
1050
1051 set(WERROR_COMMON_FLAGS "")
1052 if(ENABLE_WERROR)
1053         if(CMAKE_C_COMPILER_ID MATCHES "MSVC")
1054                 set(WERROR_COMMON_FLAGS "/WX")
1055         else()
1056                 #
1057                 # If a warning has been enabled by -Wall or -W,
1058                 # and have specified -Werror, there appears to be
1059                 # no way, in Apple's llvm-gcc, to prevent that
1060                 # particular warning from giving an error - not
1061                 # with a pragma, not with -Wno-{warning}, and not
1062                 # with -Wno-error={warning}.
1063                 #
1064                 # Therefore, with that compiler, we just disable
1065                 # -Werror.
1066                 #
1067                 if ((NOT APPLE) OR CMAKE_C_COMPILER_ID MATCHES "Clang")
1068                         check_c_compiler_flag(-Werror WERROR)
1069                         if (WERROR)
1070                                 set(WERROR_COMMON_FLAGS "-Werror")
1071                         endif()
1072                 endif()
1073         endif()
1074 endif()
1075
1076 #
1077 # Try to have the compiler default to hiding symbols, so that only
1078 # symbols explicitly exported with WS_DLL_PUBLIC will be visible
1079 # outside (shared) libraries; that way, more UN*X builds will catch
1080 # failures to export symbols, rather than having that fail only on
1081 # Windows.
1082 #
1083 # We don't need that with MSVC, as that's the default.
1084 #
1085 if( NOT CMAKE_C_COMPILER_ID MATCHES "MSVC")
1086         #
1087         # Try the GCC-and-compatible -fvisibility-hidden first.
1088         #
1089         check_c_compiler_flag(-fvisibility=hidden FVHIDDEN)
1090         if(FVHIDDEN)
1091                 set(CMAKE_C_FLAGS "-fvisibility=hidden ${CMAKE_C_FLAGS}")
1092         else()
1093                 #
1094                 # OK, try the Sun^WOracle C -xldscope=hidden
1095                 #
1096                 check_c_compiler_flag(-xldscope=hidden XLDSCOPEHIDDEN)
1097                 if(XLDSCOPEHIDDEN)
1098                         set(CMAKE_C_FLAGS "-xldscope=hidden ${CMAKE_C_FLAGS}")
1099                 else()
1100                         #
1101                         # Anything else?
1102                         # If there is anything else, we might want to
1103                         # make a list of options to try, and try them
1104                         # in a loop.
1105                         #
1106                         message(WARNING "Hiding shared library symbols is not supported by the compiler."
1107                                 " All shared library symbols will be exported.")
1108                 endif()
1109         endif()
1110 endif()
1111
1112 include(CheckCLinkerFlag)
1113
1114 if(NOT CMAKE_C_COMPILER_ID MATCHES "MSVC" AND NOT OSS_FUZZ)
1115         #
1116         # The -pie linker option produces a position-independent executable.
1117         # Some Linux distributions have this enabled by default in the compiler,
1118         # so setting it here will be superfluous though.
1119         #
1120         # Note that linking with static libraries that are not position
1121         # independent may fail, the user can set CMAKE_EXE_LINKER_FLAGS=-no-pie
1122         # as a workaround.
1123         #
1124         if(CMAKE_VERSION VERSION_LESS "3.14")
1125                 check_c_linker_flag(-pie LINK_pie_VALID)
1126                 if(LINK_pie_VALID)
1127                         set(CMAKE_EXE_LINKER_FLAGS "-pie ${CMAKE_EXE_LINKER_FLAGS}")
1128                 endif()
1129         else()
1130                 include(CheckPIESupported)
1131                 check_pie_supported()
1132         endif()
1133 endif()
1134
1135 foreach(THIS_FLAG ${WIRESHARK_LD_FLAGS})
1136         string(MAKE_C_IDENTIFIER "LINK${THIS_FLAG}_VALID" _flag_var)
1137         check_c_linker_flag(${THIS_FLAG} ${_flag_var})
1138         if (${_flag_var})
1139                 set(WS_LINK_FLAGS "${WS_LINK_FLAGS} ${THIS_FLAG}")
1140         endif()
1141 endforeach()
1142 message(STATUS "Linker flags: ${WS_LINK_FLAGS}")
1143
1144 if(APPLE AND EXISTS /usr/local/opt/gettext)
1145         # GLib on macOS requires libintl. Homebrew installs gettext (and
1146         # libintl) in /usr/local/opt/gettext
1147         include_directories(SYSTEM /usr/local/opt/gettext/include)
1148         link_directories(/usr/local/opt/gettext/lib)
1149 endif()
1150
1151 # Resets cache variables if the <PackageName>_LIBRARY has become invalid.
1152 # Call it before a find_package(<PackageName> ...) invocation that uses
1153 # find_library(<PackageName>_LIBRARY ...).
1154 #
1155 # Usage: reset_find_package(<PackageName> [<extra variables to clear>])
1156 function(reset_find_package _package_name)
1157         set(variables
1158                 # find_library / find_package
1159                 ${_package_name}_LIBRARY
1160                 ${_package_name}_INCLUDE_DIR
1161                 # mark_as_advanced
1162                 ${_package_name}_LIBRARIES
1163                 ${_package_name}_INCLUDE_DIRS
1164                 # Others
1165                 ${_package_name}_DLL_DIR
1166                 ${_package_name}_DLLS
1167                 ${_package_name}_DLL
1168                 ${_package_name}_PDB
1169                 ${ARGN}
1170         )
1171         if(NOT ${_package_name}_LIBRARY OR EXISTS ${${_package_name}_LIBRARY})
1172                 # Cache variable is already missing or cache entry is valid.
1173                 return()
1174         endif()
1175         message(STATUS "Package ${_package_name} has changed, clearing cache.")
1176         foreach(_var IN LISTS variables)
1177                 unset(${_var} CACHE)
1178         endforeach()
1179 endfunction()
1180
1181 # ws_find_package(<PackageName>
1182 #             <CMakeOptions.txt boolean variable>
1183 #             <cmakeconfig.h.in macro definition>
1184 #             [remaining find_package() arguments])
1185 macro(ws_find_package _package_name _enable_package _package_cmakedefine)
1186         if(${_enable_package})
1187                 # Clear outdated cache variables if not already.
1188                 reset_find_package(${_package_name})
1189                 find_package(${_package_name} ${ARGN})
1190                 if(${_package_name}_FOUND)
1191                         set(${_package_cmakedefine} 1)
1192                 endif()
1193         endif()
1194 endmacro()
1195
1196 # The minimum package list
1197 find_package(Git)
1198 reset_find_package(GLIB2 GLIB2_MAIN_INCLUDE_DIR GLIB2_INTERNAL_INCLUDE_DIR)
1199 find_package(GLIB2 "2.54.0" REQUIRED)
1200 include_directories(SYSTEM ${GLIB2_INCLUDE_DIRS})
1201 reset_find_package(GMODULE2)
1202 find_package(GMODULE2)
1203 reset_find_package(GTHREAD2)
1204 find_package(GTHREAD2 REQUIRED)
1205 reset_find_package(GCRYPT GCRYPT_ERROR_LIBRARY)
1206 find_package(GCRYPT "1.8.0" REQUIRED)
1207 # C Asynchronous resolver
1208 reset_find_package(CARES)
1209 find_package(CARES "1.13.0" REQUIRED)
1210 find_package(LEX REQUIRED)
1211 find_package(Perl)
1212 find_package(PCRE2 REQUIRED)
1213
1214 if (NOT WIN32)
1215         find_package(Gettext)
1216         find_package(M REQUIRED)
1217 endif()
1218
1219 if(BUILD_sshdump OR BUILD_ciscodump OR BUILD_wifidump)
1220         set(ENABLE_LIBSSH ON)
1221 else()
1222         set(ENABLE_LIBSSH OFF)
1223 endif()
1224 ws_find_package(LIBSSH ENABLE_LIBSSH HAVE_LIBSSH "0.6")
1225
1226 ws_find_package(PCAP ENABLE_PCAP HAVE_LIBPCAP)
1227 ws_find_package(AIRPCAP ENABLE_AIRPCAP HAVE_AIRPCAP)
1228 ws_find_package(Systemd BUILD_sdjournal HAVE_SYSTEMD)
1229
1230 # Build one of the Qt GUIs?
1231 if(BUILD_wireshark OR BUILD_logray)
1232         if(USE_qt6)
1233                 if(DEFINED ENV{WIRESHARK_QT6_PREFIX_PATH})
1234                         list(APPEND CMAKE_PREFIX_PATH $ENV{WIRESHARK_QT6_PREFIX_PATH})
1235                 endif()
1236
1237                 set(CMAKE_CXX_STANDARD 17)
1238                 # Setting CMAKE_CXX_STANDARD is not sufficient with MSVC, see
1239                 #   https://gitlab.kitware.com/cmake/cmake/-/issues/18837
1240                 # The below test can be found in Qt6, lib/cmake/Qt6/QtFeature.cmake
1241                 if(CMAKE_CXX_COMPILER_ID STREQUAL "MSVC" AND MSVC_VERSION GREATER_EQUAL 1913)
1242                         # Cannot use add_definitions() here because rc.exe does not understand this flag.
1243                         # https://cmake.org/pipermail/cmake/2009-August/031672.html
1244                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Zc:__cplusplus")
1245                 endif()
1246
1247                 find_package(Qt6 REQUIRED
1248                         COMPONENTS
1249                                 Core
1250                                 Gui
1251                                 LinguistTools
1252                                 PrintSupport
1253                                 Widgets
1254                                 Concurrent
1255                                 Core5Compat
1256                         OPTIONAL_COMPONENTS
1257                                 Multimedia
1258                 )
1259         else(USE_qt6)
1260                 if(DEFINED ENV{WIRESHARK_QT5_PREFIX_PATH})
1261                         list(APPEND CMAKE_PREFIX_PATH $ENV{WIRESHARK_QT5_PREFIX_PATH})
1262                 endif()
1263                 if(APPLE AND EXISTS /usr/local/opt/qt5)
1264                         # Homebrew installs Qt5 (up to at least 5.11.0) in
1265                         # /usr/local/qt5. Ensure that it can be found by CMake
1266                         # since it is not in the default /usr/local prefix.
1267                         # Add it to PATHS so that it doesn't override the
1268                         # CMAKE_PREFIX_PATH environment variable.
1269                         # QT_FIND_PACKAGE_OPTIONS should be passed to find_package,
1270                         # e.g. find_package(Qt5Core ${QT_FIND_PACKAGE_OPTIONS})
1271                         list(APPEND QT5_FIND_PACKAGE_OPTIONS PATHS /usr/local/opt/qt5)
1272                 endif()
1273
1274                 set(QT5_PACKAGELIST
1275                         Qt5Core
1276                         Qt5Gui
1277                         Qt5LinguistTools
1278                         Qt5PrintSupport
1279                         Qt5Widgets
1280                         Qt5Concurrent
1281                 )
1282                 set(QT5_OPTIONAL_PACKAGELIST
1283                         Qt5Multimedia
1284                 )
1285                 if(WIN32)
1286                         list(APPEND QT5_PACKAGELIST Qt5WinExtras)
1287                 endif()
1288                 foreach(_qt5_package IN LISTS QT5_PACKAGELIST)
1289                         find_package(${_qt5_package} REQUIRED ${QT5_FIND_PACKAGE_OPTIONS})
1290                         list(APPEND QT5_LIBRARIES ${${_qt5_package}_LIBRARIES})
1291                         list(APPEND QT5_INCLUDE_DIRS ${${_qt5_package}_INCLUDE_DIRS})
1292                         list(APPEND QT5_COMPILE_DEFINITIONS ${${_qt5_package}_COMPILE_DEFINITIONS})
1293                 endforeach()
1294                 foreach(_qt5_package IN LISTS QT5_OPTIONAL_PACKAGELIST)
1295                         find_package(${_qt5_package} ${QT5_FIND_PACKAGE_OPTIONS})
1296                         list(APPEND QT5_LIBRARIES ${${_qt5_package}_LIBRARIES})
1297                         list(APPEND QT5_INCLUDE_DIRS ${${_qt5_package}_INCLUDE_DIRS})
1298                         list(APPEND QT5_COMPILE_DEFINITIONS ${${_qt5_package}_COMPILE_DEFINITIONS})
1299                 endforeach()
1300
1301                 if (Qt5Widgets_VERSION VERSION_LESS 5.10)
1302                         message(FATAL_ERROR "Qt 5.12 or later is required.")
1303                 endif()
1304                 if (Qt5Widgets_VERSION VERSION_LESS 5.12)
1305                         message(WARNING "Wireshark can be build with this version of Qt, though 5.12 or higher is recommended.")
1306                 endif()
1307
1308                 if(APPLE AND "/usr/local/opt/qt5/lib/QtCore.framework" IN_LIST Qt5Core_INCLUDE_DIRS)
1309                         # When qt@6 and qt@5 are both installed via Homebrew,
1310                         # /usr/local/include/QtCore/qvariant.h points to Qt 6 headers.
1311                         # Normally the Headers from `-iframework /usr/local/opt/qt5/lib`
1312                         # should be used, but `-isystem /usr/local/include` (via
1313                         # Libgcrypt and others) seems to prioritized, resulting in use
1314                         # of the Qt6 headers. Resolve this by explicit including Qt5.
1315                         list(APPEND QT5_INCLUDE_DIRS /usr/local/opt/qt5/include)
1316                 endif()
1317         endif(USE_qt6)
1318
1319         set(QT_FOUND ON)
1320         if(APPLE)
1321                 ws_find_package(Sparkle ENABLE_SPARKLE HAVE_SOFTWARE_UPDATE 2)
1322         endif()
1323         if(Qt6Multimedia_FOUND OR Qt5Multimedia_FOUND)
1324                 set(QT_MULTIMEDIA_LIB 1)
1325         endif()
1326         if(NOT DEFINED MOC_OPTIONS)
1327                 # Squelch moc verbose "nothing to do" output
1328                 set(MOC_OPTIONS -nn)
1329         endif()
1330 endif()
1331
1332 # MaxMind DB address resolution
1333 reset_find_package(MAXMINDDB)
1334 ws_find_package(MaxMindDB BUILD_mmdbresolve HAVE_MAXMINDDB)
1335
1336 # SMI SNMP
1337 reset_find_package(SMI SMI_SHARE_DIR)
1338 ws_find_package(SMI ENABLE_SMI HAVE_LIBSMI)
1339
1340 # Support for TLS decryption using RSA private keys.
1341 ws_find_package(GNUTLS ENABLE_GNUTLS HAVE_LIBGNUTLS "3.5.8")
1342
1343 # Kerberos
1344 ws_find_package(KERBEROS ENABLE_KERBEROS HAVE_KERBEROS)
1345
1346 # Zlib compression
1347 ws_find_package(ZLIB ENABLE_ZLIB HAVE_ZLIB)
1348
1349 # Minizip compression
1350 ws_find_package(Minizip ENABLE_MINIZIP HAVE_MINIZIP)
1351
1352 # Brotli compression
1353 ws_find_package(BROTLI ENABLE_BROTLI HAVE_BROTLI)
1354
1355 # LZ4 compression
1356 ws_find_package(LZ4 ENABLE_LZ4 HAVE_LZ4)
1357
1358 # Snappy compression
1359 ws_find_package(SNAPPY ENABLE_SNAPPY HAVE_SNAPPY)
1360
1361 # zstd compression
1362 ws_find_package(ZSTD ENABLE_ZSTD HAVE_ZSTD "1.0.0")
1363
1364 # Enhanced HTTP/2 dissection
1365 ws_find_package(NGHTTP2 ENABLE_NGHTTP2 HAVE_NGHTTP2 "1.11.0")
1366
1367 # Embedded Lua interpreter
1368 ws_find_package(LUA ENABLE_LUA HAVE_LUA "5.1")
1369
1370 ws_find_package(NL ENABLE_NETLINK HAVE_LIBNL)
1371
1372 ws_find_package(SBC ENABLE_SBC HAVE_SBC)
1373
1374 # SpanDSP codec
1375 ws_find_package(SPANDSP ENABLE_SPANDSP HAVE_SPANDSP)
1376
1377 ws_find_package(BCG729 ENABLE_BCG729 HAVE_BCG729)
1378
1379 ws_find_package(AMRNB ENABLE_AMRNB HAVE_AMRNB)
1380
1381 ws_find_package(ILBC ENABLE_ILBC HAVE_ILBC)
1382
1383 ws_find_package(OPUS ENABLE_OPUS HAVE_OPUS)
1384
1385 if (BUILD_logray)
1386         # libsinsp+libscap, required for falco-bridge
1387         ws_find_package(Sinsp ENABLE_SINSP HAVE_SINSP)
1388 endif()
1389
1390 # CMake 3.9 and below used 'LIBXML2_LIBRARIES' as the name of the cache entry
1391 # storing the find_library result. Transfer it to the new cache variable such
1392 # that reset_find_package can detect and clear outdated cache variables.
1393 if(DEFINED LIBXML2_LIBRARIES AND NOT DEFINED LIBXML2_LIBRARY)
1394         set(LIBXML2_LIBRARY ${LIBXML2_LIBRARIES} CACHE FILEPATH "")
1395 endif()
1396 # Call reset_find_package explicitly since variables are in upper case.
1397 reset_find_package(LIBXML2)
1398 ws_find_package(LibXml2 ENABLE_LIBXML2 HAVE_LIBXML2)
1399 if(NOT LIBXML2_FOUND)
1400         # CMake 3.9 and below used LIBXML2_LIBRARIES as the name of
1401         # the cache entry storing the find_library result.
1402         # Current CMake (3.13) and below sets LIBXML2_LIBRARIES and LIBXML2_INCLUDE_DIRS
1403         # to a non-empty value, be sure to clear it when not found.
1404         set(LIBXML2_LIBRARIES "")
1405         set(LIBXML2_INCLUDE_DIRS "")
1406 endif()
1407
1408 # Capabilities to run dumpcap as non-root user.
1409 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
1410         ws_find_package(CAP ENABLE_CAP HAVE_LIBCAP)
1411         find_package(SETCAP)
1412 endif()
1413
1414 # Windows version updates
1415 ws_find_package(WinSparkle ENABLE_WINSPARKLE HAVE_SOFTWARE_UPDATE)
1416
1417 find_package( Asciidoctor 1.5 )
1418 find_package( XSLTPROC )
1419
1420 find_package(DOXYGEN)
1421
1422 # The SpeexDSP resampler is required iff building wireshark or sharkd.
1423 if(BUILD_wireshark OR BUILD_logray OR BUILD_sharkd)
1424         find_package(SpeexDSP REQUIRED)
1425 endif()
1426
1427 # Generate the distribution tarball.
1428 add_custom_target(dist
1429         COMMAND ${CMAKE_BINARY_DIR}/packaging/source/git-export-release.sh -d "${CMAKE_BINARY_DIR}"
1430         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
1431 )
1432
1433 if(GNUTLS_FOUND)
1434         # Calculating public keys from PKCS #11 private keys requires GnuTLS
1435         # 3.4.0 or greater.
1436         #
1437         # Check that the support is present in case GnuTLS was compiled
1438         # --without-p11-kit as macos-setup.sh did until December 2020.
1439         cmake_push_check_state()
1440         if(WIN32 AND NOT MINGW)
1441                 set(CMAKE_REQUIRED_DEFINITIONS -Dssize_t=int)
1442         endif()
1443         set(CMAKE_REQUIRED_INCLUDES ${GNUTLS_INCLUDE_DIRS})
1444         set(CMAKE_REQUIRED_LIBRARIES ${GNUTLS_LIBRARIES})
1445         check_symbol_exists(gnutls_pkcs11_obj_list_import_url4 gnutls/pkcs11.h HAVE_GNUTLS_PKCS11)
1446         cmake_pop_check_state()
1447 endif()
1448
1449 if (QT_FOUND)
1450         # CMake uses qmake to find Qt4. It relies on Qt's CMake modules
1451         # to find Qt5. This means that we can't assume that the qmake
1452         # in our PATH is the correct one. We can fetch qmake's location
1453         # from Qt5::qmake, which is defined in Qt5CoreConfigExtras.cmake.
1454         get_target_property(QT_QMAKE_EXECUTABLE Qt${qtver}::qmake IMPORTED_LOCATION)
1455         get_filename_component(_qt_bin_path "${QT_QMAKE_EXECUTABLE}" DIRECTORY)
1456         set(QT_BIN_PATH "${_qt_bin_path}" CACHE INTERNAL
1457                 "Path to qmake, macdeployqt, windeployqt, and other Qt utilities."
1458         )
1459         # Use qmake to find windeployqt and macdeployqt. Ideally one of
1460         # the modules in ${QTDIR}/lib/cmake would do this for us.
1461         if(WIN32)
1462                 if (USE_qt6 AND USE_MSYSTEM)
1463                         set(_windeployqt_name "windeployqt-qt6")
1464                 else()
1465                         set(_windeployqt_name "windeployqt")
1466                 endif()
1467                 find_program(QT_WINDEPLOYQT_EXECUTABLE ${_windeployqt_name}
1468                         HINTS "${QT_BIN_PATH}"
1469                         DOC "Path to the windeployqt utility."
1470                 )
1471                 # As of Qt 6.5.0, the official Qt "MSVC 2019 ARM64 (TP)" libraries don't ship
1472                 # with native Arm64 executables. Instead, you get x64 executables installed in
1473                 # msvc2019_x64. Look for the path to "qmake.bat", which has to be passed to
1474                 # windeployqt so that it can install the proper DLLs.
1475                 # https://bugreports.qt.io/browse/QTBUG-100070
1476                 set(QT_WINDEPLOYQT_EXTRA_ARGS)
1477                 find_program(_qt_qmake_bat qmake.bat
1478                         HINTS ENV CMAKE_PREFIX_PATH
1479                         PATH_SUFFIXES bin
1480                         DOC "Path to qmake.bat."
1481                 )
1482                 if(_qt_qmake_bat)
1483                         set (QT_WINDEPLOYQT_EXTRA_ARGS "--qmake \"${_qt_qmake_bat}\"")
1484                 endif()
1485         elseif(APPLE)
1486                 find_program(QT_MACDEPLOYQT_EXECUTABLE macdeployqt
1487                         HINTS "${QT_BIN_PATH}"
1488                         DOC "Path to the macdeployqt utility."
1489                 )
1490                 find_program(DMGBUILD_EXECUTABLE dmgbuild
1491                         DOC "Path to the dmgbuild utility"
1492                 )
1493                 # https://doc.qt.io/qt-5/supported-platforms.html
1494                 # https://doc.qt.io/qt-5.11/supported-platforms-and-configurations.html
1495                 # https://doc.qt.io/qt-5.15/supported-platforms.html
1496                 # https://doc-snapshots.qt.io/qt6-dev/supported-platforms.html
1497                 if(Qt${qtver}Widgets_VERSION VERSION_GREATER_EQUAL "6.0.0")
1498                         set(MIN_MACOS_VERSION 10.14)
1499                 elseif(Qt5Widgets_VERSION VERSION_GREATER_EQUAL "5.14.0")
1500                         set(MIN_MACOS_VERSION 10.13)
1501                 elseif(Qt5Widgets_VERSION VERSION_GREATER_EQUAL "5.12.0")
1502                         set(MIN_MACOS_VERSION 10.12)
1503                 elseif(Qt5Widgets_VERSION VERSION_GREATER_EQUAL "5.10.0")
1504                         set(MIN_MACOS_VERSION 10.11)
1505                 endif()
1506                 if(CMAKE_OSX_DEPLOYMENT_TARGET AND CMAKE_OSX_DEPLOYMENT_TARGET VERSION_LESS MIN_MACOS_VERSION)
1507                         message(FATAL_ERROR "Qt version ${Qt${qtver}Widgets_VERSION} requires CMAKE_OSX_DEPLOYMENT_TARGET (${CMAKE_OSX_DEPLOYMENT_TARGET}) >= ${MIN_MACOS_VERSION}")
1508                 endif()
1509         endif()
1510
1511         # Qt requires MSVC /permissive- option since 6.3 release
1512         if(CMAKE_CXX_COMPILER_ID STREQUAL "MSVC" AND Qt${qtver}Widgets_VERSION VERSION_GREATER_EQUAL "6.3.0")
1513                 add_compile_options("/permissive-")
1514         endif()
1515 endif()
1516
1517 if(ENABLE_CHECKHF_CONFLICT)
1518         set(ENABLE_CHECK_FILTER 1)
1519 endif()
1520
1521 #
1522 # Platform-specific additional libraries.
1523 #
1524 if(WIN32)
1525         set(WIN_COMCTL32_LIBRARY comctl32.lib)
1526         set(WIN_IPHLPAPI_LIBRARY iphlpapi.lib)
1527         set(WIN_PSAPI_LIBRARY    psapi.lib)
1528         set(WIN_VERSION_LIBRARY  version.lib)
1529         set(WIN_WS2_32_LIBRARY   ws2_32.lib)
1530 endif()
1531
1532 if(APPLE)
1533         #
1534         # We assume that APPLE means macOS so that we have the macOS
1535         # frameworks.
1536         #
1537         set(HAVE_MACOS_FRAMEWORKS 1)
1538         FIND_LIBRARY (APPLE_APPLICATION_SERVICES_LIBRARY ApplicationServices)
1539         FIND_LIBRARY (APPLE_APPKIT_LIBRARY AppKit)
1540         FIND_LIBRARY (APPLE_CORE_FOUNDATION_LIBRARY CoreFoundation)
1541         FIND_LIBRARY (APPLE_SYSTEM_CONFIGURATION_LIBRARY SystemConfiguration)
1542
1543         message(STATUS "Building for Mac OS X/OS X/macOS ${MIN_MACOS_VERSION} using SDK ${CMAKE_OSX_SYSROOT}")
1544 endif()
1545
1546 include(ConfigureChecks.cmake)
1547
1548 # Global properties
1549 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
1550
1551 if(ENABLE_CCACHE)
1552         if(NOT (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang"))
1553                 # https://ccache.dev/platform-compiler-language-support.html
1554                 message(WARNING "Ccache is enabled, but your compiler is ${CMAKE_C_COMPILER_ID}."
1555                 " We wish you the best of luck.")
1556         endif()
1557         find_program(CCACHE_EXECUTABLE ccache)
1558         if(CCACHE_EXECUTABLE)
1559                 set(CMAKE_C_COMPILER_LAUNCHER "${CCACHE_EXECUTABLE}")
1560                 set(CMAKE_CXX_COMPILER_LAUNCHER "${CCACHE_EXECUTABLE}")
1561                 set(CMAKE_C_LINKER_LAUNCHER "${CCACHE_EXECUTABLE}")
1562                 set(CMAKE_CXX_LINKER_LAUNCHER "${CCACHE_EXECUTABLE}")
1563         endif()
1564 endif()
1565
1566 # The top level checkAPIs target, add before subdirectory calls so it's avaiable to all
1567 add_custom_target(checkAPI)
1568 set_target_properties(checkAPI
1569         PROPERTIES
1570                 FOLDER "Auxiliary"
1571                 EXCLUDE_FROM_ALL True
1572                 EXCLUDE_FROM_DEFAULT_BUILD True
1573 )
1574
1575 include( UseCheckAPI )
1576
1577 # Target platform locations
1578 # UN*X in general, including macOS if not building an app bundle:
1579 # $DESTDIR/lib/wireshark/extcap
1580 # Windows: $DESTDIR/extcap
1581 # macOS app bundle: Wireshark.app/Contents/Resources/share/wireshark/extcap
1582 # If you change the nesting level be sure to check also the INSTALL_RPATH
1583 # target property.
1584 if(WIN32 AND NOT USE_MSYSTEM)
1585         set(EXTCAP_INSTALL_LIBDIR "extcap" CACHE INTERNAL "The extcap dir")
1586 else()
1587         set(EXTCAP_INSTALL_LIBDIR "${CMAKE_INSTALL_LIBDIR}/${PROJECT_NAME}/extcap" CACHE INTERNAL "The extcap dir")
1588 endif()
1589 set(EXTCAP_INSTALL_FULL_LIBDIR "${CMAKE_INSTALL_PREFIX}/${EXTCAP_INSTALL_LIBDIR}")
1590
1591 if(APPLE)
1592         #
1593         # As https://developer.apple.com/library/archive/technotes/tn2206/_index.html
1594         # says,
1595         #
1596         # "Note that a location where code is expected to reside cannot generally
1597         # contain directories full of nested code, because those directories tend
1598         # to be interpreted as bundles. So this occasional practice is not
1599         # recommended and not officially supported. If you do do this, do not use
1600         # periods in the directory names. The code signing machinery interprets
1601         # directories with periods in their names as code bundles and will reject
1602         # them if they don't conform to the expected code bundle layout."
1603         #
1604         set(PLUGIN_PATH_ID "${PROJECT_MAJOR_VERSION}-${PROJECT_MINOR_VERSION}")
1605 else()
1606         set(PLUGIN_PATH_ID "${PROJECT_MAJOR_VERSION}.${PROJECT_MINOR_VERSION}")
1607 endif()
1608
1609 # Directory where plugins and Lua dissectors can be found.
1610 if(WIN32 AND NOT USE_MSYSTEM)
1611         set(PLUGIN_INSTALL_LIBDIR "plugins" CACHE INTERNAL "The plugin dir")
1612 else()
1613         set(PLUGIN_INSTALL_LIBDIR "${CMAKE_INSTALL_LIBDIR}/${PROJECT_NAME}/plugins" CACHE INTERNAL "The plugin dir")
1614 endif()
1615 set(PLUGIN_INSTALL_FULL_LIBDIR "${CMAKE_INSTALL_PREFIX}/${PLUGIN_INSTALL_LIBDIR}")
1616 set(PLUGIN_INSTALL_VERSION_LIBDIR "${PLUGIN_INSTALL_LIBDIR}/${PLUGIN_PATH_ID}")
1617 set(PLUGIN_VERSION_DIR "plugins/${PLUGIN_PATH_ID}")
1618
1619 add_subdirectory( capture )
1620 add_subdirectory( doc )
1621 add_subdirectory( docbook EXCLUDE_FROM_ALL )
1622 add_subdirectory( epan )
1623 add_subdirectory( extcap )
1624 add_subdirectory( randpkt_core )
1625 if(NOT LEMON_EXECUTABLE)
1626         add_subdirectory( tools/lemon )
1627 endif()
1628 if(PCAP_FOUND)
1629         add_subdirectory( tools/radiotap-gen )
1630 endif()
1631 add_subdirectory( ui )
1632 add_subdirectory( wiretap )
1633 add_subdirectory( writecap )
1634
1635 # Location of our data files. This should be set to a value that allows
1636 # running from the build directory on Windows, on macOS when building an
1637 # application bundle, and on UNIX in general if
1638 # WIRESHARK_RUN_FROM_BUILD_DIRECTORY is set.
1639 if(ENABLE_APPLICATION_BUNDLE)
1640         if(CMAKE_CFG_INTDIR STREQUAL ".")
1641                 set(_datafile_dir "${CMAKE_BINARY_DIR}/run/Wireshark.app/Contents/Resources/share/wireshark")
1642         else()
1643                 # Xcode
1644                 set(_datafile_dir "${CMAKE_BINARY_DIR}/run/${CMAKE_CFG_INTDIR}/Wireshark.app/Contents/Resources/share/wireshark")
1645         endif()
1646 elseif(NOT CMAKE_CFG_INTDIR STREQUAL ".")
1647         # Visual Studio, Xcode, etc.
1648         set(_datafile_dir "${CMAKE_BINARY_DIR}/run/${CMAKE_CFG_INTDIR}")
1649 else()
1650         # Makefile, Ninja, etc.
1651         set(_datafile_dir "${CMAKE_BINARY_DIR}/run")
1652 endif()
1653
1654 set(DATAFILE_DIR ${_datafile_dir} CACHE INTERNAL "Build time data file location.")
1655
1656 if(ENABLE_APPLICATION_BUNDLE)
1657         if(CMAKE_CFG_INTDIR STREQUAL ".")
1658                 set(_log_datafile_dir "${CMAKE_BINARY_DIR}/run/Logray.app/Contents/Resources/share/logray")
1659         else()
1660                 # Xcode
1661                 set(_log_datafile_dir "${CMAKE_BINARY_DIR}/run/${CMAKE_CFG_INTDIR}/Logray.app/Contents/Resources/share/logray")
1662         endif()
1663         set(LOG_DATAFILE_DIR ${_log_datafile_dir} CACHE INTERNAL "Build time log analysis data file location.")
1664 # XXX We need to update wsutil/filesystem.c and packaging/nsis/*logray* to match.
1665 # elseif(NOT CMAKE_CFG_INTDIR STREQUAL ".")
1666 #       # Visual Studio, Xcode, etc.
1667 #       set(_log_datafile_dir "${CMAKE_BINARY_DIR}/run/${CMAKE_CFG_INTDIR}/share/logray")
1668 # else()
1669 #       # Makefile, Ninja, etc.
1670 #       set(_log_datafile_dir "${CMAKE_BINARY_DIR}/run/share/logray")
1671 endif()
1672
1673
1674 # wsutil must be added after DATAFILE_DIR is set such that filesystem.c can
1675 # learn about the directory location.
1676 add_subdirectory( wsutil )
1677
1678 if(BUILD_wireshark AND QT_FOUND)
1679         add_subdirectory( ui/qt )
1680 elseif(BUILD_wireshark AND USE_qt6)
1681         message(VERBOSE "To use Qt5 instead of Qt6 use CMake option USE_qt6=OFF.")
1682 endif()
1683
1684 if(BUILD_logray AND QT_FOUND)
1685         add_subdirectory( ui/logray )
1686 endif()
1687
1688 # Location of our plugins. PLUGIN_DIR should allow running
1689 # from the build directory similar to DATAFILE_DIR above.
1690 if(ENABLE_PLUGINS)
1691         # Target platform locations
1692         # UN*X in general, including macOS if not building an app bundle:
1693         # $DESTDIR/lib/wireshark/plugins/$VERSION
1694         # Windows: $DESTDIR/wireshark/plugins/$VERSION
1695         # macOS app bundle: Wireshark.app/Contents/PlugIns/wireshark
1696         set(HAVE_PLUGINS 1)
1697         add_custom_target(plugins)
1698         set_target_properties(plugins PROPERTIES FOLDER "Plugins")
1699         set(PLUGIN_SRC_DIRS
1700                 plugins/epan/ethercat
1701                 plugins/epan/gryphon
1702                 plugins/epan/irda
1703                 plugins/epan/mate
1704                 plugins/epan/opcua
1705                 plugins/epan/profinet
1706                 plugins/epan/stats_tree
1707                 plugins/epan/transum
1708                 plugins/epan/unistim
1709                 plugins/epan/wimax
1710                 plugins/epan/wimaxasncp
1711                 plugins/epan/wimaxmacphy
1712                 plugins/wiretap/usbdump
1713                 plugins/codecs/G711
1714                 plugins/codecs/l16_mono
1715                 ${CUSTOM_PLUGIN_SRC_DIR}
1716         )
1717         set(LOGRAY_PLUGIN_SRC_DIRS)
1718         if(SINSP_FOUND)
1719                 list(APPEND LOGRAY_PLUGIN_SRC_DIRS
1720                         plugins/epan/falco_bridge
1721                 )
1722         endif()
1723         if(SPANDSP_FOUND)
1724                 list(APPEND PLUGIN_SRC_DIRS
1725                         plugins/codecs/G722
1726                         plugins/codecs/G726
1727                 )
1728         endif()
1729         if(BCG729_FOUND)
1730                 list(APPEND PLUGIN_SRC_DIRS
1731                         plugins/codecs/G729
1732                 )
1733         endif()
1734         if(AMRNB_FOUND)
1735                 list(APPEND PLUGIN_SRC_DIRS
1736                         plugins/codecs/amrnb
1737                 )
1738         endif()
1739         if(ILBC_FOUND)
1740                 list(APPEND PLUGIN_SRC_DIRS
1741                         plugins/codecs/iLBC
1742                 )
1743         endif()
1744         if(OPUS_FOUND)
1745                 list(APPEND PLUGIN_SRC_DIRS
1746                         plugins/codecs/opus_dec
1747                 )
1748         endif()
1749         if(SBC_FOUND)
1750                 list(APPEND PLUGIN_SRC_DIRS
1751                         plugins/codecs/sbc
1752                 )
1753         endif()
1754
1755         # Build demo plugin, only if asked explicitly
1756         if(ENABLE_PLUGIN_IFDEMO)
1757                 list(APPEND PLUGIN_SRC_DIRS
1758                         plugins/epan/pluginifdemo
1759                 )
1760         endif()
1761
1762 else()
1763         set(PLUGIN_SRC_DIRS )
1764         set(LOGRAY_PLUGIN_SRC_DIRS )
1765 endif()
1766
1767 if(ENABLE_APPLICATION_BUNDLE)
1768         if(CMAKE_CFG_INTDIR STREQUAL ".")
1769                 set(_plugin_dir "${CMAKE_BINARY_DIR}/run/Wireshark.app/Contents/PlugIns/wireshark/${PLUGIN_PATH_ID}")
1770         else()
1771                 # Xcode
1772                 set(_plugin_dir "${CMAKE_BINARY_DIR}/run/$<CONFIG>/Wireshark.app/Contents/PlugIns/wireshark/${PLUGIN_PATH_ID}")
1773         endif()
1774         if(CMAKE_CFG_INTDIR STREQUAL ".")
1775                 set(_logray_plugin_dir "${CMAKE_BINARY_DIR}/run/Logray.app/Contents/PlugIns/logray/${PLUGIN_PATH_ID}")
1776         else()
1777                 # Xcode
1778                 set(_logray_plugin_dir "${CMAKE_BINARY_DIR}/run/$<CONFIG>/Logray.app/Contents/PlugIns/logray/${PLUGIN_PATH_ID}")
1779         endif()
1780 elseif(MSVC AND NOT CMAKE_CFG_INTDIR STREQUAL ".")
1781         set(_plugin_dir "${CMAKE_BINARY_DIR}/run/$<CONFIG>/${PLUGIN_VERSION_DIR}")
1782         set(_logray_plugin_dir ${_plugin_dir})
1783 else()
1784         set(_plugin_dir "${DATAFILE_DIR}/${PLUGIN_VERSION_DIR}")
1785         set(_logray_plugin_dir ${_plugin_dir})
1786 endif()
1787 set (PLUGIN_DIR ${_plugin_dir} CACHE INTERNAL "Build time plugin location.")
1788 set (LOGRAY_PLUGIN_DIR ${_logray_plugin_dir} CACHE INTERNAL "Build time Logray plugin location.")
1789
1790 foreach(_plugin_src_dir ${PLUGIN_SRC_DIRS} ${LOGRAY_PLUGIN_SRC_DIRS})
1791         add_subdirectory( ${_plugin_src_dir} )
1792 endforeach()
1793
1794 if(VCSVERSION_OVERRIDE)
1795         # Allow distributors to override detection of the Git tag and version.
1796         string(CONFIGURE "#define VCSVERSION \"@VCSVERSION_OVERRIDE@\"\n"
1797                 _version_h_contents ESCAPE_QUOTES)
1798         file(WRITE "${CMAKE_BINARY_DIR}/vcs_version.h" "${_version_h_contents}")
1799         message(STATUS "VCSVERSION_OVERRIDE: ${VCSVERSION_OVERRIDE}")
1800 else()
1801         add_custom_target(vcs_version
1802                 BYPRODUCTS vcs_version.h
1803                 COMMAND ${Python3_EXECUTABLE}
1804                         ${CMAKE_SOURCE_DIR}/tools/make-version.py
1805                         ${CMAKE_SOURCE_DIR}
1806         )
1807         set_target_properties(vcs_version PROPERTIES FOLDER "Auxiliary")
1808 endif()
1809
1810 set( configure_input "Built with CMake ${CMAKE_VERSION}" )
1811 configure_file(${CMAKE_SOURCE_DIR}/cmakeconfig.h.in ${CMAKE_BINARY_DIR}/config.h)
1812
1813 configure_file(${CMAKE_SOURCE_DIR}/ws_version.h.in ${CMAKE_BINARY_DIR}/ws_version.h)
1814
1815 set( prefix "${CMAKE_INSTALL_PREFIX}" )
1816 set( exec_prefix "\${prefix}" )
1817 set( libdir "\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}" )
1818 set( includedir  "\${prefix}/include" )
1819 set( plugindir "\${libdir}/wireshark/${PLUGIN_VERSION_DIR}" )
1820
1821 # Doxygen variables
1822 file(GLOB TOP_LEVEL_SOURCE_LIST *.c *.cpp *.h)
1823 string (REPLACE ";" " " DOXYGEN_TOP_LEVEL_SOURCES "${TOP_LEVEL_SOURCE_LIST}")
1824 set(DOXYGEN_INPUT_DIRECTORY ${CMAKE_SOURCE_DIR})
1825 set(DOXYGEN_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
1826
1827 set(CFG_OUT_FILES
1828         doxygen.cfg
1829         packaging/macosx/osx-app.sh
1830         packaging/macosx/osx-dmg.sh
1831         packaging/macosx/wireshark-app.dmgbuild
1832         packaging/macosx/wireshark-dsym.dmgbuild
1833         packaging/macosx/WiresharkInfo.plist
1834         packaging/source/git-export-release.sh
1835         resources/dumpcap.rc
1836         resources/libwireshark.rc
1837         resources/libwiretap.rc
1838         resources/libwsutil.rc
1839         resources/wireshark.exe.manifest
1840         resources/wireshark.rc
1841         wireshark.pc
1842 )
1843
1844 if(BUILD_logray)
1845         list(APPEND CFG_OUT_FILES
1846                 packaging/macosx/LograyInfo.plist
1847                 packaging/macosx/logray-app.dmgbuild
1848                 packaging/macosx/logray-dsym.dmgbuild
1849                 resources/logray.exe.manifest
1850         )
1851 endif()
1852
1853 foreach( _cfg_file ${CFG_OUT_FILES} )
1854         configure_file( ${CMAKE_SOURCE_DIR}/${_cfg_file}.in ${CMAKE_BINARY_DIR}/${_cfg_file} @ONLY )
1855 endforeach()
1856
1857 include(FeatureSummary)
1858 set_package_properties(CAP PROPERTIES
1859         DESCRIPTION "The Libcap package implements the user-space interfaces to the POSIX 1003.1e capabilities available in Linux kernels"
1860         URL "https://sites.google.com/site/fullycapable/"
1861         PURPOSE "Allow packet captures without running as root"
1862 )
1863 set_package_properties(SBC PROPERTIES
1864         DESCRIPTION "Bluetooth low-complexity, subband codec (SBC) decoder"
1865         URL "https://git.kernel.org/pub/scm/bluetooth/sbc.git"
1866         PURPOSE "Support for playing SBC codec in RTP player"
1867 )
1868 set_package_properties(SPANDSP PROPERTIES
1869         DESCRIPTION "a library of many DSP functions for telephony"
1870         URL "https://www.soft-switch.org"
1871         PURPOSE "Support for G.722 and G.726 codecs in RTP player"
1872 )
1873 set_package_properties(BCG729 PROPERTIES
1874         DESCRIPTION "G.729 decoder"
1875         URL "https://www.linphone.org/technical-corner/bcg729"
1876         PURPOSE "Support for G.729 codec in RTP player"
1877 )
1878 set_package_properties(AMRNB PROPERTIES
1879         DESCRIPTION "AMRNB decoder"
1880         URL "https://sourceforge.net/p/opencore-amr"
1881         PURPOSE "Support for AMRNB codec in RTP player"
1882 )
1883 set_package_properties(ILBC PROPERTIES
1884         DESCRIPTION "iLBC decoder"
1885         URL "https://github.com/TimothyGu/libilbc"
1886         PURPOSE "Support for iLBC codec in RTP player"
1887 )
1888 set_package_properties(OPUS PROPERTIES
1889         DESCRIPTION "opus decoder"
1890         URL "https://opus-codec.org/"
1891         PURPOSE "Support for opus codec in RTP player"
1892 )
1893 set_package_properties(LIBXML2 PROPERTIES
1894         DESCRIPTION "XML parsing library"
1895         URL "http://xmlsoft.org/"
1896         PURPOSE "Read XML configuration files in EPL dissector"
1897 )
1898 set_package_properties(LIBSSH PROPERTIES
1899         DESCRIPTION "Library for implementing SSH clients"
1900         URL "https://www.libssh.org/"
1901         PURPOSE "extcap remote SSH interfaces (sshdump, ciscodump, wifidump)"
1902 )
1903 set_package_properties(LZ4 PROPERTIES
1904         DESCRIPTION "LZ4 is a fast lossless compression algorithm"
1905         URL "http://www.lz4.org"
1906         PURPOSE "LZ4 decompression in CQL and Kafka dissectors, read compressed capture files"
1907 )
1908 set_package_properties(SNAPPY PROPERTIES
1909         DESCRIPTION "A fast compressor/decompressor from Google"
1910         URL "https://google.github.io/snappy/"
1911         PURPOSE "Snappy decompression in CQL and Kafka dissectors"
1912 )
1913 set_package_properties(ZSTD PROPERTIES
1914         DESCRIPTION "A compressor/decompressor from Facebook providing better compression than Snappy at a cost of speed"
1915         URL "https://facebook.github.io/zstd/"
1916         PURPOSE "Zstd decompression in Kafka dissector, read compressed capture files"
1917 )
1918 set_package_properties(NGHTTP2 PROPERTIES
1919         DESCRIPTION "HTTP/2 C library and tools"
1920         URL "https://nghttp2.org"
1921         PURPOSE "Header decompression in HTTP2"
1922 )
1923 set_package_properties(CARES PROPERTIES
1924         DESCRIPTION "Library for asynchronous DNS requests"
1925         URL "https://c-ares.org/"
1926         PURPOSE "DNS name resolution for captures"
1927 )
1928 set_package_properties(Systemd PROPERTIES
1929         URL "https://freedesktop.org/wiki/Software/systemd/"
1930         DESCRIPTION "System and Service Manager (libraries)"
1931         PURPOSE "Support for systemd journal extcap interface (sdjournal)"
1932 )
1933 set_package_properties(NL PROPERTIES
1934         URL "https://www.infradead.org/~tgr/libnl/"
1935         DESCRIPTION "Libraries for using the Netlink protocol on Linux"
1936         PURPOSE "Support for managing wireless 802.11 interfaces"
1937 )
1938 set_package_properties(MaxMindDB PROPERTIES
1939         URL "https://github.com/maxmind/libmaxminddb"
1940         DESCRIPTION "C library for the MaxMind DB file format"
1941         PURPOSE "Support for GeoIP lookup"
1942 )
1943 set_package_properties(SpeexDSP PROPERTIES
1944         URL "https://www.speex.org/"
1945         DESCRIPTION "SpeexDSP is a patent-free, Open Source/Free Software DSP library"
1946         PURPOSE "RTP audio resampling"
1947 )
1948 set_package_properties(Minizip PROPERTIES
1949         URL "https://github.com/madler/zlib"
1950         DESCRIPTION "Mini zip and unzip based on zlib"
1951         PURPOSE "Support for profiles import/export"
1952 )
1953 set_package_properties(SMI PROPERTIES
1954         URL "https://www.ibr.cs.tu-bs.de/projects/libsmi/"
1955         DESCRIPTION "Library to access SMI management information"
1956         PURPOSE "Support MIB and PIB parsing and OID resolution"
1957 )
1958 set_package_properties(PCRE2 PROPERTIES
1959         URL "https://www.pcre.org"
1960         DESCRIPTION "Regular expression pattern matching using the same syntax and semantics as Perl 5"
1961         PURPOSE "Support for regular expressions"
1962 )
1963 set_package_properties(Sinsp PROPERTIES
1964         DESCRIPTION "libsinsp and libscap"
1965         URL "https://github.com/falcosecurity/libs/"
1966         PURPOSE "Support for Falco plugins"
1967 )
1968
1969 string(TOUPPER "${CMAKE_BUILD_TYPE}" _build_type)
1970 message(STATUS "C-Flags: ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_${_build_type}}")
1971 message(STATUS "CXX-Flags: ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_${_build_type}}")
1972 if(WERROR_COMMON_FLAGS)
1973         message(STATUS "Warnings as errors enabled: ${WERROR_COMMON_FLAGS}")
1974 else()
1975         message(STATUS "Warnings as errors disabled")
1976 endif()
1977
1978 feature_summary(WHAT ALL)
1979
1980 # Should this be part of libui?
1981 if(WIN32)
1982         set(PLATFORM_UI_SRC
1983                 ui/win32/file_dlg_win32.cpp
1984         )
1985         set(PLATFORM_UI_RC_FILES
1986                 resources/file_dlg_win32.rc
1987         )
1988 elseif(APPLE)
1989         set(PLATFORM_UI_SRC
1990                 ui/macosx/cocoa_bridge.mm
1991         )
1992         if (SPARKLE_FOUND)
1993                 list(APPEND PLATFORM_UI_SRC ui/macosx/sparkle_bridge.m)
1994         endif()
1995 endif()
1996
1997 set(TSHARK_TAP_SRC
1998         ${CMAKE_SOURCE_DIR}/ui/cli/tap-credentials.c
1999         ${CMAKE_SOURCE_DIR}/ui/cli/tap-camelsrt.c
2000         ${CMAKE_SOURCE_DIR}/ui/cli/tap-diameter-avp.c
2001         ${CMAKE_SOURCE_DIR}/ui/cli/tap-expert.c
2002         ${CMAKE_SOURCE_DIR}/ui/cli/tap-exportobject.c
2003         ${CMAKE_SOURCE_DIR}/ui/cli/tap-endpoints.c
2004         ${CMAKE_SOURCE_DIR}/ui/cli/tap-flow.c
2005         ${CMAKE_SOURCE_DIR}/ui/cli/tap-follow.c
2006         ${CMAKE_SOURCE_DIR}/ui/cli/tap-funnel.c
2007         ${CMAKE_SOURCE_DIR}/ui/cli/tap-gsm_astat.c
2008         ${CMAKE_SOURCE_DIR}/ui/cli/tap-hosts.c
2009         ${CMAKE_SOURCE_DIR}/ui/cli/tap-httpstat.c
2010         ${CMAKE_SOURCE_DIR}/ui/cli/tap-icmpstat.c
2011         ${CMAKE_SOURCE_DIR}/ui/cli/tap-icmpv6stat.c
2012         ${CMAKE_SOURCE_DIR}/ui/cli/tap-iostat.c
2013         ${CMAKE_SOURCE_DIR}/ui/cli/tap-iousers.c
2014         ${CMAKE_SOURCE_DIR}/ui/cli/tap-macltestat.c
2015         ${CMAKE_SOURCE_DIR}/ui/cli/tap-protocolinfo.c
2016         ${CMAKE_SOURCE_DIR}/ui/cli/tap-protohierstat.c
2017         ${CMAKE_SOURCE_DIR}/ui/cli/tap-rlcltestat.c
2018         ${CMAKE_SOURCE_DIR}/ui/cli/tap-rpcprogs.c
2019         ${CMAKE_SOURCE_DIR}/ui/cli/tap-rtd.c
2020         ${CMAKE_SOURCE_DIR}/ui/cli/tap-rtp.c
2021         ${CMAKE_SOURCE_DIR}/ui/cli/tap-rtspstat.c
2022         ${CMAKE_SOURCE_DIR}/ui/cli/tap-sctpchunkstat.c
2023         ${CMAKE_SOURCE_DIR}/ui/cli/tap-simple_stattable.c
2024         ${CMAKE_SOURCE_DIR}/ui/cli/tap-sipstat.c
2025         ${CMAKE_SOURCE_DIR}/ui/cli/tap-smbsids.c
2026         ${CMAKE_SOURCE_DIR}/ui/cli/tap-srt.c
2027         ${CMAKE_SOURCE_DIR}/ui/cli/tap-stats_tree.c
2028         ${CMAKE_SOURCE_DIR}/ui/cli/tap-sv.c
2029         ${CMAKE_SOURCE_DIR}/ui/cli/tap-wspstat.c
2030         ${CUSTOM_TSHARK_TAP_SRC}
2031
2032 )
2033
2034 # Installed into ${DATAFILE_DIR}
2035 set(INSTALL_DIRS
2036         resources/share/wireshark/profiles
2037         resources/protocols/diameter
2038         resources/protocols/dtds
2039         resources/protocols/radius
2040         resources/protocols/tpncp
2041         resources/protocols/wimaxasncp
2042 )
2043
2044 # Installed into ${DATAFILE_DIR}
2045 set(INSTALL_FILES
2046         enterprises.tsv
2047         manuf
2048         resources/share/wireshark/cfilters
2049         resources/share/wireshark/colorfilters
2050         resources/share/wireshark/dfilter_macros
2051         resources/share/wireshark/dfilters
2052         resources/share/wireshark/smi_modules
2053         services
2054         wka
2055 )
2056 set(DOC_FILES
2057         resources/share/doc/wireshark/ipmap.html
2058         resources/share/doc/wireshark/pdml2html.xsl
2059         doc/README.xml-output
2060         docbook/ws.css
2061 )
2062
2063 if (BUILD_logray)
2064         set(LOG_INSTALL_FILES
2065                 docbook/ws.css
2066                 resources/share/logray/colorfilters
2067                 resources/share/logray/dfilter_buttons
2068         )
2069 endif()
2070
2071 if (ASCIIDOCTOR_FOUND)
2072         list(APPEND DOC_FILES
2073                 ${CMAKE_BINARY_DIR}/doc/androiddump.html
2074                 ${CMAKE_BINARY_DIR}/doc/udpdump.html
2075                 ${CMAKE_BINARY_DIR}/doc/capinfos.html
2076                 ${CMAKE_BINARY_DIR}/doc/captype.html
2077                 ${CMAKE_BINARY_DIR}/doc/ciscodump.html
2078                 ${CMAKE_BINARY_DIR}/doc/dumpcap.html
2079                 ${CMAKE_BINARY_DIR}/doc/editcap.html
2080                 ${CMAKE_BINARY_DIR}/doc/extcap.html
2081                 ${CMAKE_BINARY_DIR}/doc/mergecap.html
2082                 ${CMAKE_BINARY_DIR}/doc/randpkt.html
2083                 ${CMAKE_BINARY_DIR}/doc/randpktdump.html
2084                 ${CMAKE_BINARY_DIR}/doc/etwdump.html
2085                 ${CMAKE_BINARY_DIR}/doc/rawshark.html
2086                 ${CMAKE_BINARY_DIR}/doc/reordercap.html
2087                 ${CMAKE_BINARY_DIR}/doc/sshdump.html
2088                 ${CMAKE_BINARY_DIR}/doc/wifidump.html
2089                 ${CMAKE_BINARY_DIR}/doc/text2pcap.html
2090                 ${CMAKE_BINARY_DIR}/doc/tshark.html
2091                 ${CMAKE_BINARY_DIR}/doc/wireshark.html
2092                 ${CMAKE_BINARY_DIR}/doc/wireshark-filter.html
2093         )
2094         if(MAXMINDDB_FOUND)
2095                 list(APPEND DOC_FILES ${CMAKE_BINARY_DIR}/doc/mmdbresolve.html)
2096         endif()
2097
2098         if (BUILD_corbaidl2wrs)
2099                 list(APPEND DOC_FILES ${CMAKE_BINARY_DIR}/doc/idl2wrs.html)
2100         endif()
2101         if (BUILD_xxx2deb)
2102                 list(APPEND DOC_FILES
2103                         ${CMAKE_BINARY_DIR}/doc/asn2deb.html
2104                         ${CMAKE_BINARY_DIR}/doc/idl2deb.html
2105                 )
2106         endif()
2107         if (BUILD_logray)
2108                 list(APPEND DOC_FILES
2109                         ${CMAKE_BINARY_DIR}/doc/falcodump.html
2110                 )
2111         endif()
2112 endif()
2113
2114 if(NOT WIN32)
2115         # We do this for Windows further down in the copy_data_files target.
2116         list(APPEND DOC_FILES COPYING)
2117 endif()
2118
2119 if(USE_REPOSITORY)
2120         set(_dll_output_dir "$<TARGET_FILE_DIR:wsutil>")
2121         add_custom_target(copy_cli_dlls)
2122         set_target_properties(copy_cli_dlls PROPERTIES FOLDER "Copy Tasks")
2123         add_custom_command(TARGET copy_cli_dlls PRE_BUILD
2124                 COMMAND ${CMAKE_COMMAND} -E make_directory "${_dll_output_dir}"
2125         )
2126
2127         # XXX Can (and should) we iterate over these similar to the way
2128         # the top-level CMakeLists.txt iterates over the package list?
2129
2130         # Required DLLs and their corresponding PDBs.
2131         add_custom_command(TARGET copy_cli_dlls PRE_BUILD
2132                 COMMAND ${CMAKE_COMMAND} -E copy_if_different
2133                         "$<IF:$<CONFIG:Debug>,${GLIB2_DLLS_DEBUG},${GLIB2_DLLS_RELEASE}>"
2134                         "$<IF:$<CONFIG:Debug>,${GLIB2_PDBS_DEBUG},${GLIB2_PDBS_RELEASE}>"
2135                         "${_dll_output_dir}"
2136                 WORKING_DIRECTORY $<IF:$<CONFIG:Debug>,${GLIB2_DLL_DIR_DEBUG},${GLIB2_DLL_DIR_RELEASE}>
2137                 COMMAND_EXPAND_LISTS
2138         )
2139
2140         if (MSVC AND VLD_FOUND)
2141                 add_custom_command(TARGET copy_cli_dlls PRE_BUILD
2142                         COMMAND ${CMAKE_COMMAND} -E "$<IF:$<CONFIG:Debug>,copy_if_different,true>"
2143                         "${VLD_FILES}"
2144                         "${_dll_output_dir}"
2145                         COMMAND_EXPAND_LISTS
2146                 )
2147         endif()
2148
2149         # Third party DLLs and PDBs.
2150         set (THIRD_PARTY_DLLS)
2151         set (THIRD_PARTY_PDBS)
2152         if (AIRPCAP_FOUND)
2153                 list (APPEND THIRD_PARTY_DLLS "${AIRPCAP_DLL_DIR}/${AIRPCAP_DLL}")
2154         endif(AIRPCAP_FOUND)
2155         list (APPEND THIRD_PARTY_DLLS "${CARES_DLL_DIR}/${CARES_DLL}")
2156         list (APPEND THIRD_PARTY_PDBS "${CARES_DLL_DIR}/${CARES_PDB}")
2157         # vcpkg's libmaxminddb is static-only for now. This can be uncommented when
2158         # https://github.com/maxmind/libmaxminddb/commit/3998f42bdb6678cbaa1a543057e5c81ba1668ac2
2159         # percolates up to vcpkg.
2160         # if (MAXMINDDB_FOUND)
2161         #       list (APPEND THIRD_PARTY_DLLS "${MAXMINDDB_DLL_DIR}/${MAXMINDDB_DLL}")
2162         # endif(MAXMINDDB_FOUND)
2163         if (LIBSSH_FOUND)
2164                 foreach( _dll ${LIBSSH_DLLS} )
2165                         list (APPEND THIRD_PARTY_DLLS "${LIBSSH_DLL_DIR}/${_dll}")
2166                 endforeach(_dll)
2167         endif(LIBSSH_FOUND)
2168         foreach( _dll ${GCRYPT_DLLS} )
2169                 list (APPEND THIRD_PARTY_DLLS "${GCRYPT_DLL_DIR}/${_dll}")
2170         endforeach(_dll)
2171         foreach( _dll ${GNUTLS_DLLS} )
2172                 list (APPEND THIRD_PARTY_DLLS "${GNUTLS_DLL_DIR}/${_dll}")
2173         endforeach(_dll)
2174         foreach( _dll ${KERBEROS_DLLS} )
2175                 list (APPEND THIRD_PARTY_DLLS "${KERBEROS_DLL_DIR}/${_dll}")
2176         endforeach(_dll)
2177         if (LUA_FOUND)
2178                 list (APPEND THIRD_PARTY_DLLS "${LUA_DLL_DIR}/${LUA_DLL}")
2179         endif(LUA_FOUND)
2180         if (LZ4_FOUND)
2181                 list (APPEND THIRD_PARTY_DLLS "${LZ4_DLL_DIR}/${LZ4_DLL}")
2182                 list (APPEND THIRD_PARTY_PDBS "${LZ4_DLL_DIR}/${LZ4_PDB}")
2183         endif(LZ4_FOUND)
2184         if (ZSTD_FOUND)
2185                 list (APPEND THIRD_PARTY_DLLS "${ZSTD_DLL_DIR}/${ZSTD_DLL}")
2186         endif(ZSTD_FOUND)
2187         if (NGHTTP2_FOUND)
2188                 list (APPEND THIRD_PARTY_DLLS "${NGHTTP2_DLL_DIR}/${NGHTTP2_DLL}")
2189                 list (APPEND THIRD_PARTY_PDBS "${NGHTTP2_DLL_DIR}/${NGHTTP2_PDB}")
2190         endif(NGHTTP2_FOUND)
2191         if (PCRE2_FOUND)
2192                 list (APPEND THIRD_PARTY_DLLS "${PCRE2_DLL_DIR}/${PCRE2_DLL}")
2193                 list (APPEND THIRD_PARTY_PDBS "${PCRE2_DLL_DIR}/${PCRE2_PDB}")
2194         endif(PCRE2_FOUND)
2195         if (SBC_FOUND)
2196                 list (APPEND THIRD_PARTY_DLLS "${SBC_DLL_DIR}/${SBC_DLL}")
2197         endif(SBC_FOUND)
2198         if (SPANDSP_FOUND)
2199                 list (APPEND THIRD_PARTY_DLLS "${SPANDSP_DLL_DIR}/${SPANDSP_DLL}")
2200         endif(SPANDSP_FOUND)
2201         if (BCG729_FOUND)
2202                 list (APPEND THIRD_PARTY_DLLS "${BCG729_DLL_DIR}/${BCG729_DLL}")
2203         endif(BCG729_FOUND)
2204         if (AMRNB_FOUND)
2205                 list (APPEND OPTIONAL_DLLS "${AMRNB_DLL_DIR}/${AMRNB_DLL}")
2206         endif(AMRNB_FOUND)
2207         if (ILBC_FOUND)
2208                 list (APPEND THIRD_PARTY_DLLS "${ILBC_DLL_DIR}/${ILBC_DLL}")
2209         endif(ILBC_FOUND)
2210         if (OPUS_FOUND)
2211                 list (APPEND THIRD_PARTY_DLLS "${OPUS_DLL_DIR}/${OPUS_DLL}")
2212         endif(OPUS_FOUND)
2213         if (LIBXML2_FOUND)
2214                 foreach( _dll ${LIBXML2_DLLS} )
2215                         list (APPEND THIRD_PARTY_DLLS "${LIBXML2_DLL_DIR}/${_dll}")
2216                 endforeach(_dll)
2217                 foreach( _pdb ${LIBXML2_PDBS} )
2218                         list (APPEND THIRD_PARTY_PDBS "${LIBXML2_DLL_DIR}/${_pdb}")
2219                 endforeach(_pdb)
2220         endif(LIBXML2_FOUND)
2221         if (SMI_FOUND)
2222                 list (APPEND THIRD_PARTY_DLLS "${SMI_DLL_DIR}/${SMI_DLL}")
2223                 # Wireshark.nsi wants SMI_DIR which is the base SMI directory
2224                 get_filename_component(SMI_DIR ${SMI_DLL_DIR} DIRECTORY)
2225                 add_custom_command(TARGET copy_cli_dlls PRE_BUILD
2226                         COMMAND ${CMAKE_COMMAND} -E make_directory
2227                                 "${_dll_output_dir}/snmp"
2228                         COMMAND ${CMAKE_COMMAND} -E make_directory
2229                                 "${_dll_output_dir}/snmp/mibs"
2230                         COMMAND ${CMAKE_COMMAND} -E copy_directory
2231                                 "${SMI_SHARE_DIR}/mibs/iana"
2232                                 "${_dll_output_dir}/snmp/mibs"
2233                         COMMAND ${CMAKE_COMMAND} -E copy_directory
2234                                 "${SMI_SHARE_DIR}/mibs/ietf"
2235                                 "${_dll_output_dir}/snmp/mibs"
2236                         COMMAND ${CMAKE_COMMAND} -E copy_directory
2237                                 "${SMI_SHARE_DIR}/mibs/irtf"
2238                                 "${_dll_output_dir}/snmp/mibs"
2239                         COMMAND ${CMAKE_COMMAND} -E copy_directory
2240                                 "${SMI_SHARE_DIR}/mibs/site"
2241                                 "${_dll_output_dir}/snmp/mibs"
2242                         COMMAND ${CMAKE_COMMAND} -E copy_directory
2243                                 "${SMI_SHARE_DIR}/mibs/tubs"
2244                                 "${_dll_output_dir}/snmp/mibs"
2245                         COMMAND ${CMAKE_COMMAND} -E copy_directory
2246                                 "${SMI_SHARE_DIR}/pibs"
2247                                 "${_dll_output_dir}/snmp/mibs"
2248                         COMMAND ${CMAKE_COMMAND} -E copy_directory
2249                                 "${SMI_SHARE_DIR}/yang"
2250                                 "${_dll_output_dir}/snmp/mibs"
2251                         #remove the extra directories copied (shallow copying the above would remove the need for this)
2252                         COMMAND ${CMAKE_COMMAND} -E remove_directory
2253                                 "${_dll_output_dir}/snmp/mibs/iana"
2254                         COMMAND ${CMAKE_COMMAND} -E remove_directory
2255                                 "${_dll_output_dir}/snmp/mibs/ietf"
2256                         COMMAND ${CMAKE_COMMAND} -E remove_directory
2257                                 "${_dll_output_dir}/snmp/mibs/site"
2258                         COMMAND ${CMAKE_COMMAND} -E remove_directory
2259                                 "${_dll_output_dir}/snmp/mibs/tubs"
2260                 )
2261         endif(SMI_FOUND)
2262         if (SNAPPY_FOUND)
2263                 list (APPEND THIRD_PARTY_DLLS "${SNAPPY_DLL_DIR}/${SNAPPY_DLL}")
2264         endif(SNAPPY_FOUND)
2265         if (WINSPARKLE_FOUND)
2266                 list (APPEND THIRD_PARTY_DLLS "${WINSPARKLE_DLL_DIR}/${WINSPARKLE_DLL}")
2267         endif(WINSPARKLE_FOUND)
2268         if (ZLIB_FOUND)
2269                 list (APPEND THIRD_PARTY_DLLS "${ZLIB_DLL_DIR}/${ZLIB_DLL}")
2270                 list (APPEND THIRD_PARTY_PDBS "${ZLIB_DLL_DIR}/${ZLIB_PDB}")
2271         endif(ZLIB_FOUND)
2272         if (BROTLI_FOUND)
2273                 foreach( _dll ${BROTLI_DLLS} )
2274                         list (APPEND THIRD_PARTY_DLLS "${BROTLI_DLL_DIR}/${_dll}")
2275                 endforeach(_dll)
2276         endif(BROTLI_FOUND)
2277         if (SPEEXDSP_FOUND)
2278                 list (APPEND THIRD_PARTY_DLLS "${SPEEXDSP_DLL_DIR}/${SPEEXDSP_DLL}")
2279         endif()
2280
2281         # With libs downloaded to c:/wireshark-win64-libs this currently
2282         # (early 2018) expands to about 1900 characters.
2283         if (THIRD_PARTY_DLLS)
2284                 add_custom_command(TARGET copy_cli_dlls PRE_BUILD
2285                         COMMAND ${CMAKE_COMMAND} -E copy_if_different
2286                                 ${THIRD_PARTY_DLLS}
2287                                 "${_dll_output_dir}"
2288                         VERBATIM
2289                 )
2290                 install(FILES ${THIRD_PARTY_DLLS} DESTINATION "${CMAKE_INSTALL_BINDIR}")
2291         endif(THIRD_PARTY_DLLS)
2292
2293         if (THIRD_PARTY_PDBS)
2294                 add_custom_command(TARGET copy_cli_dlls PRE_BUILD
2295                         COMMAND ${CMAKE_COMMAND} -E copy_if_different
2296                                 ${THIRD_PARTY_PDBS}
2297                                 "${_dll_output_dir}"
2298                         VERBATIM
2299                 )
2300         endif(THIRD_PARTY_PDBS)
2301
2302         add_dependencies(epan copy_cli_dlls)
2303
2304         # We have a lot of choices for creating zip archives:
2305         # - 7z, WinZip, etc., which require a separate download+install.
2306         # - "CMake -E tar cz", which creates a tar file.
2307         # - CPack, which requires a CPack configuration.
2308         # - PowerShell via PSCX or System.IO.Compression.FileSystem.
2309         # - Python via zipfile.
2310         # For now, just look for 7z. It's installed on the Windows builders,
2311         # which might be the only systems that use this target.
2312         find_program(ZIP_EXECUTABLE 7z
2313                 PATH "$ENV{PROGRAMFILES}/7-Zip" "$ENV{PROGRAMW6432}/7-Zip"
2314                 DOC "Path to the 7z utility."
2315         )
2316         if(ZIP_EXECUTABLE)
2317                 add_custom_target(pdb_zip_package COMMENT "This packages .PDBs but will not create them.")
2318                 set_target_properties(pdb_zip_package PROPERTIES FOLDER "Packaging")
2319                 set(_pdb_zip "${CMAKE_BINARY_DIR}/Wireshark-pdb-${PROJECT_VERSION}-${WIRESHARK_TARGET_PROCESSOR_ARCHITECTURE}.zip")
2320                 file(TO_NATIVE_PATH "${_pdb_zip}" _pdb_zip_win)
2321                 add_custom_command(TARGET pdb_zip_package POST_BUILD
2322                         COMMAND ${CMAKE_COMMAND} -E remove -f "${_pdb_zip}"
2323                         COMMAND ${ZIP_EXECUTABLE} a -tzip -mmt=on "${_pdb_zip_win}"
2324                                 -bb0 -bd
2325                                 -r *.pdb *.lib
2326                         WORKING_DIRECTORY "${_dll_output_dir}"
2327                 )
2328         endif()
2329 endif()
2330
2331 # List of extra dependencies for the "copy_data_files" target
2332 set(copy_data_files_depends)
2333
2334 if(WIN32)
2335         foreach(_install_as_txt_file COPYING NEWS README.md README.windows)
2336                 # On Windows, install some files with a .txt extension so that they're
2337                 # double-clickable.
2338                 string(REGEX REPLACE ".md$" "" _no_md_file ${_install_as_txt_file})
2339                 set(_output_file "${DATAFILE_DIR}/${_no_md_file}.txt")
2340                 add_custom_command(OUTPUT ${_output_file}
2341                         COMMAND ${CMAKE_COMMAND} -E copy_if_different
2342                                 ${CMAKE_SOURCE_DIR}/${_install_as_txt_file}
2343                                 ${_output_file}
2344                         DEPENDS
2345                                 ${CMAKE_SOURCE_DIR}/${_install_as_txt_file}
2346                 )
2347                 list(APPEND copy_data_files_depends "${_output_file}")
2348         endforeach()
2349 endif()
2350
2351 foreach(_install_file ${INSTALL_FILES} ${DOC_FILES})
2352         get_filename_component(_install_file_src "${_install_file}" ABSOLUTE)
2353         get_filename_component(_install_basename "${_install_file}" NAME)
2354         set(_output_file "${DATAFILE_DIR}/${_install_basename}")
2355         add_custom_command(OUTPUT "${_output_file}"
2356                 COMMAND ${CMAKE_COMMAND} -E copy_if_different
2357                         "${_install_file_src}"
2358                         "${_output_file}"
2359                 DEPENDS
2360                         docs
2361                         "${_install_file}"
2362         )
2363         list(APPEND copy_data_files_depends "${_output_file}")
2364 endforeach()
2365
2366 if (BUILD_logray AND ENABLE_APPLICATION_BUNDLE)
2367         foreach(_install_file ${LOG_INSTALL_FILES})
2368                 get_filename_component(_install_file_src "${_install_file}" ABSOLUTE)
2369                 get_filename_component(_install_basename "${_install_file}" NAME)
2370                 set(_output_file "${LOG_DATAFILE_DIR}/${_install_basename}")
2371                 add_custom_command(OUTPUT "${_output_file}"
2372                         COMMAND ${CMAKE_COMMAND} -E copy_if_different
2373                                 "${_install_file_src}"
2374                                 "${_output_file}"
2375                         DEPENDS
2376                                 docs
2377                                 "${_install_file}"
2378                 )
2379                 list(APPEND copy_data_files_depends "${_output_file}")
2380         endforeach()
2381 endif()
2382
2383 # Install Lua files in staging directory such that Lua can used when Wireshark
2384 # is ran from the build directory. For install targets, see
2385 # epan/wslua/CMakeLists.txt
2386 if(LUA_FOUND AND ENABLE_LUA)
2387         set(_lua_files
2388                 "${CMAKE_SOURCE_DIR}/epan/wslua/init.lua"
2389                 "${CMAKE_SOURCE_DIR}/epan/wslua/console.lua"
2390                 "${CMAKE_SOURCE_DIR}/epan/wslua/dtd_gen.lua"
2391         )
2392         foreach(_lua_file ${_lua_files})
2393                 get_filename_component(_lua_filename "${_lua_file}" NAME)
2394                 list(APPEND copy_data_files_depends
2395                         "${DATAFILE_DIR}/${_lua_filename}")
2396                 add_custom_command(OUTPUT "${DATAFILE_DIR}/${_lua_filename}"
2397                         COMMAND ${CMAKE_COMMAND} -E copy_if_different
2398                                 "${_lua_file}"
2399                                 "${DATAFILE_DIR}/${_lua_filename}"
2400                         DEPENDS
2401                                 "${_lua_file}"
2402                 )
2403         endforeach()
2404 endif(LUA_FOUND AND ENABLE_LUA)
2405 # doc/*.html handled elsewhere.
2406
2407 set(_protocol_data_dir ${CMAKE_SOURCE_DIR}/resources/protocols)
2408 # Glob patterns relative to the source directory that should be copied to
2409 # ${DATAFILE_DIR} (including directory prefixes)
2410 # TODO shouldn't this use full (relative) paths instead of glob patterns?
2411 set(DATA_FILES_SRC
2412         ${_protocol_data_dir}/tpncp/tpncp.dat
2413         ${_protocol_data_dir}/wimaxasncp/*.dtd
2414         ${_protocol_data_dir}/wimaxasncp/*.xml
2415 )
2416
2417 # Copy all paths from the source tree to the data directory. Directories are
2418 # automatically created if missing as the filename is given.
2419 file(GLOB _data_files RELATIVE ${_protocol_data_dir} ${DATA_FILES_SRC})
2420 foreach(_data_file ${_data_files})
2421         add_custom_command(OUTPUT "${DATAFILE_DIR}/${_data_file}"
2422                 COMMAND ${CMAKE_COMMAND} -E copy_if_different
2423                         ${_protocol_data_dir}/${_data_file}
2424                         ${DATAFILE_DIR}/${_data_file}
2425                 DEPENDS
2426                         ${_protocol_data_dir}/${_data_file}
2427         )
2428         list(APPEND copy_data_files_depends ${DATAFILE_DIR}/${_data_file})
2429 endforeach()
2430
2431 file(GLOB _dtds_src_files RELATIVE ${_protocol_data_dir} ${_protocol_data_dir}/dtds/*.dtd)
2432
2433 set (_dtds_data_files)
2434 set (_dtds_dep_files)
2435 foreach(_data_file ${_dtds_src_files})
2436         list(APPEND _dtds_data_files ${DATAFILE_DIR}/${_data_file})
2437         list(APPEND _dtds_dep_files ${_protocol_data_dir}/${_data_file})
2438 endforeach()
2439
2440 add_custom_command(
2441         OUTPUT ${_dtds_data_files}
2442         COMMAND ${CMAKE_COMMAND} -E make_directory ${DATAFILE_DIR}/dtds
2443         COMMAND ${CMAKE_COMMAND} -E copy_if_different
2444                 ${_dtds_src_files}
2445                 ${DATAFILE_DIR}/dtds
2446         VERBATIM
2447         DEPENDS ${_dtds_dep_files}
2448         WORKING_DIRECTORY ${_protocol_data_dir}
2449 )
2450
2451 file(GLOB _diameter_src_files RELATIVE ${_protocol_data_dir}
2452         ${_protocol_data_dir}/diameter/*.dtd
2453         ${_protocol_data_dir}/diameter/*.xml
2454 )
2455
2456 set (_diameter_data_files)
2457 set (_diameter_dep_files)
2458 foreach(_data_file ${_diameter_src_files})
2459         list(APPEND _diameter_data_files ${DATAFILE_DIR}/${_data_file})
2460         list(APPEND _diameter_dep_files ${_protocol_data_dir}/${_data_file})
2461 endforeach()
2462
2463 add_custom_command(
2464         OUTPUT ${_diameter_data_files}
2465         COMMAND ${CMAKE_COMMAND} -E make_directory ${DATAFILE_DIR}/diameter
2466         COMMAND ${CMAKE_COMMAND} -E copy_if_different
2467                 ${_diameter_src_files}
2468                 ${DATAFILE_DIR}/diameter
2469         VERBATIM
2470         DEPENDS ${_diameter_dep_files}
2471         WORKING_DIRECTORY ${_protocol_data_dir}
2472 )
2473
2474 file(GLOB _radius_src_files RELATIVE ${_protocol_data_dir}
2475         ${_protocol_data_dir}/radius/README.radius_dictionary
2476         ${_protocol_data_dir}/radius/custom.includes
2477         ${_protocol_data_dir}/radius/dictionary
2478         ${_protocol_data_dir}/radius/dictionary.*
2479 )
2480
2481 set (_radius_data_files)
2482 set (_radius_dep_files)
2483 foreach(_data_file ${_radius_src_files})
2484         list(APPEND _radius_data_files ${DATAFILE_DIR}/${_data_file})
2485         list(APPEND _radius_dep_files ${_protocol_data_dir}/${_data_file})
2486 endforeach()
2487
2488 add_custom_command(
2489         OUTPUT ${_radius_data_files}
2490         COMMAND ${CMAKE_COMMAND} -E make_directory ${DATAFILE_DIR}/radius
2491         COMMAND ${CMAKE_COMMAND} -E copy_if_different
2492                 ${_radius_src_files}
2493                 ${DATAFILE_DIR}/radius
2494         VERBATIM
2495         DEPENDS ${_radius_dep_files}
2496         WORKING_DIRECTORY ${_protocol_data_dir}
2497 )
2498
2499 file(GLOB _protobuf_src_files RELATIVE ${_protocol_data_dir}
2500         ${_protocol_data_dir}/protobuf/*.proto
2501 )
2502 set (_protobuf_data_files)
2503 set (_protobuf_dep_files)
2504 foreach(_data_file ${_protobuf_src_files})
2505         list(APPEND _protobuf_data_files ${DATAFILE_DIR}/${_data_file})
2506         list(APPEND _protobuf_dep_files ${_protocol_data_dir}/${_data_file})
2507 endforeach()
2508
2509 add_custom_command(
2510         OUTPUT ${_protobuf_data_files}
2511         COMMAND ${CMAKE_COMMAND} -E make_directory ${DATAFILE_DIR}/protobuf
2512         COMMAND ${CMAKE_COMMAND} -E copy_if_different
2513                 ${_protobuf_src_files}
2514                 ${DATAFILE_DIR}/protobuf
2515         VERBATIM
2516         DEPENDS ${_protobuf_dep_files}
2517         WORKING_DIRECTORY ${_protocol_data_dir}
2518 )
2519
2520 set(_profiles_src_dir ${CMAKE_SOURCE_DIR}/resources/share/wireshark)
2521 file(GLOB _profiles_src_files RELATIVE ${_profiles_src_dir} ${_profiles_src_dir}/profiles/*/*)
2522 set (_profiles_data_files)
2523 foreach(_data_file ${_profiles_src_files})
2524         list(APPEND _profiles_data_files "${DATAFILE_DIR}/${_data_file}")
2525 endforeach()
2526
2527 add_custom_command(
2528         OUTPUT ${_profiles_data_files}
2529         COMMAND ${CMAKE_COMMAND} -E copy_directory
2530                 "${CMAKE_SOURCE_DIR}/resources/share/wireshark/profiles" "${DATAFILE_DIR}/profiles"
2531 )
2532
2533 list(APPEND copy_data_files_depends
2534         ${_dtds_data_files}
2535         ${_diameter_data_files}
2536         ${_radius_data_files}
2537         ${_protobuf_data_files}
2538         ${_profiles_data_files}
2539 )
2540
2541 # Copy files including ${INSTALL_FILES} and ${INSTALL_DIRS} to ${DATAFILE_DIR}
2542 add_custom_target(copy_data_files ALL DEPENDS ${copy_data_files_depends} )
2543 set_target_properties(copy_data_files PROPERTIES FOLDER "Copy Tasks")
2544
2545 # sources common for wireshark, tshark, rawshark and sharkd
2546 add_library(shark_common OBJECT
2547         cfile.c
2548         extcap_parser.c
2549         file_packet_provider.c
2550         frame_tvbuff.c
2551         sync_pipe_write.c
2552 )
2553 add_library(cli_main OBJECT cli_main.c)
2554 add_library(capture_opts OBJECT capture_opts.c)
2555 target_include_directories(capture_opts SYSTEM PRIVATE ${PCAP_INCLUDE_DIRS})
2556 set_target_properties(shark_common cli_main capture_opts
2557         PROPERTIES
2558         COMPILE_FLAGS "${WERROR_COMMON_FLAGS}"
2559 )
2560
2561
2562 if(BUILD_wireshark AND QT_FOUND)
2563         set(WIRESHARK_SRC
2564                 file.c
2565                 fileset.c
2566                 extcap.c
2567                 ${PLATFORM_UI_SRC}
2568         )
2569         set(wireshark_FILES
2570                 $<TARGET_OBJECTS:capture_opts>
2571                 $<TARGET_OBJECTS:shark_common>
2572                 ${WIRESHARK_SRC}
2573                 ${PLATFORM_UI_RC_FILES}
2574         )
2575         set_executable_resources(wireshark "Wireshark" UNIQUE_RC)
2576 endif()
2577
2578 if(BUILD_logray AND QT_FOUND)
2579         set(LOGRAY_SRC
2580                 file.c
2581                 fileset.c
2582                 extcap.c
2583                 ${PLATFORM_UI_SRC}
2584         )
2585         set(logray_FILES
2586                 $<TARGET_OBJECTS:capture_opts>
2587                 $<TARGET_OBJECTS:shark_common>
2588                 ${LOGRAY_SRC}
2589                 ${PLATFORM_UI_RC_FILES}
2590         )
2591         set_executable_resources(logray "Logray" UNIQUE_RC)
2592 endif()
2593
2594 if(ENABLE_APPLICATION_BUNDLE)
2595         #
2596         # Add -Wl,-single_module to the LDFLAGS used with shared
2597         # libraries, to fix some error that show up in some cases;
2598         # some Apple documentation recommends it for most shared
2599         # libraries.
2600         #
2601         set( CMAKE_SHARED_LINKER_FLAGS "-Wl,-single_module ${CMAKE_SHARED_LINKER_FLAGS}" )
2602         #
2603         # Add -Wl,-headerpad_max_install_names to the LDFLAGS, as
2604         # code-signing issues is running out of padding space.
2605         #
2606         # Add -Wl,-search_paths_first to make sure that if we search
2607         # directories A and B, in that order, for a given library, a
2608         # non-shared version in directory A, rather than a shared
2609         # version in directory B, is chosen (so we can use
2610         # --with-pcap=/usr/local to force all programs to be linked
2611         # with a static version installed in /usr/local/lib rather than
2612         # the system version in /usr/lib).
2613         #
2614
2615         set(CMAKE_EXE_LINKER_FLAGS
2616         "-Wl,-headerpad_max_install_names -Wl,-search_paths_first ${CMAKE_EXE_LINKER_FLAGS}"
2617         )
2618
2619         # Add files to the Wireshark application bundle
2620         # Wireshark.app/Contents
2621         file(WRITE ${CMAKE_BINARY_DIR}/packaging/macosx/wireshark/PkgInfo "APPLWshk\n")
2622         set(WIRESHARK_BUNDLE_CONTENTS_FILES
2623                 ${CMAKE_BINARY_DIR}/packaging/macosx/wireshark/PkgInfo
2624         )
2625         set_source_files_properties(${WIRESHARK_BUNDLE_CONTENTS_FILES} PROPERTIES
2626                 MACOSX_PACKAGE_LOCATION .
2627         )
2628
2629         # Wireshark.app/Contents/Resources
2630         set(WIRESHARK_BUNDLE_RESOURCE_FILES
2631                 ${CMAKE_SOURCE_DIR}/packaging/macosx/Wireshark.icns
2632                 ${CMAKE_SOURCE_DIR}/packaging/macosx/Wiresharkdoc.icns
2633         )
2634         set_source_files_properties(${WIRESHARK_BUNDLE_RESOURCE_FILES} PROPERTIES
2635                 MACOSX_PACKAGE_LOCATION Resources
2636         )
2637
2638         # Wireshark.app/Contents/Resources/share/man/man1
2639         set_source_files_properties(${WIRESHARK_BUNDLE_RESOURCE_SHARE_MAN1_FILES} PROPERTIES
2640                 MACOSX_PACKAGE_LOCATION Resources/share/man/man1
2641                 GENERATED 1
2642         )
2643
2644         # Wireshark.app/Contents/Resources/share/man/man4
2645         set_source_files_properties(${WIRESHARK_BUNDLE_RESOURCE_SHARE_MAN4_FILES} PROPERTIES
2646                 MACOSX_PACKAGE_LOCATION Resources/share/man/man4
2647                 GENERATED 1
2648         )
2649
2650         # INSTALL_FILES and INSTALL_DIRS are handled by copy_data_files
2651
2652         set(EXTRA_WIRESHARK_BUNDLE_FILES
2653                 ${WIRESHARK_BUNDLE_CONTENTS_FILES}
2654                 ${WIRESHARK_BUNDLE_RESOURCE_FILES}
2655                 ${WIRESHARK_BUNDLE_RESOURCE_SHARE_MAN1_FILES}
2656                 ${WIRESHARK_BUNDLE_RESOURCE_SHARE_MAN4_FILES}
2657         )
2658
2659         # Add files to the Logray application bundle
2660         # Logray.app/Contents
2661         file(WRITE ${CMAKE_BINARY_DIR}/packaging/macosx/logray/PkgInfo "APPLLgry\n")
2662         set(LOGRAY_BUNDLE_CONTENTS_FILES
2663                 ${CMAKE_BINARY_DIR}/packaging/macosx/logray/PkgInfo
2664         )
2665         set_source_files_properties(${LOGRAY_BUNDLE_CONTENTS_FILES} PROPERTIES
2666                 MACOSX_PACKAGE_LOCATION .
2667         )
2668
2669         # Logray.app/Contents/Resources
2670         set(LOGRAY_BUNDLE_RESOURCE_FILES
2671                 ${CMAKE_SOURCE_DIR}/packaging/macosx/Logray.icns
2672                 ${CMAKE_SOURCE_DIR}/packaging/macosx/Wiresharkdoc.icns
2673         )
2674         set_source_files_properties(${LOGRAY_BUNDLE_RESOURCE_FILES} PROPERTIES
2675                 MACOSX_PACKAGE_LOCATION Resources
2676         )
2677
2678         # Logray.app/Contents/Resources/share/man/man1
2679         set_source_files_properties(${LOGRAY_BUNDLE_RESOURCE_SHARE_MAN1_FILES} PROPERTIES
2680                 MACOSX_PACKAGE_LOCATION Resources/share/man/man1
2681                 GENERATED 1
2682         )
2683
2684         # Logray.app/Contents/Resources/share/man/man4
2685         set_source_files_properties(${LOGRAY_BUNDLE_RESOURCE_SHARE_MAN4_FILES} PROPERTIES
2686                 MACOSX_PACKAGE_LOCATION Resources/share/man/man4
2687                 GENERATED 1
2688         )
2689
2690         # INSTALL_FILES and INSTALL_DIRS are handled by copy_data_files
2691
2692         set(EXTRA_LOGRAY_BUNDLE_FILES
2693                 ${LOGRAY_BUNDLE_CONTENTS_FILES}
2694                 ${LOGRAY_BUNDLE_RESOURCE_FILES}
2695                 ${LOGRAY_BUNDLE_RESOURCE_SHARE_MAN1_FILES}
2696                 ${LOGRAY_BUNDLE_RESOURCE_SHARE_MAN4_FILES}
2697         )
2698
2699 else()
2700         set(EXTRA_WIRESHARK_BUNDLE_FILES)
2701         set(EXTRA_LOGRAY_BUNDLE_FILES)
2702 endif()
2703
2704 if(BUILD_wireshark AND QT_FOUND)
2705         set(wireshark_LIBS
2706                 ui
2707                 qtui
2708                 capchild
2709                 caputils
2710                 iface_monitor
2711                 wiretap
2712                 epan
2713                 summary
2714                 ${QT5_LIBRARIES}
2715                 ${APPLE_APPLICATION_SERVICES_LIBRARY}
2716                 ${APPLE_APPKIT_LIBRARY}
2717                 ${APPLE_CORE_FOUNDATION_LIBRARY}
2718                 ${APPLE_SYSTEM_CONFIGURATION_LIBRARY}
2719                 ${SPARKLE_LIBRARIES}
2720                 ${WIN_WS2_32_LIBRARY}
2721                 ${WIN_VERSION_LIBRARY}
2722                 ${WINSPARKLE_LIBRARIES}
2723                 $<$<BOOL:${WIN32}>:uxtheme.lib>
2724                 ${SPEEXDSP_LIBRARIES}
2725                 ${ZLIB_LIBRARIES}
2726                 ${MINIZIP_LIBRARIES}
2727         )
2728
2729         add_executable(wireshark WIN32 MACOSX_BUNDLE ${wireshark_FILES} ${EXTRA_WIRESHARK_BUNDLE_FILES})
2730         if(MSVC)
2731                 set_property(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR} PROPERTY VS_STARTUP_PROJECT wireshark)
2732         endif()
2733         set(PROGLIST ${PROGLIST} wireshark)
2734         set_target_properties(wireshark PROPERTIES
2735                 LINK_FLAGS "${WS_LINK_FLAGS}"
2736                 FOLDER "Executables"
2737                 INSTALL_RPATH "${EXECUTABLE_INSTALL_RPATH}"
2738                 AUTOMOC ON
2739                 AUTOUIC ON
2740                 AUTORCC ON
2741         )
2742         if(MSVC)
2743                 set_target_properties(wireshark PROPERTIES LINK_FLAGS_DEBUG "${WS_MSVC_DEBUG_LINK_FLAGS}")
2744         endif()
2745         if (USE_MSYSTEM)
2746                 set_target_properties(wireshark PROPERTIES OUTPUT_NAME wireshark)
2747         elseif(ENABLE_APPLICATION_BUNDLE OR WIN32)
2748                 set_target_properties(wireshark PROPERTIES OUTPUT_NAME Wireshark)
2749         endif()
2750
2751         if(ENABLE_APPLICATION_BUNDLE)
2752                 if(ASCIIDOCTOR_FOUND)
2753                         # Make sure to generate files referenced by
2754                         # WIRESHARK_BUNDLE_RESOURCE_SHARE_MAN1_FILES
2755                         add_dependencies(wireshark manpages)
2756                 endif()
2757                 set_target_properties(
2758                         wireshark PROPERTIES
2759                                 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_BINARY_DIR}/packaging/macosx/WiresharkInfo.plist
2760                 )
2761                 if(CMAKE_CFG_INTDIR STREQUAL ".")
2762                         # Add a wrapper script which opens the bundle. This is more convenient
2763                         # and lets Sparkle find our CFBundleIdentifier, but means that you have
2764                         # to pass the full path to run/Wireshark.app/Contents/MacOS/Wireshark
2765                         # to your debugger.
2766                         # It is not created if using Xcode
2767                         file(REMOVE ${CMAKE_BINARY_DIR}/run/wireshark)
2768                         file(WRITE ${CMAKE_BINARY_DIR}/run/wireshark "#!/bin/sh\n")
2769                         file(APPEND ${CMAKE_BINARY_DIR}/run/wireshark "# Generated by ${CMAKE_CURRENT_LIST_FILE}\n")
2770                         file(APPEND ${CMAKE_BINARY_DIR}/run/wireshark "# Wrapper script which ensures that we're properly activated via Launch Services\n")
2771                         file(APPEND ${CMAKE_BINARY_DIR}/run/wireshark "exec ${CMAKE_BINARY_DIR}/run/Wireshark.app/Contents/MacOS/Wireshark \"\$\@\"\n")
2772                         execute_process(COMMAND chmod a+x ${CMAKE_BINARY_DIR}/run/wireshark)
2773                 endif()
2774         endif()
2775
2776         target_link_libraries(wireshark ${wireshark_LIBS})
2777         target_include_directories(wireshark SYSTEM PRIVATE ${SPARKLE_INCLUDE_DIRS})
2778
2779         install(
2780                 TARGETS wireshark
2781                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
2782                 BUNDLE DESTINATION ${CMAKE_INSTALL_BINDIR}
2783         )
2784
2785         if(QT_WINDEPLOYQT_EXECUTABLE)
2786                 add_custom_target(copy_qt_dlls ALL)
2787                 set_target_properties(copy_qt_dlls PROPERTIES FOLDER "Copy Tasks")
2788                 # Will we ever need to use --debug? Windeployqt seems to
2789                 # be smart enough to copy debug DLLs when needed.
2790                 if (USE_MSYSTEM AND Qt${qtver}Widgets_VERSION VERSION_EQUAL 6.5.0)
2791                         # windeployqt released with Qt 6.5.0 is broken.
2792                         # https://bugreports.qt.io/browse/QTBUG-112204
2793                         message(WARNING "Qt Deploy Tool 6.5.0 is broken, please upgrade to a later version.")
2794                         # lconvert will fail
2795                 endif()
2796                 add_custom_command(TARGET copy_qt_dlls
2797                         POST_BUILD
2798                         COMMAND set "PATH=${QT_BIN_PATH};%PATH%"
2799                         COMMAND "${QT_WINDEPLOYQT_EXECUTABLE}"
2800                                 ${QT_WINDEPLOYQT_EXTRA_ARGS}
2801                                 --no-compiler-runtime
2802                                 --verbose 0
2803                                 $<$<BOOL:${MSVC}>:--pdb>
2804                                 "$<TARGET_FILE:wireshark>"
2805                 )
2806                 add_dependencies(copy_qt_dlls wireshark)
2807
2808                 install(CODE "execute_process(COMMAND
2809                         \"${QT_WINDEPLOYQT_EXECUTABLE}\"
2810                         --no-compiler-runtime
2811                         \"\${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_BINDIR}/Wireshark.exe\")"
2812                 )
2813
2814         endif(QT_WINDEPLOYQT_EXECUTABLE)
2815 endif()
2816
2817 if(BUILD_logray AND QT_FOUND)
2818         set(logray_LIBS
2819                 ui
2820                 ui_logray
2821                 capchild
2822                 caputils
2823                 iface_monitor
2824                 wiretap
2825                 epan
2826                 summary
2827                 ${QT5_LIBRARIES}
2828                 ${APPLE_APPLICATION_SERVICES_LIBRARY}
2829                 ${APPLE_APPKIT_LIBRARY}
2830                 ${APPLE_CORE_FOUNDATION_LIBRARY}
2831                 ${APPLE_SYSTEM_CONFIGURATION_LIBRARY}
2832                 ${SPARKLE_LIBRARIES}
2833                 ${WIN_WS2_32_LIBRARY}
2834                 ${WIN_VERSION_LIBRARY}
2835                 ${WINSPARKLE_LIBRARIES}
2836                 $<$<BOOL:${WIN32}>:uxtheme.lib>
2837                 ${SPEEXDSP_LIBRARIES}
2838                 ${ZLIB_LIBRARIES}
2839                 ${MINIZIP_LIBRARIES}
2840         )
2841
2842         add_executable(logray WIN32 MACOSX_BUNDLE ${logray_FILES} ${EXTRA_LOGRAY_BUNDLE_FILES})
2843         if(WIN32 AND NOT BUILD_wireshark)
2844                 set_property(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR} PROPERTY VS_STARTUP_PROJECT logray)
2845         endif()
2846         set(PROGLIST ${PROGLIST} logray)
2847         set_target_properties(logray PROPERTIES
2848                 LINK_FLAGS "${WS_LINK_FLAGS}"
2849                 FOLDER "Executables"
2850                 INSTALL_RPATH "${EXECUTABLE_INSTALL_RPATH}"
2851                 AUTOMOC ON
2852                 AUTOUIC ON
2853                 AUTORCC ON
2854         )
2855         if(MSVC)
2856                 set_target_properties(logray PROPERTIES LINK_FLAGS_DEBUG "${WS_MSVC_DEBUG_LINK_FLAGS}")
2857         endif()
2858         if(ENABLE_APPLICATION_BUNDLE OR WIN32)
2859                 set_target_properties(logray PROPERTIES OUTPUT_NAME Logray)
2860         endif()
2861
2862         if(ENABLE_APPLICATION_BUNDLE)
2863                 if(ASCIIDOCTOR_FOUND)
2864                         # Make sure to generate files referenced by
2865                         # LOGRAY_BUNDLE_RESOURCE_SHARE_MAN1_FILES
2866                         add_dependencies(logray manpages)
2867                 endif()
2868                 set_target_properties(
2869                         logray PROPERTIES
2870                                 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_BINARY_DIR}/packaging/macosx/LograyInfo.plist
2871                 )
2872                 if(CMAKE_CFG_INTDIR STREQUAL ".")
2873                         # Add a wrapper script which opens the bundle. This is more convenient
2874                         # and lets Sparkle find our CFBundleIdentifier, but means that you have
2875                         # to pass the full path to run/Wireshark.app/Contents/MacOS/Logray
2876                         # to your debugger.
2877                         # It is not created if using Xcode
2878                         file(REMOVE ${CMAKE_BINARY_DIR}/run/logray)
2879                         file(WRITE ${CMAKE_BINARY_DIR}/run/logray "#!/bin/sh\n")
2880                         file(APPEND ${CMAKE_BINARY_DIR}/run/logray "# Generated by ${CMAKE_CURRENT_LIST_FILE}\n")
2881                         file(APPEND ${CMAKE_BINARY_DIR}/run/logray "# Wrapper script which ensures that we're properly activated via Launch Services\n")
2882                         file(APPEND ${CMAKE_BINARY_DIR}/run/logray "exec ${CMAKE_BINARY_DIR}/run/Logray.app/Contents/MacOS/Logray \"\$\@\"\n")
2883                         execute_process(COMMAND chmod a+x ${CMAKE_BINARY_DIR}/run/logray)
2884                 endif()
2885         endif()
2886
2887         target_link_libraries(logray ${logray_LIBS})
2888         target_include_directories(logray SYSTEM PRIVATE ${SPARKLE_INCLUDE_DIRS})
2889
2890         install(
2891                 TARGETS logray
2892                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
2893                 BUNDLE DESTINATION ${CMAKE_INSTALL_BINDIR}
2894         )
2895
2896         if(QT_WINDEPLOYQT_EXECUTABLE)
2897                 add_custom_target(copy_ls_qt_dlls ALL)
2898                 set_target_properties(copy_ls_qt_dlls PROPERTIES FOLDER "Copy Tasks")
2899                 # Will we ever need to use --debug? Windeployqt seems to
2900                 # be smart enough to copy debug DLLs when needed.
2901                 add_custom_command(TARGET copy_ls_qt_dlls
2902                         POST_BUILD
2903                         COMMAND set "PATH=${QT_BIN_PATH};%PATH%"
2904                         COMMAND "${QT_WINDEPLOYQT_EXECUTABLE}"
2905                                 --no-compiler-runtime
2906                                 --verbose 0
2907                                 $<$<BOOL:${MSVC}>:--pdb>
2908                                 "$<TARGET_FILE:logray>"
2909                 )
2910                 add_dependencies(copy_ls_qt_dlls logray)
2911
2912                 install(CODE "execute_process(COMMAND
2913                         \"${QT_WINDEPLOYQT_EXECUTABLE}\"
2914                         --no-compiler-runtime
2915                         \"\${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_BINDIR}/Logray.exe\")"
2916                 )
2917
2918         endif(QT_WINDEPLOYQT_EXECUTABLE)
2919 endif()
2920
2921 if (BUILD_logray AND FALCO_PLUGINS)
2922         add_custom_target(copy_falco_plugins)
2923         add_custom_command(TARGET copy_falco_plugins
2924                 COMMAND ${CMAKE_COMMAND} -E make_directory ${LOGRAY_PLUGIN_DIR}/falco
2925                 COMMAND ${CMAKE_COMMAND} -E copy_if_different ${FALCO_PLUGINS} ${LOGRAY_PLUGIN_DIR}/falco
2926                 VERBATIM
2927         )
2928         add_dependencies(logray copy_falco_plugins)
2929 endif()
2930
2931 # Common properties for CLI executables
2932 macro(set_extra_executable_properties _executable _folder)
2933         set_target_properties(${_executable} PROPERTIES
2934                 LINK_FLAGS "${WILDCARD_OBJ} ${WS_LINK_FLAGS}"
2935                 FOLDER ${_folder}
2936                 INSTALL_RPATH "${EXECUTABLE_INSTALL_RPATH}"
2937         )
2938         if(MSVC)
2939                 set_target_properties(${_executable} PROPERTIES LINK_FLAGS_DEBUG "${WS_MSVC_DEBUG_LINK_FLAGS}")
2940         endif()
2941
2942         set(PROGLIST ${PROGLIST} ${_executable})
2943
2944         if(ENABLE_APPLICATION_BUNDLE)
2945                 if(NOT CMAKE_CFG_INTDIR STREQUAL ".")
2946                         # Xcode
2947                         set_target_properties(${_executable} PROPERTIES
2948                                 RUNTIME_OUTPUT_DIRECTORY run/$<CONFIG>/Wireshark.app/Contents/MacOS
2949                         )
2950                 else ()
2951                         set_target_properties(${_executable} PROPERTIES
2952                                 RUNTIME_OUTPUT_DIRECTORY run/Wireshark.app/Contents/MacOS
2953                         )
2954                         # Create a convenience link from run/<name> to its respective
2955                         # target in the application bundle.
2956                         add_custom_target(${_executable}-symlink
2957                                 COMMAND ln -s -f
2958                                         Wireshark.app/Contents/MacOS/${_executable}
2959                                         ${CMAKE_BINARY_DIR}/run/${_executable}
2960                         )
2961                         add_dependencies(${_executable} ${_executable}-symlink)
2962                 endif()
2963         endif()
2964 endmacro()
2965
2966 macro(executable_link_mingw_unicode _target)
2967         # target_link_options() requires CMake >= 3.13
2968         if (MINGW)
2969                 target_link_options(${_target} PRIVATE "-municode")
2970         endif()
2971 endmacro()
2972
2973 register_tap_files(tshark-tap-register.c
2974         ${TSHARK_TAP_SRC}
2975 )
2976
2977 if(BUILD_tshark)
2978         set(tshark_LIBS
2979                 ui
2980                 capchild
2981                 caputils
2982                 wiretap
2983                 epan
2984                 wsutil
2985                 ${APPLE_CORE_FOUNDATION_LIBRARY}
2986                 ${APPLE_SYSTEM_CONFIGURATION_LIBRARY}
2987                 ${WIN_WS2_32_LIBRARY}
2988                 ${M_LIBRARIES}
2989         )
2990         set(tshark_FILES
2991                 $<TARGET_OBJECTS:capture_opts>
2992                 $<TARGET_OBJECTS:cli_main>
2993                 $<TARGET_OBJECTS:shark_common>
2994                 tshark-tap-register.c
2995                 tshark.c
2996                 extcap.c
2997                 ${TSHARK_TAP_SRC}
2998         )
2999
3000         set_executable_resources(tshark "TShark" UNIQUE_RC)
3001         add_executable(tshark ${tshark_FILES})
3002         set_extra_executable_properties(tshark "Executables")
3003         target_link_libraries(tshark ${tshark_LIBS})
3004         executable_link_mingw_unicode(tshark)
3005         install(TARGETS tshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
3006 endif()
3007
3008 if(BUILD_tfshark)
3009         set(tfshark_LIBS
3010                 m
3011                 ui
3012                 wiretap
3013                 epan
3014                 ${APPLE_CORE_FOUNDATION_LIBRARY}
3015                 ${APPLE_SYSTEM_CONFIGURATION_LIBRARY}
3016         )
3017         set(tfshark_FILES
3018                 $<TARGET_OBJECTS:cli_main>
3019                 $<TARGET_OBJECTS:shark_common>
3020                 tfshark.c
3021                 ${TSHARK_TAP_SRC}
3022         )
3023         set_executable_resources(tfshark "TFShark")
3024         add_executable(tfshark ${tfshark_FILES})
3025         set_extra_executable_properties(tfshark "Executables")
3026         target_link_libraries(tfshark ${tfshark_LIBS})
3027         install(TARGETS tfshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
3028 endif()
3029
3030 if(BUILD_rawshark AND PCAP_FOUND)
3031         set(rawshark_LIBS
3032                 caputils
3033                 ui
3034                 wiretap
3035                 epan
3036                 ${APPLE_CORE_FOUNDATION_LIBRARY}
3037                 ${APPLE_SYSTEM_CONFIGURATION_LIBRARY}
3038                 ${WIN_WS2_32_LIBRARY}
3039         )
3040         set(rawshark_FILES
3041                 $<TARGET_OBJECTS:cli_main>
3042                 $<TARGET_OBJECTS:shark_common>
3043                 rawshark.c
3044         )
3045         set_executable_resources(rawshark "Rawshark")
3046         add_executable(rawshark ${rawshark_FILES})
3047         set_extra_executable_properties(rawshark "Executables")
3048         target_link_libraries(rawshark ${rawshark_LIBS})
3049         executable_link_mingw_unicode(rawshark)
3050         install(TARGETS rawshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
3051 endif()
3052
3053 if(BUILD_sharkd)
3054         set(sharkd_LIBS
3055                 ui
3056                 wiretap
3057                 epan
3058                 ${APPLE_CORE_FOUNDATION_LIBRARY}
3059                 ${APPLE_SYSTEM_CONFIGURATION_LIBRARY}
3060                 ${WIN_WS2_32_LIBRARY}
3061                 ${SPEEXDSP_LIBRARIES}
3062         )
3063         set(sharkd_FILES
3064                 #
3065                 # XXX - currently doesn't work on Windows if it uses
3066                 # $<TARGET_OBJECTS:cli_main> and has real_main().
3067                 #
3068                 $<TARGET_OBJECTS:shark_common>
3069                 sharkd.c
3070                 sharkd_daemon.c
3071                 sharkd_session.c
3072         )
3073         set_executable_resources(sharkd "SharkD")
3074         add_executable(sharkd ${sharkd_FILES})
3075         set_extra_executable_properties(sharkd "Executables")
3076         target_link_libraries(sharkd ${sharkd_LIBS})
3077         target_include_directories(sharkd SYSTEM PUBLIC ${SPEEXDSP_INCLUDE_DIRS})
3078
3079         install(TARGETS sharkd RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
3080 endif()
3081
3082 if(BUILD_dftest)
3083         set(dftest_LIBS
3084                 ui
3085                 wiretap
3086                 epan
3087         )
3088         set(dftest_FILES
3089                 dftest.c
3090         )
3091         set_executable_resources(dftest "Dftest")
3092         add_executable(dftest ${dftest_FILES})
3093         set_extra_executable_properties(dftest "Tests")
3094         target_link_libraries(dftest ${dftest_LIBS})
3095 endif()
3096
3097 if(BUILD_randpkt)
3098         set(randpkt_LIBS
3099                 randpkt_core
3100                 ui
3101                 wiretap
3102                 wsutil
3103         )
3104         set(randpkt_FILES
3105                 $<TARGET_OBJECTS:cli_main>
3106                 randpkt.c
3107         )
3108         set_executable_resources(randpkt "Randpkt"
3109                 COPYRIGHT_INFO "Copyright (C) 1999 by Gilbert Ramirez <gram@alumni.rice.edu>")
3110         add_executable(randpkt ${randpkt_FILES})
3111         set_extra_executable_properties(randpkt "Executables")
3112         target_link_libraries(randpkt ${randpkt_LIBS})
3113         executable_link_mingw_unicode(randpkt)
3114         install(TARGETS randpkt RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
3115 endif()
3116
3117 if(BUILD_fuzzshark OR ENABLE_FUZZER OR OSS_FUZZ)
3118         add_subdirectory(fuzz)
3119 endif()
3120
3121 if(BUILD_text2pcap)
3122         set(text2pcap_LIBS
3123                 wiretap
3124                 wsutil
3125                 ui
3126                 epan
3127                 ${ZLIB_LIBRARIES}
3128         )
3129         set(text2pcap_FILES
3130                 $<TARGET_OBJECTS:cli_main>
3131                 text2pcap.c
3132         )
3133         set_executable_resources(text2pcap "Text2pcap"
3134                 COPYRIGHT_INFO "2001 Ashok Narayanan <ashokn@cisco.com>")
3135         add_executable(text2pcap ${text2pcap_FILES})
3136         set_extra_executable_properties(text2pcap "Executables")
3137         target_link_libraries(text2pcap ${text2pcap_LIBS})
3138         executable_link_mingw_unicode(text2pcap)
3139         install(TARGETS text2pcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
3140 endif()
3141
3142 if(BUILD_mergecap)
3143         set(mergecap_LIBS
3144                 ui
3145                 wiretap
3146                 ${ZLIB_LIBRARIES}
3147                 ${CMAKE_DL_LIBS}
3148         )
3149         set(mergecap_FILES
3150                 $<TARGET_OBJECTS:cli_main>
3151                 mergecap.c
3152         )
3153         set_executable_resources(mergecap "Mergecap")
3154         add_executable(mergecap ${mergecap_FILES})
3155         set_extra_executable_properties(mergecap "Executables")
3156         target_link_libraries(mergecap ${mergecap_LIBS})
3157         executable_link_mingw_unicode(mergecap)
3158         install(TARGETS mergecap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
3159 endif()
3160
3161 if(BUILD_reordercap)
3162         set(reordercap_LIBS
3163                 ui
3164                 wiretap
3165                 ${ZLIB_LIBRARIES}
3166                 ${CMAKE_DL_LIBS}
3167         )
3168         set(reordercap_FILES
3169                 $<TARGET_OBJECTS:cli_main>
3170                 reordercap.c
3171         )
3172         set_executable_resources(reordercap "Reordercap")
3173         add_executable(reordercap ${reordercap_FILES})
3174         set_extra_executable_properties(reordercap "Executables")
3175         target_link_libraries(reordercap ${reordercap_LIBS})
3176         executable_link_mingw_unicode(reordercap)
3177         install(TARGETS reordercap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
3178 endif()
3179
3180 if(BUILD_capinfos)
3181         set(capinfos_LIBS
3182                 ui
3183                 wiretap
3184                 wsutil
3185                 ${ZLIB_LIBRARIES}
3186                 ${GCRYPT_LIBRARIES}
3187                 ${CMAKE_DL_LIBS}
3188         )
3189         set(capinfos_FILES
3190                 $<TARGET_OBJECTS:cli_main>
3191                 capinfos.c
3192         )
3193         set_executable_resources(capinfos "Capinfos")
3194         add_executable(capinfos ${capinfos_FILES})
3195         set_extra_executable_properties(capinfos "Executables")
3196         target_link_libraries(capinfos ${capinfos_LIBS})
3197         target_include_directories(capinfos SYSTEM PRIVATE ${GCRYPT_INCLUDE_DIRS})
3198         executable_link_mingw_unicode(capinfos)
3199         install(TARGETS capinfos RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
3200 endif()
3201
3202 if(BUILD_captype)
3203         set(captype_LIBS
3204                 ui
3205                 wiretap
3206                 wsutil
3207                 ${ZLIB_LIBRARIES}
3208                 ${CMAKE_DL_LIBS}
3209         )
3210         set(captype_FILES
3211                 $<TARGET_OBJECTS:cli_main>
3212                 captype.c
3213         )
3214         set_executable_resources(captype "Captype")
3215         add_executable(captype ${captype_FILES})
3216         set_extra_executable_properties(captype "Executables")
3217         target_link_libraries(captype ${captype_LIBS})
3218         executable_link_mingw_unicode(captype)
3219         install(TARGETS captype RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
3220 endif()
3221
3222 if(BUILD_editcap)
3223         set(editcap_LIBS
3224                 ui
3225                 wiretap
3226                 ${ZLIB_LIBRARIES}
3227                 ${GCRYPT_LIBRARIES}
3228                 ${CMAKE_DL_LIBS}
3229         )
3230         set(editcap_FILES
3231                 $<TARGET_OBJECTS:cli_main>
3232                 editcap.c
3233         )
3234         set_executable_resources(editcap "Editcap")
3235         add_executable(editcap ${editcap_FILES})
3236         set_extra_executable_properties(editcap "Executables")
3237         target_link_libraries(editcap ${editcap_LIBS})
3238         target_include_directories(editcap SYSTEM PRIVATE ${GCRYPT_INCLUDE_DIRS})
3239         executable_link_mingw_unicode(editcap)
3240         install(TARGETS editcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
3241 endif()
3242
3243 if(BUILD_dumpcap AND PCAP_FOUND)
3244         set(dumpcap_LIBS
3245                 writecap
3246                 wsutil_static
3247                 pcap::pcap
3248                 ${CAP_LIBRARIES}
3249                 ${ZLIB_LIBRARIES}
3250                 ${NL_LIBRARIES}
3251                 ${APPLE_CORE_FOUNDATION_LIBRARY}
3252                 ${APPLE_SYSTEM_CONFIGURATION_LIBRARY}
3253                 ${WIN_WS2_32_LIBRARY}
3254         )
3255         if(UNIX)
3256                 list(APPEND CAPUTILS_SRC
3257                         capture/capture-pcap-util-unix.c)
3258         endif()
3259         if(WIN32)
3260                 list(APPEND CAPUTILS_SRC
3261                         capture/capture_win_ifnames.c
3262                         capture/capture-wpcap.c
3263                 )
3264         endif()
3265         list(APPEND CAPUTILS_SRC
3266                 capture/capture-pcap-util.c
3267         )
3268         if (AIRPCAP_FOUND)
3269                 list(APPEND CAPUTILS_SRC capture/airpcap_loader.c)
3270         endif()
3271         set(dumpcap_FILES
3272                 capture_opts.c
3273                 cli_main.c
3274                 dumpcap.c
3275                 ringbuffer.c
3276                 sync_pipe_write.c
3277                 capture/iface_monitor.c
3278                 capture/ws80211_utils.c
3279                 ${CAPUTILS_SRC}
3280         )
3281         set_executable_resources(dumpcap "Dumpcap" UNIQUE_RC)
3282         add_executable(dumpcap ${dumpcap_FILES})
3283         set_extra_executable_properties(dumpcap "Executables")
3284         target_link_libraries(dumpcap ${dumpcap_LIBS})
3285         target_include_directories(dumpcap SYSTEM PRIVATE ${ZLIB_INCLUDE_DIRS} ${NL_INCLUDE_DIRS})
3286         target_compile_definitions(dumpcap PRIVATE ENABLE_STATIC)
3287         executable_link_mingw_unicode(dumpcap)
3288         install(TARGETS dumpcap
3289                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
3290                         PERMISSIONS ${DUMPCAP_SETUID}
3291                                 OWNER_READ OWNER_WRITE OWNER_EXECUTE
3292                                 GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE
3293         )
3294         if(ENABLE_DUMPCAP_GROUP)
3295                 install(CODE "execute_process(COMMAND chgrp ${DUMPCAP_INSTALL_GROUP} ${CMAKE_INSTALL_FULL_BINDIR}/dumpcap)")
3296                 install(CODE "execute_process(COMMAND chmod o-x ${CMAKE_INSTALL_FULL_BINDIR}/dumpcap)")
3297         endif()
3298         if(DUMPCAP_INSTALL_OPTION STREQUAL "capabilities")
3299                 install( CODE "execute_process(
3300                         COMMAND
3301                                 ${SETCAP_EXECUTABLE}
3302                                 cap_net_raw,cap_net_admin+ep
3303                                 ${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_BINDIR}/dumpcap${CMAKE_EXECUTABLE_SUFFIX}
3304                         RESULT_VARIABLE
3305                                 _SETCAP_RESULT
3306                         )
3307                         if( _SETCAP_RESULT )
3308                                 message( WARNING \"setcap failed (${_SETCAP_RESULT}).\")
3309                         endif()"
3310                 )
3311         endif()
3312         if(BUILD_logray AND ENABLE_APPLICATION_BUNDLE)
3313                 add_custom_command(TARGET dumpcap POST_BUILD
3314                         COMMAND ${CMAKE_COMMAND} -E copy_if_different
3315                                 $<TARGET_FILE:dumpcap> run/Logray.app/Contents/MacOS/dumpcap
3316                 )
3317         endif()
3318 elseif(BUILD_dumpcap AND ENABLE_PCAP)
3319         message(WARNING "Dumpcap was requested but libpcap dependency is not available. "
3320                 "Wireshark will be built without packet capture capability.")
3321 endif()
3322
3323 # We have two idl2wrs utilities: this and the CORBA version in tools.
3324 # We probably shouldn't do that.
3325 if(BUILD_dcerpcidl2wrs)
3326         set(idl2wrs_LIBS
3327                 wsutil
3328         )
3329         set(idl2wrs_FILES
3330                 epan/dissectors/dcerpc/idl2wrs.c
3331         )
3332
3333         add_executable(idl2wrs ${idl2wrs_FILES})
3334         set_target_properties(idl2wrs PROPERTIES FOLDER "Executables")
3335         set_extra_executable_properties(idl2wrs "Executables")
3336         target_link_libraries(idl2wrs ${idl2wrs_LIBS})
3337         install(TARGETS idl2wrs RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
3338 endif()
3339
3340 if(WIN32)
3341         find_package( MSVC_REDIST )
3342
3343         # Must come after executable targets are defined.
3344         find_package( NSIS )
3345
3346         if(MAKENSIS_EXECUTABLE)
3347                 add_subdirectory( packaging/nsis EXCLUDE_FROM_ALL )
3348                 ADD_NSIS_UNINSTALLER_TARGETS()
3349                 ADD_NSIS_PACKAGE_TARGETS()
3350         endif()
3351
3352         find_package( WiX )
3353
3354         if(WIX_CANDLE_EXECUTABLE)
3355                 add_subdirectory( packaging/wix EXCLUDE_FROM_ALL )
3356                 ADD_WIX_PACKAGE_TARGET()
3357         endif()
3358
3359         find_package( PortableApps )
3360         if(PORTABLEAPPS_LAUNCHER_GENERATOR_EXECUTABLE AND PORTABLEAPPS_INSTALLER_EXECUTABLE)
3361                 add_subdirectory( packaging/portableapps EXCLUDE_FROM_ALL )
3362                 ADD_PORTABLEAPPS_PACKAGE_TARGET()
3363         endif()
3364 endif()
3365
3366 if (MAXMINDDB_FOUND)
3367         set(mmdbresolve_LIBS
3368                 # Note: libmaxminddb is not GPL-2 compatible.
3369                 ${MAXMINDDB_LIBRARY}
3370                 # Needed for CMake-built libmaxminddb.lib <= 1.43.
3371                 ${WIN_WS2_32_LIBRARY}
3372         )
3373         set(mmdbresolve_FILES
3374                 mmdbresolve.c
3375         )
3376         set_executable_resources(mmdbresolve "Mmdbresolve")
3377         add_executable(mmdbresolve ${mmdbresolve_FILES})
3378         set_extra_executable_properties(mmdbresolve "Executables")
3379         target_link_libraries(mmdbresolve ${mmdbresolve_LIBS})
3380         target_include_directories(mmdbresolve PUBLIC ${MAXMINDDB_INCLUDE_DIRS})
3381         target_compile_definitions(mmdbresolve PUBLIC ${MAXMINDDB_DEFINITIONS})
3382         install(TARGETS mmdbresolve RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
3383 endif()
3384
3385 if(ENABLE_APPLICATION_BUNDLE AND BUILD_wireshark)
3386         file(MAKE_DIRECTORY "${CMAKE_BINARY_DIR}/run/${CMAKE_CFG_INTDIR}/Wireshark.app/Contents/Resources/Extras")
3387
3388         # --preserve-xattr is undocumented but ensures that we install
3389         # a signed ChmodBPF script.
3390         set (_chmodbpf_version 1.2)
3391         set (install_chmodbpf_component_pkg "${CMAKE_BINARY_DIR}/install.ChmodBPF.pkg")
3392         add_custom_command(OUTPUT "${install_chmodbpf_component_pkg}"
3393                 COMMAND find
3394                         "${CMAKE_SOURCE_DIR}/packaging/macosx/ChmodBPF/root"
3395                         -type d
3396                         -exec chmod 755 "{}" +
3397                 COMMAND chmod 644
3398                         "${CMAKE_SOURCE_DIR}/packaging/macosx/ChmodBPF/root/Library/LaunchDaemons/org.wireshark.ChmodBPF.plist"
3399                 COMMAND chmod 755
3400                         "${CMAKE_SOURCE_DIR}/packaging/macosx/ChmodBPF/root/Library/Application Support/Wireshark/ChmodBPF/ChmodBPF"
3401                 COMMAND "${CMAKE_SOURCE_DIR}/packaging/macosx/osx-extras.sh"
3402                 COMMAND pkgbuild
3403                         --identifier org.wireshark.ChmodBPF.pkg
3404                         --version ${_chmodbpf_version}
3405                         --preserve-xattr
3406                         --root "${CMAKE_SOURCE_DIR}/packaging/macosx/ChmodBPF/root"
3407                         --scripts "${CMAKE_SOURCE_DIR}/packaging/macosx/ChmodBPF/install-scripts"
3408                         ${install_chmodbpf_component_pkg}
3409                 DEPENDS
3410                         "${CMAKE_SOURCE_DIR}/packaging/macosx/ChmodBPF/root/Library/Application Support/Wireshark/ChmodBPF/ChmodBPF"
3411                         "${CMAKE_SOURCE_DIR}/packaging/macosx/ChmodBPF/root/Library/LaunchDaemons/org.wireshark.ChmodBPF.plist"
3412                         "${CMAKE_SOURCE_DIR}/packaging/macosx/ChmodBPF/install-scripts/postinstall"
3413         )
3414         set (install_chmodbpf_pkg "${CMAKE_BINARY_DIR}/run/Wireshark.app/Contents/Resources/Extras/Install ChmodBPF.pkg")
3415         add_custom_command(OUTPUT "${install_chmodbpf_pkg}"
3416                 COMMAND productbuild
3417                         --identifier org.wireshark.install.ChmodBPF.product
3418                         --version ${_chmodbpf_version}
3419                         --distribution "${CMAKE_SOURCE_DIR}/packaging/macosx/ChmodBPF/install-distribution.xml"
3420                         --package-path "${CMAKE_BINARY_DIR}"
3421                         ${install_chmodbpf_pkg}
3422                 DEPENDS
3423                         "${CMAKE_SOURCE_DIR}/packaging/macosx/ChmodBPF/install-distribution.xml"
3424                         ${install_chmodbpf_component_pkg}
3425         )
3426
3427         set (uninstall_chmodbpf_component_pkg "${CMAKE_BINARY_DIR}/uninstall.ChmodBPF.pkg")
3428         add_custom_command(OUTPUT "${uninstall_chmodbpf_component_pkg}"
3429                 COMMAND pkgbuild
3430                         --identifier org.wireshark.uninstall.ChmodBPF.pkg
3431                         --version ${_chmodbpf_version}
3432                         --nopayload
3433                         --scripts "${CMAKE_SOURCE_DIR}/packaging/macosx/ChmodBPF/uninstall-scripts"
3434                         ${uninstall_chmodbpf_component_pkg}
3435                 DEPENDS
3436                         "${CMAKE_SOURCE_DIR}/packaging/macosx/ChmodBPF/uninstall-scripts/postinstall"
3437         )
3438         set (uninstall_chmodbpf_pkg "${CMAKE_BINARY_DIR}/run/Wireshark.app/Contents/Resources/Extras/Uninstall ChmodBPF.pkg")
3439         add_custom_command(OUTPUT "${uninstall_chmodbpf_pkg}"
3440                 COMMAND productbuild
3441                         --identifier org.wireshark.uninstall.ChmodBPF.product
3442                         --version ${_chmodbpf_version}
3443                         --distribution "${CMAKE_SOURCE_DIR}/packaging/macosx/ChmodBPF/uninstall-distribution.xml"
3444                         --package-path "${CMAKE_BINARY_DIR}"
3445                         ${uninstall_chmodbpf_pkg}
3446                 DEPENDS
3447                         "${CMAKE_SOURCE_DIR}/packaging/macosx/ChmodBPF/uninstall-distribution.xml"
3448                         ${uninstall_chmodbpf_component_pkg}
3449         )
3450
3451         add_custom_target(chmodbpf DEPENDS ${install_chmodbpf_pkg} ${uninstall_chmodbpf_pkg})
3452
3453         set (_path_helper_version 1.1)
3454         set (install_path_helper_component_pkg "${CMAKE_BINARY_DIR}/install.path_helper.pkg")
3455         add_custom_command(OUTPUT "${install_path_helper_component_pkg}"
3456                 COMMAND find
3457                         "${CMAKE_SOURCE_DIR}/packaging/macosx/path_helper/root"
3458                         -type d
3459                         -exec chmod 755 "{}" +
3460                 COMMAND find
3461                         "${CMAKE_SOURCE_DIR}/packaging/macosx/path_helper/root"
3462                         -type f
3463                         -exec chmod 644 "{}" +
3464                 COMMAND pkgbuild
3465                         --identifier org.wireshark.path_helper.pkg
3466                         --version ${_path_helper_version}
3467                         --root "${CMAKE_SOURCE_DIR}/packaging/macosx/path_helper/root/etc"
3468                         --install-location /private/etc
3469                         ${install_path_helper_component_pkg}
3470                 DEPENDS
3471                         "${CMAKE_SOURCE_DIR}/packaging/macosx/path_helper/root/etc/paths.d/Wireshark"
3472                         "${CMAKE_SOURCE_DIR}/packaging/macosx/path_helper/root/etc/manpaths.d/Wireshark"
3473         )
3474         set (install_path_helper_pkg "${CMAKE_BINARY_DIR}/run/Wireshark.app/Contents/Resources/Extras/Add Wireshark to the system path.pkg")
3475         add_custom_command(OUTPUT "${install_path_helper_pkg}"
3476                 COMMAND productbuild
3477                         --identifier org.wireshark.install.path_helper.product
3478                         --version ${_path_helper_version}
3479                         --distribution "${CMAKE_SOURCE_DIR}/packaging/macosx/path_helper/install-distribution.xml"
3480                         --package-path "${CMAKE_BINARY_DIR}"
3481                         ${install_path_helper_pkg}
3482                 DEPENDS
3483                         "${CMAKE_SOURCE_DIR}/packaging/macosx/path_helper/install-distribution.xml"
3484                         ${install_path_helper_component_pkg}
3485         )
3486
3487         set (uninstall_path_helper_component_pkg "${CMAKE_BINARY_DIR}/uninstall.path_helper.pkg")
3488         add_custom_command(OUTPUT "${uninstall_path_helper_component_pkg}"
3489                 COMMAND pkgbuild
3490                         --identifier org.wireshark.uninstall.path_helper.pkg
3491                         --version ${_path_helper_version}
3492                         --nopayload
3493                         --scripts "${CMAKE_SOURCE_DIR}/packaging/macosx/path_helper/uninstall-scripts"
3494                         ${uninstall_path_helper_component_pkg}
3495                 DEPENDS
3496                         "${CMAKE_SOURCE_DIR}/packaging/macosx/path_helper/uninstall-scripts/postinstall"
3497         )
3498         set (uninstall_path_helper_pkg "${CMAKE_BINARY_DIR}/run/Wireshark.app/Contents/Resources/Extras/Remove Wireshark from the system path.pkg")
3499         add_custom_command(OUTPUT "${uninstall_path_helper_pkg}"
3500                 COMMAND productbuild
3501                         --identifier org.wireshark.uninstall.path_helper.product
3502                         --version ${_path_helper_version}
3503                         --distribution "${CMAKE_SOURCE_DIR}/packaging/macosx/path_helper/uninstall-distribution.xml"
3504                         --package-path "${CMAKE_BINARY_DIR}"
3505                         ${uninstall_path_helper_pkg}
3506                 DEPENDS
3507                         ${CMAKE_SOURCE_DIR}/packaging/macosx/path_helper/uninstall-distribution.xml
3508                         ${uninstall_path_helper_component_pkg}
3509         )
3510
3511         add_custom_target(path_helper DEPENDS ${install_path_helper_pkg} ${uninstall_path_helper_pkg})
3512
3513         add_custom_target(wireshark_app_bundle)
3514         set_target_properties(wireshark_app_bundle PROPERTIES FOLDER "Copy Tasks")
3515         add_custom_command(TARGET wireshark_app_bundle
3516                 POST_BUILD
3517                 COMMAND "${CMAKE_BINARY_DIR}/packaging/macosx/osx-app.sh"
3518                 WORKING_DIRECTORY "${CMAKE_BINARY_DIR}/run"
3519         )
3520         add_dependencies(wireshark_app_bundle ${PROGLIST} chmodbpf path_helper)
3521
3522         add_custom_target(wireshark_dmg_prep DEPENDS wireshark_app_bundle)
3523
3524         FILE(MAKE_DIRECTORY packaging/macosx/wireshark)
3525
3526         set(_wireshark_read_me_first "packaging/macosx/wireshark/Read me first.html")
3527         ADD_CUSTOM_COMMAND(
3528         OUTPUT
3529                 ${_wireshark_read_me_first}
3530         COMMAND ${ASCIIDOCTOR_EXECUTABLE}
3531                 --backend html
3532                 --out-file ${_wireshark_read_me_first}
3533                 --attribute include-dir=${CMAKE_SOURCE_DIR}/docbook
3534                 --attribute min-macos-version=${MIN_MACOS_VERSION}
3535                 ${CMAKE_CURRENT_SOURCE_DIR}/packaging/macosx/Wireshark_read_me_first.adoc
3536         DEPENDS
3537                 ${CMAKE_CURRENT_SOURCE_DIR}/packaging/macosx/Wireshark_read_me_first.adoc
3538         )
3539
3540         set(_wireshark_donate "packaging/macosx/wireshark/Donate to the Wireshark Foundation.html")
3541         ADD_CUSTOM_COMMAND(
3542         OUTPUT
3543                 ${_wireshark_donate}
3544         COMMAND ${ASCIIDOCTOR_EXECUTABLE}
3545                 --backend html
3546                 --out-file ${_wireshark_donate}
3547                 --attribute include-dir=${CMAKE_SOURCE_DIR}/docbook
3548                 --attribute min-macos-version=${MIN_MACOS_VERSION}
3549                 ${CMAKE_CURRENT_SOURCE_DIR}/packaging/macosx/Donate_to_the_Wireshark_Foundation.adoc
3550         DEPENDS
3551                 ${CMAKE_CURRENT_SOURCE_DIR}/packaging/macosx/Donate_to_the_Wireshark_Foundation.adoc
3552         )
3553
3554         set(_wireshark_dsym_installation "packaging/macosx/wireshark/Debugging symbols installation.html")
3555         ADD_CUSTOM_COMMAND(
3556         OUTPUT
3557                 ${_wireshark_dsym_installation}
3558         COMMAND ${ASCIIDOCTOR_EXECUTABLE}
3559                 --backend html
3560                 --out-file ${_wireshark_dsym_installation}
3561                 --attribute include-dir=${CMAKE_SOURCE_DIR}/docbook
3562                 ${CMAKE_CURRENT_SOURCE_DIR}/packaging/macosx/Wireshark_dsym_installation.adoc
3563         DEPENDS
3564                 ${CMAKE_CURRENT_SOURCE_DIR}/packaging/macosx/Wireshark_dsym_installation.adoc
3565         )
3566
3567         add_custom_target(wireshark_dmg_readmes DEPENDS ${_wireshark_read_me_first} ${_wireshark_donate} ${_wireshark_dsym_installation} )
3568         add_dependencies(wireshark_dmg_prep wireshark_dmg_readmes)
3569
3570         ADD_CUSTOM_TARGET( wireshark_dmg
3571                 COMMAND bash -x ${CMAKE_BINARY_DIR}/packaging/macosx/osx-dmg.sh
3572                 # Unlike wireshark_nsis_prep + wireshark_nsis, we can add a direct
3573                 # dependency here.
3574                 DEPENDS wireshark_dmg_prep
3575                 # We create Wireshark.app in "run". Do our work there.
3576                 WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/run
3577         )
3578
3579 endif()
3580
3581 if(ENABLE_APPLICATION_BUNDLE AND BUILD_logray)
3582         add_custom_target(logray_app_bundle)
3583         set_target_properties(logray_app_bundle PROPERTIES FOLDER "Copy Tasks")
3584         add_custom_command(TARGET logray_app_bundle
3585                 POST_BUILD
3586                 COMMAND "${CMAKE_BINARY_DIR}/packaging/macosx/osx-app.sh" --bundle Logray.app
3587                 WORKING_DIRECTORY "${CMAKE_BINARY_DIR}/run"
3588         )
3589
3590         add_custom_target(logray_dmg_prep DEPENDS logray_app_bundle)
3591
3592         FILE(MAKE_DIRECTORY packaging/macosx/logray)
3593
3594         set(_logray_read_me_first "packaging/macosx/logray/Read me first.html")
3595         ADD_CUSTOM_COMMAND(
3596         OUTPUT
3597                 ${_logray_read_me_first}
3598         COMMAND ${ASCIIDOCTOR_EXECUTABLE}
3599                 --backend html
3600                 --out-file ${_logray_read_me_first}
3601                 --attribute include-dir=${CMAKE_SOURCE_DIR}/docbook
3602                 --attribute min-macos-version=${MIN_MACOS_VERSION}
3603                 ${CMAKE_CURRENT_SOURCE_DIR}/packaging/macosx/Logray_read_me_first.adoc
3604         DEPENDS
3605                 ${CMAKE_CURRENT_SOURCE_DIR}/packaging/macosx/Logray_read_me_first.adoc
3606         )
3607
3608         set(_logray_dsym_installation "packaging/macosx/logray/Debugging symbols installation.html")
3609         ADD_CUSTOM_COMMAND(
3610         OUTPUT
3611                 ${_logray_dsym_installation}
3612         COMMAND ${ASCIIDOCTOR_EXECUTABLE}
3613                 --backend html
3614                 --out-file ${_logray_dsym_installation}
3615                 --attribute include-dir=${CMAKE_SOURCE_DIR}/docbook
3616                 ${CMAKE_CURRENT_SOURCE_DIR}/packaging/macosx/Logray_dsym_installation.adoc
3617         DEPENDS
3618                 ${CMAKE_CURRENT_SOURCE_DIR}/packaging/macosx/Logray_dsym_installation.adoc
3619         )
3620
3621         add_custom_target(logray_dmg_readmes DEPENDS ${_logray_read_me_first} ${_logray_dsym_installation} )
3622         add_dependencies(logray_dmg_prep logray_dmg_readmes)
3623
3624         ADD_CUSTOM_TARGET( logray_dmg
3625                 COMMAND bash -x ${CMAKE_BINARY_DIR}/packaging/macosx/osx-dmg.sh --app-name Logray
3626                 # Unlike wireshark_nsis_prep + wireshark_nsis, we can add a direct
3627                 # dependency here.
3628                 DEPENDS logray_dmg_prep
3629                 # We create Wireshark.app in "run". Do our work there.
3630                 WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/run
3631         )
3632
3633 endif()
3634
3635 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
3636         find_program(RPMBUILD_EXECUTABLE rpmbuild)
3637         find_program(GIT_EXECUTABLE git)
3638         # Should we add appimaged's monitored directories
3639         # as HINTS?
3640         # https://github.com/AppImage/appimaged
3641         find_program(LINUXDEPLOY_EXECUTABLE NAMES linuxdeploy-x86_64.AppImage linuxdeploy)
3642         find_program(_linuxdeploy_plugin_qt NAMES linuxdeploy-plugin-qt-x86_64.AppImage linuxdeploy-plugin-qt)
3643         find_program(APPIMAGETOOL_EXECUTABLE NAMES appimagetool-x86_64.AppImage
3644  appimagetool)
3645 endif()
3646
3647
3648 string(REPLACE "-" "_" RPM_VERSION "${PROJECT_VERSION}")
3649 configure_file(packaging/rpm/wireshark.spec.in ${CMAKE_BINARY_DIR}/packaging/rpm/SPECS/wireshark.spec)
3650 if(RPMBUILD_EXECUTABLE)
3651         foreach(_rpm_dir BUILD RPMS SOURCES SPECS SRPMS)
3652                 file(MAKE_DIRECTORY "${CMAKE_BINARY_DIR}/packaging/rpm/${_rpm_dir}")
3653         endforeach()
3654
3655         set(_rpmbuild_with_args)
3656         #
3657         # This is ugly.
3658         #
3659         # At least some versions of rpmbuild define the cmake_build
3660         # macro to run "cmake --build" with the "--verbose" option,
3661         # with no obvious way to easily override that, so, if you
3662         # are doing a build with lots of source files, and with
3663         # lots of compiler options (for example, a log of -W flags),
3664         # you can get a lot of output from rpmbuild.
3665         #
3666         # Wireshark is a program with lots of source files and
3667         # lots of compiler options.
3668         #
3669         # GitLab's shared builders have a limit of 4MB on logs
3670         # from build jobs.
3671         #
3672         # Wireshark uses the shared builders, and can produce
3673         # more than 4MB with the Fedora RPM build; this causes
3674         # the builds to fail.
3675         #
3676         # Forcibly overriding the cmake_build macro with a
3677         # version that lacks the --version file should
3678         # prevent ninja from being run with the -v flag,
3679         # so that it prints the compact output rather
3680         # than the raw command.
3681         #
3682         # We don't do that by default; if the build has the
3683         # FORCE_CMAKE_NINJA_QUIET environment variable set,
3684         # it will add it.
3685         #
3686         if(DEFINED ENV{FORCE_CMAKE_NINJA_NON_VERBOSE})
3687                 #
3688                 # Get the output of a pipeline running
3689                 # "rpmbuild --showrc", to find the settings
3690                 # of all macros, piped to an awk script
3691                 # to extract the value of the cmake_build
3692                 # macro.
3693                 #
3694                 execute_process(
3695                         COMMAND rpmbuild --showrc
3696                         COMMAND awk "/: cmake_build/ { getline; print \$0; exit }"
3697                         OUTPUT_VARIABLE CMAKE_BUILD_VALUE
3698                         OUTPUT_STRIP_TRAILING_WHITESPACE)
3699                 if (CMAKE_BUILD_VALUE MATCHES ".*--verbose.*")
3700                         #
3701                         # OK, the setting contains "--verbose".
3702                         # Rip it out.
3703                         #
3704                         string(REPLACE "--verbose" ""
3705                                 NON_VERBOSE_CMAKE_BUILD_VALUE
3706                                 ${CMAKE_BUILD_VALUE})
3707                         list(APPEND _rpmbuild_with_args --define "cmake_build ${NON_VERBOSE_CMAKE_BUILD_VALUE}")
3708                 endif()
3709         else()
3710                 if(CMAKE_VERBOSE_MAKEFILE)
3711                         list(APPEND _rpmbuild_with_args -v)
3712                 endif()
3713         endif()
3714         if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
3715                 list(APPEND _rpmbuild_with_args --with toolchain_clang)
3716         endif()
3717         if(CMAKE_GENERATOR STREQUAL "Ninja")
3718                 list(APPEND _rpmbuild_with_args --with ninja)
3719         endif()
3720         if(CCACHE_EXECUTABLE)
3721                 list(APPEND _rpmbuild_with_args --with ccache)
3722         endif()
3723         if(NOT BUILD_wireshark)
3724                 list(APPEND _rpmbuild_with_args --without qt5 --without qt6)
3725         elseif(USE_qt6)
3726                 list(APPEND _rpmbuild_with_args --without qt5 --with qt6)
3727         else()
3728                 list(APPEND _rpmbuild_with_args --with qt5 --without qt6)
3729         endif()
3730         if (MAXMINDDB_FOUND)
3731                 list(APPEND _rpmbuild_with_args --with mmdbresolve)
3732         endif()
3733         if (LUA_FOUND)
3734                 list(APPEND _rpmbuild_with_args --with lua)
3735         endif()
3736         if (LZ4_FOUND AND SNAPPY_FOUND)
3737                 list(APPEND _rpmbuild_with_args --with lz4_and_snappy)
3738         endif()
3739         if (SPANDSP_FOUND)
3740                 list(APPEND _rpmbuild_with_args --with spandsp)
3741         endif()
3742         if (BCG729_FOUND)
3743                 list(APPEND _rpmbuild_with_args --with bcg729)
3744         endif()
3745         if (AMRNB_FOUND)
3746                 list(APPEND _rpmbuild_with_args --with amrnb)
3747         endif()
3748         if (ILBC_FOUND)
3749                 list(APPEND _rpmbuild_with_args --with ilbc)
3750         endif()
3751         if (OPUS_FOUND)
3752                 list(APPEND _rpmbuild_with_args --with opus)
3753         endif()
3754         if (LIBXML2_FOUND)
3755                 list(APPEND _rpmbuild_with_args --with libxml2)
3756         endif()
3757         if (NGHTTP2_FOUND)
3758                 list(APPEND _rpmbuild_with_args --with nghttp2)
3759         endif()
3760         if (SYSTEMD_FOUND)
3761                 list(APPEND _rpmbuild_with_args --with sdjournal)
3762         endif()
3763         if (BROTLI_FOUND)
3764                 list(APPEND _rpmbuild_with_args --with brotli)
3765         endif()
3766
3767         execute_process(
3768                 COMMAND ${Python3_EXECUTABLE}
3769                         ${CMAKE_SOURCE_DIR}/tools/make-version.py
3770                         ${CMAKE_SOURCE_DIR}
3771         )
3772
3773         add_custom_target(copy-dist
3774                 COMMAND cp ${CMAKE_BINARY_DIR}/wireshark*tar* ${CMAKE_BINARY_DIR}/packaging/rpm/SOURCES/
3775                 DEPENDS dist
3776         )
3777         add_custom_target(wireshark_rpm
3778                 COMMAND ${RPMBUILD_EXECUTABLE}
3779                         --define "_topdir ${CMAKE_BINARY_DIR}/packaging/rpm"
3780                         --define "_prefix ${CMAKE_INSTALL_PREFIX}"
3781                         ${_rpmbuild_with_args}
3782                         -ba SPECS/wireshark.spec
3783                 DEPENDS copy-dist
3784                 WORKING_DIRECTORY "${CMAKE_BINARY_DIR}/packaging/rpm"
3785                 COMMENT "Create a rpm from the current git commit."
3786         )
3787 endif()
3788
3789 if(BUILD_wireshark AND QT_FOUND AND LINUXDEPLOY_EXECUTABLE AND _linuxdeploy_plugin_qt AND APPIMAGETOOL_EXECUTABLE)
3790         configure_file(packaging/appimage/Wireshark-AppRun.in ${CMAKE_BINARY_DIR}/packaging/appimage/Wireshark-AppRun @ONLY)
3791         # Require production builds (/usr + Release).
3792         if (CMAKE_BUILD_TYPE STREQUAL "Release" AND CMAKE_INSTALL_PREFIX STREQUAL "/usr" )
3793                 add_custom_target(wireshark_appimage_prerequisites)
3794                 add_dependencies(wireshark_appimage_prerequisites ${PROGLIST})
3795         else()
3796                 add_custom_target(wireshark_appimage_prerequisites
3797                         COMMAND echo "CMAKE_BUILD_TYPE isn't Release or CMAKE_INSTALL_PREFIX isn't /usr."
3798                         COMMAND false
3799                 )
3800         endif()
3801         set (_wireshark_ai_appdir ${CMAKE_BINARY_DIR}/packaging/appimage/wireshark.appdir)
3802         add_custom_target(wireshark_appimage_appdir
3803                 COMMAND ${CMAKE_COMMAND} -E make_directory ${_wireshark_ai_appdir}
3804                 COMMAND env DESTDIR=${_wireshark_ai_appdir}
3805                         ${CMAKE_COMMAND} --build . --target install
3806                 DEPENDS wireshark_appimage_prerequisites
3807         )
3808         set(_wireshark_appimage_exe_args)
3809         foreach(_prog ${PROGLIST})
3810                 # XXX This needs to be more robust.
3811                 if (${_prog} STREQUAL "dftest" OR ${_prog} STREQUAL "logray")
3812                         continue()
3813                 endif()
3814                 list(APPEND _wireshark_appimage_exe_args --executable=${_wireshark_ai_appdir}/usr/bin/${_prog})
3815         endforeach()
3816         # It looks like linuxdeploy can't handle executables in nonstandard
3817         # locations, so use it to prep our staging directory here and use
3818         # appimagetool to to build the appimage.
3819         add_custom_target(wireshark_appimage_prep
3820                 COMMAND env LD_LIBRARY_PATH=${_wireshark_ai_appdir}/${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR} ${LINUXDEPLOY_EXECUTABLE}
3821                         --appdir=${_wireshark_ai_appdir}
3822                         ${_wireshark_appimage_exe_args}
3823                         --desktop-file=${_wireshark_ai_appdir}/usr/share/applications/org.wireshark.Wireshark.desktop
3824                         --icon-file=${CMAKE_SOURCE_DIR}/resources/icons/wsicon256.png
3825                         --custom-apprun=${CMAKE_BINARY_DIR}/packaging/appimage/Wireshark-AppRun
3826                         --plugin=qt
3827                 DEPENDS wireshark_appimage_appdir
3828         )
3829         add_custom_target(wireshark_appimage
3830                 COMMAND env VERSION=${PROJECT_VERSION} ${APPIMAGETOOL_EXECUTABLE} ${_wireshark_ai_appdir}
3831                 DEPENDS wireshark_appimage_prep
3832         )
3833 endif()
3834
3835 if(BUILD_logray AND QT_FOUND AND LINUXDEPLOY_EXECUTABLE AND _linuxdeploy_plugin_qt AND APPIMAGETOOL_EXECUTABLE)
3836         configure_file(packaging/appimage/Logray-AppRun.in ${CMAKE_BINARY_DIR}/packaging/appimage/Logray-AppRun @ONLY)
3837         # Require production builds (/usr + Release).
3838         if (CMAKE_BUILD_TYPE STREQUAL "Release" AND CMAKE_INSTALL_PREFIX STREQUAL "/usr" )
3839                 add_custom_target(logray_appimage_prerequisites)
3840                 add_dependencies(logray_appimage_prerequisites ${PROGLIST})
3841         else()
3842                 add_custom_target(logray_appimage_prerequisites
3843                         COMMAND echo "CMAKE_BUILD_TYPE isn't Release or CMAKE_INSTALL_PREFIX isn't /usr."
3844                         COMMAND false
3845                 )
3846         endif()
3847         set (_logray_ai_appdir ${CMAKE_BINARY_DIR}/packaging/appimage/logray.appdir)
3848         add_custom_target(logray_appimage_appdir
3849                 COMMAND ${CMAKE_COMMAND} -E make_directory ${_logray_ai_appdir}
3850                 COMMAND env DESTDIR=${_logray_ai_appdir}
3851                         ${CMAKE_COMMAND} --build . --target install
3852                 DEPENDS logray_appimage_prerequisites
3853         )
3854         set(_logray_appimage_exe_args)
3855         foreach(_prog ${PROGLIST})
3856                 # XXX This needs to be more robust.
3857                 if (${_prog} STREQUAL "dftest" OR ${_prog} STREQUAL "logray")
3858                         continue()
3859                 endif()
3860                 list(APPEND _logray_appimage_exe_args --executable=${_logray_ai_appdir}/usr/bin/${_prog})
3861         endforeach()
3862         # It looks like linuxdeploy can't handle executables in nonstandard
3863         # locations, so use it to prep our staging directory here and use
3864         # appimagetool to to build the appimage.
3865         add_custom_target(logray_appimage_prep
3866                 COMMAND env LD_LIBRARY_PATH=${_logray_ai_appdir}/${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR} ${LINUXDEPLOY_EXECUTABLE}
3867                         --appdir=${_logray_ai_appdir}
3868                         ${_logray_appimage_exe_args}
3869                         --desktop-file=${_logray_ai_appdir}/usr/share/applications/org.wireshark.Logray.desktop
3870                         --icon-file=${CMAKE_SOURCE_DIR}/resources/icons/lricon256.png
3871                         --custom-apprun=${CMAKE_BINARY_DIR}/packaging/appimage/Logray-AppRun
3872                         --plugin=qt
3873                 DEPENDS logray_appimage_appdir
3874         )
3875         add_custom_target(logray_appimage
3876                 COMMAND env VERSION=${LOG_PROJECT_VERSION} ${APPIMAGETOOL_EXECUTABLE} ${_logray_ai_appdir}
3877                 DEPENDS logray_appimage_prep
3878         )
3879 endif()
3880
3881 set(CLEAN_C_FILES
3882         ${dumpcap_FILES}
3883         ${wireshark_FILES}
3884         ${logray_FILES}
3885         ${tshark_FILES}
3886         ${tfshark_FILES}
3887         ${rawshark_FILES}
3888         ${dftest_FILES}
3889         ${randpkt_FILES}
3890         ${randpktdump_FILES}
3891         ${etwdump_FILES}
3892         ${falcodump_FILES}
3893         ${udpdump_FILES}
3894         ${text2pcap_FILES}
3895         ${mergecap_FILES}
3896         ${capinfos_FILES}
3897         ${captype_FILES}
3898         ${editcap_FILES}
3899         ${idl2wrs_FILES}
3900         ${mmdbresolve_FILES}
3901         ${sharkd_FILES}
3902 )
3903
3904 if(CLEAN_C_FILES)
3905         # Make sure we don't pass /WX to rc.exe. Rc doesn't have a /WX flag,
3906         # but it does have /W (warn about invalid code pages) and /X (ignore
3907         # the INCLUDE environment variable).
3908         # This should apparently be handled for us via CMAKE_RC_FLAG_REGEX
3909         # in CMakeRCInformation.cmake but that doesn't appear to work.
3910         if(WIN32)
3911                 list(FILTER CLEAN_C_FILES EXCLUDE REGEX ".*\\.rc")
3912         endif()
3913
3914         # XXX This also contains object files ($<TARGET_OBJECTS:...>), is that an issue?
3915         set_source_files_properties(
3916                 ${CLEAN_C_FILES}
3917                 PROPERTIES
3918                 COMPILE_FLAGS "${WERROR_COMMON_FLAGS}"
3919         )
3920 endif()
3921
3922 install(
3923         FILES
3924                 ${INSTALL_FILES}
3925         PERMISSIONS
3926                 OWNER_WRITE OWNER_READ
3927                 GROUP_READ
3928                 WORLD_READ
3929         DESTINATION
3930                 ${CMAKE_INSTALL_DATADIR}
3931 )
3932
3933 install(
3934         FILES
3935                 ${DOC_FILES}
3936         DESTINATION
3937                 ${CMAKE_INSTALL_DOCDIR}
3938 )
3939
3940 if(ASCIIDOCTOR_FOUND AND XSLTPROC_EXECUTABLE)
3941         install(
3942                 DIRECTORY "${CMAKE_BINARY_DIR}/docbook/wsug_html_chunked"
3943                 DESTINATION "${CMAKE_INSTALL_DOCDIR}"
3944                 COMPONENT "UserGuide"
3945                 EXCLUDE_FROM_ALL
3946         )
3947         install(
3948                 DIRECTORY "${CMAKE_BINARY_DIR}/docbook/wsdg_html_chunked"
3949                 DESTINATION "${CMAKE_INSTALL_DOCDIR}"
3950                 COMPONENT "DeveloperGuide"
3951                 EXCLUDE_FROM_ALL
3952         )
3953 endif()
3954
3955 set(SHARK_PUBLIC_HEADERS
3956         cfile.h
3957         cli_main.h
3958         file.h
3959         include/ws_attributes.h
3960         include/ws_codepoints.h
3961         include/ws_compiler_tests.h
3962         include/ws_diag_control.h
3963         include/ws_exit_codes.h
3964         include/ws_log_defs.h
3965         include/ws_posix_compat.h
3966         include/ws_symbol_export.h
3967         include/wireshark.h
3968         ${CMAKE_BINARY_DIR}/ws_version.h
3969 )
3970
3971 install(FILES ${SHARK_PUBLIC_HEADERS}
3972         DESTINATION ${PROJECT_INSTALL_INCLUDEDIR}
3973         COMPONENT "Development"
3974         EXCLUDE_FROM_ALL
3975 )
3976
3977 # Install icons and other desktop files for Freedesktop.org-compliant desktops.
3978 if(BUILD_wireshark AND QT_FOUND AND NOT APPLE AND (NOT WIN32 OR USE_MSYSTEM))
3979         install(FILES resources/freedesktop/org.wireshark.Wireshark-mime.xml
3980                 DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/mime/packages"
3981                 RENAME org.wireshark.Wireshark.xml
3982         )
3983         install(FILES resources/freedesktop/org.wireshark.Wireshark.metainfo.xml
3984                 DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/metainfo"
3985         )
3986         if(BUILD_wireshark AND QT_FOUND)
3987                 install(FILES resources/freedesktop/org.wireshark.Wireshark.desktop
3988                         DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/applications")
3989         endif()
3990         foreach(size 16 24 32 48 64 128 256)
3991                 install(FILES resources/icons/wsicon${size}.png
3992                         DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/${size}x${size}/apps"
3993                         RENAME org.wireshark.Wireshark.png)
3994                 install(FILES resources/icons/WiresharkDoc-${size}.png
3995                         DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/${size}x${size}/mimetypes"
3996                         RENAME org.wireshark.Wireshark-mimetype.png)
3997         endforeach()
3998 endif()
3999
4000 if(BUILD_logray AND QT_FOUND AND NOT APPLE AND (NOT WIN32 OR USE_MSYSTEM))
4001         install(FILES resources/freedesktop/org.wireshark.Logray-mime.xml
4002                 DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/mime/packages"
4003                 RENAME org.wireshark.Logray.xml
4004         )
4005         install(FILES resources/freedesktop/org.wireshark.Logray.metainfo.xml
4006                 DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/metainfo"
4007         )
4008         if(BUILD_wireshark AND QT_FOUND)
4009                 install(FILES resources/freedesktop/org.wireshark.Logray.desktop
4010                         DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/applications")
4011         endif()
4012         foreach(size 16 32 48 64 128 256)
4013                 install(FILES resources/icons/lricon${size}.png
4014                         DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/${size}x${size}/apps"
4015                         RENAME org.wireshark.Logray.png)
4016                 install(FILES resources/icons/WiresharkDoc-${size}.png
4017                         DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/${size}x${size}/mimetypes"
4018                         RENAME org.wireshark.Logray-mimetype.png)
4019         endforeach()
4020         install(FILES resources/icons/lricon.svg
4021                 DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/scalable/apps"
4022                 RENAME org.wireshark.Logray.svg)
4023 endif()
4024
4025 install(
4026         FILES
4027                 "${CMAKE_BINARY_DIR}/wireshark.pc"
4028         DESTINATION
4029                 ${CMAKE_INSTALL_LIBDIR}/pkgconfig
4030         COMPONENT
4031                 "Development"
4032         EXCLUDE_FROM_ALL
4033 )
4034
4035 install(
4036         DIRECTORY
4037                 ${INSTALL_DIRS}
4038         DESTINATION
4039                 ${CMAKE_INSTALL_DATADIR}
4040         FILE_PERMISSIONS
4041                 OWNER_WRITE OWNER_READ
4042                 GROUP_READ
4043                 WORLD_READ
4044         DIRECTORY_PERMISSIONS
4045                 OWNER_EXECUTE OWNER_WRITE OWNER_READ
4046                 GROUP_EXECUTE GROUP_READ
4047                 WORLD_EXECUTE WORLD_READ
4048         PATTERN ".git" EXCLUDE
4049         PATTERN ".svn" EXCLUDE
4050         PATTERN "Makefile.*" EXCLUDE
4051 )
4052
4053 if(WIN32 AND NOT USE_MSYSTEM)
4054         # Note: CMake export mechanism misbehaves with a '.' in the
4055         # path (incorrect relative path computation).
4056         set(WIRESHARK_INSTALL_CMAKEDIR "cmake")
4057 else()
4058         set(WIRESHARK_INSTALL_CMAKEDIR "${CMAKE_INSTALL_LIBDIR}/${PROJECT_NAME}/cmake")
4059 endif()
4060
4061 include(CMakePackageConfigHelpers)
4062
4063 configure_package_config_file(WiresharkConfig.cmake.in
4064         ${CMAKE_BINARY_DIR}/WiresharkConfig.cmake
4065         INSTALL_DESTINATION ${WIRESHARK_INSTALL_CMAKEDIR}
4066         PATH_VARS
4067                 CMAKE_INSTALL_LIBDIR
4068                 CMAKE_INSTALL_INCLUDEDIR
4069                 PLUGIN_INSTALL_VERSION_LIBDIR
4070                 EXTCAP_INSTALL_LIBDIR
4071 )
4072
4073 write_basic_package_version_file(
4074         ${CMAKE_BINARY_DIR}/WiresharkConfigVersion.cmake
4075         COMPATIBILITY AnyNewerVersion
4076 )
4077
4078 install(
4079         FILES
4080                 ${CMAKE_BINARY_DIR}/WiresharkConfig.cmake
4081                 ${CMAKE_BINARY_DIR}/WiresharkConfigVersion.cmake
4082         DESTINATION
4083                 ${WIRESHARK_INSTALL_CMAKEDIR}
4084         COMPONENT
4085                 "Development"
4086         EXCLUDE_FROM_ALL
4087 )
4088
4089 install(EXPORT WiresharkTargets
4090         DESTINATION ${WIRESHARK_INSTALL_CMAKEDIR}
4091         COMPONENT "Development"
4092         EXCLUDE_FROM_ALL
4093 )
4094
4095 # This isn't strictly needed but it makes working around debhelper's
4096 # cleverness a lot easier.
4097 add_custom_target(install-headers
4098         COMMAND ${CMAKE_COMMAND} -DCOMPONENT=Development -P cmake_install.cmake
4099 )
4100
4101 if (DOXYGEN_EXECUTABLE)
4102         # API reference
4103         # We don't have a good way of tracking dependencies, so we simply
4104         # recreate the whole thing from scratch each time.
4105         add_custom_target(wsar_html
4106                 COMMAND ${CMAKE_COMMAND} -E remove_directory wsar_html
4107                 COMMAND ${DOXYGEN_EXECUTABLE} doxygen.cfg
4108         )
4109
4110         if(WIN32 AND NOT USE_MSYSTEM)
4111                 add_custom_target(wsar_html_perms DEPENDS wsar_html)
4112         else()
4113                 add_custom_target(wsar_html_perms
4114                         COMMAND find wsar_html
4115                                 -type d
4116                                 -exec chmod 755 "{}" +
4117                         COMMAND find wsar_html
4118                                 -type f
4119                                 -exec chmod 644 "{}" +
4120                         DEPENDS wsar_html)
4121         endif()
4122
4123         add_custom_target(wsar_html_zip
4124                 COMMAND ${CMAKE_COMMAND} -E tar "cfv" "wsar_html.zip" --format=zip wsar_html
4125                 DEPENDS wsar_html_perms
4126         )
4127         set_target_properties(wsar_html wsar_html_zip PROPERTIES
4128                 FOLDER "Documentation"
4129                 EXCLUDE_FROM_DEFAULT_BUILD True
4130         )
4131 endif(DOXYGEN_EXECUTABLE)
4132
4133 add_custom_target(test-programs
4134         DEPENDS exntest
4135                 fifo_string_cache_test
4136                 oids_test
4137                 reassemble_test
4138                 tvbtest
4139                 wmem_test
4140                 wscbor_test
4141                 test_epan
4142                 test_wsutil
4143         COMMENT "Building unit test programs and wrapper"
4144 )
4145 set_target_properties(test-programs PROPERTIES
4146         FOLDER "Tests"
4147         EXCLUDE_FROM_DEFAULT_BUILD True
4148 )
4149
4150 # Add target to enable capturing from the build directory. Requires Linux capabilities
4151 # and running with sudo.
4152 if(TARGET dumpcap AND SETCAP_EXECUTABLE)
4153         add_custom_target(test-capture
4154                 COMMAND ${SETCAP_EXECUTABLE} cap_net_raw,cap_net_admin+ep $<TARGET_FILE:dumpcap>
4155         )
4156 endif()
4157
4158 add_custom_target(test
4159         COMMAND ${CMAKE_COMMAND} -E env PYTHONIOENCODING=UTF-8
4160                 ${Python3_EXECUTABLE} -m pytest
4161         WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
4162         DEPENDS test-programs
4163         USES_TERMINAL
4164 )
4165
4166 # Make it possible to run pytest without passing the full path as argument.
4167 if(NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR)
4168         file(READ "${CMAKE_CURRENT_SOURCE_DIR}/pytest.ini" pytest_ini)
4169         string(REGEX REPLACE "\naddopts = ([^\n]+)"
4170                 "\naddopts = ${CMAKE_CURRENT_SOURCE_DIR}/test \\1"
4171                 pytest_ini "${pytest_ini}")
4172         file(WRITE "${CMAKE_BINARY_DIR}/pytest.ini" "${pytest_ini}")
4173 endif()
4174
4175 if (GIT_EXECUTABLE)
4176         # Update AUTHORS file with entries from git shortlog
4177         add_custom_target(
4178                 gen-authors
4179                 COMMAND ${Python3_EXECUTABLE} tools/generate_authors.py AUTHORS
4180                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
4181         )
4182 else (GIT_EXECUTABLE)
4183         add_custom_target( gen-authors COMMAND ${CMAKE_COMMAND} -E echo "Git not found." )
4184 endif (GIT_EXECUTABLE)
4185 set_target_properties(gen-authors PROPERTIES FOLDER "Documentation")
4186
4187 if(WIN32 AND NOT USE_MSYSTEM)
4188         file (TO_NATIVE_PATH ${CMAKE_SOURCE_DIR}/tools/Get-HardenFlags.ps1 _win_harden_flags)
4189         add_custom_target(hardening-check
4190                 COMMAND ${POWERSHELL_COMMAND} "${_win_harden_flags}" "${_dll_output_dir_win}"
4191                 DEPENDS ${PROGLIST}
4192                 COMMENT "Checking binaries for security features"
4193         )
4194         set_target_properties(hardening-check PROPERTIES FOLDER "Tests")
4195 else()
4196         find_program(HARDENING_CHECK_EXECUTABLE hardening-check
4197                 DOC "Path to the hardening-check utility."
4198         )
4199         if(HARDENING_CHECK_EXECUTABLE)
4200                 foreach(_prog ${PROGLIST})
4201                         get_target_property(_prog_dir ${_prog} RUNTIME_OUTPUT_DIRECTORY)
4202                         if(NOT _prog_dir)
4203                                 set(_prog_dir "${CMAKE_BINARY_DIR}/run")
4204                         endif()
4205                         set(_prog_paths ${_prog_paths} "${_prog_dir}/${_prog}")
4206                 endforeach()
4207                 add_custom_target(hardening-check
4208                         COMMAND ${HARDENING_CHECK_EXECUTABLE} ${_prog_paths}
4209                         DEPENDS ${PROGLIST}
4210                         COMMENT "Checking binaries for security features"
4211                 )
4212         endif()
4213 endif()
4214
4215 CHECKAPI(
4216         NAME
4217           main
4218         SWITCHES
4219         SOURCES
4220           ${WIRESHARK_SRC}
4221           ${TSHARK_TAP_SRC}
4222 )
4223
4224 find_program(SHELLCHECK_EXECUTABLE shellcheck
4225         DOC "Path to the shellcheck utility."
4226 )
4227 if(SHELLCHECK_EXECUTABLE)
4228         add_custom_target(shellcheck)
4229         set_target_properties(shellcheck PROPERTIES FOLDER "Tests")
4230         # --external-sources requires 0.4.0 or later.
4231         # ChmodBPF uses "shellcheck shell=bash". Not sure which version
4232         # added support for that.
4233         add_custom_command(TARGET shellcheck POST_BUILD
4234                 COMMAND shellcheck --external-sources
4235                         resources/stock_icons/svg-to-png.sh
4236                         packaging/appimage/Logray-AppRun.in
4237                         packaging/appimage/Wireshark-AppRun.in
4238                         "packaging/macosx/ChmodBPF/root/Library/Application Support/Wireshark/ChmodBPF/ChmodBPF"
4239                         packaging/macosx/osx-app.sh.in
4240                         packaging/macosx/osx-dmg.sh.in
4241                         packaging/source/git-export-release.sh.in
4242                         tools/debian-setup.sh
4243                         tools/fuzz-test.sh
4244                         tools/gen-bugnote
4245                         tools/pre-commit
4246                         tools/randpkt-test.sh
4247                         tools/release-update-debian-soversions.sh
4248                         tools/test-captures.sh
4249                         tools/update-tx
4250                         tools/valgrind-wireshark.sh
4251                 WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}"
4252         )
4253 endif()
4254
4255 # uninstall target
4256 configure_file(
4257         "${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake.in"
4258         "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
4259         IMMEDIATE @ONLY)
4260
4261 add_custom_target(uninstall
4262         COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
4263
4264 # Break on programmer errors when debugging in Visual Studio
4265 if(MSVC)
4266         get_property(_targets DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR} PROPERTY BUILDSYSTEM_TARGETS)
4267         foreach(_target ${_targets})
4268                 set_target_properties(${_target} PROPERTIES VS_DEBUGGER_ENVIRONMENT "G_DEBUG=fatal-criticals")
4269         endforeach()
4270 endif()
4271
4272 #
4273 # Editor modelines  -  https://www.wireshark.org/tools/modelines.html
4274 #
4275 # Local variables:
4276 # c-basic-offset: 8
4277 # tab-width: 8
4278 # indent-tabs-mode: t
4279 # End:
4280 #
4281 # vi: set shiftwidth=8 tabstop=8 noexpandtab:
4282 # :indentSize=8:tabSize=8:noTabs=false:
4283 #