configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[1.3.99],[heimdal-bugs@h5l.org])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.10])
  11 AM_MAINTAINER_MODE
  12
  13 dnl Checks for programs.
  14 AC_PROG_CC
  15 AM_PROG_CC_C_O
  16 AC_PROG_CPP
  17 AC_PROG_LIBTOOL
  18
  19 AC_PREFIX_DEFAULT(/usr/heimdal)
  20
  21 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  22 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  23
  24 AC_CANONICAL_HOST
  25 CANONICAL_HOST=$host
  26 AC_SUBST(CANONICAL_HOST)
  27
  28 dnl Hints for autobuild
  29 AB_INIT
  30
  31 rk_SYS_LARGEFILE
  32
  33 rk_AIX
  34 rk_IRIX
  35 rk_SUNOS
  36
  37 dnl
  38 dnl this is needed to run the configure tests against glibc
  39 dnl
  40 AC_DEFINE([_GNU_SOURCE], 1,
  41         [Define to enable extensions on glibc-based systems such as Linux.])
  42
  43 AC_OBJEXT
  44 AC_EXEEXT
  45
  46 dnl AC_KRB_PROG_YACC
  47 AC_PROG_YACC
  48 AM_PROG_LEX
  49 dnl AC_PROG_RANLIB
  50 AC_PROG_AWK
  51 AC_KRB_PROG_LN_S
  52
  53 AC_MIPS_ABI
  54 CC="$CC $abi"
  55 libdir="$libdir$abilibdirext"
  56
  57 AC_C___ATTRIBUTE__
  58
  59 LT_PREREQ([2.2])
  60 LT_INIT([shared static win32-dll])
  61
  62 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  63 rk_VERSIONSCRIPT
  64
  65 dnl
  66 dnl Helper bits for cross compiling
  67 dnl
  68
  69
  70
  71 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  72
  73 AC_ARG_WITH(cross-tools,
  74         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  75         [if test "$withval" = "yes"; then
  76                 AC_MSG_ERROR([Need path to cross tools])
  77         fi
  78         with_cross_tools="${with_cross_tools}/"
  79         ])
  80
  81 if test "${cross_compiling}" != yes ; then
  82
  83    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
  84    SLC="\$(top_builddir)/lib/sl/slc"
  85
  86    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
  87    SLC_DEP="\$(SLC)"
  88 else
  89    ASN1_COMPILE="${with_cross_tools}asn1_compile"
  90    SLC="${with_cross_tools}slc"
  91
  92    ASN1_COMPILE_DEP=
  93    SLC_DEP=
  94 fi
  95
  96 AC_SUBST([ASN1_COMPILE])
  97 AC_SUBST([ASN1_COMPILE_DEP])
  98 AC_SUBST([SLC])
  99 AC_SUBST([SLC_DEP])
 100
 101
 102 dnl ---
 103
 104 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 105
 106 rk_TEST_PACKAGE(openldap,
 107 [#include <lber.h>
 108 #include <ldap.h>],
 109 [-lldap -llber],,,OPENLDAP)
 110
 111 AC_ARG_ENABLE(hdb-openldap-module,
 112         AS_HELP_STRING([--enable-hdb-openldap-module],
 113                 [if you want support to build openldap hdb as shared object]))
 114 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 115     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 116 fi
 117 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 118
 119 dnl
 120 dnl Optional modules, pk-init, digest, kx509
 121 dnl
 122
 123 AC_ARG_ENABLE(pk-init,
 124         AS_HELP_STRING([--disable-pk-init],
 125                 [if you want disable to PK-INIT support]))
 126 if test "$enable_pk_init" != no ;then
 127         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 128 fi
 129 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 130
 131 AC_ARG_ENABLE(digest,
 132         AS_HELP_STRING([--disable-digest],
 133                 [if you want disable to DIGEST support]))
 134 if test "$enable_digest" != no ;then
 135         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 136 fi
 137
 138 AC_ARG_ENABLE(kx509,
 139         AS_HELP_STRING([--disable-kx509],
 140                 [if you want disable to kx509 support]))
 141 if test "$enable_kx509" != no ;then
 142         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 143 fi
 144
 145 AC_ARG_ENABLE(krb4,
 146         AS_HELP_STRING([--disable-krb4],
 147                 [if you want disable to krb4 support]))
 148 if test "$enable_krb4" != no ;then
 149         AC_DEFINE([KRB4], 1, [Define to enable Kerberos 4.])
 150 fi
 151
 152
 153 dnl Check for sqlite
 154 rk_TEST_PACKAGE(sqlite3,
 155 [#include <sqlite3.h>
 156 #ifndef SQLITE_OPEN_CREATE
 157 #error "old version"
 158 #endif],
 159 [-lsqlite3],,,SQLITE3)
 160
 161 if test "X$with_sqlite3" != Xyes ; then
 162    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 163    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 164 fi
 165 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 166
 167 AC_ARG_ENABLE(sqlite-cache,
 168         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 169 if test "$enable_sqlite_cache" != no; then
 170     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 171 fi
 172 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 173
 174
 175 dnl check for libintl
 176 rk_TEST_PACKAGE(libintl,
 177 [#include <libintl.h>],
 178 [-lintl],,,LIBINTL)
 179
 180 dnl path where the hdb directory is stored
 181 AC_ARG_WITH([hdbdir],
 182         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 183         [],
 184         [with_hdbdir=/var/heimdal])
 185 DIR_hdbdir="$with_hdbdir"
 186 AC_SUBST([DIR_hdbdir])
 187
 188
 189 dnl no kerberos4 any more
 190 with_krb4=no
 191 AC_SUBST(INCLUDE_krb4)
 192 AC_SUBST(LIB_krb4)
 193 AM_CONDITIONAL(KRB4, false)
 194
 195 AM_CONDITIONAL(KRB5, true)
 196 AM_CONDITIONAL(do_roken_rename, true)
 197
 198 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 199
 200
 201 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 202 AC_SUBST(LIB_kdb)dnl
 203
 204 KRB_CRYPTO
 205
 206 KRB_PTHREADS
 207
 208 AC_ARG_ENABLE(dce,
 209         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 210 if test "$enable_dce" = yes; then
 211     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 212 fi
 213 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 214
 215 ## XXX quite horrible:
 216 if test -f /etc/ibmcxx.cfg; then
 217         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 218         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 219         dpagaix_ldflags=
 220 else
 221         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 222         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 223         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 224 fi
 225 AC_SUBST(dpagaix_cflags)
 226 AC_SUBST(dpagaix_ldadd)
 227 AC_SUBST(dpagaix_ldflags)
 228
 229 AC_ARG_ENABLE([afs-support],
 230         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 231 if test "$enable_afs_support" = no; then
 232         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 233 fi
 234
 235 rk_DB
 236
 237 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 238
 239 rk_ROKEN(lib/roken)
 240 LIBADD_roken="$LIB_roken"
 241 AC_SUBST(LIBADD_roken)dnl
 242 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 243
 244 rk_OTP
 245
 246 rk_LIBDISPATCH
 247
 248 AC_CHECK_OSFC2
 249
 250 AC_ARG_ENABLE(mmap,
 251         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 252 if test "$enable_mmap" = "no"; then
 253         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 254 fi
 255
 256 AC_ARG_ENABLE(afs-string-to-key,
 257         AS_HELP_STRING([--disable-afs-string-to-key],
 258         [disable use of weak AFS string-to-key functions]),
 259         [], [enable_afs_string_to_key=yes])
 260
 261 if test "$enable_afs_string_to_key" = "yes"; then
 262         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 263 fi
 264
 265
 266 rk_CHECK_MAN
 267
 268 rk_TEST_PACKAGE(readline,
 269 [#include <stdio.h>
 270  #include <readline.h>],-lreadline,,, READLINE)
 271
 272 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 273
 274 KRB_C_BIGENDIAN
 275 AC_C_INLINE
 276
 277 KRB_CHECK_X
 278
 279 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 280
 281 AC_CHECK_XAU
 282
 283 dnl AM_C_PROTOTYPES
 284
 285 dnl Checks for typedefs, structures, and compiler characteristics.
 286 AC_C_CONST
 287 AC_TYPE_OFF_T
 288 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 289 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 290 AC_HAVE_TYPE([long long])
 291 AC_HEADER_TIME
 292 AC_STRUCT_TM
 293
 294 dnl Checks for header files.
 295 AC_HEADER_STDC
 296
 297 AC_CHECK_HEADERS([\
 298         arpa/ftp.h                              \
 299         arpa/telnet.h                           \
 300         bind/bitypes.h                          \
 301         bsdsetjmp.h                             \
 302         curses.h                                \
 303         dlfcn.h                                 \
 304         fnmatch.h                               \
 305         inttypes.h                              \
 306         io.h                                    \
 307         libutil.h                               \
 308         limits.h                                \
 309         maillock.h                              \
 310         netgroup.h                              \
 311         netinet/in6_machtypes.h                 \
 312         pthread.h                               \
 313         pty.h                                   \
 314         sac.h                                   \
 315         sgtty.h                                 \
 316         siad.h                                  \
 317         signal.h                                \
 318         strings.h                               \
 319         stropts.h                               \
 320         sys/bitypes.h                           \
 321         sys/category.h                          \
 322         sys/file.h                              \
 323         sys/filio.h                             \
 324         sys/ioccom.h                            \
 325         sys/mman.h                              \
 326         sys/param.h                             \
 327         sys/pty.h                               \
 328         sys/ptyio.h                             \
 329         sys/select.h                            \
 330         sys/socket.h                            \
 331         sys/str_tty.h                           \
 332         sys/stream.h                            \
 333         sys/stropts.h                           \
 334         sys/syscall.h                           \
 335         sys/termio.h                            \
 336         sys/timeb.h                             \
 337         sys/times.h                             \
 338         sys/types.h                             \
 339         sys/un.h                                \
 340         locale.h                                \
 341         termcap.h                               \
 342         termio.h                                \
 343         termios.h                               \
 344         time.h                                  \
 345         tmpdir.h                                \
 346         udb.h                                   \
 347         util.h                                  \
 348         utmp.h                                  \
 349         utmpx.h                                 \
 350 ])
 351
 352 dnl On Solaris 8 there's a compilation warning for term.h because
 353 dnl it doesn't define `bool'.
 354 AC_CHECK_HEADERS(term.h, , , -)
 355
 356 dnl aix have asl.h (A/IX screen library) that we don't want
 357 AC_CHECK_HEADERS(asl.h, , , [
 358 #include <asl.h>
 359 #ifndef ASL_STRING_EMERG
 360 #error ASL_STRING_EMERG missing
 361 #endif])
 362
 363 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 364 #if HAVE_SYS_SOCKET_H
 365 #include <sys/socket.h>
 366 #endif])
 367
 368 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 369 #if HAVE_SYS_TTY_H
 370 #include <sys/tty.h>
 371 #endif])
 372
 373 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 374 #if HAVE_TERMIOS_H
 375 #include <termios.h>
 376 #endif
 377 #if HAVE_SYS_STREAM_H
 378 #include <sys/stream.h>
 379 #endif])
 380
 381 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 382 #if HAVE_SYS_TYPES_H
 383 #include <sys/types.h>
 384 #endif
 385 #if HAVE_SYS_PARAM_H
 386 #include <sys/param.h>
 387 #endif])
 388
 389 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 390 #include <security/pam_appl.h>
 391 ])
 392
 393 dnl export symbols
 394 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 395 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 396 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 397
 398 dnl Checks for libraries.
 399
 400 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 401 #ifdef HAVE_UTIL_H
 402 #include <util.h>
 403 #endif
 404 ],[0,0,0])
 405 AC_FIND_FUNC_NO_LIBS(logout, util,[
 406 #ifdef HAVE_UTIL_H
 407 #include <util.h>
 408 #endif
 409 ],[0])
 410 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 411 #ifdef HAVE_UTIL_H
 412 #include <util.h>
 413 #endif
 414 ],[0,0,0,0,0])
 415
 416 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 417 #ifdef HAVE_TERMCAP_H
 418 #include <termcap.h>
 419 #endif
 420 #ifdef HAVE_CURSES_H
 421 #include <curses.h>
 422 #endif
 423 ],[0,0])
 424
 425 dnl Checks for library functions.
 426
 427 AC_CHECK_FUNCS([                                \
 428         _getpty                                 \
 429         _scrsize                                \
 430         arc4random                              \
 431         fcntl                                   \
 432         getpeereid                              \
 433         getpeerucred                            \
 434         grantpt                                 \
 435         mktime                                  \
 436         ptsname                                 \
 437         rand                                    \
 438         revoke                                  \
 439         select                                  \
 440         setitimer                               \
 441         setpcred                                \
 442         setpgid                                 \
 443         setproctitle                            \
 444         setregid                                \
 445         setresgid                               \
 446         setresuid                               \
 447         setreuid                                \
 448         setsid                                  \
 449         setutent                                \
 450         sigaction                               \
 451         strstr                                  \
 452         ttyname                                 \
 453         ttyslot                                 \
 454         umask                                   \
 455         unlockpt                                \
 456         vhangup                                 \
 457         yp_get_default_domain                   \
 458 ])
 459
 460 AC_FUNC_MMAP
 461
 462 KRB_CAPABILITIES
 463
 464 AC_CHECK_GETPWNAM_R_POSIX
 465
 466 dnl detect doors on solaris
 467 if test "$enable_pthread_support" != no; then
 468    saved_LIBS="$LIBS"
 469    LIBS="$LIBS $PTHREADS_LIBS"
 470    AC_FIND_FUNC_NO_LIBS(door_create, door)
 471    LIBS="$saved_LIBS"
 472 fi
 473
 474 AC_ARG_ENABLE(kcm,
 475         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 476 ,[enable_kcm=yes])
 477
 478 if test "$enable_kcm" = yes ; then
 479    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 480         enable_kcm=no
 481    fi
 482 fi
 483 if test "$enable_kcm" = yes; then
 484        AC_DEFINE(HAVE_KCM, 1,
 485                [Define if you want to use the Kerberos Credentials Manager.])
 486 fi
 487 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 488
 489
 490
 491 dnl Cray stuff
 492 AC_CHECK_FUNCS(getudbnam setlim)
 493
 494 dnl AC_KRB_FUNC_GETCWD_BROKEN
 495
 496 dnl
 497 dnl Check for fields in struct utmp
 498 dnl
 499
 500 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 501 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 502 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 503 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 504 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 505 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 506 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 507 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 508
 509 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 510         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 511         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 512 #ifdef HAVE_INTTYPES_H
 513 #include <inttypes.h>
 514 #endif
 515 #ifdef HAVE_SYS_TYPES_H
 516 #include <sys/types.h>
 517 #endif
 518 #ifdef HAVE_SYS_BITYPES_H
 519 #include <sys/bitypes.h>
 520 #endif
 521 #ifdef HAVE_BIND_BITYPES_H
 522 #include <bind/bitypes.h>
 523 #endif
 524 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 525 #include <netinet/in6_machtypes.h>
 526 #endif
 527 ])
 528
 529 rk_FRAMEWORK_SECURITY
 530
 531 KRB_READLINE
 532
 533 rk_TELNET
 534
 535 dnl Some operating systems already have com_err and compile_et
 536 CHECK_COMPILE_ET
 537
 538 rk_AUTH_MODULES([sia afskauthlib])
 539
 540 rk_DESTDIRS
 541
 542 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 543
 544
 545 AH_BOTTOM([#ifdef ROKEN_RENAME
 546 #include "roken_rename.h"
 547 #endif])
 548
 549 AC_CONFIG_FILES(Makefile                \
 550         etc/Makefile                    \
 551         include/Makefile                \
 552         include/gssapi/Makefile         \
 553         include/hcrypto/Makefile        \
 554         include/kadm5/Makefile          \
 555         lib/Makefile                    \
 556         lib/auth/Makefile               \
 557         lib/auth/afskauthlib/Makefile   \
 558         lib/auth/pam/Makefile           \
 559         lib/auth/sia/Makefile           \
 560         lib/asn1/Makefile               \
 561         lib/com_err/Makefile            \
 562         lib/hcrypto/Makefile            \
 563         lib/editline/Makefile           \
 564         lib/hx509/Makefile              \
 565         lib/gssapi/Makefile             \
 566         lib/ntlm/Makefile               \
 567         lib/hdb/Makefile                \
 568         lib/ipc/Makefile                \
 569         lib/kadm5/Makefile              \
 570         lib/kafs/Makefile               \
 571         lib/kdfs/Makefile               \
 572         lib/krb5/Makefile               \
 573         lib/otp/Makefile                \
 574         lib/roken/Makefile              \
 575         lib/sl/Makefile                 \
 576         lib/sqlite/Makefile             \
 577         lib/vers/Makefile               \
 578         lib/wind/Makefile               \
 579         po/Makefile                     \
 580         kuser/Makefile                  \
 581         kpasswd/Makefile                \
 582         kadmin/Makefile                 \
 583         admin/Makefile                  \
 584         kcm/Makefile                    \
 585         kdc/Makefile                    \
 586         appl/Makefile                   \
 587         appl/afsutil/Makefile           \
 588         appl/ftp/Makefile               \
 589         appl/ftp/common/Makefile        \
 590         appl/ftp/ftp/Makefile           \
 591         appl/ftp/ftpd/Makefile          \
 592         appl/gssmask/Makefile           \
 593         appl/kx/Makefile                \
 594         appl/login/Makefile             \
 595         appl/otp/Makefile               \
 596         appl/popper/Makefile            \
 597         appl/push/Makefile              \
 598         appl/rsh/Makefile               \
 599         appl/rcp/Makefile               \
 600         appl/su/Makefile                \
 601         appl/xnlock/Makefile            \
 602         appl/telnet/Makefile            \
 603         appl/telnet/libtelnet/Makefile  \
 604         appl/telnet/telnet/Makefile     \
 605         appl/telnet/telnetd/Makefile    \
 606         appl/test/Makefile              \
 607         appl/kf/Makefile                \
 608         appl/dceutils/Makefile          \
 609         tests/Makefile                  \
 610         tests/bin/Makefile              \
 611         tests/can/Makefile              \
 612         tests/db/Makefile               \
 613         tests/kdc/Makefile              \
 614         tests/ldap/Makefile             \
 615         tests/gss/Makefile              \
 616         tests/java/Makefile             \
 617         tests/plugin/Makefile           \
 618         packages/Makefile               \
 619         packages/mac/Makefile           \
 620         doc/Makefile                    \
 621         tools/Makefile                  \
 622 )
 623
 624 AC_OUTPUT
 625
 626 dnl
 627 dnl This is the release version name-number[beta]
 628 dnl
 629
 630 cat > include/newversion.h.in <<EOF
 631 const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 632 const char *heimdal_version = "AC_PACKAGE_STRING";
 633 EOF
 634
 635 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 636         echo "include/version.h is unchanged"
 637         rm -f include/newversion.h.in
 638 else
 639         echo "creating include/version.h"
 640         User=${USER-${LOGNAME}}
 641         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 642         Date=`date`
 643         mv -f include/newversion.h.in include/version.h.in
 644         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 645 fi