configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.1.3dev],[http://rsync.samba.org/bugzilla.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_EGREP
  45 AC_PROG_INSTALL
  46 AC_PROG_MKDIR_P
  47 AC_PROG_CC_STDC
  48 AC_SUBST(SHELL)
  49 AC_PATH_PROG([PERL], [perl])
  50
  51 AC_DEFINE([_GNU_SOURCE], 1,
  52           [Define _GNU_SOURCE so that we get all necessary prototypes])
  53
  54 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  55         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  56 fi
  57
  58 AC_ARG_ENABLE(profile,
  59         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  60 if test x"$enable_profile" = x"yes"; then
  61         CFLAGS="$CFLAGS -pg"
  62 fi
  63
  64
  65 # Specifically, this turns on panic_action handling.
  66 AC_ARG_ENABLE(maintainer-mode,
  67         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
  68 if test x"$enable_maintainer_mode" = x"yes"; then
  69         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  70 fi
  71
  72
  73 # This is needed for our included version of popt.  Kind of silly, but
  74 # I don't want our version too far out of sync.
  75 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  76
  77 # If GCC, turn on warnings.
  78 if test x"$GCC" = x"yes"; then
  79         CFLAGS="$CFLAGS -Wall -W"
  80 fi
  81
  82 AC_ARG_WITH(included-popt,
  83         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
  84
  85 AC_ARG_WITH(included-zlib,
  86         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
  87
  88 AC_ARG_WITH(protected-args,
  89         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
  90 if test x"$with_protected_args" = x"yes"; then
  91         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
  92 fi
  93
  94 AC_ARG_WITH(rsync-path,
  95         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
  96         [ RSYNC_PATH="$with_rsync_path" ],
  97         [ RSYNC_PATH="rsync" ])
  98
  99 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 100
 101 AC_ARG_WITH(rsyncd-conf,
 102         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 103         [ if test ! -z "$with_rsyncd_conf" ; then
 104                 case $with_rsyncd_conf in
 105                         yes|no)
 106                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 107                                 ;;
 108                         /*)
 109                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 110                                 ;;
 111                         *)
 112                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 113                                 ;;
 114                 esac
 115         else
 116                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 117         fi ],
 118         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 119
 120 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 121
 122 AC_ARG_WITH(rsh,
 123         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 124
 125 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 126 if test x$HAVE_REMSH = x1; then
 127         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 128 fi
 129
 130 if test x"$with_rsh" != x; then
 131         RSYNC_RSH="$with_rsh"
 132 else
 133         RSYNC_RSH="ssh"
 134 fi
 135 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 136
 137 AC_CHECK_PROG(HAVE_YODL2MAN, yodl2man, 1, 0)
 138 if test x$HAVE_YODL2MAN = x1; then
 139     MAKE_MAN=man
 140 else
 141     MAKE_MAN=man-copy
 142 fi
 143
 144 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 145 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 146 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 147
 148 AC_ARG_WITH(nobody-group,
 149     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 150     [ NOBODY_GROUP="$with_nobody_group" ])
 151
 152 if test x"$with_nobody_group" = x; then
 153     AC_MSG_CHECKING([the group for user "nobody"])
 154     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 155         NOBODY_GROUP=nobody
 156     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 157         NOBODY_GROUP=nogroup
 158     else
 159         NOBODY_GROUP=nobody # test for others?
 160     fi
 161     AC_MSG_RESULT($NOBODY_GROUP)
 162 fi
 163
 164 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 165 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 166
 167 # arrgh. libc in some old debian version screwed up the largefile
 168 # stuff, getting byte range locking wrong
 169 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 170 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 171 #define _FILE_OFFSET_BITS 64
 172 #include <stdio.h>
 173 #include <fcntl.h>
 174 #include <sys/types.h>
 175 #include <sys/wait.h>
 176
 177 int main(void)
 178 {
 179         struct flock lock;
 180         int status;
 181         char tpl[32] = "/tmp/locktest.XXXXXX";
 182         int fd = mkstemp(tpl);
 183         if (fd < 0) {
 184                 strcpy(tpl, "conftest.dat");
 185                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 186         }
 187
 188         lock.l_type = F_WRLCK;
 189         lock.l_whence = SEEK_SET;
 190         lock.l_start = 0;
 191         lock.l_len = 1;
 192         lock.l_pid = 0;
 193         fcntl(fd,F_SETLK,&lock);
 194         if (fork() == 0) {
 195                 lock.l_start = 1;
 196                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 197         }
 198         wait(&status);
 199         unlink(tpl);
 200         exit(WEXITSTATUS(status));
 201 }
 202 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 203 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 204    AC_SYS_LARGEFILE
 205 fi
 206
 207 ipv6type=unknown
 208 ipv6lib=none
 209 ipv6trylibc=yes
 210
 211 AC_ARG_ENABLE(ipv6,
 212         AS_HELP_STRING([--disable-ipv6],[do not even try to use IPv6]))
 213 if test x"$enable_ipv6" != x"no"; then
 214         AC_MSG_CHECKING([ipv6 stack type])
 215         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 216                 case $i in
 217                 inria)
 218                         # http://www.kame.net/
 219                         AC_EGREP_CPP(yes, [
 220 #include <netinet/in.h>
 221 #ifdef IPV6_INRIA_VERSION
 222 yes
 223 #endif],
 224                                 [ipv6type=$i;
 225                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 226                                 ])
 227                         ;;
 228                 kame)
 229                         # http://www.kame.net/
 230                         AC_EGREP_CPP(yes, [
 231 #include <netinet/in.h>
 232 #ifdef __KAME__
 233 yes
 234 #endif],
 235                                 [ipv6type=$i;
 236                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 237                         ;;
 238                 linux-glibc)
 239                         # http://www.v6.linux.or.jp/
 240                         AC_EGREP_CPP(yes, [
 241 #include <features.h>
 242 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 243 yes
 244 #endif],
 245                                 [ipv6type=$i;
 246 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 247                         ;;
 248                 linux-inet6)
 249                         # http://www.v6.linux.or.jp/
 250                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 251                                 ipv6type=$i
 252                                 ipv6lib=inet6
 253                                 ipv6libdir=/usr/inet6/lib
 254                                 ipv6trylibc=yes;
 255                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 256                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 257                         fi
 258                         ;;
 259                 solaris)
 260                         # http://www.sun.com
 261                         AC_EGREP_CPP(yes, [
 262 #include <netinet/ip6.h>
 263 #ifdef __sun
 264 yes
 265 #endif],
 266                                 [ipv6type=$i;
 267                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 268                         ;;
 269                 toshiba)
 270                         AC_EGREP_CPP(yes, [
 271 #include <sys/param.h>
 272 #ifdef _TOSHIBA_INET6
 273 yes
 274 #endif],
 275                                 [ipv6type=$i;
 276                                 ipv6lib=inet6;
 277                                 ipv6libdir=/usr/local/v6/lib;
 278                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 279                         ;;
 280                 v6d)
 281                         AC_EGREP_CPP(yes, [
 282 #include </usr/local/v6/include/sys/v6config.h>
 283 #ifdef __V6D__
 284 yes
 285 #endif],
 286                                 [ipv6type=$i;
 287                                 ipv6lib=v6;
 288                                 ipv6libdir=/usr/local/v6/lib;
 289                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 290                         ;;
 291                 zeta)
 292                         AC_EGREP_CPP(yes, [
 293 #include <sys/param.h>
 294 #ifdef _ZETA_MINAMI_INET6
 295 yes
 296 #endif],
 297                                 [ipv6type=$i;
 298                                 ipv6lib=inet6;
 299                                 ipv6libdir=/usr/local/v6/lib;
 300                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 301                         ;;
 302                 cygwin)
 303                         AC_EGREP_CPP(yes, [
 304 #include <netinet/in.h>
 305 #ifdef _CYGWIN_IN6_H
 306 yes
 307 #endif],
 308                                 [ipv6type=$i;
 309                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 310                         ;;
 311                 esac
 312                 if test "$ipv6type" != "unknown"; then
 313                         break
 314                 fi
 315         done
 316         AC_MSG_RESULT($ipv6type)
 317
 318         AC_SEARCH_LIBS(getaddrinfo, inet6)
 319 fi
 320
 321 dnl Do you want to disable use of locale functions
 322 AC_ARG_ENABLE([locale],
 323         AS_HELP_STRING([--disable-locale],[disable locale features]))
 324 AH_TEMPLATE([CONFIG_LOCALE],
 325 [Undefine if you do not want locale features.  By default this is defined.])
 326 if test x"$enable_locale" != x"no"; then
 327         AC_DEFINE(CONFIG_LOCALE)
 328 fi
 329
 330 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 331 case $host_os in
 332         *cygwin* ) AC_MSG_RESULT(yes)
 333                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 334                             [Define to 1 if sockets need to be shutdown])
 335                    ;;
 336                * ) AC_MSG_RESULT(no);;
 337 esac
 338
 339 AC_C_BIGENDIAN
 340 AC_HEADER_DIRENT
 341 AC_HEADER_TIME
 342 AC_HEADER_SYS_WAIT
 343 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 344     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 345     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 346     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 347     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 348     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 349     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 350     zlib.h)
 351 AC_HEADER_MAJOR
 352
 353 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 354 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 355 #include <sys/types.h>
 356 #ifdef MAJOR_IN_MKDEV
 357 #include <sys/mkdev.h>
 358 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 359 #  define makedev mkdev
 360 # endif
 361 #elif defined MAJOR_IN_SYSMACROS
 362 #include <sys/sysmacros.h>
 363 #endif
 364
 365 int main(void)
 366 {
 367         dev_t dev = makedev(0, 5, 7);
 368         if (major(dev) != 5 || minor(dev) != 7)
 369                 exit(1);
 370         return 0;
 371 }
 372 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 373 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 374    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 375 fi
 376
 377 AC_CHECK_SIZEOF(int)
 378 AC_CHECK_SIZEOF(long)
 379 AC_CHECK_SIZEOF(long long)
 380 AC_CHECK_SIZEOF(short)
 381 AC_CHECK_SIZEOF(int16_t)
 382 AC_CHECK_SIZEOF(uint16_t)
 383 AC_CHECK_SIZEOF(int32_t)
 384 AC_CHECK_SIZEOF(uint32_t)
 385 AC_CHECK_SIZEOF(int64_t)
 386 AC_CHECK_SIZEOF(off_t)
 387 AC_CHECK_SIZEOF(off64_t)
 388 AC_CHECK_SIZEOF(time_t)
 389
 390 AC_C_INLINE
 391
 392 AC_TYPE_LONG_DOUBLE_WIDER
 393 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 394 if test $ac_cv_c_long_double = yes; then
 395   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 396 fi
 397
 398 AC_TYPE_UID_T
 399 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 400 AC_TYPE_GETGROUPS
 401 AC_CHECK_MEMBERS([struct stat.st_rdev,
 402                   struct stat.st_mtimensec,
 403                   struct stat.st_mtim.tv_nsec],,,[
 404 #ifdef HAVE_SYS_TYPES_H
 405 #include <sys/types.h>
 406 #endif
 407 #ifdef HAVE_SYS_STAT_H
 408 #include <sys/stat.h>
 409 #endif
 410 #ifdef HAVE_UNISTD_H
 411 #include <unistd.h>
 412 #endif])
 413
 414 TYPE_SOCKLEN_T
 415
 416 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 417     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 418 if test x"$rsync_cv_errno" = x"yes"; then
 419    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 420 fi
 421
 422 # The following test taken from the cvs sources
 423 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 424 # These need checks to be before checks for any other functions that
 425 #    might be in the same libraries.
 426 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 427 # libsocket.so which has a bad implementation of gethostbyname (it
 428 # only looks in /etc/hosts), so we only look for -lsocket if we need
 429 # it.
 430 AC_CHECK_FUNCS(connect)
 431 if test x"$ac_cv_func_connect" = x"no"; then
 432     case "$LIBS" in
 433     *-lnsl*) ;;
 434     *) AC_CHECK_LIB(nsl_s, printf) ;;
 435     esac
 436     case "$LIBS" in
 437     *-lnsl*) ;;
 438     *) AC_CHECK_LIB(nsl, printf) ;;
 439     esac
 440     case "$LIBS" in
 441     *-lsocket*) ;;
 442     *) AC_CHECK_LIB(socket, connect) ;;
 443     esac
 444     case "$LIBS" in
 445     *-linet*) ;;
 446     *) AC_CHECK_LIB(inet, connect) ;;
 447     esac
 448     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 449     dnl has been cached.
 450     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 451        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 452         # ac_cv_func_connect=yes
 453         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 454         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 455     fi
 456 fi
 457
 458 AC_SEARCH_LIBS(inet_ntop, resolv)
 459
 460 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 461 # accept either iconv_open or libiconv_open, since some include files map
 462 # the former to the latter.
 463 AC_SEARCH_LIBS(iconv_open, iconv)
 464 AC_SEARCH_LIBS(libiconv_open, iconv)
 465
 466 AC_MSG_CHECKING([for iconv declaration])
 467 AC_CACHE_VAL(am_cv_proto_iconv, [
 468     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 469 #include <stdlib.h>
 470 #include <iconv.h>
 471 extern
 472 #ifdef __cplusplus
 473 "C"
 474 #endif
 475 #if defined(__STDC__) || defined(__cplusplus)
 476 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 477 #else
 478 size_t iconv();
 479 #endif
 480 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 481       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 482     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 483 AC_MSG_RESULT([$]{ac_t:-
 484          }[$]am_cv_proto_iconv)
 485 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 486                    [Define as const if the declaration of iconv() needs const.])
 487
 488 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 489
 490 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 491
 492 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 493 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 494 #include <sys/socket.h>])
 495
 496 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 497 #   builtin getaddrinfo if one of the defines don't exist
 498 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 499                rsync_cv_HAVE_GETADDR_DEFINES,[
 500                         AC_EGREP_CPP(yes, [
 501                         #include <sys/types.h>
 502                         #include <sys/socket.h>
 503                         #include <netdb.h>
 504                         #ifdef AI_PASSIVE
 505                         yes
 506                         #endif],
 507                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 508                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 509 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 510         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 511         # something else so we must include <netdb.h> to get the
 512         # redefinition.
 513         AC_CHECK_FUNCS(getaddrinfo, ,
 514                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 515                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 516                 #include <sys/socket.h>
 517                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 518                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 519                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 520                         AC_LIBOBJ([getaddrinfo])])])
 521     ],[AC_LIBOBJ([getaddrinfo])])
 522
 523 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 524                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 525                 [],
 526                 [
 527 #include <sys/types.h>
 528 #include <sys/socket.h>
 529 ])
 530
 531 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 532                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 533                 [],
 534                 [
 535 #include <sys/types.h>
 536 #include <sys/socket.h>
 537 #include <netinet/in.h>
 538 ])
 539
 540 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 541                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 542                 [],
 543                 [
 544 #include <sys/types.h>
 545 #include <sys/socket.h>
 546 #include <netinet/in.h>
 547 ])
 548
 549 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 550                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 551                 [],
 552                 [
 553 #include <sys/types.h>
 554 #include <sys/socket.h>
 555 #include <netinet/in.h>
 556 ])
 557
 558 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 559 #if HAVE_SYS_TYPES_H
 560 # include <sys/types.h>
 561 #endif
 562 #if HAVE_SYS_STAT_H
 563 # include <sys/stat.h>
 564 #endif
 565 #if STDC_HEADERS
 566 # include <stdlib.h>
 567 # include <stddef.h>
 568 #else
 569 # if HAVE_STDLIB_H
 570 #  include <stdlib.h>
 571 # endif
 572 #endif
 573 ])
 574
 575 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 576 #
 577 AC_CHECK_FUNCS(strcasecmp)
 578 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 579     AC_CHECK_LIB(resolv, strcasecmp)
 580 fi
 581
 582 AC_CHECK_FUNCS(aclsort)
 583 if test x"$ac_cv_func_aclsort" = x"no"; then
 584     AC_CHECK_LIB(sec, aclsort)
 585 fi
 586
 587 dnl At the moment we don't test for a broken memcmp(), because all we
 588 dnl need to do is test for equality, not comparison, and it seems that
 589 dnl every platform has a memcmp that can do at least that.
 590 dnl AC_FUNC_MEMCMP
 591
 592 AC_FUNC_UTIME_NULL
 593 AC_FUNC_ALLOCA
 594 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 595     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 596     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 597     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 598     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 599     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 600     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 601     initgroups utimensat posix_fallocate attropen setvbuf usleep)
 602
 603 dnl cygwin iconv.h defines iconv_open as libiconv_open
 604 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 605     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 606 fi
 607
 608 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 609
 610 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 611 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 612 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 613 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 614     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 615 fi
 616
 617 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 618 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 619 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 620 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 621     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 622 fi
 623
 624 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 625     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 626     case $host_os in
 627     *cygwin*)
 628         AC_MSG_RESULT(yes)
 629         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 630                   [Define if posix_fallocate is efficient (Cygwin)])
 631         ;;
 632     *)
 633         AC_MSG_RESULT(no)
 634         ;;
 635     esac
 636 fi
 637
 638 dnl End of preallocation stuff
 639
 640 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 641 if test $ac_cv_func_getpgrp = yes; then
 642     AC_FUNC_GETPGRP
 643 fi
 644
 645 AC_ARG_ENABLE(iconv-open,
 646     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 647     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 648
 649 if test x"$enable_iconv_open" != x"no"; then
 650     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 651 fi
 652
 653 AC_ARG_ENABLE(iconv,
 654     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 655     [], [enable_iconv=$enable_iconv_open])
 656 AH_TEMPLATE([ICONV_OPTION],
 657 [Define if you want the --iconv option.  Specifing a value will set the
 658 default iconv setting (a NULL means no --iconv processing by default).])
 659 if test x"$enable_iconv" != x"no"; then
 660         if test x"$enable_iconv" = x"yes"; then
 661                 AC_DEFINE(ICONV_OPTION, NULL)
 662         else
 663                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 664         fi
 665         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 666 fi
 667
 668 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 669   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 670 #if HAVE_UNISTD_H
 671 # include <unistd.h>
 672 #endif
 673 #include <stdlib.h>
 674 #include <errno.h>
 675     main() {
 676         char const *dangling_symlink = "conftest.dangle";
 677         unlink(dangling_symlink);
 678         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 679         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1);
 680         exit(0);
 681     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 682 if test $rsync_cv_chown_modifies_symlink = yes; then
 683   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 684 fi
 685
 686 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 687   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 688 #if HAVE_UNISTD_H
 689 # include <unistd.h>
 690 #endif
 691 #include <stdlib.h>
 692 #include <errno.h>
 693 #define FILENAME "conftest.dangle"
 694     main() {
 695         unlink(FILENAME);
 696         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 697         unlink(FILENAME "2");
 698         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 699         exit(0);
 700     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 701 if test $rsync_cv_can_hardlink_symlink = yes; then
 702   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 703 fi
 704
 705 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 706   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 707 #if HAVE_UNISTD_H
 708 # include <unistd.h>
 709 #endif
 710 #include <stdlib.h>
 711 #include <errno.h>
 712 #define FILENAME "conftest.fifi"
 713     main() {
 714         unlink(FILENAME);
 715         if (mkfifo(FILENAME, 0777) < 0) abort();
 716         unlink(FILENAME "2");
 717         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 718         exit(0);
 719     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 720 if test $rsync_cv_can_hardlink_special = yes; then
 721     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 722 fi
 723
 724 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 725 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 726 #include <sys/types.h>
 727 #include <sys/socket.h>
 728
 729 main() {
 730        int fd[2];
 731        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 732 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 733 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 734     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 735 fi
 736
 737 AC_REPLACE_FUNCS([getpass])
 738
 739 if test x"$with_included_popt" != x"yes"; then
 740     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 741 fi
 742 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 743     # If the system has /usr/include/popt/popt.h, we enable the
 744     # included popt because an attempt to "#include <popt/popt.h>"
 745     # would use our included header file anyway (due to -I.), and
 746     # might conflict with the system popt.
 747     with_included_popt=yes
 748 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 749     with_included_popt=yes
 750 fi
 751
 752 AC_MSG_CHECKING([whether to use included libpopt])
 753 if test x"$with_included_popt" = x"yes"; then
 754     AC_MSG_RESULT($srcdir/popt)
 755     BUILD_POPT='$(popt_OBJS)'
 756     CFLAGS="-I$srcdir/popt $CFLAGS"
 757     if test x"$ALLOCA" != x
 758     then
 759         # this can be removed when/if we add an included alloca.c;
 760         #  see autoconf documentation on AC_FUNC_ALLOCA
 761         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 762     fi
 763 else
 764     AC_MSG_RESULT(no)
 765 fi
 766
 767 # We default to using our zlib unless --with-included-zlib=no is given.
 768 if test x"$with_included_zlib" != x"no"; then
 769     with_included_zlib=yes
 770 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
 771     with_included_zlib=yes
 772 fi
 773 if test x"$with_included_zlib" != x"yes"; then
 774     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
 775 fi
 776
 777 AC_MSG_CHECKING([whether to use included zlib])
 778 if test x"$with_included_zlib" = x"yes"; then
 779     AC_MSG_RESULT($srcdir/zlib)
 780     BUILD_ZLIB='$(zlib_OBJS)'
 781     CFLAGS="-I$srcdir/zlib $CFLAGS"
 782 else
 783     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
 784     AC_MSG_RESULT(no)
 785 fi
 786
 787 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 788 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
 789 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 790     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 791 fi
 792
 793 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 794 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
 795 #include <dirent.h>
 796 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 797 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 798 di->d_name[0] == 0) exit(0); exit(1);} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
 799 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 800     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 801 fi
 802
 803 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
 804 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 805 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
 806 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
 807     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 808 fi
 809
 810 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 811 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
 812 #include <unistd.h>]], [[struct timeval tv; exit(gettimeofday(&tv, NULL));]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
 813 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 814     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 815 fi
 816
 817 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 818 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 819 #include <sys/types.h>
 820 #include <stdarg.h>
 821 void foo(const char *format, ...) {
 822        va_list ap;
 823        int len;
 824        char buf[5];
 825
 826        va_start(ap, format);
 827        len = vsnprintf(0, 0, format, ap);
 828        va_end(ap);
 829        if (len != 5) exit(1);
 830
 831        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 832
 833        exit(0);
 834 }
 835 main() { foo("hello"); }
 836 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
 837 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 838     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 839 fi
 840
 841
 842 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 843 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 844 #include <sys/types.h>
 845 #include <sys/stat.h>
 846 #include <unistd.h>
 847 main() {
 848   struct stat st;
 849   char tpl[20]="/tmp/test.XXXXXX";
 850   int fd = mkstemp(tpl);
 851   if (fd == -1) exit(1);
 852   unlink(tpl);
 853   if (fstat(fd, &st) != 0) exit(1);
 854   if ((st.st_mode & 0777) != 0600) exit(1);
 855   exit(0);
 856 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
 857 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 858     case $host_os in
 859     hpux*)
 860         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 861         dnl so we noisily skip using it.  See HP change request JAGaf34426
 862         dnl for details. (sbonds)
 863         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 864         ;;
 865     *)
 866         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 867         ;;
 868     esac
 869 fi
 870
 871
 872 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 873 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 874 #include <stdio.h>
 875 #include <sys/stat.h>
 876 #include <errno.h>
 877 main() { int rc, ec; char *fn = "fifo-test";
 878 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 879 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 880 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
 881 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 882     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 883 fi
 884
 885 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 886 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 887 #include <stdio.h>
 888 #include <sys/stat.h>
 889 #include <errno.h>
 890 main() { int rc, ec; char *fn = "sock-test";
 891 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 892 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 893 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
 894 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 895     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 896 fi
 897
 898 #
 899 # The following test was mostly taken from the tcl/tk plus patches
 900 #
 901 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 902 rm -rf conftest*
 903 cat > conftest.$ac_ext <<EOF
 904 int main() { return 0; }
 905 EOF
 906 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 907 if test -f conftest..o; then
 908     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 909 else
 910     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 911 fi
 912 rm -rf conftest*
 913 ])
 914 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 915     OBJ_SAVE="#"
 916     OBJ_RESTORE="#"
 917     CC_SHOBJ_FLAG='-o $@'
 918 else
 919     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 920     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 921     CC_SHOBJ_FLAG=""
 922 fi
 923
 924 AC_SUBST(OBJ_SAVE)
 925 AC_SUBST(OBJ_RESTORE)
 926 AC_SUBST(CC_SHOBJ_FLAG)
 927 AC_SUBST(BUILD_POPT)
 928 AC_SUBST(BUILD_ZLIB)
 929 AC_SUBST(MAKE_MAN)
 930
 931 AC_PATH_PROG([STUNNEL], [stunnel], [stunnel], [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 932 AC_PATH_PROG([STUNNEL4], [stunnel4], [$STUNNEL], [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 933
 934 AC_CHECK_FUNCS(_acl __acl _facl __facl)
 935 #################################################
 936 # check for ACL support
 937
 938 AC_MSG_CHECKING([whether to support ACLs])
 939 AC_ARG_ENABLE(acl-support,
 940         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
 941
 942 if test x"$enable_acl_support" = x"no"; then
 943     AC_MSG_RESULT(no)
 944 else
 945     case "$host_os" in
 946     *sysv5*)
 947         AC_MSG_RESULT(Using UnixWare ACLs)
 948         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
 949         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
 950         ;;
 951     solaris*|*cygwin*)
 952         AC_MSG_RESULT(Using solaris ACLs)
 953         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
 954         AC_DEFINE(SUPPORT_ACLS, 1)
 955         ;;
 956     *hpux*)
 957         AC_MSG_RESULT(Using HPUX ACLs)
 958         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
 959         AC_DEFINE(SUPPORT_ACLS, 1)
 960         ;;
 961     *irix*)
 962         AC_MSG_RESULT(Using IRIX ACLs)
 963         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
 964         AC_DEFINE(SUPPORT_ACLS, 1)
 965         ;;
 966     *aix*)
 967         AC_MSG_RESULT(Using AIX ACLs)
 968         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
 969         AC_DEFINE(SUPPORT_ACLS, 1)
 970         ;;
 971     *osf*)
 972         AC_MSG_RESULT(Using Tru64 ACLs)
 973         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
 974         AC_DEFINE(SUPPORT_ACLS, 1)
 975         LIBS="$LIBS -lpacl"
 976         ;;
 977     darwin*)
 978         AC_MSG_RESULT(Using OS X ACLs)
 979         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
 980         AC_DEFINE(SUPPORT_ACLS, 1)
 981         ;;
 982     *)
 983         AC_MSG_RESULT(running tests:)
 984         AC_CHECK_LIB(acl,acl_get_file)
 985         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
 986             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 987 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
 988         AC_MSG_CHECKING(ACL test results)
 989         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
 990             AC_MSG_RESULT(Using posix ACLs)
 991             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
 992             AC_DEFINE(SUPPORT_ACLS, 1)
 993             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
 994                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 995 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
 996             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
 997                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
 998             fi
 999         else
1000             if test x"$enable_acl_support" = x"yes"; then
1001                 AC_MSG_ERROR(Failed to find ACL support)
1002             else
1003                 AC_MSG_RESULT(No ACL support found)
1004             fi
1005         fi
1006         ;;
1007     esac
1008 fi
1009
1010 #################################################
1011 # check for extended attribute support
1012 AC_MSG_CHECKING(whether to support extended attributes)
1013 AC_ARG_ENABLE(xattr-support,
1014     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1015     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1016         *yes*) enable_xattr_support=maybe ;;
1017         *) enable_xattr_support=no ;;
1018         esac])
1019 AH_TEMPLATE([SUPPORT_XATTRS],
1020 [Define to 1 to add support for extended attributes])
1021 if test x"$enable_xattr_support" = x"no"; then
1022     AC_MSG_RESULT(no)
1023 else
1024     case "$host_os" in
1025     *linux*|*netbsd*)
1026         AC_MSG_RESULT(Using Linux xattrs)
1027         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1028         AC_DEFINE(SUPPORT_XATTRS, 1)
1029         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1030         AC_CHECK_LIB(attr,getxattr)
1031         ;;
1032     darwin*)
1033         AC_MSG_RESULT(Using OS X xattrs)
1034         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1035         AC_DEFINE(SUPPORT_XATTRS, 1)
1036         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1037         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1038         ;;
1039     freebsd*)
1040         AC_MSG_RESULT(Using FreeBSD extattrs)
1041         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1042         AC_DEFINE(SUPPORT_XATTRS, 1)
1043         ;;
1044     solaris*)
1045         AC_MSG_RESULT(Using Solaris xattrs)
1046         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1047         AC_DEFINE(SUPPORT_XATTRS, 1)
1048         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1049         ;;
1050     *)
1051         if test x"$enable_xattr_support" = x"yes"; then
1052             AC_MSG_ERROR(Failed to find extended attribute support)
1053         else
1054             AC_MSG_RESULT(No extended attribute support found)
1055         fi
1056         ;;
1057     esac
1058 fi
1059
1060 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1061     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1062     OLD_CFLAGS="$CFLAGS"
1063     CFLAGS="$CFLAGS -Wno-unused-parameter"
1064     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1065     AC_MSG_RESULT([$rsync_warn_flag])
1066     if test x"$rsync_warn_flag" = x"no"; then
1067         CFLAGS="$OLD_CFLAGS"
1068     fi
1069 fi
1070
1071 case "$CC" in
1072 ' checker'*|checker*)
1073     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1074     ;;
1075 esac
1076
1077 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1078 AC_OUTPUT
1079
1080 AC_MSG_RESULT()
1081 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1082 AC_MSG_RESULT()
1083 if test x$HAVE_YODL2MAN != x1; then
1084     AC_MSG_RESULT([    Note that yodl2man was not found, so pre-existing manpage files will be])
1085     AC_MSG_RESULT([    used w/o change (if available) -- no .yo file changes will be used.])
1086     AC_MSG_RESULT()
1087 fi