ConfigureChecks.cmake

   1 # ConfigureChecks.cmake
   2 #
   3 # Wireshark - Network traffic analyzer
   4 # By Gerald Combs <gerald@wireshark.org>
   5 # Copyright 1998 Gerald Combs
   6 #
   7 # This program is free software; you can redistribute it and/or
   8 # modify it under the terms of the GNU General Public License
   9 # as published by the Free Software Foundation; either version 2
  10 # of the License, or (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21
  22 include(CMakePushCheckState)
  23
  24 #check system for includes
  25 include(CheckIncludeFile)
  26 check_include_file("arpa/inet.h"         HAVE_ARPA_INET_H)
  27 check_include_file("arpa/nameser.h"      HAVE_ARPA_NAMESER_H)
  28 check_include_file("dlfcn.h"             HAVE_DLFCN_H)
  29 check_include_file("fcntl.h"             HAVE_FCNTL_H)
  30 check_include_file("getopt.h"            HAVE_GETOPT_H)
  31 check_include_file("grp.h"               HAVE_GRP_H)
  32 check_include_file("inttypes.h"          HAVE_INTTYPES_H)
  33 check_include_file("netinet/in.h"        HAVE_NETINET_IN_H)
  34 check_include_file("netdb.h"             HAVE_NETDB_H)
  35 # We need to set the path to Wpdpack in order to find Ntddndis.h
  36 #cmake_push_check_state()
  37 #set(CMAKE_REQUIRED_INCLUDES ${PCAP_INCLUDE_DIRS})
  38 #check_include_file("Ntddndis.h"          HAVE_NTDDNDIS_H)
  39 #cmake_pop_check_state()
  40 check_include_file("portaudio.h"         HAVE_PORTAUDIO_H)
  41 check_include_file("pwd.h"               HAVE_PWD_H)
  42 check_include_file("stdint.h"            HAVE_STDINT_H)
  43 check_include_file("sys/ioctl.h"         HAVE_SYS_IOCTL_H)
  44 check_include_file("sys/param.h"         HAVE_SYS_PARAM_H)
  45 check_include_file("sys/socket.h"        HAVE_SYS_SOCKET_H)
  46 check_include_file("sys/sockio.h"        HAVE_SYS_SOCKIO_H)
  47 check_include_file("sys/stat.h"          HAVE_SYS_STAT_H)
  48 check_include_file("sys/time.h"          HAVE_SYS_TIME_H)
  49 check_include_file("sys/types.h"         HAVE_SYS_TYPES_H)
  50 check_include_file("sys/utsname.h"       HAVE_SYS_UTSNAME_H)
  51 check_include_file("sys/wait.h"          HAVE_SYS_WAIT_H)
  52 check_include_file("unistd.h"            HAVE_UNISTD_H)
  53 check_include_file("windows.h"           HAVE_WINDOWS_H)
  54 check_include_file("winsock2.h"          HAVE_WINSOCK2_H)
  55
  56 #
  57 # On Linux, check for some additional headers, which we need as a
  58 # workaround for a bonding driver bug and for libpcap's current lack
  59 # of its own workaround for that bug.
  60 #
  61 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  62         #
  63         # Those header files require <sys/socket.h>.
  64         #
  65         check_c_source_compiles(
  66                 "#include <sys/socket.h>
  67                 #include <linux/sockios.h>
  68                 int main(void)
  69                 {
  70                         return 0;
  71                 }"
  72                 HAVE_LINUX_SOCKIOS_H
  73         )
  74         check_c_source_compiles(
  75                 "#include <sys/socket.h>
  76                 #include <linux/if_bonding.h>
  77                 int main(void)
  78                 {
  79                         return 0;
  80                 }"
  81                 HAVE_LINUX_IF_BONDING_H
  82         )
  83 endif()
  84
  85 #Functions
  86 include(CheckFunctionExists)
  87 include(CheckSymbolExists)
  88 check_function_exists("chown"            HAVE_CHOWN)
  89
  90 cmake_push_check_state()
  91 set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_DL_LIBS})
  92 check_function_exists("dladdr"           HAVE_DLADDR)
  93 cmake_pop_check_state()
  94
  95 #
  96 # Use check_symbol_exists just in case math.h does something magic
  97 # and there's not actually a function named floorl()
  98 #
  99 cmake_push_check_state()
 100 set(CMAKE_REQUIRED_INCLUDES ${M_INCLUDE_DIRS})
 101 set(CMAKE_REQUIRED_LIBRARIES ${M_LIBRARIES})
 102 check_symbol_exists("floorl" "math.h"    HAVE_FLOORL)
 103 check_symbol_exists("lrint"  "math.h"    HAVE_LRINT)
 104 cmake_pop_check_state()
 105
 106 check_function_exists("getaddrinfo"      HAVE_GETADDRINFO)
 107 check_function_exists("gethostbyname"    HAVE_GETHOSTBYNAME)
 108 check_function_exists("gethostbyname2"   HAVE_GETHOSTBYNAME2)
 109 check_function_exists("getopt_long"      HAVE_GETOPT_LONG)
 110 if(HAVE_GETOPT_LONG)
 111         if(HAVE_GETOPT_H)
 112                 check_symbol_exists("optreset" "getopt.h" HAVE_OPTRESET)
 113         else()
 114                 check_symbol_exists("optreset"           HAVE_OPTRESET)
 115         endif()
 116 endif()
 117 check_function_exists("getprotobynumber" HAVE_GETPROTOBYNUMBER)
 118 check_function_exists("inet_aton"        HAVE_INET_ATON)
 119 check_function_exists("inet_ntop"        HAVE_INET_NTOP_PROTO)
 120 check_function_exists("issetugid"        HAVE_ISSETUGID)
 121 check_function_exists("mkdtemp"          HAVE_MKDTEMP)
 122 check_function_exists("mkstemp"          HAVE_MKSTEMP)
 123 check_function_exists("popcount"         HAVE_POPCOUNT)
 124 check_function_exists("setresgid"        HAVE_SETRESGID)
 125 check_function_exists("setresuid"        HAVE_SETRESUID)
 126 check_function_exists("strptime"         HAVE_STRPTIME)
 127 check_function_exists("sysconf"          HAVE_SYSCONF)
 128 if (APPLE)
 129         cmake_push_check_state()
 130         set(CMAKE_REQUIRED_LIBRARIES ${APPLE_CORE_FOUNDATION_LIBRARY})
 131         check_function_exists("CFPropertyListCreateWithStream" HAVE_CFPROPERTYLISTCREATEWITHSTREAM)
 132         cmake_pop_check_state()
 133 endif()
 134
 135 #Struct members
 136 include(CheckStructHasMember)
 137 check_struct_has_member("struct sockaddr" sa_len   sys/socket.h HAVE_SA_LEN)
 138 check_struct_has_member("struct stat"     st_flags sys/stat.h   HAVE_ST_FLAGS)
 139 check_struct_has_member("struct tm"       tm_zone  time.h       HAVE_TM_ZONE)
 140
 141 #Symbols but NOT enums or types
 142 check_symbol_exists(tzname "time.h" HAVE_TZNAME)
 143
 144 # Check for stuff that isn't testable via the tests above
 145
 146 #
 147 # *If* we found libnl, check if we can use nl80211 stuff with it.
 148 #
 149 if (NL_FOUND)
 150         check_c_source_compiles(
 151                 "#include <linux/nl80211.h>
 152                 int main() {
 153                         int x = NL80211_FREQUENCY_ATTR_MAX_TX_POWER;
 154                         x |= NL80211_ATTR_SUPPORTED_IFTYPES;
 155                         x |= NL80211_ATTR_SUPPORTED_COMMANDS;
 156                         x |= NL80211_ATTR_WIPHY_FREQ;
 157                         x |= NL80211_CHAN_NO_HT;
 158                         (void)x;
 159                 }"
 160                 HAVE_NL80211
 161         )
 162         check_c_source_compiles(
 163                 "#include <linux/nl80211.h>
 164                 int main() {
 165                         enum nl80211_commands x = NL80211_CMD_SET_CHANNEL;
 166                 }"
 167                 HAVE_NL80211_CMD_SET_CHANNEL
 168         )
 169         check_c_source_compiles(
 170                 "#include <linux/nl80211.h>
 171                 int main() {
 172                         enum nl80211_protocol_features x = NL80211_PROTOCOL_FEATURE_SPLIT_WIPHY_DUMP;
 173                 }"
 174                 HAVE_NL80211_SPLIT_WIPHY_DUMP
 175         )
 176 endif()
 177
 178 #
 179 # Check whether GLib's printf supports thousands grouping. (This might
 180 # be different from the system's printf since GLib can optionally use
 181 # its own printf implementation.)
 182 #
 183 if (CMAKE_CROSSCOMPILING OR WIN32)
 184         #
 185         # Play it safe when cross-compiling.
 186         #
 187         # XXX - compiling and trying to run the test below appears
 188         # to loop infinitely on Windows, and the locale is wrong in
 189         # any case, so we don't do this on Window for now.
 190         #
 191         set(HAVE_GLIB_PRINTF_GROUPING FALSE)
 192 else()
 193         cmake_push_check_state()
 194         set(CMAKE_REQUIRED_INCLUDES ${GLIB2_INCLUDE_DIRS})
 195         set(CMAKE_REQUIRED_LIBRARIES ${GLIB2_LIBRARIES})
 196         check_c_source_runs(
 197                 "#include <glib.h>
 198                 #include <locale.h>
 199                 #include <stdio.h>
 200                 #include <string.h>
 201
 202                 int
 203                 main ()
 204                 {
 205                   gchar *str;
 206                   setlocale(LC_ALL, \"en_US.UTF-8\");
 207                   str = g_strdup_printf(\"%'u\", 123456);
 208                   return (strcmp (str, \"123,456\") != 0);
 209                 }" HAVE_GLIB_PRINTF_GROUPING)
 210         cmake_pop_check_state()
 211 endif()
 212
 213 #
 214 # Editor modelines  -  http://www.wireshark.org/tools/modelines.html
 215 #
 216 # Local variables:
 217 # c-basic-offset: 8
 218 # tab-width: 8
 219 # indent-tabs-mode: t
 220 # End:
 221 #
 222 # vi: set shiftwidth=8 tabstop=8 noexpandtab:
 223 # :indentSize=8:tabSize=8:noTabs=false:
 224 #