selftest/selftest.pl

   1 #!/usr/bin/perl
   2 # Bootstrap Samba and run a number of tests against it.
   3 # Copyright (C) 2005-2010 Jelmer Vernooij <jelmer@samba.org>
   4 # Copyright (C) 2007-2009 Stefan Metzmacher <metze@samba.org>
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 use strict;
  20
  21 use FindBin qw($RealBin $Script);
  22 use File::Spec;
  23 use File::Temp qw(tempfile);
  24 use Getopt::Long;
  25 use POSIX;
  26 use Cwd qw(abs_path);
  27 use lib "$RealBin";
  28 use Subunit;
  29 use SocketWrapper;
  30
  31 eval {
  32 require Time::HiRes;
  33 Time::HiRes->import("time");
  34 };
  35 if ($@) {
  36         print "You don't have Time::Hires installed !\n";
  37 }
  38
  39 my $opt_help = 0;
  40 my $opt_target = "samba";
  41 my $opt_quick = 0;
  42 my $opt_socket_wrapper = 0;
  43 my $opt_socket_wrapper_pcap = undef;
  44 my $opt_socket_wrapper_keep_pcap = undef;
  45 my $opt_random_order = 0;
  46 my $opt_one = 0;
  47 my @opt_exclude = ();
  48 my @opt_include = ();
  49 my $opt_testenv = 0;
  50 my $opt_list = 0;
  51 my $ldap = undef;
  52 my $opt_resetup_env = undef;
  53 my $opt_binary_mapping = "";
  54 my $opt_load_list = undef;
  55 my $opt_libnss_wrapper_so_path = "";
  56 my $opt_libuid_wrapper_so_path = "";
  57 my @testlists = ();
  58
  59 my $srcdir = ".";
  60 my $bindir = "./bin";
  61 my $prefix = "./st";
  62
  63 my @includes = ();
  64 my @excludes = ();
  65
  66 sub pipe_handler {
  67         my $sig = shift @_;
  68         print STDERR "Exiting early because of SIGPIPE.\n";
  69         exit(1);
  70 }
  71
  72 $SIG{PIPE} = \&pipe_handler;
  73
  74 sub find_in_list($$)
  75 {
  76         my ($list, $fullname) = @_;
  77
  78         foreach (@$list) {
  79                 if ($fullname =~ /$$_[0]/) {
  80                          return ($$_[1]) if ($$_[1]);
  81                          return "";
  82                 }
  83         }
  84
  85         return undef;
  86 }
  87
  88 sub skip($)
  89 {
  90         my ($name) = @_;
  91
  92         return find_in_list(\@excludes, $name);
  93 }
  94
  95 sub getlog_env($);
  96
  97 sub setup_pcap($)
  98 {
  99         my ($name) = @_;
 100
 101         return unless ($opt_socket_wrapper_pcap);
 102         return unless defined($ENV{SOCKET_WRAPPER_PCAP_DIR});
 103
 104         my $fname = $name;
 105         $fname =~ s%[^abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789\-]%_%g;
 106
 107         my $pcap_file = "$ENV{SOCKET_WRAPPER_PCAP_DIR}/$fname.pcap";
 108
 109         SocketWrapper::setup_pcap($pcap_file);
 110
 111         return $pcap_file;
 112 }
 113
 114 sub cleanup_pcap($$)
 115 {
 116         my ($pcap_file, $exitcode) = @_;
 117
 118         return unless ($opt_socket_wrapper_pcap);
 119         return if ($opt_socket_wrapper_keep_pcap);
 120         return unless ($exitcode == 0);
 121         return unless defined($pcap_file);
 122
 123         unlink($pcap_file);
 124 }
 125
 126 # expand strings from %ENV
 127 sub expand_environment_strings($)
 128 {
 129         my $s = shift;
 130         # we use a reverse sort so we do the longer ones first
 131         foreach my $k (sort { $b cmp $a } keys %ENV) {
 132                 $s =~ s/\$$k/$ENV{$k}/g;
 133         }
 134         return $s;
 135 }
 136
 137 sub run_testsuite($$$$$)
 138 {
 139         my ($envname, $name, $cmd, $i, $totalsuites) = @_;
 140         my $pcap_file = setup_pcap($name);
 141
 142         Subunit::start_testsuite($name);
 143         Subunit::progress_push();
 144         Subunit::report_time(time());
 145         system($cmd);
 146         Subunit::report_time(time());
 147         Subunit::progress_pop();
 148
 149         if ($? == -1) {
 150                 Subunit::progress_pop();
 151                 Subunit::end_testsuite($name, "error", "Unable to run $cmd: $!");
 152                 exit(1);
 153         } elsif ($? & 127) {
 154                 Subunit::end_testsuite($name, "error",
 155                         sprintf("%s died with signal %d, %s coredump\n", $cmd, ($? & 127),  ($? & 128) ? 'with' : 'without'));
 156                 exit(1);
 157         }
 158
 159         my $exitcode = $? >> 8;
 160
 161         my $envlog = getlog_env($envname);
 162         if ($envlog ne "") {
 163                 print "envlog: $envlog\n";
 164         }
 165
 166         print "command: $cmd\n";
 167         printf "expanded command: %s\n", expand_environment_strings($cmd);
 168
 169         if ($exitcode == 0) {
 170                 Subunit::end_testsuite($name, "success");
 171         } else {
 172                 Subunit::end_testsuite($name, "failure", "Exit code was $exitcode");
 173         }
 174
 175         cleanup_pcap($pcap_file, $exitcode);
 176
 177         if (not $opt_socket_wrapper_keep_pcap and defined($pcap_file)) {
 178                 print "PCAP FILE: $pcap_file\n";
 179         }
 180
 181         if ($exitcode != 0) {
 182                 exit(1) if ($opt_one);
 183         }
 184
 185         return $exitcode;
 186 }
 187
 188 sub ShowHelp()
 189 {
 190         print "Samba test runner
 191 Copyright (C) Jelmer Vernooij <jelmer\@samba.org>
 192 Copyright (C) Stefan Metzmacher <metze\@samba.org>
 193
 194 Usage: $Script [OPTIONS] TESTNAME-REGEX
 195
 196 Generic options:
 197  --help                     this help page
 198  --target=samba[3]|win      Samba version to target
 199  --testlist=FILE            file to read available tests from
 200
 201 Paths:
 202  --prefix=DIR               prefix to run tests in [st]
 203  --srcdir=DIR               source directory [.]
 204  --bindir=DIR               binaries directory [./bin]
 205
 206 Preload cwrap:
 207  --nss_wrapper_so_path=FILE the nss_wrapper library to preload
 208  --uid_wrapper_so_path=FILE the uid_wrapper library to preload
 209
 210 Target Specific:
 211  --socket-wrapper-pcap      save traffic to pcap directories
 212  --socket-wrapper-keep-pcap keep all pcap files, not just those for tests that
 213                             failed
 214  --socket-wrapper           enable socket wrapper
 215
 216 Samba4 Specific:
 217  --ldap=openldap|fedora-ds  back samba onto specified ldap server
 218
 219 Behaviour:
 220  --quick                    run quick overall test
 221  --one                      abort when the first test fails
 222  --testenv                  run a shell in the requested test environment
 223  --list                     list available tests
 224 ";
 225         exit(0);
 226 }
 227
 228 my $result = GetOptions (
 229                 'help|h|?' => \$opt_help,
 230                 'target=s' => \$opt_target,
 231                 'prefix=s' => \$prefix,
 232                 'socket-wrapper' => \$opt_socket_wrapper,
 233                 'socket-wrapper-pcap' => \$opt_socket_wrapper_pcap,
 234                 'socket-wrapper-keep-pcap' => \$opt_socket_wrapper_keep_pcap,
 235                 'quick' => \$opt_quick,
 236                 'one' => \$opt_one,
 237                 'exclude=s' => \@opt_exclude,
 238                 'include=s' => \@opt_include,
 239                 'srcdir=s' => \$srcdir,
 240                 'bindir=s' => \$bindir,
 241                 'testenv' => \$opt_testenv,
 242                 'list' => \$opt_list,
 243                 'ldap:s' => \$ldap,
 244                 'resetup-environment' => \$opt_resetup_env,
 245                 'testlist=s' => \@testlists,
 246                 'random-order' => \$opt_random_order,
 247                 'load-list=s' => \$opt_load_list,
 248                 'binary-mapping=s' => \$opt_binary_mapping,
 249                 'nss_wrapper_so_path=s' => \$opt_libnss_wrapper_so_path,
 250                 'uid_wrapper_so_path=s' => \$opt_libuid_wrapper_so_path
 251             );
 252
 253 exit(1) if (not $result);
 254
 255 ShowHelp() if ($opt_help);
 256
 257 die("--list and --testenv are mutually exclusive") if ($opt_list and $opt_testenv);
 258
 259 # we want unbuffered output
 260 $| = 1;
 261
 262 my @tests = @ARGV;
 263
 264 # quick hack to disable rpc validation when using valgrind - its way too slow
 265 unless (defined($ENV{VALGRIND})) {
 266         $ENV{VALIDATE} = "validate";
 267         $ENV{MALLOC_CHECK_} = 3;
 268 }
 269
 270 # make all our python scripts unbuffered
 271 $ENV{PYTHONUNBUFFERED} = 1;
 272
 273 my $bindir_abs = abs_path($bindir);
 274
 275 # Backwards compatibility:
 276 if (defined($ENV{TEST_LDAP}) and $ENV{TEST_LDAP} eq "yes") {
 277         if (defined($ENV{FEDORA_DS_ROOT})) {
 278                 $ldap = "fedora-ds";
 279         } else {
 280                 $ldap = "openldap";
 281         }
 282 }
 283
 284 my $torture_maxtime = ($ENV{TORTURE_MAXTIME} or 1200);
 285 if ($ldap) {
 286         # LDAP is slow
 287         $torture_maxtime *= 2;
 288 }
 289
 290 $prefix =~ s+//+/+;
 291 $prefix =~ s+/./+/+;
 292 $prefix =~ s+/$++;
 293
 294 die("using an empty prefix isn't allowed") unless $prefix ne "";
 295
 296 # Ensure we have the test prefix around.
 297 #
 298 # We need restrictive
 299 # permissions on this as some subdirectories in this tree will have
 300 # wider permissions (ie 0777) and this would allow other users on the
 301 # host to subvert the test process.
 302 mkdir($prefix, 0700) unless -d $prefix;
 303 chmod 0700, $prefix;
 304
 305 my $prefix_abs = abs_path($prefix);
 306 my $tmpdir_abs = abs_path("$prefix/tmp");
 307 mkdir($tmpdir_abs, 0777) unless -d $tmpdir_abs;
 308
 309 my $srcdir_abs = abs_path($srcdir);
 310
 311 die("using an empty absolute prefix isn't allowed") unless $prefix_abs ne "";
 312 die("using '/' as absolute prefix isn't allowed") unless $prefix_abs ne "/";
 313
 314 $ENV{PREFIX} = $prefix;
 315 $ENV{KRB5CCNAME} = "$prefix/krb5ticket";
 316 $ENV{PREFIX_ABS} = $prefix_abs;
 317 $ENV{SRCDIR} = $srcdir;
 318 $ENV{SRCDIR_ABS} = $srcdir_abs;
 319 $ENV{BINDIR} = $bindir_abs;
 320
 321 my $tls_enabled = not $opt_quick;
 322 $ENV{TLS_ENABLED} = ($tls_enabled?"yes":"no");
 323
 324 sub prefix_pathvar($$)
 325 {
 326         my ($name, $newpath) = @_;
 327         if (defined($ENV{$name})) {
 328                 $ENV{$name} = "$newpath:$ENV{$name}";
 329         } else {
 330                 $ENV{$name} = $newpath;
 331         }
 332 }
 333 prefix_pathvar("PKG_CONFIG_PATH", "$bindir_abs/pkgconfig");
 334 prefix_pathvar("PYTHONPATH", "$bindir_abs/python");
 335
 336 if ($opt_socket_wrapper_keep_pcap) {
 337         # Socket wrapper keep pcap implies socket wrapper pcap
 338         $opt_socket_wrapper_pcap = 1;
 339 }
 340
 341 if ($opt_socket_wrapper_pcap) {
 342         # Socket wrapper pcap implies socket wrapper
 343         $opt_socket_wrapper = 1;
 344 }
 345
 346 my $ld_preload = $ENV{LD_PRELOAD};
 347
 348 if ($opt_libnss_wrapper_so_path) {
 349         if ($ld_preload) {
 350                 $ld_preload = "$ld_preload:$opt_libnss_wrapper_so_path";
 351         } else {
 352                 $ld_preload = "$opt_libnss_wrapper_so_path";
 353         }
 354 }
 355
 356 if ($opt_libuid_wrapper_so_path) {
 357         if ($ld_preload) {
 358                 $ld_preload = "$ld_preload:$opt_libuid_wrapper_so_path";
 359         } else {
 360                 $ld_preload = "$opt_libuid_wrapper_so_path";
 361         }
 362 }
 363
 364 $ENV{LD_PRELOAD} = $ld_preload;
 365 print "LD_PRELOAD=$ENV{LD_PRELOAD}\n";
 366
 367 # Enable uid_wrapper globally
 368 $ENV{UID_WRAPPER} = 1;
 369
 370 # Disable RTLD_DEEPBIND hack for Samba bind dlz module
 371 #
 372 # This is needed in order to allow the ldb_*ldap module
 373 # to work with a preloaded socket wrapper.
 374 $ENV{LDB_MODULES_DISABLE_DEEPBIND} = 1;
 375
 376 my $socket_wrapper_dir;
 377 if ($opt_socket_wrapper) {
 378         $socket_wrapper_dir = SocketWrapper::setup_dir("$prefix_abs/w", $opt_socket_wrapper_pcap);
 379         print "SOCKET_WRAPPER_DIR=$socket_wrapper_dir\n";
 380 } elsif (not $opt_list) {
 381          unless ($< == 0) {
 382                  warn("not using socket wrapper, but also not running as root. Will not be able to listen on proper ports");
 383          }
 384 }
 385
 386 my $target;
 387 my $testenv_default = "none";
 388
 389 my %binary_mapping = ();
 390 if ($opt_binary_mapping) {
 391     my @binmapping_list = split(/,/, $opt_binary_mapping);
 392     foreach my $mapping (@binmapping_list) {
 393         my ($bin, $map) = split(/\:/, $mapping);
 394         $binary_mapping{$bin} = $map;
 395     }
 396 }
 397
 398 $ENV{BINARY_MAPPING} = $opt_binary_mapping;
 399
 400 # After this many seconds, the server will self-terminate.  All tests
 401 # must terminate in this time, and testenv will only stay alive this
 402 # long
 403
 404 my $server_maxtime = 7500;
 405 if (defined($ENV{SMBD_MAXTIME}) and $ENV{SMBD_MAXTIME} ne "") {
 406     $server_maxtime = $ENV{SMBD_MAXTIME};
 407 }
 408
 409 unless ($opt_list) {
 410         if ($opt_target eq "samba") {
 411                 if ($opt_socket_wrapper and `$bindir/smbd -b | grep SOCKET_WRAPPER` eq "") {
 412                         die("You must include --enable-socket-wrapper when compiling Samba in order to execute 'make test'.  Exiting....");
 413                 }
 414                 $testenv_default = "dc";
 415                 require target::Samba;
 416                 $target = new Samba($bindir, \%binary_mapping, $ldap, $srcdir, $server_maxtime);
 417         } elsif ($opt_target eq "samba3") {
 418                 if ($opt_socket_wrapper and `$bindir/smbd -b | grep SOCKET_WRAPPER` eq "") {
 419                         die("You must include --enable-socket-wrapper when compiling Samba in order to execute 'make test'.  Exiting....");
 420                 }
 421                 $testenv_default = "member";
 422                 require target::Samba3;
 423                 $target = new Samba3($bindir, \%binary_mapping, $srcdir_abs, $server_maxtime);
 424         }
 425 }
 426
 427 sub read_test_regexes($)
 428 {
 429         my ($name) = @_;
 430         my @ret = ();
 431         open(LF, "<$name") or die("unable to read $name: $!");
 432         while (<LF>) {
 433                 chomp;
 434                 next if (/^#/);
 435                 if (/^(.*?)([ \t]+)\#([\t ]*)(.*?)$/) {
 436                         push (@ret, [$1, $4]);
 437                 } else {
 438                         s/^(.*?)([ \t]+)\#([\t ]*)(.*?)$//;
 439                         push (@ret, [$_, undef]);
 440                 }
 441         }
 442         close(LF);
 443         return @ret;
 444 }
 445
 446 foreach (@opt_exclude) {
 447         push (@excludes, read_test_regexes($_));
 448 }
 449
 450 foreach (@opt_include) {
 451         push (@includes, read_test_regexes($_));
 452 }
 453
 454 my $interfaces = join(',', ("127.0.0.11/8",
 455                             "127.0.0.12/8",
 456                             "127.0.0.13/8",
 457                             "127.0.0.14/8",
 458                             "127.0.0.15/8",
 459                             "127.0.0.16/8"));
 460
 461 my $clientdir = "$prefix_abs/client";
 462
 463 my $conffile = "$clientdir/client.conf";
 464 $ENV{SMB_CONF_PATH} = $conffile;
 465
 466 sub write_clientconf($$$)
 467 {
 468         my ($conffile, $clientdir, $vars) = @_;
 469
 470         mkdir("$clientdir", 0777) unless -d "$clientdir";
 471
 472         if ( -d "$clientdir/private" ) {
 473                 unlink <$clientdir/private/*>;
 474         } else {
 475                 mkdir("$clientdir/private", 0777);
 476         }
 477
 478         if ( -d "$clientdir/lockdir" ) {
 479                 unlink <$clientdir/lockdir/*>;
 480         } else {
 481                 mkdir("$clientdir/lockdir", 0777);
 482         }
 483
 484         if ( -d "$clientdir/statedir" ) {
 485                 unlink <$clientdir/statedir/*>;
 486         } else {
 487                 mkdir("$clientdir/statedir", 0777);
 488         }
 489
 490         if ( -d "$clientdir/cachedir" ) {
 491                 unlink <$clientdir/cachedir/*>;
 492         } else {
 493                 mkdir("$clientdir/cachedir", 0777);
 494         }
 495
 496         # this is ugly, but the ncalrpcdir needs exactly 0755
 497         # otherwise tests fail.
 498         my $mask = umask;
 499         umask 0022;
 500         if ( -d "$clientdir/ncalrpcdir/np" ) {
 501                 unlink <$clientdir/ncalrpcdir/np/*>;
 502                 rmdir "$clientdir/ncalrpcdir/np";
 503         }
 504         if ( -d "$clientdir/ncalrpcdir" ) {
 505                 unlink <$clientdir/ncalrpcdir/*>;
 506                 rmdir "$clientdir/ncalrpcdir";
 507         }
 508         mkdir("$clientdir/ncalrpcdir", 0755);
 509         umask $mask;
 510
 511         open(CF, ">$conffile");
 512         print CF "[global]\n";
 513         print CF "\tnetbios name = client\n";
 514         if (defined($vars->{DOMAIN})) {
 515                 print CF "\tworkgroup = $vars->{DOMAIN}\n";
 516         }
 517         if (defined($vars->{REALM})) {
 518                 print CF "\trealm = $vars->{REALM}\n";
 519         }
 520         if ($opt_socket_wrapper) {
 521                 print CF "\tinterfaces = $interfaces\n";
 522         }
 523         print CF "
 524         private dir = $clientdir/private
 525         lock dir = $clientdir/lockdir
 526         state directory = $clientdir/statedir
 527         cache directory = $clientdir/cachedir
 528         ncalrpc dir = $clientdir/ncalrpcdir
 529         name resolve order = file bcast
 530         panic action = $RealBin/gdb_backtrace \%d
 531         max xmit = 32K
 532         notify:inotify = false
 533         ldb:nosync = true
 534         system:anonymous = true
 535         client lanman auth = Yes
 536         log level = 1
 537         torture:basedir = $clientdir
 538 #We don't want to pass our self-tests if the PAC code is wrong
 539         gensec:require_pac = true
 540         resolv:host file = $prefix_abs/dns_host_file
 541 #We don't want to run 'speed' tests for very long
 542         torture:timelimit = 1
 543 ";
 544         close(CF);
 545 }
 546
 547 my @todo = ();
 548
 549 sub should_run_test($)
 550 {
 551         my $name = shift;
 552         if ($#tests == -1) {
 553                 return 1;
 554         }
 555         for (my $i=0; $i <= $#tests; $i++) {
 556                 if ($name =~ /$tests[$i]/i) {
 557                         return 1;
 558                 }
 559         }
 560         return 0;
 561 }
 562
 563 sub read_testlist($)
 564 {
 565         my ($filename) = @_;
 566
 567         my @ret = ();
 568         open(IN, $filename) or die("Unable to open $filename: $!");
 569
 570         while (<IN>) {
 571                 if (/-- TEST(-LOADLIST|-IDLIST|) --\n/) {
 572                         my $supports_loadlist = (defined($1) and $1 eq "-LOADLIST");
 573                         my $supports_idlist = (defined($1) and $1 eq "-IDLIST");
 574                         my $name = <IN>;
 575                         $name =~ s/\n//g;
 576                         my $env = <IN>;
 577                         $env =~ s/\n//g;
 578                         my $cmdline = <IN>;
 579                         $cmdline =~ s/\n//g;
 580                         if (should_run_test($name) == 1) {
 581                                 push (@ret, [$name, $env, $cmdline, $supports_loadlist, $supports_idlist]);
 582                         }
 583                 } else {
 584                         print;
 585                 }
 586         }
 587         close(IN) or die("Error creating recipe");
 588         return @ret;
 589 }
 590
 591 if ($#testlists == -1) {
 592         die("No testlists specified");
 593 }
 594
 595 $ENV{SELFTEST_PREFIX} = "$prefix_abs";
 596 $ENV{SELFTEST_TMPDIR} = "$tmpdir_abs";
 597 $ENV{TEST_DATA_PREFIX} = "$tmpdir_abs";
 598 if ($opt_socket_wrapper) {
 599         $ENV{SELFTEST_INTERFACES} = $interfaces;
 600 } else {
 601         $ENV{SELFTEST_INTERFACES} = "";
 602 }
 603 if ($opt_quick) {
 604         $ENV{SELFTEST_QUICK} = "1";
 605 } else {
 606         $ENV{SELFTEST_QUICK} = "";
 607 }
 608 $ENV{SELFTEST_MAXTIME} = $torture_maxtime;
 609
 610 my @available = ();
 611 foreach my $fn (@testlists) {
 612         foreach (read_testlist($fn)) {
 613                 my $name = $$_[0];
 614                 next if (@includes and not defined(find_in_list(\@includes, $name)));
 615                 push (@available, $_);
 616         }
 617 }
 618
 619 my $restricted = undef;
 620 my $restricted_used = {};
 621
 622 if ($opt_load_list) {
 623         $restricted = [];
 624         open(LOAD_LIST, "<$opt_load_list") or die("Unable to open $opt_load_list");
 625         while (<LOAD_LIST>) {
 626                 chomp;
 627                 push (@$restricted, $_);
 628         }
 629         close(LOAD_LIST);
 630 }
 631
 632 my $individual_tests = undef;
 633 $individual_tests = {};
 634
 635 foreach my $testsuite (@available) {
 636         my $name = $$testsuite[0];
 637         my $skipreason = skip($name);
 638         if (defined($restricted)) {
 639                 # Find the testsuite for this test
 640                 my $match = undef;
 641                 foreach my $r (@$restricted) {
 642                         if ($r eq $name) {
 643                                 $individual_tests->{$name} = [];
 644                                 $match = $r;
 645                                 $restricted_used->{$r} = 1;
 646                         } elsif (substr($r, 0, length($name)+1) eq "$name.") {
 647                                 push(@{$individual_tests->{$name}}, $r);
 648                                 $match = $r;
 649                                 $restricted_used->{$r} = 1;
 650                         }
 651                 }
 652                 if ($match) {
 653                         if (defined($skipreason)) {
 654                                 if (not $opt_list) {
 655                                         Subunit::skip_testsuite($name, $skipreason);
 656                                 }
 657                         } else {
 658                                 push(@todo, $testsuite);
 659                         }
 660                 }
 661         } elsif (defined($skipreason)) {
 662                 if (not $opt_list) {
 663                         Subunit::skip_testsuite($name, $skipreason);
 664                 }
 665         } else {
 666                 push(@todo, $testsuite);
 667         }
 668 }
 669
 670 if (defined($restricted)) {
 671         foreach (@$restricted) {
 672                 unless (defined($restricted_used->{$_})) {
 673                         print "No test or testsuite found matching $_\n";
 674                 }
 675         }
 676 } elsif ($#todo == -1) {
 677         print STDERR "No tests to run\n";
 678         exit(1);
 679 }
 680
 681 my $suitestotal = $#todo + 1;
 682
 683 unless ($opt_list) {
 684         Subunit::progress($suitestotal);
 685         Subunit::report_time(time());
 686 }
 687
 688 my $i = 0;
 689 $| = 1;
 690
 691 my %running_envs = ();
 692
 693 sub get_running_env($)
 694 {
 695         my ($name) = @_;
 696
 697         my $envname = $name;
 698
 699         $envname =~ s/:.*//;
 700
 701         return $running_envs{$envname};
 702 }
 703
 704 my @exported_envvars = (
 705         # domain stuff
 706         "DOMAIN",
 707         "REALM",
 708
 709         # domain controller stuff
 710         "DC_SERVER",
 711         "DC_SERVER_IP",
 712         "DC_NETBIOSNAME",
 713         "DC_NETBIOSALIAS",
 714
 715         # domain member
 716         "MEMBER_SERVER",
 717         "MEMBER_SERVER_IP",
 718         "MEMBER_NETBIOSNAME",
 719         "MEMBER_NETBIOSALIAS",
 720
 721         # rpc proxy controller stuff
 722         "RPC_PROXY_SERVER",
 723         "RPC_PROXY_SERVER_IP",
 724         "RPC_PROXY_NETBIOSNAME",
 725         "RPC_PROXY_NETBIOSALIAS",
 726
 727         # domain controller stuff for Vampired DC
 728         "VAMPIRE_DC_SERVER",
 729         "VAMPIRE_DC_SERVER_IP",
 730         "VAMPIRE_DC_NETBIOSNAME",
 731         "VAMPIRE_DC_NETBIOSALIAS",
 732
 733         "PROMOTED_DC_SERVER",
 734         "PROMOTED_DC_SERVER_IP",
 735         "PROMOTED_DC_NETBIOSNAME",
 736         "PROMOTED_DC_NETBIOSALIAS",
 737
 738         # server stuff
 739         "SERVER",
 740         "SERVER_IP",
 741         "NETBIOSNAME",
 742         "NETBIOSALIAS",
 743
 744         # user stuff
 745         "USERNAME",
 746         "USERID",
 747         "PASSWORD",
 748         "DC_USERNAME",
 749         "DC_PASSWORD",
 750
 751         # misc stuff
 752         "KRB5_CONFIG",
 753         "SELFTEST_WINBINDD_SOCKET_DIR",
 754         "WINBINDD_PRIV_PIPE_DIR",
 755         "NMBD_SOCKET_DIR",
 756         "LOCAL_PATH",
 757
 758         # nss_wrapper
 759         "NSS_WRAPPER_PASSWD",
 760         "NSS_WRAPPER_GROUP",
 761
 762         # UID/GID for rfc2307 mapping tests
 763         "UID_RFC2307TEST",
 764         "GID_RFC2307TEST"
 765 );
 766
 767 $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 768         my $signame = shift;
 769         teardown_env($_) foreach(keys %running_envs);
 770         die("Received signal $signame");
 771 };
 772
 773 sub setup_env($$)
 774 {
 775         my ($name, $prefix) = @_;
 776
 777         my $testenv_vars = undef;
 778
 779         my $envname = $name;
 780         my $option = $name;
 781
 782         $envname =~ s/:.*//;
 783         $option =~ s/^[^:]*//;
 784         $option =~ s/^://;
 785
 786         $option = "client" if $option eq "";
 787
 788         if ($envname eq "none") {
 789                 $testenv_vars = {};
 790         } elsif (defined(get_running_env($envname))) {
 791                 $testenv_vars = get_running_env($envname);
 792                 if (not $testenv_vars->{target}->check_env($testenv_vars)) {
 793                         print $testenv_vars->{target}->getlog_env($testenv_vars);
 794                         $testenv_vars = undef;
 795                 }
 796         } else {
 797                 $testenv_vars = $target->setup_env($envname, $prefix);
 798                 if (defined($testenv_vars) and $testenv_vars eq "UNKNOWN") {
 799                     return $testenv_vars;
 800                 } elsif (defined($testenv_vars) && not defined($testenv_vars->{target})) {
 801                         $testenv_vars->{target} = $target;
 802                 }
 803                 if (not defined($testenv_vars)) {
 804                         warn("$opt_target can't start up known environment '$envname'");
 805                 }
 806         }
 807
 808
 809         return undef unless defined($testenv_vars);
 810
 811         $running_envs{$envname} = $testenv_vars;
 812
 813         if ($option eq "local") {
 814                 SocketWrapper::set_default_iface($testenv_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 815                 $ENV{SMB_CONF_PATH} = $testenv_vars->{SERVERCONFFILE};
 816         } elsif ($option eq "client") {
 817                 SocketWrapper::set_default_iface(11);
 818                 write_clientconf($conffile, $clientdir, $testenv_vars);
 819                 $ENV{SMB_CONF_PATH} = $conffile;
 820         } else {
 821                 die("Unknown option[$option] for envname[$envname]");
 822         }
 823
 824         foreach (@exported_envvars) {
 825                 if (defined($testenv_vars->{$_})) {
 826                         $ENV{$_} = $testenv_vars->{$_};
 827                 } else {
 828                         delete $ENV{$_};
 829                 }
 830         }
 831
 832         return $testenv_vars;
 833 }
 834
 835 sub exported_envvars_str($)
 836 {
 837         my ($testenv_vars) = @_;
 838         my $out = "";
 839
 840         foreach (@exported_envvars) {
 841                 next unless defined($testenv_vars->{$_});
 842                 $out .= $_."=".$testenv_vars->{$_}."\n";
 843         }
 844
 845         return $out;
 846 }
 847
 848 sub getlog_env($)
 849 {
 850         my ($envname) = @_;
 851         return "" if ($envname eq "none");
 852         my $env = get_running_env($envname);
 853         return $env->{target}->getlog_env($env);
 854 }
 855
 856 sub check_env($)
 857 {
 858         my ($envname) = @_;
 859         return 1 if ($envname eq "none");
 860         my $env = get_running_env($envname);
 861         return $env->{target}->check_env($env);
 862 }
 863
 864 sub teardown_env($)
 865 {
 866         my ($envname) = @_;
 867         return if ($envname eq "none");
 868         my $env = get_running_env($envname);
 869         $env->{target}->teardown_env($env);
 870         delete $running_envs{$envname};
 871 }
 872
 873 # This 'global' file needs to be empty when we start
 874 unlink("$prefix_abs/dns_host_file");
 875 unlink("$prefix_abs/hosts");
 876
 877 if ($opt_random_order) {
 878         require List::Util;
 879         my @newtodo = List::Util::shuffle(@todo);
 880         @todo = @newtodo;
 881 }
 882
 883 if ($opt_testenv) {
 884         my $testenv_name = $ENV{SELFTEST_TESTENV};
 885         $testenv_name = $testenv_default unless defined($testenv_name);
 886
 887         my $testenv_vars = setup_env($testenv_name, $prefix);
 888
 889         if (not $testenv_vars or $testenv_vars eq "UNKNOWN") {
 890                 die("Unable to setup environment $testenv_name");
 891         }
 892
 893         $ENV{PIDDIR} = $testenv_vars->{PIDDIR};
 894         $ENV{ENVNAME} = $testenv_name;
 895
 896         my $envvarstr = exported_envvars_str($testenv_vars);
 897
 898         my @term_args = ("echo -e \"
 899 Welcome to the Samba4 Test environment '$testenv_name'
 900
 901 This matches the client environment used in make test
 902 server is pid `cat \$PIDDIR/samba.pid`
 903
 904 Some useful environment variables:
 905 TORTURE_OPTIONS=\$TORTURE_OPTIONS
 906 SMB_CONF_PATH=\$SMB_CONF_PATH
 907
 908 $envvarstr
 909 \" && LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} bash");
 910         my @term = ();
 911         if ($ENV{TERMINAL}) {
 912             @term = ($ENV{TERMINAL});
 913         } else {
 914             @term = ("xterm", "-e");
 915             unshift(@term_args, ("bash", "-c"));
 916         }
 917
 918         system(@term, @term_args);
 919
 920         teardown_env($testenv_name);
 921 } elsif ($opt_list) {
 922         foreach (@todo) {
 923                 my $cmd = $$_[2];
 924                 my $name = $$_[0];
 925                 my $envname = $$_[1];
 926
 927                 unless($cmd =~ /\$LISTOPT/) {
 928                         warn("Unable to list tests in $name");
 929                         next;
 930                 }
 931
 932                 $cmd =~ s/\$LISTOPT/--list/g;
 933
 934                 system($cmd);
 935
 936                 if ($? == -1) {
 937                         die("Unable to run $cmd: $!");
 938                 } elsif ($? & 127) {
 939                         die(sprintf("%s died with signal %d, %s coredump\n", $cmd, ($? & 127),  ($? & 128) ? 'with' : 'without'));
 940                 }
 941
 942                 my $exitcode = $? >> 8;
 943                 if ($exitcode != 0) {
 944                         die("$cmd exited with exit code $exitcode");
 945                 }
 946         }
 947 } else {
 948         foreach (@todo) {
 949                 $i++;
 950                 my $cmd = $$_[2];
 951                 my $name = $$_[0];
 952                 my $envname = $$_[1];
 953
 954                 my $envvars = setup_env($envname, $prefix);
 955                 if (not defined($envvars)) {
 956                         Subunit::start_testsuite($name);
 957                         Subunit::end_testsuite($name, "error",
 958                                 "unable to set up environment $envname - exiting");
 959                         next;
 960                 } elsif ($envvars eq "UNKNOWN") {
 961                         Subunit::start_testsuite($name);
 962                         Subunit::end_testsuite($name, "skip",
 963                                 "environment $envname is unknown in this test backend - skipping");
 964                         next;
 965                 }
 966
 967                 # Generate a file with the individual tests to run, if the
 968                 # test runner for this test suite supports it.
 969                 if ($individual_tests and $individual_tests->{$name}) {
 970                         if ($$_[3]) {
 971                                 my ($fh, $listid_file) = tempfile(UNLINK => 0);
 972                                 foreach my $test (@{$individual_tests->{$name}}) {
 973                                         print $fh substr($test, length($name)+1) . "\n";
 974                                 }
 975                                 $cmd =~ s/\$LOADLIST/--load-list=$listid_file/g;
 976                         } elsif ($$_[4]) {
 977                                 $cmd =~ s/\s+[^\s]+\s*$//;
 978                                 $cmd .= " " . join(' ', @{$individual_tests->{$name}});
 979                         }
 980                 }
 981
 982                 run_testsuite($envname, $name, $cmd, $i, $suitestotal);
 983
 984                 teardown_env($envname) if ($opt_resetup_env);
 985         }
 986 }
 987
 988 print "\n";
 989
 990 teardown_env($_) foreach (keys %running_envs);
 991
 992 my $failed = 0;
 993
 994 # if there were any valgrind failures, show them
 995 foreach (<$prefix/valgrind.log*>) {
 996         next unless (-s $_);
 997         print "VALGRIND FAILURE\n";
 998         $failed++;
 999         system("cat $_");
1000 }
1001 exit 0;