629d413db265cdb5167084c7569fba00202f4840
[samba.git] / source / build / pidl / ndr.pm
1 ###################################################
2 # Samba4 NDR info tree generator
3 # Copyright tridge@samba.org 2000-2003
4 # Copyright tpot@samba.org 2001
5 # Copyright jelmer@samba.org 2004-2005
6 # released under the GNU GPL
7
8 package Ndr;
9
10 use strict;
11 use pidl::typelist;
12
13 #####################################################################
14 # return a table describing the order in which the parts of an element
15 # should be parsed
16 # Possible level types:
17 #  - POINTER
18 #  - ARRAY
19 #  - SUBCONTEXT
20 #  - SWITCH
21 #  - DATA
22 sub GetElementLevelTable($)
23 {
24         my $e = shift;
25
26         my $order = [];
27         my $is_deferred = 0;
28         my @bracket_array = ();
29         my @length_is = ();
30         my @size_is = ();
31
32         if (util::has_property($e, "size_is")) {
33                 @size_is = split /,/, util::has_property($e, "size_is");
34         }
35
36         if (util::has_property($e, "length_is")) {
37                 @length_is = split /,/, util::has_property($e, "length_is");
38         }
39
40         if (defined($e->{ARRAY_LEN})) {
41                 @bracket_array = @{$e->{ARRAY_LEN}};
42         }
43         
44         # Parse the [][][][] style array stuff
45         foreach my $d (@bracket_array) {
46                 my $size = $d;
47                 my $length = $d;
48                 my $is_surrounding = 0;
49                 my $is_varying = 0;
50                 my $is_conformant = 0;
51
52                 if ($d eq "*") {
53                         $is_conformant = 1;
54                         unless ($size = shift @size_is) {
55                                 print "$e->{FILE}:$e->{LINE}: Must specify size_is() for conformant array!\n";
56                                 exit 1;
57                         }
58
59                         if ($length = shift @length_is) {
60                                 $is_varying = 1;
61                         } else {
62                                 $length = $size;
63                         }
64
65                         if ($e == $e->{PARENT}->{ELEMENTS}[-1] 
66                                 and $e->{PARENT}->{TYPE} ne "FUNCTION") {
67                                 $is_surrounding = 1;
68                         }
69                 }
70
71                 push (@$order, {
72                         TYPE => "ARRAY",
73                         SIZE_IS => $size,
74                         LENGTH_IS => $length,
75                         IS_DEFERRED => "$is_deferred",
76                         # Inline arrays (which are a pidl extension) are never encoded
77                         # as surrounding the struct they're part of
78                         IS_SURROUNDING => "$is_surrounding",
79                         IS_VARYING => "$is_varying",
80                         IS_CONFORMANT => "$is_conformant",
81                         IS_FIXED => (not $is_conformant and util::is_constant($size)),
82                         NO_METADATA => (not $is_conformant),
83                         IS_INLINE => (not $is_conformant and not util::is_constant($size))
84                 });
85         }
86
87         # Next, all the pointers
88         foreach my $i (1..$e->{POINTERS}) {
89                 my $pt = pointer_type($e);
90
91                 my $level = "EMBEDDED";
92                 # Top level "ref" pointers do not have a referrent identifier
93                 $level = "TOP" if ( defined($pt) 
94                                 and $i == 1
95                                 and $e->{PARENT}->{TYPE} eq "FUNCTION");
96
97                 push (@$order, { 
98                         TYPE => "POINTER",
99                         # for now, there can only be one pointer type per element
100                         POINTER_TYPE => pointer_type($e),
101                         IS_DEFERRED => "$is_deferred",
102                         LEVEL => $level
103                 });
104                 
105                 # everything that follows will be deferred
106                 $is_deferred = 1 if ($e->{PARENT}->{TYPE} ne "FUNCTION");
107
108                 my $array_size;
109                 my $array_length;
110                 if ($array_size = shift @size_is) {
111                         my $is_varying = 0;
112                         if ($array_length = shift @length_is) {
113                                 $is_varying = 1;
114                         } else {
115                                 $array_length = $array_size;
116                         }
117
118                         push (@$order, {
119                                 TYPE => "ARRAY",
120                                 SIZE_IS => $array_size,
121                                 LENGTH_IS => $array_length,
122                                 IS_DEFERRED => "$is_deferred",
123                                 IS_SURROUNDING => 0,
124                                 IS_VARYING => "$is_varying",
125                                 IS_CONFORMANT => 1,
126                                 IS_FIXED => 0,
127                                 NO_METADATA => 0,
128                                 IS_INLINE => 0,
129                         });
130
131                         $is_deferred = 0;
132                 }
133         }
134
135         if (defined(util::has_property($e, "subcontext"))) {
136                 my $hdr_size = util::has_property($e, "subcontext");
137                 my $subsize = util::has_property($e, "subcontext_size");
138                 if (not defined($subsize)) { 
139                         $subsize = -1; 
140                 }
141                 
142                 push (@$order, {
143                         TYPE => "SUBCONTEXT",
144                         HEADER_SIZE => $hdr_size,
145                         SUBCONTEXT_SIZE => $subsize,
146                         IS_DEFERRED => $is_deferred,
147                         COMPRESSION => util::has_property($e, "compression"),
148                         OBFUSCATION => util::has_property($e, "obfuscation")
149                 });
150         }
151
152         if (my $switch = util::has_property($e, "switch_is")) {
153                 push (@$order, {
154                         TYPE => "SWITCH", 
155                         SWITCH_IS => $switch,
156                         IS_DEFERRED => $is_deferred
157                 });
158         }
159
160         push (@$order, {
161                 TYPE => "DATA",
162                 DATA_TYPE => $e->{TYPE},
163                 IS_DEFERRED => $is_deferred,
164                 CONTAINS_DEFERRED => can_contain_deferred($e),
165                 IS_SURROUNDING => is_surrounding_string($e)
166         });
167
168         my $i = 0;
169         foreach (@$order) { $_->{LEVEL_INDEX} = $i; $i+=1; }
170
171         return $order;
172 }
173
174 #####################################################################
175 # see if a type contains any deferred data 
176 sub can_contain_deferred
177 {
178         my $e = shift;
179
180         return 1 if ($e->{POINTERS});
181         return 0 if (typelist::is_scalar($e->{TYPE}));
182         return 1 unless (typelist::hasType($e->{TYPE})); # assume the worst
183
184         my $type = typelist::getType($e->{TYPE});
185
186         foreach my $x (@{$type->{DATA}->{ELEMENTS}}) {
187                 return 1 if (can_contain_deferred ($x));
188         }
189         
190         return 0;
191 }
192
193 sub pointer_type($)
194 {
195         my $e = shift;
196
197         return undef unless $e->{POINTERS};
198         
199         return "ref" if (util::has_property($e, "ref"));
200         return "ptr" if (util::has_property($e, "ptr"));
201         return "unique" if (util::has_property($e, "unique"));
202         return "relative" if (util::has_property($e, "relative"));
203         return "ignore" if (util::has_property($e, "ignore"));
204
205         return undef;
206 }
207
208 sub is_surrounding_string($)
209 {
210         my $e = shift;
211
212         return 0; #FIXME
213
214         return ($e->{TYPE} eq "string") and ($e->{POINTERS} == 0) 
215                 and util::property_matches($e, "flag", ".*LIBNDR_FLAG_STR_CONFORMANT.*") 
216                 and $e->{PARENT}->{TYPE} ne "FUNCTION";
217 }
218
219
220 #####################################################################
221 # work out the correct alignment for a structure or union
222 sub find_largest_alignment($)
223 {
224         my $s = shift;
225
226         my $align = 1;
227         for my $e (@{$s->{ELEMENTS}}) {
228                 my $a = 1;
229
230                 if (Ndr::need_wire_pointer($e)) {
231                         $a = 4; 
232                 } else { 
233                         $a = align_type($e->{TYPE}); 
234                 }
235
236                 $align = $a if ($align < $a);
237         }
238
239         return $align;
240 }
241
242 #####################################################################
243 # align a type
244 sub align_type
245 {
246         my $e = shift;
247
248         unless (typelist::hasType($e)) {
249             # it must be an external type - all we can do is guess 
250                 # print "Warning: assuming alignment of unknown type '$e' is 4\n";
251             return 4;
252         }
253
254         my $dt = typelist::getType($e)->{DATA};
255
256         if ($dt->{TYPE} eq "ENUM") {
257                 return align_type(typelist::enum_type_fn($dt));
258         } elsif ($dt->{TYPE} eq "BITMAP") {
259                 return align_type(typelist::bitmap_type_fn($dt));
260         } elsif (($dt->{TYPE} eq "STRUCT") or ($dt->{TYPE} eq "UNION")) {
261                 return find_largest_alignment($dt);
262         } elsif ($dt->{TYPE} eq "SCALAR") {
263                 return typelist::getScalarAlignment($dt->{NAME});
264         }
265
266         die("Unknown data type type $dt->{TYPE}");
267 }
268
269 # determine if an element needs a reference pointer on the wire
270 # in its NDR representation
271 sub need_wire_pointer($)
272 {
273         my $e = shift;
274
275         my $n = $e->{POINTERS};
276         my $pt = pointer_type($e);
277
278         # Top level "ref" pointers do not have a referrent identifier
279         if (    defined($pt) 
280                 and $pt eq "ref" 
281                 and $e->{PARENT}->{TYPE} eq "FUNCTION") 
282         {
283                 $n--;
284         }
285
286         return $n;
287 }
288
289 sub ParseElement($)
290 {
291         my $e = shift;
292
293         return {
294                 NAME => $e->{NAME},
295                 TYPE => $e->{TYPE},
296                 PROPERTIES => $e->{PROPERTIES},
297                 LEVELS => GetElementLevelTable($e)
298         };
299 }
300
301 sub ParseStruct($)
302 {
303         my $struct = shift;
304         my @elements = ();
305         my $surrounding = undef;
306
307         foreach my $x (@{$struct->{ELEMENTS}}) 
308         {
309                 push @elements, ParseElement($x);
310         }
311
312         my $e = $elements[-1];
313         if (defined($e) and defined($e->{LEVELS}[0]->{IS_SURROUNDING}) and
314                 $e->{LEVELS}[0]->{IS_SURROUNDING}) {
315                 $surrounding = $e;
316         }
317
318         if (defined $e->{TYPE} && $e->{TYPE} eq "string"
319             &&  util::property_matches($e, "flag", ".*LIBNDR_FLAG_STR_CONFORMANT.*")) {
320                 $surrounding = $struct->{ELEMENTS}[-1];
321         }
322                 
323         return {
324                 TYPE => "STRUCT",
325                 SURROUNDING_ELEMENT => $surrounding,
326                 ELEMENTS => \@elements,
327                 PROPERTIES => $struct->{PROPERTIES}
328         };
329 }
330
331 sub ParseUnion($)
332 {
333         my $e = shift;
334         my @elements = ();
335         my $switch_type = util::has_property($e, "switch_type");
336         unless (defined($switch_type)) { $switch_type = "uint32"; }
337
338         if (util::has_property($e, "nodiscriminant")) { $switch_type = undef; }
339         
340         foreach my $x (@{$e->{ELEMENTS}}) 
341         {
342                 my $t;
343                 if ($x->{TYPE} eq "EMPTY") {
344                         $t = { TYPE => "EMPTY" };
345                 } else {
346                         $t = ParseElement($x);
347                 }
348                 if (util::has_property($x, "default")) {
349                         $t->{CASE} = "default";
350                 } elsif (defined($x->{PROPERTIES}->{case})) {
351                         $t->{CASE} = "case $x->{PROPERTIES}->{case}";
352                 } else {
353                         die("Union element $x->{NAME} has neither default nor case property");
354                 }
355                 push @elements, $t;
356         }
357
358         return {
359                 TYPE => "UNION",
360                 SWITCH_TYPE => $switch_type,
361                 ELEMENTS => \@elements,
362                 PROPERTIES => $e->{PROPERTIES}
363         };
364 }
365
366 sub ParseEnum($)
367 {
368         my $e = shift;
369
370         return {
371                 TYPE => "ENUM",
372                 BASE_TYPE => typelist::enum_type_fn($e),
373                 ELEMENTS => $e->{ELEMENTS},
374                 PROPERTIES => $e->{PROPERTIES}
375         };
376 }
377
378 sub ParseBitmap($)
379 {
380         my $e = shift;
381
382         return {
383                 TYPE => "BITMAP",
384                 BASE_TYPE => typelist::bitmap_type_fn($e),
385                 ELEMENTS => $e->{ELEMENTS},
386                 PROPERTIES => $e->{PROPERTIES}
387         };
388 }
389
390 sub ParseDeclare($$)
391 {
392         my $ndr = shift;
393         my $d = shift;
394
395 }
396
397 sub ParseTypedef($$)
398 {
399         my $ndr = shift;
400         my $d = shift;
401         my $data;
402
403         if ($d->{DATA}->{TYPE} eq "STRUCT" or $d->{DATA}->{TYPE} eq "UNION") {
404                 CheckPointerTypes($d->{DATA}, $ndr->{PROPERTIES}->{pointer_default});
405         }
406
407         if (defined($d->{PROPERTIES}) && !defined($d->{DATA}->{PROPERTIES})) {
408                 $d->{DATA}->{PROPERTIES} = $d->{PROPERTIES};
409         }
410
411         if ($d->{DATA}->{TYPE} eq "STRUCT") {
412                 $data = ParseStruct($d->{DATA});
413         } elsif ($d->{DATA}->{TYPE} eq "UNION") {
414                 $data = ParseUnion($d->{DATA});
415         } elsif ($d->{DATA}->{TYPE} eq "ENUM") {
416                 $data = ParseEnum($d->{DATA});
417         } elsif ($d->{DATA}->{TYPE} eq "BITMAP") {
418                 $data = ParseBitmap($d->{DATA});
419         } else {
420                 die("Unknown data type '$d->{DATA}->{TYPE}'");
421         }
422
423         $data->{ALIGN} = align_type($d->{NAME});
424
425         return {
426                 NAME => $d->{NAME},
427                 TYPE => $d->{TYPE},
428                 PROPERTIES => $d->{PROPERTIES},
429                 DATA => $data
430         };
431 }
432
433 sub ParseConst($$)
434 {
435         my $ndr = shift;
436         my $d = shift;
437
438         return $d;
439 }
440
441 sub ParseFunction($$$)
442 {
443         my $ndr = shift;
444         my $d = shift;
445         my $opnum = shift;
446         my @elements = ();
447         my $rettype = undef;
448         my $thisopnum = undef;
449
450         CheckPointerTypes($d, 
451                 $ndr->{PROPERTIES}->{pointer_default_top}
452         );
453
454         if (not defined($d->{PROPERTIES}{noopnum})) {
455                 $thisopnum = ${$opnum};
456                 ${$opnum}++;
457         }
458
459         foreach my $x (@{$d->{ELEMENTS}}) {
460                 my $e = ParseElement($x);
461                 if (util::has_property($x, "in")) {
462                         push (@{$e->{DIRECTION}}, "in");
463                 }
464
465                 if (util::has_property($x, "out")) {
466                         push (@{$e->{DIRECTION}}, "out");
467                 }
468
469                 push (@elements, $e);
470         }
471
472         if ($d->{RETURN_TYPE} ne "void") {
473                 $rettype = $d->{RETURN_TYPE};
474         }
475         
476         return {
477                         NAME => $d->{NAME},
478                         TYPE => "FUNCTION",
479                         OPNUM => $thisopnum,
480                         RETURN_TYPE => $rettype,
481                         PROPERTIES => $d->{PROPERTIES},
482                         ELEMENTS => \@elements
483                 };
484 }
485
486 sub CheckPointerTypes($$)
487 {
488         my $s = shift;
489         my $default = shift;
490
491         foreach my $e (@{$s->{ELEMENTS}}) {
492                 if ($e->{POINTERS}) {
493                         if (not defined(Ndr::pointer_type($e))) {
494                                 $e->{PROPERTIES}->{$default} = 1;
495                         }
496
497                         if (Ndr::pointer_type($e) eq "ptr") {
498                                 print "Warning: ptr is not supported by pidl yet\n";
499                         }
500                 }
501         }
502 }
503
504 sub ParseInterface($)
505 {
506         my $idl = shift;
507         my @typedefs = ();
508         my @consts = ();
509         my @functions = ();
510         my @endpoints;
511         my @declares = ();
512         my $opnum = 0;
513         my $version;
514
515         if (not util::has_property($idl, "pointer_default")) {
516                 # MIDL defaults to "ptr" in DCE compatible mode (/osf)
517                 # and "unique" in Microsoft Extensions mode (default)
518                 $idl->{PROPERTIES}->{pointer_default} = "unique";
519         }
520
521         if (not util::has_property($idl, "pointer_default_top")) {
522                 $idl->{PROPERTIES}->{pointer_default_top} = "ref";
523         }
524
525         foreach my $d (@{$idl->{DATA}}) {
526                 if ($d->{TYPE} eq "TYPEDEF") {
527                         push (@typedefs, ParseTypedef($idl, $d));
528                 }
529
530                 if ($d->{TYPE} eq "DECLARE") {
531                         push (@declares, ParseDeclare($idl, $d));
532                 }
533
534                 if ($d->{TYPE} eq "FUNCTION") {
535                         push (@functions, ParseFunction($idl, $d, \$opnum));
536                 }
537
538                 if ($d->{TYPE} eq "CONST") {
539                         push (@consts, ParseConst($idl, $d));
540                 }
541         }
542
543         $version = "0.0";
544
545         if(defined $idl->{PROPERTIES}->{version}) { 
546                 $version = $idl->{PROPERTIES}->{version}; 
547         }
548
549         # If no endpoint is set, default to the interface name as a named pipe
550         if (!defined $idl->{PROPERTIES}->{endpoint}) {
551                 push @endpoints, "\"ncacn_np:[\\\\pipe\\\\" . $idl->{NAME} . "]\"";
552         } else {
553                 @endpoints = split / /, $idl->{PROPERTIES}->{endpoint};
554         }
555
556         return { 
557                 NAME => $idl->{NAME},
558                 UUID => util::has_property($idl, "uuid"),
559                 VERSION => $version,
560                 TYPE => "INTERFACE",
561                 PROPERTIES => $idl->{PROPERTIES},
562                 FUNCTIONS => \@functions,
563                 CONSTS => \@consts,
564                 TYPEDEFS => \@typedefs,
565                 DECLARES => \@declares,
566                 ENDPOINTS => \@endpoints
567         };
568 }
569
570 # Convert a IDL tree to a NDR tree
571 # Gives a result tree describing all that's necessary for easily generating
572 # NDR parsers
573 # - list of interfaces
574 #  - list with functions
575 #   - list with in elements
576 #   - list with out elements
577 #  - list of typedefs
578 #   - list with structs
579 #    - alignment of structure
580 #    - list with elements
581 #   - list with unions
582 #    - alignment of union
583 #    - list with elements
584 #   - list with enums
585 #    - base type
586 #   - list with bitmaps
587 #    - base type
588 # per element: 
589 #  - alignment
590 #  - "level" table
591 # properties are saved
592 # pointer types explicitly specified
593 sub Parse($)
594 {
595         my $idl = shift;
596         my @ndr = ();
597
598         foreach my $x (@{$idl}) {
599                 push @ndr, ParseInterface($x);
600         }
601
602         return \@ndr;
603 }
604
605 sub GetNextLevel($$)
606 {
607         my $e = shift;
608         my $fl = shift;
609
610         my $seen = 0;
611
612         foreach my $l (@{$e->{LEVELS}}) {
613                 return $l if ($seen);
614                 ($seen = 1) if ($l == $fl);
615         }
616
617         return undef;
618 }
619
620 sub GetPrevLevel($$)
621 {
622         my $e = shift;
623         my $fl = shift;
624         my $prev = undef;
625
626         foreach my $l (@{$e->{LEVELS}}) {
627                 (return $prev) if ($l == $fl);
628                 $prev = $l;
629         }
630
631         return undef;
632 }
633
634 sub ContainsDeferred($$)
635 {
636         my $e = shift;
637         my $l = shift;
638
639         do {
640                 return 1 if ($l->{IS_DEFERRED}); 
641                 return 1 if ($l->{CONTAINS_DEFERRED});
642         } while ($l = Ndr::GetNextLevel($e,$l));
643         
644         return 0;
645 }
646
647
648 1;