source/build/smb_build/output.pm

   1 # SMB Build System
   2 # - the output generating functions
   3 #
   4 #  Copyright (C) Stefan (metze) Metzmacher 2004
   5 #  Copyright (C) Jelmer Vernooij 2004
   6 #  Released under the GNU GPL
   7
   8 package output;
   9 use strict;
  10
  11 sub add_dir($$)
  12 {
  13         my ($dir,$files) = @_;
  14         my @ret = ();
  15
  16         $dir =~ s/^\.\///g;
  17
  18         foreach (@$files) {
  19                 $_ = "$dir/$_";
  20                 s/([^\/\.]+)\/\.\.\///g;
  21                 push (@ret, $_);
  22         }
  23
  24         return @ret;
  25 }
  26
  27 sub generate_mergedobj($)
  28 {
  29         my $subsys = shift;
  30
  31         $subsys->{OUTPUT} = $subsys->{TARGET} = "bin/subsystems/$subsys->{TYPE}_$subsys->{NAME}.o";
  32 }
  33
  34 sub generate_objlist($)
  35 {
  36         my $subsys = shift;
  37
  38         $subsys->{TARGET} = "bin/.$subsys->{TYPE}_$subsys->{NAME}";
  39         $subsys->{OUTPUT} = "\$($subsys->{TYPE}_$subsys->{NAME}_OBJS)";
  40 }
  41
  42 sub generate_shared_library($)
  43 {
  44         my $lib = shift;
  45         my $link_name;
  46
  47         @{$lib->{DEPEND_LIST}} = ();
  48         @{$lib->{LINK_LIST}} = ("\$($lib->{TYPE}_$lib->{NAME}\_OBJS)");
  49
  50         $link_name = $lib->{NAME};
  51         $link_name =~ s/^LIB//;
  52         $link_name = lc($link_name);
  53
  54         $lib->{LIBRARY_NAME} = "lib$link_name.\$(SHLIBEXT)";
  55         $lib->{TARGET} = "bin/$lib->{LIBRARY_NAME}";
  56         if (defined($lib->{MAJOR_VERSION})) {
  57                 $lib->{LIBRARY_SONAME} = $lib->{LIBRARY_NAME}.".$lib->{MAJOR_VERSION}";
  58                 $lib->{LIBRARY_REALNAME} = $lib->{LIBRARY_SONAME}.".$lib->{MINOR_VERSION}.$lib->{RELEASE_VERSION}";
  59                 $lib->{TARGET} = "bin/$lib->{LIBRARY_REALNAME}";
  60                 @{$lib->{LINK_FLAGS}} = ("\$(SONAMEFLAG)$lib->{LIBRARY_SONAME}");
  61         }
  62         $lib->{OUTPUT} = "-l$link_name";
  63 }
  64
  65 sub generate_static_library($)
  66 {
  67         my $lib = shift;
  68         my $link_name;
  69
  70         @{$lib->{DEPEND_LIST}} = ();
  71
  72         $link_name = $lib->{NAME};
  73         $link_name =~ s/^LIB//;
  74
  75         $lib->{LIBRARY_NAME} = "lib".lc($link_name).".a";
  76         @{$lib->{LINK_LIST}} = ("\$($lib->{TYPE}_$lib->{NAME}\_OBJS)");
  77         @{$lib->{LINK_FLAGS}} = ();
  78
  79         $lib->{TARGET} = "bin/$lib->{LIBRARY_NAME}";
  80         $lib->{OUTPUT} = "-l".lc($link_name);
  81 }
  82
  83 sub generate_binary($)
  84 {
  85         my $bin = shift;
  86
  87         @{$bin->{DEPEND_LIST}} = ();
  88         @{$bin->{LINK_LIST}} = ("\$($bin->{TYPE}_$bin->{NAME}\_OBJS)");
  89         @{$bin->{LINK_FLAGS}} = ();
  90
  91         $bin->{TARGET} = $bin->{OUTPUT} = "bin/$bin->{NAME}";
  92         $bin->{BINARY} = $bin->{NAME};
  93 }
  94
  95 sub create_output($)
  96 {
  97         my $depend = shift;
  98         my $part;
  99
 100         $depend->{PROTO} = {
 101                 OUTPUT_TYPE => "OBJLIST",
 102                 TYPE => "PROTO",
 103                 NAME => "PROTO",
 104                 OBJ_LIST => []
 105         };
 106
 107         $depend->{ALL_OBJS} = {
 108                 OUTPUT_TYPE => "OBJLIST",
 109                 TYPE => "",
 110                 NAME => "ALL_OBJS",
 111                 OBJ_LIST => []
 112         };
 113
 114         foreach $part (values %{$depend}) {
 115                 next if $part->{NAME} eq "PROTO";
 116                 next if $part->{NAME} eq "ALL_OBJS";
 117                 next if not defined($part->{OUTPUT_TYPE});
 118
 119                 # Combine object lists
 120                 push(@{$part->{OBJ_LIST}}, add_dir($part->{BASEDIR}, $part->{INIT_OBJ_FILES})) if defined($part->{INIT_OBJ_FILES});
 121                 push(@{$part->{OBJ_LIST}}, add_dir($part->{BASEDIR}, $part->{ADD_OBJ_FILES})) if defined($part->{ADD_OBJ_FILES});
 122                 push(@{$part->{OBJ_LIST}}, add_dir($part->{BASEDIR}, $part->{OBJ_FILES})) if defined($part->{OBJ_FILES});
 123
 124                 if ((not defined($part->{OBJ_LIST}) or
 125                         scalar(@{$part->{OBJ_LIST}}) == 0) and
 126                         $part->{OUTPUT_TYPE} eq "MERGEDOBJ") {
 127                         $part->{OUTPUT_TYPE} = "OBJLIST";
 128                 }
 129
 130                 generate_binary($part) if $part->{OUTPUT_TYPE} eq "BINARY";
 131                 generate_mergedobj($part) if $part->{OUTPUT_TYPE} eq "MERGEDOBJ";
 132                 generate_objlist($part) if $part->{OUTPUT_TYPE} eq "OBJLIST";
 133                 generate_shared_library($part) if $part->{OUTPUT_TYPE} eq "SHARED_LIBRARY";
 134                 generate_static_library($part) if $part->{OUTPUT_TYPE} eq "STATIC_LIBRARY";
 135
 136
 137                 push(@{$depend->{ALL_OBJS}->{OBJ_LIST}}, @{$part->{OBJ_LIST}}) if (defined(@{$part->{OBJ_LIST}}));
 138
 139                 if ((not defined ($part->{NOPROTO})) or ($part->{NOPROTO} eq "NO")) {
 140                         push(@{$depend->{PROTO}->{OBJ_LIST}}, @{$part->{OBJ_LIST}}) if (defined(@{$part->{OBJ_LIST}}));
 141                 }
 142         }
 143
 144         foreach $part (values %{$depend}) {
 145                 next if not defined($part->{OUTPUT_TYPE});
 146
 147                 # Always import the CFLAGS and CPPFLAGS of the unique dependencies
 148                 foreach my $elem (values %{$part->{UNIQUE_DEPENDENCIES}}) {
 149                         next if $elem == $part;
 150
 151                         push(@{$part->{CPPFLAGS}}, @{$elem->{CPPFLAGS}}) if defined(@{$elem->{CPPFLAGS}});
 152                         push(@{$part->{CFLAGS}}, @{$elem->{CFLAGS}}) if defined(@{$elem->{CFLAGS}});
 153                         push(@{$part->{LINK_LIST}}, $elem->{OUTPUT}) if defined($elem->{OUTPUT});
 154                         push(@{$part->{LINK_FLAGS}}, @{$elem->{LIBS}}) if defined($elem->{LIBS});
 155                         push(@{$part->{LINK_FLAGS}},@{$elem->{LDFLAGS}}) if defined($elem->{LDFLAGS});
 156                         if (defined($elem->{OUTPUT_TYPE}) and ($elem->{OUTPUT_TYPE} eq "SHARED_LIBRARY")) {
 157                             push(@{$part->{DEPEND_LIST}}, "bin/$elem->{LIBRARY_NAME}");
 158                         } else {
 159                             push(@{$part->{DEPEND_LIST}}, $elem->{TARGET}) if defined($elem->{TARGET});
 160                         }
 161                         push(@{$part->{SUBSYSTEM_INIT_FUNCTIONS}}, $elem->{INIT_FUNCTION}) if
 162                         #$part->{OUTPUT_TYPE} eq "BINARY" and
 163                                 defined($elem->{INIT_FUNCTION}) and
 164                                 $part->{OUTPUT_TYPE} ne "SHARED_LIBRARY";
 165                 }
 166         }
 167
 168         return $depend;
 169 }
 170
 171 1;