CMakeLists.txt

   1 # CMakeLists.txt
   2 #
   3 # $Id$
   4 #
   5 # Wireshark - Network traffic analyzer
   6 # By Gerald Combs <gerald@wireshark.org>
   7 # Copyright 1998 Gerald Combs
   8 #
   9 # This program is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU General Public License
  11 # as published by the Free Software Foundation; either version 2
  12 # of the License, or (at your option) any later version.
  13 #
  14 # This program is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program; if not, write to the Free Software
  21 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  22 #
  23
  24 project(Wireshark C)
  25
  26 cmake_minimum_required(VERSION 2.6)
  27
  28 #Where to find local cmake scripts
  29 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  30 INCLUDE(UseLemon)
  31 INCLUDE(UseMakeDissectorReg)
  32 INCLUDE(UseMakeTapReg)
  33
  34 # Under linux the release mode (CMAKE_BUILD_TYPE=release) defines NDEBUG
  35
  36 # Disable this later. Alternative: "make VERBOSE=1"
  37 set(CMAKE_VERBOSE_MAKEFILE ON)
  38
  39 #Defines CMAKE_INSTALL_BINDIR, CMAKE_INSTALL_DATADIR, etc ...
  40 include(CMakeInstallDirs)
  41
  42 include_directories(
  43         ${CMAKE_BINARY_DIR}
  44         ${CMAKE_SOURCE_DIR}
  45         ${CMAKE_SOURCE_DIR}/epan
  46         ${CMAKE_SOURCE_DIR}/tools/lemon
  47         ${CMAKE_SOURCE_DIR}/wiretap
  48 )
  49
  50 #Where to put libraries
  51 if(NOT LIBRARY_OUTPUT_PATH)
  52         set(LIBRARY_OUTPUT_PATH ${Wireshark_BINARY_DIR}/lib CACHE INTERNAL
  53                    "Single output directory for building all libraries.")
  54 endif()
  55
  56 option(BUILD_wireshark   "Build the GUI version of Wireshark" ON)
  57 option(BUILD_tshark      "Build tshark" ON)
  58 option(BUILD_rawshark    "Build rawshark" ON)
  59 option(BUILD_dumpcap     "Build dumpcap" ON)
  60 option(BUILD_text2pcap   "Build text2pcap" ON)
  61 option(BUILD_mergecap    "Build mergecap" ON)
  62 option(BUILD_editcap     "Build editcap" ON)
  63 option(BUILD_capinfos    "Build capinfos" ON)
  64 option(BUILD_randpkt     "Build randpkt" ON)
  65 option(BUILD_dftest      "Build dftest" ON)
  66 option(AUTOGEN_dcerpc    "Autogenerate dcerpc dissectors" OFF)
  67 option(AUTOGEN_pidl      "Autogenerate pidl dissectors" OFF)
  68
  69 option(DISABLE_WERROR    "Do not treat Warnings as errors" OFF)
  70 option(ENABLE_EXTRA_GCC_CHECKS "Do additional -W checks in GCC (disables -Werror)" OFF)
  71 option(ENABLE_AIRPCAP    "Enable Airpcap support" ON)
  72 option(ENABLE_STATIC     "Build a static version of Wireshark (not yet working)" OFF)
  73 option(ENABLE_PLUGINS    "Build with plugins" ON)
  74 # todo
  75 option(ENABLE_GUIDES     "Build Guides (not yet implemented)" OFF)
  76
  77 option(ENABLE_ADNS       "Build with adns support" ON)
  78 option(ENABLE_PCRE       "Build with pcre support" ON)
  79 option(ENABLE_PORTAUDIO  "Build with portaudio support" ON)
  80 option(ENABLE_Z          "Build with zlib compression support" ON)
  81 option(ENABLE_LUA        "Build with lua dissector support" ON)
  82 option(ENABLE_PYTHON     "Build with python dissector support" ON)
  83 option(ENABLE_SMI        "Build with smi snmp support" ON)
  84 option(ENABLE_GNUTLS     "Build with GNU TLS support" ON)
  85 option(ENABLE_GCRYPT     "Build with GNU crypto support" ON)
  86 option(ENABLE_GEOIP      "Build with GeoIP support" ON)
  87 option(ENABLE_CAP        "Build with posix capabilities support" ON)
  88 option(ENABLE_CARES      "Build with c_ares support" ON)
  89 # todo Mostly hardcoded
  90 option(ENABLE_KERBEROS   "Build with Kerberos support" ON)
  91
  92
  93 set(WIRESHARK_C_FLAGS
  94         -O2
  95         -Wall
  96         -W
  97         -Wextra
  98         -Wdeclaration-after-statement
  99         -Wendif-labels
 100         -Wpointer-arith
 101         -Wno-pointer-sign
 102         -Warray-bounds
 103         -Wcast-align
 104         -Wformat-security
 105 )
 106
 107 set(WIRESHARK_EXTRA_C_FLAGS
 108         -pedantic
 109         -Woverflow
 110         -Wlogical-op
 111         -Wno-overlength-strings
 112         -fstrict-overflow -Wstrict-overflow=4
 113         -Wunreachable-code
 114         -Wunsafe-loop-optimizations
 115         -Wno-long-long
 116         -Wbad-function-cast
 117         -Wcast-qual
 118         -Waddress
 119         -Warray-bounds
 120         -Wattributes
 121         -Wdiv-by-zero
 122         -Wformat-security
 123         -Wignored-qualifiers
 124         -Wpragmas
 125         -Wredundant-decls
 126         -Wvla
 127         -Wc++-compat
 128         -Wjump-misses-init
 129         # packet-ncp2222.inc prevents this from going into all warnings
 130         -Wwrite-strings
 131         -Wstrict-prototypes
 132         -Wmissing-declarations
 133         # Problem with packet-afs.c
 134         -Wshadow
 135         # More cleanup needed for this on LP64
 136         -Wshorten-64-to-32
 137 )
 138
 139 if(ENABLE_EXTRA_GCC_CHECKS)   # This overrides -Werror
 140         set(WIRESHARK_C_FLAGS ${WIRESHARK_C_FLAGS} ${WIRESHARK_EXTRA_C_FLAGS})
 141 endif()
 142
 143 add_definitions(
 144         -DHAVE_CONFIG_H
 145         -DPACKAGE=\"wireshark\"
 146         -DNEW_PACKET_LIST
 147 )
 148
 149 # Counterhack to work around some cache magic in CHECK_C_SOURCE_COMPILES
 150 include(CheckCCompilerFlag)
 151 set(C 0)
 152 # Sigh: Have to use THIS_FLAG instead of ${F} for some reason
 153 foreach(THIS_FLAG ${WIRESHARK_C_FLAGS})
 154         set(F WS_C_FLAG_${C})
 155         set(${F} ${THIS_FLAG})
 156         set(V WS_C_FLAG_VALID${C})
 157         check_c_compiler_flag(${${F}} ${V})
 158         if (${${V}})
 159                 add_definitions(${${F}})
 160         endif()
 161         math(EXPR C "${C} + 1")
 162 endforeach()
 163
 164 if(NOT DISABLE_WERROR AND NOT ENABLE_EXTRA_GCC_CHECKS)
 165         check_c_compiler_flag(-Werror WERROR)
 166 else()
 167         set(WERROR 0)
 168 endif()
 169
 170 if(CMAKE_COMPILER_IS_GNUCC)
 171         add_definitions( -D_U_=__attribute__\(\(unused\)\) )
 172 else()
 173         add_definitions( -D_U_=\"\" )
 174 endif()
 175
 176 # todo
 177 # Same for linker flags, but it looks like it's do-it-yourself here
 178 # AC_WIRESHARK_GCC_LDFLAGS_CHECK([-Wl,--as-needed])
 179 # AC_WIRESHARK_GCC_LDFLAGS_CHECK([-flto])
 180 # AC_WIRESHARK_GCC_LDFLAGS_CHECK([-fwhopr])
 181 # AC_WIRESHARK_GCC_LDFLAGS_CHECK([-fwhole-program])
 182
 183 if(ENABLE_STATIC)
 184   set(LINK_MODE_LIB STATIC)
 185   set(LINK_MODE_MODULE STATIC)
 186 else()
 187   set(LINK_MODE_LIB SHARED)
 188   set(LINK_MODE_MODULE MODULE)
 189 endif()
 190
 191 #The minimum package list
 192 set(PACKAGELIST GLIB2 PCAP M LEX YACC Perl SH PythonInterp HtmlViewer ${PACKAGELIST})
 193
 194 #Build the gui ?
 195 if(BUILD_wireshark)
 196         set(PACKAGELIST GTK2 ${PACKAGELIST})
 197 endif()
 198
 199 # SMI SNMP
 200 if(ENABLE_SMI)
 201         set(PACKAGELIST SMI ${PACKAGELIST})
 202 endif()
 203
 204 # GNU crypto
 205 if(ENABLE_GCRYPT)
 206         set(PACKAGELIST GCRYPT ${PACKAGELIST})
 207 endif()
 208
 209 # GNU SSL/TLS support
 210 if(ENABLE_GNUTLS)
 211         set(PACKAGELIST GNUTLS ${PACKAGELIST})
 212 endif()
 213
 214 # Regular expressions lib
 215 if(ENABLE_PCRE)
 216         set(PACKAGELIST PCRE ${PACKAGELIST})
 217 endif()
 218
 219 # Kerberos
 220 if(ENABLE_KERBEROS)
 221         set(PACKAGELIST KERBEROS ${PACKAGELIST})
 222 endif()
 223
 224 # Portable audio
 225 if(ENABLE_PORTAUDIO)
 226         set(PACKAGELIST PORTAUDIO ${PACKAGELIST})
 227 endif()
 228
 229
 230 # Prefer c-ares over adns
 231 if(ENABLE_CARES)        # C Asynchronouse resolver
 232         set(PACKAGELIST CARES ${PACKAGELIST})
 233 elseif(ENABLE_ADNS)     # Gnu asynchronous DNS
 234         set(PACKAGELIST ADNS ${PACKAGELIST})
 235 endif()
 236
 237 # Zlib compression
 238 if(ENABLE_Z)
 239         set(PACKAGELIST Z ${PACKAGELIST})
 240 endif()
 241
 242 # Lua 5.1 dissectors
 243 if(ENABLE_LUA)
 244         set(PACKAGELIST LUA ${PACKAGELIST})
 245 endif()
 246
 247 # GeoIP address resolving
 248 if(ENABLE_GEOIP)
 249         set(PACKAGELIST GEOIP ${PACKAGELIST})
 250 endif()
 251
 252 # Capabilities
 253 if(ENABLE_CAP)
 254         set(PACKAGELIST CAP ${PACKAGELIST})
 255 endif()
 256
 257 if(ENABLE_PYTHON)
 258         set(PACKAGELIST PYTHON ${PACKAGELIST})
 259 endif()
 260
 261 set(PROGLIST text2pcap mergecap capinfos editcap dumpcap)
 262
 263 #Let's loop the package list
 264 foreach(PACKAGE ${PACKAGELIST})
 265         find_package(${PACKAGE} REQUIRED)
 266         message(${PACKAGE}_FOUND)
 267         if (${PACKAGE}_FOUND)
 268                 set(HAVE_LIB${PACKAGE} 1)
 269                 include_directories(${${PACKAGE}_INCLUDE_DIRS})
 270                 message(STATUS "${PACKAGE} includes: ${${PACKAGE}_INCLUDE_DIRS}")
 271                 message(STATUS "${PACKAGE} libs: ${${PACKAGE}_LIBRARIES}")
 272         endif()
 273 endforeach()
 274
 275 find_package(YAPP)
 276
 277 #packaging
 278 include(CPackConfig.txt)
 279
 280 if(HAVE_LIBPYTHON)
 281         set(HAVE_PYTHON 1)
 282         set(PYTHON_DIR "${CMAKE_INSTALL_PREFIX}/lib/wireshark/python/${CPACK_PACKAGE_VERSION}")
 283 endif()
 284 if(HAVE_LIBLUA)
 285         set(HAVE_LUA_H 1)
 286         set(HAVE_LUA_5_1 1)
 287 endif()
 288 if(HAVE_LIBKERBEROS)
 289         set(HAVE_KERBEROS 1)
 290         # HAVE_HEIMDAL_KERBEROS
 291         set(HAVE_MIT_KERBEROS 1)
 292         set(HAVE_KEYTYPE_ARCFOUR_56 1)
 293 endif()
 294 if(HAVE_LIBGEOIP)
 295         set(HAVE_GEOIP 1)
 296 endif()
 297 if(HAVE_LIBCARES)
 298         set(HAVE_C_ARES 1)
 299 endif()
 300 if(HAVE_LIBADNS)
 301         set(HAVE_GNU_ADNS 1)
 302 endif()
 303 if(ENABLE_AIRPCAP)
 304         set(HAVE_AIRPCAP 1)
 305 endif()
 306
 307 include(ConfigureChecks.cmake)
 308
 309 #Big or little endian ?
 310 include(TestBigEndian)
 311 test_big_endian(WORDS_BIGENDIAN)
 312
 313 set(DATAFILE_DIR "${CMAKE_INSTALL_PREFIX}/share/${CPACK_PACKAGE_NAME}")
 314
 315 if(ENABLE_PLUGINS)
 316         set(HAVE_PLUGINS 1)
 317         set(PLUGIN_DIR="${DATAFILE_DIR}/plugins/${CPACK_PACKAGE_VERSION}")
 318         set(PLUGIN_SRC_DIRS
 319                 plugins/asn1
 320                 plugins/docsis
 321                 plugins/ethercat
 322                 plugins/giop
 323                 plugins/gryphon
 324                 plugins/irda
 325                 plugins/m2m
 326                 plugins/mate
 327                 plugins/opcua
 328                 plugins/profinet
 329                 plugins/sercosiii
 330                 plugins/stats_tree
 331                 plugins/unistim
 332                 plugins/wimax
 333                 plugins/wimaxasncp
 334         )
 335 # It seems this stuff doesn't build with autofoo either...
 336 #       if(YAPP_FOUND)
 337 #               set(PLUGIN_SRC_DIRS
 338 #                       ${PLUGIN_SRC_DIRS}
 339 #                       plugins/tpg
 340 #               )
 341 #       endif()
 342 else()
 343         set(PLUGIN_SRC_DIRS )
 344 endif()
 345
 346 foreach(PLUGIN_DIR ${PLUGIN_SRC_DIRS})
 347         add_subdirectory( ${PLUGIN_DIR} )
 348 endforeach()
 349
 350 add_subdirectory( codecs )
 351 add_subdirectory( epan )
 352 add_subdirectory( gtk )
 353 add_subdirectory( tools/lemon )
 354 add_subdirectory( wiretap )
 355 add_subdirectory( wsutil )
 356
 357 if(ENABLE_GUIDES)
 358         add_subdirectory( docbook )
 359 endif()
 360
 361 #Platform specific
 362 if(UNIX)
 363         set(WS_VAR_IMPORT "extern")
 364 endif()
 365
 366 if(APPLE)
 367 #TODO verify that APPLE implies HAVE_OS_X_FRAMEWORKS
 368         set(HAVE_OS_X_FRAMEWORKS 1)
 369         FIND_LIBRARY (APPLE_CORE_SERVICES_LIBRARY CoreServices)
 370         FIND_LIBRARY (APPLE_COCOA_LIBRARY Cocoa)
 371 endif()
 372
 373 if(WIN32)
 374         add_definitions(-D_NEED_VAR_IMPORT_)
 375         set(WS_VAR_IMPORT "__declspec(dllimport) extern")
 376
 377         # Disable deprecation
 378         if(MSVC80 OR MSVC90)
 379                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 380         endif()
 381 endif()
 382
 383 configure_file(${CMAKE_SOURCE_DIR}/cmakeconfig.h.in ${CMAKE_BINARY_DIR}/config.h)
 384
 385 include(FeatureSummary)
 386 #SET_FEATURE_INFO(NAME DESCRIPTION [URL [COMMENT] ]
 387 PRINT_ENABLED_FEATURES()
 388 PRINT_DISABLED_FEATURES()
 389
 390 link_directories(
 391         gtk
 392         codecs
 393         epan
 394         wiretap
 395         wsutil
 396 )
 397
 398 ADD_CUSTOM_TARGET(
 399         svnversion ALL
 400         COMMAND LANG=C ${PERL}
 401                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 402                 ${CMAKE_CURRENT_SOURCE_DIR}
 403         DEPENDS
 404                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 405 )
 406
 407 register_tap_files(tshark-tap-register.c
 408         ${TSHARK_TAP_SRC}
 409 )
 410
 411 ADD_CUSTOM_COMMAND(
 412         OUTPUT ps.c
 413         COMMAND ${PYTHON_EXECUTABLE}
 414           ${CMAKE_CURRENT_SOURCE_DIR}/tools/rdps.py
 415           ${CMAKE_CURRENT_SOURCE_DIR}/print.ps
 416           ps.c
 417         DEPENDS
 418           ${CMAKE_CURRENT_SOURCE_DIR}/tools/rdps.py
 419           ${CMAKE_CURRENT_SOURCE_DIR}/print.ps
 420 )
 421
 422 if(UNIX)
 423         set(PLATFORM_SRC
 424                 capture-pcap-util-unix.c
 425         )
 426 endif()
 427
 428 if(WIN32)
 429         set(PLATFORM_SRC
 430                 capture-wpcap.c capture_wpcap_packet.c
 431         )
 432 endif()
 433
 434 set(WTAP_PLUGIN_SOURCES
 435         epan/plugins.c
 436         epan/report_err.c
 437         epan/filesystem.c
 438 )
 439
 440 set(WIRESHARK_COMMON_SRC
 441         ${PLATFORM_SRC}
 442         capture_errs.c
 443         capture-pcap-util.c
 444         capture_ui_utils.c
 445         cfile.c
 446         clopts_common.c
 447         disabled_protos.c
 448         packet-range.c
 449         print.c
 450         ps.c
 451         svnversion.h
 452         sync_pipe_write.c
 453         timestats.c
 454         util.c
 455         tap-megaco-common.c
 456         tap-rtp-common.c
 457         version_info.c
 458 )
 459
 460 set(TSHARK_TAP_SRC
 461         tap-afpstat.c
 462         tap-ansi_astat.c
 463         tap-bootpstat.c
 464         tap-camelcounter.c
 465         tap-camelsrt.c
 466         tap-comparestat.c
 467         tap-dcerpcstat.c
 468         tap-funnel.c
 469         tap-gsm_astat.c
 470         tap-h225counter.c
 471         tap-h225rassrt.c
 472         tap-httpstat.c
 473         tap-iostat.c
 474         tap-iousers.c
 475         tap-mgcpstat.c
 476         tap-megacostat.c
 477         tap-protocolinfo.c
 478         tap-protohierstat.c
 479         tap-radiusstat.c
 480         tap-rpcstat.c
 481         tap-rpcprogs.c
 482         tap-rtp.c
 483         tap-sctpchunkstat.c
 484         tap-sipstat.c
 485         tap-smbsids.c
 486         tap-smbstat.c
 487         tap-stats_tree.c
 488         tap-wspstat.c
 489 )
 490
 491 set(INSTALL_DIRS
 492         diameter
 493         dtds
 494         help
 495         radius
 496         tpncp
 497         wimaxasncp
 498 )
 499
 500 set(INSTALL_FILES
 501         ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 502         COPYING
 503         ${CMAKE_BINARY_DIR}/capinfos.html
 504         cfilters
 505         colorfilters
 506         dfilters
 507         ${CMAKE_BINARY_DIR}/dumpcap.html
 508         ${CMAKE_BINARY_DIR}/editcap.html
 509         ${CMAKE_BINARY_DIR}/idl2wrs.html
 510         ipmap.html
 511         manuf
 512         ${CMAKE_BINARY_DIR}/mergecap.html
 513         ${CMAKE_BINARY_DIR}/rawshark.html
 514         services
 515         smi_modules
 516         ${CMAKE_BINARY_DIR}/text2pcap.html
 517         ${CMAKE_BINARY_DIR}/tshark.html
 518         ${CMAKE_BINARY_DIR}/wireshark-filter.html
 519         ${CMAKE_BINARY_DIR}/wireshark.html
 520         docbook/ws.css
 521 )
 522
 523 set(LIBEPAN_LIBS
 524 #               @GETOPT_O@      # wsgetopt.c
 525 #               @INET_ATON_LO@  # epan/inet_aton.c
 526 #               @INET_NTOP_LO@  # inet_ntop.c
 527 #               @INET_PTON_LO@  # inet_pton.c
 528 #               @NSL_LIBS@      # -lnsl
 529 #               @SOCKET_LIBS@   # -lsocket
 530 #               @SSL_LIBS@      # -lcrypto
 531 #               @STRERROR_O@    # strerror.c
 532 #               @STRNCASECMP_O@ # strncasecmp.c
 533 #               @STRPTIME_O@    # strptime.c
 534                 epan
 535 #               $(plugin_ldadd) # in case of static
 536                 ${PCRE_LIBRARIES}
 537                 ${PCAP_LIBRARIES}
 538                 ${CARES_LIBRARIES}
 539                 ${ADNS_LIBRARIES}
 540                 ${KERBEROS_LIBRARIES}
 541                 ${LUA_LIBRARIES}
 542                 ${PYTHON_LIBRARIES}
 543                 ${GEOIP_LIBRARIES}
 544                 ${GCRYPT_LIBRARIES}
 545                 ${GNUTLS_LIBRARIES}
 546                 ${SMI_LIBRARIES}
 547                 ${Z_LIBRARIES}
 548                 ${M_LIBRARIES}
 549 )
 550
 551 if(BUILD_wireshark)
 552         set(wireshark_LIBS
 553                 ui
 554                 ${GTK2_LIBRARIES}
 555                 codecs
 556                 ${PORTAUDIO_LIBRARIES}
 557                 ${LIBEPAN_LIBS}
 558                 ${APPLE_CORE_SERVICES_LIBRARY}
 559                 ${APPLE_COCOA_LIBRARY}
 560         )
 561         set(wireshark_FILES
 562                 airpcap_loader.c
 563                 alert_box.c
 564                 capture.c
 565                 capture_info.c
 566                 capture_opts.c
 567                 capture_sync.c
 568                 color_filters.c
 569                 file.c
 570                 fileset.c
 571                 filters.c
 572                 g711.c
 573                 merge.c
 574                 proto_hier_stats.c
 575                 summary.c
 576                 tempfile.c
 577                 ${WIRESHARK_COMMON_SRC}
 578         )
 579         add_executable(wireshark ${wireshark_FILES})
 580         add_dependencies(wireshark svnversion)
 581         target_link_libraries(wireshark ${wireshark_LIBS})
 582         install(TARGETS wireshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 583 endif()
 584
 585 if(BUILD_tshark)
 586         set(tshark_LIBS
 587                 ${LIBEPAN_LIBS}
 588                 ${APPLE_COCOA_LIBRARY}
 589         )
 590         set(tshark_FILES
 591                 capture_opts.c
 592                 capture_sync.c
 593                 tempfile.c
 594                 tshark-tap-register.c
 595                 tshark.c
 596                 ${TSHARK_TAP_SRC}
 597                 ${WIRESHARK_COMMON_SRC}
 598         )
 599         add_executable(tshark ${tshark_FILES})
 600         add_dependencies(tshark svnversion)
 601         target_link_libraries(tshark ${tshark_LIBS})
 602         install(TARGETS tshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 603 endif()
 604
 605 if(BUILD_rawshark)
 606         set(rawshark_LIBS
 607                 ${LIBEPAN_LIBS}
 608                 ${APPLE_COCOA_LIBRARY}
 609         )
 610         set(rawshark_FILES
 611                 ${WIRESHARK_COMMON_SRC}
 612                 rawshark.c
 613         )
 614         add_executable(rawshark ${rawshark_FILES})
 615         add_dependencies(rawshark svnversion)
 616         target_link_libraries(rawshark ${rawshark_LIBS})
 617         install(TARGETS rawshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 618 endif()
 619
 620 if(BUILD_dftest)
 621         set(dftest_LIBS
 622                 ${LIBEPAN_LIBS}
 623         )
 624         set(dftest_FILES
 625                 dftest.c
 626                 util.c
 627         )
 628         add_executable(dftest ${dftest_FILES})
 629         target_link_libraries(dftest ${dftest_LIBS})
 630         install(TARGETS dftest RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 631 endif()
 632
 633 if(BUILD_randpkt)
 634         set(randpkt_LIBS
 635                 wiretap
 636                 ${M_LIBRARIES}
 637                 ${PCAP_LIBRARIES}
 638 #               @SOCKET_LIBS@
 639 #               @NSL_LIBS@
 640                 ${CARES_LIBRARIES}
 641                 ${ADNS_LIBRARIES}
 642                 ${Z_LIBRARIES}
 643         )
 644         set(randpkt_FILES
 645                 randpkt.c
 646         )
 647         add_executable(randpkt ${randpkt_FILES})
 648         target_link_libraries(randpkt ${randpkt_LIBS})
 649         install(TARGETS randpkt RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 650 endif()
 651
 652 if(BUILD_text2pcap)
 653         set(text2pcap_LIBS
 654                 wiretap
 655                 ${M_LIBRARIES}
 656                 ${Z_LIBRARIES}
 657         )
 658         set(text2pcap_FILES
 659                 text2pcap.c
 660         )
 661         set(text2pcap_CLEAN_FILES
 662                 ${text2pcap_FILES}
 663         )
 664         add_lex_files(text2pcap_FILES
 665                 text2pcap-scanner.l
 666         )
 667         add_executable(text2pcap ${text2pcap_FILES})
 668         add_dependencies(text2pcap svnversion)
 669         target_link_libraries(text2pcap ${text2pcap_LIBS})
 670         install(TARGETS text2pcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 671 endif()
 672
 673 if(BUILD_mergecap)
 674         set(mergecap_LIBS
 675                 wiretap
 676                 ${Z_LIBRARIES}
 677         )
 678         set(mergecap_FILES
 679                 mergecap.c
 680                 merge.c
 681                 svnversion.h
 682         )
 683         add_executable(mergecap ${mergecap_FILES})
 684         add_dependencies(mergecap svnversion)
 685         target_link_libraries(mergecap ${mergecap_LIBS})
 686         install(TARGETS mergecap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 687 endif()
 688
 689 if(BUILD_capinfos)
 690         set(capinfos_LIBS
 691                 wiretap
 692                 ${Z_LIBRARIES}
 693                 ${GCRYPT_LIBRARIES}
 694                 ${APPLE_COCOA_LIBRARY}
 695         )
 696         set(capinfos_FILES
 697                 capinfos.c
 698                 ${WTAP_PLUGIN_SOURCES}
 699         )
 700         add_executable(capinfos ${capinfos_FILES})
 701         target_link_libraries(capinfos ${capinfos_LIBS})
 702         install(TARGETS capinfos RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 703 endif()
 704
 705 if(BUILD_editcap)
 706         set(editcap_LIBS
 707                 wiretap
 708                 ${Z_LIBRARIES}
 709         )
 710         set(editcap_FILES
 711                 editcap.c
 712                 epan/crypt/crypt-md5.c
 713                 epan/nstime.c
 714                 ${WTAP_PLUGIN_SOURCES}
 715         )
 716         add_executable(editcap ${editcap_FILES})
 717         add_dependencies(editcap svnversion)
 718         target_link_libraries(editcap ${editcap_LIBS})
 719         install(TARGETS editcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 720 endif()
 721
 722 if(BUILD_dumpcap)
 723         set(dumpcap_LIBS
 724                 wiretap
 725 #               @INET_NTOP_LO@
 726                 ${PCAP_LIBRARIES}
 727                 ${CAP_LIBRARIES}
 728 #               @SOCKET_LIBS@
 729 #               @NSL_LIBS@
 730                 ${GCRYPT_LIBRARIES}
 731                 ${GNUTLS_LIBRARIES}
 732                 ${Z_LIBRARIES}
 733                 ${APPLE_COCOA_LIBRARY}
 734         )
 735         set(dumpcap_FILES
 736                 svnversion.h
 737                 capture_opts.c
 738                 capture-pcap-util.c
 739                 capture_stop_conditions.c
 740                 clopts_common.c
 741                 conditions.c
 742                 dumpcap.c
 743                 pcapio.c
 744                 ringbuffer.c
 745                 sync_pipe_write.c
 746                 tempfile.c
 747                 version_info.c
 748                 ${PLATFORM_SRC}
 749         )
 750         add_executable(dumpcap ${dumpcap_FILES})
 751         add_dependencies(dumpcap svnversion)
 752         target_link_libraries(dumpcap ${dumpcap_LIBS})
 753         install(TARGETS dumpcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 754 endif()
 755
 756 ADD_CUSTOM_COMMAND(
 757         OUTPUT  AUTHORS-SHORT
 758         COMMAND ${PERL}
 759                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 760                 ${CMAKE_SOURCE_DIR}/doc/make-authors-short.pl
 761                 < ${CMAKE_SOURCE_DIR}/AUTHORS
 762                 > AUTHORS-SHORT
 763         DEPENDS
 764                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 765                 ${CMAKE_SOURCE_DIR}/doc/make-authors-short.pl
 766                 ${CMAKE_SOURCE_DIR}/AUTHORS
 767 )
 768
 769 ADD_CUSTOM_COMMAND(
 770         OUTPUT  AUTHORS-SHORT-FORMAT
 771                 wireshark.pod
 772         COMMAND ${PERL}
 773                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 774                 ${CMAKE_SOURCE_DIR}/doc/make-authors-format.pl
 775                 < AUTHORS-SHORT
 776                 > AUTHORS-SHORT-FORMAT
 777         COMMAND cat
 778                 ${CMAKE_SOURCE_DIR}/doc/wireshark.pod.template
 779                 AUTHORS-SHORT-FORMAT
 780                 > wireshark.pod
 781         DEPENDS
 782                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 783                 ${CMAKE_SOURCE_DIR}/doc/make-authors-format.pl
 784                 AUTHORS-SHORT
 785                 ${CMAKE_SOURCE_DIR}/doc/wireshark.pod.template
 786 )
 787
 788 ADD_CUSTOM_COMMAND(
 789         OUTPUT  wireshark-filter.pod
 790         COMMAND tshark
 791                 -G fields |
 792                 ${PERL}
 793                 ${CMAKE_SOURCE_DIR}/doc/dfilter2pod.pl
 794                 ${CMAKE_SOURCE_DIR}/doc/wireshark-filter.pod.template
 795                 > wireshark-filter.pod
 796         DEPENDS
 797                 ${CMAKE_SOURCE_DIR}/doc/dfilter2pod.pl
 798                 ${CMAKE_SOURCE_DIR}/doc/wireshark-filter.pod.template
 799                 tshark
 800 )
 801
 802 find_package(POD)
 803
 804 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/capinfos 1 )
 805 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/dumpcap 1 )
 806 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/editcap 1 )
 807 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/idl2wrs 1 )
 808 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/mergecap 1 )
 809 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/rawshark 1 )
 810 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/text2pcap 1 )
 811 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/tshark 1 )
 812 pod2manhtml( wireshark 1 )
 813 pod2manhtml( wireshark-filter 4 )
 814
 815 add_custom_target(
 816         auxiliary ALL
 817         DEPENDS
 818                 AUTHORS-SHORT
 819                 capinfos.html
 820                 dumpcap.html
 821                 editcap.html
 822                 idl2wrs.html
 823                 mergecap.html
 824                 rawshark.html
 825                 text2pcap.html
 826                 tshark.html
 827                 wireshark.html
 828                 wireshark-filter.html
 829 )
 830
 831 set(MAN1_FILES
 832         ${CMAKE_BINARY_DIR}/capinfos.1
 833         ${CMAKE_BINARY_DIR}/dumpcap.1
 834         ${CMAKE_BINARY_DIR}/editcap.1
 835         ${CMAKE_BINARY_DIR}/idl2wrs.1
 836         ${CMAKE_BINARY_DIR}/mergecap.1
 837         ${CMAKE_BINARY_DIR}/rawshark.1
 838         ${CMAKE_BINARY_DIR}/text2pcap.1
 839         ${CMAKE_BINARY_DIR}/tshark.1
 840         ${CMAKE_BINARY_DIR}/wireshark.1
 841 )
 842
 843 set(MAN4_FILES
 844         ${CMAKE_BINARY_DIR}/wireshark-filter.4
 845 )
 846
 847 set(CLEAN_FILES
 848         ${wireshark_FILES}
 849         ${tshark_FILES}
 850         ${rawshark_FILES}
 851         ${dftest_FILES}
 852         ${randpkt_FILES}
 853         ${text2pcap_CLEAN_FILES}
 854         ${mergecap_FILES}
 855         ${capinfos_FILES}
 856         ${editcap_FILES}
 857         ${dumpcap_FILES}
 858 )
 859
 860 if (WERROR)
 861         set_source_files_properties(
 862                 ${CLEAN_FILES}
 863                 PROPERTIES
 864                 COMPILE_FLAGS -Werror
 865         )
 866 endif()
 867
 868 install(
 869         FILES
 870                 ${INSTALL_FILES}
 871         DESTINATION
 872                 ${CMAKE_INSTALL_DATADIR}/${CPACK_PACKAGE_NAME}
 873 )
 874
 875 install(
 876         FILES
 877                 ${MAN1_FILES}
 878         DESTINATION
 879                 ${CMAKE_INSTALL_MANDIR}/man1
 880 )
 881
 882 install(
 883         FILES
 884                 ${MAN4_FILES}
 885         DESTINATION
 886                 ${CMAKE_INSTALL_MANDIR}/man4
 887 )
 888
 889 install(
 890         DIRECTORY
 891                 ${INSTALL_DIRS}
 892         DIRECTORY_PERMISSIONS
 893                 OWNER_EXECUTE OWNER_WRITE OWNER_READ
 894                 GROUP_EXECUTE GROUP_READ
 895                 WORLD_EXECUTE WORLD_READ
 896         DESTINATION
 897                 ${CMAKE_INSTALL_DATADIR}/${CPACK_PACKAGE_NAME}
 898         PATTERN ".svn" EXCLUDE
 899         PATTERN "Makefile.*" EXCLUDE
 900         PATTERN "faq.py" EXCLUDE
 901 )