808d5d1c0662cb46c423a73a0fa91583730d3d1b
[idra/samba.git] / lib / replace / libreplace.m4
1 AC_DEFUN_ONCE(AC_LIBREPLACE_LOCATION_CHECKS,
2 [
3 echo "LIBREPLACE_LOCATION_CHECKS: START"
4
5 dnl find the libreplace sources. This is meant to work both for 
6 dnl libreplace standalone builds, and builds of packages using libreplace
7 libreplacedir=""
8 libreplacepaths="$srcdir $srcdir/lib/replace $srcdir/libreplace $srcdir/../libreplace $srcdir/../replace $srcdir/../lib/replace $srcdir/../../../lib/replace"
9 for d in $libreplacepaths; do
10         if test -f "$d/replace.c"; then
11                 libreplacedir="$d"              
12                 AC_SUBST(libreplacedir)
13                 break;
14         fi
15 done
16 if test x"$libreplacedir" = "x"; then
17         AC_MSG_ERROR([cannot find libreplace in $libreplacepaths])
18 fi
19 LIBREPLACEOBJ="$libreplacedir/replace.o"
20 AC_SUBST(LIBREPLACEOBJ)
21
22 AC_CANONICAL_BUILD
23 AC_CANONICAL_HOST
24 AC_CANONICAL_TARGET
25
26 echo "LIBREPLACE_LOCATION_CHECKS: END"
27 ]) dnl end AC_LIBREPLACE_LOCATION_CHECKS
28
29
30 AC_DEFUN_ONCE(AC_LIBREPLACE_BROKEN_CHECKS,
31 [
32 echo "LIBREPLACE_BROKEN_CHECKS: START"
33
34 dnl find the libreplace sources. This is meant to work both for 
35 dnl libreplace standalone builds, and builds of packages using libreplace
36 libreplacedir=""
37 libreplacepaths="$srcdir $srcdir/lib/replace $srcdir/libreplace $srcdir/../libreplace $srcdir/../replace $srcdir/../lib/replace $srcdir/../../../lib/replace"
38 for d in $libreplacepaths; do
39         if test -f "$d/replace.c"; then
40                 libreplacedir="$d"              
41                 AC_SUBST(libreplacedir)
42                 break;
43         fi
44 done
45 if test x"$libreplacedir" = "x"; then
46         AC_MSG_ERROR([cannot find libreplace in $libreplacepaths])
47 fi
48
49 LIBREPLACEOBJ="$libreplacedir/replace.o"
50 AC_SUBST(LIBREPLACEOBJ)
51
52 LIBREPLACEOBJ="${LIBREPLACEOBJ} $libreplacedir/snprintf.o"
53
54 AC_TYPE_UID_T
55 AC_TYPE_MODE_T
56 AC_TYPE_OFF_T
57 AC_TYPE_SIZE_T
58 AC_TYPE_PID_T
59 AC_STRUCT_ST_RDEV
60 AC_CHECK_TYPE(ino_t,unsigned)
61 AC_CHECK_TYPE(loff_t,off_t)
62 AC_CHECK_TYPE(offset_t,loff_t)
63
64 AC_FUNC_MEMCMP
65
66 AC_CHECK_FUNCS([pipe strftime srandom random srand rand usleep setbuffer lstat getpgrp utime utimes])
67
68 AC_CHECK_HEADERS(stdbool.h stdint.h sys/select.h)
69 AC_CHECK_HEADERS(setjmp.h utime.h)
70
71 LIBREPLACE_PROVIDE_HEADER([stdint.h])
72 LIBREPLACE_PROVIDE_HEADER([stdbool.h])
73
74 AC_CHECK_TYPE(bool, 
75 [AC_DEFINE(HAVE_BOOL, 1, [Whether the bool type is available])],,
76 [
77 AC_INCLUDES_DEFAULT
78 #ifdef HAVE_STDBOOL_H
79 #include <stdbool.h>
80 #endif]
81 )
82
83 AC_CHECK_TYPE(_Bool, 
84 [AC_DEFINE(HAVE__Bool, 1, [Whether the _Bool type is available])],,
85 [
86 AC_INCLUDES_DEFAULT
87 #ifdef HAVE_STDBOOL_H
88 #include <stdbool.h>
89 #endif]
90 )
91
92 AC_CHECK_HEADERS(linux/types.h)
93
94 AC_CACHE_CHECK([for working mmap],libreplace_cv_HAVE_MMAP,[
95 AC_TRY_RUN([#include "$libreplacedir/test/shared_mmap.c"],
96            libreplace_cv_HAVE_MMAP=yes,libreplace_cv_HAVE_MMAP=no,libreplace_cv_HAVE_MMAP=cross)])
97 if test x"$libreplace_cv_HAVE_MMAP" = x"yes"; then
98     AC_DEFINE(HAVE_MMAP,1,[Whether mmap works])
99 fi
100
101
102 AC_CHECK_HEADERS(sys/syslog.h syslog.h)
103 AC_CHECK_HEADERS(sys/time.h time.h)
104 AC_CHECK_HEADERS(stdarg.h vararg.h)
105 AC_CHECK_HEADERS(sys/mount.h mntent.h)
106 AC_CHECK_HEADERS(stropts.h)
107 AC_CHECK_HEADERS(unix.h)
108
109 AC_CHECK_FUNCS(seteuid setresuid setegid setresgid chroot bzero strerror strerror_r)
110 AC_CHECK_FUNCS(vsyslog setlinebuf mktime ftruncate chsize rename)
111 AC_CHECK_FUNCS(waitpid wait4 strlcpy strlcat initgroups memmove strdup)
112 AC_CHECK_FUNCS(pread pwrite strndup strcasestr strtok_r mkdtemp dup2 dprintf vdprintf)
113 AC_CHECK_FUNCS(isatty chown lchown link readlink symlink realpath)
114 AC_CHECK_FUNCS(fdatasync,,[
115         # if we didn't find it, look in librt (Solaris hides it there...)
116         AC_CHECK_LIB(rt, fdatasync,
117                 [libreplace_cv_HAVE_FDATASYNC_IN_LIBRT=yes
118                 AC_DEFINE(HAVE_FDATASYNC, 1, Define to 1 if there is support for fdatasync)])
119 ])
120 AC_HAVE_DECL(fdatasync, [#include <unistd.h>])
121 AC_CHECK_FUNCS(clock_gettime,libreplace_cv_have_clock_gettime=yes,[
122         AC_CHECK_LIB(rt, clock_gettime,
123                 [libreplace_cv_HAVE_CLOCK_GETTIME_IN_LIBRT=yes
124                 libreplace_cv_have_clock_gettime=yes
125                 AC_DEFINE(HAVE_CLOCK_GETTIME, 1, Define to 1 if there is support for clock_gettime)])
126 ])
127 AC_CHECK_FUNCS(get_current_dir_name)
128 AC_HAVE_DECL(setresuid, [#include <unistd.h>])
129 AC_HAVE_DECL(setresgid, [#include <unistd.h>])
130 AC_HAVE_DECL(errno, [#include <errno.h>])
131
132 AC_CACHE_CHECK([for secure mkstemp],libreplace_cv_HAVE_SECURE_MKSTEMP,[
133 AC_TRY_RUN([#include <stdlib.h>
134 #include <sys/types.h>
135 #include <sys/stat.h>
136 #include <unistd.h>
137 main() { 
138   struct stat st;
139   char tpl[20]="/tmp/test.XXXXXX"; 
140   int fd = mkstemp(tpl); 
141   if (fd == -1) exit(1);
142   unlink(tpl);
143   if (fstat(fd, &st) != 0) exit(1);
144   if ((st.st_mode & 0777) != 0600) exit(1);
145   exit(0);
146 }],
147 libreplace_cv_HAVE_SECURE_MKSTEMP=yes,
148 libreplace_cv_HAVE_SECURE_MKSTEMP=no,
149 libreplace_cv_HAVE_SECURE_MKSTEMP=cross)])
150 if test x"$libreplace_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
151     AC_DEFINE(HAVE_SECURE_MKSTEMP,1,[Whether mkstemp is secure])
152 fi
153
154 dnl Provided by snprintf.c:
155 AC_CHECK_HEADERS(stdio.h strings.h)
156 AC_CHECK_DECLS([snprintf, vsnprintf, asprintf, vasprintf])
157 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
158
159 AC_CACHE_CHECK([for C99 vsnprintf],libreplace_cv_HAVE_C99_VSNPRINTF,[
160 AC_TRY_RUN([
161 #include <sys/types.h>
162 #include <stdio.h>
163 #include <stdarg.h>
164 #include <stdlib.h>
165 void foo(const char *format, ...) { 
166        va_list ap;
167        int len;
168        char buf[20];
169        long long l = 1234567890;
170        l *= 100;
171
172        va_start(ap, format);
173        len = vsnprintf(buf, 0, format, ap);
174        va_end(ap);
175        if (len != 5) exit(1);
176
177        va_start(ap, format);
178        len = vsnprintf(0, 0, format, ap);
179        va_end(ap);
180        if (len != 5) exit(2);
181
182        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(3);
183
184        if (snprintf(buf, 20, "%lld", l) != 12 || strcmp(buf, "123456789000") != 0) exit(4);
185        if (snprintf(buf, 20, "%zu", 123456789) != 9 || strcmp(buf, "123456789") != 0) exit(5);
186        if (snprintf(buf, 20, "%2\$d %1\$d", 3, 4) != 3 || strcmp(buf, "4 3") != 0) exit(6);
187        if (snprintf(buf, 20, "%s", 0) < 3) exit(7);
188
189        exit(0);
190 }
191 main() { foo("hello"); }
192 ],
193 libreplace_cv_HAVE_C99_VSNPRINTF=yes,libreplace_cv_HAVE_C99_VSNPRINTF=no,libreplace_cv_HAVE_C99_VSNPRINTF=cross)])
194 if test x"$libreplace_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
195     AC_DEFINE(HAVE_C99_VSNPRINTF,1,[Whether there is a C99 compliant vsnprintf])
196 fi
197
198
199 dnl VA_COPY
200 AC_CACHE_CHECK([for va_copy],libreplace_cv_HAVE_VA_COPY,[
201 AC_TRY_LINK([#include <stdarg.h>
202 va_list ap1,ap2;], [va_copy(ap1,ap2);],
203 libreplace_cv_HAVE_VA_COPY=yes,libreplace_cv_HAVE_VA_COPY=no)])
204 if test x"$libreplace_cv_HAVE_VA_COPY" = x"yes"; then
205     AC_DEFINE(HAVE_VA_COPY,1,[Whether va_copy() is available])
206 fi
207
208 if test x"$libreplace_cv_HAVE_VA_COPY" != x"yes"; then
209 AC_CACHE_CHECK([for __va_copy],libreplace_cv_HAVE___VA_COPY,[
210 AC_TRY_LINK([#include <stdarg.h>
211 va_list ap1,ap2;], [__va_copy(ap1,ap2);],
212 libreplace_cv_HAVE___VA_COPY=yes,libreplace_cv_HAVE___VA_COPY=no)])
213 if test x"$libreplace_cv_HAVE___VA_COPY" = x"yes"; then
214     AC_DEFINE(HAVE___VA_COPY,1,[Whether __va_copy() is available])
215 fi
216 fi
217
218 dnl __FUNCTION__ macro
219 AC_CACHE_CHECK([for __FUNCTION__ macro],libreplace_cv_HAVE_FUNCTION_MACRO,[
220 AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __FUNCTION__);],
221 libreplace_cv_HAVE_FUNCTION_MACRO=yes,libreplace_cv_HAVE_FUNCTION_MACRO=no)])
222 if test x"$libreplace_cv_HAVE_FUNCTION_MACRO" = x"yes"; then
223     AC_DEFINE(HAVE_FUNCTION_MACRO,1,[Whether there is a __FUNCTION__ macro])
224 else
225     dnl __func__ macro
226     AC_CACHE_CHECK([for __func__ macro],libreplace_cv_HAVE_func_MACRO,[
227     AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __func__);],
228     libreplace_cv_HAVE_func_MACRO=yes,libreplace_cv_HAVE_func_MACRO=no)])
229     if test x"$libreplace_cv_HAVE_func_MACRO" = x"yes"; then
230        AC_DEFINE(HAVE_func_MACRO,1,[Whether there is a __func__ macro])
231     fi
232 fi
233
234 AC_CHECK_HEADERS([sys/param.h limits.h])
235
236 AC_CHECK_TYPE(comparison_fn_t, 
237 [AC_DEFINE(HAVE_COMPARISON_FN_T, 1,[Whether or not we have comparison_fn_t])])
238
239 AC_HAVE_DECL(setenv, [#include <stdlib.h>])
240 AC_CHECK_FUNCS(setenv unsetenv)
241 AC_HAVE_DECL(environ, [#include <unistd.h>])
242
243 AC_CHECK_FUNCS(strnlen)
244 AC_CHECK_FUNCS(strtoull __strtoull strtouq strtoll __strtoll strtoq)
245
246 AC_CHECK_FUNCS(memmem)
247
248 # this test disabled as we don't actually need __VA_ARGS__ yet
249 AC_TRY_CPP([
250 #define eprintf(...) fprintf(stderr, __VA_ARGS__)
251 eprintf("bla", "bar");
252 ], AC_DEFINE(HAVE__VA_ARGS__MACRO, 1, [Whether the __VA_ARGS__ macro is available]))
253
254
255 AC_CACHE_CHECK([for sig_atomic_t type],libreplace_cv_sig_atomic_t, [
256     AC_TRY_COMPILE([
257 #include <sys/types.h>
258 #if STDC_HEADERS
259 #include <stdlib.h>
260 #include <stddef.h>
261 #endif
262 #include <signal.h>],[sig_atomic_t i = 0],
263         libreplace_cv_sig_atomic_t=yes,libreplace_cv_sig_atomic_t=no)])
264 if test x"$libreplace_cv_sig_atomic_t" = x"yes"; then
265    AC_DEFINE(HAVE_SIG_ATOMIC_T_TYPE,1,[Whether we have the atomic_t variable type])
266 fi
267
268
269 AC_CACHE_CHECK([for O_DIRECT flag to open(2)],libreplace_cv_HAVE_OPEN_O_DIRECT,[
270 AC_TRY_COMPILE([
271 #include <unistd.h>
272 #ifdef HAVE_FCNTL_H
273 #include <fcntl.h>
274 #endif],
275 [int fd = open("/dev/null", O_DIRECT);],
276 libreplace_cv_HAVE_OPEN_O_DIRECT=yes,libreplace_cv_HAVE_OPEN_O_DIRECT=no)])
277 if test x"$libreplace_cv_HAVE_OPEN_O_DIRECT" = x"yes"; then
278     AC_DEFINE(HAVE_OPEN_O_DIRECT,1,[Whether the open(2) accepts O_DIRECT])
279 fi
280
281
282 dnl Check if the C compiler understands volatile (it should, being ANSI).
283 AC_CACHE_CHECK([that the C compiler understands volatile],libreplace_cv_volatile, [
284         AC_TRY_COMPILE([#include <sys/types.h>],[volatile int i = 0],
285                 libreplace_cv_volatile=yes,libreplace_cv_volatile=no)])
286 if test x"$libreplace_cv_volatile" = x"yes"; then
287         AC_DEFINE(HAVE_VOLATILE, 1, [Whether the C compiler understands volatile])
288 fi
289
290 m4_include(system/config.m4)
291
292 m4_include(dlfcn.m4)
293 m4_include(getpass.m4)
294 m4_include(strptime.m4)
295 m4_include(win32.m4)
296 m4_include(timegm.m4)
297 m4_include(repdir.m4)
298 m4_include(crypt.m4)
299
300 if test x$libreplace_cv_have_clock_gettime = xyes ; then
301         SMB_CHECK_CLOCK_ID(CLOCK_MONOTONIC)
302         SMB_CHECK_CLOCK_ID(CLOCK_PROCESS_CPUTIME_ID)
303         SMB_CHECK_CLOCK_ID(CLOCK_REALTIME)
304 fi
305
306 AC_CACHE_CHECK([for struct timespec type],libreplace_cv_struct_timespec, [
307     AC_TRY_COMPILE([
308 #include <sys/types.h>
309 #if STDC_HEADERS
310 #include <stdlib.h>
311 #include <stddef.h>
312 #endif
313 #if TIME_WITH_SYS_TIME
314 # include <sys/time.h>
315 # include <time.h>
316 #else
317 # if HAVE_SYS_TIME_H
318 #  include <sys/time.h>
319 # else
320 #  include <time.h>
321 # endif
322 #endif
323 ],[struct timespec ts;],
324         libreplace_cv_struct_timespec=yes,libreplace_cv_struct_timespec=no)])
325 if test x"$libreplace_cv_struct_timespec" = x"yes"; then
326    AC_DEFINE(HAVE_STRUCT_TIMESPEC,1,[Whether we have struct timespec])
327 fi
328
329 AC_CHECK_FUNCS([printf memset memcpy],,[AC_MSG_ERROR([Required function not found])])
330
331 echo "LIBREPLACE_BROKEN_CHECKS: END"
332 ]) dnl end AC_LIBREPLACE_BROKEN_CHECKS
333
334 AC_DEFUN_ONCE(AC__LIBREPLACE_ALL_CHECKS_START,
335 [
336 #LIBREPLACE_ALL_CHECKS: START"
337 ])
338 AC_DEFUN_ONCE(AC__LIBREPLACE_ALL_CHECKS_END,
339 [
340 #LIBREPLACE_ALL_CHECKS: END"
341 ])
342 m4_define(AC_LIBREPLACE_ALL_CHECKS,
343 [
344 AC__LIBREPLACE_ALL_CHECKS_START
345 AC_LIBREPLACE_LOCATION_CHECKS
346 AC_LIBREPLACE_CC_CHECKS
347 AC_LIBREPLACE_BROKEN_CHECKS
348 AC__LIBREPLACE_ALL_CHECKS_END
349 CFLAGS="$CFLAGS -I$libreplacedir"
350 ])
351
352 m4_include(libreplace_cc.m4)
353 m4_include(libreplace_ld.m4)
354 m4_include(libreplace_network.m4)
355 m4_include(libreplace_macros.m4)
356
357
358 dnl SMB_CHECK_CLOCK_ID(clockid)
359 dnl Test whether the specified clock_gettime clock ID is available. If it
360 dnl is, we define HAVE_clockid
361 AC_DEFUN([SMB_CHECK_CLOCK_ID],
362 [
363     AC_MSG_CHECKING(for $1)
364     AC_TRY_LINK([
365 #if TIME_WITH_SYS_TIME
366 # include <sys/time.h>
367 # include <time.h>
368 #else
369 # if HAVE_SYS_TIME_H
370 #  include <sys/time.h>
371 # else
372 #  include <time.h>
373 # endif
374 #endif
375     ],
376     [
377 clockid_t clk = $1;
378     ],
379     [
380         AC_MSG_RESULT(yes)
381         AC_DEFINE(HAVE_$1, 1,
382             [Whether the clock_gettime clock ID $1 is available])
383     ],
384     [
385         AC_MSG_RESULT(no)
386     ])
387 ])
388 m4_ifndef([AC_USE_SYSTEM_EXTENSIONS],[m4_include(autoconf-2.60.m4)])