r7122: Some cleanups, simplification of the code.
[samba.git] / source / build / pidl / ndr.pm
1 ###################################################
2 # Samba4 NDR info tree generator
3 # Copyright tridge@samba.org 2000-2003
4 # Copyright tpot@samba.org 2001
5 # Copyright jelmer@samba.org 2004-2005
6 # released under the GNU GPL
7
8 package Ndr;
9
10 use strict;
11 use pidl::typelist;
12
13 #####################################################################
14 # return a table describing the order in which the parts of an element
15 # should be parsed
16 # Possible level types:
17 #  - POINTER
18 #  - ARRAY
19 #  - SUBCONTEXT
20 #  - SWITCH
21 #  - DATA
22 sub GetElementLevelTable($)
23 {
24         my $e = shift;
25
26         my $order = [];
27         my $is_deferred = 0;
28         my @bracket_array = ();
29         my @length_is = ();
30         my @size_is = ();
31
32         if (util::has_property($e, "size_is")) {
33                 @size_is = split /,/, util::has_property($e, "size_is");
34         }
35
36         if (util::has_property($e, "length_is")) {
37                 @length_is = split /,/, util::has_property($e, "length_is");
38         }
39
40         if (defined($e->{ARRAY_LEN})) {
41                 @bracket_array = @{$e->{ARRAY_LEN}};
42         }
43         
44         # Parse the [][][][] style array stuff
45         foreach my $d (@bracket_array) {
46                 my $size = $d;
47                 my $length = $d;
48                 my $is_surrounding = 0;
49                 my $is_varying = 0;
50                 my $is_conformant = 0;
51
52                 if ($d eq "*") {
53                         $is_conformant = 1;
54                         unless ($size = shift @size_is) {
55                                 print "$e->{FILE}:$e->{LINE}: Must specify size_is() for conformant array!\n";
56                                 exit 1;
57                         }
58
59                         if ($length = shift @length_is) {
60                                 $is_varying = 1;
61                         } else {
62                                 $length = $size;
63                         }
64
65                         if ($e == $e->{PARENT}->{ELEMENTS}[-1] 
66                                 and $e->{PARENT}->{TYPE} ne "FUNCTION") {
67                                 $is_surrounding = 1;
68                         }
69                 }
70
71                 push (@$order, {
72                         TYPE => "ARRAY",
73                         SIZE_IS => $size,
74                         LENGTH_IS => $length,
75                         IS_DEFERRED => "$is_deferred",
76                         # Inline arrays (which are a pidl extension) are never encoded
77                         # as surrounding the struct they're part of
78                         IS_SURROUNDING => "$is_surrounding",
79                         IS_VARYING => "$is_varying",
80                         IS_CONFORMANT => "$is_conformant",
81                         IS_FIXED => (not $is_conformant and util::is_constant($size)),
82                         NO_METADATA => (not $is_conformant),
83                         IS_INLINE => (not $is_conformant and not util::is_constant($size))
84                 });
85         }
86
87         # Next, all the pointers
88         foreach my $i (1..$e->{POINTERS}) {
89                 my $pt = pointer_type($e);
90
91                 my $level = "EMBEDDED";
92                 # Top level "ref" pointers do not have a referrent identifier
93                 $level = "TOP" if ( defined($pt) 
94                                 and $i == 1
95                                 and $e->{PARENT}->{TYPE} eq "FUNCTION");
96
97                 push (@$order, { 
98                         TYPE => "POINTER",
99                         # for now, there can only be one pointer type per element
100                         POINTER_TYPE => pointer_type($e),
101                         IS_DEFERRED => "$is_deferred",
102                         LEVEL => $level
103                 });
104                 
105                 # everything that follows will be deferred
106                 $is_deferred = 1 if ($e->{PARENT}->{TYPE} ne "FUNCTION");
107
108                 my $array_size;
109                 my $array_length;
110                 if ($array_size = shift @size_is) {
111                         my $is_varying = 0;
112                         if ($array_length = shift @length_is) {
113                                 $is_varying = 1;
114                         } else {
115                                 $array_length = $array_size;
116                         }
117
118                         push (@$order, {
119                                 TYPE => "ARRAY",
120                                 SIZE_IS => $array_size,
121                                 LENGTH_IS => $array_length,
122                                 IS_DEFERRED => "$is_deferred",
123                                 IS_SURROUNDING => 0,
124                                 IS_VARYING => "$is_varying",
125                                 IS_CONFORMANT => 1,
126                                 IS_FIXED => 0,
127                                 NO_METADATA => 0,
128                                 IS_INLINE => 0,
129                         });
130
131                         $is_deferred = 0;
132                 }
133         }
134
135         if (defined(util::has_property($e, "subcontext"))) {
136                 my $hdr_size = util::has_property($e, "subcontext");
137                 my $subsize = util::has_property($e, "subcontext_size");
138                 if (not defined($subsize)) { 
139                         $subsize = -1; 
140                 }
141                 
142                 push (@$order, {
143                         TYPE => "SUBCONTEXT",
144                         HEADER_SIZE => $hdr_size,
145                         SUBCONTEXT_SIZE => $subsize,
146                         IS_DEFERRED => $is_deferred,
147                         COMPRESSION => util::has_property($e, "compression"),
148                         OBFUSCATION => util::has_property($e, "obfuscation")
149                 });
150         }
151
152         if (my $switch = util::has_property($e, "switch_is")) {
153                 push (@$order, {
154                         TYPE => "SWITCH", 
155                         SWITCH_IS => $switch,
156                         IS_DEFERRED => $is_deferred
157                 });
158         }
159
160         push (@$order, {
161                 TYPE => "DATA",
162                 DATA_TYPE => $e->{TYPE},
163                 IS_DEFERRED => $is_deferred,
164                 CONTAINS_DEFERRED => can_contain_deferred($e),
165                 IS_SURROUNDING => is_surrounding_string($e)
166         });
167
168         my $i = 0;
169         foreach (@$order) { $_->{LEVEL_INDEX} = $i; $i+=1; }
170
171         return $order;
172 }
173
174 #####################################################################
175 # see if a type contains any deferred data 
176 sub can_contain_deferred
177 {
178         my $e = shift;
179
180         return 1 if ($e->{POINTERS});
181         return 0 if (typelist::is_scalar($e->{TYPE}));
182         return 1 unless (typelist::hasType($e->{TYPE})); # assume the worst
183
184         my $type = typelist::getType($e->{TYPE});
185
186         foreach my $x (@{$type->{DATA}->{ELEMENTS}}) {
187                 return 1 if (can_contain_deferred ($x));
188         }
189         
190         return 0;
191 }
192
193 sub pointer_type($)
194 {
195         my $e = shift;
196
197         return undef unless $e->{POINTERS};
198         
199         return "ref" if (util::has_property($e, "ref"));
200         return "ptr" if (util::has_property($e, "ptr"));
201         return "unique" if (util::has_property($e, "unique"));
202         return "relative" if (util::has_property($e, "relative"));
203         return "ignore" if (util::has_property($e, "ignore"));
204
205         return undef;
206 }
207
208 sub is_surrounding_string($)
209 {
210         my $e = shift;
211
212         return 0; #FIXME
213
214         return ($e->{TYPE} eq "string") and ($e->{POINTERS} == 0) 
215                 and util::property_matches($e, "flag", ".*LIBNDR_FLAG_STR_CONFORMANT.*") 
216                 and $e->{PARENT}->{TYPE} ne "FUNCTION";
217 }
218
219 #####################################################################
220 # work out the correct alignment for a structure or union
221 sub find_largest_alignment($)
222 {
223         my $s = shift;
224
225         my $align = 1;
226         for my $e (@{$s->{ELEMENTS}}) {
227                 my $a = 1;
228
229                 if ($e->{POINTERS}) {
230                         $a = 4; 
231                 } else { 
232                         $a = align_type($e->{TYPE}); 
233                 }
234
235                 $align = $a if ($align < $a);
236         }
237
238         return $align;
239 }
240
241 #####################################################################
242 # align a type
243 sub align_type
244 {
245         my $e = shift;
246
247         unless (typelist::hasType($e)) {
248             # it must be an external type - all we can do is guess 
249                 # print "Warning: assuming alignment of unknown type '$e' is 4\n";
250             return 4;
251         }
252
253         my $dt = typelist::getType($e)->{DATA};
254
255         if ($dt->{TYPE} eq "ENUM") {
256                 return align_type(typelist::enum_type_fn($dt));
257         } elsif ($dt->{TYPE} eq "BITMAP") {
258                 return align_type(typelist::bitmap_type_fn($dt));
259         } elsif (($dt->{TYPE} eq "STRUCT") or ($dt->{TYPE} eq "UNION")) {
260                 return find_largest_alignment($dt);
261         } elsif ($dt->{TYPE} eq "SCALAR") {
262                 return typelist::getScalarAlignment($dt->{NAME});
263         }
264
265         die("Unknown data type type $dt->{TYPE}");
266 }
267
268 sub ParseElement($)
269 {
270         my $e = shift;
271
272         return {
273                 NAME => $e->{NAME},
274                 TYPE => $e->{TYPE},
275                 PROPERTIES => $e->{PROPERTIES},
276                 LEVELS => GetElementLevelTable($e)
277         };
278 }
279
280 sub ParseStruct($)
281 {
282         my $struct = shift;
283         my @elements = ();
284         my $surrounding = undef;
285
286         foreach my $x (@{$struct->{ELEMENTS}}) 
287         {
288                 push @elements, ParseElement($x);
289         }
290
291         my $e = $elements[-1];
292         if (defined($e) and defined($e->{LEVELS}[0]->{IS_SURROUNDING}) and
293                 $e->{LEVELS}[0]->{IS_SURROUNDING}) {
294                 $surrounding = $e;
295         }
296
297         if (defined $e->{TYPE} && $e->{TYPE} eq "string"
298             &&  util::property_matches($e, "flag", ".*LIBNDR_FLAG_STR_CONFORMANT.*")) {
299                 $surrounding = $struct->{ELEMENTS}[-1];
300         }
301                 
302         return {
303                 TYPE => "STRUCT",
304                 SURROUNDING_ELEMENT => $surrounding,
305                 ELEMENTS => \@elements,
306                 PROPERTIES => $struct->{PROPERTIES}
307         };
308 }
309
310 sub ParseUnion($)
311 {
312         my $e = shift;
313         my @elements = ();
314         my $switch_type = util::has_property($e, "switch_type");
315         unless (defined($switch_type)) { $switch_type = "uint32"; }
316
317         if (util::has_property($e, "nodiscriminant")) { $switch_type = undef; }
318         
319         foreach my $x (@{$e->{ELEMENTS}}) 
320         {
321                 my $t;
322                 if ($x->{TYPE} eq "EMPTY") {
323                         $t = { TYPE => "EMPTY" };
324                 } else {
325                         $t = ParseElement($x);
326                 }
327                 if (util::has_property($x, "default")) {
328                         $t->{CASE} = "default";
329                 } elsif (defined($x->{PROPERTIES}->{case})) {
330                         $t->{CASE} = "case $x->{PROPERTIES}->{case}";
331                 } else {
332                         die("Union element $x->{NAME} has neither default nor case property");
333                 }
334                 push @elements, $t;
335         }
336
337         return {
338                 TYPE => "UNION",
339                 SWITCH_TYPE => $switch_type,
340                 ELEMENTS => \@elements,
341                 PROPERTIES => $e->{PROPERTIES}
342         };
343 }
344
345 sub ParseEnum($)
346 {
347         my $e = shift;
348
349         return {
350                 TYPE => "ENUM",
351                 BASE_TYPE => typelist::enum_type_fn($e),
352                 ELEMENTS => $e->{ELEMENTS},
353                 PROPERTIES => $e->{PROPERTIES}
354         };
355 }
356
357 sub ParseBitmap($)
358 {
359         my $e = shift;
360
361         return {
362                 TYPE => "BITMAP",
363                 BASE_TYPE => typelist::bitmap_type_fn($e),
364                 ELEMENTS => $e->{ELEMENTS},
365                 PROPERTIES => $e->{PROPERTIES}
366         };
367 }
368
369 sub ParseTypedef($$)
370 {
371         my $ndr = shift;
372         my $d = shift;
373         my $data;
374
375         if ($d->{DATA}->{TYPE} eq "STRUCT" or $d->{DATA}->{TYPE} eq "UNION") {
376                 CheckPointerTypes($d->{DATA}, $ndr->{PROPERTIES}->{pointer_default});
377         }
378
379         if (defined($d->{PROPERTIES}) && !defined($d->{DATA}->{PROPERTIES})) {
380                 $d->{DATA}->{PROPERTIES} = $d->{PROPERTIES};
381         }
382
383         if ($d->{DATA}->{TYPE} eq "STRUCT") {
384                 $data = ParseStruct($d->{DATA});
385         } elsif ($d->{DATA}->{TYPE} eq "UNION") {
386                 $data = ParseUnion($d->{DATA});
387         } elsif ($d->{DATA}->{TYPE} eq "ENUM") {
388                 $data = ParseEnum($d->{DATA});
389         } elsif ($d->{DATA}->{TYPE} eq "BITMAP") {
390                 $data = ParseBitmap($d->{DATA});
391         } else {
392                 die("Unknown data type '$d->{DATA}->{TYPE}'");
393         }
394
395         $data->{ALIGN} = align_type($d->{NAME});
396
397         return {
398                 NAME => $d->{NAME},
399                 TYPE => $d->{TYPE},
400                 PROPERTIES => $d->{PROPERTIES},
401                 DATA => $data
402         };
403 }
404
405 sub ParseConst($$)
406 {
407         my $ndr = shift;
408         my $d = shift;
409
410         return $d;
411 }
412
413 sub ParseFunction($$$)
414 {
415         my $ndr = shift;
416         my $d = shift;
417         my $opnum = shift;
418         my @elements = ();
419         my $rettype = undef;
420         my $thisopnum = undef;
421
422         CheckPointerTypes($d, 
423                 $ndr->{PROPERTIES}->{pointer_default_top}
424         );
425
426         if (not defined($d->{PROPERTIES}{noopnum})) {
427                 $thisopnum = ${$opnum};
428                 ${$opnum}++;
429         }
430
431         foreach my $x (@{$d->{ELEMENTS}}) {
432                 my $e = ParseElement($x);
433                 push (@{$e->{DIRECTION}}, "in") if (util::has_property($x, "in"));
434                 push (@{$e->{DIRECTION}}, "out") if (util::has_property($x, "out"));
435                 push (@elements, $e);
436         }
437
438         if ($d->{RETURN_TYPE} ne "void") {
439                 $rettype = $d->{RETURN_TYPE};
440         }
441         
442         return {
443                         NAME => $d->{NAME},
444                         TYPE => "FUNCTION",
445                         OPNUM => $thisopnum,
446                         RETURN_TYPE => $rettype,
447                         PROPERTIES => $d->{PROPERTIES},
448                         ELEMENTS => \@elements
449                 };
450 }
451
452 sub CheckPointerTypes($$)
453 {
454         my $s = shift;
455         my $default = shift;
456
457         foreach my $e (@{$s->{ELEMENTS}}) {
458                 if ($e->{POINTERS} and not defined(Ndr::pointer_type($e))) {
459                         $e->{PROPERTIES}->{$default} = 1;
460                 }
461         }
462 }
463
464 sub ParseInterface($)
465 {
466         my $idl = shift;
467         my @typedefs = ();
468         my @consts = ();
469         my @functions = ();
470         my @endpoints;
471         my @declares = ();
472         my $opnum = 0;
473         my $version;
474
475         if (not util::has_property($idl, "pointer_default")) {
476                 # MIDL defaults to "ptr" in DCE compatible mode (/osf)
477                 # and "unique" in Microsoft Extensions mode (default)
478                 $idl->{PROPERTIES}->{pointer_default} = "unique";
479         }
480
481         if (not util::has_property($idl, "pointer_default_top")) {
482                 $idl->{PROPERTIES}->{pointer_default_top} = "ref";
483         }
484
485         foreach my $d (@{$idl->{DATA}}) {
486                 if ($d->{TYPE} eq "TYPEDEF") {
487                         push (@typedefs, ParseTypedef($idl, $d));
488                 }
489
490                 if ($d->{TYPE} eq "DECLARE") {
491                         push (@declares, $d);
492                 }
493
494                 if ($d->{TYPE} eq "FUNCTION") {
495                         push (@functions, ParseFunction($idl, $d, \$opnum));
496                 }
497
498                 if ($d->{TYPE} eq "CONST") {
499                         push (@consts, ParseConst($idl, $d));
500                 }
501         }
502
503         $version = "0.0";
504
505         if(defined $idl->{PROPERTIES}->{version}) { 
506                 $version = $idl->{PROPERTIES}->{version}; 
507         }
508
509         # If no endpoint is set, default to the interface name as a named pipe
510         if (!defined $idl->{PROPERTIES}->{endpoint}) {
511                 push @endpoints, "\"ncacn_np:[\\\\pipe\\\\" . $idl->{NAME} . "]\"";
512         } else {
513                 @endpoints = split / /, $idl->{PROPERTIES}->{endpoint};
514         }
515
516         return { 
517                 NAME => $idl->{NAME},
518                 UUID => util::has_property($idl, "uuid"),
519                 VERSION => $version,
520                 TYPE => "INTERFACE",
521                 PROPERTIES => $idl->{PROPERTIES},
522                 FUNCTIONS => \@functions,
523                 CONSTS => \@consts,
524                 TYPEDEFS => \@typedefs,
525                 DECLARES => \@declares,
526                 ENDPOINTS => \@endpoints
527         };
528 }
529
530 # Convert a IDL tree to a NDR tree
531 # Gives a result tree describing all that's necessary for easily generating
532 # NDR parsers / generators
533 sub Parse($)
534 {
535         my $idl = shift;
536         my @ndr = ();
537
538         foreach my $x (@{$idl}) {
539                 push @ndr, ParseInterface($x);
540         }
541
542         return \@ndr;
543 }
544
545 sub GetNextLevel($$)
546 {
547         my $e = shift;
548         my $fl = shift;
549
550         my $seen = 0;
551
552         foreach my $l (@{$e->{LEVELS}}) {
553                 return $l if ($seen);
554                 ($seen = 1) if ($l == $fl);
555         }
556
557         return undef;
558 }
559
560 sub GetPrevLevel($$)
561 {
562         my $e = shift;
563         my $fl = shift;
564         my $prev = undef;
565
566         foreach my $l (@{$e->{LEVELS}}) {
567                 (return $prev) if ($l == $fl);
568                 $prev = $l;
569         }
570
571         return undef;
572 }
573
574 sub ContainsDeferred($$)
575 {
576         my $e = shift;
577         my $l = shift;
578
579         do {
580                 return 1 if ($l->{IS_DEFERRED}); 
581                 return 1 if ($l->{CONTAINS_DEFERRED});
582         } while ($l = Ndr::GetNextLevel($e,$l));
583         
584         return 0;
585 }
586
587 1;