source4/configure.ac

   1 dnl -*- mode: m4-mode -*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.54)
   5
   6 AC_INIT([samba],[4],[samba-technical@samba.org])
   7
   8 AC_CONFIG_SRCDIR([include/includes.h])
   9 AC_CONFIG_HEADER(include/config_tmp.h)
  10 AC_DEFINE(CONFIG_H_IS_FROM_SAMBA,1,[Marker for samba's config.h])
  11
  12 # Configuration rules.
  13 m4_include(build/m4/env.m4)
  14 m4_include(../lib/replace/samba.m4)
  15 m4_include(lib/smbreadline/readline.m4)
  16 m4_include(heimdal_build/config.m4)
  17 m4_include(../lib/util/fault.m4)
  18 m4_include(../lib/util/signal.m4)
  19 m4_include(../lib/util/util.m4)
  20 m4_include(../lib/util/fsusage.m4)
  21 m4_include(../lib/util/xattr.m4)
  22 m4_include(../lib/util/capability.m4)
  23 m4_include(../lib/util/time.m4)
  24 m4_include(../lib/popt/samba.m4)
  25 m4_include(../lib/util/charset/config.m4)
  26 m4_include(lib/socket/config.m4)
  27 m4_include(../lib/zlib/zlib.m4)
  28 AC_ZLIB([
  29 SMB_EXT_LIB(ZLIB, [${ZLIB_LIBS}])
  30 ],[
  31 SMB_INCLUDE_MK(lib/zlib.mk)
  32 ])
  33 m4_include(../nsswitch/nsstest.m4)
  34 m4_include(../pidl/config.m4)
  35
  36 AC_CONFIG_FILES(lib/registry/registry.pc)
  37 AC_CONFIG_FILES(librpc/dcerpc.pc)
  38 AC_CONFIG_FILES(../librpc/ndr.pc)
  39 AC_CONFIG_FILES(../lib/torture/torture.pc)
  40 AC_CONFIG_FILES(auth/gensec/gensec.pc)
  41 AC_CONFIG_FILES(param/samba-hostconfig.pc)
  42 AC_CONFIG_FILES(librpc/dcerpc_samr.pc)
  43 AC_CONFIG_FILES(librpc/dcerpc_atsvc.pc)
  44
  45 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTALLOC, talloc >= 1.2.0,
  46         [],
  47         [
  48                 m4_include(../lib/talloc/libtalloc.m4)
  49                 SMB_INCLUDE_MK(../lib/talloc/config.mk)
  50         ]
  51 )
  52
  53 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTDB, tdb >= 1.1.3,
  54         [],
  55         [
  56                 m4_include(../lib/tdb/libtdb.m4)
  57                 SMB_INCLUDE_MK(../lib/tdb/config.mk)
  58         ]
  59 )
  60
  61 SMB_INCLUDE_MK(../lib/tdb/python.mk)
  62
  63 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTEVENT, tevent >= 1.0.0,
  64         [],
  65         [
  66                 m4_include(../lib/tevent/libtevent.m4)
  67                 SMB_INCLUDE_MK(../lib/tevent/config.mk)
  68                 AC_CONFIG_FILES(../lib/tevent/tevent.pc)
  69         ]
  70 )
  71
  72 SMB_INCLUDE_MK(../lib/tevent/python.mk)
  73
  74 SMB_EXT_LIB_FROM_PKGCONFIG(LIBLDB, ldb = 0.9.1,
  75         [
  76                 SMB_INCLUDE_MK(lib/ldb/ldb_ildap/config.mk)
  77                 SMB_INCLUDE_MK(lib/ldb/tools/config.mk)
  78                 define_ldb_modulesdir=no
  79         ],
  80         [
  81                 # Here we need to do some tricks
  82                 # with AC_CONFIG_COMMANDS_PRE
  83                 # as that's the deferrs the commands
  84                 # to location after $prefix and $exec_prefix
  85                 # have usefull values and directly before
  86                 # creating config.status.
  87                 #
  88                 # The 'eval eval echo' trick is used to
  89                 # actually get the raw absolute directory
  90                 # path as this is needed in config.h
  91                 define_ldb_modulesdir=yes
  92                 AC_CONFIG_COMMANDS_PRE([
  93                 if test x"$define_ldb_modulesdir" = x"yes";then
  94                         LDB_MODULESDIR=`eval eval echo ${modulesdir}/ldb`
  95                         AC_DEFINE_UNQUOTED(LDB_MODULESDIR, "${LDB_MODULESDIR}" , [ldb Modules directory])
  96                 fi
  97                 ])
  98                 ldbdir=lib/ldb
  99                 AC_SUBST(ldbdir)
 100                 m4_include(lib/ldb/sqlite3.m4)
 101                 m4_include(lib/ldb/libldb.m4)
 102                 SMB_INCLUDE_MK(lib/ldb/config.mk)
 103                 AC_CONFIG_FILES(lib/ldb/ldb.pc)
 104         ]
 105 )
 106 SMB_INCLUDE_MK(lib/ldb/python.mk)
 107
 108 m4_include(lib/tls/config.m4)
 109
 110 dnl m4_include(auth/kerberos/config.m4)
 111 m4_include(auth/gensec/config.m4)
 112 m4_include(smbd/process_model.m4)
 113 m4_include(ntvfs/posix/config.m4)
 114 m4_include(ntvfs/unixuid/config.m4)
 115 m4_include(../lib/socket_wrapper/config.m4)
 116 m4_include(../lib/nss_wrapper/config.m4)
 117 m4_include(auth/config.m4)
 118 m4_include(kdc/config.m4)
 119 m4_include(ntvfs/sysdep/config.m4)
 120 m4_include(../nsswitch/config.m4)
 121
 122 #################################################
 123 # add *_CFLAGS only for the real build
 124 CFLAGS="${CFLAGS} ${DEVELOPER_CFLAGS}"
 125
 126 #################################################
 127 # final configure stuff
 128
 129 AC_MSG_CHECKING([configure summary])
 130 AC_TRY_RUN([#include "${srcdir-.}/build/tests/summary.c"],
 131            AC_MSG_RESULT(yes),
 132            AC_MSG_ERROR([summary failure. Aborting config]); exit 1;,
 133            AC_MSG_WARN([cannot run when cross-compiling]))
 134
 135 LIBS=`echo $LIBS | sed -e 's/ *//g'`
 136 if test x"$LIBS" != x""; then
 137         echo "LIBS: $LIBS"
 138         AC_MSG_WARN([the global \$LIBS variable contains some libraries!])
 139         AC_MSG_WARN([this should not happen, please report to samba-technical@lists.samba.org!])
 140         AC_MSG_ERROR([only _EXT macros from aclocal.m4 should be used!])
 141 fi
 142
 143 dnl Remove -L/usr/lib/? from LDFLAGS and LIBS
 144 LIB_REMOVE_USR_LIB(LDFLAGS)
 145 LIB_REMOVE_USR_LIB(LIBS)
 146
 147 dnl Remove -I/usr/include/? from CFLAGS and CPPFLAGS
 148 CFLAGS_REMOVE_USR_INCLUDE(CFLAGS)
 149 CFLAGS_REMOVE_USR_INCLUDE(CPPFLAGS)
 150
 151 AC_SUBST(ac_default_prefix)
 152
 153 for d in build/smb_build bin include ; do
 154     test -d ${builddir}/$d || AS_MKDIR_P(${builddir}/$d)
 155 done
 156
 157 AC_SUBST(INTERN_LDFLAGS)
 158 AC_SUBST(INSTALL_LINK_FLAGS)
 159 if test $USESHARED = "true";
 160 then
 161         INTERN_LDFLAGS="-L\$(shliboutputdir) -L\${builddir}/bin/static"
 162         INSTALL_LINK_FLAGS="-Wl,-rpath-link,\$(shliboutputdir)";
 163 else
 164         INTERN_LDFLAGS="-L\${builddir}/bin/static -L\$(shliboutputdir)"
 165 fi
 166
 167 builddir_headers=""
 168
 169 if test "x$ac_abs_srcdir" != "x$ac_abs_builddir"
 170 then
 171         builddir_headers="-I\$(builddir)/include -I\$(builddir) -I\$(builddir)/lib ";
 172 fi
 173
 174 CPPFLAGS="$builddir_headers-I\$(srcdir)/include -I\$(srcdir) -I\$(srcdir)/lib -I\$(srcdir)/../lib/replace -I\$(srcdir)/../lib/talloc -I\$(srcdir)/.. -D_SAMBA_BUILD_=4 -DHAVE_CONFIG_H $CPPFLAGS"
 175
 176 SMB_WRITE_PERLVARS(build/smb_build/config.pm)
 177
 178 echo "configure: creating config.mk"
 179 cat >config.mk<<CEOF
 180 # config.mk - Autogenerated by configure, DO NOT EDIT!
 181 $SMB_INFO_EXT_LIBS
 182 $SMB_INFO_SUBSYSTEMS
 183 $SMB_INFO_LIBRARIES
 184 CEOF
 185
 186 SMB_BUILD_RUN(data.mk)
 187 AC_OUTPUT
 188
 189 cmp include/config_tmp.h include/config.h >/dev/null 2>&1
 190 CMP_RET=$?
 191 if test $CMP_RET != 0; then
 192         cp include/config_tmp.h include/config.h
 193 fi
 194
 195 SMB_WRITE_MAKEVARS(mkconfig.mk)
 196
 197 if test $USESHARED = true
 198 then
 199         echo "To run binaries without installing, set the following environment variable:"
 200         echo "$LIB_PATH_VAR=$builddir/bin/shared"
 201 fi
 202
 203 echo
 204 echo "To build Samba, run $MAKE"