pidl/lib/Parse/Pidl/Samba3/ClientNDR.pm

   1 ###################################################
   2 # Samba3 client generator for IDL structures
   3 # on top of Samba4 style NDR functions
   4 # Copyright jelmer@samba.org 2005-2006
   5 # Copyright gd@samba.org 2008
   6 # released under the GNU GPL
   7
   8 package Parse::Pidl::Samba3::ClientNDR;
   9
  10 use Exporter;
  11 @ISA = qw(Exporter);
  12 @EXPORT_OK = qw(ParseFunction $res $res_hdr ParseOutputArgument);
  13
  14 use strict;
  15 use Parse::Pidl qw(fatal warning error);
  16 use Parse::Pidl::Util qw(has_property ParseExpr);
  17 use Parse::Pidl::Samba4 qw(DeclLong);
  18 use Parse::Pidl::Samba4::Header qw(GenerateFunctionInEnv);
  19
  20 use vars qw($VERSION);
  21 $VERSION = '0.01';
  22
  23 sub indent($) { my ($self) = @_; $self->{tabs}.="\t"; }
  24 sub deindent($) { my ($self) = @_; $self->{tabs} = substr($self->{tabs}, 1); }
  25 sub pidl($$) { my ($self,$txt) = @_; $self->{res} .= $txt ? "$self->{tabs}$txt\n" : "\n"; }
  26 sub pidl_hdr($$) { my ($self, $txt) = @_; $self->{res_hdr} .= "$txt\n"; }
  27 sub fn_declare($$) { my ($self,$n) = @_; $self->pidl($n); $self->pidl_hdr("$n;"); }
  28
  29 sub genpad($)
  30 {
  31         my ($s) = @_;
  32         my $nt = int((length($s)+1)/8);
  33         my $lt = ($nt*8)-1;
  34         my $ns = (length($s)-$lt);
  35         return "\t"x($nt)." "x($ns);
  36 }
  37
  38 sub new($)
  39 {
  40         my ($class) = shift;
  41         my $self = { res => "", res_hdr => "", tabs => "" };
  42         bless($self, $class);
  43 }
  44
  45 sub ElementDirection($)
  46 {
  47         my ($e) = @_;
  48
  49         return "[in,out]" if (has_property($e, "in") and has_property($e, "out"));
  50         return "[in]" if (has_property($e, "in"));
  51         return "[out]" if (has_property($e, "out"));
  52         return "[in,out]";
  53 }
  54
  55 sub HeaderProperties($$)
  56 {
  57         my($props,$ignores) = @_;
  58         my $ret = "";
  59
  60         foreach my $d (keys %{$props}) {
  61                 next if (grep(/^$d$/, @$ignores));
  62                 if($props->{$d} ne "1") {
  63                         $ret.= "$d($props->{$d}),";
  64                 } else {
  65                         $ret.="$d,";
  66                 }
  67         }
  68
  69         if ($ret) {
  70                 return "[" . substr($ret, 0, -1) . "]";
  71         }
  72 }
  73
  74 sub ParseOutputArgument($$$)
  75 {
  76         my ($self, $fn, $e) = @_;
  77         my $level = 0;
  78
  79         if ($e->{LEVELS}[0]->{TYPE} ne "POINTER" and $e->{LEVELS}[0]->{TYPE} ne "ARRAY") {
  80                 $self->pidl("return NT_STATUS_NOT_SUPPORTED;");
  81                 error($e->{ORIGINAL}, "[out] argument is not a pointer or array");
  82                 return;
  83         }
  84
  85         if ($e->{LEVELS}[0]->{TYPE} eq "POINTER") {
  86                 $level = 1;
  87                 if ($e->{LEVELS}[0]->{POINTER_TYPE} ne "ref") {
  88                         $self->pidl("if ($e->{NAME} && r.out.$e->{NAME}) {");
  89                         $self->indent;
  90                 }
  91         }
  92
  93         if ($e->{LEVELS}[$level]->{TYPE} eq "ARRAY") {
  94                 # This is a call to GenerateFunctionInEnv intentionally.
  95                 # Since the data is being copied into a user-provided data
  96                 # structure, the user should be able to know the size beforehand
  97                 # to allocate a structure of the right size.
  98                 my $env = GenerateFunctionInEnv($fn, "r.");
  99                 my $l = $e->{LEVELS}[$level];
 100                 unless (defined($l->{SIZE_IS})) {
 101                         error($e->{ORIGINAL}, "no size known for [out] array `$e->{NAME}'");
 102                         $self->pidl('#error No size known for [out] array `$e->{NAME}');
 103                 } else {
 104                         my $size_is = ParseExpr($l->{SIZE_IS}, $env, $e->{ORIGINAL});
 105                         if (has_property($e, "charset")) {
 106                                 $self->pidl("memcpy(CONST_DISCARD(char *, $e->{NAME}), r.out.$e->{NAME}, $size_is * sizeof(*$e->{NAME}));");
 107                         } else {
 108                                 $self->pidl("memcpy($e->{NAME}, r.out.$e->{NAME}, $size_is * sizeof(*$e->{NAME}));");
 109                         }
 110                 }
 111         } else {
 112                 $self->pidl("*$e->{NAME} = *r.out.$e->{NAME};");
 113         }
 114
 115         if ($e->{LEVELS}[0]->{TYPE} eq "POINTER") {
 116                 if ($e->{LEVELS}[0]->{POINTER_TYPE} ne "ref") {
 117                         $self->deindent;
 118                         $self->pidl("}");
 119                 }
 120         }
 121 }
 122
 123 sub ParseFunction($$$)
 124 {
 125         my ($self, $if, $fn) = @_;
 126
 127         my $fn_args = "";
 128         my $uif = uc($if);
 129         my $ufn = "NDR_".uc($fn->{NAME});
 130         my $fn_str = "NTSTATUS rpccli_$fn->{NAME}";
 131         my $pad = genpad($fn_str);
 132
 133         $fn_args .= "struct rpc_pipe_client *cli,\n" . $pad . "TALLOC_CTX *mem_ctx";
 134
 135         foreach (@{$fn->{ELEMENTS}}) {
 136                 my $dir = ElementDirection($_);
 137                 my $prop = HeaderProperties($_->{PROPERTIES}, ["in", "out"]);
 138                 $fn_args .= ",\n" . $pad . DeclLong($_) . " /* $dir $prop */";
 139         }
 140
 141         if (defined($fn->{RETURN_TYPE}) && ($fn->{RETURN_TYPE} eq "WERROR")) {
 142                 $fn_args .= ",\n" . $pad . "WERROR *werror";
 143         }
 144
 145         $self->fn_declare("$fn_str($fn_args)");
 146         $self->pidl("{");
 147         $self->indent;
 148         $self->pidl("struct $fn->{NAME} r;");
 149         $self->pidl("NTSTATUS status;");
 150         $self->pidl("");
 151         $self->pidl("/* In parameters */");
 152
 153         foreach (@{$fn->{ELEMENTS}}) {
 154                 if (grep(/in/, @{$_->{DIRECTION}})) {
 155                         $self->pidl("r.in.$_->{NAME} = $_->{NAME};");
 156                 }
 157         }
 158
 159         $self->pidl("");
 160         $self->pidl("if (DEBUGLEVEL >= 10) {");
 161         $self->indent;
 162         $self->pidl("NDR_PRINT_IN_DEBUG($fn->{NAME}, &r);");
 163         $self->deindent;
 164         $self->pidl("}");
 165         $self->pidl("");
 166         $self->pidl("status = cli->dispatch(cli,");
 167         $self->pidl("\t\t\tmem_ctx,");
 168         $self->pidl("\t\t\t&ndr_table_$if,");
 169         $self->pidl("\t\t\t$ufn,");
 170         $self->pidl("\t\t\t&r);");
 171         $self->pidl("");
 172
 173         $self->pidl("if (!NT_STATUS_IS_OK(status)) {");
 174         $self->indent;
 175         $self->pidl("return status;");
 176         $self->deindent;
 177         $self->pidl("}");
 178
 179         $self->pidl("");
 180         $self->pidl("if (DEBUGLEVEL >= 10) {");
 181         $self->indent;
 182         $self->pidl("NDR_PRINT_OUT_DEBUG($fn->{NAME}, &r);");
 183         $self->deindent;
 184         $self->pidl("}");
 185         $self->pidl("");
 186         $self->pidl("if (NT_STATUS_IS_ERR(status)) {");
 187         $self->indent;
 188         $self->pidl("return status;");
 189         $self->deindent;
 190         $self->pidl("}");
 191         $self->pidl("");
 192         $self->pidl("/* Return variables */");
 193         foreach my $e (@{$fn->{ELEMENTS}}) {
 194                 next unless (grep(/out/, @{$e->{DIRECTION}}));
 195
 196                 $self->ParseOutputArgument($fn, $e);
 197
 198         }
 199
 200         $self->pidl("");
 201         $self->pidl("/* Return result */");
 202         if (not $fn->{RETURN_TYPE}) {
 203                 $self->pidl("return NT_STATUS_OK;");
 204         } elsif ($fn->{RETURN_TYPE} eq "NTSTATUS") {
 205                 $self->pidl("return r.out.result;");
 206         } elsif ($fn->{RETURN_TYPE} eq "WERROR") {
 207                 $self->pidl("if (werror) {");
 208                 $self->indent;
 209                 $self->pidl("*werror = r.out.result;");
 210                 $self->deindent;
 211                 $self->pidl("}");
 212                 $self->pidl("");
 213                 $self->pidl("return werror_to_ntstatus(r.out.result);");
 214         } else {
 215                 warning($fn->{ORIGINAL}, "Unable to convert $fn->{RETURN_TYPE} to NTSTATUS");
 216                 $self->pidl("return NT_STATUS_OK;");
 217         }
 218
 219         $self->deindent;
 220         $self->pidl("}");
 221         $self->pidl("");
 222 }
 223
 224 sub ParseInterface($$)
 225 {
 226         my ($self, $if) = @_;
 227
 228         my $uif = uc($if->{NAME});
 229
 230         $self->pidl_hdr("#ifndef __CLI_$uif\__");
 231         $self->pidl_hdr("#define __CLI_$uif\__");
 232         foreach (@{$if->{FUNCTIONS}}) {
 233                 next if ($_->{PROPERTIES}{noopnum});
 234                 $self->ParseFunction($if->{NAME}, $_);
 235         }
 236         $self->pidl_hdr("#endif /* __CLI_$uif\__ */");
 237 }
 238
 239 sub Parse($$$$)
 240 {
 241         my($self,$ndr,$header,$ndr_header) = @_;
 242
 243         $self->pidl("/*");
 244         $self->pidl(" * Unix SMB/CIFS implementation.");
 245         $self->pidl(" * client auto-generated by pidl. DO NOT MODIFY!");
 246         $self->pidl(" */");
 247         $self->pidl("");
 248         $self->pidl("#include \"includes.h\"");
 249         $self->pidl("#include \"$header\"");
 250         $self->pidl_hdr("#include \"$ndr_header\"");
 251         $self->pidl("");
 252
 253         foreach (@$ndr) {
 254                 $self->ParseInterface($_) if ($_->{TYPE} eq "INTERFACE");
 255         }
 256
 257         return ($self->{res}, $self->{res_hdr});
 258 }
 259
 260 1;