selftest/selftest.pl

   1 #!/usr/bin/perl
   2 # Bootstrap Samba and run a number of tests against it.
   3 # Copyright (C) 2005-2010 Jelmer Vernooij <jelmer@samba.org>
   4 # Copyright (C) 2007-2009 Stefan Metzmacher <metze@samba.org>
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 =pod
  20
  21 =head1 NAME
  22
  23 selftest - Samba test runner
  24
  25 =head1 SYNOPSIS
  26
  27 selftest --help
  28
  29 selftest [--srcdir=DIR] [--bindir=DIR] [--exeext=EXT][--target=samba4|samba3|win|kvm] [--socket-wrapper] [--quick] [--exclude=FILE] [--include=FILE] [--one] [--prefix=prefix] [--testlist=FILE] [TESTS]
  30
  31 =head1 DESCRIPTION
  32
  33 A simple test runner. TESTS is a regular expression with tests to run.
  34
  35 =head1 OPTIONS
  36
  37 =over 4
  38
  39 =item I<--help>
  40
  41 Show list of available options.
  42
  43 =item I<--srcdir=DIR>
  44
  45 Source directory.
  46
  47 =item I<--bindir=DIR>
  48
  49 Built binaries directory.
  50
  51 =item I<--exeext=EXT>
  52
  53 Executable extention
  54
  55 =item I<--prefix=DIR>
  56
  57 Change directory to run tests in. Default is 'st'.
  58
  59 =item I<--target samba4|samba3|win|kvm>
  60
  61 Specify test target against which to run. Default is 'samba4'.
  62
  63 =item I<--quick>
  64
  65 Run only a limited number of tests. Intended to run in about 30 seconds on
  66 moderately recent systems.
  67
  68 =item I<--socket-wrapper>
  69
  70 Use socket wrapper library for communication with server. Only works
  71 when the server is running locally.
  72
  73 Will prevent TCP and UDP ports being opened on the local host but
  74 (transparently) redirects these calls to use unix domain sockets.
  75
  76 =item I<--exclude>
  77
  78 Specify a file containing a list of tests that should be skipped. Possible
  79 candidates are tests that segfault the server, flip or don't end.
  80
  81 =item I<--include>
  82
  83 Specify a file containing a list of tests that should be run. Same format
  84 as the --exclude flag.
  85
  86 Not includes specified means all tests will be run.
  87
  88 =item I<--one>
  89
  90 Abort as soon as one test fails.
  91
  92 =item I<--testlist>
  93
  94 Load a list of tests from the specified location.
  95
  96 =back
  97
  98 =head1 ENVIRONMENT
  99
 100 =over 4
 101
 102 =item I<SMBD_VALGRIND>
 103
 104 =item I<TORTURE_MAXTIME>
 105
 106 =item I<VALGRIND>
 107
 108 =item I<TLS_ENABLED>
 109
 110 =item I<srcdir>
 111
 112 =back
 113
 114 =head1 LICENSE
 115
 116 selftest is licensed under the GNU General Public License L<http://www.gnu.org/licenses/gpl.html>.
 117
 118 =head1 AUTHOR
 119
 120 Jelmer Vernooij
 121
 122 =cut
 123
 124 use strict;
 125
 126 use FindBin qw($RealBin $Script);
 127 use File::Spec;
 128 use File::Temp qw(tempfile);
 129 use Getopt::Long;
 130 use POSIX;
 131 use Cwd qw(abs_path);
 132 use lib "$RealBin";
 133 use Subunit;
 134 use SocketWrapper;
 135
 136 eval {
 137 require Time::HiRes;
 138 Time::HiRes->import("time");
 139 };
 140 if ($@) {
 141         print "You don't have Time::Hires installed !\n";
 142 }
 143
 144 my $opt_help = 0;
 145 my $opt_target = "samba4";
 146 my $opt_quick = 0;
 147 my $opt_socket_wrapper = 0;
 148 my $opt_socket_wrapper_pcap = undef;
 149 my $opt_socket_wrapper_keep_pcap = undef;
 150 my $opt_one = 0;
 151 my @opt_exclude = ();
 152 my @opt_include = ();
 153 my $opt_verbose = 0;
 154 my $opt_image = undef;
 155 my $opt_testenv = 0;
 156 my $opt_list = 0;
 157 my $ldap = undef;
 158 my $opt_resetup_env = undef;
 159 my $opt_binary_mapping = "";
 160 my $opt_load_list = undef;
 161 my @testlists = ();
 162
 163 my $srcdir = ".";
 164 my $bindir = "./bin";
 165 my $exeext = "";
 166 my $prefix = "./st";
 167
 168 my @includes = ();
 169 my @excludes = ();
 170
 171 sub pipe_handler {
 172         my $sig = shift @_;
 173         print STDERR "Exiting early because of SIGPIPE.\n";
 174         exit(1);
 175 }
 176
 177 $SIG{PIPE} = \&pipe_handler;
 178
 179 sub find_in_list($$)
 180 {
 181         my ($list, $fullname) = @_;
 182
 183         foreach (@$list) {
 184                 if ($fullname =~ /$$_[0]/) {
 185                          return ($$_[1]) if ($$_[1]);
 186                          return "";
 187                 }
 188         }
 189
 190         return undef;
 191 }
 192
 193 sub skip($)
 194 {
 195         my ($name) = @_;
 196
 197         return find_in_list(\@excludes, $name);
 198 }
 199
 200 sub getlog_env($);
 201
 202 sub setup_pcap($)
 203 {
 204         my ($name) = @_;
 205
 206         return unless ($opt_socket_wrapper_pcap);
 207         return unless defined($ENV{SOCKET_WRAPPER_PCAP_DIR});
 208
 209         my $fname = $name;
 210         $fname =~ s%[^abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789\-]%_%g;
 211
 212         my $pcap_file = "$ENV{SOCKET_WRAPPER_PCAP_DIR}/$fname.pcap";
 213
 214         SocketWrapper::setup_pcap($pcap_file);
 215
 216         return $pcap_file;
 217 }
 218
 219 sub cleanup_pcap($$)
 220 {
 221         my ($pcap_file, $exitcode) = @_;
 222
 223         return unless ($opt_socket_wrapper_pcap);
 224         return if ($opt_socket_wrapper_keep_pcap);
 225         return unless ($exitcode == 0);
 226         return unless defined($pcap_file);
 227
 228         unlink($pcap_file);
 229 }
 230
 231 # expand strings from %ENV
 232 sub expand_environment_strings($)
 233 {
 234         my $s = shift;
 235         # we use a reverse sort so we do the longer ones first
 236         foreach my $k (sort { $b cmp $a } keys %ENV) {
 237                 $s =~ s/\$$k/$ENV{$k}/g;
 238         }
 239         return $s;
 240 }
 241
 242 sub run_testsuite($$$$$)
 243 {
 244         my ($envname, $name, $cmd, $i, $totalsuites) = @_;
 245         my $pcap_file = setup_pcap($name);
 246
 247         Subunit::start_testsuite($name);
 248         Subunit::progress_push();
 249         Subunit::report_time(time());
 250         system($cmd);
 251         Subunit::report_time(time());
 252         Subunit::progress_pop();
 253
 254         if ($? == -1) {
 255                 Subunit::progress_pop();
 256                 Subunit::end_testsuite($name, "error", "Unable to run $cmd: $!");
 257                 exit(1);
 258         } elsif ($? & 127) {
 259                 Subunit::end_testsuite($name, "error",
 260                         sprintf("%s died with signal %d, %s coredump\n", $cmd, ($? & 127),  ($? & 128) ? 'with' : 'without'));
 261                 exit(1);
 262         }
 263
 264         my $exitcode = $? >> 8;
 265
 266         my $envlog = getlog_env($envname);
 267         if ($envlog ne "") {
 268                 print "envlog: $envlog\n";
 269         }
 270
 271         print "command: $cmd\n";
 272         printf "expanded command: %s\n", expand_environment_strings($cmd);
 273
 274         if ($exitcode == 0) {
 275                 Subunit::end_testsuite($name, "success");
 276         } else {
 277                 Subunit::end_testsuite($name, "failure", "Exit code was $exitcode");
 278         }
 279
 280         cleanup_pcap($pcap_file, $exitcode);
 281
 282         if (not $opt_socket_wrapper_keep_pcap and defined($pcap_file)) {
 283                 print "PCAP FILE: $pcap_file\n";
 284         }
 285
 286         if ($exitcode != 0) {
 287                 exit(1) if ($opt_one);
 288         }
 289
 290         return $exitcode;
 291 }
 292
 293 sub ShowHelp()
 294 {
 295         print "Samba test runner
 296 Copyright (C) Jelmer Vernooij <jelmer\@samba.org>
 297 Copyright (C) Stefan Metzmacher <metze\@samba.org>
 298
 299 Usage: $Script [OPTIONS] TESTNAME-REGEX
 300
 301 Generic options:
 302  --help                     this help page
 303  --target=samba[34]|win|kvm Samba version to target
 304  --testlist=FILE            file to read available tests from
 305
 306 Paths:
 307  --prefix=DIR               prefix to run tests in [st]
 308  --srcdir=DIR               source directory [.]
 309  --bindir=DIR               binaries directory [./bin]
 310  --exeext=EXT               executable extention []
 311
 312 Target Specific:
 313  --socket-wrapper-pcap      save traffic to pcap directories
 314  --socket-wrapper-keep-pcap keep all pcap files, not just those for tests that
 315                             failed
 316  --socket-wrapper           enable socket wrapper
 317
 318 Samba4 Specific:
 319  --ldap=openldap|fedora-ds  back samba onto specified ldap server
 320
 321 Kvm Specific:
 322  --image=PATH               path to KVM image
 323
 324 Behaviour:
 325  --quick                    run quick overall test
 326  --one                      abort when the first test fails
 327  --verbose                  be verbose
 328  --testenv                  run a shell in the requested test environment
 329  --list                     list available tests
 330 ";
 331         exit(0);
 332 }
 333
 334 my $result = GetOptions (
 335                 'help|h|?' => \$opt_help,
 336                 'target=s' => \$opt_target,
 337                 'prefix=s' => \$prefix,
 338                 'socket-wrapper' => \$opt_socket_wrapper,
 339                 'socket-wrapper-pcap' => \$opt_socket_wrapper_pcap,
 340                 'socket-wrapper-keep-pcap' => \$opt_socket_wrapper_keep_pcap,
 341                 'quick' => \$opt_quick,
 342                 'one' => \$opt_one,
 343                 'exclude=s' => \@opt_exclude,
 344                 'include=s' => \@opt_include,
 345                 'srcdir=s' => \$srcdir,
 346                 'bindir=s' => \$bindir,
 347                 'exeext=s' => \$exeext,
 348                 'verbose' => \$opt_verbose,
 349                 'testenv' => \$opt_testenv,
 350                 'list' => \$opt_list,
 351                 'ldap:s' => \$ldap,
 352                 'resetup-environment' => \$opt_resetup_env,
 353                 'image=s' => \$opt_image,
 354                 'testlist=s' => \@testlists,
 355                 'load-list=s' => \$opt_load_list,
 356                 'binary-mapping=s' => \$opt_binary_mapping
 357             );
 358
 359 exit(1) if (not $result);
 360
 361 ShowHelp() if ($opt_help);
 362
 363 die("--list and --testenv are mutually exclusive") if ($opt_list and $opt_testenv);
 364
 365 # we want unbuffered output
 366 $| = 1;
 367
 368 my @tests = @ARGV;
 369
 370 # quick hack to disable rpc validation when using valgrind - its way too slow
 371 unless (defined($ENV{VALGRIND})) {
 372         $ENV{VALIDATE} = "validate";
 373         $ENV{MALLOC_CHECK_} = 2;
 374 }
 375
 376 # make all our python scripts unbuffered
 377 $ENV{PYTHONUNBUFFERED} = 1;
 378
 379 my $bindir_abs = abs_path($bindir);
 380
 381 # Backwards compatibility:
 382 if (defined($ENV{TEST_LDAP}) and $ENV{TEST_LDAP} eq "yes") {
 383         if (defined($ENV{FEDORA_DS_ROOT})) {
 384                 $ldap = "fedora-ds";
 385         } else {
 386                 $ldap = "openldap";
 387         }
 388 }
 389
 390 my $torture_maxtime = ($ENV{TORTURE_MAXTIME} or 1200);
 391 if ($ldap) {
 392         # LDAP is slow
 393         $torture_maxtime *= 2;
 394 }
 395
 396 $prefix =~ s+//+/+;
 397 $prefix =~ s+/./+/+;
 398 $prefix =~ s+/$++;
 399
 400 die("using an empty prefix isn't allowed") unless $prefix ne "";
 401
 402 # Ensure we have the test prefix around.
 403 #
 404 # We need restrictive
 405 # permissions on this as some subdirectories in this tree will have
 406 # wider permissions (ie 0777) and this would allow other users on the
 407 # host to subvert the test process.
 408 mkdir($prefix, 0700) unless -d $prefix;
 409 chmod 0700, $prefix;
 410
 411 my $prefix_abs = abs_path($prefix);
 412 my $tmpdir_abs = abs_path("$prefix/tmp");
 413 mkdir($tmpdir_abs, 0777) unless -d $tmpdir_abs;
 414
 415 my $srcdir_abs = abs_path($srcdir);
 416
 417 die("using an empty absolute prefix isn't allowed") unless $prefix_abs ne "";
 418 die("using '/' as absolute prefix isn't allowed") unless $prefix_abs ne "/";
 419
 420 $ENV{PREFIX} = $prefix;
 421 $ENV{KRB5CCNAME} = "$prefix/krb5ticket";
 422 $ENV{PREFIX_ABS} = $prefix_abs;
 423 $ENV{SRCDIR} = $srcdir;
 424 $ENV{SRCDIR_ABS} = $srcdir_abs;
 425 $ENV{BINDIR} = $bindir_abs;
 426 $ENV{EXEEXT} = $exeext;
 427
 428 my $tls_enabled = not $opt_quick;
 429 $ENV{TLS_ENABLED} = ($tls_enabled?"yes":"no");
 430
 431 sub prefix_pathvar($$)
 432 {
 433         my ($name, $newpath) = @_;
 434         if (defined($ENV{$name})) {
 435                 $ENV{$name} = "$newpath:$ENV{$name}";
 436         } else {
 437                 $ENV{$name} = $newpath;
 438         }
 439 }
 440 prefix_pathvar("PKG_CONFIG_PATH", "$bindir_abs/pkgconfig");
 441 prefix_pathvar("PYTHONPATH", "$bindir_abs/python");
 442
 443 if ($opt_socket_wrapper_keep_pcap) {
 444         # Socket wrapper keep pcap implies socket wrapper pcap
 445         $opt_socket_wrapper_pcap = 1;
 446 }
 447
 448 if ($opt_socket_wrapper_pcap) {
 449         # Socket wrapper pcap implies socket wrapper
 450         $opt_socket_wrapper = 1;
 451 }
 452
 453 my $socket_wrapper_dir;
 454 if ($opt_socket_wrapper) {
 455         $socket_wrapper_dir = SocketWrapper::setup_dir("$prefix_abs/w", $opt_socket_wrapper_pcap);
 456         print "SOCKET_WRAPPER_DIR=$socket_wrapper_dir\n";
 457 } else {
 458          unless ($< == 0) {
 459                  print "WARNING: Not using socket wrapper, but also not running as root. Will not be able to listen on proper ports\n";
 460          }
 461 }
 462
 463 my $target;
 464 my $testenv_default = "none";
 465
 466 my %binary_mapping = {};
 467 if ($opt_binary_mapping) {
 468     my @binmapping_list = split(/,/, $opt_binary_mapping);
 469     foreach my $mapping (@binmapping_list) {
 470         my ($bin, $map) = split(/\:/, $mapping);
 471         $binary_mapping{$bin} = $map;
 472     }
 473 }
 474
 475 $ENV{BINARY_MAPPING} = $opt_binary_mapping;
 476
 477 # After this many seconds, the server will self-terminate.  All tests
 478 # must terminate in this time, and testenv will only stay alive this
 479 # long
 480
 481 my $server_maxtime = 7500;
 482 if (defined($ENV{SMBD_MAXTIME}) and $ENV{SMBD_MAXTIME} ne "") {
 483     $server_maxtime = $ENV{SMBD_MAXTIME};
 484 }
 485
 486 if ($opt_target eq "samba") {
 487         if ($opt_socket_wrapper and `$bindir/smbd -b | grep SOCKET_WRAPPER` eq "") {
 488                 die("You must include --enable-socket-wrapper when compiling Samba in order to execute 'make test'.  Exiting....");
 489         }
 490         $testenv_default = "all";
 491         require target::Samba;
 492         $target = new Samba($bindir, \%binary_mapping, $ldap, $srcdir, $exeext, $server_maxtime);
 493 } elsif ($opt_target eq "samba4") {
 494         $testenv_default = "all";
 495         require target::Samba4;
 496         $target = new Samba4($bindir, \%binary_mapping, $ldap, $srcdir, $exeext, $server_maxtime);
 497 } elsif ($opt_target eq "samba3") {
 498         if ($opt_socket_wrapper and `$bindir/smbd -b | grep SOCKET_WRAPPER` eq "") {
 499                 die("You must include --enable-socket-wrapper when compiling Samba in order to execute 'make test'.  Exiting....");
 500         }
 501         $testenv_default = "member";
 502         require target::Samba3;
 503         $target = new Samba3($bindir, \%binary_mapping, $srcdir_abs, $exeext, $server_maxtime);
 504 } elsif ($opt_target eq "win") {
 505         die("Windows tests will not run with socket wrapper enabled.")
 506                 if ($opt_socket_wrapper);
 507         $testenv_default = "dc";
 508         require target::Windows;
 509         $target = new Windows();
 510 } elsif ($opt_target eq "kvm") {
 511         die("Kvm tests will not run with socket wrapper enabled.")
 512                 if ($opt_socket_wrapper);
 513         require target::Kvm;
 514         die("No image specified") unless ($opt_image);
 515         $target = new Kvm($opt_image, undef);
 516 }
 517
 518 #
 519 # Start a Virtual Distributed Ethernet Switch
 520 # Returns the pid of the switch.
 521 #
 522 sub start_vde_switch($)
 523 {
 524         my ($path) = @_;
 525
 526         system("vde_switch --pidfile $path/vde.pid --sock $path/vde.sock --daemon");
 527
 528         open(PID, "$path/vde.pid");
 529         <PID> =~ /([0-9]+)/;
 530         my $pid = $1;
 531         close(PID);
 532
 533         return $pid;
 534 }
 535
 536 # Stop a Virtual Distributed Ethernet Switch
 537 sub stop_vde_switch($)
 538 {
 539         my ($pid) = @_;
 540         kill 9, $pid;
 541 }
 542
 543 sub read_test_regexes($)
 544 {
 545         my ($name) = @_;
 546         my @ret = ();
 547         open(LF, "<$name") or die("unable to read $name: $!");
 548         while (<LF>) {
 549                 chomp;
 550                 next if (/^#/);
 551                 if (/^(.*?)([ \t]+)\#([\t ]*)(.*?)$/) {
 552                         push (@ret, [$1, $4]);
 553                 } else {
 554                         s/^(.*?)([ \t]+)\#([\t ]*)(.*?)$//;
 555                         push (@ret, [$_, undef]);
 556                 }
 557         }
 558         close(LF);
 559         return @ret;
 560 }
 561
 562 foreach (@opt_exclude) {
 563         push (@excludes, read_test_regexes($_));
 564 }
 565
 566 foreach (@opt_include) {
 567         push (@includes, read_test_regexes($_));
 568 }
 569
 570 my $interfaces = join(',', ("127.0.0.11/8",
 571                             "127.0.0.12/8",
 572                             "127.0.0.13/8",
 573                             "127.0.0.14/8",
 574                             "127.0.0.15/8",
 575                             "127.0.0.16/8"));
 576
 577 my $clientdir = "$prefix_abs/client";
 578
 579 my $conffile = "$clientdir/client.conf";
 580 $ENV{SMB_CONF_PATH} = $conffile;
 581
 582 sub write_clientconf($$$)
 583 {
 584         my ($conffile, $clientdir, $vars) = @_;
 585
 586         mkdir("$clientdir", 0777) unless -d "$clientdir";
 587
 588         if ( -d "$clientdir/private" ) {
 589                 unlink <$clientdir/private/*>;
 590         } else {
 591                 mkdir("$clientdir/private", 0777);
 592         }
 593
 594         if ( -d "$clientdir/lockdir" ) {
 595                 unlink <$clientdir/lockdir/*>;
 596         } else {
 597                 mkdir("$clientdir/lockdir", 0777);
 598         }
 599
 600         if ( -d "$clientdir/ncalrpcdir" ) {
 601                 unlink <$clientdir/ncalrpcdir/*>;
 602         } else {
 603                 mkdir("$clientdir/ncalrpcdir", 0777);
 604         }
 605
 606         open(CF, ">$conffile");
 607         print CF "[global]\n";
 608         print CF "\tnetbios name = client\n";
 609         if (defined($vars->{DOMAIN})) {
 610                 print CF "\tworkgroup = $vars->{DOMAIN}\n";
 611         }
 612         if (defined($vars->{REALM})) {
 613                 print CF "\trealm = $vars->{REALM}\n";
 614         }
 615         if ($opt_socket_wrapper) {
 616                 print CF "\tinterfaces = $interfaces\n";
 617         }
 618         print CF "
 619         private dir = $clientdir/private
 620         lock dir = $clientdir/lockdir
 621         ncalrpc dir = $clientdir/ncalrpcdir
 622         name resolve order = file bcast
 623         panic action = $RealBin/gdb_backtrace \%PID\% \%PROG\%
 624         max xmit = 32K
 625         notify:inotify = false
 626         ldb:nosync = true
 627         system:anonymous = true
 628         client lanman auth = Yes
 629         log level = 1
 630         torture:basedir = $clientdir
 631 #We don't want to pass our self-tests if the PAC code is wrong
 632         gensec:require_pac = true
 633         resolv:host file = $prefix_abs/dns_host_file
 634 #We don't want to run 'speed' tests for very long
 635         torture:timelimit = 1
 636 ";
 637         close(CF);
 638 }
 639
 640 my @todo = ();
 641
 642 sub should_run_test($)
 643 {
 644         my $name = shift;
 645         if ($#tests == -1) {
 646                 return 1;
 647         }
 648         for (my $i=0; $i <= $#tests; $i++) {
 649                 if ($name =~ /$tests[$i]/i) {
 650                         return 1;
 651                 }
 652         }
 653         return 0;
 654 }
 655
 656 sub read_testlist($)
 657 {
 658         my ($filename) = @_;
 659
 660         my @ret = ();
 661         open(IN, $filename) or die("Unable to open $filename: $!");
 662
 663         while (<IN>) {
 664                 if (/-- TEST(-LOADLIST|-IDLIST|) --\n/) {
 665                         my $supports_loadlist = (defined($1) and $1 eq "-LOADLIST");
 666                         my $supports_idlist = (defined($1) and $1 eq "-IDLIST");
 667                         my $name = <IN>;
 668                         $name =~ s/\n//g;
 669                         my $env = <IN>;
 670                         $env =~ s/\n//g;
 671                         my $cmdline = <IN>;
 672                         $cmdline =~ s/\n//g;
 673                         if (should_run_test($name) == 1) {
 674                                 push (@ret, [$name, $env, $cmdline, $supports_loadlist, $supports_idlist]);
 675                         }
 676                 } else {
 677                         print;
 678                 }
 679         }
 680         close(IN) or die("Error creating recipe");
 681         return @ret;
 682 }
 683
 684 if ($#testlists == -1) {
 685         die("No testlists specified");
 686 }
 687
 688 $ENV{SELFTEST_PREFIX} = "$prefix_abs";
 689 $ENV{SELFTEST_TMPDIR} = "$tmpdir_abs";
 690 $ENV{TEST_DATA_PREFIX} = "$tmpdir_abs";
 691 if ($opt_socket_wrapper) {
 692         $ENV{SELFTEST_INTERFACES} = $interfaces;
 693 } else {
 694         $ENV{SELFTEST_INTERFACES} = "";
 695 }
 696 if ($opt_verbose) {
 697         $ENV{SELFTEST_VERBOSE} = "1";
 698 } else {
 699         $ENV{SELFTEST_VERBOSE} = "";
 700 }
 701 if ($opt_quick) {
 702         $ENV{SELFTEST_QUICK} = "1";
 703 } else {
 704         $ENV{SELFTEST_QUICK} = "";
 705 }
 706 $ENV{SELFTEST_MAXTIME} = $torture_maxtime;
 707
 708 my @available = ();
 709 foreach my $fn (@testlists) {
 710         foreach (read_testlist($fn)) {
 711                 my $name = $$_[0];
 712                 next if (@includes and not defined(find_in_list(\@includes, $name)));
 713                 push (@available, $_);
 714         }
 715 }
 716
 717 my $restricted = undef;
 718 my $restricted_used = {};
 719
 720 if ($opt_load_list) {
 721         $restricted = [];
 722         open(LOAD_LIST, "<$opt_load_list") or die("Unable to open $opt_load_list");
 723         while (<LOAD_LIST>) {
 724                 chomp;
 725                 push (@$restricted, $_);
 726         }
 727         close(LOAD_LIST);
 728 }
 729
 730 my $individual_tests = undef;
 731 $individual_tests = {};
 732
 733 foreach my $testsuite (@available) {
 734         my $name = $$testsuite[0];
 735         my $skipreason = skip($name);
 736         if (defined($restricted)) {
 737                 # Find the testsuite for this test
 738                 my $match = undef;
 739                 foreach my $r (@$restricted) {
 740                         if ($r eq $name) {
 741                                 $individual_tests->{$name} = [];
 742                                 $match = $r;
 743                                 $restricted_used->{$r} = 1;
 744                         } elsif (substr($r, 0, length($name)+1) eq "$name.") {
 745                                 push(@{$individual_tests->{$name}}, $r);
 746                                 $match = $r;
 747                                 $restricted_used->{$r} = 1;
 748                         }
 749                 }
 750                 if ($match) {
 751                         if (defined($skipreason)) {
 752                                         Subunit::skip_testsuite($name, $skipreason);
 753                         } else {
 754                                 push(@todo, $testsuite);
 755                         }
 756                 }
 757         } elsif (defined($skipreason)) {
 758                 Subunit::skip_testsuite($name, $skipreason);
 759         } else {
 760                 push(@todo, $testsuite);
 761         }
 762 }
 763
 764 if (defined($restricted)) {
 765         foreach (@$restricted) {
 766                 unless (defined($restricted_used->{$_})) {
 767                         print "No test or testsuite found matching $_\n";
 768                 }
 769         }
 770 } elsif ($#todo == -1) {
 771         print STDERR "No tests to run\n";
 772         exit(1);
 773 }
 774
 775 my $suitestotal = $#todo + 1;
 776
 777 Subunit::progress($suitestotal);
 778 Subunit::report_time(time());
 779
 780 my $i = 0;
 781 $| = 1;
 782
 783 my %running_envs = ();
 784
 785 sub get_running_env($)
 786 {
 787         my ($name) = @_;
 788
 789         my $envname = $name;
 790
 791         $envname =~ s/:.*//;
 792
 793         return $running_envs{$envname};
 794 }
 795
 796 my @exported_envvars = (
 797         # domain stuff
 798         "DOMAIN",
 799         "REALM",
 800
 801         # domain controller stuff
 802         "DC_SERVER",
 803         "DC_SERVER_IP",
 804         "DC_NETBIOSNAME",
 805         "DC_NETBIOSALIAS",
 806
 807         # domain member
 808         "MEMBER_SERVER",
 809         "MEMBER_SERVER_IP",
 810         "MEMBER_NETBIOSNAME",
 811         "MEMBER_NETBIOSALIAS",
 812
 813         # rpc proxy controller stuff
 814         "RPC_PROXY_SERVER",
 815         "RPC_PROXY_SERVER_IP",
 816         "RPC_PROXY_NETBIOSNAME",
 817         "RPC_PROXY_NETBIOSALIAS",
 818
 819         # domain controller stuff for Vampired DC
 820         "VAMPIRE_DC_SERVER",
 821         "VAMPIRE_DC_SERVER_IP",
 822         "VAMPIRE_DC_NETBIOSNAME",
 823         "VAMPIRE_DC_NETBIOSALIAS",
 824
 825         # server stuff
 826         "SERVER",
 827         "SERVER_IP",
 828         "NETBIOSNAME",
 829         "NETBIOSALIAS",
 830
 831         # user stuff
 832         "USERNAME",
 833         "USERID",
 834         "PASSWORD",
 835         "DC_USERNAME",
 836         "DC_PASSWORD",
 837
 838         # misc stuff
 839         "KRB5_CONFIG",
 840         "WINBINDD_SOCKET_DIR",
 841         "WINBINDD_PRIV_PIPE_DIR",
 842         "NMBD_SOCKET_DIR",
 843         "LOCAL_PATH"
 844 );
 845
 846 $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 847         my $signame = shift;
 848         teardown_env($_) foreach(keys %running_envs);
 849         die("Received signal $signame");
 850 };
 851
 852 sub setup_env($$)
 853 {
 854         my ($name, $prefix) = @_;
 855
 856         my $testenv_vars = undef;
 857
 858         my $envname = $name;
 859         my $option = $name;
 860
 861         $envname =~ s/:.*//;
 862         $option =~ s/^[^:]*//;
 863         $option =~ s/^://;
 864
 865         $option = "client" if $option eq "";
 866
 867         if ($envname eq "none") {
 868                 $testenv_vars = {};
 869         } elsif (defined(get_running_env($envname))) {
 870                 $testenv_vars = get_running_env($envname);
 871                 if (not $testenv_vars->{target}->check_env($testenv_vars)) {
 872                         print $testenv_vars->{target}->getlog_env($testenv_vars);
 873                         $testenv_vars = undef;
 874                 }
 875         } else {
 876                 $testenv_vars = $target->setup_env($envname, $prefix);
 877                 if (defined($testenv_vars) && not defined($testenv_vars->{target})) {
 878                         $testenv_vars->{target} = $target;
 879                 }
 880                 if (not defined($testenv_vars)) {
 881                         warn("$opt_target can't provide environment '$envname'");
 882                 }
 883         }
 884
 885
 886         return undef unless defined($testenv_vars);
 887
 888         $running_envs{$envname} = $testenv_vars;
 889
 890         if ($option eq "local") {
 891                 SocketWrapper::set_default_iface($testenv_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 892                 $ENV{SMB_CONF_PATH} = $testenv_vars->{SERVERCONFFILE};
 893         } elsif ($option eq "client") {
 894                 SocketWrapper::set_default_iface(11);
 895                 write_clientconf($conffile, $clientdir, $testenv_vars);
 896                 $ENV{SMB_CONF_PATH} = $conffile;
 897         } else {
 898                 die("Unknown option[$option] for envname[$envname]");
 899         }
 900
 901         foreach (@exported_envvars) {
 902                 if (defined($testenv_vars->{$_})) {
 903                         $ENV{$_} = $testenv_vars->{$_};
 904                 } else {
 905                         delete $ENV{$_};
 906                 }
 907         }
 908
 909         return $testenv_vars;
 910 }
 911
 912 sub exported_envvars_str($)
 913 {
 914         my ($testenv_vars) = @_;
 915         my $out = "";
 916
 917         foreach (@exported_envvars) {
 918                 next unless defined($testenv_vars->{$_});
 919                 $out .= $_."=".$testenv_vars->{$_}."\n";
 920         }
 921
 922         return $out;
 923 }
 924
 925 sub getlog_env($)
 926 {
 927         my ($envname) = @_;
 928         return "" if ($envname eq "none");
 929         my $env = get_running_env($envname);
 930         return $env->{target}->getlog_env($env);
 931 }
 932
 933 sub check_env($)
 934 {
 935         my ($envname) = @_;
 936         return 1 if ($envname eq "none");
 937         my $env = get_running_env($envname);
 938         return $env->{target}->check_env($env);
 939 }
 940
 941 sub teardown_env($)
 942 {
 943         my ($envname) = @_;
 944         return if ($envname eq "none");
 945         my $env = get_running_env($envname);
 946         $env->{target}->teardown_env($env);
 947         delete $running_envs{$envname};
 948 }
 949
 950 # This 'global' file needs to be empty when we start
 951 unlink("$prefix_abs/dns_host_file");
 952
 953 if ($opt_testenv) {
 954         my $testenv_name = $ENV{SELFTEST_TESTENV};
 955         $testenv_name = $testenv_default unless defined($testenv_name);
 956
 957         my $testenv_vars = setup_env($testenv_name, $prefix);
 958
 959         die("Unable to setup environment $testenv_name") unless ($testenv_vars);
 960
 961         $ENV{PIDDIR} = $testenv_vars->{PIDDIR};
 962         $ENV{ENVNAME} = $testenv_name;
 963
 964         my $envvarstr = exported_envvars_str($testenv_vars);
 965
 966         my $term = ($ENV{TERMINAL} or "xterm -e");
 967         system("$term 'echo -e \"
 968 Welcome to the Samba4 Test environment '$testenv_name'
 969
 970 This matches the client environment used in make test
 971 server is pid `cat \$PIDDIR/samba.pid`
 972
 973 Some useful environment variables:
 974 TORTURE_OPTIONS=\$TORTURE_OPTIONS
 975 SMB_CONF_PATH=\$SMB_CONF_PATH
 976
 977 $envvarstr
 978 \" && LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} bash'");
 979         teardown_env($testenv_name);
 980 } elsif ($opt_list) {
 981         foreach (@todo) {
 982                 my $cmd = $$_[2];
 983                 my $name = $$_[0];
 984                 my $envname = $$_[1];
 985
 986                 unless($cmd =~ /\$LISTOPT/) {
 987                         warn("Unable to list tests in $name");
 988                         next;
 989                 }
 990
 991                 $cmd =~ s/\$LISTOPT/--list/g;
 992
 993                 system($cmd);
 994
 995                 if ($? == -1) {
 996                         die("Unable to run $cmd: $!");
 997                 } elsif ($? & 127) {
 998                         die(snprintf("%s died with signal %d, %s coredump\n", $cmd, ($? & 127),  ($? & 128) ? 'with' : 'without'));
 999                 }
1000
1001                 my $exitcode = $? >> 8;
1002                 if ($exitcode != 0) {
1003                         die("$cmd exited with exit code $exitcode");
1004                 }
1005         }
1006 } else {
1007         foreach (@todo) {
1008                 $i++;
1009                 my $cmd = $$_[2];
1010                 my $name = $$_[0];
1011                 my $envname = $$_[1];
1012
1013                 my $envvars = setup_env($envname, $prefix);
1014                 if (not defined($envvars)) {
1015                         Subunit::start_testsuite($name);
1016                         Subunit::end_testsuite($name, "error",
1017                                 "unable to set up environment $envname - exiting");
1018                         next;
1019                 }
1020
1021                 # Generate a file with the individual tests to run, if the
1022                 # test runner for this test suite supports it.
1023                 if ($individual_tests and $individual_tests->{$name}) {
1024                         if ($$_[3]) {
1025                                 my ($fh, $listid_file) = tempfile(UNLINK => 0);
1026                                 foreach my $test (@{$individual_tests->{$name}}) {
1027                                         print $fh substr($test, length($name)+1) . "\n";
1028                                 }
1029                                 $cmd =~ s/\$LOADLIST/--load-list=$listid_file/g;
1030                         } elsif ($$_[4]) {
1031                                 $cmd =~ s/\s+[^\s]+\s*$//;
1032                                 $cmd .= " " . join(' ', @{$individual_tests->{$name}});
1033                         }
1034                 }
1035
1036                 run_testsuite($envname, $name, $cmd, $i, $suitestotal);
1037
1038                 teardown_env($envname) if ($opt_resetup_env);
1039         }
1040 }
1041
1042 print "\n";
1043
1044 teardown_env($_) foreach (keys %running_envs);
1045
1046 my $failed = 0;
1047
1048 # if there were any valgrind failures, show them
1049 foreach (<$prefix/valgrind.log*>) {
1050         next unless (-s $_);
1051         print "VALGRIND FAILURE\n";
1052         $failed++;
1053         system("cat $_");
1054 }
1055 exit 0;