selftest/Subunit.pm

   1 # Perl module for parsing and generating the Subunit protocol
   2 # Copyright (C) 2008-2009 Jelmer Vernooij <jelmer@samba.org>
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 3 of the License, or
   7 # (at your option) any later version.
   8
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 package Subunit;
  18 use POSIX;
  19
  20 require Exporter;
  21 @ISA = qw(Exporter);
  22 @EXPORT_OK = qw(parse_results);
  23
  24 use strict;
  25
  26 sub parse_results($$$)
  27 {
  28         my ($msg_ops, $statistics, $fh) = @_;
  29         my $expected_fail = 0;
  30         my $open_tests = [];
  31
  32         while(<$fh>) {
  33                 if (/^test: (.+)\n/) {
  34                         $msg_ops->control_msg($_);
  35                         $msg_ops->start_test($1);
  36                         push (@$open_tests, $1);
  37                 } elsif (/^time: (\d+)-(\d+)-(\d+) (\d+):(\d+):(\d+)\n/) {
  38                         $msg_ops->report_time(mktime($6, $5, $4, $3, $2-1, $1-1900));
  39                 } elsif (/^(success|successful|failure|fail|skip|knownfail|error|xfail|skip-testsuite|testsuite-failure|testsuite-xfail|testsuite-success|testsuite-error): (.*?)( \[)?([ \t]*)( multipart)?\n/) {
  40                         $msg_ops->control_msg($_);
  41                         my $result = $1;
  42                         my $testname = $2;
  43                         my $reason = undef;
  44                         if ($3) {
  45                                 $reason = "";
  46                                 # reason may be specified in next lines
  47                                 my $terminated = 0;
  48                                 while(<$fh>) {
  49                                         $msg_ops->control_msg($_);
  50                                         if ($_ eq "]\n") { $terminated = 1; last; } else { $reason .= $_; }
  51                                 }
  52
  53                                 unless ($terminated) {
  54                                         $statistics->{TESTS_ERROR}++;
  55                                         $msg_ops->end_test($testname, "error", 1,
  56                                                                "reason ($result) interrupted");
  57                                         return 1;
  58                                 }
  59                         }
  60                         if ($result eq "success" or $result eq "successful") {
  61                                 pop(@$open_tests); #FIXME: Check that popped value == $testname
  62                                 $statistics->{TESTS_EXPECTED_OK}++;
  63                                 $msg_ops->end_test($testname, "success", 0, $reason);
  64                         } elsif ($result eq "xfail" or $result eq "knownfail") {
  65                                 pop(@$open_tests); #FIXME: Check that popped value == $testname
  66                                 $statistics->{TESTS_EXPECTED_FAIL}++;
  67                                 $msg_ops->end_test($testname, "xfail", 0, $reason);
  68                                 $expected_fail++;
  69                         } elsif ($result eq "failure" or $result eq "fail") {
  70                                 pop(@$open_tests); #FIXME: Check that popped value == $testname
  71                                 $statistics->{TESTS_UNEXPECTED_FAIL}++;
  72                                 $msg_ops->end_test($testname, "failure", 1, $reason);
  73                         } elsif ($result eq "skip") {
  74                                 $statistics->{TESTS_SKIP}++;
  75                                 # Allow tests to be skipped without prior announcement of test
  76                                 my $last = pop(@$open_tests);
  77                                 if (defined($last) and $last ne $testname) {
  78                                         push (@$open_tests, $testname);
  79                                 }
  80                                 $msg_ops->end_test($testname, "skip", 0, $reason);
  81                         } elsif ($result eq "error") {
  82                                 $statistics->{TESTS_ERROR}++;
  83                                 pop(@$open_tests); #FIXME: Check that popped value == $testname
  84                                 $msg_ops->end_test($testname, "error", 1, $reason);
  85                         } elsif ($result eq "skip-testsuite") {
  86                                 $msg_ops->skip_testsuite($testname);
  87                         } elsif ($result eq "testsuite-success") {
  88                                 $msg_ops->end_testsuite($testname, "success", $reason);
  89                         } elsif ($result eq "testsuite-failure") {
  90                                 $msg_ops->end_testsuite($testname, "failure", $reason);
  91                         } elsif ($result eq "testsuite-xfail") {
  92                                 $msg_ops->end_testsuite($testname, "xfail", $reason);
  93                         } elsif ($result eq "testsuite-error") {
  94                                 $msg_ops->end_testsuite($testname, "error", $reason);
  95                         }
  96                 } elsif (/^testsuite: (.*)\n/) {
  97                         $msg_ops->start_testsuite($1);
  98                 } else {
  99                         $msg_ops->output_msg($_);
 100                 }
 101         }
 102
 103         while ($#$open_tests+1 > 0) {
 104                 $msg_ops->end_test(pop(@$open_tests), "error", 1,
 105                                    "was started but never finished!");
 106                 $statistics->{TESTS_ERROR}++;
 107         }
 108
 109         # if the Filter module is in use, it will have the right counts
 110         if (defined($msg_ops->{total_error})) {
 111                 $statistics->{TESTS_ERROR} = $msg_ops->{total_error};
 112                 $statistics->{TESTS_UNEXPECTED_FAIL} = $msg_ops->{total_fail};
 113                 $statistics->{TESTS_EXPECTED_FAIL} = $msg_ops->{total_xfail};
 114         }
 115
 116         return 1 if $statistics->{TESTS_ERROR} > 0;
 117         return 1 if $statistics->{TESTS_UNEXPECTED_FAIL} > 0;
 118
 119         return 0;
 120 }
 121
 122 sub start_test($)
 123 {
 124         my ($testname) = @_;
 125         print "test: $testname\n";
 126 }
 127
 128 sub end_test($$;$)
 129 {
 130         my $name = shift;
 131         my $result = shift;
 132         my $reason = shift;
 133         if ($reason) {
 134                 print "$result: $name [\n";
 135                 print "$reason";
 136                 print "]\n";
 137         } else {
 138                 print "$result: $name\n";
 139         }
 140 }
 141
 142 sub skip_test($;$)
 143 {
 144         my $name = shift;
 145         my $reason = shift;
 146         end_test($name, "skip", $reason);
 147 }
 148
 149 sub fail_test($;$)
 150 {
 151         my $name = shift;
 152         my $reason = shift;
 153         end_test($name, "fail", $reason);
 154 }
 155
 156 sub success_test($;$)
 157 {
 158         my $name = shift;
 159         my $reason = shift;
 160         end_test($name, "success", $reason);
 161 }
 162
 163 sub xfail_test($;$)
 164 {
 165         my $name = shift;
 166         my $reason = shift;
 167         end_test($name, "xfail", $reason);
 168 }
 169
 170 sub report_time($)
 171 {
 172         my ($time) = @_;
 173         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday, $isdst) = localtime($time);
 174         printf "time: %04d-%02d-%02d %02d:%02d:%02d\n", $year+1900, $mon+1, $mday, $hour, $min, $sec;
 175 }
 176
 177 sub progress_pop()
 178 {
 179         print "progress: pop\n";
 180 }
 181
 182 sub progress_push()
 183 {
 184         print "progress: push\n";
 185 }
 186
 187 sub progress($;$)
 188 {
 189         my ($count, $whence) = @_;
 190
 191         unless(defined($whence)) {
 192                 $whence = "";
 193         }
 194
 195         print "progress: $whence$count\n";
 196 }
 197
 198 # The following are Samba extensions:
 199
 200 sub start_testsuite($)
 201 {
 202         my ($name) = @_;
 203         print "testsuite: $name\n";
 204 }
 205
 206 sub skip_testsuite($;$)
 207 {
 208         my ($name, $reason) = @_;
 209         if ($reason) {
 210                 print "skip-testsuite: $name [\n$reason\n]\n";
 211         } else {
 212                 print "skip-testsuite: $name\n";
 213         }
 214 }
 215
 216 sub end_testsuite($$;$)
 217 {
 218         my $name = shift;
 219         my $result = shift;
 220         my $reason = shift;
 221         if ($reason) {
 222                 print "testsuite-$result: $name [\n";
 223                 print "$reason\n";
 224                 print "]\n";
 225         } else {
 226                 print "testsuite-$result: $name\n";
 227         }
 228 }
 229
 230 1;