1f6641522c8b18fdfa728d99851793995ce09dac
[amitay/samba.git] / pidl / lib / Parse / Pidl / Samba3 / ServerNDR.pm
1 ###################################################
2 # Samba3 server generator for IDL structures
3 # on top of Samba4 style NDR functions
4 # Copyright jelmer@samba.org 2005-2006
5 # released under the GNU GPL
6
7 package Parse::Pidl::Samba3::ServerNDR;
8
9 use Exporter;
10 @ISA = qw(Exporter);
11 @EXPORT_OK = qw(DeclLevel);
12
13 use strict;
14 use Parse::Pidl qw(warning error fatal);
15 use Parse::Pidl::Typelist qw(mapTypeName scalar_is_reference);
16 use Parse::Pidl::Util qw(ParseExpr has_property is_constant);
17 use Parse::Pidl::NDR qw(GetNextLevel);
18 use Parse::Pidl::Samba4 qw(ElementStars DeclLong);
19 use Parse::Pidl::Samba4::Header qw(GenerateFunctionOutEnv);
20
21 use vars qw($VERSION);
22 $VERSION = '0.01';
23
24 my $res;
25 my $res_hdr;
26 my $tabs = "";
27 sub indent() { $tabs.="\t"; }
28 sub deindent() { $tabs = substr($tabs, 1); }
29 sub pidl($) { my ($txt) = @_; $res .= $txt?$tabs.(shift)."\n":"\n"; }
30 sub pidl_hdr($) { $res_hdr .= (shift)."\n"; }
31 sub fn_declare($) { my ($n) = @_; pidl $n; pidl_hdr "$n;"; }
32
33 sub DeclLevel($$)
34 {
35         my ($e, $l) = @_;
36         my $res = "";
37
38         if (has_property($e, "charset")) {
39                 $res .= "const char";
40         } else {
41                 $res .= mapTypeName($e->{TYPE});
42         }
43
44         my $stars = ElementStars($e, $l);
45
46         $res .= " ".$stars unless ($stars eq "");
47
48         return $res;
49 }
50
51 sub AllocOutVar($$$$$)
52 {
53         my ($e, $mem_ctx, $name, $env, $fail) = @_;
54
55         my $l = $e->{LEVELS}[0];
56
57         # we skip pointer to arrays
58         if ($l->{TYPE} eq "POINTER") {
59                 my $nl = GetNextLevel($e, $l);
60                 $l = $nl if ($nl->{TYPE} eq "ARRAY");
61         } elsif
62
63         # we don't support multi-dimentional arrays yet
64         ($l->{TYPE} eq "ARRAY") {
65                 my $nl = GetNextLevel($e, $l);
66                 if ($nl->{TYPE} eq "ARRAY") {
67                         fatal($e->{ORIGINAL},"multi-dimentional [out] arrays are not supported!");
68                 }
69         } else {
70                 # neither pointer nor array, no need to alloc something.
71                 return;
72         }
73
74         if ($l->{TYPE} eq "ARRAY") {
75                 unless(defined($l->{SIZE_IS})) {
76                         error($e->{ORIGINAL}, "No size known for array `$e->{NAME}'");
77                         pidl "#error No size known for array `$e->{NAME}'";
78                 } else {
79                         my $size = ParseExpr($l->{SIZE_IS}, $env, $e);
80                         pidl "$name = talloc_zero_array($mem_ctx, " . DeclLevel($e, 1) . ", $size);";
81                 }
82         } else {
83                 pidl "$name = talloc_zero($mem_ctx, " . DeclLevel($e, 1) . ");";
84         }
85
86         pidl "if ($name == NULL) {";
87         $fail->();
88         pidl "}";
89         pidl "";
90 }
91
92 sub CallWithStruct($$$$)
93 {
94         my ($pipes_struct, $mem_ctx, $fn, $fail) = @_;
95         my $env = GenerateFunctionOutEnv($fn);
96         my $hasout = 0;
97         foreach (@{$fn->{ELEMENTS}}) {
98                 if (grep(/out/, @{$_->{DIRECTION}})) { $hasout = 1; }
99         }
100
101         pidl "ZERO_STRUCT(r->out);" if ($hasout);
102
103         my $proto = "_$fn->{NAME}(struct pipes_struct *p, struct $fn->{NAME} *r";
104         my $ret = "_$fn->{NAME}($pipes_struct, r";
105         foreach (@{$fn->{ELEMENTS}}) {
106                 my @dir = @{$_->{DIRECTION}};
107                 if (grep(/in/, @dir) and grep(/out/, @dir)) {
108                         pidl "r->out.$_->{NAME} = r->in.$_->{NAME};";
109                 }
110         }
111
112         foreach (@{$fn->{ELEMENTS}}) {
113                 my @dir = @{$_->{DIRECTION}};
114                 if (grep(/in/, @dir) and grep(/out/, @dir)) {
115                         # noop
116                 } elsif (grep(/out/, @dir) and not
117                                  has_property($_, "represent_as")) {
118                         AllocOutVar($_, $mem_ctx, "r->out.$_->{NAME}", $env, $fail);
119                 }
120         }
121         $ret .= ")";
122         $proto .= ");";
123
124         if ($fn->{RETURN_TYPE}) {
125                 $ret = "r->out.result = $ret";
126                 $proto = "$fn->{RETURN_TYPE} $proto";
127         } else {
128                 $proto = "void $proto";
129         }
130
131         pidl_hdr "$proto";
132         pidl "$ret;";
133 }
134
135 sub ParseFunction($$)
136 {
137         my ($if,$fn) = @_;
138
139         my $op = "NDR_".uc($fn->{NAME});
140
141         pidl "static bool api_$fn->{NAME}(struct pipes_struct *p)";
142         pidl "{";
143         indent;
144         pidl "const struct ndr_interface_call *call;";
145         pidl "struct ndr_pull *pull;";
146         pidl "struct ndr_push *push;";
147         pidl "enum ndr_err_code ndr_err;";
148         pidl "struct $fn->{NAME} *r;";
149         pidl "";
150         pidl "call = &ndr_table_$if->{NAME}.calls[$op];";
151         pidl "";
152         pidl "r = talloc(talloc_tos(), struct $fn->{NAME});";
153         pidl "if (r == NULL) {";
154         pidl "\treturn false;";
155         pidl "}";
156         pidl "";
157         pidl "pull = ndr_pull_init_blob(&p->in_data.data, r);";
158         pidl "if (pull == NULL) {";
159         pidl "\ttalloc_free(r);";
160         pidl "\treturn false;";
161         pidl "}";
162         pidl "";
163         pidl "pull->flags |= LIBNDR_FLAG_REF_ALLOC;";
164         pidl "if (p->endian) {";
165         pidl "\tpull->flags |= LIBNDR_FLAG_BIGENDIAN;";
166         pidl "}";
167         pidl "ndr_err = call->ndr_pull(pull, NDR_IN, r);";
168         pidl "if (!NDR_ERR_CODE_IS_SUCCESS(ndr_err)) {";
169         pidl "\ttalloc_free(r);";
170         pidl "\treturn false;";
171         pidl "}";
172         pidl "";
173         pidl "if (DEBUGLEVEL >= 10) {";
174         pidl "\tNDR_PRINT_IN_DEBUG($fn->{NAME}, r);";
175         pidl "}";
176         pidl "";
177
178         CallWithStruct("p", "r", $fn, 
179         sub { 
180                         pidl "\ttalloc_free(r);";
181                         pidl "\treturn false;";
182                 }
183         );
184
185         pidl "";
186         pidl "if (p->rng_fault_state) {";
187         pidl "\ttalloc_free(r);";
188         pidl "\t/* Return true here, srv_pipe_hnd.c will take care */";
189         pidl "\treturn true;";
190         pidl "}";
191         pidl "";
192         pidl "if (DEBUGLEVEL >= 10) {";
193         pidl "\tNDR_PRINT_OUT_DEBUG($fn->{NAME}, r);";
194         pidl "}";
195         pidl "";
196         pidl "push = ndr_push_init_ctx(r);";
197         pidl "if (push == NULL) {";
198         pidl "\ttalloc_free(r);";
199         pidl "\treturn false;";
200         pidl "}";
201         pidl "";
202         pidl "ndr_err = call->ndr_push(push, NDR_OUT, r);";
203         pidl "if (!NDR_ERR_CODE_IS_SUCCESS(ndr_err)) {";
204         pidl "\ttalloc_free(r);";
205         pidl "\treturn false;";
206         pidl "}";
207         pidl "";
208         pidl "p->out_data.rdata = ndr_push_blob(push);";
209         pidl "talloc_steal(p->mem_ctx, p->out_data.rdata.data);";
210         pidl "";
211         pidl "talloc_free(r);";
212         pidl "";
213         pidl "return true;";
214         deindent;
215         pidl "}";
216         pidl "";
217 }
218
219 sub ParseInterface($)
220 {
221         my $if = shift;
222
223         my $uif = uc($if->{NAME});
224
225         pidl_hdr "#ifndef __SRV_$uif\__";
226         pidl_hdr "#define __SRV_$uif\__";
227
228         foreach (@{$if->{FUNCTIONS}}) {
229                 next if ($_->{PROPERTIES}{noopnum});
230                 ParseFunction($if, $_);
231         }
232
233         pidl "";
234         pidl "/* Tables */";
235         pidl "static struct api_struct api_$if->{NAME}_cmds[] = ";
236         pidl "{";
237         indent;
238
239         foreach (@{$if->{FUNCTIONS}}) {
240                 next if ($_->{PROPERTIES}{noopnum});
241                 pidl "{\"" . uc($_->{NAME}) . "\", NDR_" . uc($_->{NAME}) . ", api_$_->{NAME}},";
242         }
243
244         deindent;
245         pidl "};";
246
247         pidl "";
248
249         pidl_hdr "void $if->{NAME}_get_pipe_fns(struct api_struct **fns, int *n_fns);";
250         pidl "void $if->{NAME}_get_pipe_fns(struct api_struct **fns, int *n_fns)";
251         pidl "{";
252         indent;
253         pidl "*fns = api_$if->{NAME}_cmds;";
254         pidl "*n_fns = sizeof(api_$if->{NAME}_cmds) / sizeof(struct api_struct);";
255         deindent;
256         pidl "}";
257         pidl "";
258
259         if (not has_property($if, "no_srv_register")) {
260             pidl_hdr "struct rpc_srv_callbacks;";
261             pidl_hdr "NTSTATUS rpc_$if->{NAME}_init(const struct rpc_srv_callbacks *rpc_srv_cb);";
262             pidl "NTSTATUS rpc_$if->{NAME}_init(const struct rpc_srv_callbacks *rpc_srv_cb)";
263             pidl "{";
264             pidl "\treturn rpc_srv_register(SMB_RPC_INTERFACE_VERSION, \"$if->{NAME}\", \"$if->{NAME}\", \&ndr_table_$if->{NAME}, api_$if->{NAME}_cmds, sizeof(api_$if->{NAME}_cmds) / sizeof(struct api_struct), rpc_srv_cb);";
265             pidl "}";
266
267             pidl "";
268
269             pidl_hdr "NTSTATUS rpc_$if->{NAME}_shutdown(void);";
270             pidl "NTSTATUS rpc_$if->{NAME}_shutdown(void)";
271             pidl "{";
272             pidl "\treturn rpc_srv_unregister(\&ndr_table_$if->{NAME});";
273             pidl "}";
274         }
275         pidl_hdr "#endif /* __SRV_$uif\__ */";
276 }
277
278 sub Parse($$$)
279 {
280         my($ndr,$header,$ndr_header) = @_;
281
282         $res = "";
283         $res_hdr = "";
284
285         pidl "/*";
286         pidl " * Unix SMB/CIFS implementation.";
287         pidl " * server auto-generated by pidl. DO NOT MODIFY!";
288         pidl " */";
289         pidl "";
290         pidl "#include \"includes.h\"";
291         pidl "#include \"$header\"";
292         pidl_hdr "#include \"$ndr_header\"";
293         pidl "";
294
295         foreach (@$ndr) {
296                 ParseInterface($_) if ($_->{TYPE} eq "INTERFACE");
297         }
298
299         return ($res, $res_hdr);
300 }
301
302 1;