configure.ac

   1 # $Id$
   2 #
   3
   4 m4_define([version_major], [1])
   5 m4_define([version_minor], [11])
   6 m4_define([version_micro], [0])
   7 m4_define([version_micro_extra], version_micro)
   8 m4_append([version_micro_extra], [])
   9
  10 AC_INIT(wireshark, [version_major.version_minor.version_micro_extra], http://bugs.wireshark.org/, , http://www.wireshark.org/)
  11
  12 # Minimum autoconf version we require.
  13 AC_PREREQ(2.60)
  14 # Variable expansion doesn't work in AC_PREREQ()
  15 AC_MIN_VERSION=2.60
  16 AC_SUBST(AC_MIN_VERSION)
  17
  18 dnl Check for CPU / vendor / OS
  19 dnl The user is encouraged to use either `AC_CANONICAL_BUILD', or
  20 dnl `AC_CANONICAL_HOST', or `AC_CANONICAL_TARGET', depending on the
  21 dnl needs.  Using `AC_CANONICAL_TARGET' is enough to run the two other
  22 dnl macros.
  23 dnl
  24 dnl As nothing in the Wireshark is itself a build tool (we are not,
  25 dnl for example, a compiler that generates machine code), we probably
  26 dnl don't need AC_CANONICAL_TARGET, so, in theory, we should be able
  27 dnl to use AC_CANONICAL_BUILD and AC_CANONICAL_HOST - or perhaps just
  28 dnl AC_CANONICAL_HOST - instead.  Note that we do have tools, such as
  29 dnl lemon, that need to be built for the build machine, not for the
  30 dnl host machine, so we might need both.
  31 dnl
  32 dnl This has to be done *after* AC_INIT, otherwise autogen.sh fails.
  33
  34 dnl AC_CANONICAL_BUILD
  35 dnl AC_CANONICAL_HOST
  36 AC_CANONICAL_TARGET
  37
  38 AM_INIT_AUTOMAKE([1.9 tar-ustar dist-bzip2 no-dist-gzip])
  39
  40 # Make Wireshark's version available in config.h
  41 AC_DEFINE(VERSION_MAJOR, version_major, [Wireshark's major version])
  42 AC_DEFINE(VERSION_MINOR, version_minor, [Wireshark's minor version])
  43 AC_DEFINE(VERSION_MICRO, version_micro, [Wireshark's micro version])
  44
  45 AM_DISABLE_STATIC
  46
  47 #
  48 # Checks for programs used in the main build process.
  49 #
  50 AC_PROG_CC
  51 AM_PROG_CC_C_O
  52 AC_PROG_CXX
  53 AC_PROG_CPP
  54 dnl Work around libtool bug (fixed in the version 1.5a?)
  55 AC_DEFUN([AC_PROVIDE_AC_LIBTOOL_DLOPEN], )
  56 AC_LIBTOOL_DLOPEN
  57 AC_PROG_LIBTOOL
  58 AC_PATH_PROG(PERL, perl)
  59
  60 # Check for Python.
  61 AC_PATH_PROG(PYTHON, python)
  62 if test ! -z "$PYTHON"; then
  63         #
  64         # OK, we found Python; is it Python 2.x?
  65         # Note: we don't use named components for sys.version_info to get
  66         # the major version number, as named components for version_info
  67         # were apparently introduced in Python 2.7.
  68         #
  69         AC_MSG_CHECKING([whether $PYTHON is Python 2])
  70         python_major_version=`$PYTHON -c 'import sys; print sys.version_info[[0]]'`
  71         if test "$python_major_version" = 2; then
  72                 AC_MSG_RESULT([yes])
  73         else
  74                 #
  75                 # It's not 2.x.
  76                 #
  77                 AC_MSG_RESULT([no])
  78
  79                 #
  80                 # Try looking for python2; if we find it, we assume it's
  81                 # Python 2
  82                 #
  83                 AC_PATH_PROG(PYTHON, python2)
  84         fi
  85 fi
  86
  87 #
  88 # XXX - should autogen.sh check for YACC/Bison and Flex?  A user building
  89 # from a distribution tarball shouldn't have to have YACC/Bison or Flex,
  90 # as the tarball should contain the results of running YACC/Bison on .y
  91 # files and running Flex on .l files, but a user building from SVN
  92 # will have to run YACC/Bison and Flex to process those files.
  93 #
  94 # On the other hand, what about users who use a distribution tarball to
  95 # do development?  They *shouldn't* - that's what the SVN repository is
  96 # for - but they might.  They'd get errors if they modify a .y or .l
  97 # file and try to do a build - but the error should tell them that they
  98 # need to get YACC/Bison and/or Flex.
  99 #
 100 # Then again, getting them shouldn't be too big of a burden.
 101 #
 102 # XXX - is the same true of pod2man and pod2html, or are they needed
 103 # even when building from a distribution tarball?
 104 #
 105 #
 106 AC_PROG_YACC
 107 AC_PATH_PROG(YACCDUMMY, $YACC)
 108 if test "x$YACCDUMMY" = x
 109 then
 110         AC_MSG_ERROR(I couldn't find yacc (or bison or ...); make sure it's installed and in your path)
 111 fi
 112 AM_PROG_LEX
 113 AC_PATH_PROG(LEX, flex)
 114 if test "x$LEX" = x
 115 then
 116         AC_MSG_ERROR(I couldn't find flex; make sure it's installed and in your path)
 117 fi
 118 AC_PATH_PROG(POD2MAN, pod2man)
 119 if test "x$POD2MAN" = x
 120 then
 121         #
 122         # The alternative is not to build the man pages....
 123         #
 124         AC_MSG_ERROR(I couldn't find pod2man; make sure it's installed and in your path)
 125 fi
 126 AC_PATH_PROG(POD2HTML, pod2html)
 127 if test "x$POD2HTML" = x
 128 then
 129         #
 130         # The alternative is not to build the HTML man pages....
 131         #
 132         AC_MSG_ERROR(I couldn't find pod2html; make sure it's installed and in your path)
 133 fi
 134
 135 #
 136 # Checks for programs used by Wireshark/TShark/etc.
 137 #
 138
 139 #
 140 # XXX - this looks for various HTML viewers on the host, not the target;
 141 # we really want to know what's available on the target, for cross-builds.
 142 # That would probably require us to, at run time, look for xdg-open and,
 143 # if we don't find it, look for mozilla, htmlview, etc.
 144 #
 145 AC_PATH_PROG(HTML_VIEWER, xdg-open)
 146 if test "x$HTML_VIEWER" != x
 147 then
 148         #
 149         # XXX - the HTML_VIEWER shell variable is the full path of xdg-open.
 150         # Define some variable to be that, so we just run that?
 151         #
 152         AC_DEFINE(HAVE_XDG_OPEN, 1, [Define if we have xdg-open])
 153
 154         #
 155         # XXX - we have to define HTML_VIEWER for the prefs.c code that
 156         # sets the default value of the Web browser preference, even
 157         # though that preference won't be offered.
 158         #
 159         AC_DEFINE_UNQUOTED(HTML_VIEWER, "xdg-open", [HTML viewer, e.g. mozilla])
 160 else
 161         AC_PATH_PROG(HTML_VIEWER, htmlview)
 162         if test "x$HTML_VIEWER" = x
 163         then
 164                 AC_DEFINE_UNQUOTED(HTML_VIEWER, "mozilla", [HTML viewer, e.g. mozilla])
 165         else
 166                 AC_DEFINE_UNQUOTED(HTML_VIEWER, "htmlview", [HTML viewer, e.g. mozilla])
 167         fi
 168 fi
 169
 170 #
 171 # Set "ac_supports_gcc_flags" if the compiler is known to support GCC-style
 172 # flags such as -pedantic, -W warning flags and -f feature flags.  Currently,
 173 # we assume GCC and clang do; other compilers should be added here.
 174 #
 175 # This is done to avoid getting tripped up by compilers that support
 176 # those flags but give them a different meaning.
 177 #
 178 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 179         ac_supports_gcc_flags=yes
 180 fi
 181
 182 #
 183 # Set "ac_supports_W_linker_passthrough" if the compiler is known to
 184 # support "-Wl,{options}" to pass options through to the linker.
 185 # Currently, we assume GCC, xlc, and clang do; other compilers should
 186 # be added here.
 187 #
 188 if test "x$GCC" = "xyes" -o "x$CC" = "xxlc" -o "x$CC" = "xclang" ; then
 189         ac_supports_W_linker_passthrough=yes
 190 fi
 191
 192 #
 193 # Set "ac_supports_attribute_unused" if the compiler is known to
 194 # support "__attribute__(unused)".
 195 # Currently, we assume GCC and clang do; other compilers should
 196 # be added here.
 197 #
 198 # XXX - do this with a compiler test?
 199 #
 200 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 201         ac_supports_W_linker_passthrough=yes
 202 fi
 203
 204 if test "x$CC_FOR_BUILD" = x
 205 then
 206        CC_FOR_BUILD=$CC
 207 fi
 208 AC_SUBST(CC_FOR_BUILD)
 209 AC_SUBST(CFLAGS_FOR_BUILD)
 210
 211 # Check for doxygen
 212 AC_PATH_PROG(DOXYGEN, doxygen)
 213 AC_CHECK_PROG(HAVE_DOXYGEN, doxygen, "yes", "no")
 214 AM_CONDITIONAL(HAVE_DOXYGEN, test x$HAVE_DOXYGEN = xyes)
 215
 216 #
 217 # Check for pkg-config and set PKG_CONFIG accordingly.
 218 #
 219 # This is referenced via AC_REQUIRE([PKG_PROG_PKG_CONFIG] in some macros
 220 # like PKG_CHECK_MODULES. If the first call to such a macro is under an
 221 # "if" statement, it's safer to call PKG_PROG_PKG_CONFIG directly, see
 222 # the comments in acolocal.m4
 223 #
 224 PKG_PROG_PKG_CONFIG
 225
 226 #
 227 # Try to arrange for large file support.
 228 #
 229 AC_SYS_LARGEFILE
 230
 231 # GnuTLS
 232 # Version 3.0 switched from LGPLv2.1+ to LGPLv3+, then switched back to
 233 # LGPLv2.1+ in version 3.1.10
 234 tls_message="no"
 235 AC_ARG_WITH([gnutls],
 236   AC_HELP_STRING( [--with-gnutls=@<:@yes/no@:>@],
 237                   [use GnuTLS library @<:@default=yes@:>@]),
 238   with_gnutls="$withval", with_gnutls="yes")
 239 if test "x$with_gnutls" = "xyes"; then
 240   have_license_compatible_gnutls="no"
 241   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.1.10 ],
 242     [ have_license_compatible_gnutls="yes" ], [ echo "GnuTLS >= 3.1.10 not found " ]
 243   )
 244
 245   if test "x$have_license_compatible_gnutls" != "xyes"; then
 246     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 1.2.0 gnutls < 3],
 247       [ have_license_compatible_gnutls="yes" ] , [ echo "GnuTLS >= 1.2.0, < 3.0 not found " ]
 248     )
 249   fi
 250
 251   if test "x$have_license_compatible_gnutls" = "xyes"; then
 252     echo "GnuTLS found, enabling SSL decryption"
 253     AC_DEFINE(HAVE_LIBGNUTLS, 1, [Define to use GnuTLS library])
 254     tls_message="yes"
 255   else
 256     echo "GnuTLS with compatible license not found, disabling SSL decryption"
 257     tls_message="no"
 258   fi
 259 fi
 260
 261 # libgrypt
 262 gcrypt_message="no"
 263 AC_ARG_WITH([gcrypt],
 264   AC_HELP_STRING( [--with-gcrypt=@<:@yes/no@:>@],
 265                   [use gcrypt library @<:@default=yes@:>@]),
 266   with_gcrypt="$withval", with_gcrypt="yes")
 267 if test "x$with_gcrypt" = "xyes"; then
 268   AM_PATH_LIBGCRYPT(1.1.92,
 269         [
 270                 echo "libgcrypt found, enabling ipsec decryption"
 271                 AC_DEFINE(HAVE_LIBGCRYPT, 1, [Define to use libgcrypt])
 272                 gcrypt_message="yes"
 273         ]
 274         , [
 275                 if test x$libgcrypt_config_prefix != x ; then
 276                         AC_MSG_ERROR([[libgcrypt not found; install libgcrypt-devel package for your system]])
 277                 else
 278                         echo "libgcrypt not found, disabling ipsec decryption"
 279                         gcrypt_message="no"
 280                 fi
 281         ]
 282   )
 283 fi
 284
 285 AC_ARG_WITH([qt],
 286   AC_HELP_STRING( [--with-qt=@<:@yes/no@:>@],
 287                   [use Qt instead of GTK+ @<:@default=no@:>@]),
 288   with_qt="$withval", with_qt="no")
 289
 290 AC_ARG_WITH(libnl,
 291   AC_HELP_STRING([--with-libnl@<:@=VERSION@:>@],
 292                  [use libnl (force version VERSION, if supplied) @<:@default: yes, if available@:>@]),
 293 [
 294         if test "x$withval" = "xno"
 295         then
 296                 want_libnl=no
 297         elif test "x$withval" = "xyes"
 298         then
 299                 want_libnl=yes
 300                 libnl_version=any
 301         elif test "x$withval" = "x1"
 302         then
 303                 want_libnl=yes
 304                 libnl_version=1
 305         elif test "x$withval" = "x2"
 306         then
 307                 want_libnl=yes
 308                 libnl_version=2
 309         elif test "x$withval" = "x3"
 310         then
 311                 want_libnl=yes
 312                 libnl_version=3
 313         else
 314                 AC_MSG_ERROR(["$withval" is not a valid argument to --with-libnl])
 315         fi
 316 ],[
 317         #
 318         # Use libnl if it's present, otherwise don't.
 319         #
 320         want_libnl=ifavailable
 321         libnl_version=any
 322 ])
 323 #
 324 # Libnl is Linux-specific.
 325 #
 326 libnl_message="no"
 327 case "$host_os" in
 328 linux*)
 329         AC_MSG_CHECKING(whether to use libnl for various network interface purposes)
 330
 331         if test x$want_libnl = "xno"; then
 332                 AC_MSG_RESULT(no)
 333         else
 334                 AC_MSG_RESULT(yes)
 335                 #
 336                 # Test for specific libnl versions only if no version
 337                 # was specified by the user or if the version in question
 338                 # was requested by the user.
 339                 #
 340                 if test x$libnl_version = "xany" -o x$libnl_version = "x3"; then
 341                         PKG_CHECK_MODULES(LIBNL3, [libnl-route-3.0 >= 3.0 libnl-genl-3.0] >= 3.0, [have_libnl3=yes], [have_libnl3=no])
 342                 fi
 343                 if test x$libnl_version = "xany" -o x$libnl_version = "x2"; then
 344                         PKG_CHECK_MODULES(LIBNL2, libnl-2.0 >= 2.0, [have_libnl2=yes], [have_libnl2=no])
 345                 fi
 346                 if test x$libnl_version = "xany" -o x$libnl_version = "x1"; then
 347                         PKG_CHECK_MODULES(LIBNL1, libnl-1 >= 1.0, [have_libnl1=yes], [have_libnl1=no])
 348                 fi
 349                 if (test "${have_libnl3}" = "yes"); then
 350                         CFLAGS="$CFLAGS $LIBNL3_CFLAGS"
 351                         LIBS="$LIBS $LIBNL3_LIBS"
 352                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 353                         AC_DEFINE(HAVE_LIBNL3, 1, [libnl version 3])
 354                         libnl_message="yes (v3)"
 355                         enable_airpcap=no
 356                 elif (test "${have_libnl2}" = "yes"); then
 357                         CFLAGS="$CFLAGS $LIBNL2_CFLAGS"
 358                         LIBS="$LIBS $LIBNL2_LIBS"
 359                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 360                         AC_DEFINE(HAVE_LIBNL2, 1, [libnl version 2])
 361                         libnl_message="yes (v2)"
 362                         enable_airpcap=no
 363                 elif (test "${have_libnl1}" = "yes"); then
 364                         CFLAGS="$CFLAGS $LIBNL1_CFLAGS"
 365                         LIBS="$LIBS $LIBNL1_LIBS"
 366                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 367                         AC_DEFINE(HAVE_LIBNL1, 1, [libnl version 1])
 368                         libnl_message="yes (v1)"
 369                         enable_airpcap=no
 370                 else
 371                         if test x$want_libnl = "xyes"; then
 372                                 case "$libnl_version" in
 373
 374                                 any)
 375                                         AC_MSG_ERROR("I couldn't find libnl even though you manually enabled it.")
 376                                         ;;
 377
 378                                 *)
 379                                         AC_MSG_ERROR("I couldn't find libnl version $libnl_version even though you manually enabled it.")
 380                                         ;;
 381                                 esac
 382                         fi
 383                 fi
 384         fi
 385
 386         AC_MSG_CHECKING([if nl80211.h is new enough])
 387           AC_TRY_COMPILE([#include <linux/nl80211.h>],
 388             [int x = NL80211_FREQUENCY_ATTR_MAX_TX_POWER;
 389                 x = NL80211_ATTR_SUPPORTED_IFTYPES;
 390                 x = NL80211_ATTR_SUPPORTED_COMMANDS;
 391                 x = NL80211_ATTR_WIPHY_FREQ;
 392                 x = NL80211_CHAN_NO_HT;],
 393             [AC_MSG_RESULT(yes) AC_DEFINE(HAVE_NL80211, 1, [nl80211.h is new enough])],
 394             [AC_MSG_RESULT(no)])
 395
 396         AC_MSG_CHECKING([for NL80211_SET_CHANNEL])
 397           AC_TRY_COMPILE([#include <linux/nl80211.h>],
 398             [enum nl80211_commands x = NL80211_CMD_SET_CHANNEL;],
 399             [AC_MSG_RESULT(yes) AC_DEFINE(HAVE_NL80211_CMD_SET_CHANNEL, 1, [SET_CHANNEL is supported])],
 400             [AC_MSG_RESULT(no)])
 401         ;;
 402
 403 *)
 404         if test x$want_libnl != "xno" -a x$want_libnl != "xifavailable"; then
 405                 AC_MSG_WARN([libnl is Linux-specific, ignoring --with-libnl])
 406         fi
 407 esac
 408
 409 AC_ARG_WITH([gtk3],
 410   AC_HELP_STRING( [--with-gtk3=@<:@yes/no@:>@],
 411                   [use GTK+ 3.0 instead of 2.0 @<:@default=no@:>@]),
 412   with_gtk3="$withval", with_gtk3="no")
 413
 414 # libsmi
 415 # FIXME: currently the path argument to with-libsmi is being ignored
 416 AX_LIBSMI
 417
 418 #
 419 # Check for programs used when building DocBook documentation.
 420 #
 421
 422 # Check for a2x (convert asciidoc to another format)
 423 AC_PATH_PROG(A2X, a2x)
 424 AC_CHECK_PROG(HAVE_A2X, a2x, "yes", "no")
 425 AM_CONDITIONAL(HAVE_A2X, test x$HAVE_A2X = xyes)
 426
 427 # Want to control a tape drive? Use mt. Want to convert HTML to text?
 428 # Uhhhhh... elinks? lynx? w3m? pandoc? html2text?
 429 AC_PATH_PROG(ELINKS, elinks)
 430 AC_CHECK_PROG(HAVE_ELINKS, elinks, "yes", "no")
 431 AM_CONDITIONAL(HAVE_ELINKS, test x$HAVE_ELINKS = xyes)
 432
 433 # Check for fop (translate .fo to e.g. pdf)
 434 AC_PATH_PROG(FOP, fop)
 435 AC_CHECK_PROG(HAVE_FOP, fop, "yes", "no")
 436 AM_CONDITIONAL(HAVE_FOP, test x$HAVE_FOP = xyes)
 437
 438 # Check for lynx (html -> text)
 439 AC_PATH_PROG(LYNX, lynx)
 440 AC_CHECK_PROG(HAVE_LYNX, lynx, "yes", "no")
 441 AM_CONDITIONAL(HAVE_LYNX, test x$HAVE_LYNX = xyes)
 442
 443 # Check for w3m (html -> text)
 444 AC_PATH_PROG(W3M, w3m)
 445 AC_CHECK_PROG(HAVE_W3M, w3m, "yes", "no")
 446 AM_CONDITIONAL(HAVE_W3M, test x$HAVE_W3M = xyes)
 447
 448 # Check for xmllint
 449 AC_PATH_PROG(XMLLINT, xmllint)
 450 AC_CHECK_PROG(HAVE_XMLLINT, xmllint, "yes", "no")
 451 AM_CONDITIONAL(HAVE_XMLLINT, test x$HAVE_XMLLINT = xyes)
 452
 453 # Check for xsltproc
 454 AC_PATH_PROG(XSLTPROC, xsltproc)
 455 AC_CHECK_PROG(HAVE_XSLTPROC, xsltproc, "yes", "no")
 456 AM_CONDITIONAL(HAVE_XSLTPROC, test x$HAVE_XSLTPROC = xyes)
 457
 458
 459 # Check for packaging utilities
 460 # For now, we check to see if the various packaging utilites are in our
 461 # path.  I'm too lazy to write code to go hunt for them.  -  Gerald
 462
 463 #
 464 # Source packages.
 465 # (Lets you install the desktop files.)
 466 #
 467 AC_PATH_PROG(DESKTOP_FILE_INSTALL, desktop-file-install)
 468
 469 # SVR4/Solaris
 470 AC_CHECK_PROG(HAVE_PKGPROTO, pkgproto, "yes", "no")
 471 AC_CHECK_PROG(HAVE_PKGMK, pkgmk, "yes", "no")
 472 AC_CHECK_PROG(HAVE_PKGTRANS, pkgtrans, "yes", "no")
 473
 474 if test x$HAVE_PKGPROTO = xyes -a x$HAVE_PKGMK = xyes \
 475      -a x$HAVE_PKGTRANS = xyes ; then
 476   HAVE_SVR4_PACKAGING=yes
 477 else
 478   HAVE_SVR4_PACKAGING=no
 479 fi
 480 AC_SUBST(HAVE_SVR4_PACKAGING)
 481
 482 # RPM
 483 AC_WIRESHARK_RPM_CHECK
 484 AC_SUBST(HAVE_RPM)
 485
 486 # Debian
 487 AC_CHECK_PROG(HAVE_DPKG_BUILDPACKAGE, dpkg-buildpackage, "yes", "no")
 488
 489 # Mac OS X
 490 AC_CHECK_PROG(HAVE_XCODEBUILD, xcodebuild, "yes", "no")
 491 AC_CHECK_PROG(HAVE_HDIUTIL, hdiutil, "yes", "no")
 492 AC_CHECK_PROG(HAVE_BLESS, bless, "yes", "no")
 493
 494 if test x$HAVE_XCODEBUILD = xyes -a x$HAVE_HDIUTIL = xyes \
 495      -a x$HAVE_BLESS = xyes ; then
 496   HAVE_OSX_PACKAGING=yes
 497 else
 498   HAVE_OSX_PACKAGING=no
 499 fi
 500 AC_SUBST(HAVE_OSX_PACKAGING)
 501
 502 #
 503 # Try to add some additional gcc checks to CFLAGS
 504 #
 505 AC_ARG_ENABLE(extra-gcc-checks,
 506   AC_HELP_STRING( [--enable-extra-gcc-checks],
 507                   [do additional -W checks in GCC @<:@default=no@:>@]),
 508 [
 509         wireshark_extra_gcc_flags=$enableval
 510         if test $enableval != no
 511         then
 512                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-pedantic)
 513                 #
 514                 # Various code blocks this one.
 515                 #
 516                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Woverflow)
 517                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-fstrict-overflow -Wstrict-overflow=4)
 518                 #
 519                 # Some memset() calls to clear out structures
 520                 # on the stack are getting flagged as "will never
 521                 # be executed" by this, at least by Apple's
 522                 # i686-apple-darwin11-llvm-gcc-4.2 (GCC) 4.2.1 (Based on
 523                 # Apple Inc. build 5658) (LLVM build 2336.11.00), for
 524                 # some unknown reason.
 525                 #
 526                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wunreachable-code)
 527                 #
 528                 # Due to various places where APIs we don't control
 529                 # require us to cast away constness, we can probably
 530                 # never enable these ones with -Werror.
 531                 #
 532                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wcast-qual)
 533                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wbad-function-cast, C)
 534                 #
 535                 # Some generated ASN.1 dissectors block this one;
 536                 # multiple function declarations for the same
 537                 # function are being generated.
 538                 #
 539                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wredundant-decls)
 540                 #
 541                 # Some loops are safe, but it's hard to convince the
 542                 # compiler of that.
 543                 #
 544                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wunsafe-loop-optimizations)
 545                 #
 546                 # All the registration functions block these for now.
 547                 #
 548                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wmissing-prototypes)
 549                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wmissing-declarations)
 550         fi
 551 ],)
 552 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wall -W) # -W is now known as -Wextra
 553 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wextra) # -W is now known as -Wextra
 554 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wdeclaration-after-statement, C)
 555 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wendif-labels)
 556 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wpointer-arith)
 557 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-pointer-sign, C)
 558 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Warray-bounds)
 559 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wcast-align)
 560 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wformat-security)
 561 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wold-style-definition, C)
 562 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wshorten-64-to-32)
 563 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wstrict-prototypes, C)
 564 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wjump-misses-init, C)
 565 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wvla)
 566 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Waddress)
 567 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Warray-bounds)
 568 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wattributes)
 569 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wdiv-by-zero)
 570 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wignored-qualifiers)
 571 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wpragmas)
 572 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-overlength-strings)
 573 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wwrite-strings)
 574 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-long-long)
 575 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wc++-compat, C)
 576
 577 #
 578 # XXX - OK for C++?
 579 #
 580 # Make sure -Wshadow doesn't complain about variables in function and
 581 # function pointer declarations shadowing other variables; if not, don't
 582 # turn it on, as some versions of GCC (including the one in at least
 583 # some Xcode versions that came with Mac OS X 10.5) complain about
 584 # that.
 585 #
 586 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wshadow, C,
 587   [
 588 extern int bar(int a);
 589 extern int foo(int);
 590
 591 int
 592 foo(int a)
 593 {
 594         int (*fptr)(int a) = bar;
 595
 596         return fptr(a) * 2;
 597 }
 598   ],
 599   [warns about variables in function declarations shadowing other variables])
 600
 601 # Unfortunately some versions of gcc generate logical-op warnings when strchr()
 602 # is given a constant string.
 603 # gcc versions 4.3.2 and 4.4.5 are known to have the problem.
 604 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wlogical-op, C,
 605   [
 606 #include <string.h>
 607
 608 int foo(const char *, int);
 609 int bar(void);
 610
 611 int
 612 foo(const char *sep, int c)
 613 {
 614         if (strchr (sep, c) != NULL)
 615                 return 1;
 616         else
 617                 return 0;
 618 }
 619
 620 int
 621 bar(void)
 622 {
 623         return foo("<", 'a');
 624 }
 625   ],
 626   [generates warnings from strchr()])
 627
 628
 629 ## AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-error=unused-but-set-variable)
 630
 631 #
 632 # Use the faster pre gcc 4.5 floating point precision if available;
 633 # clang doesn't error out on -f options that it doesn't know about,
 634 # it just warns and ignores them, so this check doesn't cause us
 635 # to omit -fexcess-precision=fast, which produces a pile of
 636 # annoying warnings.
 637 #
 638 if test "x$CC" != "xclang" ; then
 639   AC_WIRESHARK_GCC_CFLAGS_CHECK(-fexcess-precision=fast)
 640 fi
 641
 642 CFLAGS_before_fvhidden=$CFLAGS
 643 AC_WIRESHARK_GCC_CFLAGS_CHECK(-fvisibility=hidden)
 644 if test "x$CLFAGS" = "x$CFLAGS_before_fvhidden"
 645 then
 646         # TODO add other ways of hiding symbols
 647         AC_MSG_WARN(Compiler will export all symbols from shared libraries)
 648 fi
 649
 650 AC_WIRESHARK_LDFLAGS_CHECK([-Wl,--as-needed])
 651 ###AC_WIRESHARK_LDFLAGS_CHECK([-Wl,-M])
 652 ###AC_WIRESHARK_LDFLAGS_CHECK([-Wl,--cref])
 653 # AC_WIRESHARK_LDFLAGS_CHECK([-flto])
 654 # AC_WIRESHARK_LDFLAGS_CHECK([-fwhopr])
 655 # AC_WIRESHARK_LDFLAGS_CHECK([-fwhole-program])
 656
 657 #
 658 # Put -fPIE in PIE_CFLAGS and -pie in PIE_LDFLAGS if we can use them,
 659 # so that we can build dumpcap PIE - it may run with elevated
 660 # privileges, and using PIE means the OS can run it at random locations
 661 # in the address space to make attacks more difficult.
 662 #
 663 CFLAGS_before_pie=$CFLAGS
 664 AC_WIRESHARK_GCC_CFLAGS_CHECK(-fPIE, C)
 665 if test "x$CLFAGS" != "x$CFLAGS_before_pie"
 666 then
 667         # Restore CFLAGS
 668         CFLAGS=$CFLAGS_before_pie
 669
 670         LDFLAGS_before_pie=$LDFLAGS
 671         AC_WIRESHARK_LDFLAGS_CHECK([-fPIE -pie])
 672         if test "x$LDFLAGS" != "x$LDFLAGS_before_pie"
 673         then
 674                 # We can use PIE
 675                 PIE_CFLAGS="-fPIE"
 676                 PIE_LDFLAGS="-pie"
 677
 678                 # Restore LDFLAGS
 679                 LDFLAGS=$LDFLAGS_before_pie
 680         fi
 681
 682 fi
 683 AC_SUBST(PIE_CFLAGS)
 684 AC_SUBST(PIE_LDFLAGS)
 685
 686 #
 687 # If we're running GCC or clang define _U_ to be "__attribute__((unused))"
 688 # so we can use _U_ to flag unused function parameters and not get warnings
 689 # about them. Otherwise, define _U_ to be an empty string so that _U_ used
 690 # to flag an unused function parameters will compile with other compilers.
 691 #
 692 # XXX - similar hints for other compilers?
 693 #
 694 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 695   AC_DEFINE(_U_, __attribute__((unused)), [Hint to the compiler that a function parameters is not used])
 696 else
 697   AC_DEFINE(_U_, , [Hint to the compiler that a function parameters is not used])
 698 fi
 699
 700 # If we're running GCC or CLang, use FORTIFY_SOURCE=2
 701 #  (only if the GCC 'optimization level' > 0).
 702 #
 703 # See: http://gcc.gnu.org/ml/gcc-patches/2004-09/msg02055.html
 704 # See: http://sourceware.org/bugzilla/show_bug.cgi?id=13979
 705 #
 706 # Note: FORTIFY_SOURCE is only effective for gcc optimization level > 0 (-O1, etc)
 707 AC_WIRESHARK_GCC_FORTIFY_SOURCE_CHECK
 708
 709 #
 710 # If the compiler supports GCC-style flags, enable a barrier "stop on
 711 # warning".
 712 # This barrier is set for a very large part of the code. However, it is
 713 # typically not set for "generated" code  (flex, ans2wrs, idl2wrs, ...)
 714 #
 715 warnings_as_errors_default="yes"
 716 AC_MSG_CHECKING(whether we should treat compiler warnings as errors)
 717 AC_ARG_ENABLE(warnings-as-errors,
 718   AC_HELP_STRING( [--enable-warnings-as-errors],
 719                   [treat warnings as errors (only for GCC or clang) @<:@default=yes, unless extra warnings are enabled@:>@]),
 720 [
 721   if test "x$ac_supports_gcc_flags" = "xyes" -a "x$enableval" = "xyes"; then
 722     with_warnings_as_errors="yes"
 723     AC_MSG_RESULT(yes)
 724   else
 725     with_warnings_as_errors="no"
 726     AC_MSG_RESULT(no)
 727   fi
 728 ],
 729 [
 730   if test "x$ac_supports_gcc_flags" = "xyes" -a "x$wireshark_extra_gcc_flags" = "x" -a "x$warnings_as_errors_default" = "xyes"; then
 731     with_warnings_as_errors="yes"
 732     AC_MSG_RESULT(yes)
 733   else
 734     with_warnings_as_errors="no"
 735     AC_MSG_RESULT(no)
 736   fi
 737 ]
 738 )
 739 AM_CONDITIONAL(HAVE_WARNINGS_AS_ERRORS, test "x$with_warnings_as_errors" = "xyes")
 740
 741 #
 742 # Add any platform-specific compiler flags needed.
 743 #
 744 AC_MSG_CHECKING(for platform-specific compiler flags)
 745 if test "x$GCC" = "xyes" ; then
 746         #
 747         # GCC - do any platform-specific tweaking necessary.
 748         #
 749         case "$host_os" in
 750         solaris*)
 751                 # the X11 headers don't automatically include prototype info
 752                 # and a lot don't include the return type
 753                 CPPFLAGS="$CPPFLAGS -DFUNCPROTO=15"
 754                 CFLAGS="$CFLAGS -Wno-return-type"
 755                 CXXFLAGS="$CXXFLAGS -Wno-return-type"
 756                 AC_MSG_RESULT(GCC on Solaris - added -Wno-return-type -DFUNCPROTO=15)
 757                 ;;
 758         *)
 759                 AC_MSG_RESULT(none needed)
 760                 ;;
 761         esac
 762 else
 763         #
 764         # Not GCC - assume it's the vendor's compiler.
 765         #
 766         case "$host_os" in
 767         hpux*)
 768                 #
 769                 # HP's ANSI C compiler; flags suggested by Jost Martin.
 770                 # "-Ae" for ANSI C plus extensions such as "long long".
 771                 # "+O2", for optimization.  XXX - works with "-g"?
 772                 #
 773                 # HP's ANSI C++ compiler doesn't support "-Ae", but
 774                 # does support "+O2", at least according to the
 775                 # documentation I can find online.
 776                 #
 777                 CFLAGS="-Ae +O2 $CFLAGS"
 778                 CFLAGS_FOR_BUILD="-Ae +O2 $CFLAGS"
 779                 CXXFLAGS="+O2 $CFLAGS"
 780                 AC_MSG_RESULT(HP ANSI C compiler - added -Ae +O2)
 781                 ;;
 782         *)
 783                 AC_MSG_RESULT(none needed)
 784                 ;;
 785         esac
 786 fi
 787
 788 #
 789 # Add any platform-specific linker flags needed.
 790 #
 791 AC_MSG_CHECKING(for platform-specific linker flags)
 792 case "$host_os" in
 793 darwin*)
 794         #
 795         # Add -Wl,-single_module to the LDFLAGS used with shared
 796         # libraries, to fix some error that show up in some cases;
 797         # some Apple documentation recommends it for most shared
 798         # libraries.
 799         #
 800         LDFLAGS_SHAREDLIB="-Wl,-single_module"
 801         #
 802         # Add -Wl,-search_paths_first to make sure that if we search
 803         # directories A and B, in that order, for a given library, a
 804         # non-shared version in directory A, rather than a shared
 805         # version in directory B, is chosen (so we can use
 806         # --with-pcap=/usr/local to force all programs to be linked
 807         # with a static version installed in /usr/local/lib rather than
 808         # the system version in /usr/lib).
 809         #
 810         LDFLAGS="-Wl,-search_paths_first $LDFLAGS"
 811         AC_MSG_RESULT([Apple linker - added -Wl,-single_module and -Wl,-search_paths_first])
 812         ;;
 813 cygwin*)
 814         #
 815         # Shared libraries in cygwin/Win32 must never contain
 816         # undefined symbols.
 817         #
 818         LDFLAGS="$LDFLAGS -no-undefined"
 819         AC_MSG_RESULT(CygWin GNU ld - added -no-undefined)
 820         ;;
 821 *)
 822         AC_MSG_RESULT(none needed)
 823         ;;
 824 esac
 825 AC_SUBST(LDFLAGS_SHAREDLIB)
 826
 827 # Enable silent builds by default
 828 # Verbose builds can be enabled with "./configure
 829 # --enable-silent-rules ..." or "make V=1 ..."
 830 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
 831   [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
 832
 833 #
 834 # On "Darwin", which we assume to mean "OS X" rather than "iOS" or
 835 # "just Darwin" (as we don't currently support iOS, and as I don't
 836 # think you can build and run "just Darwin" as an OS for PCs), we
 837 # arrange to build some programs with Application Services so they
 838 # can launch Web browsers and Finder windows, arrange to build some
 839 # programs with System Configuration so they can get "friendly names"
 840 # and other information about interfaces, and build any programs that
 841 # use either of those frameworks or that report version information
 842 # with Core Foundation as the frameworks in question use it and as we
 843 # get version information from plists and thus need Core Foundation
 844 # to process those plists.
 845 #
 846 case "$host_os" in
 847
 848 darwin*)
 849         AC_DEFINE(HAVE_OS_X_FRAMEWORKS, 1, [Define to 1 if you have OS X frameworks])
 850         APPLICATIONSERVICES_FRAMEWORKS="-framework ApplicationServices"
 851         SYSTEMCONFIGURATION_FRAMEWORKS="-framework SystemConfiguration"
 852         COREFOUNDATION_FRAMEWORKS="-framework CoreFoundation"
 853
 854         #
 855         # OK, so we have the OS X frameworks; do they include
 856         # CFPropertyListCreateWithStream, or do we have
 857         # to fall back on CFPropertyListCreateFromStream?
 858         # (They only differ in the error return, which we
 859         # don't care about.  And, no, we shouldn't just
 860         # use CFPropertyListCreateFromStream, because it's
 861         # deprecated in newer releases.)
 862         #
 863         ac_save_LIBS="$LIBS"
 864         LIBS="$LIBS $COREFOUNDATION_FRAMEWORKS"
 865         AC_CHECK_FUNCS(CFPropertyListCreateWithStream)
 866         LIBS="$ac_save_LIBS"
 867         ;;
 868 esac
 869 AC_SUBST(APPLICATIONSERVICES_FRAMEWORKS)
 870 AC_SUBST(SYSTEMCONFIGURATION_FRAMEWORKS)
 871 AC_SUBST(COREFOUNDATION_FRAMEWORKS)
 872
 873 dnl Look in /usr/local for header files and libraries ?
 874 dnl XXX FIXME don't include /usr/local if it is already in the system
 875 dnl search path as this causes gcc 3.2 on Linux to complain about a change
 876 dnl of the system search order for includes
 877 AC_ARG_ENABLE(usr-local,
 878   AC_HELP_STRING( [--enable-usr-local],
 879                   [look for headers and libs in /usr/local tree @<:@default=yes@:>@]),
 880     ac_cv_enable_usr_local=$enableval,ac_cv_enable_usr_local=yes)
 881
 882 AC_MSG_CHECKING(whether to use /usr/local for headers and libraries)
 883 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
 884         if test -d "/usr/local"; then
 885                 AC_MSG_RESULT(yes)
 886                 #
 887                 # Arrange that we search for header files in the source directory
 888                 # and in its "wiretap" subdirectory, as well as in "/usr/local/include",
 889                 # as various packages we use ("libpcap", "zlib", "adns")
 890                 # may have been installed under "/usr/local/include".
 891                 #
 892                 CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 893
 894                 #
 895                 # Arrange that we search for libraries in "/usr/local/lib".
 896                 #
 897                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, /usr/local/lib)
 898         else
 899                 AC_MSG_RESULT(no)
 900         fi
 901 else
 902         AC_MSG_RESULT(no)
 903 fi
 904
 905 #
 906 # If we're running Solaris, and LD_LIBRARY_PATH is defined, add it as a
 907 # link directory.
 908 #
 909 case "$host_os" in
 910   solaris*)
 911     AC_MSG_CHECKING(for LD_LIBRARY_PATH, since you appear to be running Solaris)
 912     if test x$LD_LIBRARY_PATH != x ; then
 913       LIBS="$LIBS -R$LD_LIBRARY_PATH"
 914       AC_MSG_RESULT(yes -- added LD_LIBRARY_PATH to run-time linker path)
 915     else
 916       AC_MSG_RESULT(no -- this may be a problem in a few seconds)
 917     fi
 918   ;;
 919 esac
 920
 921 #
 922 # Check for versions of "sed" inadequate to handle, in libtool, a list
 923 # of object files as large as the list in Wireshark.
 924 #
 925 # On Solaris, we check for "/bin/sed", "/usr/bin/sed", and "/usr/ucb/sed",
 926 # as both "/usr/bin/sed" (which is also "/bin/sed", as "/bin" is just a
 927 # symlink to "/usr/bin", but people may have "/bin" before "/usr/bin" in
 928 # their search path) and "/usr/ucb/sed" are inadequate; "/usr/xpg4/bin/sed"
 929 # is the only "sed" that comes with Solaris that can handle Wireshark.
 930 #
 931 # Add any checks here that are necessary for other OSes.
 932 #
 933 AC_WIRESHARK_GNU_SED_CHECK
 934 if test "$HAVE_GNU_SED" = no ; then
 935         case "$host_os" in
 936         solaris*)
 937                 AC_MSG_CHECKING(whether one of /usr/bin/sed or /bin/sed or /usr/ucb/sed will be used)
 938                 case `which sed` in
 939                         /bin/sed|/usr/bin/sed|/usr/ucb/sed)
 940                         AC_MSG_RESULT(yes)
 941                         AC_MSG_ERROR([change your path to search /usr/xpg4/bin or directory containing GNU sed before /usr/bin (and /bin and /usr/ucb)])
 942                         ;;
 943
 944                         *)
 945                         AC_MSG_RESULT(no)
 946                         ;;
 947                 esac
 948                 ;;
 949
 950         *)
 951                 :
 952                 ;;
 953         esac
 954 fi
 955
 956 # Enable/disable wireshark
 957
 958 AC_ARG_ENABLE(wireshark,
 959   AC_HELP_STRING( [--enable-wireshark],
 960                   [build GTK+-based Wireshark @<:@default=yes, if GTK+ available@:>@]),
 961     enable_wireshark=$enableval,enable_wireshark=yes)
 962
 963 AC_ARG_ENABLE(packet-editor,
 964   AC_HELP_STRING( [--enable-packet-editor],
 965                   [add support for packet editor in Wireshark @<:@default=no@:>@]),
 966     enable_packet_editor=$enableval,enable_packet_editor=no)
 967 if test x$enable_packet_editor = xyes; then
 968         AC_DEFINE(WANT_PACKET_EDITOR, 1, [Support for packet editor])
 969 fi
 970
 971 AC_ARG_ENABLE(profile-build,
 972   AC_HELP_STRING( [--enable-profile-build],
 973                   [build profile-ready binaries @<:@default=no@:>@]),
 974     enable_profile_build=$enableval,enable_profile_build=no)
 975 AM_CONDITIONAL(USE_PROFILE_BUILD, test x$enable_profile_build = xyes)
 976 AC_MSG_CHECKING(if profile builds must be generated)
 977 if test "x$enable_profile_build" = "xyes" ; then
 978         if test "x$GCC" = "xyes" -o "x$CLANG" = "xyes" ; then
 979                 AC_MSG_RESULT(yes)
 980                 CFLAGS=" -pg $CFLAGS"
 981                 CXXFLAGS=" -pg $CXXFLAGS"
 982         else
 983                 AC_MSG_RESULT(no)
 984                 echo "Building profile binaries currently only supported for GCC and clang."
 985         fi
 986 else
 987         AC_MSG_RESULT(no)
 988 fi
 989
 990 # Create DATAFILE_DIR #define for config.h
 991 datafiledir=$datadir/wireshark
 992 datafiledir=`(
 993     test "x$prefix" = xNONE && prefix=$ac_default_prefix
 994     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
 995     # Ugly hack, but I don't see how this problem can be solved
 996     # properly that DATAFILE_DIR had a value starting with
 997     # "${prefix}/" instead of e.g. "/usr/local/"
 998     eval eval echo "$datafiledir"
 999 )`
1000 AC_DEFINE_UNQUOTED(DATAFILE_DIR,"$datafiledir", [Directory for data])
1001
1002 # Create DOC_DIR #define for config.h
1003 docdir=`(
1004     test "x$prefix" = xNONE && prefix=$ac_default_prefix
1005     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1006     # Ugly hack, but I don't see how this problem can be solved
1007     # properly that DOC_DIR had a value starting with
1008     # "${prefix}/" instead of e.g. "/usr/local/"
1009     eval eval echo "$docdir"
1010 )`
1011 AC_DEFINE_UNQUOTED(DOC_DIR, "$docdir", [Directory for docs])
1012
1013 GTK2_MIN_VERSION=2.12.0
1014 AC_SUBST(GTK2_MIN_VERSION)
1015 GTK3_MIN_VERSION=3.0.0
1016 AC_SUBST(GTK3_MIN_VERSION)
1017 QT_MIN_VERSION=4.6.0
1018 AC_SUBST(QT_MIN_VERSION)
1019 # GTK+ and Qt checks; we require GTK+ $GTK2_MIN_VERSION or later or
1020 # GTK3_MIN_VERSION or later or Qt $QT_MIN_VERSION or later.
1021 #
1022 # We only do those if we're going to be building Wireshark;
1023 # otherwise, we don't have any GUI to build, so we don't use
1024 # GTK+ or Qt.
1025 #
1026 # We don't add $GTK_LIBS or $Qt_LIBS to LIBS, because we don't want to
1027 # force all programs to be built with GTK+ or Qt.
1028 #
1029 # Release dates for GTK+ versions:
1030 # 2.12.0: 14 Sep 2007
1031 # 2.14.0: 04 Sep 2008
1032 # 2.16.0: 13 Mar 2009
1033 # 2.18.0: 23 Sep 2009
1034 # 2.20.0: 23 Mar 2010
1035 # 2.22.0: 23 Sep 2010
1036 # 2.24.0: 30 Jan 2011
1037 # 3.0.0:  10 Feb 2011
1038 # 3.2.0:  25 Sep 2011
1039 # 3.4.0:  26 Mar 2012
1040 # 3.6.0:  24 Sep 2012
1041 # 3.8.0:  25 Mar 2013
1042
1043 if test "x$enable_wireshark" = "xyes"; then
1044         if test "x$with_qt" = "xyes"; then
1045
1046                 AC_MSG_CHECKING(whether we have a working C++ compiler)
1047                 AC_LANG_PUSH([C++])
1048                 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1049                         [AC_MSG_RESULT(yes)],
1050                         [
1051                          AC_MSG_RESULT(no)
1052                          AC_MSG_ERROR(Need a working C++ compiler to build Wireshark with Qt)
1053                         ])
1054                 AC_LANG_POP([C++])
1055
1056                 AM_PATH_QT($QT_MIN_VERSION,
1057                 [
1058                         CFLAGS="$CFLAGS $Qt_CFLAGS"
1059                         CXXFLAGS="$CXXFLAGS $Qt_CFLAGS"
1060                         have_qt=yes
1061                 ]
1062                 , [AC_MSG_ERROR([Qt is not available])])
1063
1064                 #
1065                 # XXX - greasy hack to make ui/gtk/recent.c
1066                 # compile.
1067                 #
1068                 CPPFLAGS="-DQT_GUI_LIB"
1069
1070                 #
1071                 # We don't know whether we have GTK+, but we
1072                 # won't be using it, so it's as if we don't
1073                 # have it.
1074                 #
1075                 have_gtk=no
1076         else
1077                 #
1078                 # Not Qt - either GTK+ 3.x or 2.x.
1079                 #
1080                 if test "x$with_gtk3" = "xyes"; then
1081                         AM_PATH_GTK_3_0(3.0.0,
1082                         [
1083                                 CFLAGS="$CFLAGS $GTK_CFLAGS"
1084                                 CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
1085                                 have_gtk=yes
1086                                 AC_DEFINE(HAVE_GTK, 1,
1087                                     [Define to 1 if compiling with GTK])
1088                         ], have_gtk=no)
1089
1090                 else
1091                         AM_PATH_GTK_2_0($GTK2_MIN_VERSION,
1092                         [
1093                                 CFLAGS="$CFLAGS $GTK_CFLAGS"
1094                                 CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
1095                                 have_gtk=yes
1096                                 AC_DEFINE(HAVE_GTK, 1,
1097                                     [Define to 1 if compiling with GTK])
1098                         ], have_gtk=no)
1099                 fi
1100         fi
1101 else
1102         have_qt=no
1103         have_gtk=no
1104 fi
1105
1106 GLIB_MIN_VERSION=2.16.0
1107 AC_SUBST(GLIB_MIN_VERSION)
1108 # GLib checks; we require GLib $GLIB_MIN_VERSION or later, and require gmodule
1109 # support, as we need that for dynamically loading plugins.
1110 # If we found GTK+, this doesn't add GLIB_CFLAGS to CFLAGS, because
1111 # AM_PATH_GTK will add GTK_CFLAGS to CFLAGS, and GTK_CFLAGS is a
1112 # superset of GLIB_CFLAGS.  If we didn't find GTK+, it does add
1113 # GLIB_CFLAGS to CFLAGS.
1114 # However, this means that both @GLIB_LIBS@ and @GTK_LIBS@ will be
1115 # set when generating the Makefile, so we can make programs that require
1116 # only GLib link with @GLIB_LIBS@ and make programs that require GTK+
1117 # link with @GTK_LIBS@ (which includes @GLIB_LIBS@).
1118 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
1119 # programs to be built with GLib.
1120 #
1121 # Release dates for GLib versions:
1122 # 2.14.0: 03 Aug 2007
1123 # 2.16.0: 10 Mar 2008
1124 # 2.18.0: 02 Sep 2008
1125 # 2.20.0: 13 Mar 2009
1126 # 2.22.0: 22 Sep 2009
1127 # 2.24.0: 28 Mar 2010
1128 # 2.26.0: 27 Sep 2010
1129 # 2.28.0: 08 Feb 2011
1130 # 2.30.0: 27 Sep 2011
1131 # 2.32.0: 24 Mar 2012
1132 # 2.34.0: 24 Sep 2012
1133 # 2.36.0: 25 Mar 2013
1134
1135 have_wireshark_cxx="false"
1136 if test "$have_gtk" = "no" ; then
1137         #
1138         # We don't have GTK+.
1139         #
1140         if test "$have_qt" = "yes" ; then
1141                 #
1142                 # However, we do have Qt, and thus will be building
1143                 # Wireshark (if the user had explicitly disabled
1144                 # Wireshark, we wouldn't have looked for Qt, so we
1145                 # wouldn't think we had it, and thus wouldn't be here).
1146                 #
1147                 wireshark_bin="wireshark\$(EXEEXT)"
1148                 # Give automake a hint that it needs to use c++ linking.
1149                 have_wireshark_cxx="yes"
1150                 wireshark_man="wireshark.1"
1151                 wireshark_SUBDIRS="codecs ui/qt"
1152         else
1153                 #
1154                 # We don't have Qt, either, which means we have no UI
1155                 # toolkit.
1156                 #
1157                 # If they didn't explicitly say "--disable-wireshark",
1158                 # fail (so that, unless they explicitly indicated that
1159                 # they don't want Wireshark, we stop so they know they
1160                 # won't be getting Wireshark unless they fix the GTK+/Qt
1161                 # problem).
1162                 #
1163                 if test "x$enable_wireshark" = "xyes"; then
1164                         if test "x$with_gtk3" = "xyes"; then
1165                                 AC_MSG_ERROR([GTK+ $GTK3_MIN_VERSION or later isn't available, so Wireshark can't be compiled])
1166                         else
1167                                 AC_MSG_ERROR([Neither Qt nor GTK+ $GTK2_MIN_VERSION or later are available, so Wireshark can't be compiled])
1168                         fi
1169                 fi
1170                 wireshark_bin=""
1171                 wireshark_man=""
1172         fi
1173         # Use GLIB_CFLAGS
1174         AM_PATH_GLIB_2_0($GLIB_MIN_VERSION,
1175         [
1176                 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1177                 CXXFLAGS="$CXXFLAGS $GLIB_CFLAGS"
1178         ], AC_MSG_ERROR(GLib $GLIB_MIN_VERSION or later distribution not found.), gthread gmodule)
1179 else
1180         #
1181         # We have GTK+, and thus will be building Wireshark (if the user
1182         # had explicitly disabled Wireshark, we wouldn't have looked for
1183         # GTK+, so we wouldn't think we had it, and thus wouldn't be here).
1184         #
1185         wireshark_bin="wireshark\$(EXEEXT)"
1186         wireshark_man="wireshark.1"
1187         wireshark_SUBDIRS="codecs ui/gtk"
1188         # Don't use GLIB_CFLAGS
1189         AM_PATH_GLIB_2_0($GLIB_MIN_VERSION, , AC_MSG_ERROR(GLib $GLIB_MIN_VERSION or later distribution not found.), gthread gmodule)
1190
1191         CPPFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CPPFLAGS"
1192         CPPFLAGS="-DGDK_DISABLE_DEPRECATED $CPPFLAGS"
1193         CPPFLAGS="-DGTK_DISABLE_DEPRECATED $CPPFLAGS"
1194         CPPFLAGS="-DGTK_DISABLE_SINGLE_INCLUDES $CPPFLAGS"
1195         if test ! \( $gtk_config_major_version -eq 2 -a $gtk_config_minor_version -lt 20 \) ; then
1196                 # Enable GSEAL when building with GTK > 2.20
1197                 # (Versions prior to 2.22 lacked some necessary accessors.)
1198                 CPPFLAGS="-DGSEAL_ENABLE $CPPFLAGS"
1199         fi
1200 fi
1201
1202 #
1203 # "make dist" requires that we have the Qt build tools.
1204 #
1205 # Annoyingly, at least on Fedora 16, uic and moc are named XXX-qt4
1206 # rather than just XXX, perhaps to allow Qt 3 and Qt 4 tools to be
1207 # installed; if they're still doing that in current Fedora releases,
1208 # perhaps there will also be XXX-qt5 when they pick up Qt 5.
1209 #
1210 AC_PATH_PROG(UIC, uic)
1211 if test "x$UIC" = x
1212 then
1213         AC_PATH_PROG(UIC, uic-qt4)
1214         if test "x$UIC" = x
1215         then
1216                 if test "x$with_qt" = "xyes"; then
1217                         #
1218                         # If you want to build with Qt, you'd better
1219                         # have uic.
1220                         #
1221                         AC_MSG_ERROR(I couldn't find uic or uic-qt4; make sure it's installed and in your path)
1222                 else
1223                         #
1224                         # We shouldn't fail here, as the user's not
1225                         # building with Qt, and we shouldn't force them
1226                         # to have Qt installed if they're not doing so.
1227                         # "make dist" will fail if they do that, but
1228                         # we don't know whether they'll be doing that,
1229                         # so this is the best we can do.
1230                         #
1231                         UIC=uic
1232                 fi
1233         fi
1234 fi
1235 AC_SUBST(UIC)
1236 AC_PATH_PROG(MOC, moc)
1237 if test "x$MOC" = x
1238 then
1239         AC_PATH_PROG(MOC, moc-qt4)
1240         if test "x$MOC" = x
1241         then
1242                 if test "x$with_qt" = "xyes"; then
1243                         #
1244                         # If you want to build with Qt, you'd better
1245                         # have moc.
1246                         #
1247                         AC_MSG_ERROR(I couldn't find moc or moc-qt4; make sure it's installed and in your path)
1248                 else
1249                         #
1250                         # We shouldn't fail here, as the user's not
1251                         # building with Qt, and we shouldn't force them
1252                         # to have Qt installed if they're not doing so.
1253                         # "make dist" will fail if they do that, but
1254                         # we don't know whether they'll be doing that,
1255                         # so this is the best we can do.
1256                         #
1257                         MIC=moc
1258                 fi
1259         fi
1260 fi
1261 AC_SUBST(MOC)
1262
1263 # Error out if a glib header other than a "top level" header
1264 #  (glib.h, glib-object.h, gio.h) or certain other headers( e.g.,gmodule.h)
1265 #  is used.
1266 CPPFLAGS="-DG_DISABLE_SINGLE_INCLUDES $CPPFLAGS"
1267
1268 # Error out on the usage of deprecated glib functions
1269 CPPFLAGS="-DG_DISABLE_DEPRECATED $CPPFLAGS"
1270
1271 #
1272 # Check whether GLib modules are supported, to determine whether we
1273 # can support plugins.
1274 #
1275 AC_MSG_CHECKING(whether GLib supports loadable modules)
1276 ac_save_CFLAGS="$CFLAGS"
1277 ac_save_LIBS="$LIBS"
1278 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1279 LIBS="$GLIB_LIBS $LIBS"
1280 AC_TRY_RUN([
1281 #include <glib.h>
1282 #include <gmodule.h>
1283 #include <stdio.h>
1284 #include <stdlib.h>
1285
1286 int
1287 main ()
1288 {
1289   if (g_module_supported())
1290     return 0;   /* success */
1291   else
1292     return 1;   /* failure */
1293 }
1294 ], ac_cv_glib_supports_modules=yes, ac_cv_glib_supports_modules=no,
1295    [echo $ac_n "cross compiling; assumed OK... $ac_c"
1296     ac_cv_glib_supports_modules=yes])
1297 CFLAGS="$ac_save_CFLAGS"
1298 LIBS="$ac_save_LIBS"
1299 if test "$ac_cv_glib_supports_modules" = yes ; then
1300   AC_MSG_RESULT(yes)
1301   have_plugins=yes
1302 else
1303   AC_MSG_RESULT(no)
1304   have_plugins=no
1305 fi
1306
1307 #
1308 # If we have <dlfcn.h>, check whether we can use dladdr to find a
1309 # filename (hopefully, a full pathname, but no guarantees) for
1310 # the executable.
1311 #
1312 if test "$ac_cv_header_dlfcn_h" = "yes"
1313 then
1314         AC_MSG_CHECKING(whether dladdr can be used to find the pathname of an executable)
1315         ac_save_CFLAGS="$CFLAGS"
1316         ac_save_LIBS="$LIBS"
1317         CFLAGS="$CFLAGS $GLIB_CFLAGS"
1318         LIBS="$GLIB_LIBS $LIBS"
1319         AC_TRY_RUN([
1320 #define _GNU_SOURCE     /* required on Linux, sigh */
1321 #include <dlfcn.h>
1322
1323 int
1324 main(void)
1325 {
1326         Dl_info info;
1327
1328         if (!dladdr((void *)main, &info))
1329                 return 1;       /* failure */
1330         return 0;               /* assume success */
1331 }
1332 ], ac_cv_dladdr_finds_executable_path=yes, ac_cv_dladdr_finds_executable_path=no,
1333    [echo $ac_n "cross compiling; assumed OK... $ac_c"
1334     ac_cv_dladdr_finds_executable_path=yes])
1335         CFLAGS="$ac_save_CFLAGS"
1336         LIBS="$ac_save_LIBS"
1337         if test x$ac_cv_dladdr_finds_executable_path = xyes
1338         then
1339                 AC_DEFINE(DLADDR_FINDS_EXECUTABLE_PATH, 1, [Define if dladdr can be used to find the path of the executable])
1340         fi
1341         AC_MSG_RESULT($ac_cv_dladdr_finds_executable_path)
1342 fi
1343
1344 #
1345 # Check whether GLib's printf supports thousands grouping. (This might
1346 # be different from the system's printf since GLib can optionally use
1347 # its own printf implementation.)
1348 #
1349 AC_MSG_CHECKING(whether GLib supports POSIX/XSI thousands grouping)
1350 ac_save_CFLAGS="$CFLAGS"
1351 ac_save_LIBS="$LIBS"
1352 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1353 LIBS="$GLIB_LIBS $LIBS"
1354 AC_TRY_RUN([
1355 #include <glib.h>
1356 #include <locale.h>
1357 #include <stdio.h>
1358 #include <string.h>
1359
1360 int
1361 main ()
1362 {
1363   gchar *str;
1364   setlocale(LC_ALL, "en_US.UTF-8");
1365   str = g_strdup_printf("%'u", 123456);
1366   return (strcmp (str, "123,456") != 0);
1367 }
1368 ], ac_cv_glib_supports_printf_grouping=yes, ac_cv_glib_supports_printf_grouping=no,
1369    [echo $ac_n "cross compiling; playing it safe... $ac_c"
1370     ac_cv_glib_supports_printf_grouping=no])
1371 CFLAGS="$ac_save_CFLAGS"
1372 LIBS="$ac_save_LIBS"
1373 if test "$ac_cv_glib_supports_printf_grouping" = yes ; then
1374   AC_MSG_RESULT(yes)
1375   AC_DEFINE(HAVE_GLIB_PRINTF_GROUPING, 1, [Define if your printf() function supports thousands grouping.])
1376 else
1377   AC_MSG_RESULT(no)
1378 fi
1379
1380 if test "x$have_gtk" = "xyes"
1381 then
1382     #
1383     # We have GTK+; do we want the OS X integration functions and,
1384     # if so, do we have them and, if so, which versions do we have,
1385     # the old Carbon-based ones or the new Cocoa-based ones?
1386     #
1387     AC_MSG_CHECKING(whether to use OS X integration functions)
1388
1389     AC_ARG_WITH(osx-integration,
1390       AC_HELP_STRING( [--with-osx-integration],
1391                       [use OS X integration functions @<:@default=yes, if available@:>@]),
1392     [
1393         if test $withval = no
1394         then
1395             want_osx_integration=no
1396         else
1397             want_osx_integration=yes
1398         fi
1399     ],[
1400         want_osx_integration=yes
1401     ])
1402     if test "x$want_osx_integration" = "xno"; then
1403         AC_MSG_RESULT(no)
1404     else
1405         AC_MSG_RESULT(yes)
1406         AC_WIRESHARK_OSX_INTEGRATION_CHECK
1407     fi
1408 fi
1409
1410 AC_SUBST(wireshark_bin)
1411 AC_SUBST(wireshark_man)
1412 AM_CONDITIONAL(HAVE_Qt, test "$have_qt" = "yes")
1413 AM_CONDITIONAL(HAVE_WIRESHARK_CXX, test "$have_wireshark_cxx" = "yes")
1414
1415
1416 # Enable/disable tshark
1417
1418 AC_ARG_ENABLE(tshark,
1419   AC_HELP_STRING( [--enable-tshark],
1420                   [build TShark @<:@default=yes@:>@]),
1421     tshark=$enableval,enable_tshark=yes)
1422
1423 if test "x$enable_tshark" = "xyes" ; then
1424         tshark_bin="tshark\$(EXEEXT)"
1425         tshark_man="tshark.1"
1426         wiresharkfilter_man="wireshark-filter.4"
1427 else
1428         tshark_bin=""
1429         tshark_man=""
1430 fi
1431 AC_SUBST(tshark_bin)
1432 AC_SUBST(tshark_man)
1433 AC_SUBST(wiresharkfilter_man)
1434
1435
1436
1437 # Enable/disable editcap
1438
1439 AC_ARG_ENABLE(editcap,
1440   AC_HELP_STRING( [--enable-editcap],
1441                   [build editcap @<:@default=yes@:>@]),
1442     enable_editcap=$enableval,enable_editcap=yes)
1443
1444 if test "x$enable_editcap" = "xyes" ; then
1445         editcap_bin="editcap\$(EXEEXT)"
1446         editcap_man="editcap.1"
1447 else
1448         editcap_bin=""
1449         editcap_man=""
1450 fi
1451 AC_SUBST(editcap_bin)
1452 AC_SUBST(editcap_man)
1453
1454 # Enabling/disabling of dumpcap is done later (after we know if we have PCAP
1455 # or not)
1456
1457 # Enable/disable capinfos
1458
1459 AC_ARG_ENABLE(capinfos,
1460   AC_HELP_STRING( [--enable-capinfos],
1461                   [build capinfos @<:@default=yes@:>@]),
1462     enable_capinfos=$enableval,enable_capinfos=yes)
1463
1464 if test "x$enable_capinfos" = "xyes" ; then
1465         capinfos_bin="capinfos\$(EXEEXT)"
1466         capinfos_man="capinfos.1"
1467 else
1468         capinfos_bin=""
1469         capinfos_man=""
1470 fi
1471 AC_SUBST(capinfos_bin)
1472 AC_SUBST(capinfos_man)
1473
1474
1475 # Enable/disable mergecap
1476
1477 AC_ARG_ENABLE(mergecap,
1478   AC_HELP_STRING( [--enable-mergecap],
1479                   [build mergecap @<:@default=yes@:>@]),
1480     enable_mergecap=$enableval,enable_mergecap=yes)
1481
1482 if test "x$enable_mergecap" = "xyes" ; then
1483         mergecap_bin="mergecap\$(EXEEXT)"
1484         mergecap_man="mergecap.1"
1485 else
1486         mergecap_bin=""
1487         mergecap_man=""
1488 fi
1489 AC_SUBST(mergecap_bin)
1490 AC_SUBST(mergecap_man)
1491
1492
1493 # Enable/disable reordercap
1494
1495 AC_ARG_ENABLE(reordercap,
1496   AC_HELP_STRING( [--enable-reordercap],
1497                   [build reordercap @<:@default=yes@:>@]),
1498     enable_reordercap=$enableval,enable_reordercap=yes)
1499
1500 if test "x$enable_reordercap" = "xyes" ; then
1501         reordercap_bin="reordercap\$(EXEEXT)"
1502         reordercap_man="reordercap.1"
1503 else
1504         reordercap_bin=""
1505         reordercap_man=""
1506 fi
1507 AC_SUBST(reordercap_bin)
1508 AC_SUBST(reordercap_man)
1509
1510
1511 # Enable/disable text2pcap
1512
1513 AC_ARG_ENABLE(text2pcap,
1514   AC_HELP_STRING( [--enable-text2pcap],
1515                   [build text2pcap @<:@default=yes@:>@]),
1516     text2pcap=$enableval,enable_text2pcap=yes)
1517
1518 if test "x$enable_text2pcap" = "xyes" ; then
1519         text2pcap_bin="text2pcap\$(EXEEXT)"
1520         text2pcap_man="text2pcap.1"
1521 else
1522         text2pcap_bin=""
1523         text2pcap_man=""
1524 fi
1525 AC_SUBST(text2pcap_bin)
1526 AC_SUBST(text2pcap_man)
1527
1528
1529 # Enable/disable dftest
1530
1531 AC_ARG_ENABLE(dftest,
1532   AC_HELP_STRING( [--enable-dftest],
1533                   [build dftest @<:@default=yes@:>@]),
1534     enable_dftest=$enableval,enable_dftest=yes)
1535
1536 if test "x$enable_dftest" = "xyes" ; then
1537         dftest_bin="dftest\$(EXEEXT)"
1538         dftest_man="dftest.1"
1539 else
1540         dftest_bin=""
1541         dftest_man=""
1542 fi
1543 AC_SUBST(dftest_bin)
1544 AC_SUBST(dftest_man)
1545
1546
1547 # Enable/disable randpkt
1548
1549 AC_ARG_ENABLE(randpkt,
1550   AC_HELP_STRING( [--enable-randpkt],
1551                   [build randpkt @<:@default=yes@:>@]),
1552     enable_randpkt=$enableval,enable_randpkt=yes)
1553
1554 if test "x$enable_randpkt" = "xyes" ; then
1555         randpkt_bin="randpkt\$(EXEEXT)"
1556         randpkt_man="randpkt.1"
1557 else
1558         randpkt_bin=""
1559         randpkt_man=""
1560 fi
1561 AC_SUBST(randpkt_bin)
1562 AC_SUBST(randpkt_man)
1563
1564
1565
1566 dnl Checks for "gethostbyname()" - and "-lnsl", if we need it to get
1567 dnl "gethostbyname()".
1568 AC_WIRESHARK_GETHOSTBY_LIB_CHECK
1569
1570 dnl Checks for "connect()", used as a proxy for "socket()" - and
1571 dnl "-lsocket", if we need it to get "connect()".
1572 AC_WIRESHARK_SOCKET_LIB_CHECK
1573
1574 dnl pcap check
1575 AC_MSG_CHECKING(whether to use libpcap for packet capture)
1576
1577 AC_ARG_WITH(pcap,
1578   AC_HELP_STRING( [--with-pcap@<:@=DIR@:>@],
1579                   [use libpcap for packet capturing @<:@default=yes@:>@]),
1580 [
1581         if test $withval = no
1582         then
1583                 want_pcap=no
1584         elif test $withval = yes
1585         then
1586                 want_pcap=yes
1587         else
1588                 want_pcap=yes
1589                 pcap_dir=$withval
1590         fi
1591 ],[
1592         want_pcap=yes
1593         pcap_dir=
1594 ])
1595 if test "x$want_pcap" = "xno" ; then
1596         AC_MSG_RESULT(no)
1597 else
1598         AC_MSG_RESULT(yes)
1599         AC_WIRESHARK_PCAP_CHECK
1600 fi
1601
1602
1603 dnl Check for airpcap
1604 AC_MSG_CHECKING(whether to include airpcap support)
1605 AC_ARG_ENABLE(airpcap,
1606   AC_HELP_STRING( [--enable-airpcap],
1607                   [use AirPcap in Wireshark @<:@default=yes@:>@]),
1608   enable_airpcap=$enableval, enable_airpcap=yes)
1609
1610 if test x$enable_airpcap = xyes; then
1611         if test "x$want_pcap" = "xno" ; then
1612                 enable_airpcap=no
1613                 AC_MSG_RESULT(pcap not available - disabling airpcap)
1614         else
1615                 AC_MSG_RESULT(yes)
1616                 AC_DEFINE(HAVE_AIRPCAP, 1, [Enable AirPcap])
1617         fi
1618 else
1619         AC_MSG_RESULT(no)
1620 fi
1621
1622
1623 dnl dumpcap check
1624 AC_MSG_CHECKING(whether to build dumpcap)
1625
1626 AC_ARG_ENABLE(dumpcap,
1627   AC_HELP_STRING( [--enable-dumpcap],
1628                   [build dumpcap @<:@default=yes@:>@]),
1629     enable_dumpcap=$enableval,enable_dumpcap=yes)
1630
1631 if test "x$enable_dumpcap" = "xyes" ; then
1632         if test "x$want_pcap" = "xno" ; then
1633                 enable_dumpcap=no
1634                 AC_MSG_RESULT(pcap not available - disabling dumpcap)
1635         else
1636                 AC_MSG_RESULT(yes)
1637         fi
1638 else
1639         AC_MSG_RESULT(no)
1640 fi
1641
1642 if test "x$enable_dumpcap" = "xyes" ; then
1643         dumpcap_bin="dumpcap\$(EXEEXT)"
1644         dumpcap_man="dumpcap.1"
1645 else
1646         dumpcap_bin=""
1647         dumpcap_man=""
1648 fi
1649 AC_SUBST(dumpcap_bin)
1650 AC_SUBST(dumpcap_man)
1651
1652 # Enable/disable rawshark
1653
1654 dnl rawshark check
1655 AC_MSG_CHECKING(whether to build rawshark)
1656
1657 AC_ARG_ENABLE(rawshark,
1658   AC_HELP_STRING( [--enable-rawshark],
1659                   [build rawshark @<:@default=yes@:>@]),
1660     rawshark=$enableval,enable_rawshark=yes)
1661
1662 if test "x$enable_rawshark" = "xyes" ; then
1663         if test "x$want_pcap" = "xno" ; then
1664                 enable_rawshark=no
1665                 AC_MSG_RESULT(pcap not available - disabling rawshark)
1666         else
1667                 AC_MSG_RESULT(yes)
1668         fi
1669 else
1670         AC_MSG_RESULT(no)
1671 fi
1672
1673 if test "x$enable_rawshark" = "xyes" ; then
1674         rawshark_bin="rawshark\$(EXEEXT)"
1675         rawshark_man="rawshark.1"
1676 else
1677         rawshark_bin=""
1678         rawshark_man=""
1679 fi
1680 AC_SUBST(rawshark_bin)
1681 AC_SUBST(rawshark_man)
1682
1683 dnl Use pcap-ng by default
1684 AC_ARG_ENABLE(pcap-ng-default,
1685   AC_HELP_STRING( [--enable-pcap-ng-default],
1686                   [use the pcap-ng file format by default instead of pcap @<:@default=yes@:>@]),
1687     enable_pcap_ng_default=$enableval,enable_pcap_ng_default=yes)
1688 if test x$enable_pcap_ng_default = xyes; then
1689         AC_DEFINE(PCAP_NG_DEFAULT, 1, [Support for pcap-ng])
1690 fi
1691
1692 dnl pcap remote check
1693 AC_MSG_CHECKING(whether to use libpcap remote capturing feature)
1694
1695 AC_ARG_WITH(pcap-remote,
1696     AC_HELP_STRING([--with-pcap-remote],
1697                    [use libpcap remote capturing (requires libpcap)]),
1698 [
1699     if test $withval = no
1700     then
1701         want_pcap_remote=no
1702     else
1703         want_pcap_remote=yes
1704     fi
1705 ],[
1706     want_pcap_remote=no
1707 ])
1708 if test "x$want_pcap_remote" = "xno" -o "x$want_pcap" = "xno" ; then
1709     AC_MSG_RESULT(no)
1710 else
1711     AC_MSG_RESULT(yes)
1712     AC_WIRESHARK_PCAP_REMOTE_CHECK
1713 fi
1714
1715 dnl zlib check
1716 AC_MSG_CHECKING(whether to use zlib for gzip compression and decompression)
1717
1718 AC_ARG_WITH(zlib,
1719   AC_HELP_STRING([--with-zlib@<:@=DIR@:>@],
1720                  [use zlib (located in directory DIR, if supplied) for gzip compression and decompression @<:@default=yes, if available@:>@]),
1721 [
1722         if test "x$withval" = "xno"
1723         then
1724                 want_zlib=no
1725         elif test "x$withval" = "xyes"
1726         then
1727                 want_zlib=yes
1728         else
1729                 want_zlib=yes
1730                 zlib_dir="$withval"
1731         fi
1732 ],[
1733         #
1734         # Use zlib if it's present, otherwise don't.
1735         #
1736         want_zlib=ifavailable
1737         zlib_dir=
1738 ])
1739 if test "x$want_zlib" = "xno" ; then
1740         AC_MSG_RESULT(no)
1741 else
1742         AC_MSG_RESULT(yes)
1743         AC_WIRESHARK_ZLIB_CHECK
1744         if test "x$want_zlib" = "xno" ; then
1745                 AC_MSG_RESULT(zlib not found - disabling gzip compression and decompression)
1746         else
1747                 if test "x$ac_cv_func_inflatePrime" = "xno" ; then
1748                         AC_MSG_RESULT(inflatePrime not found in zlib - disabling gzipped capture file support)
1749                 fi
1750         fi
1751 fi
1752
1753 dnl Lua check
1754 AC_MSG_CHECKING(whether to use liblua for the Lua scripting plugin)
1755
1756 AC_ARG_WITH(lua,
1757   AC_HELP_STRING( [--with-lua@<:@=DIR@:>@],
1758                   [use liblua (located in directory DIR, if supplied) for the Lua scripting plugin @<:@default=yes, if available@:>@]),
1759 [
1760         if test $withval = no
1761         then
1762                 want_lua=no
1763         elif test $withval = yes
1764         then
1765                 want_lua=yes
1766         else
1767                 want_lua=yes
1768                 lua_dir=$withval
1769         fi
1770 ],[
1771         #
1772         # Use liblua by default
1773         #
1774         want_lua=ifavailable
1775         lua_dir=
1776 ])
1777 if test "x$want_lua" = "xno" ; then
1778         AC_MSG_RESULT(no)
1779 else
1780         AC_MSG_RESULT(yes)
1781         AC_WIRESHARK_LIBLUA_CHECK
1782         if test "x$want_lua" = "xno" ; then
1783                 AC_MSG_RESULT(liblua not found - disabling support for the lua scripting plugin)
1784         fi
1785 fi
1786 AM_CONDITIONAL(HAVE_LIBLUA, test x$want_lua = xyes)
1787
1788
1789 dnl portaudio check
1790 AC_MSG_CHECKING(whether to use libportaudio for the rtp_player)
1791
1792 AC_ARG_WITH(portaudio,
1793   AC_HELP_STRING( [--with-portaudio@<:@=DIR@:>@],
1794                   [use libportaudio (located in directory DIR, if supplied) for the rtp_player @<:@default=yes, if available@:>@]),
1795 [
1796         if test $withval = no
1797         then
1798                 want_portaudio=no
1799         elif test $withval = yes
1800         then
1801                 want_portaudio=yes
1802         else
1803                 want_portaudio=yes
1804                 portaudio_dir=$withval
1805         fi
1806 ],[
1807         #
1808         # Use libportaudio by default
1809         #
1810         want_portaudio=ifavailable
1811         portaudio_dir=
1812 ])
1813 if test "x$want_portaudio" = "xno" ; then
1814         AC_MSG_RESULT(no)
1815 else
1816         AC_MSG_RESULT(yes)
1817         AC_WIRESHARK_LIBPORTAUDIO_CHECK
1818         if test "x$want_portaudio" = "xno" ; then
1819                 AC_MSG_RESULT(libportaudio not found - disabling support for the rtp_player)
1820         fi
1821 fi
1822 AM_CONDITIONAL(HAVE_LIBPORTAUDIO, test x$want_portaudio = xyes)
1823
1824
1825 dnl ipv6 check
1826 AC_ARG_ENABLE(ipv6,
1827   AC_HELP_STRING( [--enable-ipv6],
1828                   [use IPv6 name resolution, if available @<:@default=yes@:>@]),
1829     enable_ipv6=$enableval,enable_ipv6=yes)
1830
1831 AC_MSG_CHECKING(whether to enable ipv6 name resolution if available)
1832 if test "x$enable_ipv6" = "xno" ; then
1833         AC_MSG_RESULT(no)
1834 else
1835         AC_MSG_RESULT(yes)
1836         AC_WIRESHARK_IPV6_STACK
1837 fi
1838
1839
1840 dnl Check if dumpcap should be installed with filesystem capabilities
1841 AC_PATH_PROG(SETCAP, setcap)
1842 AC_ARG_ENABLE(setcap-install,
1843   AC_HELP_STRING( [--enable-setcap-install],
1844                   [install dumpcap with cap_net_admin and cap_net_raw @<:@default=no@:>@]),
1845     enable_setcap_install=$enableval,enable_setcap_install=no)
1846
1847 AC_MSG_CHECKING(whether to install dumpcap with cap_net_admin and cap_net_raw capabilities)
1848 if test "x$enable_setcap_install" = "xno" ; then
1849         AC_MSG_RESULT(no)
1850 else
1851         if test "x$SETCAP" = "x" ; then
1852                 AC_MSG_RESULT(no. Setcap not found)
1853         elif test "x$enable_dumpcap" = "xno" ; then
1854                 AC_MSG_ERROR(Setcap install works only with dumpcap but dumpcap is disabled)
1855         else
1856                 AC_MSG_RESULT(yes)
1857         fi
1858 fi
1859
1860 AM_CONDITIONAL(SETCAP_INSTALL, test x$enable_setcap_install = xyes)
1861
1862 dnl Check if dumpcap should be installed setuid
1863 AC_ARG_ENABLE(setuid-install,
1864   AC_HELP_STRING( [--enable-setuid-install],
1865                   [install dumpcap as setuid @<:@default=no@:>@]),
1866     enable_setuid_install=$enableval,enable_setuid_install=no)
1867
1868 AC_MSG_CHECKING(whether to install dumpcap setuid)
1869 if test "x$enable_setuid_install" = "xno" ; then
1870         AC_MSG_RESULT(no)
1871 else
1872         if test "x$enable_setcap_install" = "xyes" ; then
1873                 enable_setuid_install=no
1874                 AC_MSG_RESULT(no; using setcap instead)
1875         elif test "x$enable_dumpcap" = "xno" ; then
1876                 AC_MSG_ERROR(Setuid install works only with dumpcap but dumpcap is disabled)
1877         else
1878                 AC_MSG_RESULT(yes)
1879         fi
1880 fi
1881
1882 AM_CONDITIONAL(SETUID_INSTALL, test x$enable_setuid_install = xyes)
1883 AC_CHECK_FUNCS(setresuid setresgid)
1884
1885 dnl ...but our Network Operations group is named "no"!
1886 DUMPCAP_GROUP=''
1887 AC_ARG_WITH(dumpcap-group,
1888   AC_HELP_STRING( [--with-dumpcap-group=GROUP],
1889                   [restrict dumpcap to GROUP]),
1890 [
1891   if test "x$withval" = "xyes"; then
1892       AC_MSG_ERROR([No dumpcap group specified.])
1893   elif test "x$withval" != "xno"; then
1894       if test "x$enable_dumpcap" = "xno" ; then
1895           AC_MSG_ERROR(dumpcap group install works only with dumpcap but dumpcap is disabled)
1896       fi
1897       AC_MSG_RESULT($withval)
1898       DUMPCAP_GROUP="$withval"
1899   fi
1900 ])
1901 AC_SUBST(DUMPCAP_GROUP)
1902 AM_CONDITIONAL(HAVE_DUMPCAP_GROUP, test x$DUMPCAP_GROUP != x)
1903
1904 dnl libcap (not libpcap) check
1905 LIBCAP_LIBS=''
1906 AC_MSG_CHECKING(whether to use the libcap capabilities library)
1907
1908 AC_ARG_WITH(libcap,
1909   AC_HELP_STRING( [--with-libcap@<:@=DIR@:>@],
1910                   [use libcap (located in directory DIR, if supplied) for POSIX.1e capabilities management @<:@default=yes, if present@:>@]),
1911 [
1912 if   test "x$withval" = "xno";  then
1913         want_libcap=no
1914 elif test "x$withval" = "xyes"; then
1915         want_libcap=yes
1916 elif test -d "$withval"; then
1917         want_libcap=yes
1918         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1919 fi
1920 ])
1921 if test "x$with_libcap" = "xno" ; then
1922         AC_MSG_RESULT(no)
1923 else
1924         AC_MSG_RESULT(yes)
1925         AC_WIRESHARK_LIBCAP_CHECK
1926 fi
1927 AC_SUBST(LIBCAP_LIBS)
1928
1929 dnl Checks for header files.
1930 dnl Some of these may not be needed: http://hacks.owlfolio.org/header-survey/
1931 AC_CHECK_HEADERS(direct.h dirent.h fcntl.h grp.h inttypes.h netdb.h pwd.h stdarg.h stddef.h unistd.h)
1932 AC_CHECK_HEADERS(sys/ioctl.h sys/param.h sys/socket.h sys/sockio.h sys/stat.h sys/time.h sys/types.h sys/utsname.h sys/wait.h)
1933 AC_CHECK_HEADERS(netinet/in.h)
1934 AC_CHECK_HEADERS(arpa/inet.h arpa/nameser.h)
1935
1936 dnl SSL Check
1937 SSL_LIBS=''
1938 AC_MSG_CHECKING(whether to use SSL library)
1939
1940 AC_ARG_WITH(ssl,
1941   AC_HELP_STRING( [--with-ssl@<:@=DIR@:>@],
1942                   [use SSL crypto library (located in directory DIR, if supplied) @<:@default=no@:>@]),
1943 [
1944 if test "x$withval" = "xno";  then
1945         want_ssl=no
1946 elif test "x$withval" = "xyes"; then
1947         want_ssl=yes
1948 elif test -d "$withval"; then
1949         want_ssl=yes
1950         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1951 fi
1952 ],[
1953         want_ssl=no
1954 ])
1955 if test "x$want_ssl" = "xyes"; then
1956         AC_MSG_RESULT(yes)
1957         AC_CHECK_LIB(crypto,EVP_md5,
1958             [
1959                 SSL_LIBS=-lcrypto
1960             ],
1961             [
1962                 AC_MSG_ERROR([SSL crypto library was requested, but is not available])
1963             ])
1964 else
1965         AC_MSG_RESULT(no)
1966 fi
1967 AC_SUBST(SSL_LIBS)
1968
1969 dnl kerberos check
1970 AC_MSG_CHECKING(whether to use Kerberos library)
1971
1972 AC_ARG_WITH(krb5,
1973   AC_HELP_STRING( [--with-krb5@<:@=DIR@:>@],
1974                   [use Kerberos library (located in directory DIR, if supplied) to use in Kerberos dissection @<:@default=yes@:>@]),
1975 [
1976         if test $withval = no
1977         then
1978                 want_krb5=no
1979         elif test $withval = yes
1980         then
1981                 want_krb5=yes
1982         else
1983                 want_krb5=yes
1984                 krb5_dir=$withval
1985         fi
1986 ],[
1987         #
1988         # Use Kerberos library if available, otherwise don't.
1989         #
1990         want_krb5=ifavailable
1991         krb5_dir=
1992 ])
1993 if test "x$want_krb5" = "xno" ; then
1994         AC_MSG_RESULT(no)
1995 else
1996         AC_MSG_RESULT(yes)
1997         AC_WIRESHARK_KRB5_CHECK
1998 fi
1999
2000
2001 dnl c-ares Check
2002 C_ARES_LIBS=''
2003 AC_MSG_CHECKING(whether to use the c-ares library if available)
2004
2005 AC_ARG_WITH(c-ares,
2006   AC_HELP_STRING( [--with-c-ares@<:@=DIR@:>@],
2007                   [use c-ares (located in directory DIR, if supplied) - supersedes --with-adns @<:@default=yes, if present@:>@]),
2008 [
2009 if   test "x$withval" = "xno";  then
2010         want_c_ares=no
2011 elif test "x$withval" = "xyes"; then
2012         want_c_ares=yes
2013 elif test -d "$withval"; then
2014         want_c_ares=yes
2015         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2016 fi
2017 ])
2018 if test "x$want_c_ares" = "xno" ; then
2019         AC_MSG_RESULT(no)
2020 else
2021         AC_MSG_RESULT(yes)
2022         AC_WIRESHARK_C_ARES_CHECK
2023 fi
2024 AC_SUBST(C_ARES_LIBS)
2025
2026 dnl ADNS Check
2027 ADNS_LIBS=''
2028 AC_MSG_CHECKING(whether to use the GNU ADNS library if available)
2029
2030 AC_ARG_WITH(adns,
2031   AC_HELP_STRING( [--with-adns@<:@=DIR@:>@],
2032                   [use GNU ADNS (located in directory DIR, if supplied) @<:@default=yes, if present@:>@]),
2033 [
2034 if   test "x$withval" = "xno";  then
2035         want_adns=no
2036 elif test "x$withval" = "xyes"; then
2037         want_adns=yes
2038 elif test -d "$withval"; then
2039         want_adns=yes
2040         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2041 fi
2042 ])
2043 if test "x$want_adns" = "xno" -o "x$have_good_c_ares" = "xyes" ; then
2044         AC_MSG_RESULT(no)
2045 else
2046         AC_MSG_RESULT(yes)
2047         AC_WIRESHARK_ADNS_CHECK
2048 fi
2049 AC_SUBST(ADNS_LIBS)
2050
2051 dnl GEOIP Check
2052 GEOIP_LIBS=''
2053 AC_MSG_CHECKING(whether to use the GeoIP IP address mapping library if available)
2054
2055 AC_ARG_WITH(geoip,
2056   AC_HELP_STRING( [--with-geoip@<:@=DIR@:>@],
2057                   [use GeoIP (located in directory DIR, if supplied) @<:@default=yes, if present@:>@]),
2058 [
2059 if   test "x$withval" = "xno";  then
2060         want_geoip=no
2061 elif test "x$withval" = "xyes"; then
2062         want_geoip=yes
2063 elif test -d "$withval"; then
2064         want_geoip=yes
2065         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2066 fi
2067 ])
2068 if test "x$want_geoip" = "xno"; then
2069         AC_MSG_RESULT(no)
2070 else
2071         AC_MSG_RESULT(yes)
2072         AC_WIRESHARK_GEOIP_CHECK
2073 fi
2074 AC_SUBST(GEOIP_LIBS)
2075
2076 # Warning: this Python scripting appears to be broken (does not work at all).
2077 # Running it also causes Valgrind to complain about all sorts of memory errors.
2078 # Suggestion: do not enable it unless you are working on fixing it.
2079 #
2080 # An alternative might be https://code.google.com/p/pyreshark/
2081 #
2082 dnl Python devel Check
2083 AC_MSG_CHECKING(whether to use the Python interpreter for scripting)
2084
2085 AC_ARG_WITH(broken-python,
2086     AC_HELP_STRING( [--with-broken-python@<:@=DIR@:>@],
2087                     [use the (BROKEN) Python interpreter (installed in DIR, if supplied) @<:@default=no@:>@]),
2088 [
2089         pythondir='${libdir}/wireshark/python/${VERSION}'
2090         if test "x$withval" = "xno"
2091         then
2092                 want_python=no
2093         elif test "x$withval" = "xyes"
2094         then
2095                 want_python=yes
2096         else
2097                 want_python=yes
2098                 pythondir="$withval"
2099         fi
2100 ],[
2101         # By default (user didn't explicitly enable Python), don't enable
2102         # Python support.
2103         #
2104         want_python=no
2105         #pythondir='${libdir}/wireshark/python/${VERSION}'
2106 ])
2107 if test "x$want_python" = "xno" ; then
2108         AC_MSG_RESULT(no)
2109 else
2110         AC_MSG_RESULT(yes)
2111         AC_WIRESHARK_PYTHON_CHECK
2112 fi
2113 AM_CONDITIONAL(HAVE_LIBPY, test x$want_python != xno)
2114 AC_SUBST(pythondir)
2115
2116 #
2117 # Define WS_MSVC_NORETURN appropriately for declarations of routines that
2118 # never return (just like Charlie on the MTA).
2119 #
2120 # Note that MSVC++ expects __declspec(noreturn) to precede the function
2121 # name and GCC, as far as I know, expects __attribute__((noreturn)) to
2122 # follow the function name, so we need two different flavors of
2123 # noreturn tag.
2124 #
2125 AC_DEFINE(WS_MSVC_NORETURN,, [Define as the string to precede declarations of routines that never return])
2126
2127 dnl Checks for typedefs, structures, and compiler characteristics.
2128 # AC_C_CONST
2129
2130 # Check how we can get the time zone abbreviation
2131 AC_WIRESHARK_TIMEZONE_ABBREV
2132
2133 # We need to know whether "struct stat" has an "st_flags" member
2134 # for file_user_immutable().
2135
2136 AC_WIRESHARK_STRUCT_ST_FLAGS
2137
2138 # We need to know whether "struct sockaddr" has an "sa_len" member
2139 # for get_interface_list().
2140
2141 AC_WIRESHARK_STRUCT_SA_LEN
2142
2143 # We must know our byte order
2144 AC_C_BIGENDIAN
2145
2146 # Checks whether "-traditional" is needed when using "ioctl".
2147 # XXX - do we need this?
2148 AC_PROG_GCC_TRADITIONAL
2149
2150 GETOPT_LO=""
2151 AC_CHECK_FUNC(getopt,
2152   [GETOPT_LO=""
2153    AC_DEFINE(HAVE_GETOPT, 1, [Define to 1 if you have the getopt function.])
2154   ],
2155   GETOPT_LO="wsgetopt.lo"
2156 )
2157 if test "$ac_cv_func_getopt" = no ; then
2158   GETOPT_LO="wsgetopt.lo"
2159 fi
2160 AM_CONDITIONAL(NEED_GETOPT_LO, test "x$ac_cv_func_getopt" = "xno")
2161 AC_SUBST(GETOPT_LO)
2162
2163 AC_CHECK_FUNC(strncasecmp, STRNCASECMP_LO="",
2164   STRNCASECMP_LO="strncasecmp.lo")
2165 if test "$ac_cv_func_strncasecmp" = no ; then
2166   STRNCASECMP_LO="strncasecmp.lo"
2167 fi
2168 AM_CONDITIONAL(NEED_STRNCASECMP_LO, test "x$ac_cv_func_strncasecmp" = "xno")
2169 AC_SUBST(STRNCASECMP_LO)
2170
2171 AC_CHECK_FUNCS(mkstemp mkdtemp)
2172
2173 AC_SEARCH_LIBS(inet_aton, [socket nsl], have_inet_aton=yes,
2174     have_inet_aton=no)
2175 if test "$have_inet_aton" = no; then
2176   INET_ATON_LO="inet_aton.lo"
2177   AC_DEFINE(NEED_INET_ATON_H, 1, [Define if inet/aton.h needs to be included])
2178 else
2179   INET_ATON_LO=""
2180 fi
2181 AM_CONDITIONAL(NEED_INET_ATON_LO, test "x$have_inet_aton" = "xno")
2182 AC_SUBST(INET_ATON_LO)
2183
2184 AC_SEARCH_LIBS(inet_pton, [socket nsl], [
2185   dnl check for pre-BIND82 inet_pton() bug.
2186   AC_MSG_CHECKING(for broken inet_pton)
2187   AC_TRY_RUN([#include <sys/types.h>
2188 #include <sys/socket.h>
2189 #include <netinet/in.h>
2190 #include <arpa/inet.h>
2191 int main()
2192 {
2193 #ifdef AF_INET6
2194   char buf[16];
2195   /* this should return 0 (error) */
2196   return inet_pton(AF_INET6, "0:1:2:3:4:5:6:7:", buf);
2197 #else
2198   return 1;
2199 #endif
2200 }], [AC_MSG_RESULT(ok);
2201 have_inet_pton=yes], [AC_MSG_RESULT(broken);
2202 have_inet_pton=no], [AC_MSG_RESULT(cross compiling, assume it is broken);
2203 have_inet_pton=no])],
2204 have_inet_pton=no)
2205 if test "$have_inet_pton" = no; then
2206   INET_PTON_LO="inet_pton.lo"
2207 else
2208   INET_PTON_LO=""
2209 fi
2210 AM_CONDITIONAL(NEED_INET_PTON_LO, test "x$have_inet_pton" = "xno")
2211 AC_SUBST(INET_PTON_LO)
2212
2213 AC_SEARCH_LIBS(inet_ntop, [socket nsl], [
2214   AC_MSG_CHECKING([for inet_ntop prototype])
2215   AC_TRY_COMPILE([#include <stdio.h>
2216 #include <sys/types.h>
2217 #include <sys/socket.h>
2218 #include <netinet/in.h>
2219 #include <arpa/inet.h>
2220
2221 extern const char *inet_ntop(int, const void *, char *, size_t);],, [
2222     AC_MSG_RESULT(yes)
2223     AC_DEFINE(HAVE_INET_NTOP_PROTO, 1,
2224     [Define if inet_ntop() prototype exists])], [
2225     AC_TRY_COMPILE([#include <stdio.h>
2226 #include <sys/types.h>
2227 #include <sys/socket.h>
2228 #include <netinet/in.h>
2229 #include <arpa/inet.h>
2230
2231 extern const char *inet_ntop(int, const void *, char *, socklen_t);],, [
2232       AC_MSG_RESULT(yes)
2233       AC_DEFINE(HAVE_INET_NTOP_PROTO, 1,
2234       [Define if inet_ntop() prototype exists])], [
2235       AC_MSG_RESULT(no)])])
2236   INET_NTOP_LO=""], [
2237   INET_NTOP_LO="inet_ntop.lo"
2238   AC_DEFINE(NEED_INET_V6DEFS_H, 1,
2239   [Define if inet/v6defs.h needs to be included])])
2240 AM_CONDITIONAL(NEED_INET_NTOP_LO, test "x$INET_NTOP_LO" != "x")
2241 AC_SUBST(INET_NTOP_LO)
2242
2243 AC_CHECK_FUNC(strptime, STRPTIME_LO="",
2244   [STRPTIME_LO="strptime.lo"
2245    AC_DEFINE(NEED_STRPTIME_H, 1, [Define if strptime.h needs to be included])
2246 ])
2247 if test "$ac_cv_func_strptime" = no ; then
2248   STRPTIME_LO="strptime.lo"
2249 fi
2250 AC_SUBST(STRPTIME_C)
2251 AM_CONDITIONAL(NEED_STRPTIME_LO, test "x$ac_cv_func_strptime" = "no")
2252 AC_SUBST(STRPTIME_LO)
2253
2254 AC_CHECK_FUNCS(getprotobynumber gethostbyname2)
2255 AC_CHECK_FUNCS(issetugid)
2256 AC_CHECK_FUNCS(mmap mprotect sysconf)
2257 AC_CHECK_FUNCS(strtoll)
2258
2259 dnl blank for now, but will be used in future
2260 AC_SUBST(wireshark_SUBDIRS)
2261
2262 dnl
2263 dnl check whether plugins should be enabled and, if they should be,
2264 dnl check for plugins directory - stolen from Amanda's configure.ac
2265 dnl
2266 dnl we don't wish to expand ${libdir} yet
2267 plugindir='${libdir}/wireshark/plugins/${VERSION}'
2268 AC_ARG_WITH(plugins,
2269   AC_HELP_STRING( [--with-plugins@<:@=DIR@:>@],
2270                   [support plugins (installed in DIR, if supplied) @<:@default=yes, if possible@:>@]),
2271 [
2272   if test "x$withval" = "xno"; then
2273     have_plugins=no
2274   elif test "x$have_plugins" = "xno"; then
2275       AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
2276   elif test "x$withval" != "xyes"; then
2277       plugindir="$withval"
2278   fi
2279 ])
2280 AM_CONDITIONAL(HAVE_PLUGINS, test "x$have_plugins" = "xyes")
2281 if test x$have_plugins = xyes
2282 then
2283   AC_DEFINE(HAVE_PLUGINS, 1, [Define if plugins are enabled])
2284 fi
2285 AC_SUBST(plugindir)
2286 CPPFLAGS="$CPPFLAGS '-DPLUGIN_DIR=\"\$(plugindir)\"'"
2287
2288 #
2289 # The plugin dissectors reside in ./plugins/PROTO/
2290 #
2291 PLUGIN_LIBS=""
2292 AC_SUBST(PLUGIN_LIBS)
2293
2294 #
2295 # Check if (emem) memory allocations must be 8-byte aligned.
2296 # I haven't been able to write C code that reliably makes that determination
2297 # (different versions of GCC with or without optimization give different
2298 # results) so just assume everything except (32-bit) x86 needs 8-byte
2299 # alignment (64-bit platforms either require 8-byte alignment for pointers
2300 # and 64-bit integral data types or may get better performance from that;
2301 # 64-bit x86 will get 8-byte alignment from G_MEM_ALIGN anyway.  32-bit
2302 # platforms would only require it, or get better performance from it,
2303 # for 64-bit floating-point values.).
2304 #
2305 AC_MSG_CHECKING(whether we need memory allocations to be 8-byte aligned)
2306 case $host_cpu in
2307         i386|i486|i586|i686)
2308                 AC_MSG_RESULT(no)
2309                 ;;
2310         *)
2311                 AC_MSG_RESULT(yes)
2312                 AC_DEFINE(NEED_8_BYTE_ALIGNMENT, 1, [Define if we need memory allocations to be 8-byte aligned])
2313                 ;;
2314 esac
2315
2316 dnl libtool defs
2317 #
2318 # Yes, AM_PROG_LIBTOOL is redundant with newer version(s) of some tool(s)
2319 # (autoconf?  automake?  libtool?) - with the newer version(s), it's
2320 # just an alias for AC_PROG_LIBTOOL, which is called earlier.
2321 #
2322 # With older version(s) of those tool(s), however, it's not just an
2323 # alias, and the configure scripts don't work without it.
2324 #
2325 AM_PROG_LIBTOOL
2326 AC_SUBST(LIBTOOL_DEPS)
2327
2328 AM_CONDITIONAL(ENABLE_STATIC, test x$enable_static = xyes)
2329 if test x$enable_static = xyes -a x$have_plugins = xyes
2330 then
2331   AC_DEFINE(ENABLE_STATIC, 1, [Link plugins statically into Wireshark])
2332 fi
2333 AC_SUBST(ENABLE_STATIC)
2334
2335 dnl Save the cacheable configure results to config.cache before recursing
2336 AC_CACHE_SAVE
2337
2338 sinclude(plugins/Custom.m4) dnl
2339 ifdef(_CUSTOM_AC_OUTPUT_,, define(_CUSTOM_AC_OUTPUT_, )) dnl
2340
2341 sinclude(asn1/Custom.m4) dnl
2342 ifdef(_CUSTOM_ASN1_AC_OUTPUT_,, define(_CUSTOM_ASN1_AC_OUTPUT_, )) dnl
2343
2344 AC_CONFIG_HEADERS(config.h)
2345 AC_OUTPUT(
2346   Makefile
2347   doxygen.cfg
2348   asn1/Makefile
2349   _CUSTOM_ASN1_AC_OUTPUT_
2350   asn1/acp133/Makefile
2351   asn1/acse/Makefile
2352   asn1/ansi_map/Makefile
2353   asn1/ansi_tcap/Makefile
2354   asn1/c1222/Makefile
2355   asn1/camel/Makefile
2356   asn1/cdt/Makefile
2357   asn1/charging_ase/Makefile
2358   asn1/cmip/Makefile
2359   asn1/cmp/Makefile
2360   asn1/crmf/Makefile
2361   asn1/cms/Makefile
2362   asn1/credssp/Makefile
2363   asn1/dap/Makefile
2364   asn1/disp/Makefile
2365   asn1/dop/Makefile
2366   asn1/dsp/Makefile
2367   asn1/ess/Makefile
2368   asn1/ftam/Makefile
2369   asn1/gnm/Makefile
2370   asn1/goose/Makefile
2371   asn1/gprscdr/Makefile
2372   asn1/gsm_map/Makefile
2373   asn1/h225/Makefile
2374   asn1/h235/Makefile
2375   asn1/h245/Makefile
2376   asn1/h248/Makefile
2377   asn1/h282/Makefile
2378   asn1/h283/Makefile
2379   asn1/h323/Makefile
2380   asn1/h450/Makefile
2381   asn1/h450-ros/Makefile
2382   asn1/h460/Makefile
2383   asn1/h501/Makefile
2384   asn1/HI2Operations/Makefile
2385   asn1/hnbap/Makefile
2386   asn1/idmp/Makefile
2387   asn1/inap/Makefile
2388   asn1/isdn-sup/Makefile
2389   asn1/kerberos/Makefile
2390   asn1/lcsap/Makefile
2391   asn1/ldap/Makefile
2392   asn1/logotypecertextn/Makefile
2393   asn1/lpp/Makefile
2394   asn1/lppa/Makefile
2395   asn1/lppe/Makefile
2396   asn1/lte-rrc/Makefile
2397   asn1/m3ap/Makefile
2398   asn1/mms/Makefile
2399   asn1/mpeg-audio/Makefile
2400   asn1/mpeg-pes/Makefile
2401   asn1/nbap/Makefile
2402   asn1/ns_cert_exts/Makefile
2403   asn1/ocsp/Makefile
2404   asn1/p1/Makefile
2405   asn1/p22/Makefile
2406   asn1/p7/Makefile
2407   asn1/p772/Makefile
2408   asn1/pcap/Makefile
2409   asn1/pkcs1/Makefile
2410   asn1/pkcs12/Makefile
2411   asn1/pkinit/Makefile
2412   asn1/pkixac/Makefile
2413   asn1/pkix1explicit/Makefile
2414   asn1/pkix1implicit/Makefile
2415   asn1/pkixproxy/Makefile
2416   asn1/pkixqualified/Makefile
2417   asn1/pkixtsp/Makefile
2418   asn1/pres/Makefile
2419   asn1/q932/Makefile
2420   asn1/q932-ros/Makefile
2421   asn1/qsig/Makefile
2422   asn1/ranap/Makefile
2423   asn1/rnsap/Makefile
2424   asn1/ros/Makefile
2425   asn1/rrc/Makefile
2426   asn1/rrlp/Makefile
2427   asn1/rtse/Makefile
2428   asn1/rua/Makefile
2429   asn1/s1ap/Makefile
2430   asn1/sabp/Makefile
2431   asn1/sbc-ap/Makefile
2432   asn1/smrse/Makefile
2433   asn1/snmp/Makefile
2434   asn1/spnego/Makefile
2435   asn1/sv/Makefile
2436   asn1/t124/Makefile
2437   asn1/t125/Makefile
2438   asn1/t38/Makefile
2439   asn1/tcap/Makefile
2440   asn1/tetra/Makefile
2441   asn1/ulp/Makefile
2442   asn1/wlancertextn/Makefile
2443   asn1/x2ap/Makefile
2444   asn1/x509af/Makefile
2445   asn1/x509ce/Makefile
2446   asn1/x509if/Makefile
2447   asn1/x509sat/Makefile
2448   asn1/x721/Makefile
2449   doc/Makefile
2450   docbook/Makefile
2451   epan/Makefile
2452   epan/crypt/Makefile
2453   epan/doxygen.cfg
2454   epan/dfilter/Makefile
2455   epan/dissectors/Makefile
2456   epan/dissectors/dcerpc/Makefile
2457   epan/dissectors/pidl/Makefile
2458   epan/ftypes/Makefile
2459   epan/wmem/Makefile
2460   epan/wslua/Makefile
2461   epan/wspython/Makefile
2462   codecs/Makefile
2463   ui/Makefile
2464   ui/doxygen.cfg
2465   ui/gtk/Makefile
2466   ui/gtk/doxygen.cfg
2467   ui/cli/Makefile
2468   ui/qt/Makefile
2469   ui/qt/doxygen.cfg
2470   help/Makefile
2471   packaging/Makefile
2472   packaging/macosx/Info.plist
2473   packaging/macosx/Makefile
2474   packaging/macosx/osx-dmg.sh
2475   packaging/nsis/Makefile
2476   packaging/rpm/Makefile
2477   packaging/rpm/SPECS/Makefile
2478   packaging/rpm/SPECS/wireshark.spec
2479   packaging/svr4/Makefile
2480   packaging/svr4/checkinstall
2481   packaging/svr4/pkginfo
2482   plugins/Makefile
2483   plugins/asn1/Makefile
2484   plugins/docsis/Makefile
2485   plugins/ethercat/Makefile
2486   plugins/gryphon/Makefile
2487   plugins/irda/Makefile
2488   plugins/m2m/Makefile
2489   plugins/mate/Makefile
2490   plugins/opcua/Makefile
2491   plugins/profinet/Makefile
2492   plugins/stats_tree/Makefile
2493   plugins/unistim/Makefile
2494   plugins/wimax/Makefile
2495   plugins/wimaxasncp/Makefile
2496   plugins/wimaxmacphy/Makefile
2497   tools/Makefile
2498   tools/lemon/Makefile
2499   wiretap/Makefile
2500   wsutil/Makefile
2501   _CUSTOM_AC_OUTPUT_
2502   ,)
2503 dnl AC_CONFIG_FILES([tools/setuid-root.pl], [chmod +x tools/setuid-root.pl])
2504
2505
2506 # Pretty messages
2507
2508 if test "x$have_qt" = "xyes"; then
2509         gui_lib_message=" (with Qt)"
2510 else
2511         if test "x$have_gtk" = "xyes"; then
2512                 if test "x$with_gtk3" = "xyes"; then
2513                         gui_lib_message=" (with GTK+ 3"
2514                 else
2515                         gui_lib_message=" (with GTK+ 2"
2516                 fi
2517                 if test "x$have_ige_mac" = "xyes"; then
2518                         gui_lib_message="$gui_lib_message and Mac OS X integration)"
2519                 else
2520                         gui_lib_message="$gui_lib_message)"
2521                 fi
2522         fi
2523 fi
2524
2525 if test "x$enable_setcap_install" = "xyes" ; then
2526         setcap_message="yes"
2527 else
2528         setcap_message="no"
2529 fi
2530
2531 if test "x$enable_setuid_install" = "xyes" ; then
2532         setuid_message="yes"
2533 else
2534         setuid_message="no"
2535 fi
2536
2537 if test "x$DUMPCAP_GROUP" = "x" ; then
2538         dumpcap_group_message="(none)"
2539 else
2540         dumpcap_group_message="$DUMPCAP_GROUP"
2541 fi
2542
2543 if test "x$want_zlib" = "xno" ; then
2544         zlib_message="no"
2545 else
2546         zlib_message="yes"
2547 fi
2548
2549 if test "x$want_lua" = "xyes" ; then
2550         lua_message="yes"
2551 else
2552         lua_message="no"
2553 fi
2554
2555 if test "x$want_python" = "xno"; then
2556         python_message="no"
2557 else
2558         python_message="yes"
2559 fi
2560
2561 if test "x$want_portaudio" = "xyes" ; then
2562         portaudio_message="yes"
2563 else
2564         portaudio_message="no"
2565 fi
2566
2567 if test "x$want_ssl" = "xno" ; then
2568         ssl_message="no"
2569 else
2570         ssl_message="yes"
2571 fi
2572
2573 if test "x$want_krb5" = "xno" ; then
2574         krb5_message="no"
2575 else
2576         krb5_message="yes ($ac_krb5_version)"
2577 fi
2578
2579 if test "x$have_good_c_ares" = "xyes" ; then
2580         c_ares_message="yes"
2581 else
2582         c_ares_message="no"
2583 fi
2584
2585 if test "x$have_good_adns" = "xyes" ; then
2586         adns_message="yes"
2587 else
2588         if test "x$have_good_c_ares" = "xyes" ; then
2589                 adns_message="no (using c-ares instead)"
2590         else
2591                 adns_message="no"
2592         fi
2593 fi
2594
2595 if test "x$have_good_libcap" = "xyes" ; then
2596         libcap_message="yes"
2597 else
2598         libcap_message="no"
2599 fi
2600
2601 if test "x$have_good_geoip" = "xyes" ; then
2602         geoip_message="yes"
2603 else
2604         geoip_message="no"
2605 fi
2606
2607 echo ""
2608 echo "The Wireshark package has been configured with the following options."
2609 echo "                    Build wireshark : $enable_wireshark""$gui_lib_message"
2610 echo "                       Build tshark : $enable_tshark"
2611 echo "                     Build capinfos : $enable_capinfos"
2612 echo "                      Build editcap : $enable_editcap"
2613 echo "                      Build dumpcap : $enable_dumpcap"
2614 echo "                     Build mergecap : $enable_mergecap"
2615 echo "                   Build reordercap : $enable_reordercap"
2616 echo "                    Build text2pcap : $enable_text2pcap"
2617 echo "                      Build randpkt : $enable_randpkt"
2618 echo "                       Build dftest : $enable_dftest"
2619 echo "                     Build rawshark : $enable_rawshark"
2620 echo ""
2621 echo "   Save files as pcap-ng by default : $enable_pcap_ng_default"
2622 echo "  Install dumpcap with capabilities : $setcap_message"
2623 echo "             Install dumpcap setuid : $setuid_message"
2624 echo "                  Use dumpcap group : $dumpcap_group_message"
2625 echo "                        Use plugins : $have_plugins"
2626 echo "                    Use Lua library : $lua_message"
2627 echo "                 Use Python binding : $python_message"
2628 echo "                   Build rtp_player : $portaudio_message"
2629 echo "             Build profile binaries : $enable_profile_build"
2630 echo "                   Use pcap library : $want_pcap"
2631 echo "                   Use zlib library : $zlib_message"
2632 echo "               Use kerberos library : $krb5_message"
2633 echo "                 Use c-ares library : $c_ares_message"
2634 echo "               Use GNU ADNS library : $adns_message"
2635 echo "                Use SMI MIB library : $libsmi_message"
2636 echo "             Use GNU crypto library : $gcrypt_message"
2637 echo "             Use SSL crypto library : $ssl_message"
2638 echo "           Use IPv6 name resolution : $enable_ipv6"
2639 echo "                 Use gnutls library : $tls_message"
2640 echo "     Use POSIX capabilities library : $libcap_message"
2641 echo "                  Use GeoIP library : $geoip_message"
2642 echo "                     Use nl library : $libnl_message"