selftest/selftest.pl

   1 #!/usr/bin/perl
   2 # Bootstrap Samba and run a number of tests against it.
   3 # Copyright (C) 2005-2010 Jelmer Vernooij <jelmer@samba.org>
   4 # Copyright (C) 2007-2009 Stefan Metzmacher <metze@samba.org>
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 use strict;
  20
  21 use FindBin qw($RealBin $Script);
  22 use File::Spec;
  23 use File::Temp qw(tempfile);
  24 use Getopt::Long;
  25 use POSIX;
  26 use Cwd qw(abs_path);
  27 use lib "$RealBin";
  28 use Subunit;
  29 use SocketWrapper;
  30
  31 eval {
  32 require Time::HiRes;
  33 Time::HiRes->import("time");
  34 };
  35 if ($@) {
  36         print "You don't have Time::Hires installed !\n";
  37 }
  38
  39 my $opt_help = 0;
  40 my $opt_target = "samba";
  41 my $opt_quick = 0;
  42 my $opt_socket_wrapper = 0;
  43 my $opt_socket_wrapper_pcap = undef;
  44 my $opt_socket_wrapper_keep_pcap = undef;
  45 my $opt_random_order = 0;
  46 my $opt_one = 0;
  47 my @opt_exclude = ();
  48 my @opt_include = ();
  49 my $opt_testenv = 0;
  50 my $opt_list = 0;
  51 my $ldap = undef;
  52 my $opt_resetup_env = undef;
  53 my $opt_binary_mapping = "";
  54 my $opt_load_list = undef;
  55 my $opt_libnss_wrapper_so_path = "";
  56 my $opt_libsocket_wrapper_so_path = "";
  57 my $opt_libuid_wrapper_so_path = "";
  58 my @testlists = ();
  59
  60 my $srcdir = ".";
  61 my $bindir = "./bin";
  62 my $prefix = "./st";
  63
  64 my @includes = ();
  65 my @excludes = ();
  66
  67 sub find_in_list($$)
  68 {
  69         my ($list, $fullname) = @_;
  70
  71         foreach (@$list) {
  72                 if ($fullname =~ /$$_[0]/) {
  73                          return ($$_[1]) if ($$_[1]);
  74                          return "";
  75                 }
  76         }
  77
  78         return undef;
  79 }
  80
  81 sub skip($)
  82 {
  83         my ($name) = @_;
  84
  85         return find_in_list(\@excludes, $name);
  86 }
  87
  88 sub getlog_env($);
  89
  90 sub setup_pcap($)
  91 {
  92         my ($name) = @_;
  93
  94         return unless ($opt_socket_wrapper_pcap);
  95         return unless defined($ENV{SOCKET_WRAPPER_PCAP_DIR});
  96
  97         my $fname = $name;
  98         $fname =~ s%[^abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789\-]%_%g;
  99
 100         my $pcap_file = "$ENV{SOCKET_WRAPPER_PCAP_DIR}/$fname.pcap";
 101
 102         SocketWrapper::setup_pcap($pcap_file);
 103
 104         return $pcap_file;
 105 }
 106
 107 sub cleanup_pcap($$)
 108 {
 109         my ($pcap_file, $exitcode) = @_;
 110
 111         return unless ($opt_socket_wrapper_pcap);
 112         return if ($opt_socket_wrapper_keep_pcap);
 113         return unless ($exitcode == 0);
 114         return unless defined($pcap_file);
 115
 116         unlink($pcap_file);
 117 }
 118
 119 # expand strings from %ENV
 120 sub expand_environment_strings($)
 121 {
 122         my $s = shift;
 123         # we use a reverse sort so we do the longer ones first
 124         foreach my $k (sort { $b cmp $a } keys %ENV) {
 125                 $s =~ s/\$$k/$ENV{$k}/g;
 126         }
 127         return $s;
 128 }
 129
 130 sub run_testsuite($$$$$)
 131 {
 132         my ($envname, $name, $cmd, $i, $totalsuites) = @_;
 133         my $pcap_file = setup_pcap($name);
 134
 135         Subunit::start_testsuite($name);
 136         Subunit::progress_push();
 137         Subunit::report_time(time());
 138         system($cmd);
 139         Subunit::report_time(time());
 140         Subunit::progress_pop();
 141
 142         if ($? == -1) {
 143                 Subunit::progress_pop();
 144                 Subunit::end_testsuite($name, "error", "Unable to run $cmd: $!");
 145                 exit(1);
 146         } elsif ($? & 127) {
 147                 Subunit::end_testsuite($name, "error",
 148                         sprintf("%s died with signal %d, %s coredump\n", $cmd, ($? & 127),  ($? & 128) ? 'with' : 'without'));
 149                 exit(1);
 150         }
 151
 152         my $exitcode = $? >> 8;
 153
 154         my $envlog = getlog_env($envname);
 155         if ($envlog ne "") {
 156                 print "envlog: $envlog\n";
 157         }
 158
 159         print "command: $cmd\n";
 160         printf "expanded command: %s\n", expand_environment_strings($cmd);
 161
 162         if ($exitcode == 0) {
 163                 Subunit::end_testsuite($name, "success");
 164         } else {
 165                 Subunit::end_testsuite($name, "failure", "Exit code was $exitcode");
 166         }
 167
 168         cleanup_pcap($pcap_file, $exitcode);
 169
 170         if (not $opt_socket_wrapper_keep_pcap and defined($pcap_file)) {
 171                 print "PCAP FILE: $pcap_file\n";
 172         }
 173
 174         if ($exitcode != 0) {
 175                 exit(1) if ($opt_one);
 176         }
 177
 178         return $exitcode;
 179 }
 180
 181 sub ShowHelp()
 182 {
 183         print "Samba test runner
 184 Copyright (C) Jelmer Vernooij <jelmer\@samba.org>
 185 Copyright (C) Stefan Metzmacher <metze\@samba.org>
 186
 187 Usage: $Script [OPTIONS] TESTNAME-REGEX
 188
 189 Generic options:
 190  --help                     this help page
 191  --target=samba[3]|win      Samba version to target
 192  --testlist=FILE            file to read available tests from
 193  --exclude=FILE             Exclude tests listed in the file
 194  --include=FILE             Include tests listed in the file
 195
 196 Paths:
 197  --prefix=DIR               prefix to run tests in [st]
 198  --srcdir=DIR               source directory [.]
 199  --bindir=DIR               binaries directory [./bin]
 200
 201 Preload cwrap:
 202  --nss_wrapper_so_path=FILE the nss_wrapper library to preload
 203  --socket_wrapper_so_path=FILE the socket_wrapper library to preload
 204  --uid_wrapper_so_path=FILE the uid_wrapper library to preload
 205
 206 Target Specific:
 207  --socket-wrapper-pcap      save traffic to pcap directories
 208  --socket-wrapper-keep-pcap keep all pcap files, not just those for tests that
 209                             failed
 210  --socket-wrapper           enable socket wrapper
 211
 212 Samba4 Specific:
 213  --ldap=openldap|fedora-ds  back samba onto specified ldap server
 214
 215 Behaviour:
 216  --quick                    run quick overall test
 217  --one                      abort when the first test fails
 218  --testenv                  run a shell in the requested test environment
 219  --list                     list available tests
 220 ";
 221         exit(0);
 222 }
 223
 224 my $result = GetOptions (
 225                 'help|h|?' => \$opt_help,
 226                 'target=s' => \$opt_target,
 227                 'prefix=s' => \$prefix,
 228                 'socket-wrapper' => \$opt_socket_wrapper,
 229                 'socket-wrapper-pcap' => \$opt_socket_wrapper_pcap,
 230                 'socket-wrapper-keep-pcap' => \$opt_socket_wrapper_keep_pcap,
 231                 'quick' => \$opt_quick,
 232                 'one' => \$opt_one,
 233                 'exclude=s' => \@opt_exclude,
 234                 'include=s' => \@opt_include,
 235                 'srcdir=s' => \$srcdir,
 236                 'bindir=s' => \$bindir,
 237                 'testenv' => \$opt_testenv,
 238                 'list' => \$opt_list,
 239                 'ldap:s' => \$ldap,
 240                 'resetup-environment' => \$opt_resetup_env,
 241                 'testlist=s' => \@testlists,
 242                 'random-order' => \$opt_random_order,
 243                 'load-list=s' => \$opt_load_list,
 244                 'binary-mapping=s' => \$opt_binary_mapping,
 245                 'nss_wrapper_so_path=s' => \$opt_libnss_wrapper_so_path,
 246                 'socket_wrapper_so_path=s' => \$opt_libsocket_wrapper_so_path,
 247                 'uid_wrapper_so_path=s' => \$opt_libuid_wrapper_so_path
 248             );
 249
 250 exit(1) if (not $result);
 251
 252 ShowHelp() if ($opt_help);
 253
 254 die("--list and --testenv are mutually exclusive") if ($opt_list and $opt_testenv);
 255
 256 # we want unbuffered output
 257 $| = 1;
 258
 259 my @tests = @ARGV;
 260
 261 # quick hack to disable rpc validation when using valgrind - its way too slow
 262 unless (defined($ENV{VALGRIND})) {
 263         $ENV{VALIDATE} = "validate";
 264         $ENV{MALLOC_CHECK_} = 3;
 265 }
 266
 267 # make all our python scripts unbuffered
 268 $ENV{PYTHONUNBUFFERED} = 1;
 269
 270 my $bindir_abs = abs_path($bindir);
 271
 272 # Backwards compatibility:
 273 if (defined($ENV{TEST_LDAP}) and $ENV{TEST_LDAP} eq "yes") {
 274         if (defined($ENV{FEDORA_DS_ROOT})) {
 275                 $ldap = "fedora-ds";
 276         } else {
 277                 $ldap = "openldap";
 278         }
 279 }
 280
 281 my $torture_maxtime = ($ENV{TORTURE_MAXTIME} or 1200);
 282 if ($ldap) {
 283         # LDAP is slow
 284         $torture_maxtime *= 2;
 285 }
 286
 287 $prefix =~ s+//+/+;
 288 $prefix =~ s+/./+/+;
 289 $prefix =~ s+/$++;
 290
 291 die("using an empty prefix isn't allowed") unless $prefix ne "";
 292
 293 # Ensure we have the test prefix around.
 294 #
 295 # We need restrictive
 296 # permissions on this as some subdirectories in this tree will have
 297 # wider permissions (ie 0777) and this would allow other users on the
 298 # host to subvert the test process.
 299 mkdir($prefix, 0700) unless -d $prefix;
 300 chmod 0700, $prefix;
 301
 302 my $prefix_abs = abs_path($prefix);
 303 my $tmpdir_abs = abs_path("$prefix/tmp");
 304 mkdir($tmpdir_abs, 0777) unless -d $tmpdir_abs;
 305
 306 my $srcdir_abs = abs_path($srcdir);
 307
 308 die("using an empty absolute prefix isn't allowed") unless $prefix_abs ne "";
 309 die("using '/' as absolute prefix isn't allowed") unless $prefix_abs ne "/";
 310
 311 $ENV{PREFIX} = $prefix;
 312 $ENV{KRB5CCNAME} = "$prefix/krb5ticket";
 313 $ENV{PREFIX_ABS} = $prefix_abs;
 314 $ENV{SRCDIR} = $srcdir;
 315 $ENV{SRCDIR_ABS} = $srcdir_abs;
 316 $ENV{BINDIR} = $bindir_abs;
 317
 318 my $tls_enabled = not $opt_quick;
 319 $ENV{TLS_ENABLED} = ($tls_enabled?"yes":"no");
 320
 321 sub prefix_pathvar($$)
 322 {
 323         my ($name, $newpath) = @_;
 324         if (defined($ENV{$name})) {
 325                 $ENV{$name} = "$newpath:$ENV{$name}";
 326         } else {
 327                 $ENV{$name} = $newpath;
 328         }
 329 }
 330 prefix_pathvar("PKG_CONFIG_PATH", "$bindir_abs/pkgconfig");
 331 prefix_pathvar("PYTHONPATH", "$bindir_abs/python");
 332
 333 if ($opt_socket_wrapper_keep_pcap) {
 334         # Socket wrapper keep pcap implies socket wrapper pcap
 335         $opt_socket_wrapper_pcap = 1;
 336 }
 337
 338 if ($opt_socket_wrapper_pcap) {
 339         # Socket wrapper pcap implies socket wrapper
 340         $opt_socket_wrapper = 1;
 341 }
 342
 343 my $ld_preload = $ENV{LD_PRELOAD};
 344
 345 if ($opt_libnss_wrapper_so_path) {
 346         if ($ld_preload) {
 347                 $ld_preload = "$ld_preload:$opt_libnss_wrapper_so_path";
 348         } else {
 349                 $ld_preload = "$opt_libnss_wrapper_so_path";
 350         }
 351 }
 352
 353 if ($opt_libsocket_wrapper_so_path) {
 354         if ($ld_preload) {
 355                 $ld_preload = "$ld_preload:$opt_libsocket_wrapper_so_path";
 356         } else {
 357                 $ld_preload = "$opt_libsocket_wrapper_so_path";
 358         }
 359 }
 360
 361 if ($opt_libuid_wrapper_so_path) {
 362         if ($ld_preload) {
 363                 $ld_preload = "$ld_preload:$opt_libuid_wrapper_so_path";
 364         } else {
 365                 $ld_preload = "$opt_libuid_wrapper_so_path";
 366         }
 367 }
 368
 369 $ENV{LD_PRELOAD} = $ld_preload;
 370 print "LD_PRELOAD=$ENV{LD_PRELOAD}\n";
 371
 372 # Enable uid_wrapper globally
 373 $ENV{UID_WRAPPER} = 1;
 374
 375 # Disable RTLD_DEEPBIND hack for Samba bind dlz module
 376 #
 377 # This is needed in order to allow the ldb_*ldap module
 378 # to work with a preloaded socket wrapper.
 379 $ENV{LDB_MODULES_DISABLE_DEEPBIND} = 1;
 380
 381 my $socket_wrapper_dir;
 382 if ($opt_socket_wrapper) {
 383         $socket_wrapper_dir = SocketWrapper::setup_dir("$prefix_abs/w", $opt_socket_wrapper_pcap);
 384         print "SOCKET_WRAPPER_DIR=$socket_wrapper_dir\n";
 385 } elsif (not $opt_list) {
 386          unless ($< == 0) {
 387                  warn("not using socket wrapper, but also not running as root. Will not be able to listen on proper ports");
 388          }
 389 }
 390
 391 my $target;
 392 my $testenv_default = "none";
 393
 394 my %binary_mapping = ();
 395 if ($opt_binary_mapping) {
 396     my @binmapping_list = split(/,/, $opt_binary_mapping);
 397     foreach my $mapping (@binmapping_list) {
 398         my ($bin, $map) = split(/\:/, $mapping);
 399         $binary_mapping{$bin} = $map;
 400     }
 401 }
 402
 403 $ENV{BINARY_MAPPING} = $opt_binary_mapping;
 404
 405 # After this many seconds, the server will self-terminate.  All tests
 406 # must terminate in this time, and testenv will only stay alive this
 407 # long
 408
 409 my $server_maxtime = 7500;
 410 if (defined($ENV{SMBD_MAXTIME}) and $ENV{SMBD_MAXTIME} ne "") {
 411     $server_maxtime = $ENV{SMBD_MAXTIME};
 412 }
 413
 414 unless ($opt_list) {
 415         if ($opt_target eq "samba") {
 416                 $testenv_default = "dc";
 417                 require target::Samba;
 418                 $target = new Samba($bindir, \%binary_mapping, $ldap, $srcdir, $server_maxtime);
 419         } elsif ($opt_target eq "samba3") {
 420                 $testenv_default = "member";
 421                 require target::Samba3;
 422                 $target = new Samba3($bindir, \%binary_mapping, $srcdir_abs, $server_maxtime);
 423         }
 424 }
 425
 426 sub read_test_regexes($)
 427 {
 428         my ($name) = @_;
 429         my @ret = ();
 430         open(LF, "<$name") or die("unable to read $name: $!");
 431         while (<LF>) {
 432                 chomp;
 433                 next if (/^#/);
 434                 if (/^(.*?)([ \t]+)\#([\t ]*)(.*?)$/) {
 435                         push (@ret, [$1, $4]);
 436                 } else {
 437                         s/^(.*?)([ \t]+)\#([\t ]*)(.*?)$//;
 438                         push (@ret, [$_, undef]);
 439                 }
 440         }
 441         close(LF);
 442         return @ret;
 443 }
 444
 445 foreach (@opt_exclude) {
 446         push (@excludes, read_test_regexes($_));
 447 }
 448
 449 foreach (@opt_include) {
 450         push (@includes, read_test_regexes($_));
 451 }
 452
 453 my $interfaces = join(',', ("127.0.0.11/8",
 454                             "127.0.0.12/8",
 455                             "127.0.0.13/8",
 456                             "127.0.0.14/8",
 457                             "127.0.0.15/8",
 458                             "127.0.0.16/8"));
 459
 460 my $clientdir = "$prefix_abs/client";
 461
 462 my $conffile = "$clientdir/client.conf";
 463 $ENV{SMB_CONF_PATH} = $conffile;
 464
 465 sub write_clientconf($$$)
 466 {
 467         my ($conffile, $clientdir, $vars) = @_;
 468
 469         mkdir("$clientdir", 0777) unless -d "$clientdir";
 470
 471         if ( -d "$clientdir/private" ) {
 472                 unlink <$clientdir/private/*>;
 473         } else {
 474                 mkdir("$clientdir/private", 0777);
 475         }
 476
 477         if ( -d "$clientdir/lockdir" ) {
 478                 unlink <$clientdir/lockdir/*>;
 479         } else {
 480                 mkdir("$clientdir/lockdir", 0777);
 481         }
 482
 483         if ( -d "$clientdir/statedir" ) {
 484                 unlink <$clientdir/statedir/*>;
 485         } else {
 486                 mkdir("$clientdir/statedir", 0777);
 487         }
 488
 489         if ( -d "$clientdir/cachedir" ) {
 490                 unlink <$clientdir/cachedir/*>;
 491         } else {
 492                 mkdir("$clientdir/cachedir", 0777);
 493         }
 494
 495         # this is ugly, but the ncalrpcdir needs exactly 0755
 496         # otherwise tests fail.
 497         my $mask = umask;
 498         umask 0022;
 499         if ( -d "$clientdir/ncalrpcdir/np" ) {
 500                 unlink <$clientdir/ncalrpcdir/np/*>;
 501                 rmdir "$clientdir/ncalrpcdir/np";
 502         }
 503         if ( -d "$clientdir/ncalrpcdir" ) {
 504                 unlink <$clientdir/ncalrpcdir/*>;
 505                 rmdir "$clientdir/ncalrpcdir";
 506         }
 507         mkdir("$clientdir/ncalrpcdir", 0755);
 508         umask $mask;
 509
 510         open(CF, ">$conffile");
 511         print CF "[global]\n";
 512         print CF "\tnetbios name = client\n";
 513         if (defined($vars->{DOMAIN})) {
 514                 print CF "\tworkgroup = $vars->{DOMAIN}\n";
 515         }
 516         if (defined($vars->{REALM})) {
 517                 print CF "\trealm = $vars->{REALM}\n";
 518         }
 519         if ($opt_socket_wrapper) {
 520                 print CF "\tinterfaces = $interfaces\n";
 521         }
 522         print CF "
 523         private dir = $clientdir/private
 524         lock dir = $clientdir/lockdir
 525         state directory = $clientdir/statedir
 526         cache directory = $clientdir/cachedir
 527         ncalrpc dir = $clientdir/ncalrpcdir
 528         name resolve order = file bcast
 529         panic action = $RealBin/gdb_backtrace \%d
 530         max xmit = 32K
 531         notify:inotify = false
 532         ldb:nosync = true
 533         system:anonymous = true
 534         client lanman auth = Yes
 535         log level = 1
 536         torture:basedir = $clientdir
 537 #We don't want to pass our self-tests if the PAC code is wrong
 538         gensec:require_pac = true
 539         resolv:host file = $prefix_abs/dns_host_file
 540 #We don't want to run 'speed' tests for very long
 541         torture:timelimit = 1
 542         winbind separator = /
 543 ";
 544         close(CF);
 545 }
 546
 547 my @todo = ();
 548
 549 sub should_run_test($)
 550 {
 551         my $name = shift;
 552         if ($#tests == -1) {
 553                 return 1;
 554         }
 555         for (my $i=0; $i <= $#tests; $i++) {
 556                 if ($name =~ /$tests[$i]/i) {
 557                         return 1;
 558                 }
 559         }
 560         return 0;
 561 }
 562
 563 sub read_testlist($)
 564 {
 565         my ($filename) = @_;
 566
 567         my @ret = ();
 568         open(IN, $filename) or die("Unable to open $filename: $!");
 569
 570         while (<IN>) {
 571                 if (/-- TEST(-LOADLIST|) --\n/) {
 572                         my $supports_loadlist = (defined($1) and $1 eq "-LOADLIST");
 573                         my $name = <IN>;
 574                         $name =~ s/\n//g;
 575                         my $env = <IN>;
 576                         $env =~ s/\n//g;
 577                         my $cmdline = <IN>;
 578                         $cmdline =~ s/\n//g;
 579                         if (should_run_test($name) == 1) {
 580                                 push (@ret, [$name, $env, $cmdline, $supports_loadlist]);
 581                         }
 582                 } else {
 583                         print;
 584                 }
 585         }
 586         close(IN) or die("Error creating recipe from $filename");
 587         return @ret;
 588 }
 589
 590 if ($#testlists == -1) {
 591         die("No testlists specified");
 592 }
 593
 594 $ENV{SELFTEST_PREFIX} = "$prefix_abs";
 595 $ENV{SELFTEST_TMPDIR} = "$tmpdir_abs";
 596 $ENV{TEST_DATA_PREFIX} = "$tmpdir_abs";
 597 if ($opt_socket_wrapper) {
 598         $ENV{SELFTEST_INTERFACES} = $interfaces;
 599 } else {
 600         $ENV{SELFTEST_INTERFACES} = "";
 601 }
 602 if ($opt_quick) {
 603         $ENV{SELFTEST_QUICK} = "1";
 604 } else {
 605         $ENV{SELFTEST_QUICK} = "";
 606 }
 607 $ENV{SELFTEST_MAXTIME} = $torture_maxtime;
 608
 609 my @available = ();
 610 foreach my $fn (@testlists) {
 611         foreach (read_testlist($fn)) {
 612                 my $name = $$_[0];
 613                 next if (@includes and not defined(find_in_list(\@includes, $name)));
 614                 push (@available, $_);
 615         }
 616 }
 617
 618 my $restricted = undef;
 619 my $restricted_used = {};
 620
 621 if ($opt_load_list) {
 622         $restricted = [];
 623         open(LOAD_LIST, "<$opt_load_list") or die("Unable to open $opt_load_list");
 624         while (<LOAD_LIST>) {
 625                 chomp;
 626                 push (@$restricted, $_);
 627         }
 628         close(LOAD_LIST);
 629 }
 630
 631 my $individual_tests = undef;
 632 $individual_tests = {};
 633
 634 foreach my $testsuite (@available) {
 635         my $name = $$testsuite[0];
 636         my $skipreason = skip($name);
 637         if (defined($restricted)) {
 638                 # Find the testsuite for this test
 639                 my $match = undef;
 640                 foreach my $r (@$restricted) {
 641                         if ($r eq $name) {
 642                                 $individual_tests->{$name} = [];
 643                                 $match = $r;
 644                                 $restricted_used->{$r} = 1;
 645                         } elsif (substr($r, 0, length($name)+1) eq "$name.") {
 646                                 push(@{$individual_tests->{$name}}, $r);
 647                                 $match = $r;
 648                                 $restricted_used->{$r} = 1;
 649                         }
 650                 }
 651                 if ($match) {
 652                         if (defined($skipreason)) {
 653                                 if (not $opt_list) {
 654                                         Subunit::skip_testsuite($name, $skipreason);
 655                                 }
 656                         } else {
 657                                 push(@todo, $testsuite);
 658                         }
 659                 }
 660         } elsif (defined($skipreason)) {
 661                 if (not $opt_list) {
 662                         Subunit::skip_testsuite($name, $skipreason);
 663                 }
 664         } else {
 665                 push(@todo, $testsuite);
 666         }
 667 }
 668
 669 if (defined($restricted)) {
 670         foreach (@$restricted) {
 671                 unless (defined($restricted_used->{$_})) {
 672                         print "No test or testsuite found matching $_\n";
 673                 }
 674         }
 675 } elsif ($#todo == -1) {
 676         print STDERR "No tests to run\n";
 677         exit(1);
 678 }
 679
 680 my $suitestotal = $#todo + 1;
 681
 682 unless ($opt_list) {
 683         Subunit::progress($suitestotal);
 684         Subunit::report_time(time());
 685 }
 686
 687 my $i = 0;
 688 $| = 1;
 689
 690 my %running_envs = ();
 691
 692 sub get_running_env($)
 693 {
 694         my ($name) = @_;
 695
 696         my $envname = $name;
 697
 698         $envname =~ s/:.*//;
 699
 700         return $running_envs{$envname};
 701 }
 702
 703 my @exported_envvars = (
 704         # domain stuff
 705         "DOMAIN",
 706         "REALM",
 707
 708         # domain controller stuff
 709         "DC_SERVER",
 710         "DC_SERVER_IP",
 711         "DC_SERVER_IPV6",
 712         "DC_NETBIOSNAME",
 713         "DC_NETBIOSALIAS",
 714
 715         # domain member
 716         "MEMBER_SERVER",
 717         "MEMBER_SERVER_IP",
 718         "MEMBER_SERVER_IPV6",
 719         "MEMBER_NETBIOSNAME",
 720         "MEMBER_NETBIOSALIAS",
 721
 722         # rpc proxy controller stuff
 723         "RPC_PROXY_SERVER",
 724         "RPC_PROXY_SERVER_IP",
 725         "RPC_PROXY_SERVER_IPV6",
 726         "RPC_PROXY_NETBIOSNAME",
 727         "RPC_PROXY_NETBIOSALIAS",
 728
 729         # domain controller stuff for Vampired DC
 730         "VAMPIRE_DC_SERVER",
 731         "VAMPIRE_DC_SERVER_IP",
 732         "VAMPIRE_DC_SERVER_IPV6",
 733         "VAMPIRE_DC_NETBIOSNAME",
 734         "VAMPIRE_DC_NETBIOSALIAS",
 735
 736         "PROMOTED_DC_SERVER",
 737         "PROMOTED_DC_SERVER_IP",
 738         "PROMOTED_DC_SERVER_IPV6",
 739         "PROMOTED_DC_NETBIOSNAME",
 740         "PROMOTED_DC_NETBIOSALIAS",
 741
 742         # server stuff
 743         "SERVER",
 744         "SERVER_IP",
 745         "SERVER_IPV6",
 746         "NETBIOSNAME",
 747         "NETBIOSALIAS",
 748
 749         # user stuff
 750         "USERNAME",
 751         "USERID",
 752         "PASSWORD",
 753         "DC_USERNAME",
 754         "DC_PASSWORD",
 755
 756         # misc stuff
 757         "KRB5_CONFIG",
 758         "SELFTEST_WINBINDD_SOCKET_DIR",
 759         "WINBINDD_PRIV_PIPE_DIR",
 760         "NMBD_SOCKET_DIR",
 761         "LOCAL_PATH",
 762
 763         # nss_wrapper
 764         "NSS_WRAPPER_PASSWD",
 765         "NSS_WRAPPER_GROUP",
 766
 767         # UID/GID for rfc2307 mapping tests
 768         "UID_RFC2307TEST",
 769         "GID_RFC2307TEST"
 770 );
 771
 772 sub sighandler($)
 773 {
 774         my $signame = shift;
 775
 776         $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = 'DEFAULT';
 777         $SIG{PIPE} = 'IGNORE';
 778
 779         open(STDOUT, ">&STDERR") or die "can't dup STDOUT to STDERR: $!";
 780
 781         print "$0: PID[$$]: Got SIG${signame} teardown environments.\n";
 782         teardown_env($_) foreach(keys %running_envs);
 783         system("pstree -p $$");
 784         print "$0: PID[$$]: Exiting...\n";
 785         exit(1);
 786 };
 787
 788 $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = $SIG{PIPE} = \&sighandler;
 789
 790 sub setup_env($$)
 791 {
 792         my ($name, $prefix) = @_;
 793
 794         my $testenv_vars = undef;
 795
 796         my $envname = $name;
 797         my $option = $name;
 798
 799         $envname =~ s/:.*//;
 800         $option =~ s/^[^:]*//;
 801         $option =~ s/^://;
 802
 803         $option = "client" if $option eq "";
 804
 805         if ($envname eq "none") {
 806                 $testenv_vars = {};
 807         } elsif (defined(get_running_env($envname))) {
 808                 $testenv_vars = get_running_env($envname);
 809                 if (not $testenv_vars->{target}->check_env($testenv_vars)) {
 810                         print $testenv_vars->{target}->getlog_env($testenv_vars);
 811                         $testenv_vars = undef;
 812                 }
 813         } else {
 814                 $testenv_vars = $target->setup_env($envname, $prefix);
 815                 if (defined($testenv_vars) and $testenv_vars eq "UNKNOWN") {
 816                     return $testenv_vars;
 817                 } elsif (defined($testenv_vars) && not defined($testenv_vars->{target})) {
 818                         $testenv_vars->{target} = $target;
 819                 }
 820                 if (not defined($testenv_vars)) {
 821                         warn("$opt_target can't start up known environment '$envname'");
 822                 }
 823         }
 824
 825         return undef unless defined($testenv_vars);
 826
 827         $running_envs{$envname} = $testenv_vars;
 828
 829         if ($option eq "local") {
 830                 SocketWrapper::set_default_iface($testenv_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 831                 $ENV{SMB_CONF_PATH} = $testenv_vars->{SERVERCONFFILE};
 832         } elsif ($option eq "client") {
 833                 SocketWrapper::set_default_iface(11);
 834                 write_clientconf($conffile, $clientdir, $testenv_vars);
 835                 $ENV{SMB_CONF_PATH} = $conffile;
 836         } else {
 837                 die("Unknown option[$option] for envname[$envname]");
 838         }
 839
 840         foreach (@exported_envvars) {
 841                 if (defined($testenv_vars->{$_})) {
 842                         $ENV{$_} = $testenv_vars->{$_};
 843                 } else {
 844                         delete $ENV{$_};
 845                 }
 846         }
 847
 848         return $testenv_vars;
 849 }
 850
 851 sub exported_envvars_str($)
 852 {
 853         my ($testenv_vars) = @_;
 854         my $out = "";
 855
 856         foreach (@exported_envvars) {
 857                 next unless defined($testenv_vars->{$_});
 858                 $out .= $_."=".$testenv_vars->{$_}."\n";
 859         }
 860
 861         return $out;
 862 }
 863
 864 sub getlog_env($)
 865 {
 866         my ($envname) = @_;
 867         return "" if ($envname eq "none");
 868         my $env = get_running_env($envname);
 869         return $env->{target}->getlog_env($env);
 870 }
 871
 872 sub check_env($)
 873 {
 874         my ($envname) = @_;
 875         return 1 if ($envname eq "none");
 876         my $env = get_running_env($envname);
 877         return $env->{target}->check_env($env);
 878 }
 879
 880 sub teardown_env($)
 881 {
 882         my ($envname) = @_;
 883         return if ($envname eq "none");
 884         print STDERR "teardown_env($envname)\n";
 885         my $env = get_running_env($envname);
 886         $env->{target}->teardown_env($env);
 887         delete $running_envs{$envname};
 888 }
 889
 890 # This 'global' file needs to be empty when we start
 891 unlink("$prefix_abs/dns_host_file");
 892 unlink("$prefix_abs/hosts");
 893
 894 if ($opt_random_order) {
 895         require List::Util;
 896         my @newtodo = List::Util::shuffle(@todo);
 897         @todo = @newtodo;
 898 }
 899
 900 if ($opt_testenv) {
 901         my $testenv_name = $ENV{SELFTEST_TESTENV};
 902         $testenv_name = $testenv_default unless defined($testenv_name);
 903
 904         my $testenv_vars = setup_env($testenv_name, $prefix);
 905
 906         if (not $testenv_vars or $testenv_vars eq "UNKNOWN") {
 907                 die("Unable to setup environment $testenv_name");
 908         }
 909
 910         $ENV{PIDDIR} = $testenv_vars->{PIDDIR};
 911         $ENV{ENVNAME} = $testenv_name;
 912
 913         my $envvarstr = exported_envvars_str($testenv_vars);
 914
 915         my @term_args = ("echo -e \"
 916 Welcome to the Samba4 Test environment '$testenv_name'
 917
 918 This matches the client environment used in make test
 919 server is pid `cat \$PIDDIR/samba.pid`
 920
 921 Some useful environment variables:
 922 TORTURE_OPTIONS=\$TORTURE_OPTIONS
 923 SMB_CONF_PATH=\$SMB_CONF_PATH
 924
 925 $envvarstr
 926 \" && LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} bash");
 927         my @term = ();
 928         if ($ENV{TERMINAL}) {
 929             @term = ($ENV{TERMINAL});
 930         } else {
 931             @term = ("xterm", "-e");
 932             unshift(@term_args, ("bash", "-c"));
 933         }
 934
 935         system(@term, @term_args);
 936
 937         teardown_env($testenv_name);
 938 } elsif ($opt_list) {
 939         foreach (@todo) {
 940                 my $cmd = $$_[2];
 941                 my $name = $$_[0];
 942                 my $envname = $$_[1];
 943
 944                 unless($cmd =~ /\$LISTOPT/) {
 945                         warn("Unable to list tests in $name");
 946                         # Rather than ignoring this testsuite altogether, just pretend the entire testsuite is
 947                         # a single "test".
 948                         print "$name\n";
 949                         next;
 950                 }
 951
 952                 $cmd =~ s/\$LISTOPT/--list/g;
 953
 954                 system($cmd);
 955
 956                 if ($? == -1) {
 957                         die("Unable to run $cmd: $!");
 958                 } elsif ($? & 127) {
 959                         die(sprintf("%s died with signal %d, %s coredump\n", $cmd, ($? & 127),  ($? & 128) ? 'with' : 'without'));
 960                 }
 961
 962                 my $exitcode = $? >> 8;
 963                 if ($exitcode != 0) {
 964                         die("$cmd exited with exit code $exitcode");
 965                 }
 966         }
 967 } else {
 968         foreach (@todo) {
 969                 $i++;
 970                 my $cmd = $$_[2];
 971                 my $name = $$_[0];
 972                 my $envname = $$_[1];
 973
 974                 my $envvars = setup_env($envname, $prefix);
 975                 if (not defined($envvars)) {
 976                         Subunit::start_testsuite($name);
 977                         Subunit::end_testsuite($name, "error",
 978                                 "unable to set up environment $envname - exiting");
 979                         next;
 980                 } elsif ($envvars eq "UNKNOWN") {
 981                         Subunit::start_testsuite($name);
 982                         Subunit::end_testsuite($name, "skip",
 983                                 "environment $envname is unknown in this test backend - skipping");
 984                         next;
 985                 }
 986
 987                 # Generate a file with the individual tests to run, if the
 988                 # test runner for this test suite supports it.
 989                 if ($individual_tests and $individual_tests->{$name}) {
 990                         if ($$_[3]) {
 991                                 my ($fh, $listid_file) = tempfile(UNLINK => 0);
 992                                 foreach my $test (@{$individual_tests->{$name}}) {
 993                                         print $fh substr($test, length($name)+1) . "\n";
 994                                 }
 995                                 $cmd =~ s/\$LOADLIST/--load-list=$listid_file/g;
 996                         } else {
 997                                 warn("Unable to run individual tests in $name, it does not support --loadlist.");
 998                         }
 999                 }
1000
1001                 run_testsuite($envname, $name, $cmd, $i, $suitestotal);
1002
1003                 teardown_env($envname) if ($opt_resetup_env);
1004         }
1005 }
1006
1007 print "\n";
1008
1009 teardown_env($_) foreach (keys %running_envs);
1010
1011 my $failed = 0;
1012
1013 # if there were any valgrind failures, show them
1014 foreach (<$prefix/valgrind.log*>) {
1015         next unless (-s $_);
1016         print "VALGRIND FAILURE\n";
1017         $failed++;
1018         system("cat $_");
1019 }
1020 exit 0;