Allow the Gtk+ and Qt versions to be built simultaneously (with autotools).
[metze/wireshark/wip.git] / configure.ac
1 # $Id$
2 #
3
4 m4_define([version_major], [1])
5 m4_define([version_minor], [11])
6 m4_define([version_micro], [0])
7 m4_define([version_micro_extra], version_micro)
8 m4_append([version_micro_extra], [])
9
10 AC_INIT(wireshark, [version_major.version_minor.version_micro_extra], http://bugs.wireshark.org/, , http://www.wireshark.org/)
11
12 # Minimum autoconf version we require.
13 AC_PREREQ(2.60)
14 # Variable expansion doesn't work in AC_PREREQ()
15 AC_MIN_VERSION=2.60
16 AC_SUBST(AC_MIN_VERSION)
17
18 dnl Check for CPU / vendor / OS
19 dnl The user is encouraged to use either `AC_CANONICAL_BUILD', or
20 dnl `AC_CANONICAL_HOST', or `AC_CANONICAL_TARGET', depending on the
21 dnl needs.  Using `AC_CANONICAL_TARGET' is enough to run the two other
22 dnl macros.
23 dnl
24 dnl As nothing in the Wireshark is itself a build tool (we are not,
25 dnl for example, a compiler that generates machine code), we probably
26 dnl don't need AC_CANONICAL_TARGET, so, in theory, we should be able
27 dnl to use AC_CANONICAL_BUILD and AC_CANONICAL_HOST - or perhaps just
28 dnl AC_CANONICAL_HOST - instead.  Note that we do have tools, such as
29 dnl lemon, that need to be built for the build machine, not for the
30 dnl host machine, so we might need both.
31 dnl
32 dnl This has to be done *after* AC_INIT, otherwise autogen.sh fails.
33
34 dnl AC_CANONICAL_BUILD
35 dnl AC_CANONICAL_HOST
36 AC_CANONICAL_TARGET
37
38 AM_INIT_AUTOMAKE([1.9 tar-ustar dist-bzip2 no-dist-gzip])
39
40 # Make Wireshark's version available in config.h
41 AC_DEFINE(VERSION_MAJOR, version_major, [Wireshark's major version])
42 AC_DEFINE(VERSION_MINOR, version_minor, [Wireshark's minor version])
43 AC_DEFINE(VERSION_MICRO, version_micro, [Wireshark's micro version])
44
45 AM_DISABLE_STATIC
46
47 #
48 # Checks for programs used in the main build process.
49 #
50 AC_PROG_CC
51 AM_PROG_CC_C_O
52 AC_PROG_CXX
53 AC_PROG_CPP
54 dnl Work around libtool bug (fixed in the version 1.5a?)
55 AC_DEFUN([AC_PROVIDE_AC_LIBTOOL_DLOPEN], )
56 AC_LIBTOOL_DLOPEN
57 AC_PROG_LIBTOOL
58 AC_PATH_PROG(PERL, perl)
59
60 # Check for Python.
61 AC_PATH_PROG(PYTHON, python)
62 if test ! -z "$PYTHON"; then
63         #
64         # OK, we found Python; is it Python 2.x?
65         # Note: we don't use named components for sys.version_info to get
66         # the major version number, as named components for version_info
67         # were apparently introduced in Python 2.7.
68         #
69         AC_MSG_CHECKING([whether $PYTHON is Python 2])
70         python_major_version=`$PYTHON -c 'import sys; print sys.version_info[[0]]'`
71         if test "$python_major_version" = 2; then
72                 AC_MSG_RESULT([yes])
73         else
74                 #
75                 # It's not 2.x.
76                 #
77                 AC_MSG_RESULT([no])
78
79                 #
80                 # Try looking for python2; if we find it, we assume it's
81                 # Python 2
82                 #
83                 AC_PATH_PROG(PYTHON, python2)
84         fi
85 fi
86
87 #
88 # XXX - should autogen.sh check for YACC/Bison and Flex?  A user building
89 # from a distribution tarball shouldn't have to have YACC/Bison or Flex,
90 # as the tarball should contain the results of running YACC/Bison on .y
91 # files and running Flex on .l files, but a user building from SVN
92 # will have to run YACC/Bison and Flex to process those files.
93 #
94 # On the other hand, what about users who use a distribution tarball to
95 # do development?  They *shouldn't* - that's what the SVN repository is
96 # for - but they might.  They'd get errors if they modify a .y or .l
97 # file and try to do a build - but the error should tell them that they
98 # need to get YACC/Bison and/or Flex.
99 #
100 # Then again, getting them shouldn't be too big of a burden.
101 #
102 # XXX - is the same true of pod2man and pod2html, or are they needed
103 # even when building from a distribution tarball?
104 #
105 #
106 AC_PROG_YACC
107 AC_PATH_PROG(YACCDUMMY, $YACC)
108 if test "x$YACCDUMMY" = x
109 then
110         AC_MSG_ERROR(I couldn't find yacc (or bison or ...); make sure it's installed and in your path)
111 fi
112 AM_PROG_LEX
113 AC_PATH_PROG(LEX, flex)
114 if test "x$LEX" = x
115 then
116         AC_MSG_ERROR(I couldn't find flex; make sure it's installed and in your path)
117 fi
118 AC_PATH_PROG(POD2MAN, pod2man)
119 if test "x$POD2MAN" = x
120 then
121         #
122         # The alternative is not to build the man pages....
123         #
124         AC_MSG_ERROR(I couldn't find pod2man; make sure it's installed and in your path)
125 fi
126 AC_PATH_PROG(POD2HTML, pod2html)
127 if test "x$POD2HTML" = x
128 then
129         #
130         # The alternative is not to build the HTML man pages....
131         #
132         AC_MSG_ERROR(I couldn't find pod2html; make sure it's installed and in your path)
133 fi
134
135 #
136 # Checks for programs used by Wireshark/TShark/etc.
137 #
138
139 #
140 # XXX - this looks for various HTML viewers on the host, not the target;
141 # we really want to know what's available on the target, for cross-builds.
142 # That would probably require us to, at run time, look for xdg-open and,
143 # if we don't find it, look for mozilla, htmlview, etc.
144 #
145 AC_PATH_PROG(HTML_VIEWER, xdg-open)
146 if test "x$HTML_VIEWER" != x
147 then
148         #
149         # XXX - the HTML_VIEWER shell variable is the full path of xdg-open.
150         # Define some variable to be that, so we just run that?
151         #
152         AC_DEFINE(HAVE_XDG_OPEN, 1, [Define if we have xdg-open])
153
154         #
155         # XXX - we have to define HTML_VIEWER for the prefs.c code that
156         # sets the default value of the Web browser preference, even
157         # though that preference won't be offered.
158         #
159         AC_DEFINE_UNQUOTED(HTML_VIEWER, "xdg-open", [HTML viewer, e.g. mozilla])
160 else
161         AC_PATH_PROG(HTML_VIEWER, htmlview)
162         if test "x$HTML_VIEWER" = x
163         then
164                 AC_DEFINE_UNQUOTED(HTML_VIEWER, "mozilla", [HTML viewer, e.g. mozilla])
165         else
166                 AC_DEFINE_UNQUOTED(HTML_VIEWER, "htmlview", [HTML viewer, e.g. mozilla])
167         fi
168 fi
169
170 #
171 # Set "ac_supports_gcc_flags" if the compiler is known to support GCC-style
172 # flags such as -pedantic, -W warning flags and -f feature flags.  Currently,
173 # we assume GCC and clang do; other compilers should be added here.
174 #
175 # This is done to avoid getting tripped up by compilers that support
176 # those flags but give them a different meaning.
177 #
178 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
179         ac_supports_gcc_flags=yes
180 fi
181
182 #
183 # Set "ac_supports_W_linker_passthrough" if the compiler is known to
184 # support "-Wl,{options}" to pass options through to the linker.
185 # Currently, we assume GCC, xlc, and clang do; other compilers should
186 # be added here.
187 #
188 if test "x$GCC" = "xyes" -o "x$CC" = "xxlc" -o "x$CC" = "xclang" ; then
189         ac_supports_W_linker_passthrough=yes
190 fi
191
192 #
193 # Set "ac_supports_attribute_unused" if the compiler is known to
194 # support "__attribute__(unused)".
195 # Currently, we assume GCC and clang do; other compilers should
196 # be added here.
197 #
198 # XXX - do this with a compiler test?
199 #
200 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
201         ac_supports_W_linker_passthrough=yes
202 fi
203
204 if test "x$CC_FOR_BUILD" = x
205 then
206        CC_FOR_BUILD=$CC
207 fi
208 AC_SUBST(CC_FOR_BUILD)
209 AC_SUBST(CFLAGS_FOR_BUILD)
210
211 # Check for doxygen
212 AC_PATH_PROG(DOXYGEN, doxygen)
213 AC_CHECK_PROG(HAVE_DOXYGEN, doxygen, "yes", "no")
214 AM_CONDITIONAL(HAVE_DOXYGEN, test x$HAVE_DOXYGEN = xyes)
215
216 #
217 # Check for pkg-config and set PKG_CONFIG accordingly.
218 #
219 # This is referenced via AC_REQUIRE([PKG_PROG_PKG_CONFIG] in some macros
220 # like PKG_CHECK_MODULES. If the first call to such a macro is under an
221 # "if" statement, it's safer to call PKG_PROG_PKG_CONFIG directly, see
222 # the comments in acolocal.m4
223 #
224 PKG_PROG_PKG_CONFIG
225
226 #
227 # Try to arrange for large file support.
228 #
229 AC_SYS_LARGEFILE
230
231 # GnuTLS
232 # Version 3.0 switched from LGPLv2.1+ to LGPLv3+, then switched back to
233 # LGPLv2.1+ in version 3.1.10
234 tls_message="no"
235 AC_ARG_WITH([gnutls],
236   AC_HELP_STRING( [--with-gnutls=@<:@yes/no@:>@],
237                   [use GnuTLS library @<:@default=yes@:>@]),
238   with_gnutls="$withval", with_gnutls="yes")
239 if test "x$with_gnutls" = "xyes"; then
240   have_license_compatible_gnutls="no"
241   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.1.10 ],
242     [ have_license_compatible_gnutls="yes" ], [ echo "GnuTLS >= 3.1.10 not found " ]
243   )
244
245   if test "x$have_license_compatible_gnutls" != "xyes"; then
246     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 1.2.0 gnutls < 3],
247       [ have_license_compatible_gnutls="yes" ] , [ echo "GnuTLS >= 1.2.0, < 3.0 not found " ]
248     )
249   fi
250
251   if test "x$have_license_compatible_gnutls" = "xyes"; then
252     echo "GnuTLS found, enabling SSL decryption"
253     AC_DEFINE(HAVE_LIBGNUTLS, 1, [Define to use GnuTLS library])
254     tls_message="yes"
255   else
256     echo "GnuTLS with compatible license not found, disabling SSL decryption"
257     tls_message="no"
258   fi
259 fi
260
261 # libgrypt
262 gcrypt_message="no"
263 AC_ARG_WITH([gcrypt],
264   AC_HELP_STRING( [--with-gcrypt=@<:@yes/no@:>@],
265                   [use gcrypt library @<:@default=yes@:>@]),
266   with_gcrypt="$withval", with_gcrypt="yes")
267 if test "x$with_gcrypt" = "xyes"; then
268   AM_PATH_LIBGCRYPT(1.1.92,
269         [
270                 echo "libgcrypt found, enabling ipsec decryption"
271                 AC_DEFINE(HAVE_LIBGCRYPT, 1, [Define to use libgcrypt])
272                 gcrypt_message="yes"
273         ]
274         , [
275                 if test x$libgcrypt_config_prefix != x ; then
276                         AC_MSG_ERROR([[libgcrypt not found; install libgcrypt-devel package for your system]])
277                 else
278                         echo "libgcrypt not found, disabling ipsec decryption"
279                         gcrypt_message="no"
280                 fi
281         ]
282   )
283 fi
284
285 AC_ARG_WITH(libnl,
286   AC_HELP_STRING([--with-libnl@<:@=VERSION@:>@],
287                  [use libnl (force version VERSION, if supplied) @<:@default: yes, if available@:>@]),
288 [
289         if test "x$withval" = "xno"
290         then
291                 want_libnl=no
292         elif test "x$withval" = "xyes"
293         then
294                 want_libnl=yes
295                 libnl_version=any
296         elif test "x$withval" = "x1"
297         then
298                 want_libnl=yes
299                 libnl_version=1
300         elif test "x$withval" = "x2"
301         then
302                 want_libnl=yes
303                 libnl_version=2
304         elif test "x$withval" = "x3"
305         then
306                 want_libnl=yes
307                 libnl_version=3
308         else
309                 AC_MSG_ERROR(["$withval" is not a valid argument to --with-libnl])
310         fi
311 ],[
312         #
313         # Use libnl if it's present, otherwise don't.
314         #
315         want_libnl=ifavailable
316         libnl_version=any
317 ])
318 #
319 # Libnl is Linux-specific.
320 #
321 libnl_message="no"
322 case "$host_os" in
323 linux*)
324         AC_MSG_CHECKING(whether to use libnl for various network interface purposes)
325
326         if test x$want_libnl = "xno"; then
327                 AC_MSG_RESULT(no)
328         else
329                 AC_MSG_RESULT(yes)
330                 #
331                 # Test for specific libnl versions only if no version
332                 # was specified by the user or if the version in question
333                 # was requested by the user.
334                 #
335                 if test x$libnl_version = "xany" -o x$libnl_version = "x3"; then
336                         PKG_CHECK_MODULES(LIBNL3, [libnl-route-3.0 >= 3.0 libnl-genl-3.0] >= 3.0, [have_libnl3=yes], [have_libnl3=no])
337                 fi
338                 if test x$libnl_version = "xany" -o x$libnl_version = "x2"; then
339                         PKG_CHECK_MODULES(LIBNL2, libnl-2.0 >= 2.0, [have_libnl2=yes], [have_libnl2=no])
340                 fi
341                 if test x$libnl_version = "xany" -o x$libnl_version = "x1"; then
342                         PKG_CHECK_MODULES(LIBNL1, libnl-1 >= 1.0, [have_libnl1=yes], [have_libnl1=no])
343                 fi
344                 if (test "${have_libnl3}" = "yes"); then
345                         CFLAGS="$CFLAGS $LIBNL3_CFLAGS"
346                         LIBS="$LIBS $LIBNL3_LIBS"
347                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
348                         AC_DEFINE(HAVE_LIBNL3, 1, [libnl version 3])
349                         libnl_message="yes (v3)"
350                         enable_airpcap=no
351                 elif (test "${have_libnl2}" = "yes"); then
352                         CFLAGS="$CFLAGS $LIBNL2_CFLAGS"
353                         LIBS="$LIBS $LIBNL2_LIBS"
354                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
355                         AC_DEFINE(HAVE_LIBNL2, 1, [libnl version 2])
356                         libnl_message="yes (v2)"
357                         enable_airpcap=no
358                 elif (test "${have_libnl1}" = "yes"); then
359                         CFLAGS="$CFLAGS $LIBNL1_CFLAGS"
360                         LIBS="$LIBS $LIBNL1_LIBS"
361                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
362                         AC_DEFINE(HAVE_LIBNL1, 1, [libnl version 1])
363                         libnl_message="yes (v1)"
364                         enable_airpcap=no
365                 else
366                         if test x$want_libnl = "xyes"; then
367                                 case "$libnl_version" in
368
369                                 any)
370                                         AC_MSG_ERROR("I couldn't find libnl even though you manually enabled it.")
371                                         ;;
372
373                                 *)
374                                         AC_MSG_ERROR("I couldn't find libnl version $libnl_version even though you manually enabled it.")
375                                         ;;
376                                 esac
377                         fi
378                 fi
379         fi
380
381         AC_MSG_CHECKING([if nl80211.h is new enough])
382           AC_TRY_COMPILE([#include <linux/nl80211.h>],
383             [int x = NL80211_FREQUENCY_ATTR_MAX_TX_POWER;
384                 x = NL80211_ATTR_SUPPORTED_IFTYPES;
385                 x = NL80211_ATTR_SUPPORTED_COMMANDS;
386                 x = NL80211_ATTR_WIPHY_FREQ;
387                 x = NL80211_CHAN_NO_HT;],
388             [AC_MSG_RESULT(yes) AC_DEFINE(HAVE_NL80211, 1, [nl80211.h is new enough])],
389             [AC_MSG_RESULT(no)])
390
391         AC_MSG_CHECKING([for NL80211_SET_CHANNEL])
392           AC_TRY_COMPILE([#include <linux/nl80211.h>],
393             [enum nl80211_commands x = NL80211_CMD_SET_CHANNEL;],
394             [AC_MSG_RESULT(yes) AC_DEFINE(HAVE_NL80211_CMD_SET_CHANNEL, 1, [SET_CHANNEL is supported])],
395             [AC_MSG_RESULT(no)])
396         ;;
397
398 *)
399         if test x$want_libnl != "xno" -a x$want_libnl != "xifavailable"; then
400                 AC_MSG_WARN([libnl is Linux-specific, ignoring --with-libnl])
401         fi
402 esac
403
404 AC_ARG_WITH([qt],
405   AC_HELP_STRING( [--with-qt=@<:@yes/no@:>@],
406                   [use Qt @<:@default=no@:>@]),
407   with_qt="$withval", with_qt="no")
408
409 AC_ARG_WITH([gtk2],
410   AC_HELP_STRING( [--with-gtk2=@<:@yes/no@:>@],
411                   [use GTK+ 2.0 @<:@default=yes@:>@]),
412   with_gtk2="$withval", with_gtk2="no")
413
414 AC_ARG_WITH([gtk3],
415   AC_HELP_STRING( [--with-gtk3=@<:@yes/no@:>@],
416                   [use GTK+ 3.0 instead of 2.0 @<:@default=no@:>@]),
417   with_gtk3="$withval", with_gtk3="no")
418
419 # libsmi
420 # FIXME: currently the path argument to with-libsmi is being ignored
421 AX_LIBSMI
422
423 #
424 # Check for programs used when building DocBook documentation.
425 #
426
427 # Check for a2x (convert asciidoc to another format)
428 AC_PATH_PROG(A2X, a2x)
429 AC_CHECK_PROG(HAVE_A2X, a2x, "yes", "no")
430 AM_CONDITIONAL(HAVE_A2X, test x$HAVE_A2X = xyes)
431
432 # Want to control a tape drive? Use mt. Want to convert HTML to text?
433 # Uhhhhh... elinks? lynx? w3m? pandoc? html2text?
434 AC_PATH_PROG(ELINKS, elinks)
435 AC_CHECK_PROG(HAVE_ELINKS, elinks, "yes", "no")
436 AM_CONDITIONAL(HAVE_ELINKS, test x$HAVE_ELINKS = xyes)
437
438 # Check for fop (translate .fo to e.g. pdf)
439 AC_PATH_PROG(FOP, fop)
440 AC_CHECK_PROG(HAVE_FOP, fop, "yes", "no")
441 AM_CONDITIONAL(HAVE_FOP, test x$HAVE_FOP = xyes)
442
443 # Check for lynx (html -> text)
444 AC_PATH_PROG(LYNX, lynx)
445 AC_CHECK_PROG(HAVE_LYNX, lynx, "yes", "no")
446 AM_CONDITIONAL(HAVE_LYNX, test x$HAVE_LYNX = xyes)
447
448 # Check for w3m (html -> text)
449 AC_PATH_PROG(W3M, w3m)
450 AC_CHECK_PROG(HAVE_W3M, w3m, "yes", "no")
451 AM_CONDITIONAL(HAVE_W3M, test x$HAVE_W3M = xyes)
452
453 # Check for xmllint
454 AC_PATH_PROG(XMLLINT, xmllint)
455 AC_CHECK_PROG(HAVE_XMLLINT, xmllint, "yes", "no")
456 AM_CONDITIONAL(HAVE_XMLLINT, test x$HAVE_XMLLINT = xyes)
457
458 # Check for xsltproc
459 AC_PATH_PROG(XSLTPROC, xsltproc)
460 AC_CHECK_PROG(HAVE_XSLTPROC, xsltproc, "yes", "no")
461 AM_CONDITIONAL(HAVE_XSLTPROC, test x$HAVE_XSLTPROC = xyes)
462
463
464 # Check for packaging utilities
465 # For now, we check to see if the various packaging utilites are in our
466 # path.  I'm too lazy to write code to go hunt for them.  -  Gerald
467
468 #
469 # Source packages.
470 # (Lets you install the desktop files.)
471 #
472 AC_PATH_PROG(DESKTOP_FILE_INSTALL, desktop-file-install)
473
474 # SVR4/Solaris
475 AC_CHECK_PROG(HAVE_PKGPROTO, pkgproto, "yes", "no")
476 AC_CHECK_PROG(HAVE_PKGMK, pkgmk, "yes", "no")
477 AC_CHECK_PROG(HAVE_PKGTRANS, pkgtrans, "yes", "no")
478
479 if test x$HAVE_PKGPROTO = xyes -a x$HAVE_PKGMK = xyes \
480      -a x$HAVE_PKGTRANS = xyes ; then
481   HAVE_SVR4_PACKAGING=yes
482 else
483   HAVE_SVR4_PACKAGING=no
484 fi
485 AC_SUBST(HAVE_SVR4_PACKAGING)
486
487 # RPM
488 AC_WIRESHARK_RPM_CHECK
489 AC_SUBST(HAVE_RPM)
490
491 # Debian
492 AC_CHECK_PROG(HAVE_DPKG_BUILDPACKAGE, dpkg-buildpackage, "yes", "no")
493
494 # Mac OS X
495 AC_CHECK_PROG(HAVE_XCODEBUILD, xcodebuild, "yes", "no")
496 AC_CHECK_PROG(HAVE_HDIUTIL, hdiutil, "yes", "no")
497 AC_CHECK_PROG(HAVE_BLESS, bless, "yes", "no")
498
499 if test x$HAVE_XCODEBUILD = xyes -a x$HAVE_HDIUTIL = xyes \
500      -a x$HAVE_BLESS = xyes ; then
501   HAVE_OSX_PACKAGING=yes
502 else
503   HAVE_OSX_PACKAGING=no
504 fi
505 AC_SUBST(HAVE_OSX_PACKAGING)
506
507 #
508 # Try to add some additional gcc checks to CFLAGS
509 #
510 AC_ARG_ENABLE(extra-gcc-checks,
511   AC_HELP_STRING( [--enable-extra-gcc-checks],
512                   [do additional -W checks in GCC @<:@default=no@:>@]),
513 [
514         wireshark_extra_gcc_flags=$enableval
515         if test $enableval != no
516         then
517                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-pedantic)
518                 #
519                 # Various code blocks this one.
520                 #
521                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Woverflow)
522                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-fstrict-overflow -Wstrict-overflow=4)
523                 #
524                 # Some memset() calls to clear out structures
525                 # on the stack are getting flagged as "will never
526                 # be executed" by this, at least by Apple's
527                 # i686-apple-darwin11-llvm-gcc-4.2 (GCC) 4.2.1 (Based on
528                 # Apple Inc. build 5658) (LLVM build 2336.11.00), for
529                 # some unknown reason.
530                 #
531                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wunreachable-code)
532                 #
533                 # Due to various places where APIs we don't control
534                 # require us to cast away constness, we can probably
535                 # never enable these ones with -Werror.
536                 #
537                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wcast-qual)
538                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wbad-function-cast, C)
539                 #
540                 # Some generated ASN.1 dissectors block this one;
541                 # multiple function declarations for the same
542                 # function are being generated.
543                 #
544                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wredundant-decls)
545                 #
546                 # Some loops are safe, but it's hard to convince the
547                 # compiler of that.
548                 #
549                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wunsafe-loop-optimizations)
550                 #
551                 # All the registration functions block these for now.
552                 #
553                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wmissing-prototypes)
554                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wmissing-declarations)
555         fi
556 ],)
557 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wall -W) # -W is now known as -Wextra
558 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wextra) # -W is now known as -Wextra
559 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wdeclaration-after-statement, C)
560 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wendif-labels)
561 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wpointer-arith)
562 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-pointer-sign, C)
563 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Warray-bounds)
564 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wcast-align)
565 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wformat-security)
566 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wold-style-definition, C)
567 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wshorten-64-to-32)
568 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wstrict-prototypes, C)
569 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wjump-misses-init, C)
570 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wvla)
571 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Waddress)
572 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Warray-bounds)
573 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wattributes)
574 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wdiv-by-zero)
575 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wignored-qualifiers)
576 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wpragmas)
577 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-overlength-strings)
578 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wwrite-strings)
579 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-long-long)
580 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wc++-compat, C)
581
582 #
583 # XXX - OK for C++?
584 #
585 # Make sure -Wshadow doesn't complain about variables in function and
586 # function pointer declarations shadowing other variables; if not, don't
587 # turn it on, as some versions of GCC (including the one in at least
588 # some Xcode versions that came with Mac OS X 10.5) complain about
589 # that.
590 #
591 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wshadow, C,
592   [
593 extern int bar(int a);
594 extern int foo(int);
595
596 int
597 foo(int a)
598 {
599         int (*fptr)(int a) = bar;
600
601         return fptr(a) * 2;
602 }
603   ],
604   [warns about variables in function declarations shadowing other variables])
605
606 # Unfortunately some versions of gcc generate logical-op warnings when strchr()
607 # is given a constant string.
608 # gcc versions 4.3.2 and 4.4.5 are known to have the problem.
609 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wlogical-op, C,
610   [
611 #include <string.h>
612
613 int foo(const char *, int);
614 int bar(void);
615
616 int
617 foo(const char *sep, int c)
618 {
619         if (strchr (sep, c) != NULL)
620                 return 1;
621         else
622                 return 0;
623 }
624
625 int
626 bar(void)
627 {
628         return foo("<", 'a');
629 }
630   ],
631   [generates warnings from strchr()])
632
633
634 ## AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-error=unused-but-set-variable)
635
636 #
637 # Use the faster pre gcc 4.5 floating point precision if available;
638 # clang doesn't error out on -f options that it doesn't know about,
639 # it just warns and ignores them, so this check doesn't cause us
640 # to omit -fexcess-precision=fast, which produces a pile of
641 # annoying warnings.
642 #
643 if test "x$CC" != "xclang" ; then
644   AC_WIRESHARK_GCC_CFLAGS_CHECK(-fexcess-precision=fast)
645 fi
646
647 CFLAGS_before_fvhidden=$CFLAGS
648 AC_WIRESHARK_GCC_CFLAGS_CHECK(-fvisibility=hidden)
649 if test "x$CLFAGS" = "x$CFLAGS_before_fvhidden"
650 then
651         # TODO add other ways of hiding symbols
652         AC_MSG_WARN(Compiler will export all symbols from shared libraries)
653 fi
654
655 AC_WIRESHARK_LDFLAGS_CHECK([-Wl,--as-needed])
656 ###AC_WIRESHARK_LDFLAGS_CHECK([-Wl,-M])
657 ###AC_WIRESHARK_LDFLAGS_CHECK([-Wl,--cref])
658 # AC_WIRESHARK_LDFLAGS_CHECK([-flto])
659 # AC_WIRESHARK_LDFLAGS_CHECK([-fwhopr])
660 # AC_WIRESHARK_LDFLAGS_CHECK([-fwhole-program])
661
662 #
663 # Put -fPIE in PIE_CFLAGS and -pie in PIE_LDFLAGS if we can use them,
664 # so that we can build dumpcap PIE - it may run with elevated
665 # privileges, and using PIE means the OS can run it at random locations
666 # in the address space to make attacks more difficult.
667 #
668 CFLAGS_before_pie=$CFLAGS
669 AC_WIRESHARK_GCC_CFLAGS_CHECK(-fPIE, C)
670 if test "x$CLFAGS" != "x$CFLAGS_before_pie"
671 then
672         # Restore CFLAGS
673         CFLAGS=$CFLAGS_before_pie
674
675         LDFLAGS_before_pie=$LDFLAGS
676         AC_WIRESHARK_LDFLAGS_CHECK([-fPIE -pie])
677         if test "x$LDFLAGS" != "x$LDFLAGS_before_pie"
678         then
679                 # We can use PIE
680                 PIE_CFLAGS="-fPIE"
681                 PIE_LDFLAGS="-pie"
682
683                 # Restore LDFLAGS
684                 LDFLAGS=$LDFLAGS_before_pie
685         fi
686
687 fi
688 AC_SUBST(PIE_CFLAGS)
689 AC_SUBST(PIE_LDFLAGS)
690
691 #
692 # If we're running GCC or clang define _U_ to be "__attribute__((unused))"
693 # so we can use _U_ to flag unused function parameters and not get warnings
694 # about them. Otherwise, define _U_ to be an empty string so that _U_ used
695 # to flag an unused function parameters will compile with other compilers.
696 #
697 # XXX - similar hints for other compilers?
698 #
699 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
700   AC_DEFINE(_U_, __attribute__((unused)), [Hint to the compiler that a function parameters is not used])
701 else
702   AC_DEFINE(_U_, , [Hint to the compiler that a function parameters is not used])
703 fi
704
705 # If we're running GCC or CLang, use FORTIFY_SOURCE=2
706 #  (only if the GCC 'optimization level' > 0).
707 #
708 # See: http://gcc.gnu.org/ml/gcc-patches/2004-09/msg02055.html
709 # See: http://sourceware.org/bugzilla/show_bug.cgi?id=13979
710 #
711 # Note: FORTIFY_SOURCE is only effective for gcc optimization level > 0 (-O1, etc)
712 AC_WIRESHARK_GCC_FORTIFY_SOURCE_CHECK
713
714 #
715 # If the compiler supports GCC-style flags, enable a barrier "stop on
716 # warning".
717 # This barrier is set for a very large part of the code. However, it is
718 # typically not set for "generated" code  (flex, ans2wrs, idl2wrs, ...)
719 #
720 warnings_as_errors_default="yes"
721 AC_MSG_CHECKING(whether we should treat compiler warnings as errors)
722 AC_ARG_ENABLE(warnings-as-errors,
723   AC_HELP_STRING( [--enable-warnings-as-errors],
724                   [treat warnings as errors (only for GCC or clang) @<:@default=yes, unless extra warnings are enabled@:>@]),
725 [
726   if test "x$ac_supports_gcc_flags" = "xyes" -a "x$enableval" = "xyes"; then
727     with_warnings_as_errors="yes"
728     AC_MSG_RESULT(yes)
729   else
730     with_warnings_as_errors="no"
731     AC_MSG_RESULT(no)
732   fi
733 ],
734 [
735   if test "x$ac_supports_gcc_flags" = "xyes" -a "x$wireshark_extra_gcc_flags" = "x" -a "x$warnings_as_errors_default" = "xyes"; then
736     with_warnings_as_errors="yes"
737     AC_MSG_RESULT(yes)
738   else
739     with_warnings_as_errors="no"
740     AC_MSG_RESULT(no)
741   fi
742 ]
743 )
744 AM_CONDITIONAL(HAVE_WARNINGS_AS_ERRORS, test "x$with_warnings_as_errors" = "xyes")
745
746 #
747 # Add any platform-specific compiler flags needed.
748 #
749 AC_MSG_CHECKING(for platform-specific compiler flags)
750 if test "x$GCC" = "xyes" ; then
751         #
752         # GCC - do any platform-specific tweaking necessary.
753         #
754         case "$host_os" in
755         solaris*)
756                 # the X11 headers don't automatically include prototype info
757                 # and a lot don't include the return type
758                 CPPFLAGS="$CPPFLAGS -DFUNCPROTO=15"
759                 CFLAGS="$CFLAGS -Wno-return-type"
760                 CXXFLAGS="$CXXFLAGS -Wno-return-type"
761                 AC_MSG_RESULT(GCC on Solaris - added -Wno-return-type -DFUNCPROTO=15)
762                 ;;
763         *)
764                 AC_MSG_RESULT(none needed)
765                 ;;
766         esac
767 else
768         #
769         # Not GCC - assume it's the vendor's compiler.
770         #
771         case "$host_os" in
772         hpux*)
773                 #
774                 # HP's ANSI C compiler; flags suggested by Jost Martin.
775                 # "-Ae" for ANSI C plus extensions such as "long long".
776                 # "+O2", for optimization.  XXX - works with "-g"?
777                 #
778                 # HP's ANSI C++ compiler doesn't support "-Ae", but
779                 # does support "+O2", at least according to the
780                 # documentation I can find online.
781                 #
782                 CFLAGS="-Ae +O2 $CFLAGS"
783                 CFLAGS_FOR_BUILD="-Ae +O2 $CFLAGS"
784                 CXXFLAGS="+O2 $CFLAGS"
785                 AC_MSG_RESULT(HP ANSI C compiler - added -Ae +O2)
786                 ;;
787         *)
788                 AC_MSG_RESULT(none needed)
789                 ;;
790         esac
791 fi
792
793 #
794 # Add any platform-specific linker flags needed.
795 #
796 AC_MSG_CHECKING(for platform-specific linker flags)
797 case "$host_os" in
798 darwin*)
799         #
800         # Add -Wl,-single_module to the LDFLAGS used with shared
801         # libraries, to fix some error that show up in some cases;
802         # some Apple documentation recommends it for most shared
803         # libraries.
804         #
805         LDFLAGS_SHAREDLIB="-Wl,-single_module"
806         #
807         # Add -Wl,-search_paths_first to make sure that if we search
808         # directories A and B, in that order, for a given library, a
809         # non-shared version in directory A, rather than a shared
810         # version in directory B, is chosen (so we can use
811         # --with-pcap=/usr/local to force all programs to be linked
812         # with a static version installed in /usr/local/lib rather than
813         # the system version in /usr/lib).
814         #
815         LDFLAGS="-Wl,-search_paths_first $LDFLAGS"
816         AC_MSG_RESULT([Apple linker - added -Wl,-single_module and -Wl,-search_paths_first])
817         ;;
818 cygwin*)
819         #
820         # Shared libraries in cygwin/Win32 must never contain
821         # undefined symbols.
822         #
823         LDFLAGS="$LDFLAGS -no-undefined"
824         AC_MSG_RESULT(CygWin GNU ld - added -no-undefined)
825         ;;
826 *)
827         AC_MSG_RESULT(none needed)
828         ;;
829 esac
830 AC_SUBST(LDFLAGS_SHAREDLIB)
831
832 # Enable silent builds by default
833 # Verbose builds can be enabled with "./configure
834 # --enable-silent-rules ..." or "make V=1 ..."
835 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
836   [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
837
838 #
839 # On "Darwin", which we assume to mean "OS X" rather than "iOS" or
840 # "just Darwin" (as we don't currently support iOS, and as I don't
841 # think you can build and run "just Darwin" as an OS for PCs), we
842 # arrange to build some programs with Application Services so they
843 # can launch Web browsers and Finder windows, arrange to build some
844 # programs with System Configuration so they can get "friendly names"
845 # and other information about interfaces, and build any programs that
846 # use either of those frameworks or that report version information
847 # with Core Foundation as the frameworks in question use it and as we
848 # get version information from plists and thus need Core Foundation
849 # to process those plists.
850 #
851 case "$host_os" in
852
853 darwin*)
854         AC_DEFINE(HAVE_OS_X_FRAMEWORKS, 1, [Define to 1 if you have OS X frameworks])
855         APPLICATIONSERVICES_FRAMEWORKS="-framework ApplicationServices"
856         SYSTEMCONFIGURATION_FRAMEWORKS="-framework SystemConfiguration"
857         COREFOUNDATION_FRAMEWORKS="-framework CoreFoundation"
858
859         #
860         # OK, so we have the OS X frameworks; do they include
861         # CFPropertyListCreateWithStream, or do we have
862         # to fall back on CFPropertyListCreateFromStream?
863         # (They only differ in the error return, which we
864         # don't care about.  And, no, we shouldn't just
865         # use CFPropertyListCreateFromStream, because it's
866         # deprecated in newer releases.)
867         #
868         ac_save_LIBS="$LIBS"
869         LIBS="$LIBS $COREFOUNDATION_FRAMEWORKS"
870         AC_CHECK_FUNCS(CFPropertyListCreateWithStream)
871         LIBS="$ac_save_LIBS"
872         ;;
873 esac
874 AC_SUBST(APPLICATIONSERVICES_FRAMEWORKS)
875 AC_SUBST(SYSTEMCONFIGURATION_FRAMEWORKS)
876 AC_SUBST(COREFOUNDATION_FRAMEWORKS)
877
878 dnl Look in /usr/local for header files and libraries ?
879 dnl XXX FIXME don't include /usr/local if it is already in the system
880 dnl search path as this causes gcc 3.2 on Linux to complain about a change
881 dnl of the system search order for includes
882 AC_ARG_ENABLE(usr-local,
883   AC_HELP_STRING( [--enable-usr-local],
884                   [look for headers and libs in /usr/local tree @<:@default=yes@:>@]),
885     ac_cv_enable_usr_local=$enableval,ac_cv_enable_usr_local=yes)
886
887 AC_MSG_CHECKING(whether to use /usr/local for headers and libraries)
888 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
889         if test -d "/usr/local"; then
890                 AC_MSG_RESULT(yes)
891                 #
892                 # Arrange that we search for header files in the source directory
893                 # and in its "wiretap" subdirectory, as well as in "/usr/local/include",
894                 # as various packages we use ("libpcap", "zlib", "adns")
895                 # may have been installed under "/usr/local/include".
896                 #
897                 CPPFLAGS="$CPPFLAGS -I/usr/local/include"
898
899                 #
900                 # Arrange that we search for libraries in "/usr/local/lib".
901                 #
902                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, /usr/local/lib)
903         else
904                 AC_MSG_RESULT(no)
905         fi
906 else
907         AC_MSG_RESULT(no)
908 fi
909
910 #
911 # If we're running Solaris, and LD_LIBRARY_PATH is defined, add it as a
912 # link directory.
913 #
914 case "$host_os" in
915   solaris*)
916     AC_MSG_CHECKING(for LD_LIBRARY_PATH, since you appear to be running Solaris)
917     if test x$LD_LIBRARY_PATH != x ; then
918       LIBS="$LIBS -R$LD_LIBRARY_PATH"
919       AC_MSG_RESULT(yes -- added LD_LIBRARY_PATH to run-time linker path)
920     else
921       AC_MSG_RESULT(no -- this may be a problem in a few seconds)
922     fi
923   ;;
924 esac
925
926 #
927 # Check for versions of "sed" inadequate to handle, in libtool, a list
928 # of object files as large as the list in Wireshark.
929 #
930 # On Solaris, we check for "/bin/sed", "/usr/bin/sed", and "/usr/ucb/sed",
931 # as both "/usr/bin/sed" (which is also "/bin/sed", as "/bin" is just a
932 # symlink to "/usr/bin", but people may have "/bin" before "/usr/bin" in
933 # their search path) and "/usr/ucb/sed" are inadequate; "/usr/xpg4/bin/sed"
934 # is the only "sed" that comes with Solaris that can handle Wireshark.
935 #
936 # Add any checks here that are necessary for other OSes.
937 #
938 AC_WIRESHARK_GNU_SED_CHECK
939 if test "$HAVE_GNU_SED" = no ; then
940         case "$host_os" in
941         solaris*)
942                 AC_MSG_CHECKING(whether one of /usr/bin/sed or /bin/sed or /usr/ucb/sed will be used)
943                 case `which sed` in
944                         /bin/sed|/usr/bin/sed|/usr/ucb/sed)
945                         AC_MSG_RESULT(yes)
946                         AC_MSG_ERROR([change your path to search /usr/xpg4/bin or directory containing GNU sed before /usr/bin (and /bin and /usr/ucb)])
947                         ;;
948
949                         *)
950                         AC_MSG_RESULT(no)
951                         ;;
952                 esac
953                 ;;
954
955         *)
956                 :
957                 ;;
958         esac
959 fi
960
961 # Enable/disable wireshark
962 AC_ARG_ENABLE(wireshark,
963   AC_HELP_STRING( [--enable-wireshark],
964                   [build the Wireshark GUI (with Gtk+, Qt, or both) @<:@default=yes@:>@]),
965     enable_wireshark=$enableval,enable_wireshark=yes)
966
967 AC_ARG_ENABLE(packet-editor,
968   AC_HELP_STRING( [--enable-packet-editor],
969                   [add support for packet editor in Wireshark @<:@default=no@:>@]),
970     enable_packet_editor=$enableval,enable_packet_editor=no)
971 if test x$enable_packet_editor = xyes; then
972         AC_DEFINE(WANT_PACKET_EDITOR, 1, [Support for packet editor])
973 fi
974
975 AC_ARG_ENABLE(profile-build,
976   AC_HELP_STRING( [--enable-profile-build],
977                   [build profile-ready binaries @<:@default=no@:>@]),
978     enable_profile_build=$enableval,enable_profile_build=no)
979 AM_CONDITIONAL(USE_PROFILE_BUILD, test x$enable_profile_build = xyes)
980 AC_MSG_CHECKING(if profile builds must be generated)
981 if test "x$enable_profile_build" = "xyes" ; then
982         if test "x$GCC" = "xyes" -o "x$CLANG" = "xyes" ; then
983                 AC_MSG_RESULT(yes)
984                 CFLAGS=" -pg $CFLAGS"
985                 CXXFLAGS=" -pg $CXXFLAGS"
986         else
987                 AC_MSG_RESULT(no)
988                 echo "Building profile binaries currently only supported for GCC and clang."
989         fi
990 else
991         AC_MSG_RESULT(no)
992 fi
993
994 # Create DATAFILE_DIR #define for config.h
995 datafiledir=$datadir/wireshark
996 datafiledir=`(
997     test "x$prefix" = xNONE && prefix=$ac_default_prefix
998     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
999     # Ugly hack, but I don't see how this problem can be solved
1000     # properly that DATAFILE_DIR had a value starting with
1001     # "${prefix}/" instead of e.g. "/usr/local/"
1002     eval eval echo "$datafiledir"
1003 )`
1004 AC_DEFINE_UNQUOTED(DATAFILE_DIR,"$datafiledir", [Directory for data])
1005
1006 # Create DOC_DIR #define for config.h
1007 docdir=`(
1008     test "x$prefix" = xNONE && prefix=$ac_default_prefix
1009     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1010     # Ugly hack, but I don't see how this problem can be solved
1011     # properly that DOC_DIR had a value starting with
1012     # "${prefix}/" instead of e.g. "/usr/local/"
1013     eval eval echo "$docdir"
1014 )`
1015 AC_DEFINE_UNQUOTED(DOC_DIR, "$docdir", [Directory for docs])
1016
1017 GTK2_MIN_VERSION=2.12.0
1018 AC_SUBST(GTK2_MIN_VERSION)
1019 GTK3_MIN_VERSION=3.0.0
1020 AC_SUBST(GTK3_MIN_VERSION)
1021 QT_MIN_VERSION=4.6.0
1022 AC_SUBST(QT_MIN_VERSION)
1023 # GTK+ and Qt checks; we require GTK+ $GTK2_MIN_VERSION or later or
1024 # GTK3_MIN_VERSION or later or Qt $QT_MIN_VERSION or later.
1025 #
1026 # We only do those if we're going to be building Wireshark;
1027 # otherwise, we don't have any GUI to build, so we don't use
1028 # GTK+ or Qt.
1029 #
1030 # We don't add $GTK_LIBS or $Qt_LIBS to LIBS, because we don't want to
1031 # force all programs to be built with GTK+ or Qt.
1032 #
1033 # Release dates for GTK+ versions:
1034 # 2.12.0: 14 Sep 2007
1035 # 2.14.0: 04 Sep 2008
1036 # 2.16.0: 13 Mar 2009
1037 # 2.18.0: 23 Sep 2009
1038 # 2.20.0: 23 Mar 2010
1039 # 2.22.0: 23 Sep 2010
1040 # 2.24.0: 30 Jan 2011
1041 # 3.0.0:  10 Feb 2011
1042 # 3.2.0:  25 Sep 2011
1043 # 3.4.0:  26 Mar 2012
1044 # 3.6.0:  24 Sep 2012
1045 # 3.8.0:  25 Mar 2013
1046
1047 have_qt=no
1048 have_gtk=no
1049 if test "x$enable_wireshark" = "xyes"; then
1050         if test "x$with_qt" = "xyes"; then
1051
1052                 AC_MSG_CHECKING(whether we have a working C++ compiler)
1053                 AC_LANG_PUSH([C++])
1054                 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1055                         [AC_MSG_RESULT(yes)],
1056                         [
1057                          AC_MSG_RESULT(no)
1058                          AC_MSG_ERROR(Need a working C++ compiler to build Wireshark with Qt)
1059                         ])
1060                 AC_LANG_POP([C++])
1061
1062                 AM_PATH_QT($QT_MIN_VERSION,
1063                 [
1064                         CFLAGS="$CFLAGS $Qt_CFLAGS"
1065                         CXXFLAGS="$CXXFLAGS $Qt_CFLAGS"
1066                         have_qt=yes
1067                 ]
1068                 , [AC_MSG_ERROR([Qt is not available])])
1069
1070                 #
1071                 # XXX - greasy hack to make ui/gtk/recent.c
1072                 # compile.
1073                 #
1074                 CPPFLAGS="-DQT_GUI_LIB"
1075         fi
1076
1077         if test "x$with_gtk3" = "xyes" -a "x$with_gtk2" = "xyes" ; then
1078                 AC_MSG_ERROR(--with-gtk2 and --with-gtk3 are mutually exclusive)
1079         fi
1080
1081         if test "x$with_gtk3" = "xyes"; then
1082                 AM_PATH_GTK_3_0(3.0.0,
1083                 [
1084                         CFLAGS="$CFLAGS $GTK_CFLAGS"
1085                         CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
1086                         have_gtk=yes
1087                         AC_DEFINE(HAVE_GTK, 1,
1088                             [Define to 1 if compiling with GTK])
1089                 ], have_gtk=no)
1090         fi
1091
1092         if test "x$with_gtk2" = "xyes"; then
1093                 AM_PATH_GTK_2_0($GTK2_MIN_VERSION,
1094                 [
1095                         CFLAGS="$CFLAGS $GTK_CFLAGS"
1096                         CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
1097                         have_gtk=yes
1098                         AC_DEFINE(HAVE_GTK, 1,
1099                             [Define to 1 if compiling with GTK])
1100                 ], have_gtk=no)
1101         fi
1102 fi
1103
1104 GLIB_MIN_VERSION=2.16.0
1105 AC_SUBST(GLIB_MIN_VERSION)
1106 # GLib checks; we require GLib $GLIB_MIN_VERSION or later, and require gmodule
1107 # support, as we need that for dynamically loading plugins.
1108 # If we found GTK+, this doesn't add GLIB_CFLAGS to CFLAGS, because
1109 # AM_PATH_GTK will add GTK_CFLAGS to CFLAGS, and GTK_CFLAGS is a
1110 # superset of GLIB_CFLAGS.  If we didn't find GTK+, it does add
1111 # GLIB_CFLAGS to CFLAGS.
1112 # However, this means that both @GLIB_LIBS@ and @GTK_LIBS@ will be
1113 # set when generating the Makefile, so we can make programs that require
1114 # only GLib link with @GLIB_LIBS@ and make programs that require GTK+
1115 # link with @GTK_LIBS@ (which includes @GLIB_LIBS@).
1116 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
1117 # programs to be built with GLib.
1118 #
1119 # Release dates for GLib versions:
1120 # 2.14.0: 03 Aug 2007
1121 # 2.16.0: 10 Mar 2008
1122 # 2.18.0: 02 Sep 2008
1123 # 2.20.0: 13 Mar 2009
1124 # 2.22.0: 22 Sep 2009
1125 # 2.24.0: 28 Mar 2010
1126 # 2.26.0: 27 Sep 2010
1127 # 2.28.0: 08 Feb 2011
1128 # 2.30.0: 27 Sep 2011
1129 # 2.32.0: 24 Mar 2012
1130 # 2.34.0: 24 Sep 2012
1131 # 2.36.0: 25 Mar 2013
1132
1133 use_glib_cflags="true"
1134 if test "$have_gtk" = "yes" -a "$have_qt" = "yes" ; then
1135         # We have both GTK and Qt and thus will be building both wireshark
1136         # and wireshark-qt.
1137
1138         wireshark_bin="wireshark\$(EXEEXT) wireshark-qt\$(EXEEXT)"
1139         wireshark_man="wireshark.1"
1140         wireshark_SUBDIRS="codecs ui/qt ui/gtk"
1141 fi
1142 if test "$have_gtk" = "no" -a "$have_qt" = "yes" ; then
1143         # We don't have GTK+ but we have Qt.
1144
1145         wireshark_bin="wireshark-qt\$(EXEEXT)"
1146         wireshark_man="wireshark.1"
1147         wireshark_SUBDIRS="codecs ui/qt"
1148 fi
1149 if test "$have_gtk" = "yes" -a "$have_qt" = "no" ; then
1150         # We have GTK+ but not Qt.
1151
1152         wireshark_bin="wireshark\$(EXEEXT)"
1153         wireshark_man="wireshark.1"
1154         wireshark_SUBDIRS="codecs ui/gtk"
1155         use_glib_cflags="false"
1156 fi
1157 if test "$have_gtk" = "no" -a "$have_qt" = "no" ; then
1158         # We have neither GTK+ nor Qt.
1159         #
1160         # If they didn't explicitly say "--disable-wireshark",
1161         # fail (so that, unless they explicitly indicated that
1162         # they don't want Wireshark, we stop so they know they
1163         # won't be getting Wireshark unless they fix the GTK+/Qt
1164         # problem).
1165         #
1166         if test "x$enable_wireshark" = "xyes"; then
1167                 if test "x$with_gtk3" = "xyes"; then
1168                         AC_MSG_ERROR([Neither Qt nor GTK+ $GTK3_MIN_VERSION or later are available, so Wireshark can't be compiled])
1169                 else
1170                         AC_MSG_ERROR([Neither Qt nor GTK+ $GTK2_MIN_VERSION or later are available, so Wireshark can't be compiled])
1171                 fi
1172         fi
1173         wireshark_bin=""
1174         wireshark_man=""
1175 fi
1176
1177 if test "$have_gtk" = "yes" ; then
1178         # If we have GTK then add flags for it.
1179
1180         CPPFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CPPFLAGS"
1181         CPPFLAGS="-DGDK_DISABLE_DEPRECATED $CPPFLAGS"
1182         CPPFLAGS="-DGTK_DISABLE_DEPRECATED $CPPFLAGS"
1183         CPPFLAGS="-DGTK_DISABLE_SINGLE_INCLUDES $CPPFLAGS"
1184         if test ! \( $gtk_config_major_version -eq 2 -a $gtk_config_minor_version -lt 20 \) ; then
1185                 # Enable GSEAL when building with GTK > 2.20
1186                 # (Versions prior to 2.22 lacked some necessary accessors.)
1187                 CPPFLAGS="-DGSEAL_ENABLE $CPPFLAGS"
1188         fi
1189 fi
1190
1191 # XXX - Is this really necessary?  When we build with both Gtk+ and Qt it works...
1192 if test "$use_glib_cflags" = "true"; then
1193         # Use GLIB_CFLAGS
1194         AM_PATH_GLIB_2_0($GLIB_MIN_VERSION,
1195         [
1196                 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1197                 CXXFLAGS="$CXXFLAGS $GLIB_CFLAGS"
1198         ], AC_MSG_ERROR(GLib $GLIB_MIN_VERSION or later distribution not found.), gthread gmodule)
1199 else
1200         # Don't use GLIB_CFLAGS
1201         AM_PATH_GLIB_2_0($GLIB_MIN_VERSION, , AC_MSG_ERROR(GLib $GLIB_MIN_VERSION or later distribution not found.), gthread gmodule)
1202 fi
1203
1204 #
1205 # "make dist" requires that we have the Qt build tools.
1206 #
1207 # Annoyingly, at least on Fedora 16, uic and moc are named XXX-qt4
1208 # rather than just XXX, perhaps to allow Qt 3 and Qt 4 tools to be
1209 # installed; if they're still doing that in current Fedora releases,
1210 # perhaps there will also be XXX-qt5 when they pick up Qt 5.
1211 #
1212 AC_PATH_PROG(UIC, uic)
1213 if test "x$UIC" = x
1214 then
1215         AC_PATH_PROG(UIC, uic-qt4)
1216         if test "x$UIC" = x
1217         then
1218                 if test "x$with_qt" = "xyes"; then
1219                         #
1220                         # If you want to build with Qt, you'd better
1221                         # have uic.
1222                         #
1223                         AC_MSG_ERROR(I couldn't find uic or uic-qt4; make sure it's installed and in your path)
1224                 else
1225                         #
1226                         # We shouldn't fail here, as the user's not
1227                         # building with Qt, and we shouldn't force them
1228                         # to have Qt installed if they're not doing so.
1229                         # "make dist" will fail if they do that, but
1230                         # we don't know whether they'll be doing that,
1231                         # so this is the best we can do.
1232                         #
1233                         UIC=uic
1234                 fi
1235         fi
1236 fi
1237 AC_SUBST(UIC)
1238 AC_PATH_PROG(MOC, moc)
1239 if test "x$MOC" = x
1240 then
1241         AC_PATH_PROG(MOC, moc-qt4)
1242         if test "x$MOC" = x
1243         then
1244                 if test "x$with_qt" = "xyes"; then
1245                         #
1246                         # If you want to build with Qt, you'd better
1247                         # have moc.
1248                         #
1249                         AC_MSG_ERROR(I couldn't find moc or moc-qt4; make sure it's installed and in your path)
1250                 else
1251                         #
1252                         # We shouldn't fail here, as the user's not
1253                         # building with Qt, and we shouldn't force them
1254                         # to have Qt installed if they're not doing so.
1255                         # "make dist" will fail if they do that, but
1256                         # we don't know whether they'll be doing that,
1257                         # so this is the best we can do.
1258                         #
1259                         MIC=moc
1260                 fi
1261         fi
1262 fi
1263 AC_SUBST(MOC)
1264
1265 # Error out if a glib header other than a "top level" header
1266 #  (glib.h, glib-object.h, gio.h) or certain other headers( e.g.,gmodule.h)
1267 #  is used.
1268 CPPFLAGS="-DG_DISABLE_SINGLE_INCLUDES $CPPFLAGS"
1269
1270 # Error out on the usage of deprecated glib functions
1271 CPPFLAGS="-DG_DISABLE_DEPRECATED $CPPFLAGS"
1272
1273 #
1274 # Check whether GLib modules are supported, to determine whether we
1275 # can support plugins.
1276 #
1277 AC_MSG_CHECKING(whether GLib supports loadable modules)
1278 ac_save_CFLAGS="$CFLAGS"
1279 ac_save_LIBS="$LIBS"
1280 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1281 LIBS="$GLIB_LIBS $LIBS"
1282 AC_TRY_RUN([
1283 #include <glib.h>
1284 #include <gmodule.h>
1285 #include <stdio.h>
1286 #include <stdlib.h>
1287
1288 int
1289 main ()
1290 {
1291   if (g_module_supported())
1292     return 0;   /* success */
1293   else
1294     return 1;   /* failure */
1295 }
1296 ], ac_cv_glib_supports_modules=yes, ac_cv_glib_supports_modules=no,
1297    [echo $ac_n "cross compiling; assumed OK... $ac_c"
1298     ac_cv_glib_supports_modules=yes])
1299 CFLAGS="$ac_save_CFLAGS"
1300 LIBS="$ac_save_LIBS"
1301 if test "$ac_cv_glib_supports_modules" = yes ; then
1302   AC_MSG_RESULT(yes)
1303   have_plugins=yes
1304 else
1305   AC_MSG_RESULT(no)
1306   have_plugins=no
1307 fi
1308
1309 #
1310 # If we have <dlfcn.h>, check whether we can use dladdr to find a
1311 # filename (hopefully, a full pathname, but no guarantees) for
1312 # the executable.
1313 #
1314 if test "$ac_cv_header_dlfcn_h" = "yes"
1315 then
1316         AC_MSG_CHECKING(whether dladdr can be used to find the pathname of an executable)
1317         ac_save_CFLAGS="$CFLAGS"
1318         ac_save_LIBS="$LIBS"
1319         CFLAGS="$CFLAGS $GLIB_CFLAGS"
1320         LIBS="$GLIB_LIBS $LIBS"
1321         AC_TRY_RUN([
1322 #define _GNU_SOURCE     /* required on Linux, sigh */
1323 #include <dlfcn.h>
1324
1325 int
1326 main(void)
1327 {
1328         Dl_info info;
1329
1330         if (!dladdr((void *)main, &info))
1331                 return 1;       /* failure */
1332         return 0;               /* assume success */
1333 }
1334 ], ac_cv_dladdr_finds_executable_path=yes, ac_cv_dladdr_finds_executable_path=no,
1335    [echo $ac_n "cross compiling; assumed OK... $ac_c"
1336     ac_cv_dladdr_finds_executable_path=yes])
1337         CFLAGS="$ac_save_CFLAGS"
1338         LIBS="$ac_save_LIBS"
1339         if test x$ac_cv_dladdr_finds_executable_path = xyes
1340         then
1341                 AC_DEFINE(DLADDR_FINDS_EXECUTABLE_PATH, 1, [Define if dladdr can be used to find the path of the executable])
1342         fi
1343         AC_MSG_RESULT($ac_cv_dladdr_finds_executable_path)
1344 fi
1345
1346 #
1347 # Check whether GLib's printf supports thousands grouping. (This might
1348 # be different from the system's printf since GLib can optionally use
1349 # its own printf implementation.)
1350 #
1351 AC_MSG_CHECKING(whether GLib supports POSIX/XSI thousands grouping)
1352 ac_save_CFLAGS="$CFLAGS"
1353 ac_save_LIBS="$LIBS"
1354 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1355 LIBS="$GLIB_LIBS $LIBS"
1356 AC_TRY_RUN([
1357 #include <glib.h>
1358 #include <locale.h>
1359 #include <stdio.h>
1360 #include <string.h>
1361
1362 int
1363 main ()
1364 {
1365   gchar *str;
1366   setlocale(LC_ALL, "en_US.UTF-8");
1367   str = g_strdup_printf("%'u", 123456);
1368   return (strcmp (str, "123,456") != 0);
1369 }
1370 ], ac_cv_glib_supports_printf_grouping=yes, ac_cv_glib_supports_printf_grouping=no,
1371    [echo $ac_n "cross compiling; playing it safe... $ac_c"
1372     ac_cv_glib_supports_printf_grouping=no])
1373 CFLAGS="$ac_save_CFLAGS"
1374 LIBS="$ac_save_LIBS"
1375 if test "$ac_cv_glib_supports_printf_grouping" = yes ; then
1376   AC_MSG_RESULT(yes)
1377   AC_DEFINE(HAVE_GLIB_PRINTF_GROUPING, 1, [Define if your printf() function supports thousands grouping.])
1378 else
1379   AC_MSG_RESULT(no)
1380 fi
1381
1382 if test "x$have_gtk" = "xyes"
1383 then
1384     #
1385     # We have GTK+; do we want the OS X integration functions and,
1386     # if so, do we have them and, if so, which versions do we have,
1387     # the old Carbon-based ones or the new Cocoa-based ones?
1388     #
1389     AC_MSG_CHECKING(whether to use OS X integration functions)
1390
1391     AC_ARG_WITH(osx-integration,
1392       AC_HELP_STRING( [--with-osx-integration],
1393                       [use OS X integration functions @<:@default=yes, if available@:>@]),
1394     [
1395         if test $withval = no
1396         then
1397             want_osx_integration=no
1398         else
1399             want_osx_integration=yes
1400         fi
1401     ],[
1402         want_osx_integration=yes
1403     ])
1404     if test "x$want_osx_integration" = "xno"; then
1405         AC_MSG_RESULT(no)
1406     else
1407         AC_MSG_RESULT(yes)
1408         AC_WIRESHARK_OSX_INTEGRATION_CHECK
1409     fi
1410 fi
1411
1412 AC_SUBST(wireshark_bin)
1413 AC_SUBST(wireshark_man)
1414 AM_CONDITIONAL(HAVE_Qt, test "$have_qt" = "yes")
1415 # XXX - is it bad form for HAVE_GTK to be both a define and a conditional?
1416 AM_CONDITIONAL(HAVE_GTK, test "$have_gtk" = "yes")
1417
1418
1419 # Enable/disable tshark
1420
1421 AC_ARG_ENABLE(tshark,
1422   AC_HELP_STRING( [--enable-tshark],
1423                   [build TShark @<:@default=yes@:>@]),
1424     tshark=$enableval,enable_tshark=yes)
1425
1426 if test "x$enable_tshark" = "xyes" ; then
1427         tshark_bin="tshark\$(EXEEXT)"
1428         tshark_man="tshark.1"
1429         wiresharkfilter_man="wireshark-filter.4"
1430 else
1431         tshark_bin=""
1432         tshark_man=""
1433 fi
1434 AC_SUBST(tshark_bin)
1435 AC_SUBST(tshark_man)
1436 AC_SUBST(wiresharkfilter_man)
1437
1438
1439
1440 # Enable/disable editcap
1441
1442 AC_ARG_ENABLE(editcap,
1443   AC_HELP_STRING( [--enable-editcap],
1444                   [build editcap @<:@default=yes@:>@]),
1445     enable_editcap=$enableval,enable_editcap=yes)
1446
1447 if test "x$enable_editcap" = "xyes" ; then
1448         editcap_bin="editcap\$(EXEEXT)"
1449         editcap_man="editcap.1"
1450 else
1451         editcap_bin=""
1452         editcap_man=""
1453 fi
1454 AC_SUBST(editcap_bin)
1455 AC_SUBST(editcap_man)
1456
1457
1458
1459 # Enable/disable echld
1460
1461 AC_ARG_WITH(echld,
1462   AC_HELP_STRING( [--with-echld],
1463                   [support echld]),
1464 [
1465   if test "x$withval" = "xno"; then
1466       have_echld="no"
1467   else
1468       have_echld="$withval"
1469   fi
1470 ])
1471 AM_CONDITIONAL(HAVE_ECHLD, test "x$have_echld" = "xyes")
1472 if test "x$have_echld" = xyes
1473 then
1474   AC_DEFINE(HAVE_ECHLD, 1, [Define if echld is enabled])
1475   echld_test_bin="echld_test\$(EXEEXT)"
1476 else
1477   have_echld="no"
1478   echld_test_bin=""
1479 fi
1480 AC_SUBST(echld_test_bin)
1481
1482
1483 # Enabling/disabling of dumpcap is done later (after we know if we have PCAP
1484 # or not)
1485
1486 # Enable/disable capinfos
1487
1488 AC_ARG_ENABLE(capinfos,
1489   AC_HELP_STRING( [--enable-capinfos],
1490                   [build capinfos @<:@default=yes@:>@]),
1491     enable_capinfos=$enableval,enable_capinfos=yes)
1492
1493 if test "x$enable_capinfos" = "xyes" ; then
1494         capinfos_bin="capinfos\$(EXEEXT)"
1495         capinfos_man="capinfos.1"
1496 else
1497         capinfos_bin=""
1498         capinfos_man=""
1499 fi
1500 AC_SUBST(capinfos_bin)
1501 AC_SUBST(capinfos_man)
1502
1503
1504 # Enable/disable mergecap
1505
1506 AC_ARG_ENABLE(mergecap,
1507   AC_HELP_STRING( [--enable-mergecap],
1508                   [build mergecap @<:@default=yes@:>@]),
1509     enable_mergecap=$enableval,enable_mergecap=yes)
1510
1511 if test "x$enable_mergecap" = "xyes" ; then
1512         mergecap_bin="mergecap\$(EXEEXT)"
1513         mergecap_man="mergecap.1"
1514 else
1515         mergecap_bin=""
1516         mergecap_man=""
1517 fi
1518 AC_SUBST(mergecap_bin)
1519 AC_SUBST(mergecap_man)
1520
1521
1522 # Enable/disable reordercap
1523
1524 AC_ARG_ENABLE(reordercap,
1525   AC_HELP_STRING( [--enable-reordercap],
1526                   [build reordercap @<:@default=yes@:>@]),
1527     enable_reordercap=$enableval,enable_reordercap=yes)
1528
1529 if test "x$enable_reordercap" = "xyes" ; then
1530         reordercap_bin="reordercap\$(EXEEXT)"
1531         reordercap_man="reordercap.1"
1532 else
1533         reordercap_bin=""
1534         reordercap_man=""
1535 fi
1536 AC_SUBST(reordercap_bin)
1537 AC_SUBST(reordercap_man)
1538
1539
1540 # Enable/disable text2pcap
1541
1542 AC_ARG_ENABLE(text2pcap,
1543   AC_HELP_STRING( [--enable-text2pcap],
1544                   [build text2pcap @<:@default=yes@:>@]),
1545     text2pcap=$enableval,enable_text2pcap=yes)
1546
1547 if test "x$enable_text2pcap" = "xyes" ; then
1548         text2pcap_bin="text2pcap\$(EXEEXT)"
1549         text2pcap_man="text2pcap.1"
1550 else
1551         text2pcap_bin=""
1552         text2pcap_man=""
1553 fi
1554 AC_SUBST(text2pcap_bin)
1555 AC_SUBST(text2pcap_man)
1556
1557
1558 # Enable/disable dftest
1559
1560 AC_ARG_ENABLE(dftest,
1561   AC_HELP_STRING( [--enable-dftest],
1562                   [build dftest @<:@default=yes@:>@]),
1563     enable_dftest=$enableval,enable_dftest=yes)
1564
1565 if test "x$enable_dftest" = "xyes" ; then
1566         dftest_bin="dftest\$(EXEEXT)"
1567         dftest_man="dftest.1"
1568 else
1569         dftest_bin=""
1570         dftest_man=""
1571 fi
1572 AC_SUBST(dftest_bin)
1573 AC_SUBST(dftest_man)
1574
1575
1576 # Enable/disable randpkt
1577
1578 AC_ARG_ENABLE(randpkt,
1579   AC_HELP_STRING( [--enable-randpkt],
1580                   [build randpkt @<:@default=yes@:>@]),
1581     enable_randpkt=$enableval,enable_randpkt=yes)
1582
1583 if test "x$enable_randpkt" = "xyes" ; then
1584         randpkt_bin="randpkt\$(EXEEXT)"
1585         randpkt_man="randpkt.1"
1586 else
1587         randpkt_bin=""
1588         randpkt_man=""
1589 fi
1590 AC_SUBST(randpkt_bin)
1591 AC_SUBST(randpkt_man)
1592
1593
1594
1595 dnl Checks for "gethostbyname()" - and "-lnsl", if we need it to get
1596 dnl "gethostbyname()".
1597 AC_WIRESHARK_GETHOSTBY_LIB_CHECK
1598
1599 dnl Checks for "connect()", used as a proxy for "socket()" - and
1600 dnl "-lsocket", if we need it to get "connect()".
1601 AC_WIRESHARK_SOCKET_LIB_CHECK
1602
1603 dnl pcap check
1604 AC_MSG_CHECKING(whether to use libpcap for packet capture)
1605
1606 AC_ARG_WITH(pcap,
1607   AC_HELP_STRING( [--with-pcap@<:@=DIR@:>@],
1608                   [use libpcap for packet capturing @<:@default=yes@:>@]),
1609 [
1610         if test $withval = no
1611         then
1612                 want_pcap=no
1613         elif test $withval = yes
1614         then
1615                 want_pcap=yes
1616         else
1617                 want_pcap=yes
1618                 pcap_dir=$withval
1619         fi
1620 ],[
1621         want_pcap=yes
1622         pcap_dir=
1623 ])
1624 if test "x$want_pcap" = "xno" ; then
1625         AC_MSG_RESULT(no)
1626 else
1627         AC_MSG_RESULT(yes)
1628         AC_WIRESHARK_PCAP_CHECK
1629 fi
1630
1631
1632 dnl Check for airpcap
1633 AC_MSG_CHECKING(whether to include airpcap support)
1634 AC_ARG_ENABLE(airpcap,
1635   AC_HELP_STRING( [--enable-airpcap],
1636                   [use AirPcap in Wireshark @<:@default=yes@:>@]),
1637   enable_airpcap=$enableval, enable_airpcap=yes)
1638
1639 if test x$enable_airpcap = xyes; then
1640         if test "x$want_pcap" = "xno" ; then
1641                 enable_airpcap=no
1642                 AC_MSG_RESULT(pcap not available - disabling airpcap)
1643         else
1644                 AC_MSG_RESULT(yes)
1645                 AC_DEFINE(HAVE_AIRPCAP, 1, [Enable AirPcap])
1646         fi
1647 else
1648         AC_MSG_RESULT(no)
1649 fi
1650
1651
1652 dnl dumpcap check
1653 AC_MSG_CHECKING(whether to build dumpcap)
1654
1655 AC_ARG_ENABLE(dumpcap,
1656   AC_HELP_STRING( [--enable-dumpcap],
1657                   [build dumpcap @<:@default=yes@:>@]),
1658     enable_dumpcap=$enableval,enable_dumpcap=yes)
1659
1660 if test "x$enable_dumpcap" = "xyes" ; then
1661         if test "x$want_pcap" = "xno" ; then
1662                 enable_dumpcap=no
1663                 AC_MSG_RESULT(pcap not available - disabling dumpcap)
1664         else
1665                 AC_MSG_RESULT(yes)
1666         fi
1667 else
1668         AC_MSG_RESULT(no)
1669 fi
1670
1671 if test "x$enable_dumpcap" = "xyes" ; then
1672         dumpcap_bin="dumpcap\$(EXEEXT)"
1673         dumpcap_man="dumpcap.1"
1674 else
1675         dumpcap_bin=""
1676         dumpcap_man=""
1677 fi
1678 AC_SUBST(dumpcap_bin)
1679 AC_SUBST(dumpcap_man)
1680
1681 # Enable/disable rawshark
1682
1683 dnl rawshark check
1684 AC_MSG_CHECKING(whether to build rawshark)
1685
1686 AC_ARG_ENABLE(rawshark,
1687   AC_HELP_STRING( [--enable-rawshark],
1688                   [build rawshark @<:@default=yes@:>@]),
1689     rawshark=$enableval,enable_rawshark=yes)
1690
1691 if test "x$enable_rawshark" = "xyes" ; then
1692         if test "x$want_pcap" = "xno" ; then
1693                 enable_rawshark=no
1694                 AC_MSG_RESULT(pcap not available - disabling rawshark)
1695         else
1696                 AC_MSG_RESULT(yes)
1697         fi
1698 else
1699         AC_MSG_RESULT(no)
1700 fi
1701
1702 if test "x$enable_rawshark" = "xyes" ; then
1703         rawshark_bin="rawshark\$(EXEEXT)"
1704         rawshark_man="rawshark.1"
1705 else
1706         rawshark_bin=""
1707         rawshark_man=""
1708 fi
1709 AC_SUBST(rawshark_bin)
1710 AC_SUBST(rawshark_man)
1711
1712 dnl Use pcap-ng by default
1713 AC_ARG_ENABLE(pcap-ng-default,
1714   AC_HELP_STRING( [--enable-pcap-ng-default],
1715                   [use the pcap-ng file format by default instead of pcap @<:@default=yes@:>@]),
1716     enable_pcap_ng_default=$enableval,enable_pcap_ng_default=yes)
1717 if test x$enable_pcap_ng_default = xyes; then
1718         AC_DEFINE(PCAP_NG_DEFAULT, 1, [Support for pcap-ng])
1719 fi
1720
1721 dnl pcap remote check
1722 AC_MSG_CHECKING(whether to use libpcap remote capturing feature)
1723
1724 AC_ARG_WITH(pcap-remote,
1725     AC_HELP_STRING([--with-pcap-remote],
1726                    [use libpcap remote capturing (requires libpcap)]),
1727 [
1728     if test $withval = no
1729     then
1730         want_pcap_remote=no
1731     else
1732         want_pcap_remote=yes
1733     fi
1734 ],[
1735     want_pcap_remote=no
1736 ])
1737 if test "x$want_pcap_remote" = "xno" -o "x$want_pcap" = "xno" ; then
1738     AC_MSG_RESULT(no)
1739 else
1740     AC_MSG_RESULT(yes)
1741     AC_WIRESHARK_PCAP_REMOTE_CHECK
1742 fi
1743
1744 dnl zlib check
1745 AC_MSG_CHECKING(whether to use zlib for gzip compression and decompression)
1746
1747 AC_ARG_WITH(zlib,
1748   AC_HELP_STRING([--with-zlib@<:@=DIR@:>@],
1749                  [use zlib (located in directory DIR, if supplied) for gzip compression and decompression @<:@default=yes, if available@:>@]),
1750 [
1751         if test "x$withval" = "xno"
1752         then
1753                 want_zlib=no
1754         elif test "x$withval" = "xyes"
1755         then
1756                 want_zlib=yes
1757         else
1758                 want_zlib=yes
1759                 zlib_dir="$withval"
1760         fi
1761 ],[
1762         #
1763         # Use zlib if it's present, otherwise don't.
1764         #
1765         want_zlib=ifavailable
1766         zlib_dir=
1767 ])
1768 if test "x$want_zlib" = "xno" ; then
1769         AC_MSG_RESULT(no)
1770 else
1771         AC_MSG_RESULT(yes)
1772         AC_WIRESHARK_ZLIB_CHECK
1773         if test "x$want_zlib" = "xno" ; then
1774                 AC_MSG_RESULT(zlib not found - disabling gzip compression and decompression)
1775         else
1776                 if test "x$ac_cv_func_inflatePrime" = "xno" ; then
1777                         AC_MSG_RESULT(inflatePrime not found in zlib - disabling gzipped capture file support)
1778                 fi
1779         fi
1780 fi
1781
1782 dnl Lua check
1783 AC_MSG_CHECKING(whether to use liblua for the Lua scripting plugin)
1784
1785 AC_ARG_WITH(lua,
1786   AC_HELP_STRING( [--with-lua@<:@=DIR@:>@],
1787                   [use liblua (located in directory DIR, if supplied) for the Lua scripting plugin @<:@default=yes, if available@:>@]),
1788 [
1789         if test $withval = no
1790         then
1791                 want_lua=no
1792         elif test $withval = yes
1793         then
1794                 want_lua=yes
1795         else
1796                 want_lua=yes
1797                 lua_dir=$withval
1798         fi
1799 ],[
1800         #
1801         # Use liblua by default
1802         #
1803         want_lua=ifavailable
1804         lua_dir=
1805 ])
1806 if test "x$want_lua" = "xno" ; then
1807         AC_MSG_RESULT(no)
1808 else
1809         AC_MSG_RESULT(yes)
1810         AC_WIRESHARK_LIBLUA_CHECK
1811         if test "x$want_lua" = "xno" ; then
1812                 AC_MSG_RESULT(liblua not found - disabling support for the lua scripting plugin)
1813         fi
1814 fi
1815 AM_CONDITIONAL(HAVE_LIBLUA, test x$want_lua = xyes)
1816
1817
1818 dnl portaudio check
1819 AC_MSG_CHECKING(whether to use libportaudio for the rtp_player)
1820
1821 AC_ARG_WITH(portaudio,
1822   AC_HELP_STRING( [--with-portaudio@<:@=DIR@:>@],
1823                   [use libportaudio (located in directory DIR, if supplied) for the rtp_player @<:@default=yes, if available@:>@]),
1824 [
1825         if test $withval = no
1826         then
1827                 want_portaudio=no
1828         elif test $withval = yes
1829         then
1830                 want_portaudio=yes
1831         else
1832                 want_portaudio=yes
1833                 portaudio_dir=$withval
1834         fi
1835 ],[
1836         #
1837         # Use libportaudio by default
1838         #
1839         want_portaudio=ifavailable
1840         portaudio_dir=
1841 ])
1842 if test "x$want_portaudio" = "xno" ; then
1843         AC_MSG_RESULT(no)
1844 else
1845         AC_MSG_RESULT(yes)
1846         AC_WIRESHARK_LIBPORTAUDIO_CHECK
1847         if test "x$want_portaudio" = "xno" ; then
1848                 AC_MSG_RESULT(libportaudio not found - disabling support for the rtp_player)
1849         fi
1850 fi
1851 AM_CONDITIONAL(HAVE_LIBPORTAUDIO, test x$want_portaudio = xyes)
1852
1853
1854 dnl ipv6 check
1855 AC_ARG_ENABLE(ipv6,
1856   AC_HELP_STRING( [--enable-ipv6],
1857                   [use IPv6 name resolution, if available @<:@default=yes@:>@]),
1858     enable_ipv6=$enableval,enable_ipv6=yes)
1859
1860 AC_MSG_CHECKING(whether to enable ipv6 name resolution if available)
1861 if test "x$enable_ipv6" = "xno" ; then
1862         AC_MSG_RESULT(no)
1863 else
1864         AC_MSG_RESULT(yes)
1865         AC_WIRESHARK_IPV6_STACK
1866 fi
1867
1868
1869 dnl Check if dumpcap should be installed with filesystem capabilities
1870 AC_PATH_PROG(SETCAP, setcap)
1871 AC_ARG_ENABLE(setcap-install,
1872   AC_HELP_STRING( [--enable-setcap-install],
1873                   [install dumpcap with cap_net_admin and cap_net_raw @<:@default=no@:>@]),
1874     enable_setcap_install=$enableval,enable_setcap_install=no)
1875
1876 AC_MSG_CHECKING(whether to install dumpcap with cap_net_admin and cap_net_raw capabilities)
1877 if test "x$enable_setcap_install" = "xno" ; then
1878         AC_MSG_RESULT(no)
1879 else
1880         if test "x$SETCAP" = "x" ; then
1881                 AC_MSG_RESULT(no. Setcap not found)
1882         elif test "x$enable_dumpcap" = "xno" ; then
1883                 AC_MSG_ERROR(Setcap install works only with dumpcap but dumpcap is disabled)
1884         else
1885                 AC_MSG_RESULT(yes)
1886         fi
1887 fi
1888
1889 AM_CONDITIONAL(SETCAP_INSTALL, test x$enable_setcap_install = xyes)
1890
1891 dnl Check if dumpcap should be installed setuid
1892 AC_ARG_ENABLE(setuid-install,
1893   AC_HELP_STRING( [--enable-setuid-install],
1894                   [install dumpcap as setuid @<:@default=no@:>@]),
1895     enable_setuid_install=$enableval,enable_setuid_install=no)
1896
1897 AC_MSG_CHECKING(whether to install dumpcap setuid)
1898 if test "x$enable_setuid_install" = "xno" ; then
1899         AC_MSG_RESULT(no)
1900 else
1901         if test "x$enable_setcap_install" = "xyes" ; then
1902                 enable_setuid_install=no
1903                 AC_MSG_RESULT(no; using setcap instead)
1904         elif test "x$enable_dumpcap" = "xno" ; then
1905                 AC_MSG_ERROR(Setuid install works only with dumpcap but dumpcap is disabled)
1906         else
1907                 AC_MSG_RESULT(yes)
1908         fi
1909 fi
1910
1911 AM_CONDITIONAL(SETUID_INSTALL, test x$enable_setuid_install = xyes)
1912 AC_CHECK_FUNCS(setresuid setresgid)
1913
1914 dnl ...but our Network Operations group is named "no"!
1915 DUMPCAP_GROUP=''
1916 AC_ARG_WITH(dumpcap-group,
1917   AC_HELP_STRING( [--with-dumpcap-group=GROUP],
1918                   [restrict dumpcap to GROUP]),
1919 [
1920   if test "x$withval" = "xyes"; then
1921       AC_MSG_ERROR([No dumpcap group specified.])
1922   elif test "x$withval" != "xno"; then
1923       if test "x$enable_dumpcap" = "xno" ; then
1924           AC_MSG_ERROR(dumpcap group install works only with dumpcap but dumpcap is disabled)
1925       fi
1926       AC_MSG_RESULT($withval)
1927       DUMPCAP_GROUP="$withval"
1928   fi
1929 ])
1930 AC_SUBST(DUMPCAP_GROUP)
1931 AM_CONDITIONAL(HAVE_DUMPCAP_GROUP, test x$DUMPCAP_GROUP != x)
1932
1933 dnl libcap (not libpcap) check
1934 LIBCAP_LIBS=''
1935 AC_MSG_CHECKING(whether to use the libcap capabilities library)
1936
1937 AC_ARG_WITH(libcap,
1938   AC_HELP_STRING( [--with-libcap@<:@=DIR@:>@],
1939                   [use libcap (located in directory DIR, if supplied) for POSIX.1e capabilities management @<:@default=yes, if present@:>@]),
1940 [
1941 if   test "x$withval" = "xno";  then
1942         want_libcap=no
1943 elif test "x$withval" = "xyes"; then
1944         want_libcap=yes
1945 elif test -d "$withval"; then
1946         want_libcap=yes
1947         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1948 fi
1949 ])
1950 if test "x$with_libcap" = "xno" ; then
1951         AC_MSG_RESULT(no)
1952 else
1953         AC_MSG_RESULT(yes)
1954         AC_WIRESHARK_LIBCAP_CHECK
1955 fi
1956 AC_SUBST(LIBCAP_LIBS)
1957
1958 dnl Checks for header files.
1959 dnl Some of these may not be needed: http://hacks.owlfolio.org/header-survey/
1960 AC_CHECK_HEADERS(direct.h dirent.h fcntl.h grp.h inttypes.h netdb.h pwd.h stdarg.h stddef.h unistd.h)
1961 AC_CHECK_HEADERS(sys/ioctl.h sys/param.h sys/socket.h sys/sockio.h sys/stat.h sys/time.h sys/types.h sys/utsname.h sys/wait.h)
1962 AC_CHECK_HEADERS(netinet/in.h)
1963 AC_CHECK_HEADERS(arpa/inet.h arpa/nameser.h)
1964
1965 dnl SSL Check
1966 SSL_LIBS=''
1967 AC_MSG_CHECKING(whether to use SSL library)
1968
1969 AC_ARG_WITH(ssl,
1970   AC_HELP_STRING( [--with-ssl@<:@=DIR@:>@],
1971                   [use SSL crypto library (located in directory DIR, if supplied) @<:@default=no@:>@]),
1972 [
1973 if test "x$withval" = "xno";  then
1974         want_ssl=no
1975 elif test "x$withval" = "xyes"; then
1976         want_ssl=yes
1977 elif test -d "$withval"; then
1978         want_ssl=yes
1979         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1980 fi
1981 ],[
1982         want_ssl=no
1983 ])
1984 if test "x$want_ssl" = "xyes"; then
1985         AC_MSG_RESULT(yes)
1986         AC_CHECK_LIB(crypto,EVP_md5,
1987             [
1988                 SSL_LIBS=-lcrypto
1989             ],
1990             [
1991                 AC_MSG_ERROR([SSL crypto library was requested, but is not available])
1992             ])
1993 else
1994         AC_MSG_RESULT(no)
1995 fi
1996 AC_SUBST(SSL_LIBS)
1997
1998 dnl kerberos check
1999 AC_MSG_CHECKING(whether to use Kerberos library)
2000
2001 AC_ARG_WITH(krb5,
2002   AC_HELP_STRING( [--with-krb5@<:@=DIR@:>@],
2003                   [use Kerberos library (located in directory DIR, if supplied) to use in Kerberos dissection @<:@default=yes@:>@]),
2004 [
2005         if test $withval = no
2006         then
2007                 want_krb5=no
2008         elif test $withval = yes
2009         then
2010                 want_krb5=yes
2011         else
2012                 want_krb5=yes
2013                 krb5_dir=$withval
2014         fi
2015 ],[
2016         #
2017         # Use Kerberos library if available, otherwise don't.
2018         #
2019         want_krb5=ifavailable
2020         krb5_dir=
2021 ])
2022 if test "x$want_krb5" = "xno" ; then
2023         AC_MSG_RESULT(no)
2024 else
2025         AC_MSG_RESULT(yes)
2026         AC_WIRESHARK_KRB5_CHECK
2027 fi
2028
2029
2030 dnl c-ares Check
2031 C_ARES_LIBS=''
2032 AC_MSG_CHECKING(whether to use the c-ares library if available)
2033
2034 AC_ARG_WITH(c-ares,
2035   AC_HELP_STRING( [--with-c-ares@<:@=DIR@:>@],
2036                   [use c-ares (located in directory DIR, if supplied) - supersedes --with-adns @<:@default=yes, if present@:>@]),
2037 [
2038 if   test "x$withval" = "xno";  then
2039         want_c_ares=no
2040 elif test "x$withval" = "xyes"; then
2041         want_c_ares=yes
2042 elif test -d "$withval"; then
2043         want_c_ares=yes
2044         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2045 fi
2046 ])
2047 if test "x$want_c_ares" = "xno" ; then
2048         AC_MSG_RESULT(no)
2049 else
2050         AC_MSG_RESULT(yes)
2051         AC_WIRESHARK_C_ARES_CHECK
2052 fi
2053 AC_SUBST(C_ARES_LIBS)
2054
2055 dnl ADNS Check
2056 ADNS_LIBS=''
2057 AC_MSG_CHECKING(whether to use the GNU ADNS library if available)
2058
2059 AC_ARG_WITH(adns,
2060   AC_HELP_STRING( [--with-adns@<:@=DIR@:>@],
2061                   [use GNU ADNS (located in directory DIR, if supplied) @<:@default=yes, if present@:>@]),
2062 [
2063 if   test "x$withval" = "xno";  then
2064         want_adns=no
2065 elif test "x$withval" = "xyes"; then
2066         want_adns=yes
2067 elif test -d "$withval"; then
2068         want_adns=yes
2069         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2070 fi
2071 ])
2072 if test "x$want_adns" = "xno" -o "x$have_good_c_ares" = "xyes" ; then
2073         AC_MSG_RESULT(no)
2074 else
2075         AC_MSG_RESULT(yes)
2076         AC_WIRESHARK_ADNS_CHECK
2077 fi
2078 AC_SUBST(ADNS_LIBS)
2079
2080 dnl GEOIP Check
2081 GEOIP_LIBS=''
2082 AC_MSG_CHECKING(whether to use the GeoIP IP address mapping library if available)
2083
2084 AC_ARG_WITH(geoip,
2085   AC_HELP_STRING( [--with-geoip@<:@=DIR@:>@],
2086                   [use GeoIP (located in directory DIR, if supplied) @<:@default=yes, if present@:>@]),
2087 [
2088 if   test "x$withval" = "xno";  then
2089         want_geoip=no
2090 elif test "x$withval" = "xyes"; then
2091         want_geoip=yes
2092 elif test -d "$withval"; then
2093         want_geoip=yes
2094         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2095 fi
2096 ])
2097 if test "x$want_geoip" = "xno"; then
2098         AC_MSG_RESULT(no)
2099 else
2100         AC_MSG_RESULT(yes)
2101         AC_WIRESHARK_GEOIP_CHECK
2102 fi
2103 AC_SUBST(GEOIP_LIBS)
2104
2105 # Warning: this Python scripting appears to be broken (does not work at all).
2106 # Running it also causes Valgrind to complain about all sorts of memory errors.
2107 # Suggestion: do not enable it unless you are working on fixing it.
2108 #
2109 # An alternative might be https://code.google.com/p/pyreshark/
2110 #
2111 dnl Python devel Check
2112 AC_MSG_CHECKING(whether to use the Python interpreter for scripting)
2113
2114 AC_ARG_WITH(broken-python,
2115     AC_HELP_STRING( [--with-broken-python@<:@=DIR@:>@],
2116                     [use the (BROKEN) Python interpreter (installed in DIR, if supplied) @<:@default=no@:>@]),
2117 [
2118         pythondir='${libdir}/wireshark/python/${VERSION}'
2119         if test "x$withval" = "xno"
2120         then
2121                 want_python=no
2122         elif test "x$withval" = "xyes"
2123         then
2124                 want_python=yes
2125         else
2126                 want_python=yes
2127                 pythondir="$withval"
2128         fi
2129 ],[
2130         # By default (user didn't explicitly enable Python), don't enable
2131         # Python support.
2132         #
2133         want_python=no
2134         #pythondir='${libdir}/wireshark/python/${VERSION}'
2135 ])
2136 if test "x$want_python" = "xno" ; then
2137         AC_MSG_RESULT(no)
2138 else
2139         AC_MSG_RESULT(yes)
2140         AC_WIRESHARK_PYTHON_CHECK
2141 fi
2142 AM_CONDITIONAL(HAVE_LIBPY, test x$want_python != xno)
2143 AC_SUBST(pythondir)
2144
2145 #
2146 # Define WS_MSVC_NORETURN appropriately for declarations of routines that
2147 # never return (just like Charlie on the MTA).
2148 #
2149 # Note that MSVC++ expects __declspec(noreturn) to precede the function
2150 # name and GCC, as far as I know, expects __attribute__((noreturn)) to
2151 # follow the function name, so we need two different flavors of
2152 # noreturn tag.
2153 #
2154 AC_DEFINE(WS_MSVC_NORETURN,, [Define as the string to precede declarations of routines that never return])
2155
2156 dnl Checks for typedefs, structures, and compiler characteristics.
2157 # AC_C_CONST
2158
2159 # Check how we can get the time zone abbreviation
2160 AC_WIRESHARK_TIMEZONE_ABBREV
2161
2162 # We need to know whether "struct stat" has an "st_flags" member
2163 # for file_user_immutable().
2164
2165 AC_WIRESHARK_STRUCT_ST_FLAGS
2166
2167 # We need to know whether "struct sockaddr" has an "sa_len" member
2168 # for get_interface_list().
2169
2170 AC_WIRESHARK_STRUCT_SA_LEN
2171
2172 # We must know our byte order
2173 AC_C_BIGENDIAN
2174
2175 # Checks whether "-traditional" is needed when using "ioctl".
2176 # XXX - do we need this?
2177 AC_PROG_GCC_TRADITIONAL
2178
2179 GETOPT_LO=""
2180 AC_CHECK_FUNC(getopt,
2181   [GETOPT_LO=""
2182    AC_DEFINE(HAVE_GETOPT, 1, [Define to 1 if you have the getopt function.])
2183   ],
2184   GETOPT_LO="wsgetopt.lo"
2185 )
2186 if test "$ac_cv_func_getopt" = no ; then
2187   GETOPT_LO="wsgetopt.lo"
2188 fi
2189 AM_CONDITIONAL(NEED_GETOPT_LO, test "x$ac_cv_func_getopt" = "xno")
2190 AC_SUBST(GETOPT_LO)
2191
2192 AC_CHECK_FUNC(strncasecmp, STRNCASECMP_LO="",
2193   STRNCASECMP_LO="strncasecmp.lo")
2194 if test "$ac_cv_func_strncasecmp" = no ; then
2195   STRNCASECMP_LO="strncasecmp.lo"
2196 fi
2197 AM_CONDITIONAL(NEED_STRNCASECMP_LO, test "x$ac_cv_func_strncasecmp" = "xno")
2198 AC_SUBST(STRNCASECMP_LO)
2199
2200 AC_CHECK_FUNCS(mkstemp mkdtemp)
2201
2202 AC_SEARCH_LIBS(inet_aton, [socket nsl], have_inet_aton=yes,
2203     have_inet_aton=no)
2204 if test "$have_inet_aton" = no; then
2205   INET_ATON_LO="inet_aton.lo"
2206   AC_DEFINE(NEED_INET_ATON_H, 1, [Define if inet/aton.h needs to be included])
2207 else
2208   INET_ATON_LO=""
2209 fi
2210 AM_CONDITIONAL(NEED_INET_ATON_LO, test "x$have_inet_aton" = "xno")
2211 AC_SUBST(INET_ATON_LO)
2212
2213 AC_SEARCH_LIBS(inet_pton, [socket nsl], [
2214   dnl check for pre-BIND82 inet_pton() bug.
2215   AC_MSG_CHECKING(for broken inet_pton)
2216   AC_TRY_RUN([#include <sys/types.h>
2217 #include <sys/socket.h>
2218 #include <netinet/in.h>
2219 #include <arpa/inet.h>
2220 int main()
2221 {
2222 #ifdef AF_INET6
2223   char buf[16];
2224   /* this should return 0 (error) */
2225   return inet_pton(AF_INET6, "0:1:2:3:4:5:6:7:", buf);
2226 #else
2227   return 1;
2228 #endif
2229 }], [AC_MSG_RESULT(ok);
2230 have_inet_pton=yes], [AC_MSG_RESULT(broken);
2231 have_inet_pton=no], [AC_MSG_RESULT(cross compiling, assume it is broken);
2232 have_inet_pton=no])],
2233 have_inet_pton=no)
2234 if test "$have_inet_pton" = no; then
2235   INET_PTON_LO="inet_pton.lo"
2236 else
2237   INET_PTON_LO=""
2238 fi
2239 AM_CONDITIONAL(NEED_INET_PTON_LO, test "x$have_inet_pton" = "xno")
2240 AC_SUBST(INET_PTON_LO)
2241
2242 AC_SEARCH_LIBS(inet_ntop, [socket nsl], [
2243   AC_MSG_CHECKING([for inet_ntop prototype])
2244   AC_TRY_COMPILE([#include <stdio.h>
2245 #include <sys/types.h>
2246 #include <sys/socket.h>
2247 #include <netinet/in.h>
2248 #include <arpa/inet.h>
2249
2250 extern const char *inet_ntop(int, const void *, char *, size_t);],, [
2251     AC_MSG_RESULT(yes)
2252     AC_DEFINE(HAVE_INET_NTOP_PROTO, 1,
2253     [Define if inet_ntop() prototype exists])], [
2254     AC_TRY_COMPILE([#include <stdio.h>
2255 #include <sys/types.h>
2256 #include <sys/socket.h>
2257 #include <netinet/in.h>
2258 #include <arpa/inet.h>
2259
2260 extern const char *inet_ntop(int, const void *, char *, socklen_t);],, [
2261       AC_MSG_RESULT(yes)
2262       AC_DEFINE(HAVE_INET_NTOP_PROTO, 1,
2263       [Define if inet_ntop() prototype exists])], [
2264       AC_MSG_RESULT(no)])])
2265   INET_NTOP_LO=""], [
2266   INET_NTOP_LO="inet_ntop.lo"
2267   AC_DEFINE(NEED_INET_V6DEFS_H, 1,
2268   [Define if inet/v6defs.h needs to be included])])
2269 AM_CONDITIONAL(NEED_INET_NTOP_LO, test "x$INET_NTOP_LO" != "x")
2270 AC_SUBST(INET_NTOP_LO)
2271
2272 AC_CHECK_FUNC(strptime, STRPTIME_LO="",
2273   [STRPTIME_LO="strptime.lo"
2274    AC_DEFINE(NEED_STRPTIME_H, 1, [Define if strptime.h needs to be included])
2275 ])
2276 if test "$ac_cv_func_strptime" = no ; then
2277   STRPTIME_LO="strptime.lo"
2278 fi
2279 AC_SUBST(STRPTIME_C)
2280 AM_CONDITIONAL(NEED_STRPTIME_LO, test "x$ac_cv_func_strptime" = "no")
2281 AC_SUBST(STRPTIME_LO)
2282
2283 AC_CHECK_FUNCS(getprotobynumber gethostbyname2)
2284 AC_CHECK_FUNCS(issetugid)
2285 AC_CHECK_FUNCS(mmap mprotect sysconf)
2286 AC_CHECK_FUNCS(strtoll)
2287
2288 dnl blank for now, but will be used in future
2289 AC_SUBST(wireshark_SUBDIRS)
2290
2291 dnl
2292 dnl check whether plugins should be enabled and, if they should be,
2293 dnl check for plugins directory - stolen from Amanda's configure.ac
2294 dnl
2295 dnl we don't wish to expand ${libdir} yet
2296 plugindir='${libdir}/wireshark/plugins/${VERSION}'
2297 AC_ARG_WITH(plugins,
2298   AC_HELP_STRING( [--with-plugins@<:@=DIR@:>@],
2299                   [support plugins (installed in DIR, if supplied) @<:@default=yes, if possible@:>@]),
2300 [
2301   if test "x$withval" = "xno"; then
2302     have_plugins=no
2303   elif test "x$have_plugins" = "xno"; then
2304       AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
2305   elif test "x$withval" != "xyes"; then
2306       plugindir="$withval"
2307   fi
2308 ])
2309 AM_CONDITIONAL(HAVE_PLUGINS, test "x$have_plugins" = "xyes")
2310 if test x$have_plugins = xyes
2311 then
2312   AC_DEFINE(HAVE_PLUGINS, 1, [Define if plugins are enabled])
2313 fi
2314 AC_SUBST(plugindir)
2315 CPPFLAGS="$CPPFLAGS '-DPLUGIN_DIR=\"\$(plugindir)\"'"
2316
2317 #
2318 # The plugin dissectors reside in ./plugins/PROTO/
2319 #
2320 PLUGIN_LIBS=""
2321 AC_SUBST(PLUGIN_LIBS)
2322
2323 #
2324 # Check if (emem) memory allocations must be 8-byte aligned.
2325 # I haven't been able to write C code that reliably makes that determination
2326 # (different versions of GCC with or without optimization give different
2327 # results) so just assume everything except (32-bit) x86 needs 8-byte
2328 # alignment (64-bit platforms either require 8-byte alignment for pointers
2329 # and 64-bit integral data types or may get better performance from that;
2330 # 64-bit x86 will get 8-byte alignment from G_MEM_ALIGN anyway.  32-bit
2331 # platforms would only require it, or get better performance from it,
2332 # for 64-bit floating-point values.).
2333 #
2334 AC_MSG_CHECKING(whether we need memory allocations to be 8-byte aligned)
2335 case $host_cpu in
2336         i386|i486|i586|i686)
2337                 AC_MSG_RESULT(no)
2338                 ;;
2339         *)
2340                 AC_MSG_RESULT(yes)
2341                 AC_DEFINE(NEED_8_BYTE_ALIGNMENT, 1, [Define if we need memory allocations to be 8-byte aligned])
2342                 ;;
2343 esac
2344
2345 dnl libtool defs
2346 #
2347 # Yes, AM_PROG_LIBTOOL is redundant with newer version(s) of some tool(s)
2348 # (autoconf?  automake?  libtool?) - with the newer version(s), it's
2349 # just an alias for AC_PROG_LIBTOOL, which is called earlier.
2350 #
2351 # With older version(s) of those tool(s), however, it's not just an
2352 # alias, and the configure scripts don't work without it.
2353 #
2354 AM_PROG_LIBTOOL
2355 AC_SUBST(LIBTOOL_DEPS)
2356
2357 AM_CONDITIONAL(ENABLE_STATIC, test x$enable_static = xyes)
2358 if test x$enable_static = xyes -a x$have_plugins = xyes
2359 then
2360   AC_DEFINE(ENABLE_STATIC, 1, [Link plugins statically into Wireshark])
2361 fi
2362 AC_SUBST(ENABLE_STATIC)
2363
2364 dnl Save the cacheable configure results to config.cache before recursing
2365 AC_CACHE_SAVE
2366
2367 sinclude(plugins/Custom.m4) dnl
2368 ifdef(_CUSTOM_AC_OUTPUT_,, define(_CUSTOM_AC_OUTPUT_, )) dnl
2369
2370 sinclude(asn1/Custom.m4) dnl
2371 ifdef(_CUSTOM_ASN1_AC_OUTPUT_,, define(_CUSTOM_ASN1_AC_OUTPUT_, )) dnl
2372
2373 AC_CONFIG_HEADERS(config.h)
2374 AC_OUTPUT(
2375   Makefile
2376   doxygen.cfg
2377   asn1/Makefile
2378   _CUSTOM_ASN1_AC_OUTPUT_
2379   asn1/acp133/Makefile
2380   asn1/acse/Makefile
2381   asn1/ansi_map/Makefile
2382   asn1/ansi_tcap/Makefile
2383   asn1/c1222/Makefile
2384   asn1/camel/Makefile
2385   asn1/cdt/Makefile
2386   asn1/charging_ase/Makefile
2387   asn1/cmip/Makefile
2388   asn1/cmp/Makefile
2389   asn1/crmf/Makefile
2390   asn1/cms/Makefile
2391   asn1/credssp/Makefile
2392   asn1/dap/Makefile
2393   asn1/disp/Makefile
2394   asn1/dop/Makefile
2395   asn1/dsp/Makefile
2396   asn1/ess/Makefile
2397   asn1/ftam/Makefile
2398   asn1/gnm/Makefile
2399   asn1/goose/Makefile
2400   asn1/gprscdr/Makefile
2401   asn1/gsm_map/Makefile
2402   asn1/h225/Makefile
2403   asn1/h235/Makefile
2404   asn1/h245/Makefile
2405   asn1/h248/Makefile
2406   asn1/h282/Makefile
2407   asn1/h283/Makefile
2408   asn1/h323/Makefile
2409   asn1/h450/Makefile
2410   asn1/h450-ros/Makefile
2411   asn1/h460/Makefile
2412   asn1/h501/Makefile
2413   asn1/HI2Operations/Makefile
2414   asn1/hnbap/Makefile
2415   asn1/idmp/Makefile
2416   asn1/inap/Makefile
2417   asn1/isdn-sup/Makefile
2418   asn1/kerberos/Makefile
2419   asn1/lcsap/Makefile
2420   asn1/ldap/Makefile
2421   asn1/logotypecertextn/Makefile
2422   asn1/lpp/Makefile
2423   asn1/lppa/Makefile
2424   asn1/lppe/Makefile
2425   asn1/lte-rrc/Makefile
2426   asn1/m3ap/Makefile
2427   asn1/mms/Makefile
2428   asn1/mpeg-audio/Makefile
2429   asn1/mpeg-pes/Makefile
2430   asn1/nbap/Makefile
2431   asn1/ns_cert_exts/Makefile
2432   asn1/ocsp/Makefile
2433   asn1/p1/Makefile
2434   asn1/p22/Makefile
2435   asn1/p7/Makefile
2436   asn1/p772/Makefile
2437   asn1/pcap/Makefile
2438   asn1/pkcs1/Makefile
2439   asn1/pkcs12/Makefile
2440   asn1/pkinit/Makefile
2441   asn1/pkixac/Makefile
2442   asn1/pkix1explicit/Makefile
2443   asn1/pkix1implicit/Makefile
2444   asn1/pkixproxy/Makefile
2445   asn1/pkixqualified/Makefile
2446   asn1/pkixtsp/Makefile
2447   asn1/pres/Makefile
2448   asn1/q932/Makefile
2449   asn1/q932-ros/Makefile
2450   asn1/qsig/Makefile
2451   asn1/ranap/Makefile
2452   asn1/rnsap/Makefile
2453   asn1/ros/Makefile
2454   asn1/rrc/Makefile
2455   asn1/rrlp/Makefile
2456   asn1/rtse/Makefile
2457   asn1/rua/Makefile
2458   asn1/s1ap/Makefile
2459   asn1/sabp/Makefile
2460   asn1/sbc-ap/Makefile
2461   asn1/smrse/Makefile
2462   asn1/snmp/Makefile
2463   asn1/spnego/Makefile
2464   asn1/sv/Makefile
2465   asn1/t124/Makefile
2466   asn1/t125/Makefile
2467   asn1/t38/Makefile
2468   asn1/tcap/Makefile
2469   asn1/tetra/Makefile
2470   asn1/ulp/Makefile
2471   asn1/wlancertextn/Makefile
2472   asn1/x2ap/Makefile
2473   asn1/x509af/Makefile
2474   asn1/x509ce/Makefile
2475   asn1/x509if/Makefile
2476   asn1/x509sat/Makefile
2477   asn1/x721/Makefile
2478   doc/Makefile
2479   docbook/Makefile
2480   epan/Makefile
2481   epan/crypt/Makefile
2482   epan/doxygen.cfg
2483   epan/dfilter/Makefile
2484   epan/dissectors/Makefile
2485   epan/dissectors/dcerpc/Makefile
2486   epan/dissectors/pidl/Makefile
2487   epan/ftypes/Makefile
2488   epan/wmem/Makefile
2489   epan/wslua/Makefile
2490   epan/wspython/Makefile
2491   codecs/Makefile
2492   ui/Makefile
2493   ui/doxygen.cfg
2494   ui/gtk/Makefile
2495   ui/gtk/doxygen.cfg
2496   ui/cli/Makefile
2497   ui/qt/Makefile
2498   ui/qt/doxygen.cfg
2499   help/Makefile
2500   packaging/Makefile
2501   packaging/macosx/Info.plist
2502   packaging/macosx/Makefile
2503   packaging/macosx/osx-dmg.sh
2504   packaging/nsis/Makefile
2505   packaging/rpm/Makefile
2506   packaging/rpm/SPECS/Makefile
2507   packaging/rpm/SPECS/wireshark.spec
2508   packaging/svr4/Makefile
2509   packaging/svr4/checkinstall
2510   packaging/svr4/pkginfo
2511   plugins/Makefile
2512   plugins/asn1/Makefile
2513   plugins/docsis/Makefile
2514   plugins/ethercat/Makefile
2515   plugins/gryphon/Makefile
2516   plugins/irda/Makefile
2517   plugins/m2m/Makefile
2518   plugins/mate/Makefile
2519   plugins/opcua/Makefile
2520   plugins/profinet/Makefile
2521   plugins/stats_tree/Makefile
2522   plugins/unistim/Makefile
2523   plugins/wimax/Makefile
2524   plugins/wimaxasncp/Makefile
2525   plugins/wimaxmacphy/Makefile
2526   tools/Makefile
2527   tools/lemon/Makefile
2528   wiretap/Makefile
2529   wsutil/Makefile
2530   echld/Makefile
2531   _CUSTOM_AC_OUTPUT_
2532   ,)
2533 dnl AC_CONFIG_FILES([tools/setuid-root.pl], [chmod +x tools/setuid-root.pl])
2534
2535
2536 # Pretty messages
2537
2538 if test "x$have_gtk" = "xyes"; then
2539         if test "x$with_gtk3" = "xyes"; then
2540                 gtk_lib_message=" (with GTK+ 3"
2541         else
2542                 gtk_lib_message=" (with GTK+ 2"
2543         fi
2544         if test "x$have_ige_mac" = "xyes"; then
2545                 gtk_lib_message="$gtk_lib_message and Mac OS X integration)"
2546         else
2547                 gtk_lib_message="$gtk_lib_message)"
2548         fi
2549 fi
2550
2551 if test "x$have_qt" = "xyes" ; then
2552         enable_qtshark="yes"
2553 else
2554         enable_qtshark="no"
2555 fi
2556
2557 if test "x$enable_setcap_install" = "xyes" ; then
2558         setcap_message="yes"
2559 else
2560         setcap_message="no"
2561 fi
2562
2563 if test "x$enable_setuid_install" = "xyes" ; then
2564         setuid_message="yes"
2565 else
2566         setuid_message="no"
2567 fi
2568
2569 if test "x$DUMPCAP_GROUP" = "x" ; then
2570         dumpcap_group_message="(none)"
2571 else
2572         dumpcap_group_message="$DUMPCAP_GROUP"
2573 fi
2574
2575 if test "x$want_zlib" = "xno" ; then
2576         zlib_message="no"
2577 else
2578         zlib_message="yes"
2579 fi
2580
2581 if test "x$want_lua" = "xyes" ; then
2582         lua_message="yes"
2583 else
2584         lua_message="no"
2585 fi
2586
2587 if test "x$want_python" = "xno"; then
2588         python_message="no"
2589 else
2590         python_message="yes"
2591 fi
2592
2593 if test "x$want_portaudio" = "xyes" ; then
2594         portaudio_message="yes"
2595 else
2596         portaudio_message="no"
2597 fi
2598
2599 if test "x$want_ssl" = "xno" ; then
2600         ssl_message="no"
2601 else
2602         ssl_message="yes"
2603 fi
2604
2605 if test "x$want_krb5" = "xno" ; then
2606         krb5_message="no"
2607 else
2608         krb5_message="yes ($ac_krb5_version)"
2609 fi
2610
2611 if test "x$have_good_c_ares" = "xyes" ; then
2612         c_ares_message="yes"
2613 else
2614         c_ares_message="no"
2615 fi
2616
2617 if test "x$have_good_adns" = "xyes" ; then
2618         adns_message="yes"
2619 else
2620         if test "x$have_good_c_ares" = "xyes" ; then
2621                 adns_message="no (using c-ares instead)"
2622         else
2623                 adns_message="no"
2624         fi
2625 fi
2626
2627 if test "x$have_good_libcap" = "xyes" ; then
2628         libcap_message="yes"
2629 else
2630         libcap_message="no"
2631 fi
2632
2633 if test "x$have_good_geoip" = "xyes" ; then
2634         geoip_message="yes"
2635 else
2636         geoip_message="no"
2637 fi
2638
2639 echo ""
2640 echo "The Wireshark package has been configured with the following options."
2641 echo "             Build wireshark (Gtk+) : $have_gtk""$gtk_lib_message"
2642 echo "                 Build wireshark-qt : $enable_qtshark"
2643 echo "                       Build tshark : $enable_tshark"
2644 echo "                     Build capinfos : $enable_capinfos"
2645 echo "                      Build editcap : $enable_editcap"
2646 echo "                      Build dumpcap : $enable_dumpcap"
2647 echo "                     Build mergecap : $enable_mergecap"
2648 echo "                   Build reordercap : $enable_reordercap"
2649 echo "                    Build text2pcap : $enable_text2pcap"
2650 echo "                      Build randpkt : $enable_randpkt"
2651 echo "                       Build dftest : $enable_dftest"
2652 echo "                     Build rawshark : $enable_rawshark"
2653 echo "                     Build echld : $have_echld"
2654 echo ""
2655 echo "   Save files as pcap-ng by default : $enable_pcap_ng_default"
2656 echo "  Install dumpcap with capabilities : $setcap_message"
2657 echo "             Install dumpcap setuid : $setuid_message"
2658 echo "                  Use dumpcap group : $dumpcap_group_message"
2659 echo "                        Use plugins : $have_plugins"
2660 echo "                    Use Lua library : $lua_message"
2661 echo "                 Use Python binding : $python_message"
2662 echo "                   Build rtp_player : $portaudio_message"
2663 echo "             Build profile binaries : $enable_profile_build"
2664 echo "                   Use pcap library : $want_pcap"
2665 echo "                   Use zlib library : $zlib_message"
2666 echo "               Use kerberos library : $krb5_message"
2667 echo "                 Use c-ares library : $c_ares_message"
2668 echo "               Use GNU ADNS library : $adns_message"
2669 echo "                Use SMI MIB library : $libsmi_message"
2670 echo "             Use GNU crypto library : $gcrypt_message"
2671 echo "             Use SSL crypto library : $ssl_message"
2672 echo "           Use IPv6 name resolution : $enable_ipv6"
2673 echo "                 Use gnutls library : $tls_message"
2674 echo "     Use POSIX capabilities library : $libcap_message"
2675 echo "                  Use GeoIP library : $geoip_message"
2676 echo "                     Use nl library : $libnl_message"