selftest/selftest.pl

   1 #!/usr/bin/perl
   2 # Bootstrap Samba and run a number of tests against it.
   3 # Copyright (C) 2005-2010 Jelmer Vernooij <jelmer@samba.org>
   4 # Copyright (C) 2007-2009 Stefan Metzmacher <metze@samba.org>
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 use strict;
  20
  21 use FindBin qw($RealBin $Script);
  22 use File::Spec;
  23 use File::Temp qw(tempfile);
  24 use Getopt::Long;
  25 use POSIX;
  26 use Cwd qw(abs_path);
  27 use lib "$RealBin";
  28 use Subunit;
  29 use SocketWrapper;
  30
  31 eval {
  32 require Time::HiRes;
  33 Time::HiRes->import("time");
  34 };
  35 if ($@) {
  36         print "You don't have Time::Hires installed !\n";
  37 }
  38
  39 my $opt_help = 0;
  40 my $opt_target = "samba";
  41 my $opt_quick = 0;
  42 my $opt_socket_wrapper = 0;
  43 my $opt_socket_wrapper_pcap = undef;
  44 my $opt_socket_wrapper_keep_pcap = undef;
  45 my $opt_random_order = 0;
  46 my $opt_one = 0;
  47 my @opt_exclude = ();
  48 my @opt_include = ();
  49 my $opt_testenv = 0;
  50 my $opt_list = 0;
  51 my $ldap = undef;
  52 my $opt_resetup_env = undef;
  53 my $opt_binary_mapping = "";
  54 my $opt_load_list = undef;
  55 my $opt_libnss_wrapper_so_path = "";
  56 my $opt_libsocket_wrapper_so_path = "";
  57 my $opt_libuid_wrapper_so_path = "";
  58 my @testlists = ();
  59
  60 my $srcdir = ".";
  61 my $bindir = "./bin";
  62 my $prefix = "./st";
  63
  64 my @includes = ();
  65 my @excludes = ();
  66
  67 sub find_in_list($$)
  68 {
  69         my ($list, $fullname) = @_;
  70
  71         foreach (@$list) {
  72                 if ($fullname =~ /$$_[0]/) {
  73                          return ($$_[1]) if ($$_[1]);
  74                          return "";
  75                 }
  76         }
  77
  78         return undef;
  79 }
  80
  81 sub skip($)
  82 {
  83         my ($name) = @_;
  84
  85         return find_in_list(\@excludes, $name);
  86 }
  87
  88 sub getlog_env($);
  89
  90 sub setup_pcap($)
  91 {
  92         my ($name) = @_;
  93
  94         return unless ($opt_socket_wrapper_pcap);
  95         return unless defined($ENV{SOCKET_WRAPPER_PCAP_DIR});
  96
  97         my $fname = $name;
  98         $fname =~ s%[^abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789\-]%_%g;
  99
 100         my $pcap_file = "$ENV{SOCKET_WRAPPER_PCAP_DIR}/$fname.pcap";
 101
 102         SocketWrapper::setup_pcap($pcap_file);
 103
 104         return $pcap_file;
 105 }
 106
 107 sub cleanup_pcap($$)
 108 {
 109         my ($pcap_file, $exitcode) = @_;
 110
 111         return unless ($opt_socket_wrapper_pcap);
 112         return if ($opt_socket_wrapper_keep_pcap);
 113         return unless ($exitcode == 0);
 114         return unless defined($pcap_file);
 115
 116         unlink($pcap_file);
 117 }
 118
 119 # expand strings from %ENV
 120 sub expand_environment_strings($)
 121 {
 122         my $s = shift;
 123         # we use a reverse sort so we do the longer ones first
 124         foreach my $k (sort { $b cmp $a } keys %ENV) {
 125                 $s =~ s/\$$k/$ENV{$k}/g;
 126         }
 127         return $s;
 128 }
 129
 130 sub run_testsuite($$$$$)
 131 {
 132         my ($envname, $name, $cmd, $i, $totalsuites) = @_;
 133         my $pcap_file = setup_pcap($name);
 134
 135         Subunit::start_testsuite($name);
 136         Subunit::progress_push();
 137         Subunit::report_time(time());
 138         system($cmd);
 139         Subunit::report_time(time());
 140         Subunit::progress_pop();
 141
 142         if ($? == -1) {
 143                 Subunit::progress_pop();
 144                 Subunit::end_testsuite($name, "error", "Unable to run $cmd: $!");
 145                 exit(1);
 146         } elsif ($? & 127) {
 147                 Subunit::end_testsuite($name, "error",
 148                         sprintf("%s died with signal %d, %s coredump\n", $cmd, ($? & 127),  ($? & 128) ? 'with' : 'without'));
 149                 exit(1);
 150         }
 151
 152         my $exitcode = $? >> 8;
 153
 154         my $envlog = getlog_env($envname);
 155         if ($envlog ne "") {
 156                 print "envlog: $envlog\n";
 157         }
 158
 159         print "command: $cmd\n";
 160         printf "expanded command: %s\n", expand_environment_strings($cmd);
 161
 162         if ($exitcode == 0) {
 163                 Subunit::end_testsuite($name, "success");
 164         } else {
 165                 Subunit::end_testsuite($name, "failure", "Exit code was $exitcode");
 166         }
 167
 168         cleanup_pcap($pcap_file, $exitcode);
 169
 170         if (not $opt_socket_wrapper_keep_pcap and defined($pcap_file)) {
 171                 print "PCAP FILE: $pcap_file\n";
 172         }
 173
 174         if ($exitcode != 0) {
 175                 exit(1) if ($opt_one);
 176         }
 177
 178         return $exitcode;
 179 }
 180
 181 sub ShowHelp()
 182 {
 183         print "Samba test runner
 184 Copyright (C) Jelmer Vernooij <jelmer\@samba.org>
 185 Copyright (C) Stefan Metzmacher <metze\@samba.org>
 186
 187 Usage: $Script [OPTIONS] TESTNAME-REGEX
 188
 189 Generic options:
 190  --help                     this help page
 191  --target=samba[3]|win      Samba version to target
 192  --testlist=FILE            file to read available tests from
 193
 194 Paths:
 195  --prefix=DIR               prefix to run tests in [st]
 196  --srcdir=DIR               source directory [.]
 197  --bindir=DIR               binaries directory [./bin]
 198
 199 Preload cwrap:
 200  --nss_wrapper_so_path=FILE the nss_wrapper library to preload
 201  --socket_wrapper_so_path=FILE the socket_wrapper library to preload
 202  --uid_wrapper_so_path=FILE the uid_wrapper library to preload
 203
 204 Target Specific:
 205  --socket-wrapper-pcap      save traffic to pcap directories
 206  --socket-wrapper-keep-pcap keep all pcap files, not just those for tests that
 207                             failed
 208  --socket-wrapper           enable socket wrapper
 209
 210 Samba4 Specific:
 211  --ldap=openldap|fedora-ds  back samba onto specified ldap server
 212
 213 Behaviour:
 214  --quick                    run quick overall test
 215  --one                      abort when the first test fails
 216  --testenv                  run a shell in the requested test environment
 217  --list                     list available tests
 218 ";
 219         exit(0);
 220 }
 221
 222 my $result = GetOptions (
 223                 'help|h|?' => \$opt_help,
 224                 'target=s' => \$opt_target,
 225                 'prefix=s' => \$prefix,
 226                 'socket-wrapper' => \$opt_socket_wrapper,
 227                 'socket-wrapper-pcap' => \$opt_socket_wrapper_pcap,
 228                 'socket-wrapper-keep-pcap' => \$opt_socket_wrapper_keep_pcap,
 229                 'quick' => \$opt_quick,
 230                 'one' => \$opt_one,
 231                 'exclude=s' => \@opt_exclude,
 232                 'include=s' => \@opt_include,
 233                 'srcdir=s' => \$srcdir,
 234                 'bindir=s' => \$bindir,
 235                 'testenv' => \$opt_testenv,
 236                 'list' => \$opt_list,
 237                 'ldap:s' => \$ldap,
 238                 'resetup-environment' => \$opt_resetup_env,
 239                 'testlist=s' => \@testlists,
 240                 'random-order' => \$opt_random_order,
 241                 'load-list=s' => \$opt_load_list,
 242                 'binary-mapping=s' => \$opt_binary_mapping,
 243                 'nss_wrapper_so_path=s' => \$opt_libnss_wrapper_so_path,
 244                 'socket_wrapper_so_path=s' => \$opt_libsocket_wrapper_so_path,
 245                 'uid_wrapper_so_path=s' => \$opt_libuid_wrapper_so_path
 246             );
 247
 248 exit(1) if (not $result);
 249
 250 ShowHelp() if ($opt_help);
 251
 252 die("--list and --testenv are mutually exclusive") if ($opt_list and $opt_testenv);
 253
 254 # we want unbuffered output
 255 $| = 1;
 256
 257 my @tests = @ARGV;
 258
 259 # quick hack to disable rpc validation when using valgrind - its way too slow
 260 unless (defined($ENV{VALGRIND})) {
 261         $ENV{VALIDATE} = "validate";
 262         $ENV{MALLOC_CHECK_} = 3;
 263 }
 264
 265 # make all our python scripts unbuffered
 266 $ENV{PYTHONUNBUFFERED} = 1;
 267
 268 my $bindir_abs = abs_path($bindir);
 269
 270 # Backwards compatibility:
 271 if (defined($ENV{TEST_LDAP}) and $ENV{TEST_LDAP} eq "yes") {
 272         if (defined($ENV{FEDORA_DS_ROOT})) {
 273                 $ldap = "fedora-ds";
 274         } else {
 275                 $ldap = "openldap";
 276         }
 277 }
 278
 279 my $torture_maxtime = ($ENV{TORTURE_MAXTIME} or 1200);
 280 if ($ldap) {
 281         # LDAP is slow
 282         $torture_maxtime *= 2;
 283 }
 284
 285 $prefix =~ s+//+/+;
 286 $prefix =~ s+/./+/+;
 287 $prefix =~ s+/$++;
 288
 289 die("using an empty prefix isn't allowed") unless $prefix ne "";
 290
 291 # Ensure we have the test prefix around.
 292 #
 293 # We need restrictive
 294 # permissions on this as some subdirectories in this tree will have
 295 # wider permissions (ie 0777) and this would allow other users on the
 296 # host to subvert the test process.
 297 mkdir($prefix, 0700) unless -d $prefix;
 298 chmod 0700, $prefix;
 299
 300 my $prefix_abs = abs_path($prefix);
 301 my $tmpdir_abs = abs_path("$prefix/tmp");
 302 mkdir($tmpdir_abs, 0777) unless -d $tmpdir_abs;
 303
 304 my $srcdir_abs = abs_path($srcdir);
 305
 306 die("using an empty absolute prefix isn't allowed") unless $prefix_abs ne "";
 307 die("using '/' as absolute prefix isn't allowed") unless $prefix_abs ne "/";
 308
 309 $ENV{PREFIX} = $prefix;
 310 $ENV{KRB5CCNAME} = "$prefix/krb5ticket";
 311 $ENV{PREFIX_ABS} = $prefix_abs;
 312 $ENV{SRCDIR} = $srcdir;
 313 $ENV{SRCDIR_ABS} = $srcdir_abs;
 314 $ENV{BINDIR} = $bindir_abs;
 315
 316 my $tls_enabled = not $opt_quick;
 317 $ENV{TLS_ENABLED} = ($tls_enabled?"yes":"no");
 318
 319 sub prefix_pathvar($$)
 320 {
 321         my ($name, $newpath) = @_;
 322         if (defined($ENV{$name})) {
 323                 $ENV{$name} = "$newpath:$ENV{$name}";
 324         } else {
 325                 $ENV{$name} = $newpath;
 326         }
 327 }
 328 prefix_pathvar("PKG_CONFIG_PATH", "$bindir_abs/pkgconfig");
 329 prefix_pathvar("PYTHONPATH", "$bindir_abs/python");
 330
 331 if ($opt_socket_wrapper_keep_pcap) {
 332         # Socket wrapper keep pcap implies socket wrapper pcap
 333         $opt_socket_wrapper_pcap = 1;
 334 }
 335
 336 if ($opt_socket_wrapper_pcap) {
 337         # Socket wrapper pcap implies socket wrapper
 338         $opt_socket_wrapper = 1;
 339 }
 340
 341 my $ld_preload = $ENV{LD_PRELOAD};
 342
 343 if ($opt_libnss_wrapper_so_path) {
 344         if ($ld_preload) {
 345                 $ld_preload = "$ld_preload:$opt_libnss_wrapper_so_path";
 346         } else {
 347                 $ld_preload = "$opt_libnss_wrapper_so_path";
 348         }
 349 }
 350
 351 if ($opt_libsocket_wrapper_so_path) {
 352         if ($ld_preload) {
 353                 $ld_preload = "$ld_preload:$opt_libsocket_wrapper_so_path";
 354         } else {
 355                 $ld_preload = "$opt_libsocket_wrapper_so_path";
 356         }
 357 }
 358
 359 if ($opt_libuid_wrapper_so_path) {
 360         if ($ld_preload) {
 361                 $ld_preload = "$ld_preload:$opt_libuid_wrapper_so_path";
 362         } else {
 363                 $ld_preload = "$opt_libuid_wrapper_so_path";
 364         }
 365 }
 366
 367 $ENV{LD_PRELOAD} = $ld_preload;
 368 print "LD_PRELOAD=$ENV{LD_PRELOAD}\n";
 369
 370 # Enable uid_wrapper globally
 371 $ENV{UID_WRAPPER} = 1;
 372
 373 # Disable RTLD_DEEPBIND hack for Samba bind dlz module
 374 #
 375 # This is needed in order to allow the ldb_*ldap module
 376 # to work with a preloaded socket wrapper.
 377 $ENV{LDB_MODULES_DISABLE_DEEPBIND} = 1;
 378
 379 my $socket_wrapper_dir;
 380 if ($opt_socket_wrapper) {
 381         $socket_wrapper_dir = SocketWrapper::setup_dir("$prefix_abs/w", $opt_socket_wrapper_pcap);
 382         print "SOCKET_WRAPPER_DIR=$socket_wrapper_dir\n";
 383 } elsif (not $opt_list) {
 384          unless ($< == 0) {
 385                  warn("not using socket wrapper, but also not running as root. Will not be able to listen on proper ports");
 386          }
 387 }
 388
 389 my $target;
 390 my $testenv_default = "none";
 391
 392 my %binary_mapping = ();
 393 if ($opt_binary_mapping) {
 394     my @binmapping_list = split(/,/, $opt_binary_mapping);
 395     foreach my $mapping (@binmapping_list) {
 396         my ($bin, $map) = split(/\:/, $mapping);
 397         $binary_mapping{$bin} = $map;
 398     }
 399 }
 400
 401 $ENV{BINARY_MAPPING} = $opt_binary_mapping;
 402
 403 # After this many seconds, the server will self-terminate.  All tests
 404 # must terminate in this time, and testenv will only stay alive this
 405 # long
 406
 407 my $server_maxtime = 7500;
 408 if (defined($ENV{SMBD_MAXTIME}) and $ENV{SMBD_MAXTIME} ne "") {
 409     $server_maxtime = $ENV{SMBD_MAXTIME};
 410 }
 411
 412 unless ($opt_list) {
 413         if ($opt_target eq "samba") {
 414                 $testenv_default = "dc";
 415                 require target::Samba;
 416                 $target = new Samba($bindir, \%binary_mapping, $ldap, $srcdir, $server_maxtime);
 417         } elsif ($opt_target eq "samba3") {
 418                 $testenv_default = "member";
 419                 require target::Samba3;
 420                 $target = new Samba3($bindir, \%binary_mapping, $srcdir_abs, $server_maxtime);
 421         }
 422 }
 423
 424 sub read_test_regexes($)
 425 {
 426         my ($name) = @_;
 427         my @ret = ();
 428         open(LF, "<$name") or die("unable to read $name: $!");
 429         while (<LF>) {
 430                 chomp;
 431                 next if (/^#/);
 432                 if (/^(.*?)([ \t]+)\#([\t ]*)(.*?)$/) {
 433                         push (@ret, [$1, $4]);
 434                 } else {
 435                         s/^(.*?)([ \t]+)\#([\t ]*)(.*?)$//;
 436                         push (@ret, [$_, undef]);
 437                 }
 438         }
 439         close(LF);
 440         return @ret;
 441 }
 442
 443 foreach (@opt_exclude) {
 444         push (@excludes, read_test_regexes($_));
 445 }
 446
 447 foreach (@opt_include) {
 448         push (@includes, read_test_regexes($_));
 449 }
 450
 451 my $interfaces = join(',', ("127.0.0.11/8",
 452                             "127.0.0.12/8",
 453                             "127.0.0.13/8",
 454                             "127.0.0.14/8",
 455                             "127.0.0.15/8",
 456                             "127.0.0.16/8"));
 457
 458 my $clientdir = "$prefix_abs/client";
 459
 460 my $conffile = "$clientdir/client.conf";
 461 $ENV{SMB_CONF_PATH} = $conffile;
 462
 463 sub write_clientconf($$$)
 464 {
 465         my ($conffile, $clientdir, $vars) = @_;
 466
 467         mkdir("$clientdir", 0777) unless -d "$clientdir";
 468
 469         if ( -d "$clientdir/private" ) {
 470                 unlink <$clientdir/private/*>;
 471         } else {
 472                 mkdir("$clientdir/private", 0777);
 473         }
 474
 475         if ( -d "$clientdir/lockdir" ) {
 476                 unlink <$clientdir/lockdir/*>;
 477         } else {
 478                 mkdir("$clientdir/lockdir", 0777);
 479         }
 480
 481         if ( -d "$clientdir/statedir" ) {
 482                 unlink <$clientdir/statedir/*>;
 483         } else {
 484                 mkdir("$clientdir/statedir", 0777);
 485         }
 486
 487         if ( -d "$clientdir/cachedir" ) {
 488                 unlink <$clientdir/cachedir/*>;
 489         } else {
 490                 mkdir("$clientdir/cachedir", 0777);
 491         }
 492
 493         # this is ugly, but the ncalrpcdir needs exactly 0755
 494         # otherwise tests fail.
 495         my $mask = umask;
 496         umask 0022;
 497         if ( -d "$clientdir/ncalrpcdir/np" ) {
 498                 unlink <$clientdir/ncalrpcdir/np/*>;
 499                 rmdir "$clientdir/ncalrpcdir/np";
 500         }
 501         if ( -d "$clientdir/ncalrpcdir" ) {
 502                 unlink <$clientdir/ncalrpcdir/*>;
 503                 rmdir "$clientdir/ncalrpcdir";
 504         }
 505         mkdir("$clientdir/ncalrpcdir", 0755);
 506         umask $mask;
 507
 508         open(CF, ">$conffile");
 509         print CF "[global]\n";
 510         print CF "\tnetbios name = client\n";
 511         if (defined($vars->{DOMAIN})) {
 512                 print CF "\tworkgroup = $vars->{DOMAIN}\n";
 513         }
 514         if (defined($vars->{REALM})) {
 515                 print CF "\trealm = $vars->{REALM}\n";
 516         }
 517         if ($opt_socket_wrapper) {
 518                 print CF "\tinterfaces = $interfaces\n";
 519         }
 520         print CF "
 521         private dir = $clientdir/private
 522         lock dir = $clientdir/lockdir
 523         state directory = $clientdir/statedir
 524         cache directory = $clientdir/cachedir
 525         ncalrpc dir = $clientdir/ncalrpcdir
 526         name resolve order = file bcast
 527         panic action = $RealBin/gdb_backtrace \%d
 528         max xmit = 32K
 529         notify:inotify = false
 530         ldb:nosync = true
 531         system:anonymous = true
 532         client lanman auth = Yes
 533         log level = 1
 534         torture:basedir = $clientdir
 535 #We don't want to pass our self-tests if the PAC code is wrong
 536         gensec:require_pac = true
 537         resolv:host file = $prefix_abs/dns_host_file
 538 #We don't want to run 'speed' tests for very long
 539         torture:timelimit = 1
 540         winbind separator = /
 541 ";
 542         close(CF);
 543 }
 544
 545 my @todo = ();
 546
 547 sub should_run_test($)
 548 {
 549         my $name = shift;
 550         if ($#tests == -1) {
 551                 return 1;
 552         }
 553         for (my $i=0; $i <= $#tests; $i++) {
 554                 if ($name =~ /$tests[$i]/i) {
 555                         return 1;
 556                 }
 557         }
 558         return 0;
 559 }
 560
 561 sub read_testlist($)
 562 {
 563         my ($filename) = @_;
 564
 565         my @ret = ();
 566         open(IN, $filename) or die("Unable to open $filename: $!");
 567
 568         while (<IN>) {
 569                 if (/-- TEST(-LOADLIST|-IDLIST|) --\n/) {
 570                         my $supports_loadlist = (defined($1) and $1 eq "-LOADLIST");
 571                         my $supports_idlist = (defined($1) and $1 eq "-IDLIST");
 572                         my $name = <IN>;
 573                         $name =~ s/\n//g;
 574                         my $env = <IN>;
 575                         $env =~ s/\n//g;
 576                         my $cmdline = <IN>;
 577                         $cmdline =~ s/\n//g;
 578                         if (should_run_test($name) == 1) {
 579                                 push (@ret, [$name, $env, $cmdline, $supports_loadlist, $supports_idlist]);
 580                         }
 581                 } else {
 582                         print;
 583                 }
 584         }
 585         close(IN) or die("Error creating recipe from $filename");
 586         return @ret;
 587 }
 588
 589 if ($#testlists == -1) {
 590         die("No testlists specified");
 591 }
 592
 593 $ENV{SELFTEST_PREFIX} = "$prefix_abs";
 594 $ENV{SELFTEST_TMPDIR} = "$tmpdir_abs";
 595 $ENV{TEST_DATA_PREFIX} = "$tmpdir_abs";
 596 if ($opt_socket_wrapper) {
 597         $ENV{SELFTEST_INTERFACES} = $interfaces;
 598 } else {
 599         $ENV{SELFTEST_INTERFACES} = "";
 600 }
 601 if ($opt_quick) {
 602         $ENV{SELFTEST_QUICK} = "1";
 603 } else {
 604         $ENV{SELFTEST_QUICK} = "";
 605 }
 606 $ENV{SELFTEST_MAXTIME} = $torture_maxtime;
 607
 608 my @available = ();
 609 foreach my $fn (@testlists) {
 610         foreach (read_testlist($fn)) {
 611                 my $name = $$_[0];
 612                 next if (@includes and not defined(find_in_list(\@includes, $name)));
 613                 push (@available, $_);
 614         }
 615 }
 616
 617 my $restricted = undef;
 618 my $restricted_used = {};
 619
 620 if ($opt_load_list) {
 621         $restricted = [];
 622         open(LOAD_LIST, "<$opt_load_list") or die("Unable to open $opt_load_list");
 623         while (<LOAD_LIST>) {
 624                 chomp;
 625                 push (@$restricted, $_);
 626         }
 627         close(LOAD_LIST);
 628 }
 629
 630 my $individual_tests = undef;
 631 $individual_tests = {};
 632
 633 foreach my $testsuite (@available) {
 634         my $name = $$testsuite[0];
 635         my $skipreason = skip($name);
 636         if (defined($restricted)) {
 637                 # Find the testsuite for this test
 638                 my $match = undef;
 639                 foreach my $r (@$restricted) {
 640                         if ($r eq $name) {
 641                                 $individual_tests->{$name} = [];
 642                                 $match = $r;
 643                                 $restricted_used->{$r} = 1;
 644                         } elsif (substr($r, 0, length($name)+1) eq "$name.") {
 645                                 push(@{$individual_tests->{$name}}, $r);
 646                                 $match = $r;
 647                                 $restricted_used->{$r} = 1;
 648                         }
 649                 }
 650                 if ($match) {
 651                         if (defined($skipreason)) {
 652                                 if (not $opt_list) {
 653                                         Subunit::skip_testsuite($name, $skipreason);
 654                                 }
 655                         } else {
 656                                 push(@todo, $testsuite);
 657                         }
 658                 }
 659         } elsif (defined($skipreason)) {
 660                 if (not $opt_list) {
 661                         Subunit::skip_testsuite($name, $skipreason);
 662                 }
 663         } else {
 664                 push(@todo, $testsuite);
 665         }
 666 }
 667
 668 if (defined($restricted)) {
 669         foreach (@$restricted) {
 670                 unless (defined($restricted_used->{$_})) {
 671                         print "No test or testsuite found matching $_\n";
 672                 }
 673         }
 674 } elsif ($#todo == -1) {
 675         print STDERR "No tests to run\n";
 676         exit(1);
 677 }
 678
 679 my $suitestotal = $#todo + 1;
 680
 681 unless ($opt_list) {
 682         Subunit::progress($suitestotal);
 683         Subunit::report_time(time());
 684 }
 685
 686 my $i = 0;
 687 $| = 1;
 688
 689 my %running_envs = ();
 690
 691 sub get_running_env($)
 692 {
 693         my ($name) = @_;
 694
 695         my $envname = $name;
 696
 697         $envname =~ s/:.*//;
 698
 699         return $running_envs{$envname};
 700 }
 701
 702 my @exported_envvars = (
 703         # domain stuff
 704         "DOMAIN",
 705         "REALM",
 706
 707         # domain controller stuff
 708         "DC_SERVER",
 709         "DC_SERVER_IP",
 710         "DC_SERVER_IPV6",
 711         "DC_NETBIOSNAME",
 712         "DC_NETBIOSALIAS",
 713
 714         # domain member
 715         "MEMBER_SERVER",
 716         "MEMBER_SERVER_IP",
 717         "MEMBER_SERVER_IPV6",
 718         "MEMBER_NETBIOSNAME",
 719         "MEMBER_NETBIOSALIAS",
 720
 721         # rpc proxy controller stuff
 722         "RPC_PROXY_SERVER",
 723         "RPC_PROXY_SERVER_IP",
 724         "RPC_PROXY_SERVER_IPV6",
 725         "RPC_PROXY_NETBIOSNAME",
 726         "RPC_PROXY_NETBIOSALIAS",
 727
 728         # domain controller stuff for Vampired DC
 729         "VAMPIRE_DC_SERVER",
 730         "VAMPIRE_DC_SERVER_IP",
 731         "VAMPIRE_DC_SERVER_IPV6",
 732         "VAMPIRE_DC_NETBIOSNAME",
 733         "VAMPIRE_DC_NETBIOSALIAS",
 734
 735         "PROMOTED_DC_SERVER",
 736         "PROMOTED_DC_SERVER_IP",
 737         "PROMOTED_DC_SERVER_IPV6",
 738         "PROMOTED_DC_NETBIOSNAME",
 739         "PROMOTED_DC_NETBIOSALIAS",
 740
 741         # server stuff
 742         "SERVER",
 743         "SERVER_IP",
 744         "SERVER_IPV6",
 745         "NETBIOSNAME",
 746         "NETBIOSALIAS",
 747
 748         # user stuff
 749         "USERNAME",
 750         "USERID",
 751         "PASSWORD",
 752         "DC_USERNAME",
 753         "DC_PASSWORD",
 754
 755         # misc stuff
 756         "KRB5_CONFIG",
 757         "SELFTEST_WINBINDD_SOCKET_DIR",
 758         "WINBINDD_PRIV_PIPE_DIR",
 759         "NMBD_SOCKET_DIR",
 760         "LOCAL_PATH",
 761
 762         # nss_wrapper
 763         "NSS_WRAPPER_PASSWD",
 764         "NSS_WRAPPER_GROUP",
 765
 766         # UID/GID for rfc2307 mapping tests
 767         "UID_RFC2307TEST",
 768         "GID_RFC2307TEST"
 769 );
 770
 771 sub sighandler($)
 772 {
 773         my $signame = shift;
 774
 775         $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = 'DEFAULT';
 776         $SIG{PIPE} = 'IGNORE';
 777
 778         open(STDOUT, ">&STDERR") or die "can't dup STDOUT to STDERR: $!";
 779
 780         print "$0: PID[$$]: Got SIG${signame} teardown environments.\n";
 781         teardown_env($_) foreach(keys %running_envs);
 782         system("pstree -p $$");
 783         print "$0: PID[$$]: Exiting...\n";
 784         exit(1);
 785 };
 786
 787 $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = $SIG{PIPE} = \&sighandler;
 788
 789 sub setup_env($$)
 790 {
 791         my ($name, $prefix) = @_;
 792
 793         my $testenv_vars = undef;
 794
 795         my $envname = $name;
 796         my $option = $name;
 797
 798         $envname =~ s/:.*//;
 799         $option =~ s/^[^:]*//;
 800         $option =~ s/^://;
 801
 802         $option = "client" if $option eq "";
 803
 804         if ($envname eq "none") {
 805                 $testenv_vars = {};
 806         } elsif (defined(get_running_env($envname))) {
 807                 $testenv_vars = get_running_env($envname);
 808                 if (not $testenv_vars->{target}->check_env($testenv_vars)) {
 809                         print $testenv_vars->{target}->getlog_env($testenv_vars);
 810                         $testenv_vars = undef;
 811                 }
 812         } else {
 813                 $testenv_vars = $target->setup_env($envname, $prefix);
 814                 if (defined($testenv_vars) and $testenv_vars eq "UNKNOWN") {
 815                     return $testenv_vars;
 816                 } elsif (defined($testenv_vars) && not defined($testenv_vars->{target})) {
 817                         $testenv_vars->{target} = $target;
 818                 }
 819                 if (not defined($testenv_vars)) {
 820                         warn("$opt_target can't start up known environment '$envname'");
 821                 }
 822         }
 823
 824
 825         return undef unless defined($testenv_vars);
 826
 827         $running_envs{$envname} = $testenv_vars;
 828
 829         if ($option eq "local") {
 830                 SocketWrapper::set_default_iface($testenv_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 831                 $ENV{SMB_CONF_PATH} = $testenv_vars->{SERVERCONFFILE};
 832         } elsif ($option eq "client") {
 833                 SocketWrapper::set_default_iface(11);
 834                 write_clientconf($conffile, $clientdir, $testenv_vars);
 835                 $ENV{SMB_CONF_PATH} = $conffile;
 836         } else {
 837                 die("Unknown option[$option] for envname[$envname]");
 838         }
 839
 840         foreach (@exported_envvars) {
 841                 if (defined($testenv_vars->{$_})) {
 842                         $ENV{$_} = $testenv_vars->{$_};
 843                 } else {
 844                         delete $ENV{$_};
 845                 }
 846         }
 847
 848         return $testenv_vars;
 849 }
 850
 851 sub exported_envvars_str($)
 852 {
 853         my ($testenv_vars) = @_;
 854         my $out = "";
 855
 856         foreach (@exported_envvars) {
 857                 next unless defined($testenv_vars->{$_});
 858                 $out .= $_."=".$testenv_vars->{$_}."\n";
 859         }
 860
 861         return $out;
 862 }
 863
 864 sub getlog_env($)
 865 {
 866         my ($envname) = @_;
 867         return "" if ($envname eq "none");
 868         my $env = get_running_env($envname);
 869         return $env->{target}->getlog_env($env);
 870 }
 871
 872 sub check_env($)
 873 {
 874         my ($envname) = @_;
 875         return 1 if ($envname eq "none");
 876         my $env = get_running_env($envname);
 877         return $env->{target}->check_env($env);
 878 }
 879
 880 sub teardown_env($)
 881 {
 882         my ($envname) = @_;
 883         return if ($envname eq "none");
 884         print STDERR "teardown_env($envname)\n";
 885         my $env = get_running_env($envname);
 886         $env->{target}->teardown_env($env);
 887         delete $running_envs{$envname};
 888 }
 889
 890 # This 'global' file needs to be empty when we start
 891 unlink("$prefix_abs/dns_host_file");
 892 unlink("$prefix_abs/hosts");
 893
 894 if ($opt_random_order) {
 895         require List::Util;
 896         my @newtodo = List::Util::shuffle(@todo);
 897         @todo = @newtodo;
 898 }
 899
 900 if ($opt_testenv) {
 901         my $testenv_name = $ENV{SELFTEST_TESTENV};
 902         $testenv_name = $testenv_default unless defined($testenv_name);
 903
 904         my $testenv_vars = setup_env($testenv_name, $prefix);
 905
 906         if (not $testenv_vars or $testenv_vars eq "UNKNOWN") {
 907                 die("Unable to setup environment $testenv_name");
 908         }
 909
 910         $ENV{PIDDIR} = $testenv_vars->{PIDDIR};
 911         $ENV{ENVNAME} = $testenv_name;
 912
 913         my $envvarstr = exported_envvars_str($testenv_vars);
 914
 915         my @term_args = ("echo -e \"
 916 Welcome to the Samba4 Test environment '$testenv_name'
 917
 918 This matches the client environment used in make test
 919 server is pid `cat \$PIDDIR/samba.pid`
 920
 921 Some useful environment variables:
 922 TORTURE_OPTIONS=\$TORTURE_OPTIONS
 923 SMB_CONF_PATH=\$SMB_CONF_PATH
 924
 925 $envvarstr
 926 \" && LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} bash");
 927         my @term = ();
 928         if ($ENV{TERMINAL}) {
 929             @term = ($ENV{TERMINAL});
 930         } else {
 931             @term = ("xterm", "-e");
 932             unshift(@term_args, ("bash", "-c"));
 933         }
 934
 935         system(@term, @term_args);
 936
 937         teardown_env($testenv_name);
 938 } elsif ($opt_list) {
 939         foreach (@todo) {
 940                 my $cmd = $$_[2];
 941                 my $name = $$_[0];
 942                 my $envname = $$_[1];
 943
 944                 unless($cmd =~ /\$LISTOPT/) {
 945                         warn("Unable to list tests in $name");
 946                         next;
 947                 }
 948
 949                 $cmd =~ s/\$LISTOPT/--list/g;
 950
 951                 system($cmd);
 952
 953                 if ($? == -1) {
 954                         die("Unable to run $cmd: $!");
 955                 } elsif ($? & 127) {
 956                         die(sprintf("%s died with signal %d, %s coredump\n", $cmd, ($? & 127),  ($? & 128) ? 'with' : 'without'));
 957                 }
 958
 959                 my $exitcode = $? >> 8;
 960                 if ($exitcode != 0) {
 961                         die("$cmd exited with exit code $exitcode");
 962                 }
 963         }
 964 } else {
 965         foreach (@todo) {
 966                 $i++;
 967                 my $cmd = $$_[2];
 968                 my $name = $$_[0];
 969                 my $envname = $$_[1];
 970
 971                 my $envvars = setup_env($envname, $prefix);
 972                 if (not defined($envvars)) {
 973                         Subunit::start_testsuite($name);
 974                         Subunit::end_testsuite($name, "error",
 975                                 "unable to set up environment $envname - exiting");
 976                         next;
 977                 } elsif ($envvars eq "UNKNOWN") {
 978                         Subunit::start_testsuite($name);
 979                         Subunit::end_testsuite($name, "skip",
 980                                 "environment $envname is unknown in this test backend - skipping");
 981                         next;
 982                 }
 983
 984                 # Generate a file with the individual tests to run, if the
 985                 # test runner for this test suite supports it.
 986                 if ($individual_tests and $individual_tests->{$name}) {
 987                         if ($$_[3]) {
 988                                 my ($fh, $listid_file) = tempfile(UNLINK => 0);
 989                                 foreach my $test (@{$individual_tests->{$name}}) {
 990                                         print $fh substr($test, length($name)+1) . "\n";
 991                                 }
 992                                 $cmd =~ s/\$LOADLIST/--load-list=$listid_file/g;
 993                         } elsif ($$_[4]) {
 994                                 $cmd =~ s/\s+[^\s]+\s*$//;
 995                                 $cmd .= " " . join(' ', @{$individual_tests->{$name}});
 996                         }
 997                 }
 998
 999                 run_testsuite($envname, $name, $cmd, $i, $suitestotal);
1000
1001                 teardown_env($envname) if ($opt_resetup_env);
1002         }
1003 }
1004
1005 print "\n";
1006
1007 teardown_env($_) foreach (keys %running_envs);
1008
1009 my $failed = 0;
1010
1011 # if there were any valgrind failures, show them
1012 foreach (<$prefix/valgrind.log*>) {
1013         next unless (-s $_);
1014         print "VALGRIND FAILURE\n";
1015         $failed++;
1016         system("cat $_");
1017 }
1018 exit 0;