configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[7.99.1],[https://github.com/heimdal/heimdal/issues])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.11])
  11 AM_MAINTAINER_MODE
  12
  13 LT_PREREQ([2.2])
  14 LT_INIT([shared static win32-dll])
  15
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC
  19 AM_PROG_CC_C_O
  20 AC_PROG_CPP
  21 AM_PATH_PYTHON
  22 AC_CHECK_PROG(CLANG_FORMAT, clang-format, [clang-format], [no])
  23
  24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  25
  26 AC_PREFIX_DEFAULT(/usr/heimdal)
  27
  28 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  29 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  30
  31 AC_CANONICAL_HOST
  32 CANONICAL_HOST=$host
  33 AC_SUBST(CANONICAL_HOST)
  34
  35 rk_SYS_LARGEFILE
  36
  37 rk_AIX
  38 rk_IRIX
  39 rk_SUNOS
  40
  41 dnl
  42 dnl this is needed to run the configure tests against glibc
  43 dnl
  44 AC_DEFINE([_GNU_SOURCE], 1,
  45         [Define to enable extensions on glibc-based systems such as Linux.])
  46
  47 AC_OBJEXT
  48 AC_EXEEXT
  49
  50 dnl
  51 dnl this is needed when der-protos.h or der-private.h has to be generated
  52 dnl
  53 if ! test -f "$srcdir/lib/asn1/der-protos.h" ||
  54    ! test -f "$srcdir/lib/asn1/der-private.h"; then
  55     AC_KRB_PROG_PERL
  56     AC_KRB_PERL_MOD(Getopt::Std)
  57     AC_KRB_PERL_MOD(File::Compare)
  58     AC_KRB_PERL_MOD(JSON)
  59 fi
  60
  61 dnl AC_KRB_PROG_YACC
  62 AC_PROG_YACC
  63 AM_PROG_LEX
  64 AS_IF([$LEX --nounput -V > /dev/null 2>&1 && test $? -eq 0],
  65       [AC_SUBST([FLEXNOUNPUTARGS], ["--nounput"])],
  66       [AC_SUBST([FLEXNOUNPUTARGS], [""])])
  67 dnl AC_PROG_RANLIB
  68 AC_PROG_AWK
  69 AC_KRB_PROG_LN_S
  70
  71 AC_MIPS_ABI
  72 CC="$CC $abi"
  73 libdir="$libdir$abilibdirext"
  74
  75 AC_C___ATTRIBUTE__
  76
  77 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  78 rk_VERSIONSCRIPT
  79
  80 dnl Code coverage
  81 AC_ARG_ENABLE([gcov],
  82         AC_HELP_STRING([--enable-gcov], [enable gcov code coverage tool]))
  83 AM_CONDITIONAL([ENABLE_GCOV], [test "x$enable_gcov" = xyes])
  84
  85
  86 dnl
  87 dnl Helper bits for cross compiling
  88 dnl
  89
  90
  91
  92 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  93
  94 AC_ARG_WITH(cross-tools,
  95         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  96         [if test "$withval" = "yes"; then
  97                 AC_MSG_ERROR([Need path to cross tools])
  98         fi
  99         with_cross_tools="${with_cross_tools}/"
 100         ])
 101
 102 if test "${cross_compiling}" != yes ; then
 103
 104    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
 105    SLC="\$(top_builddir)/lib/sl/slc"
 106
 107    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
 108    SLC_DEP="\$(SLC)"
 109 else
 110    ASN1_COMPILE="${with_cross_tools}asn1_compile"
 111    SLC="${with_cross_tools}slc"
 112
 113    ASN1_COMPILE_DEP=
 114    SLC_DEP=
 115
 116    ac_cv_prog_COMPILE_ET=${with_cross_tools}compile_et
 117
 118 fi
 119
 120 AC_SUBST([ASN1_COMPILE])
 121 AC_SUBST([ASN1_COMPILE_DEP])
 122 AC_SUBST([SLC])
 123 AC_SUBST([SLC_DEP])
 124
 125 dnl ---
 126
 127 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 128
 129 rk_TEST_PACKAGE(openldap,
 130 [#include <lber.h>
 131 #include <ldap.h>],
 132 [-lldap -llber],,,OPENLDAP)
 133 AM_CONDITIONAL(OPENLDAP, test "$with_openldap" != "no")
 134
 135 AC_ARG_ENABLE(hdb-openldap-module,
 136         AS_HELP_STRING([--enable-hdb-openldap-module],
 137                 [if you want support to build openldap hdb as shared object]))
 138 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 139     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 140 fi
 141 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 142
 143 AC_ARG_ENABLE(asn1-templating,
 144         AS_HELP_STRING([--disable-asn1-templating],
 145                 [if you want disable to use of the ASN.1 templating compiler]))
 146 AM_CONDITIONAL(ASN1_TEMPLATING, test "x$enable_asn1_templating" != xno)
 147
 148 dnl
 149 dnl Optional modules, pk-init, digest, kx509
 150 dnl
 151
 152 AC_ARG_ENABLE(pk-init,
 153         AS_HELP_STRING([--disable-pk-init],
 154                 [if you want disable to PK-INIT support]))
 155 if test "$enable_pk_init" != no ;then
 156         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 157 fi
 158 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 159
 160 AC_ARG_ENABLE(digest,
 161         AS_HELP_STRING([--disable-digest],
 162                 [if you want disable to DIGEST support]))
 163 if test "$enable_digest" != no ;then
 164         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 165 fi
 166
 167 AC_ARG_ENABLE(kx509,
 168         AS_HELP_STRING([--disable-kx509],
 169                 [if you want disable to kx509 support]))
 170 if test "$enable_kx509" != no ;then
 171         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 172 fi
 173
 174 dnl Need to test if pkg-config exists
 175 PKG_PROG_PKG_CONFIG
 176
 177 dnl libcap-ng
 178 AC_ARG_WITH([capng],
 179   AC_HELP_STRING([--with-capng], [use libcap-ng to drop KDC privileges @<:@default=check@:>@]),
 180   [],
 181   [with_capng=check])
 182 if test "$with_capng" != "no"; then
 183   PKG_CHECK_MODULES([CAPNG], [libcap-ng >= 0.4.0],
 184                     [with_capng=yes],[with_capng=no])
 185 fi
 186 if test "$with_capng" = "yes"; then
 187   AC_DEFINE_UNQUOTED([HAVE_CAPNG], 1, [whether capng is available for privilege reduction])
 188 fi
 189 AM_CONDITIONAL([HAVE_CAPNG], [test "$with_capng" != "no"])
 190 AC_SUBST([CAPNG_CFLAGS])
 191 AC_SUBST([CAPNG_LIBS])
 192
 193 dnl libmicrohttpd
 194 AC_ARG_WITH([microhttpd],
 195   AC_HELP_STRING([--with-microhttpd], [use microhttpd to serve KDC REST API @<:@default=check@:>@]),
 196   [],
 197   [with_microhttpd=check])
 198 if test "$with_microhttpd" != "no"; then
 199   PKG_CHECK_MODULES([MICROHTTPD], [libmicrohttpd >= 0.9.37],
 200                     [with_microhttpd=yes],[with_microhttpd=no])
 201 fi
 202 if test "$with_microhttpd" = "yes"; then
 203   AC_DEFINE_UNQUOTED([HAVE_MICROHTTPD], 1, [whether libmicrohttpd is available for KDC REST API])
 204 fi
 205 AM_CONDITIONAL([HAVE_MICROHTTPD], [test "$with_microhttpd" != "no"])
 206 AC_SUBST([MICROHTTPD_CFLAGS])
 207 AC_SUBST([MICROHTTPD_LIBS])
 208
 209 dnl libcjwt
 210 AC_ARG_WITH([cjwt],
 211   AC_HELP_STRING([--with-cjwt], [(Experimental) use cjwt to validate JWT tokens @<:@default=check@:>@]),
 212   [],
 213   [with_cjwt=check])
 214 if test "$with_cjwt" != "no"; then
 215   PKG_CHECK_MODULES([CJWT], [libcjwt >= 1.0.0],
 216                     [with_cjwt=yes],[with_cjwt=no])
 217 fi
 218 if test "$with_cjwt" = "yes"; then
 219   AC_DEFINE_UNQUOTED([HAVE_CJWT], 1, [whether libcjwt is available for KDC REST API])
 220 fi
 221 AM_CONDITIONAL([HAVE_CJWT], [test "$with_cjwt" != "no"])
 222 AC_SUBST([CJWT_CFLAGS])
 223 AC_SUBST([CJWT_LIBS])
 224
 225 dnl libcjson
 226 AC_ARG_WITH([cjson],
 227   AC_HELP_STRING([--with-cjson], [(Experimental) use cJSON to extract private claims from JWT tokens @<:@default=check@:>@]),
 228   [],
 229   [with_cjson=check])
 230 if test "$with_cjson" != "no"; then
 231   PKG_CHECK_MODULES([CJSON], [libcjson >= 1.0.0],
 232                     [with_cjson=yes],[with_cjson=no])
 233 fi
 234 if test "$with_cjson" = "yes"; then
 235   AC_DEFINE_UNQUOTED([HAVE_CJSON], 1, [whether libcjson is available for KDC REST API])
 236 fi
 237 AM_CONDITIONAL([HAVE_CJSON], [test "$with_cjson" != "no"])
 238 AC_SUBST([CJSON_CFLAGS])
 239 AC_SUBST([CJSON_LIBS])
 240
 241 dnl Check for sqlite
 242 rk_TEST_PACKAGE(sqlite3,
 243 [#include <sqlite3.h>
 244 #ifndef SQLITE_OPEN_CREATE
 245 #error "old version"
 246 #endif],
 247 [-lsqlite3],,,SQLITE3)
 248
 249 if test "X$with_sqlite3" != Xyes ; then
 250    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 251    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 252 fi
 253 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 254
 255 AC_DEFINE(HAVE_SQLITE3, 1, [Define if you want support for sqlite in Heimdal.])
 256
 257 AC_ARG_ENABLE(sqlite-cache,
 258         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 259 if test "$enable_sqlite_cache" != no; then
 260     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 261 fi
 262 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 263
 264
 265 dnl check for libintl
 266 rk_TEST_PACKAGE(libintl,
 267 [#include <libintl.h>],
 268 [-lintl],,,LIBINTL)
 269
 270 dnl path where the hdb directory is stored
 271 AC_ARG_WITH([hdbdir],
 272         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 273         [],
 274         [with_hdbdir=/var/heimdal])
 275 DIR_hdbdir="$with_hdbdir"
 276 AC_SUBST([DIR_hdbdir])
 277
 278
 279 AM_CONDITIONAL(KRB5, true)
 280 AM_CONDITIONAL(do_roken_rename, true)
 281
 282 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 283
 284
 285 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 286 AC_SUBST(LIB_kdb)dnl
 287
 288 KRB_CRYPTO
 289
 290 KRB_PTHREADS
 291
 292 AC_ARG_ENABLE(dce,
 293         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 294 if test "$enable_dce" = yes; then
 295     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 296 fi
 297 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 298
 299 ## XXX quite horrible:
 300 if test -f /etc/ibmcxx.cfg; then
 301         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 302         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 303         dpagaix_ldflags=
 304 else
 305         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 306         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 307         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 308 fi
 309 AC_SUBST(dpagaix_cflags)
 310 AC_SUBST(dpagaix_ldadd)
 311 AC_SUBST(dpagaix_ldflags)
 312
 313 AC_ARG_ENABLE([afs-support],
 314         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 315 if test "$enable_afs_support" = no; then
 316         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 317         NO_AFS="1"
 318 fi
 319 AC_SUBST(NO_AFS)dnl
 320 AM_CONDITIONAL(NO_AFS, test "$enable_afs_support" = no)
 321
 322 rk_DB
 323
 324 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 325
 326 rk_ROKEN(lib/roken)
 327 LIBADD_roken="$LIB_roken"
 328 AC_SUBST(LIBADD_roken)dnl
 329 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 330
 331 rk_OTP
 332
 333 rk_LIBDISPATCH
 334
 335 AC_CHECK_OSFC2
 336
 337 AC_ARG_ENABLE(mmap,
 338         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 339 if test "$enable_mmap" = "no"; then
 340         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 341 fi
 342
 343 AC_ARG_ENABLE(afs-string-to-key,
 344         AS_HELP_STRING([--disable-afs-string-to-key],
 345         [disable use of weak AFS string-to-key functions]),
 346         [], [enable_afs_string_to_key=yes])
 347
 348 if test "$enable_afs_string_to_key" = "yes"; then
 349         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 350         ENABLE_AFS_STRING_TO_KEY=1
 351 fi
 352 AC_SUBST(ENABLE_AFS_STRING_TO_KEY)dnl
 353
 354
 355 rk_CHECK_MAN
 356
 357 rk_TEST_PACKAGE(readline,
 358 [#include <stdio.h>
 359 #if defined(HAVE_READLINE_READLINE_H)
 360 #include <readline/readline.h>
 361 #elif defined(HAVE_READLINE_H)
 362 #include <readline.h>
 363 #endif
 364 ],-lreadline,,, READLINE,, [readline.h readline/readline.h])
 365
 366 rk_TEST_PACKAGE(libedit,
 367 [#include <stdio.h>
 368 #if defined(HAVE_READLINE_READLINE_H)
 369 #include <readline/readline.h>
 370 #elif defined(HAVE_READLINE_H)
 371 #include <readline.h>
 372 #elif defined(HAVE_EDITLINE_READLINE_H)
 373 #include <editline/readline.h>
 374 #endif
 375 ],-ledit,,, READLINE,, [readline.h readline/readline.h editline/readline.h])
 376
 377 AC_CONFIG_SUBDIRS([lib/libedit])
 378
 379 KRB_C_BIGENDIAN
 380 AC_C_INLINE
 381
 382 dnl AM_C_PROTOTYPES
 383
 384 dnl Checks for typedefs, structures, and compiler characteristics.
 385 AC_C_CONST
 386 AC_TYPE_OFF_T
 387 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 388 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 389 AC_HAVE_TYPE([long long])
 390 AC_HEADER_TIME
 391 AC_STRUCT_TM
 392
 393 dnl Checks for header files.
 394 AC_HEADER_STDC
 395
 396 AC_CHECK_HEADERS([\
 397         CommonCrypto/CommonDigest.h             \
 398         CommonCrypto/CommonCryptor.h            \
 399         arpa/telnet.h                           \
 400         bind/bitypes.h                          \
 401         bsdsetjmp.h                             \
 402         curses.h                                \
 403         dlfcn.h                                 \
 404         execinfo.h                              \
 405         fnmatch.h                               \
 406         inttypes.h                              \
 407         io.h                                    \
 408         keyutils.h                              \
 409         libutil.h                               \
 410         limits.h                                \
 411         maillock.h                              \
 412         netgroup.h                              \
 413         netinet/in6_machtypes.h                 \
 414         netinet/tcp.h                           \
 415         pthread.h                               \
 416         pty.h                                   \
 417         sac.h                                   \
 418         sgtty.h                                 \
 419         siad.h                                  \
 420         signal.h                                \
 421         strings.h                               \
 422         stropts.h                               \
 423         stdatomic.h                             \
 424         sys/bitypes.h                           \
 425         sys/category.h                          \
 426         sys/file.h                              \
 427         sys/filio.h                             \
 428         sys/ioccom.h                            \
 429         sys/mman.h                              \
 430         sys/param.h                             \
 431         sys/pty.h                               \
 432         sys/ptyio.h                             \
 433         sys/select.h                            \
 434         sys/socket.h                            \
 435         sys/str_tty.h                           \
 436         sys/stream.h                            \
 437         sys/stropts.h                           \
 438         sys/syscall.h                           \
 439         sys/termio.h                            \
 440         sys/timeb.h                             \
 441         sys/times.h                             \
 442         sys/types.h                             \
 443         sys/un.h                                \
 444         locale.h                                \
 445         termcap.h                               \
 446         termio.h                                \
 447         termios.h                               \
 448         time.h                                  \
 449         tmpdir.h                                \
 450         udb.h                                   \
 451         util.h                                  \
 452 ])
 453
 454 dnl On Solaris 8 there's a compilation warning for term.h because
 455 dnl it doesn't define `bool'.
 456 AC_CHECK_HEADERS(term.h, , , -)
 457
 458 dnl aix have asl.h (A/IX screen library) that we don't want
 459 AC_CHECK_HEADERS(asl.h, , , [
 460 #include <asl.h>
 461 #ifndef ASL_STRING_EMERG
 462 #error ASL_STRING_EMERG missing
 463 #endif])
 464
 465 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 466 #if HAVE_SYS_SOCKET_H
 467 #include <sys/socket.h>
 468 #endif])
 469
 470 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 471 #if HAVE_SYS_TTY_H
 472 #include <sys/tty.h>
 473 #endif])
 474
 475 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 476 #if HAVE_TERMIOS_H
 477 #include <termios.h>
 478 #endif
 479 #if HAVE_SYS_STREAM_H
 480 #include <sys/stream.h>
 481 #endif])
 482
 483 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 484 #if HAVE_SYS_TYPES_H
 485 #include <sys/types.h>
 486 #endif
 487 #if HAVE_SYS_PARAM_H
 488 #include <sys/param.h>
 489 #endif])
 490
 491 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 492 #include <security/pam_appl.h>
 493 ])
 494
 495 dnl export symbols
 496 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 497 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 498 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 499
 500 dnl Checks for libraries.
 501
 502 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 503 #ifdef HAVE_UTIL_H
 504 #include <util.h>
 505 #endif
 506 ],[0,0,0,0,0])
 507
 508 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses tinfo,[
 509 #ifdef HAVE_TERMCAP_H
 510 #include <termcap.h>
 511 #endif
 512 #ifdef HAVE_CURSES_H
 513 #include <curses.h>
 514 #endif
 515 ],[0,0])
 516
 517 dnl Checks for library functions.
 518
 519 AC_CHECK_FUNCS([                                \
 520         _scrsize                                \
 521         arc4random                              \
 522         backtrace                               \
 523         fcntl                                   \
 524         fork                                    \
 525         fseeko                                  \
 526         ftello                                  \
 527         getpeereid                              \
 528         getpeerucred                            \
 529         getresgid                               \
 530         getresuid                               \
 531         grantpt                                 \
 532         ptsname_r                               \
 533         rand                                    \
 534         setitimer                               \
 535         setregid                                \
 536         setresgid                               \
 537         setresuid                               \
 538         setreuid                                \
 539         setsid                                  \
 540         sigaction                               \
 541         unlockpt                                \
 542         waitpid                                 \
 543 ])
 544
 545 AC_MSG_CHECKING([checking for __sync_add_and_fetch])
 546 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 547         [[unsigned int foo, bar; bar = __sync_add_and_fetch(&foo, 1);]])],
 548         [ac_rk_have___sync_add_and_fetch=yes], [ac_rk_have___sync_add_and_fetch=no])
 549 if test "$ac_rk_have___sync_add_and_fetch" = "yes" ; then
 550         AC_DEFINE_UNQUOTED(HAVE___SYNC_ADD_AND_FETCH, 1, [have __sync_add_and_fetch])
 551 fi
 552 AC_MSG_RESULT($ac_rk_have___sync_add_and_fetch)
 553
 554 AC_FUNC_MMAP
 555
 556 rk_DLADDR
 557
 558 AC_CHECK_GETPWNAM_R_POSIX
 559 AC_CHECK_GETPWUID_R_POSIX
 560
 561 dnl detect doors on solaris
 562 if test "$enable_pthread_support" != no; then
 563    saved_LIBS="$LIBS"
 564    LIBS="$LIBS $PTHREADS_LIBS"
 565    AC_FIND_FUNC_NO_LIBS(door_create, door)
 566    LIBS="$saved_LIBS"
 567 fi
 568
 569 AC_ARG_ENABLE(kcm,
 570         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 571 ,[enable_kcm=yes])
 572
 573 if test "$enable_kcm" = yes ; then
 574    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 575         enable_kcm=no
 576    fi
 577 fi
 578 if test "$enable_kcm" = yes; then
 579        AC_DEFINE(HAVE_KCM, 1,
 580                [Define if you want to use the Kerberos Credentials Manager.])
 581 fi
 582 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 583
 584 dnl detect keyring on Linux
 585 if test "$ac_cv_header_keyutils_h" = yes; then
 586     AC_CHECK_SIZEOF([key_serial_t],,[
 587         #ifdef HAVE_INTTYPES_H
 588         #include <inttypes.h>
 589         #endif
 590         #ifdef HAVE_SYS_TYPES_H
 591         #include <sys/types.h>
 592         #endif
 593         #include <keyutils.h>
 594     ])
 595 fi
 596
 597 AC_FIND_FUNC_NO_LIBS(add_key, keyutils)
 598 if test -n "$LIB_add_key"; then
 599     saved_LIBS="$LIBS"
 600     LIBS="$LIBS $LIB_add_key"
 601     AC_CHECK_FUNCS(keyctl_get_persistent)
 602     LIBS="$saved_LIBS"
 603 fi
 604
 605 AC_CHECK_SIZEOF([time_t])
 606
 607 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 608         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 609         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 610 #ifdef HAVE_INTTYPES_H
 611 #include <inttypes.h>
 612 #endif
 613 #ifdef HAVE_SYS_TYPES_H
 614 #include <sys/types.h>
 615 #endif
 616 #ifdef HAVE_SYS_BITYPES_H
 617 #include <sys/bitypes.h>
 618 #endif
 619 #ifdef HAVE_BIND_BITYPES_H
 620 #include <bind/bitypes.h>
 621 #endif
 622 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 623 #include <netinet/in6_machtypes.h>
 624 #endif
 625 ])
 626
 627 rk_FRAMEWORK_SECURITY
 628 rk_FRAMEWORK_COREFOUNDATION
 629
 630 KRB_READLINE
 631
 632 rk_TELNET
 633
 634 dnl Some operating systems already have com_err and compile_et
 635 CHECK_COMPILE_ET
 636
 637 rk_AUTH_MODULES([sia afskauthlib])
 638
 639 rk_DESTDIRS
 640
 641 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 642
 643
 644 AH_BOTTOM([#ifdef __APPLE__
 645 #include <AvailabilityMacros.h>
 646 #endif])
 647
 648 AH_BOTTOM([#ifdef ROKEN_RENAME
 649 #include "roken_rename.h"
 650 #endif])
 651
 652 AC_ARG_ENABLE(heimdal-documentation,
 653         AS_HELP_STRING([--disable-heimdal-documentation],
 654                 [if you want disable to heimdal documentation]))
 655 AM_CONDITIONAL(HEIMDAL_DOCUMENTATION, test "$enable_heimdal_documentation" != no)
 656
 657 AC_CONFIG_FILES(Makefile                \
 658         etc/Makefile                    \
 659         include/Makefile                \
 660         include/gssapi/Makefile         \
 661         include/hcrypto/Makefile        \
 662         include/kadm5/Makefile          \
 663         lib/Makefile                    \
 664         lib/base/Makefile                       \
 665         lib/asn1/Makefile               \
 666         lib/com_err/Makefile            \
 667         lib/hcrypto/Makefile            \
 668         lib/hx509/Makefile              \
 669         lib/gssapi/Makefile             \
 670         lib/ntlm/Makefile               \
 671         lib/hdb/Makefile                \
 672         lib/ipc/Makefile                \
 673         lib/kadm5/Makefile              \
 674         lib/kafs/Makefile               \
 675         lib/kdfs/Makefile               \
 676         lib/krb5/Makefile               \
 677         lib/otp/Makefile                \
 678         lib/roken/Makefile              \
 679         lib/sl/Makefile                 \
 680         lib/sqlite/Makefile             \
 681         lib/vers/Makefile               \
 682         lib/wind/Makefile               \
 683         lib/gss_preauth/Makefile        \
 684         po/Makefile                     \
 685         kuser/Makefile                  \
 686         kpasswd/Makefile                \
 687         kadmin/Makefile                 \
 688         admin/Makefile                  \
 689         kcm/Makefile                    \
 690         kdc/Makefile                    \
 691         appl/Makefile                   \
 692         appl/afsutil/Makefile           \
 693         appl/dbutils/Makefile           \
 694         appl/gssmask/Makefile           \
 695         appl/otp/Makefile               \
 696         appl/test/Makefile              \
 697         appl/kf/Makefile                \
 698         appl/dceutils/Makefile          \
 699         tests/Makefile                  \
 700         tests/bin/Makefile              \
 701         tests/can/Makefile              \
 702         tests/db/Makefile               \
 703         tests/kdc/Makefile              \
 704         tests/ldap/Makefile             \
 705         tests/gss/Makefile              \
 706         tests/java/Makefile             \
 707         tests/plugin/Makefile           \
 708         packages/Makefile               \
 709         packages/mac/Makefile           \
 710         doc/Makefile                    \
 711         tools/Makefile                  \
 712 )
 713
 714 AC_OUTPUT
 715
 716 dnl
 717 dnl This is the release version name-number[beta]
 718 dnl
 719
 720 if test -d "$srcdir/.git"; then
 721     cat > include/newversion.h.in <<EOF
 722 #ifndef VERSION_HIDDEN
 723 #define VERSION_HIDDEN
 724 #endif
 725 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ @BRANCH@ @TAG@ ($host) @COMMIT@ @DATE@ \$";
 726 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 727 EOF
 728 else
 729     cat > include/newversion.h.in <<EOF
 730 #ifndef VERSION_HIDDEN
 731 #define VERSION_HIDDEN
 732 #endif
 733 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 734 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 735 EOF
 736 fi
 737
 738 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 739         echo "include/version.h is unchanged"
 740         rm -f include/newversion.h.in
 741 else
 742         echo "creating include/version.h"
 743         if test -n "$SOURCE_DATE_EPOCH"; then
 744             Date=`
 745                   # BSD, OS X
 746                   date -u -r "$SOURCE_DATE_EPOCH" "+%Y-%m-%dT%H:%M:%SZ" 2>/dev/null ||
 747                   # Linux
 748                   date -u -d "@${SOURCE_DATE_EPOCH}" 2>/dev/null ||
 749                   # Illumos -- sorry, no -r/-d here
 750                   date -u ||
 751                   date`
 752         else
 753             Date=`date -u "+%Y-%m-%dT%H:%M:%SZ"`
 754         fi
 755         if test -n "$SOURCE_HOST"; then
 756             Host=$SOURCE_HOST
 757         else
 758             Host=`uname -n`
 759         fi
 760         if test -n "$SOURCE_USER"; then
 761             User=$SOURCE_USER
 762         else
 763             User=${USER:-${LOGNAME:-`id -nu`}}
 764         fi
 765         if test -d "$srcdir/.git"; then
 766             GitCommit=`cd $srcdir && git rev-parse HEAD`
 767             GitBranch=`cd $srcdir && git rev-parse --abbrev-ref HEAD`
 768             if test "x$GitBranch" = master; then
 769                 GitDesc=`cd $srcdir && git describe --all --dirty`
 770             else
 771                 GitDesc=`cd $srcdir && \
 772                          git describe --tags --match 'heimdal-*' --dirty`
 773             fi
 774         else
 775             GitCommit='<commit-unknown>'
 776             GitBranch='<branch-unknown>'
 777             GitDesc='<tag-unknown>'
 778         fi
 779         mv -f include/newversion.h.in include/version.h.in
 780         sed -e "s/@HOST@/$Host/" \
 781             -e "s;@USER@;$User;" \
 782             -e "s;@DATE@;$Date;" \
 783             -e "s;@BRANCH@;$GitBranch;" \
 784             -e "s;@TAG@;$GitDesc;" \
 785             -e "s;@COMMIT@;$GitCommit;" \
 786             include/version.h.in > include/version.h
 787 fi