source3/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(include/includes.h)
   3 AC_CONFIG_HEADER(include/config.h)
   4
   5 dnl Checks for programs.
   6 AC_PROG_CC
   7 AC_PROG_INSTALL
   8 AC_SUBST(SHELL)
   9 AC_SUBST(MPROGS)
  10 AC_SUBST(LDSHFLAGS)
  11 AC_SUBST(HOST_OS)
  12 AC_SUBST(WRAP32)
  13 AC_SUBST(PICFLAG)
  14 AC_PROG_AWK
  15
  16 AC_CANONICAL_SYSTEM
  17 AC_VALIDATE_CACHE_SYSTEM_TYPE
  18 SAMBA_MAINTAINER_MODE
  19
  20
  21
  22 # this bit needs to be modified for each OS that is suported by
  23 # smbwrapper. You need to specify how to created a shared library and
  24 # how to compile C code to produce PIC object files
  25
  26 # these are the defaults, good for lots of systems
  27 PICFLAG="-fpic"
  28 HOST_OS="$host_os"
  29 LDSHFLAGS="-shared"
  30
  31 # and these are for particular systems
  32 case "$host_os" in
  33         *linux*)   AC_DEFINE(LINUX);;
  34         *solaris*) AC_DEFINE(SUNOS5)
  35                    LDSHFLAGS="-G";;
  36         *sunos*) AC_DEFINE(SUNOS4);;
  37         *irix*) AC_DEFINE(IRIX)
  38                 WRAP32=smbwrapper/smbwrapper.32.so
  39                 PICFLAG="-KPIC"
  40                 ;;
  41         *aix*) AC_DEFINE(AIX);;
  42         *hpux*) AC_DEFINE(HPUX);;
  43         *qnx*) AC_DEFINE(QNX);;
  44         *osf*) AC_DEFINE(OSF1);;
  45         *sco*) AC_DEFINE(SCO);;
  46         *next2*) AC_DEFINE(NEXT2);;
  47 esac
  48
  49 AC_INLINE
  50 AC_HEADER_STDC
  51 AC_HEADER_DIRENT
  52 AC_HEADER_TIME
  53 AC_HEADER_SYS_WAIT
  54 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h)
  55 AC_CHECK_HEADERS(unistd.h utime.h grp.h sys/id.h limits.h memory.h net/if.h)
  56 AC_CHECK_HEADERS(compat.h rpc/types.h rpc/xdr.h rpc/auth.h rpc/clnt.h)
  57 AC_CHECK_HEADERS(rpcsvc/yp_prot.h rpcsvc/ypclnt.h sys/param.h ctype.h )
  58 AC_CHECK_HEADERS(sys/wait.h sys/resource.h sys/ioctl.h sys/mode.h)
  59 AC_CHECK_HEADERS(sys/filio.h string.h strings.h stdlib.h sys/socket.h)
  60 AC_CHECK_HEADERS(sys/mount.h sys/vfs.h sys/fs/s5param.h sys/filsys.h termios.h)
  61 AC_CHECK_HEADERS(sys/statfs.h sys/dustat.h sys/statvfs.h stdarg.h sys/sockio.h)
  62 AC_CHECK_HEADERS(shadow.h netinet/tcp.h sys/security.h security/pam_appl.h)
  63 AC_CHECK_HEADERS(stropts.h poll.h readline.h history.h readline/readline.h)
  64 AC_CHECK_HEADERS(readline/history.h sys/capability.h syscall.h sys/syscall.h)
  65 AC_CHECK_HEADERS(sys/acl.h sys/cdefs.h)
  66
  67 AC_CHECK_SIZEOF(int,cross)
  68 AC_CHECK_SIZEOF(long,cross)
  69 AC_CHECK_SIZEOF(short,cross)
  70
  71 AC_C_CONST
  72 AC_C_INLINE
  73 AC_C_BIGENDIAN
  74 AC_C_CHAR_UNSIGNED
  75
  76 AC_TYPE_SIGNAL
  77 AC_TYPE_UID_T
  78 AC_TYPE_MODE_T
  79 AC_TYPE_OFF_T
  80 AC_TYPE_SIZE_T
  81 AC_TYPE_PID_T
  82 AC_STRUCT_ST_RDEV
  83 AC_DIRENT_D_OFF
  84 AC_CHECK_TYPE(ino_t,unsigned)
  85 AC_CHECK_TYPE(loff_t,off_t)
  86 AC_CHECK_TYPE(offset_t,loff_t)
  87 AC_CHECK_TYPE(ssize_t, int)
  88
  89 AC_CACHE_CHECK([for errno in errno.h],samba_cv_errno, [
  90     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
  91         samba_cv_errno=yes,samba_cv_have_errno_decl=no)])
  92 if test x"$samba_cv_errno" = x"yes"; then
  93    AC_DEFINE(HAVE_ERRNO_DECL)
  94 fi
  95
  96 # stupid glibc has the functions but no declaration. grrrr.
  97 AC_CACHE_CHECK([for setresuid declaration],samba_cv_have_setresuid_decl,[
  98     AC_TRY_COMPILE([#include <unistd.h>],[int i = setresuid],
  99         samba_cv_have_setresuid_decl=yes,samba_cv_have_setresuid_decl=no)])
 100 if test x"$samba_cv_have_setresuid_decl" = x"yes"; then
 101     AC_DEFINE(HAVE_SETRESUID_DECL)
 102 fi
 103
 104 # and glibc has setresuid under linux but the function does
 105 # nothing until kernel 2.1.44! very dumb.
 106 AC_CACHE_CHECK([for real setresuid],samba_cv_have_setresuid,[
 107     AC_TRY_RUN([#include <errno.h>
 108 main() { setresuid(1,1,1); setresuid(2,2,2); exit(errno==EPERM?0:1);}],
 109         samba_cv_have_setresuid=yes,samba_cv_have_setresuid=no,samba_cv_have_setresuid=cross)])
 110 if test x"$samba_cv_have_setresuid" = x"yes"; then
 111     AC_DEFINE(HAVE_SETRESUID)
 112 fi
 113
 114 AC_FUNC_MEMCMP
 115
 116 ###############################################
 117 # test for where we get crypt() from
 118 AC_CHECK_FUNCS(crypt)
 119 if test x"$ac_cv_func_crypt" = x"no"; then
 120     AC_CHECK_LIB(crypt, crypt, [LIBS="$LIBS -lcrypt";
 121         AC_DEFINE(HAVE_CRYPT)])
 122 fi
 123
 124
 125 ###############################################
 126 # test for where we get pam_authenticate() from
 127 # might need libdl for this to work
 128 if test "$ac_cv_header_security_pam_appl_h" = "yes"; then
 129   AC_CHECK_LIB(dl,main)
 130 fi
 131 AC_CHECK_FUNCS(pam_authenticate)
 132 if test x"$ac_cv_func_pam_authenticate" = x"no"; then
 133     AC_CHECK_LIB(pam, pam_authenticate, [LIBS="$LIBS -lpam"
 134         AC_DEFINE(HAVE_PAM_AUTHENTICATE)])
 135 fi
 136
 137
 138 ###############################################
 139 # test for where we get readline() from
 140 if test "$ac_cv_header_readline_h" = "yes" ||
 141    test "$ac_cv_header_readline_readline_h" = "yes"; then
 142   AC_CHECK_LIB(readline,readline)
 143 fi
 144
 145
 146 # The following test taken from the cvs sources
 147 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 148 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 149 # libsocket.so which has a bad implementation of gethostbyname (it
 150 # only looks in /etc/hosts), so we only look for -lsocket if we need
 151 # it.
 152 AC_CHECK_FUNCS(connect)
 153 if test x"$ac_cv_func_connect" = x"no"; then
 154     case "$LIBS" in
 155     *-lnsl*) ;;
 156     *) AC_CHECK_LIB(nsl_s, printf) ;;
 157     esac
 158     case "$LIBS" in
 159     *-lnsl*) ;;
 160     *) AC_CHECK_LIB(nsl, printf) ;;
 161     esac
 162     case "$LIBS" in
 163     *-lsocket*) ;;
 164     *) AC_CHECK_LIB(socket, connect) ;;
 165     esac
 166     case "$LIBS" in
 167     *-linet*) ;;
 168     *) AC_CHECK_LIB(inet, connect) ;;
 169     esac
 170     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 171     dnl has been cached.
 172     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 173        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 174         # ac_cv_func_connect=yes
 175         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 176         AC_DEFINE(HAVE_CONNECT)
 177     fi
 178 fi
 179
 180
 181 AC_CHECK_FUNCS(waitpid getcwd strdup strerror chown chmod chroot)
 182 AC_CHECK_FUNCS(fstat strchr utime utimes getrlimit fsync execl bzero memset)
 183 AC_CHECK_FUNCS(memmove vsnprintf setsid glob strpbrk pipe crypt16 getauthuid)
 184 AC_CHECK_FUNCS(strftime sigprocmask sigblock sigaction innetgr)
 185 AC_CHECK_FUNCS(initgroups select rdchk getgrnam pathconf putprpwnam)
 186 AC_CHECK_FUNCS(setuidx setgroups mktime rename ftruncate stat64 fstat64 lstat64)
 187 AC_CHECK_FUNCS(set_auth_parameters atexit grantpt getspnam dup2 lseek64 ftruncate64)
 188 AC_CHECK_FUNCS(fseek64 ftell64 bigcrypt getprpwnam setluid yp_get_default_domain getpwanam)
 189 AC_CHECK_FUNCS(srandom random srand rand setenv)
 190
 191 AC_CHECK_FUNCS(_dup _dup2 _opendir _readdir _seekdir _telldir _closedir)
 192 AC_CHECK_FUNCS(__dup __dup2 __opendir __readdir __seekdir __telldir __closedir)
 193 AC_CHECK_FUNCS(__getcwd _getcwd)
 194 AC_CHECK_FUNCS(__xstat __fxstat __lxstat)
 195 AC_CHECK_FUNCS(_stat _lstat _fstat __stat __lstat __fstat)
 196 AC_CHECK_FUNCS(_acl __acl _facl __facl _open __open _chdir __chdir)
 197 AC_CHECK_FUNCS(_close __close _fchdir __fchdir _fcntl __fcntl)
 198 AC_CHECK_FUNCS(getdents _getdents __getdents _lseek __lseek _read __read)
 199 AC_CHECK_FUNCS(_write __write _fork __fork)
 200 AC_CHECK_FUNCS(_stat64 __stat64 _fstat64 __fstat64 _lstat64 __lstat64)
 201 AC_CHECK_FUNCS(__sys_llseek llseek _llseek __llseek readdir64 _readdir64 __readdir64)
 202 AC_CHECK_FUNCS(pread _pread __pread pread64 _pread64 __pread64)
 203 AC_CHECK_FUNCS(pwrite _pwrite __pwrite pwrite64 _pwrite64 __pwrite64)
 204 AC_CHECK_FUNCS(open64 _open64 __open64 creat64)
 205
 206 AC_CACHE_CHECK([for long long],samba_cv_have_longlong,[
 207 AC_TRY_RUN([#include <stdio.h>
 208 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
 209 samba_cv_have_longlong=yes,samba_cv_have_longlong=no,samba_cv_have_longlong=cross)])
 210 if test x"$samba_cv_have_longlong" = x"yes"; then
 211     AC_DEFINE(HAVE_LONGLONG)
 212 fi
 213
 214 AC_CACHE_CHECK([for 64 bit off_t],samba_cv_SIZEOF_OFF_T,[
 215 AC_TRY_RUN([#include <stdio.h>
 216 #include <sys/stat.h>
 217 main() { exit((sizeof(off_t) == 8) ? 0 : 1); }],
 218 samba_cv_SIZEOF_OFF_T=yes,samba_cv_SIZEOF_OFF_T=no,samba_cv_SIZEOF_OFF_T=cross)])
 219 if test x"$samba_cv_SIZEOF_OFF_T" = x"yes"; then
 220     AC_DEFINE(SIZEOF_OFF_T,8)
 221 fi
 222
 223 AC_CACHE_CHECK([for off64_t],samba_cv_HAVE_OFF64_T,[
 224 AC_TRY_RUN([#include <stdio.h>
 225 #include <sys/stat.h>
 226 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
 227 samba_cv_HAVE_OFF64_T=yes,samba_cv_HAVE_OFF64_T=no,samba_cv_HAVE_OFF64_T=cross)])
 228 if test x"$samba_cv_HAVE_OFF64_T" = x"yes"; then
 229     AC_DEFINE(HAVE_OFF64_T)
 230 fi
 231
 232 AC_CACHE_CHECK([for 64 bit ino_t],samba_cv_SIZEOF_INO_T,[
 233 AC_TRY_RUN([#include <stdio.h>
 234 #include <sys/stat.h>
 235 main() { exit((sizeof(ino_t) == 8) ? 0 : 1); }],
 236 samba_cv_SIZEOF_INO_T=yes,samba_cv_SIZEOF_INO_T=no,samba_cv_SIZEOF_INO_T=cross)])
 237 if test x"$samba_cv_SIZEOF_INO_T" = x"yes"; then
 238     AC_DEFINE(SIZEOF_INO_T,8)
 239 fi
 240
 241 AC_CACHE_CHECK([for ino64_t],samba_cv_HAVE_INO64_T,[
 242 AC_TRY_RUN([#include <stdio.h>
 243 #include <sys/stat.h>
 244 main() { struct stat64 st; ino64_t s; if (sizeof(ino_t) == sizeof(ino64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
 245 samba_cv_HAVE_INO64_T=yes,samba_cv_HAVE_INO64_T=no,samba_cv_HAVE_INO64_T=cross)])
 246 if test x"$samba_cv_HAVE_INO64_T" = x"yes"; then
 247     AC_DEFINE(HAVE_INO64_T)
 248 fi
 249
 250 AC_CACHE_CHECK([for union semun],samba_cv_HAVE_UNION_SEMUN,[
 251 AC_TRY_RUN([
 252 #include <sys/types.h>
 253 #include <sys/ipc.h>
 254 #include <sys/sem.h>
 255 main() { union semun ss; exit(0); }],
 256 samba_cv_HAVE_UNION_SEMUN=yes,samba_cv_HAVE_UNION_SEMUN=no,samba_cv_HAVE_UNION_SEMUN=cross)])
 257 if test x"$samba_cv_HAVE_UNION_SEMUN" = x"yes"; then
 258     AC_DEFINE(HAVE_UNION_SEMUN)
 259 fi
 260
 261 AC_CACHE_CHECK([for unsigned char],samba_cv_HAVE_UNSIGNED_CHAR,[
 262 AC_TRY_RUN([#include <stdio.h>
 263 main() { char c; c=250; exit((c > 0)?0:1); }],
 264 samba_cv_HAVE_UNSIGNED_CHAR=yes,samba_cv_HAVE_UNSIGNED_CHAR=no,samba_cv_HAVE_UNSIGNED_CHAR=cross)])
 265 if test x"$samba_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
 266     AC_DEFINE(HAVE_UNSIGNED_CHAR)
 267 fi
 268
 269 AC_CACHE_CHECK([for sin_len in sock],samba_cv_HAVE_SOCK_SIN_LEN,[
 270 AC_TRY_COMPILE([#include <sys/types.h>
 271 #include <sys/socket.h>
 272 #include <netinet/in.h>],
 273 [struct sockaddr_in sock; sock.sin_len = sizeof(sock);],
 274 samba_cv_HAVE_SOCK_SIN_LEN=yes,samba_cv_HAVE_SOCK_SIN_LEN=no)])
 275 if test x"$samba_cv_HAVE_SOCK_SIN_LEN" = x"yes"; then
 276     AC_DEFINE(HAVE_SOCK_SIN_LEN)
 277 fi
 278
 279 AC_CACHE_CHECK([whether seekdir returns void],samba_cv_SEEKDIR_RETURNS_VOID,[
 280 AC_TRY_COMPILE([#include <sys/types.h>
 281 #include <dirent.h>
 282 void seekdir(DIR *d, long loc) { return; }],[return 0;],
 283 samba_cv_SEEKDIR_RETURNS_VOID=yes,samba_cv_SEEKDIR_RETURNS_VOID=no)])
 284 if test x"$samba_cv_SEEKDIR_RETURNS_VOID" = x"yes"; then
 285     AC_DEFINE(SEEKDIR_RETURNS_VOID)
 286 fi
 287
 288 AC_CACHE_CHECK([for __FILE__ macro],samba_cv_HAVE_FILE_MACRO,[
 289 AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __FILE__);],
 290 samba_cv_HAVE_FILE_MACRO=yes,samba_cv_HAVE_FILE_MACRO=no)])
 291 if test x"$samba_cv_HAVE_FILE_MACRO" = x"yes"; then
 292     AC_DEFINE(HAVE_FILE_MACRO)
 293 fi
 294
 295 AC_CACHE_CHECK([for __FUNCTION__ macro],samba_cv_HAVE_FUNCTION_MACRO,[
 296 AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __FUNCTION__);],
 297 samba_cv_HAVE_FUNCTION_MACRO=yes,samba_cv_HAVE_FUNCTION_MACRO=no)])
 298 if test x"$samba_cv_HAVE_FUNCTION_MACRO" = x"yes"; then
 299     AC_DEFINE(HAVE_FUNCTION_MACRO)
 300 fi
 301
 302 AC_CACHE_CHECK([if gettimeofday takes tz argument],samba_cv_HAVE_GETTIMEOFDAY_TZ,[
 303 AC_TRY_RUN([
 304 #include <sys/time.h>
 305 #include <unistd.h>
 306 main() { struct timeval tv; exit(gettimeofday(&tv, NULL));}],
 307            samba_cv_HAVE_GETTIMEOFDAY_TZ=yes,samba_cv_HAVE_GETTIMEOFDAY_TZ=no,samba_cv_HAVE_GETTIMEOFDAY_TZ=cross)])
 308 if test x"$samba_cv_HAVE_GETTIMEOFDAY_TZ" = x"yes"; then
 309     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ)
 310 fi
 311
 312
 313 AC_CACHE_CHECK([for broken readdir],samba_cv_HAVE_BROKEN_READDIR,[
 314 AC_TRY_RUN([#include <sys/types.h>
 315 #include <dirent.h>
 316 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 317 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 318 di->d_name[0] == 0) exit(0); exit(1);} ],
 319 samba_cv_HAVE_BROKEN_READDIR=yes,samba_cv_HAVE_BROKEN_READDIR=no,samba_cv_HAVE_BROKEN_READDIR=cross)])
 320 if test x"$samba_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 321     AC_DEFINE(HAVE_BROKEN_READDIR)
 322 fi
 323
 324 AC_CACHE_CHECK([for utimbuf],samba_cv_HAVE_UTIMBUF,[
 325 AC_TRY_COMPILE([#include <sys/types.h>
 326 #include <utime.h>],
 327 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 328 samba_cv_HAVE_UTIMBUF=yes,samba_cv_HAVE_UTIMBUF=no,samba_cv_HAVE_UTIMBUF=cross)])
 329 if test x"$samba_cv_HAVE_UTIMBUF" = x"yes"; then
 330     AC_DEFINE(HAVE_UTIMBUF)
 331 fi
 332
 333 AC_CACHE_CHECK([for kernel oplock type definitions],samba_cv_HAVE_KERNEL_OPLOCKS,[
 334 AC_TRY_COMPILE([#include <sys/types.h>
 335 #include <fcntl.h>],
 336 [oplock_stat_t t; t.os_state = OP_REVOKE; t.os_dev = 1; t.os_ino = 1;],
 337 samba_cv_HAVE_KERNEL_OPLOCKS=yes,samba_cv_HAVE_KERNEL_OPLOCKS=no)])
 338 if test x"$samba_cv_HAVE_KERNEL_OPLOCKS" = x"yes"; then
 339     AC_DEFINE(HAVE_KERNEL_OPLOCKS)
 340 fi
 341
 342 AC_CACHE_CHECK([for irix specific capabilities],samba_cv_HAVE_IRIX_SPECIFIC_CAPABILITIES,[
 343 AC_TRY_RUN([#include <sys/types.h>
 344 #include <sys/capability.h>
 345 main() {
 346  cap_t cap;
 347  if ((cap = cap_get_proc()) == NULL)
 348    exit(1);
 349  cap->cap_effective |= CAP_NETWORK_MGT;
 350  cap->cap_inheritable |= CAP_NETWORK_MGT;
 351  cap_set_proc(cap);
 352  exit(0);
 353 }
 354 ],
 355 samba_cv_HAVE_IRIX_SPECIFIC_CAPABILITIES=yes,samba_cv_HAVE_IRIX_SPECIFIC_CAPABILITIES=no,samba_cv_HAVE_IRIX_SPECIFIC_CAPABILITIES=cross)])
 356 if test x"$samba_cv_HAVE_IRIX_SPECIFIC_CAPABILITIES" = x"yes"; then
 357     AC_DEFINE(HAVE_IRIX_SPECIFIC_CAPABILITIES)
 358 fi
 359
 360 AC_MSG_CHECKING([for test routines])
 361 AC_TRY_RUN([#include "${srcdir-.}/tests/trivial.c"],
 362            AC_MSG_RESULT(yes),
 363            AC_MSG_ERROR([cant find test code. Aborting config]),
 364            AC_MSG_WARN([cannot run when cross-compiling]))
 365
 366 AC_CACHE_CHECK([for ftruncate extend],samba_cv_HAVE_FTRUNCATE_EXTEND,[
 367 AC_TRY_RUN([#include "${srcdir-.}/tests/ftruncate.c"],
 368            samba_cv_HAVE_FTRUNCATE_EXTEND=yes,samba_cv_HAVE_FTRUNCATE_EXTEND=no,samba_cv_HAVE_FTRUNCATE_EXTEND=cross)])
 369 if test x"$samba_cv_HAVE_FTRUNCATE_EXTEND" = x"yes"; then
 370     AC_DEFINE(HAVE_FTRUNCATE_EXTEND)
 371 fi
 372
 373 AC_CACHE_CHECK([for broken getgroups],samba_cv_HAVE_BROKEN_GETGROUPS,[
 374 AC_TRY_RUN([#include "${srcdir-.}/tests/getgroups.c"],
 375            samba_cv_HAVE_BROKEN_GETGROUPS=yes,samba_cv_HAVE_BROKEN_GETGROUPS=no,samba_cv_HAVE_BROKEN_GETGROUPS=cross)])
 376 if test x"$samba_cv_HAVE_BROKEN_GETGROUPS" = x"yes"; then
 377     AC_DEFINE(HAVE_BROKEN_GETGROUPS)
 378 fi
 379
 380 AC_CACHE_CHECK([whether getpass should be replaced],samba_cv_REPLACE_GETPASS,[
 381 SAVE_CPPFLAGS="$CPPFLAGS"
 382 CPPFLAGS="$CPPFLAGS -I${srcdir-.}/include -I${srcdir-.}/ubiqx"
 383 AC_TRY_COMPILE([
 384 #define REPLACE_GETPASS 1
 385 #define NO_CONFIG_H 1
 386 #define main dont_declare_main
 387 #include "${srcdir-.}/lib/getsmbpass.c"
 388 #undef main
 389 ],[],samba_cv_REPLACE_GETPASS=yes,samba_cv_REPLACE_GETPASS=no)
 390 CPPFLAGS="$SAVE_CPPFLAGS"
 391 ])
 392 if test x"$samba_cv_REPLACE_GETPASS" = x"yes"; then
 393         AC_DEFINE(REPLACE_GETPASS)
 394 fi
 395
 396 AC_CACHE_CHECK([for broken inet_ntoa],samba_cv_REPLACE_INET_NTOA,[
 397 AC_TRY_RUN([
 398 #include <stdio.h>
 399 #include <sys/types.h>
 400 #include <netinet/in.h>
 401 #include <arpa/inet.h>
 402 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 403 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 404     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(0); }
 405 exit(1);}],
 406            samba_cv_REPLACE_INET_NTOA=yes,samba_cv_REPLACE_INET_NTOA=no,samba_cv_REPLACE_INET_NTOA=cross)])
 407 if test x"$samba_cv_REPLACE_INET_NTOA" = x"yes"; then
 408     AC_DEFINE(REPLACE_INET_NTOA)
 409 fi
 410
 411 AC_CACHE_CHECK([for root],samba_cv_HAVE_ROOT,[
 412 AC_TRY_RUN([main() { exit(getuid() != 0); }],
 413            samba_cv_HAVE_ROOT=yes,samba_cv_HAVE_ROOT=no,samba_cv_HAVE_ROOT=cross)])
 414 if test x"$samba_cv_HAVE_ROOT" = x"yes"; then
 415     AC_DEFINE(HAVE_ROOT)
 416 else
 417     AC_MSG_WARN(running as non-root will disable some tests)
 418 fi
 419
 420 netmask=no;
 421 AC_CACHE_CHECK([for netmask ifconf],samba_cv_HAVE_NETMASK_IFCONF,[
 422 AC_TRY_RUN([
 423 #define HAVE_NETMASK_IFCONF 1
 424 #define AUTOCONF 1
 425 #include "${srcdir-.}/lib/netmask.c"],
 426            samba_cv_HAVE_NETMASK_IFCONF=yes,samba_cv_HAVE_NETMASK_IFCONF=no,samba_cv_HAVE_NETMASK_IFCONF=cross)])
 427 if test x"$samba_cv_HAVE_NETMASK_IFCONF" = x"yes"; then
 428     netmask=yes;AC_DEFINE(HAVE_NETMASK_IFCONF)
 429 fi
 430
 431 if test $netmask = no; then
 432 AC_CACHE_CHECK([for netmask ifreq],samba_cv_HAVE_NETMASK_IFREQ,[
 433 AC_TRY_RUN([
 434 #define HAVE_NETMASK_IFREQ 1
 435 #define AUTOCONF 1
 436 #include "${srcdir-.}/lib/netmask.c"],
 437            samba_cv_HAVE_NETMASK_IFREQ=yes,samba_cv_HAVE_NETMASK_IFREQ=no,samba_cv_HAVE_NETMASK_IFREQ=cross)])
 438 if test x"$samba_cv_HAVE_NETMASK_IFREQ" = x"yes"; then
 439     netmask=yes;AC_DEFINE(HAVE_NETMASK_IFREQ)
 440 fi
 441 fi
 442
 443 if test $netmask = no; then
 444 AC_CACHE_CHECK([for netmask AIX],samba_cv_HAVE_NETMASK_AIX,[
 445 AC_TRY_RUN([
 446 #define HAVE_NETMASK_AIX 1
 447 #define AUTOCONF 1
 448 #include "${srcdir-.}/lib/netmask.c"],
 449            samba_cv_HAVE_NETMASK_AIX=yes,samba_cv_HAVE_NETMASK_AIX=no,samba_cv_HAVE_NETMASK_AIX=cross)])
 450 if test x"$samba_cv_HAVE_NETMASK_AIX" = x"yes"; then
 451     netmask=yes;AC_DEFINE(HAVE_NETMASK_AIX)
 452 fi
 453 fi
 454
 455 AC_CACHE_CHECK([for trapdoor seteuid],samba_cv_HAVE_TRAPDOOR_UID,[
 456 AC_TRY_RUN([#include "${srcdir-.}/tests/trapdoor.c"],
 457            samba_cv_HAVE_TRAPDOOR_UID=no,samba_cv_HAVE_TRAPDOOR_UID=yes,:)])
 458 if test x"$samba_cv_HAVE_TRAPDOOR_UID" = x"yes"; then
 459     AC_DEFINE(HAVE_TRAPDOOR_UID)
 460 fi
 461
 462 AC_CACHE_CHECK([for shared mmap],samba_cv_HAVE_SHARED_MMAP,[
 463 AC_TRY_RUN([#include "${srcdir-.}/tests/shared_mmap.c"],
 464            samba_cv_HAVE_SHARED_MMAP=yes,samba_cv_HAVE_SHARED_MMAP=no,samba_cv_HAVE_SHARED_MMAP=cross)])
 465 if test x"$samba_cv_HAVE_SHARED_MMAP" = x"yes"; then
 466     AC_DEFINE(HAVE_SHARED_MMAP)
 467 fi
 468
 469 AC_CACHE_CHECK([for fcntl locking],samba_cv_HAVE_FCNTL_LOCK,[
 470 AC_TRY_RUN([#include "${srcdir-.}/tests/fcntl_lock.c"],
 471            samba_cv_HAVE_FCNTL_LOCK=yes,samba_cv_HAVE_FCNTL_LOCK=no,samba_cv_HAVE_FCNTL_LOCK=cross)])
 472 if test x"$samba_cv_HAVE_FCNTL_LOCK" = x"yes"; then
 473     AC_DEFINE(HAVE_FCNTL_LOCK)
 474 fi
 475
 476 AC_CACHE_CHECK([for 64 bit fcntl locking],samba_cv_HAVE_STRUCT_FLOCK64,[
 477 AC_TRY_RUN([
 478 #include <stdio.h>
 479 #include <stdlib.h>
 480
 481 #ifdef HAVE_FCNTL_H
 482 #include <fcntl.h>
 483 #endif
 484
 485 #ifdef HAVE_SYS_FCNTL_H
 486 #include <sys/fcntl.h>
 487 #endif
 488 main() { struct flock64 fl64;
 489 #if defined(F_SETLKW64) && defined(F_SETLK64) && defined(F_GETLK64)
 490 exit(0);
 491 #else
 492 exit(1);
 493 #endif
 494 }],
 495        samba_cv_HAVE_STRUCT_FLOCK64=yes,samba_cv_HAVE_STRUCT_FLOCK64=no,samba_cv_HAVE_STRUCT_FLOCK64=cross)])
 496 if test x"$samba_cv_HAVE_STRUCT_FLOCK64" = x"yes"; then
 497     AC_DEFINE(HAVE_STRUCT_FLOCK64)
 498 fi
 499
 500 AC_CACHE_CHECK([for sysv ipc],samba_cv_HAVE_SYSV_IPC,[
 501 AC_TRY_RUN([#include "${srcdir-.}/tests/sysv_ipc.c"],
 502            samba_cv_HAVE_SYSV_IPC=yes,samba_cv_HAVE_SYSV_IPC=no,samba_cv_HAVE_SYSV_IPC=cross)])
 503 if test x"$samba_cv_HAVE_SYSV_IPC" = x"yes"; then
 504     AC_DEFINE(HAVE_SYSV_IPC)
 505 fi
 506
 507 #################################################
 508 # check for the AFS filesystem
 509 AC_MSG_CHECKING(whether to use AFS)
 510 AC_ARG_WITH(afs,
 511 [  --with-afs     Include AFS support
 512   --without-afs  Don't include AFS support (default)],
 513 [ case "$withval" in
 514   yes)
 515     AC_MSG_RESULT(yes)
 516     AC_DEFINE(WITH_AFS)
 517     ;;
 518   *)
 519     AC_MSG_RESULT(no)
 520     ;;
 521   esac ],
 522   AC_MSG_RESULT(no)
 523 )
 524
 525
 526 #################################################
 527 # check for the DFS auth system
 528 AC_MSG_CHECKING(whether to use DFS auth)
 529 AC_ARG_WITH(dfs,
 530 [  --with-dfs     Include DFS support
 531   --without-dfs  Don't include DFS support (default)],
 532 [ case "$withval" in
 533   yes)
 534     AC_MSG_RESULT(yes)
 535     AC_DEFINE(WITH_DFS)
 536     ;;
 537   *)
 538     AC_MSG_RESULT(no)
 539     ;;
 540   esac ],
 541   AC_MSG_RESULT(no)
 542 )
 543
 544 #################################################
 545 # check for Kerberos IV auth system
 546 AC_MSG_CHECKING(whether to use Kerberos IV)
 547 AC_ARG_WITH(krb4,
 548 [  --with-krb4=base-dir     Include Kerberos IV support
 549   --whithout-krb4          Don't include Kerbers IV support (default)],
 550 [   AC_MSG_RESULT(yes)
 551     AC_DEFINE(KRB4_AUTH)
 552     AC_CHECK_LIB(resolv, dn_expand)
 553     LIBS="$LIBS -lkrb -ldes"
 554     CFLAGS="$CFLAGS -I$withval/include"
 555     LDFLAGS="$LDFLAGS -L$withval/lib"],
 556   AC_MSG_RESULT(no)
 557 )
 558
 559 #################################################
 560 # check for automount support
 561 AC_MSG_CHECKING(whether to use AUTOMOUNT)
 562 AC_ARG_WITH(automount,
 563 [  --with-automount     Include AUTOMOUNT support
 564   --without-automount  Don't include AUTOMOUNT support (default)],
 565 [ case "$withval" in
 566   yes)
 567     AC_MSG_RESULT(yes)
 568     AC_DEFINE(WITH_AUTOMOUNT)
 569     ;;
 570   *)
 571     AC_MSG_RESULT(no)
 572     ;;
 573   esac ],
 574   AC_MSG_RESULT(no)
 575 )
 576
 577 #################################################
 578 # check for smbmount support
 579 AC_MSG_CHECKING(whether to use SMBMOUNT)
 580 AC_ARG_WITH(smbmount,
 581 [  --with-smbmount     Include SMBMOUNT (Linux only) support
 582   --without-smbmount  Don't include SMBMOUNT support (default)],
 583 [ case "$withval" in
 584   yes)
 585     AC_MSG_RESULT(yes)
 586     AC_DEFINE(WITH_SMBMOUNT)
 587     MPROGS="bin/smbmount bin/smbmnt bin/smbumount"
 588     ;;
 589   *)
 590     AC_MSG_RESULT(no)
 591     MPROGS=
 592     ;;
 593   esac ],
 594   AC_MSG_RESULT(no)
 595   MPROGS=
 596 )
 597
 598 #################################################
 599 # check for a LDAP password database
 600 AC_MSG_CHECKING(whether to use LDAP password database)
 601 AC_ARG_WITH(ldap,
 602 [  --with-ldap     Include LDAP support
 603   --without-ldap  Don't include LDAP support (default)],
 604 [ case "$withval" in
 605   yes)
 606     AC_MSG_RESULT(yes)
 607     AC_DEFINE(WITH_LDAP)
 608     ;;
 609   *)
 610     AC_MSG_RESULT(no)
 611     ;;
 612   esac ],
 613   AC_MSG_RESULT(no)
 614 )
 615
 616 #################################################
 617 # check for a NISPLUS password database
 618 AC_MSG_CHECKING(whether to use NISPLUS password database)
 619 AC_ARG_WITH(nisplus,
 620 [  --with-nisplus     Include NISPLUS password database support
 621   --without-nisplus  Don't include NISPLUS password database support (default)],
 622 [ case "$withval" in
 623   yes)
 624     AC_MSG_RESULT(yes)
 625     AC_DEFINE(WITH_NISPLUS)
 626     ;;
 627   *)
 628     AC_MSG_RESULT(no)
 629     ;;
 630   esac ],
 631   AC_MSG_RESULT(no)
 632 )
 633
 634 #################################################
 635 # check for a NISPLUS_HOME support
 636 AC_MSG_CHECKING(whether to use NISPLUS_HOME)
 637 AC_ARG_WITH(nisplus-home,
 638 [  --with-nisplus-home     Include NISPLUS_HOME support
 639   --without-nisplus-home  Don't include NISPLUS_HOME support (default)],
 640 [ case "$withval" in
 641   yes)
 642     AC_MSG_RESULT(yes)
 643     AC_DEFINE(WITH_NISPLUS_HOME)
 644     ;;
 645   *)
 646     AC_MSG_RESULT(no)
 647     ;;
 648   esac ],
 649   AC_MSG_RESULT(no)
 650 )
 651
 652 #################################################
 653 # check for the secure socket layer
 654 AC_MSG_CHECKING(whether to use SSL)
 655 AC_ARG_WITH(ssl,
 656 [  --with-ssl     Include SSL support
 657   --without-ssl  Don't include SSL support (default)],
 658 [ case "$withval" in
 659   yes)
 660     AC_MSG_RESULT(yes)
 661     AC_DEFINE(WITH_SSL)
 662     ;;
 663   *)
 664     AC_MSG_RESULT(no)
 665     ;;
 666   esac ],
 667   AC_MSG_RESULT(no)
 668 )
 669
 670 #################################################
 671 # check for experimental mmap support
 672 AC_MSG_CHECKING(whether to use MMAP)
 673 AC_ARG_WITH(mmap,
 674 [  --with-mmap     Include experimental MMAP support
 675   --without-mmap  Don't include MMAP support (default)],
 676 [ case "$withval" in
 677   yes)
 678     AC_MSG_RESULT(yes)
 679     AC_DEFINE(WITH_MMAP)
 680     ;;
 681   *)
 682     AC_MSG_RESULT(no)
 683     ;;
 684   esac ],
 685   AC_MSG_RESULT(no)
 686 )
 687
 688 #################################################
 689 # check for syslog logging
 690 AC_MSG_CHECKING(whether to use syslog logging)
 691 AC_ARG_WITH(syslog,
 692 [  --with-syslog     Include experimental SYSLOG support
 693   --without-syslog  Don't include SYSLOG support (default)],
 694 [ case "$withval" in
 695   yes)
 696     AC_MSG_RESULT(yes)
 697     AC_DEFINE(WITH_SYSLOG)
 698     ;;
 699   *)
 700     AC_MSG_RESULT(no)
 701     ;;
 702   esac ],
 703   AC_MSG_RESULT(no)
 704 )
 705
 706 #################################################
 707 # check for experimental netatalk resource fork support
 708 AC_MSG_CHECKING(whether to support netatalk)
 709 AC_ARG_WITH(netatalk,
 710 [  --with-netatalk     Include experimental Netatalk support
 711   --without-netatalk  Don't include experimental Netatalk support (default)],
 712 [ case "$withval" in
 713   yes)
 714     AC_MSG_RESULT(yes)
 715     AC_DEFINE(WITH_NETATALK)
 716     ;;
 717   *)
 718     AC_MSG_RESULT(no)
 719     ;;
 720   esac ],
 721   AC_MSG_RESULT(no)
 722 )
 723
 724
 725 #################################################
 726 # these tests are taken from the GNU fileutils package
 727 AC_CHECKING(how to get filesystem space usage)
 728 space=no
 729
 730 # Test for statvfs64.
 731 if test $space = no; then
 732   # SVR4
 733   AC_CACHE_CHECK([statvfs64 function (SVR4)], fu_cv_sys_stat_statvfs64,
 734   [AC_TRY_RUN([
 735 #include <sys/types.h>
 736 #include <sys/statvfs.h>
 737   main ()
 738   {
 739     struct statvfs64 fsd;
 740     exit (statfs64 (".", &fsd));
 741   }],
 742   fu_cv_sys_stat_statvfs64=yes,
 743   fu_cv_sys_stat_statvfs64=no,
 744   fu_cv_sys_stat_statvfs64=cross)])
 745   if test $fu_cv_sys_stat_statvfs64 = yes; then
 746     space=yes
 747     AC_DEFINE(STAT_STATVFS64)
 748   fi
 749 fi
 750
 751 # Perform only the link test since it seems there are no variants of the
 752 # statvfs function.  This check is more than just AC_CHECK_FUNCS(statvfs)
 753 # because that got a false positive on SCO OSR5.  Adding the declaration
 754 # of a `struct statvfs' causes this test to fail (as it should) on such
 755 # systems.  That system is reported to work fine with STAT_STATFS4 which
 756 # is what it gets when this test fails.
 757 if test $space = no; then
 758   # SVR4
 759   AC_CACHE_CHECK([statvfs function (SVR4)], fu_cv_sys_stat_statvfs,
 760                  [AC_TRY_LINK([#include <sys/types.h>
 761 #include <sys/statvfs.h>],
 762                               [struct statvfs fsd; statvfs (0, &fsd);],
 763                               fu_cv_sys_stat_statvfs=yes,
 764                               fu_cv_sys_stat_statvfs=no)])
 765   if test $fu_cv_sys_stat_statvfs = yes; then
 766     space=yes
 767     AC_DEFINE(STAT_STATVFS)
 768   fi
 769 fi
 770
 771 if test $space = no; then
 772   # DEC Alpha running OSF/1
 773   AC_MSG_CHECKING([for 3-argument statfs function (DEC OSF/1)])
 774   AC_CACHE_VAL(fu_cv_sys_stat_statfs3_osf1,
 775   [AC_TRY_RUN([
 776 #include <sys/param.h>
 777 #include <sys/types.h>
 778 #include <sys/mount.h>
 779   main ()
 780   {
 781     struct statfs fsd;
 782     fsd.f_fsize = 0;
 783     exit (statfs (".", &fsd, sizeof (struct statfs)));
 784   }],
 785   fu_cv_sys_stat_statfs3_osf1=yes,
 786   fu_cv_sys_stat_statfs3_osf1=no,
 787   fu_cv_sys_stat_statfs3_osf1=no)])
 788   AC_MSG_RESULT($fu_cv_sys_stat_statfs3_osf1)
 789   if test $fu_cv_sys_stat_statfs3_osf1 = yes; then
 790     space=yes
 791     AC_DEFINE(STAT_STATFS3_OSF1)
 792   fi
 793 fi
 794
 795 if test $space = no; then
 796 # AIX
 797   AC_MSG_CHECKING([for two-argument statfs with statfs.bsize dnl
 798 member (AIX, 4.3BSD)])
 799   AC_CACHE_VAL(fu_cv_sys_stat_statfs2_bsize,
 800   [AC_TRY_RUN([
 801 #ifdef HAVE_SYS_PARAM_H
 802 #include <sys/param.h>
 803 #endif
 804 #ifdef HAVE_SYS_MOUNT_H
 805 #include <sys/mount.h>
 806 #endif
 807 #ifdef HAVE_SYS_VFS_H
 808 #include <sys/vfs.h>
 809 #endif
 810   main ()
 811   {
 812   struct statfs fsd;
 813   fsd.f_bsize = 0;
 814   exit (statfs (".", &fsd));
 815   }],
 816   fu_cv_sys_stat_statfs2_bsize=yes,
 817   fu_cv_sys_stat_statfs2_bsize=no,
 818   fu_cv_sys_stat_statfs2_bsize=no)])
 819   AC_MSG_RESULT($fu_cv_sys_stat_statfs2_bsize)
 820   if test $fu_cv_sys_stat_statfs2_bsize = yes; then
 821     space=yes
 822     AC_DEFINE(STAT_STATFS2_BSIZE)
 823   fi
 824 fi
 825
 826 if test $space = no; then
 827 # SVR3
 828   AC_MSG_CHECKING([for four-argument statfs (AIX-3.2.5, SVR3)])
 829   AC_CACHE_VAL(fu_cv_sys_stat_statfs4,
 830   [AC_TRY_RUN([#include <sys/types.h>
 831 #include <sys/statfs.h>
 832   main ()
 833   {
 834   struct statfs fsd;
 835   exit (statfs (".", &fsd, sizeof fsd, 0));
 836   }],
 837     fu_cv_sys_stat_statfs4=yes,
 838     fu_cv_sys_stat_statfs4=no,
 839     fu_cv_sys_stat_statfs4=no)])
 840   AC_MSG_RESULT($fu_cv_sys_stat_statfs4)
 841   if test $fu_cv_sys_stat_statfs4 = yes; then
 842     space=yes
 843     AC_DEFINE(STAT_STATFS4)
 844   fi
 845 fi
 846
 847 if test $space = no; then
 848 # 4.4BSD and NetBSD
 849   AC_MSG_CHECKING([for two-argument statfs with statfs.fsize dnl
 850 member (4.4BSD and NetBSD)])
 851   AC_CACHE_VAL(fu_cv_sys_stat_statfs2_fsize,
 852   [AC_TRY_RUN([#include <sys/types.h>
 853 #ifdef HAVE_SYS_PARAM_H
 854 #include <sys/param.h>
 855 #endif
 856 #ifdef HAVE_SYS_MOUNT_H
 857 #include <sys/mount.h>
 858 #endif
 859   main ()
 860   {
 861   struct statfs fsd;
 862   fsd.f_fsize = 0;
 863   exit (statfs (".", &fsd));
 864   }],
 865   fu_cv_sys_stat_statfs2_fsize=yes,
 866   fu_cv_sys_stat_statfs2_fsize=no,
 867   fu_cv_sys_stat_statfs2_fsize=no)])
 868   AC_MSG_RESULT($fu_cv_sys_stat_statfs2_fsize)
 869   if test $fu_cv_sys_stat_statfs2_fsize = yes; then
 870     space=yes
 871     AC_DEFINE(STAT_STATFS2_FSIZE)
 872   fi
 873 fi
 874
 875 if test $space = no; then
 876   # Ultrix
 877   AC_MSG_CHECKING([for two-argument statfs with struct fs_data (Ultrix)])
 878   AC_CACHE_VAL(fu_cv_sys_stat_fs_data,
 879   [AC_TRY_RUN([#include <sys/types.h>
 880 #ifdef HAVE_SYS_PARAM_H
 881 #include <sys/param.h>
 882 #endif
 883 #ifdef HAVE_SYS_MOUNT_H
 884 #include <sys/mount.h>
 885 #endif
 886 #ifdef HAVE_SYS_FS_TYPES_H
 887 #include <sys/fs_types.h>
 888 #endif
 889   main ()
 890   {
 891   struct fs_data fsd;
 892   /* Ultrix's statfs returns 1 for success,
 893      0 for not mounted, -1 for failure.  */
 894   exit (statfs (".", &fsd) != 1);
 895   }],
 896   fu_cv_sys_stat_fs_data=yes,
 897   fu_cv_sys_stat_fs_data=no,
 898   fu_cv_sys_stat_fs_data=no)])
 899   AC_MSG_RESULT($fu_cv_sys_stat_fs_data)
 900   if test $fu_cv_sys_stat_fs_data = yes; then
 901     space=yes
 902     AC_DEFINE(STAT_STATFS2_FS_DATA)
 903   fi
 904 fi
 905
 906 echo "checking configure summary"
 907 AC_TRY_RUN([#include "${srcdir-.}/tests/summary.c"],
 908            echo "configure OK";,
 909            AC_MSG_ERROR([summary failure. Aborting config]),:)
 910
 911 builddir=`pwd`
 912 AC_SUBST(builddir)
 913
 914 AC_OUTPUT(include/stamp-h Makefile)