acinclude.m4

   1 dnl Macros that test for specific features.
   2 dnl This file is part of the Autoconf packaging for Wireshark.
   3 dnl Copyright (C) 1998-2000 by Gerald Combs.
   4 dnl
   5 dnl $Id$
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2, or (at your option)
  10 dnl any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20 dnl 02111-1307, USA.
  21 dnl
  22 dnl As a special exception, the Free Software Foundation gives unlimited
  23 dnl permission to copy, distribute and modify the configure scripts that
  24 dnl are the output of Autoconf.  You need not follow the terms of the GNU
  25 dnl General Public License when using or distributing such scripts, even
  26 dnl though portions of the text of Autoconf appear in them.  The GNU
  27 dnl General Public License (GPL) does govern all other use of the material
  28 dnl that constitutes the Autoconf program.
  29 dnl
  30 dnl Certain portions of the Autoconf source text are designed to be copied
  31 dnl (in certain cases, depending on the input) into the output of
  32 dnl Autoconf.  We call these the "data" portions.  The rest of the Autoconf
  33 dnl source text consists of comments plus executable code that decides which
  34 dnl of the data portions to output in any given case.  We call these
  35 dnl comments and executable code the "non-data" portions.  Autoconf never
  36 dnl copies any of the non-data portions into its output.
  37 dnl
  38 dnl This special exception to the GPL applies to versions of Autoconf
  39 dnl released by the Free Software Foundation.  When you make and
  40 dnl distribute a modified version of Autoconf, you may extend this special
  41 dnl exception to the GPL to apply to your modified version as well, *unless*
  42 dnl your modified version has the potential to copy into its output some
  43 dnl of the text that was the non-data portion of the version that you started
  44 dnl with.  (In other words, unless your change moves or copies text from
  45 dnl the non-data portions to the data portions.)  If your modification has
  46 dnl such potential, you must delete any notice of this special exception
  47 dnl to the GPL from your modified version.
  48 dnl
  49 dnl Written by David MacKenzie, with help from
  50 dnl Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
  51 dnl Roland McGrath, Noah Friedman, david d zuhn, and many others.
  52
  53 #
  54 # AC_WIRESHARK_ADD_DASH_L
  55 #
  56 # Add to the variable specified as the first argument a "-L" flag for the
  57 # directory specified as the second argument, and, on Solaris, add a
  58 # "-R" flag for it as well.
  59 #
  60 # XXX - IRIX, and other OSes, may require some flag equivalent to
  61 # "-R" here.
  62 #
  63 AC_DEFUN([AC_WIRESHARK_ADD_DASH_L],
  64 [$1="$$1 -L$2"
  65 case "$host_os" in
  66   solaris*)
  67     $1="$$1 -R$2"
  68   ;;
  69 esac
  70 ])
  71
  72 #
  73 # AC_WIRESHARK_TIMEZONE_ABBREV
  74 #
  75
  76 AC_DEFUN([AC_WIRESHARK_TIMEZONE_ABBREV],
  77 [
  78   AC_CACHE_CHECK([for tm_zone in struct tm],
  79     ac_cv_wireshark_have_tm_zone,
  80     [
  81       AC_TRY_COMPILE(
  82         [#include <time.h>],
  83         [struct tm t; t.tm_zone;],
  84         ac_cv_wireshark_have_tm_zone=yes,
  85         ac_cv_wireshark_have_tm_zone=no)
  86     ])
  87   if test $ac_cv_wireshark_have_tm_zone = yes; then
  88     AC_DEFINE(HAVE_TM_ZONE, 1, [Define if tm_zone field exists in struct tm])
  89   else
  90     AC_CACHE_CHECK([for tzname],
  91       ac_cv_wireshark_have_tzname,
  92       [
  93         AC_TRY_LINK(
  94 [#include <time.h>
  95 #include <stdio.h>],
  96           [printf("%s", tzname[0]);],
  97           ac_cv_wireshark_have_tzname=yes,
  98           ac_cv_wireshark_have_tzname=no)
  99       ])
 100     if test $ac_cv_wireshark_have_tzname = yes; then
 101       AC_DEFINE(HAVE_TZNAME, 1, [Define if tzname array exists])
 102     fi
 103   fi
 104 ])
 105
 106
 107 #
 108 # AC_WIRESHARK_STRUCT_ST_FLAGS
 109 #
 110 dnl AC_STRUCT_ST_BLKSIZE extracted from the file in question,
 111 dnl "acspecific.m4" in GNU Autoconf 2.12, and turned into
 112 dnl AC_WIRESHARK_STRUCT_ST_FLAGS, which checks if "struct stat"
 113 dnl has the 4.4BSD "st_flags" member, and defines HAVE_ST_FLAGS; that's
 114 dnl what's in this file.
 115 dnl Done by Guy Harris <guy@alum.mit.edu> on 2012-06-02.
 116
 117 dnl ### Checks for structure members
 118
 119 AC_DEFUN([AC_WIRESHARK_STRUCT_ST_FLAGS],
 120 [AC_CACHE_CHECK([for st_flags in struct stat], ac_cv_wireshark_struct_st_flags,
 121 [AC_TRY_COMPILE([#include <sys/stat.h>], [struct stat s; s.st_flags;],
 122 ac_cv_wireshark_struct_st_flags=yes, ac_cv_wireshark_struct_st_flags=no)])
 123 if test $ac_cv_wireshark_struct_st_flags = yes; then
 124   AC_DEFINE(HAVE_ST_FLAGS, 1, [Define if st_flags field exists in struct stat])
 125 fi
 126 ])
 127
 128
 129 #
 130 # AC_WIRESHARK_STRUCT_SA_LEN
 131 #
 132 dnl AC_STRUCT_ST_BLKSIZE extracted from the file in question,
 133 dnl "acspecific.m4" in GNU Autoconf 2.12, and turned into
 134 dnl AC_WIRESHARK_STRUCT_SA_LEN, which checks if "struct sockaddr"
 135 dnl has the 4.4BSD "sa_len" member, and defines HAVE_SA_LEN; that's
 136 dnl what's in this file.
 137 dnl Done by Guy Harris <guy@alum.mit.edu> on 1998-11-14.
 138
 139 dnl ### Checks for structure members
 140
 141 AC_DEFUN([AC_WIRESHARK_STRUCT_SA_LEN],
 142 [AC_CACHE_CHECK([for sa_len in struct sockaddr], ac_cv_wireshark_struct_sa_len,
 143 [AC_TRY_COMPILE([#include <sys/types.h>
 144 #include <sys/socket.h>], [struct sockaddr s; s.sa_len;],
 145 ac_cv_wireshark_struct_sa_len=yes, ac_cv_wireshark_struct_sa_len=no)])
 146 if test $ac_cv_wireshark_struct_sa_len = yes; then
 147   AC_DEFINE(HAVE_SA_LEN, 1, [Define if sa_len field exists in struct sockaddr])
 148 fi
 149 ])
 150
 151
 152 #
 153 # AC_WIRESHARK_IPV6_STACK
 154 #
 155 # By Jun-ichiro "itojun" Hagino, <itojun@iijlab.net>
 156 #
 157 AC_DEFUN([AC_WIRESHARK_IPV6_STACK],
 158 [
 159         v6type=unknown
 160         v6lib=none
 161
 162         AC_MSG_CHECKING([ipv6 stack type])
 163         for i in v6d toshiba kame inria zeta linux linux-glibc solaris; do
 164                 case $i in
 165                 v6d)
 166                         AC_EGREP_CPP(yes, [
 167 #include </usr/local/v6/include/sys/types.h>
 168 #ifdef __V6D__
 169 yes
 170 #endif],
 171                                 [v6type=$i; v6lib=v6;
 172                                 v6libdir=/usr/local/v6/lib;
 173                                 #
 174                                 # XXX - this doesn't define INET6;
 175                                 # is that a mistake?
 176                                 #
 177                                 CPPFLAGS="-I/usr/local/v6/include $CPPFLAGS"])
 178                         ;;
 179                 toshiba)
 180                         AC_EGREP_CPP(yes, [
 181 #include <sys/param.h>
 182 #ifdef _TOSHIBA_INET6
 183 yes
 184 #endif],
 185                                 [v6type=$i; v6lib=inet6;
 186                                 v6libdir=/usr/local/v6/lib;
 187                                 AC_DEFINE(INET6, 1, [Define if the platform supports IPv6])])
 188                         ;;
 189                 kame)
 190                         AC_EGREP_CPP(yes, [
 191 #include <netinet/in.h>
 192 #ifdef __KAME__
 193 yes
 194 #endif],
 195                                 [v6type=$i; v6lib=inet6;
 196                                 v6libdir=/usr/local/v6/lib;
 197                                 AC_DEFINE(INET6, 1, [Define if the platform supports IPv6])])
 198                         ;;
 199                 inria)
 200                         AC_EGREP_CPP(yes, [
 201 #include <netinet/in.h>
 202 #ifdef IPV6_INRIA_VERSION
 203 yes
 204 #endif],
 205                                 [v6type=$i;
 206                                 AC_DEFINE(INET6, 1, [Define if the platform supports IPv6])])
 207                         ;;
 208                 zeta)
 209                         AC_EGREP_CPP(yes, [
 210 #include <sys/param.h>
 211 #ifdef _ZETA_MINAMI_INET6
 212 yes
 213 #endif],
 214                                 [v6type=$i; v6lib=inet6;
 215                                 v6libdir=/usr/local/v6/lib;
 216                                 AC_DEFINE(INET6, 1, [Define if the platform supports IPv6])])
 217                         ;;
 218                 linux)
 219                         if test -d /usr/inet6; then
 220                                 v6type=$i
 221                                 v6lib=inet6
 222                                 v6libdir=/usr/inet6
 223                                 AC_DEFINE(INET6, 1, [Define if the platform supports IPv6])
 224                         fi
 225                         ;;
 226                 linux-glibc)
 227                         AC_EGREP_CPP(yes, [
 228 #include <features.h>
 229 #if defined(__GLIBC__) && defined(__GLIBC_MINOR__)
 230 #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || __GLIBC__ > 2
 231 yes
 232 #endif
 233 #endif],
 234                         [v6type=$i; v6lib=inet6;
 235                         AC_DEFINE(INET6, 1, [Define if the platform supports IPv6])])
 236                         ;;
 237                 solaris)
 238                         #
 239                         # There's nothing we can check for in the header
 240                         # file, so we just check for SunOS (pre-SunOS 5
 241                         # versions didn't include IPv6 support, so we
 242                         # just check the OS, not the version).
 243                         #
 244                         if test "`uname -s`" = "SunOS"; then
 245                                 v6type=$i
 246                                 v6lib=inet6
 247                                 AC_DEFINE(INET6, 1, [Define if the platform supports IPv6])
 248                         fi
 249                         ;;
 250                 esac
 251                 if test "$v6type" != "unknown"; then
 252                         break
 253                 fi
 254         done
 255
 256         if test "$v6lib" != "none"; then
 257                 for dir in $v6libdir /usr/local/v6/lib /usr/local/lib; do
 258                         if test -d $dir -a -f $dir/lib$v6lib.a; then
 259                                 LIBS="-L$dir $LIBS -l$v6lib"
 260                                 break
 261                         fi
 262                 done
 263                 enable_ipv6="yes"
 264         else
 265                 enable_ipv6="no"
 266         fi
 267         AC_MSG_RESULT(["$v6type, $v6lib"])
 268 ])
 269
 270 #
 271 # AC_WIRESHARK_GETADDRINFO_LIB_CHECK
 272 #
 273 # Checks whether we have "getaddrinfo()" and whether we need "-lnsl" to get it.
 274 AC_DEFUN([AC_WIRESHARK_GETADDRINFO_LIB_CHECK],
 275 [
 276     AC_CHECK_FUNCS(getaddrinfo, ,
 277         AC_CHECK_LIB(nsl, getaddrinfo,
 278                      [
 279                          NSL_LIBS="-lnsl"
 280                          AC_DEFINE(HAVE_GETADDRINFO, 1, [Defined if we have getaddrinfo])
 281                      ]))
 282     AC_SUBST(NSL_LIBS)
 283 ])
 284
 285 #
 286 # AC_WIRESHARK_GETHOSTBY_LIB_CHECK
 287 #
 288 # Checks whether we need "-lnsl" to get "gethostby*()", which we use
 289 # in "resolv.c".
 290 #
 291 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 292 # GNU Autoconf 2.13; the comment came from there.
 293 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 294 #
 295 AC_DEFUN([AC_WIRESHARK_GETHOSTBY_LIB_CHECK],
 296 [
 297     # msh@cis.ufl.edu says -lnsl (and -lsocket) are needed for his 386/AT,
 298     # to get the SysV transport functions.
 299     # chad@anasazi.com says the Pyramid MIS-ES running DC/OSx (SVR4)
 300     # needs -lnsl.
 301     # The nsl library prevents programs from opening the X display
 302     # on Irix 5.2, according to dickey@clark.net.
 303     AC_CHECK_FUNCS(gethostbyname, ,
 304         AC_CHECK_LIB(nsl, gethostbyname,
 305                      [
 306                         NSL_LIBS="-lnsl"
 307                         AC_DEFINE(HAVE_GETHOSTBYNAME, 1, [Defined if we have gethostbyname])
 308                      ]))
 309     AC_SUBST(NSL_LIBS)
 310 ])
 311
 312 #
 313 # AC_WIRESHARK_SOCKET_LIB_CHECK
 314 #
 315 # Checks whether we need "-lsocket" to get "socket()", which is used
 316 # by libpcap on some platforms - and, in effect, "gethostbyname()" or
 317 # "getaddrinfo()" on most if not all platforms (so that it can use NIS or
 318 # DNS or... to look up host names).
 319 #
 320 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 321 # GNU Autoconf 2.13; the comment came from there.
 322 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 323 #
 324 # We use "connect" because that's what AC_PATH_XTRA did.
 325 #
 326 AC_DEFUN([AC_WIRESHARK_SOCKET_LIB_CHECK],
 327 [
 328     # lieder@skyler.mavd.honeywell.com says without -lsocket,
 329     # socket/setsockopt and other routines are undefined under SCO ODT
 330     # 2.0.  But -lsocket is broken on IRIX 5.2 (and is not necessary
 331     # on later versions), says simon@lia.di.epfl.ch: it contains
 332     # gethostby* variants that don't use the nameserver (or something).
 333     # -lsocket must be given before -lnsl if both are needed.
 334     # We assume that if connect needs -lnsl, so does gethostbyname.
 335     AC_CHECK_FUNC(connect, ,
 336       AC_CHECK_LIB(socket, connect, SOCKET_LIBS="-lsocket",
 337                 AC_MSG_ERROR(Function 'socket' not found.), $NSL_LIBS))
 338     AC_SUBST(SOCKET_LIBS)
 339 ])
 340
 341 #
 342 # AC_WIRESHARK_BREAKLOOP_TRY_LINK
 343 #
 344 AC_DEFUN([AC_WIRESHARK_PCAP_BREAKLOOP_TRY_LINK],
 345 [
 346   AC_LINK_IFELSE(
 347   [
 348       AC_LANG_SOURCE(
 349       [[
 350 #       include <pcap.h>
 351         int main(void)
 352         {
 353           pcap_t  *pct = NULL;
 354           pcap_breakloop(pct);
 355           return 0;
 356         }
 357       ]])
 358   ],
 359   [
 360     ws_breakloop_compiled=yes
 361   ],
 362   [
 363     ws_breakloop_compiled=no
 364   ])
 365 ])
 366
 367
 368
 369 #
 370 # AC_WIRESHARK_PCAP_CHECK
 371 #
 372 AC_DEFUN([AC_WIRESHARK_PCAP_CHECK],
 373 [
 374         if test -z "$pcap_dir"
 375         then
 376           # Pcap header checks
 377           # XXX need to set a var AC_CHECK_HEADER(pcap.h,,)
 378
 379           #
 380           # The user didn't specify a directory in which libpcap resides.
 381           # First, look for a pcap-config script.
 382           #
 383           AC_PATH_PROG(PCAP_CONFIG, pcap-config)
 384
 385           if test -n "$PCAP_CONFIG" ; then
 386             #
 387             # Found it.
 388             #
 389             # Now check whether it's the libpcap 1.0 version, which
 390             # put a space after "-L" - on some platforms, that doesn't
 391             # work.
 392             #
 393             AC_MSG_CHECKING(for broken pcap-config)
 394             case "`\"$PCAP_CONFIG\" --libs`" in
 395
 396             "-L "*)
 397               #
 398               # Space after -L.  Pretend pcap-config doesn't exist.
 399               #
 400               AC_MSG_RESULT(yes)
 401               PCAP_CONFIG=""
 402               ;;
 403
 404             *)
 405               #
 406               # No space after -L.
 407               #
 408               AC_MSG_RESULT(no)
 409               ;;
 410             esac
 411           fi
 412           if test -n "$PCAP_CONFIG" ; then
 413             #
 414             # Found it, and it's usable; use it to get the include flags
 415             # for libpcap.
 416             #
 417             CPPFLAGS="$CPPFLAGS `\"$PCAP_CONFIG\" --cflags`"
 418           else
 419             #
 420             # Didn't find it; we have to look for libpcap ourselves.
 421             # We assume that the current library search path will work,
 422             # but we may have to look for the header in a "pcap"
 423             # subdirectory of "/usr/include" or "/usr/local/include",
 424             # as some systems apparently put "pcap.h" in a "pcap"
 425             # subdirectory, and we also check "$prefix/include" - and
 426             # "$prefix/include/pcap", in case $prefix is set to
 427             # "/usr/include" or "/usr/local/include".
 428             #
 429             # XXX - should we just add "$prefix/include" to the include
 430             # search path and "$prefix/lib" to the library search path?
 431             #
 432             AC_MSG_CHECKING(for extraneous pcap header directories)
 433             found_pcap_dir=""
 434             pcap_dir_list="/usr/include/pcap $prefix/include/pcap $prefix/include"
 435             if test "x$ac_cv_enable_usr_local" = "xyes" ; then
 436               pcap_dir_list="$pcap_dir_list /usr/local/include/pcap"
 437             fi
 438             for pcap_dir in $pcap_dir_list
 439             do
 440               if test -d $pcap_dir ; then
 441                 if test x$pcap_dir != x/usr/include -a x$pcap_dir != x/usr/local/include ; then
 442                     CPPFLAGS="$CPPFLAGS -I$pcap_dir"
 443                 fi
 444                 found_pcap_dir=" $found_pcap_dir -I$pcap_dir"
 445                 break
 446               fi
 447             done
 448
 449             if test "$found_pcap_dir" != "" ; then
 450               AC_MSG_RESULT(found --$found_pcap_dir added to CFLAGS)
 451             else
 452               AC_MSG_RESULT(not found)
 453             fi
 454           fi
 455         else
 456           #
 457           # The user specified a directory in which libpcap resides,
 458           # so add the "include" subdirectory of that directory to
 459           # the include file search path and the "lib" subdirectory
 460           # of that directory to the library search path.
 461           #
 462           # XXX - if there's also a libpcap in a directory that's
 463           # already in CPPFLAGS or LDFLAGS, this won't make us find
 464           # the version in the specified directory, as the compiler
 465           # and/or linker will search that other directory before it
 466           # searches the specified directory.
 467           #
 468           CPPFLAGS="$CPPFLAGS -I$pcap_dir/include"
 469           AC_WIRESHARK_ADD_DASH_L(LDFLAGS, $pcap_dir/lib)
 470         fi
 471
 472         # Pcap header check
 473         AC_CHECK_HEADER(pcap.h,,
 474             AC_MSG_ERROR([[Header file pcap.h not found; if you installed libpcap
 475 from source, did you also do \"make install-incl\", and if you installed a
 476 binary package of libpcap, is there also a developer's package of libpcap,
 477 and did you also install that package?]]))
 478
 479         if test -n "$PCAP_CONFIG" ; then
 480           #
 481           # We have pcap-config; we assume that means we have libpcap
 482           # installed and that pcap-config will tell us whatever
 483           # libraries libpcap needs.
 484           #
 485           if test x$enable_static = xyes; then
 486             PCAP_LIBS="`\"$PCAP_CONFIG\" --libs --static`"
 487           else
 488             PCAP_LIBS="`\"$PCAP_CONFIG\" --libs`"
 489           fi
 490           AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 491         else
 492           #
 493           # Check to see if we find "pcap_open_live" in "-lpcap".
 494           # Also check for various additional libraries that libpcap might
 495           # require.
 496           #
 497           AC_CHECK_LIB(pcap, pcap_open_live,
 498             [
 499               PCAP_LIBS=-lpcap
 500               AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 501             ], [
 502               ac_wireshark_extras_found=no
 503               ac_save_LIBS="$LIBS"
 504               for extras in "-lcfg -lodm" "-lpfring"
 505               do
 506                 AC_MSG_CHECKING([for pcap_open_live in -lpcap with $extras])
 507                 LIBS="-lpcap $extras"
 508                 #
 509                 # XXX - can't we use AC_CHECK_LIB here?
 510                 #
 511                 AC_TRY_LINK(
 512                     [
 513 #       include <pcap.h>
 514                     ],
 515                     [
 516         pcap_open_live(NULL, 0, 0, 0, NULL);
 517                     ],
 518                     [
 519                         ac_wireshark_extras_found=yes
 520                         AC_MSG_RESULT([yes])
 521                         PCAP_LIBS="-lpcap $extras"
 522                         AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 523                     ],
 524                     [
 525                         AC_MSG_RESULT([no])
 526                     ])
 527                 if test x$ac_wireshark_extras_found = xyes
 528                 then
 529                     break
 530                 fi
 531               done
 532               if test x$ac_wireshark_extras_found = xno
 533               then
 534                 AC_MSG_ERROR([Can't link with library libpcap.])
 535               fi
 536               LIBS=$ac_save_LIBS
 537             ], $SOCKET_LIBS $NSL_LIBS)
 538         fi
 539         AC_SUBST(PCAP_LIBS)
 540
 541         #
 542         # Check whether various variables and functions are defined by
 543         # libpcap.
 544         #
 545         ac_save_LIBS="$LIBS"
 546         LIBS="$PCAP_LIBS $SOCKET_LIBS $NSL_LIBS $LIBS"
 547         AC_CHECK_FUNCS(pcap_open_dead pcap_freecode)
 548         #
 549         # pcap_breakloop may be present in the library but not declared
 550         # in the pcap.h header file.  If it's not declared in the header
 551         # file, attempts to use it will get warnings, and, if we're
 552         # building with warnings treated as errors, that warning will
 553         # cause compilation to fail.
 554         #
 555         # We are therefore first testing whether the function is present
 556         # and then, if we're compiling with warnings as errors, testing
 557         # whether it is usable.  It is usable if it compiles without
 558         # a -Wimplicit warning (the "compile with warnings as errors"
 559         # option requires GCC). If it is not usable, we fail and tell
 560         # the user that the pcap.h header needs to be updated.
 561         #
 562         # Ceteris paribus, this should only happen with Mac OS X 10.3[.x] which
 563         # can have an up-to-date pcap library without the corresponding pcap
 564         # header.
 565         #
 566         # However, it might also happen on some others OSes with some erroneous
 567         # system manipulations where multiple versions of libpcap might co-exist
 568         # e.g. hand made symbolic link from libpcap.so -> libpcap.so.0.8 but
 569         # having the pcap header version 0.7.
 570         #
 571         AC_MSG_CHECKING([whether pcap_breakloop is present])
 572         ac_CFLAGS_saved="$CFLAGS"
 573         AC_WIRESHARK_PCAP_BREAKLOOP_TRY_LINK
 574         if test "x$ws_breakloop_compiled" = "xyes"; then
 575           AC_MSG_RESULT(yes)
 576           AC_DEFINE(HAVE_PCAP_BREAKLOOP, 1, [Define if pcap_breakloop is known])
 577           if test "x$with_warnings_as_errors" = "xyes"; then
 578             AC_MSG_CHECKING([whether pcap_breakloop is usable])
 579             CFLAGS="$CFLAGS -Werror -Wimplicit"
 580             AC_WIRESHARK_PCAP_BREAKLOOP_TRY_LINK
 581             if test "x$ws_breakloop_compiled" = "xyes"; then
 582               AC_MSG_RESULT(yes)
 583             else
 584               AC_MSG_RESULT(no)
 585               AC_MSG_ERROR(
 586 [Your pcap library is more recent than your pcap header.
 587 As you are building with compiler warnings treated as errors, Wireshark
 588 won't be able to use functions not declared in that header.
 589 If you wish to build with compiler warnings treated as errors, You should
 590 install a newer version of the header file.])
 591             fi
 592             CFLAGS="$ac_CFLAGS_saved"
 593           fi
 594         else
 595           AC_MSG_RESULT(no)
 596         fi
 597
 598         #
 599         # Later versions of Mac OS X 10.3[.x] ship a pcap.h that
 600         # doesn't define pcap_if_t but ship an 0.8[.x] libpcap,
 601         # so the library has "pcap_findalldevs()", but pcap.h
 602         # doesn't define "pcap_if_t" so you can't actually *use*
 603         # "pcap_findalldevs()".
 604         #
 605         # That even appears to be true of systems shipped with
 606         # 10.3.4, so it doesn't appear only to be a case of
 607         # Software Update not updating header files.
 608         #
 609         # (You can work around this by installing the 0.8 header
 610         # files.)
 611         #
 612         AC_CACHE_CHECK([whether pcap_findalldevs is present and usable],
 613           [ac_cv_func_pcap_findalldevs],
 614           [
 615             AC_LINK_IFELSE(
 616               [
 617                 AC_LANG_SOURCE(
 618                   [[
 619                     #include <pcap.h>
 620                     main()
 621                     {
 622                       pcap_if_t *devpointer;
 623                       char errbuf[1];
 624
 625                       pcap_findalldevs(&devpointer, errbuf);
 626                     }
 627                   ]])
 628               ],
 629               [
 630                 ac_cv_func_pcap_findalldevs=yes
 631               ],
 632               [
 633                 ac_cv_func_pcap_findalldevs=no
 634               ])
 635           ])
 636         #
 637         # Don't check for other new routines that showed up after
 638         # "pcap_findalldevs()" if we don't have a usable
 639         # "pcap_findalldevs()", so we don't end up using them if the
 640         # "pcap.h" is crufty and old and doesn't declare them.
 641         #
 642         if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 643           AC_DEFINE(HAVE_PCAP_FINDALLDEVS, 1,
 644            [Define to 1 if you have the `pcap_findalldevs' function and a pcap.h that declares pcap_if_t.])
 645           AC_CHECK_FUNCS(pcap_datalink_val_to_name pcap_datalink_name_to_val)
 646           AC_CHECK_FUNCS(pcap_datalink_val_to_description)
 647           AC_CHECK_FUNCS(pcap_list_datalinks pcap_set_datalink pcap_lib_version)
 648           AC_CHECK_FUNCS(pcap_get_selectable_fd pcap_free_datalinks)
 649           AC_CHECK_FUNC(pcap_create,
 650           [
 651             AC_DEFINE(HAVE_PCAP_CREATE, 1,
 652              [Define to 1 if you have the `pcap_create' function.])
 653             AC_DEFINE(CAN_SET_CAPTURE_BUFFER_SIZE, 1,
 654              [Define to 1 if the capture buffer size can be set.])
 655           ])
 656           AC_CHECK_FUNCS(bpf_image pcap_set_tstamp_precision)
 657         fi
 658         LIBS="$ac_save_LIBS"
 659 ])
 660
 661 AC_DEFUN([AC_WIRESHARK_PCAP_REMOTE_CHECK],
 662 [
 663     ac_save_LIBS="$LIBS"
 664     LIBS="$PCAP_LIBS $SOCKET_LIBS $NSL_LIBS $LIBS"
 665     AC_DEFINE(HAVE_REMOTE, 1, [Define to 1 to enable remote
 666               capturing feature in WinPcap library])
 667     AC_CHECK_FUNCS(pcap_open)
 668     if test $ac_cv_func_pcap_open = "yes" ; then
 669         AC_DEFINE(HAVE_PCAP_REMOTE, 1,
 670             [Define to 1 if you have WinPcap remote capturing support and prefer to use these new API features.])
 671     fi
 672     AC_CHECK_FUNCS(pcap_setsampling)
 673     LIBS="$ac_save_LIBS"
 674 ])
 675
 676 #
 677 # AC_WIRESHARK_ZLIB_CHECK
 678 #
 679 AC_DEFUN([AC_WIRESHARK_ZLIB_CHECK],
 680 [
 681         if test "x$zlib_dir" != "x"
 682         then
 683           #
 684           # The user specified a directory in which zlib resides,
 685           # so add the "include" subdirectory of that directory to
 686           # the include file search path and the "lib" subdirectory
 687           # of that directory to the library search path.
 688           #
 689           # XXX - if there's also a zlib in a directory that's
 690           # already in CPPFLAGS or LDFLAGS, this won't make us find
 691           # the version in the specified directory, as the compiler
 692           # and/or linker will search that other directory before it
 693           # searches the specified directory.
 694           #
 695           wireshark_save_CPPFLAGS="$CPPFLAGS"
 696           CPPFLAGS="$CPPFLAGS -I$zlib_dir/include"
 697           wireshark_save_LIBS="$LIBS"
 698           AC_WIRESHARK_ADD_DASH_L(LIBS, $zlib_dir/lib)
 699         fi
 700
 701         #
 702         # Make sure we have "zlib.h".  If we don't, it means we probably
 703         # don't have zlib, so don't use it.
 704         #
 705         AC_CHECK_HEADER(zlib.h,,
 706           [
 707             if test "x$zlib_dir" != "x"
 708             then
 709               #
 710               # The user used "--with-zlib=" to specify a directory
 711               # containing zlib, but we didn't find the header file
 712               # there; that either means they didn't specify the
 713               # right directory or are confused about whether zlib
 714               # is, in fact, installed.  Report the error and give up.
 715               #
 716               AC_MSG_ERROR([zlib header not found in directory specified in --with-zlib])
 717             else
 718               if test "x$want_zlib" = "xyes"
 719               then
 720                 #
 721                 # The user tried to force us to use the library, but we
 722                 # couldn't find the header file; report an error.
 723                 #
 724                 AC_MSG_ERROR(Header file zlib.h not found.)
 725               else
 726                 #
 727                 # We couldn't find the header file; don't use the
 728                 # library, as it's probably not present.
 729                 #
 730                 want_zlib=no
 731               fi
 732             fi
 733           ])
 734
 735         if test "x$want_zlib" != "xno"
 736         then
 737                 #
 738                 # Well, we at least have the zlib header file.
 739                 # We link with zlib to support uncompression of
 740                 # gzipped network traffic, e.g. in an HTTP request
 741                 # or response body.
 742                 #
 743                 if test "x$zlib_dir" != "x"
 744                 then
 745                         #
 746                         # Put the "-L" flags for zlib at the beginning
 747                         # of LIBS.
 748                         #
 749                         LIBS=""
 750                         AC_WIRESHARK_ADD_DASH_L(LIBS, $zlib_dir/lib)
 751                         LIBS="$LIBS -lz $wireshark_save_LIBS"
 752                 else
 753                         LIBS="-lz $LIBS"
 754                 fi
 755                 AC_DEFINE(HAVE_LIBZ, 1, [Define to use libz library])
 756
 757                 #
 758                 # Check for "inflatePrime()" in zlib, which we need
 759                 # in order to read compressed capture files.
 760                 #
 761                 AC_CHECK_FUNCS(inflatePrime)
 762
 763                 if test "x$ac_cv_func_inflatePrime" = "xyes" ; then
 764                         #
 765                         # Now check for "inflatePrime()" in zlib when
 766                         # linking with the linker flags for GTK+
 767                         # applications; people often grab XFree86 source
 768                         # and build and install it on their systems,
 769                         # and they appear sometimes to misconfigure
 770                         # XFree86 so that, even on systems with zlib,
 771                         # it assumes there is no zlib, so the XFree86
 772                         # build process builds and installs its
 773                         # own zlib in the X11 library directory.
 774                         #
 775                         # The zlib in at least some versions of XFree86
 776                         # is an older version that may lack "inflatePrime()",
 777                         # and that's the zlib with which Wireshark gets
 778                         # linked, so the build of Wireshark fails.
 779                         #
 780                         AC_MSG_CHECKING([for inflatePrime missing when linking with X11])
 781                         AC_TRY_LINK_FUNC(inflatePrime, AC_MSG_RESULT(no),
 782                           [
 783                             AC_MSG_RESULT(yes)
 784                             AC_MSG_ERROR(old zlib found when linking with X11 - get rid of old zlib.)
 785                           ])
 786                 fi
 787         else
 788                 #
 789                 # Restore the versions of CPPFLAGS and LIBS before
 790                 # we added the "-with-zlib=" directory, as we didn't
 791                 # actually find zlib there.
 792                 #
 793                 CPPFLAGS="$wireshark_save_CPPFLAGS"
 794                 LIBS="$wireshark_save_LIBS"
 795                 want_zlib=no
 796         fi
 797 ])
 798
 799 #
 800 # AC_WIRESHARK_LIBLUA_CHECK
 801 #
 802 # Sets $have_lua to yes or no.
 803 # If it's yes, it also sets $LUA_CFLAGS and $LUA_LIBS.
 804 AC_DEFUN([AC_WIRESHARK_LIBLUA_CHECK],[
 805
 806         if test "x$want_lua_dir" = "x"
 807         then
 808                 # The user didn't tell us where to find Lua.  Let's go look for it.
 809
 810                 # First, try the standard (pkg-config) way.
 811                 PKG_CHECK_MODULES(LUA, lua, [have_lua=yes], [true])
 812
 813                 # Unfortunately Lua's pkg-config file isn't standardly named.
 814                 # Apparently Debian, in particular, allows installation of multiple
 815                 # versions of Lua at the same time (thus each version has its own
 816                 # package name).
 817                 for ver in 5.2 -5.2 5.1 -5.1 5.0 -5.0
 818                 do
 819                         if test "x$have_lua" = "xyes"
 820                         then
 821                                 break
 822                         fi
 823
 824                         PKG_CHECK_MODULES(LUA, lua$ver, [have_lua=yes], [true])
 825                 done
 826
 827         fi
 828
 829         if test "x$have_lua" != "xyes"
 830         then
 831                 # We don't have pkg-config or the user specified the path to
 832                 # Lua (in $want_lua_dir).
 833                 # Let's look for the header file.
 834
 835                 AC_MSG_CHECKING(for the location of lua.h)
 836                 if test "x$want_lua_dir" = "x"
 837                 then
 838                         # The user didn't tell us where to look so we'll look in some
 839                         # standard locations.
 840                         want_lua_dir="/usr /usr/local $prefix"
 841                 fi
 842                 for dir in $want_lua_dir
 843                 do
 844                         if test -r "$dir/include/lua.h"
 845                         then
 846                                 header_dir="$dir/include"
 847                                 lua_dir=$dir
 848                                 break
 849                         fi
 850
 851                         for ver in 5.2 52 5.1 51 5.0 50
 852                         do
 853                                 if test -r "$dir/include/lua$ver/lua.h"
 854                                 then
 855                                         header_dir="$dir/include/lua$ver"
 856                                         lua_dir=$dir
 857                                         break
 858                                 fi
 859                         done
 860                 done
 861
 862                 if test "x$header_dir" = "x"
 863                 then
 864                         have_lua=no
 865                         AC_MSG_RESULT(not found)
 866                 else
 867                         AC_MSG_RESULT($header_dir)
 868
 869                         AC_MSG_CHECKING(the Lua version)
 870                         lua_ver=`$AWK AS_ESCAPE('/LUA_VERSION_NUM/ { print $NF; }' $header_dir/lua.h | sed 's/0/./')`
 871                         AC_MSG_RESULT($lua_ver)
 872
 873                         wireshark_save_CPPFLAGS="$CPPFLAGS"
 874                         CPPFLAGS="$CPPFLAGS -I$header_dir"
 875                         AC_CHECK_HEADERS(lua.h lualib.h lauxlib.h, ,
 876                         [
 877                                 have_lua=no
 878                                 # Restore our CPPFLAGS
 879                                 CPPFLAGS="$wireshark_save_CPPFLAGS"
 880                                 break
 881                         ])
 882
 883                         if test "x$have_lua" = "x"
 884                         then
 885                                 # Restore our CPPFLAGS and set LUA_CFLAGS
 886                                 CPPFLAGS="$wireshark_save_CPPFLAGS"
 887                                 LUA_CFLAGS="-I$header_dir"
 888
 889                                 # We have the header files and they work.  Now let's check if we
 890                                 # have the library and it works.
 891                                 #
 892                                 # XXX - if there's also a liblua in a directory that's
 893                                 # already in CPPFLAGS or LDFLAGS, this won't make us find
 894                                 # the version in the specified directory, as the compiler
 895                                 # and/or linker will search that other directory before it
 896                                 # searches the specified directory.
 897                                 #
 898                                 # XXX - lib64?
 899                                 wireshark_save_LIBS="$LIBS"
 900                                 LIBS="$LIBS -L$lua_dir/lib"
 901                                 AC_SEARCH_LIBS(luaL_openlibs, [lua-${lua_ver} lua${lua_ver} lua],
 902                                 [
 903                                         LUA_LIBS="-L$lua_dir/lib $ac_cv_search_luaL_openlibs -lm"
 904                                         LIBS="$wireshark_save_LIBS"
 905                                         have_lua=yes
 906                                 ],[
 907                                         LIBS="$wireshark_save_LIBS"
 908                                         have_lua=no
 909                                 ], -lm)
 910                         fi
 911                 fi
 912         fi
 913
 914 ])
 915
 916 #
 917 # AC_WIRESHARK_LIBPORTAUDIO_CHECK
 918 #
 919 AC_DEFUN([AC_WIRESHARK_LIBPORTAUDIO_CHECK],[
 920
 921         if test "x$portaudio_dir" != "x"
 922         then
 923                 #
 924                 # The user specified a directory in which libportaudio
 925                 # resides, so add the "include" subdirectory of that directory to
 926                 # the include file search path and the "lib" subdirectory
 927                 # of that directory to the library search path.
 928                 #
 929                 # XXX - if there's also a libportaudio in a directory that's
 930                 # already in CPPFLAGS or LDFLAGS, this won't make us find
 931                 # the version in the specified directory, as the compiler
 932                 # and/or linker will search that other directory before it
 933                 # searches the specified directory.
 934                 #
 935                 wireshark_save_CPPFLAGS="$CPPFLAGS"
 936                 CPPFLAGS="$CPPFLAGS -I$portaudio_dir/include"
 937                 wireshark_save_LIBS="$LIBS"
 938                 LIBS="$LIBS -L$portaudio_dir/lib -lportaudio"
 939                 wireshark_save_LDFLAGS="$LDFLAGS"
 940                 LDFLAGS="$LDFLAGS -L$portaudio_dir/lib"
 941         else
 942                 #
 943                 # The user specified no directory in which libportaudio resides,
 944                 # so just add "-lportaudio" to the used libs.
 945                 #
 946                 wireshark_save_CPPFLAGS="$CPPFLAGS"
 947                 wireshark_save_LDFLAGS="$LDFLAGS"
 948                 wireshark_save_LIBS="$LIBS"
 949                 LIBS="$LIBS -lportaudio"
 950         fi
 951
 952         #
 953         # Make sure we have "portaudio.h".  If we don't, it means we probably
 954         # don't have libportaudio, so don't use it.
 955         #
 956         AC_CHECK_HEADERS(portaudio.h,,
 957         [
 958                 if test "x$portaudio_dir" != "x"
 959                 then
 960                         #
 961                         # The user used "--with-portaudio=" to specify a directory
 962                         # containing libportaudio, but we didn't find the header file
 963                         # there; that either means they didn't specify the
 964                         # right directory or are confused about whether libportaudio
 965                         # is, in fact, installed.  Report the error and give up.
 966                         #
 967                         AC_MSG_ERROR([libportaudio header not found in directory specified in --with-portaudio])
 968                 else
 969                         CPPFLAGS="$wireshark_save_CPPFLAGS"
 970                         LDFLAGS="$wireshark_save_LDFLAGS"
 971                         LIBS="$wireshark_save_LIBS"
 972                         PORTAUDIO_LIBS=""
 973                         if test "x$want_portaudio" = "xyes"
 974                         then
 975                                 #
 976                                 # The user tried to force us to use the library, but we
 977                                 # couldn't find the header file; report an error.
 978                                 #
 979                                 AC_MSG_ERROR(Header file portaudio.h not found.)
 980                         else
 981                                 #
 982                                 # We couldn't find the header file; don't use the
 983                                 # library, as it's probably not present.
 984                                 #
 985                                 want_portaudio=no
 986                         fi
 987                 fi
 988         ])
 989
 990         #
 991         # Check whether we have the right version of portaudio
 992         #
 993         if test "x$want_portaudio" != "xno"
 994         then
 995                 AC_CHECK_TYPE(PortAudioStream,
 996                 AC_DEFINE(PORTAUDIO_API_1, 1, [Define if we are using version of of the Portaudio library API]),
 997                 ,
 998                 [#include <portaudio.h>])
 999         fi
1000
1001         if test "x$want_portaudio" != "xno"
1002         then
1003                 #
1004                 # Well, we at least have the portaudio header file.
1005                 #
1006                 # let's check if the libs are there
1007                 #
1008
1009                 AC_CHECK_LIB(portaudio, Pa_Initialize,
1010                 [
1011                         if test "x$portaudio_dir" != "x"
1012                         then
1013                                 #
1014                                 # Put the "-I" and "-L" flags for portaudio
1015                                 # into PORTAUDIO_INCLUDES and PORTAUDIO_LIBS,
1016                                 # respectively.
1017                                 #
1018                                 PORTAUDIO_LIBS="-L$portaudio_dir/lib -lportaudio"
1019                                 PORTAUDIO_INCLUDES="-I$portaudio_dir/include"
1020                         else
1021                                 PORTAUDIO_LIBS="-lportaudio"
1022                                 PORTAUDIO_INCLUDES=""
1023                         fi
1024                         AC_DEFINE(HAVE_LIBPORTAUDIO, 1, [Define to use libportaudio library])
1025                         want_portaudio=yes
1026                 ],[
1027                         #
1028                         # Restore the versions of CPPFLAGS, LDFLAGS, and
1029                         # LIBS before we added the "--with-portaudio="
1030                         # directory, as we didn't actually find portaudio
1031                         # there.
1032                         #
1033                         CPPFLAGS="$wireshark_save_CPPFLAGS"
1034                         LDFLAGS="$wireshark_save_LDFLAGS"
1035                         LIBS="$wireshark_save_LIBS"
1036                         PORTAUDIO_LIBS=""
1037                         # User requested --with-portaudio but it isn't available
1038                         if test "x$want_portaudio" = "xyes"
1039                         then
1040                                 AC_MSG_ERROR(Linking with libportaudio failed.)
1041                         fi
1042                         want_portaudio=no
1043                 ])
1044
1045         CPPFLAGS="$wireshark_save_CPPFLAGS"
1046         LDFLAGS="$wireshark_save_LDFLAGS"
1047         LIBS="$wireshark_save_LIBS"
1048         AC_SUBST(PORTAUDIO_LIBS)
1049         AC_SUBST(PORTAUDIO_INCLUDES)
1050
1051         fi
1052 ])
1053
1054 #
1055 # AC_WIRESHARK_RPM_CHECK
1056 # Looks for the rpm program, and checks to see if we can redefine "_topdir".
1057 #
1058 AC_DEFUN([AC_WIRESHARK_RPM_CHECK],
1059 [
1060         AC_CHECK_PROG(ac_cv_wireshark_have_rpm, rpm, "yes", "no")
1061         if test "x$ac_cv_wireshark_have_rpm" = "xyes"; then
1062                 rpm --define '_topdir /tmp' > /dev/null 2>&1
1063                 AC_MSG_CHECKING(to see if we can redefine _topdir)
1064                 if test $? -eq 0 ; then
1065                         AC_MSG_RESULT(yes)
1066                         HAVE_RPM=yes
1067                 else
1068                         AC_MSG_RESULT(no.  You'll have to build packages manually.)
1069                         HAVE_RPM=no
1070                 fi
1071         fi
1072 ])
1073
1074 #
1075 # AC_WIRESHARK_GNU_SED_CHECK
1076 # Checks if GNU sed is the first sed in PATH.
1077 #
1078 AC_DEFUN([AC_WIRESHARK_GNU_SED_CHECK],
1079 [
1080         AC_MSG_CHECKING(for GNU sed as first sed in PATH)
1081         if  ( sh -c "sed --version" </dev/null 2> /dev/null | grep "GNU sed" 2>&1 > /dev/null ) ;  then
1082                 AC_MSG_RESULT(yes)
1083                 HAVE_GNU_SED=yes
1084         else
1085                 AC_MSG_RESULT(no)
1086                 HAVE_GNU_SED=no
1087         fi
1088 ])
1089
1090 #
1091 # AC_WIRESHARK_C_ARES_CHECK
1092 #
1093 AC_DEFUN([AC_WIRESHARK_C_ARES_CHECK],
1094 [
1095         want_c_ares=defaultyes
1096
1097         if test "x$want_c_ares" = "xdefaultyes"; then
1098                 want_c_ares=yes
1099                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1100                         withval=/usr/local
1101                         if test -d "$withval"; then
1102                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1103                         fi
1104                 fi
1105         fi
1106
1107         if test "x$want_c_ares" = "xyes"; then
1108                 AC_CHECK_LIB(cares, ares_init,
1109                   [
1110                     C_ARES_LIBS=-lcares
1111                 AC_DEFINE(HAVE_C_ARES, 1, [Define to use c-ares library])
1112                 have_good_c_ares=yes
1113                   ],, $SOCKET_LIBS $NSL_LIBS
1114                 )
1115         else
1116                 AC_MSG_RESULT(not required)
1117         fi
1118 ])
1119
1120
1121 #
1122 # AC_WIRESHARK_ADNS_CHECK
1123 #
1124 AC_DEFUN([AC_WIRESHARK_ADNS_CHECK],
1125 [
1126         want_adns=defaultyes
1127
1128         if test "x$want_adns" = "xdefaultyes"; then
1129                 want_adns=yes
1130                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1131                         withval=/usr/local
1132                         if test -d "$withval"; then
1133                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1134                         fi
1135                 fi
1136         fi
1137
1138         if test "x$want_adns" = "xyes"; then
1139                 AC_CHECK_LIB(adns, adns_init,
1140                   [
1141                     ADNS_LIBS=-ladns
1142                     AC_DEFINE(HAVE_GNU_ADNS, 1, [Define to use GNU ADNS library])
1143                     have_good_adns=yes
1144                   ],, $SOCKET_LIBS $NSL_LIBS
1145                 )
1146         else
1147                 AC_MSG_RESULT(not required)
1148         fi
1149 ])
1150
1151
1152 #
1153 # AC_WIRESHARK_LIBCAP_CHECK
1154 #
1155 AC_DEFUN([AC_WIRESHARK_LIBCAP_CHECK],
1156 [
1157         want_libcap=defaultyes
1158
1159         if test "x$want_libcap" = "xdefaultyes"; then
1160                 want_libcap=yes
1161                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1162                         withval=/usr/local
1163                         if test -d "$withval"; then
1164                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1165                         fi
1166                 fi
1167         fi
1168
1169         if test "x$want_libcap" = "xyes"; then
1170                 AC_CHECK_LIB(cap, cap_set_flag,
1171                   [
1172                     LIBCAP_LIBS=-lcap
1173                     AC_DEFINE(HAVE_LIBCAP, 1, [Define to use the libcap library])
1174                     have_good_libcap=yes
1175                   ],,
1176                 )
1177         else
1178                 AC_MSG_RESULT(not required)
1179         fi
1180 ])
1181
1182
1183 #
1184 # AC_WIRESHARK_KRB5_CHECK
1185 #
1186 AC_DEFUN([AC_WIRESHARK_KRB5_CHECK],
1187 [
1188         wireshark_save_CPPFLAGS="$CPPFLAGS"
1189         if test "x$krb5_dir" != "x"
1190         then
1191           #
1192           # The user specified a directory in which kerberos resides,
1193           # so add the "include" subdirectory of that directory to
1194           # the include file search path and the "lib" subdirectory
1195           # of that directory to the library search path.
1196           #
1197           # XXX - if there's also a kerberos in a directory that's
1198           # already in CPPFLAGS or LDFLAGS, this won't make us find
1199           # the version in the specified directory, as the compiler
1200           # and/or linker will search that other directory before it
1201           # searches the specified directory.
1202           #
1203           CPPFLAGS="$CPPFLAGS -I$krb5_dir/include"
1204           ac_heimdal_version=`grep heimdal $krb5_dir/include/krb5.h | head -n 1 | sed 's/^.*heimdal.*$/HEIMDAL/'`
1205           # MIT Kerberos moved krb5.h to krb5/krb5.h starting with release 1.5
1206           ac_mit_version_olddir=`grep 'Massachusetts' $krb5_dir/include/krb5.h | head -n 1 | sed 's/^.*Massachusetts.*$/MIT/'`
1207           ac_mit_version_newdir=`grep 'Massachusetts' $krb5_dir/include/krb5/krb5.h | head -n 1 | sed 's/^.*Massachusetts.*$/MIT/'`
1208           ac_krb5_version="$ac_heimdal_version$ac_mit_version_olddir$ac_mit_version_newdir"
1209           if test "x$ac_krb5_version" = "xHEIMDAL"
1210           then
1211               KRB5_LIBS="-L$krb5_dir/lib -lkrb5 -lasn1 $SSL_LIBS -lroken -lcrypt"
1212           else
1213               KRB5_LIBS="-L$krb5_dir/lib -lkrb5 -lk5crypto -lcom_err"
1214           fi
1215           if test "x$ac_krb5_version" = "xMIT"
1216           then
1217             AC_DEFINE(HAVE_MIT_KERBEROS, 1, [Define to use MIT kerberos])
1218           fi
1219         else
1220           AC_PATH_PROG(KRB5_CONFIG, krb5-config)
1221           if test -x "$KRB5_CONFIG"
1222           then
1223             KRB5_FLAGS=`"$KRB5_CONFIG" --cflags`
1224             KRB5_LIBS=`"$KRB5_CONFIG" --libs`
1225             CPPFLAGS="$CPPFLAGS $KRB5_FLAGS"
1226             #
1227             # If -lcrypto is in KRB5_FLAGS, we require it to build
1228             # with Heimdal/MIT.  We don't want to built with it by
1229             # default, due to annoying license incompatibilities
1230             # between the OpenSSL license and the GPL, so:
1231             #
1232             #   if SSL_LIBS is set to a non-empty string, we
1233             #   remove -lcrypto from KRB5_LIBS and replace
1234             #   it with SSL_LIBS;
1235             #
1236             #   if SSL_LIBS is not set to a non-empty string
1237             #   we fail with an appropriate error message.
1238             #
1239             case "$KRB5_LIBS" in
1240             *-lcrypto*)
1241                 if test ! -z "$SSL_LIBS"
1242                 then
1243                     KRB5_LIBS=`echo $KRB5_LIBS | sed 's/-lcrypto//'`
1244                     KRB5_LIBS="$KRB5_LIBS $SSL_LIBS"
1245                 else
1246                     AC_MSG_ERROR([Kerberos library requires -lcrypto, so you must specify --with-ssl])
1247                 fi
1248                 ;;
1249             esac
1250             ac_krb5_version=`"$KRB5_CONFIG" --version | head -n 1 | sed -e 's/^.*heimdal.*$/HEIMDAL/' -e 's/^Kerberos .*$/MIT/' -e 's/^Solaris Kerberos .*$/MIT/'`
1251           fi
1252         fi
1253
1254         #
1255         # Make sure we have "krb5.h".  If we don't, it means we probably
1256         # don't have kerberos, so don't use it.
1257         #
1258         AC_CHECK_HEADER(krb5.h,,
1259           [
1260             if test "x$krb5_dir" != "x"
1261             then
1262               #
1263               # The user used "--with-krb5=" to specify a directory
1264               # containing kerberos, but we didn't find the header file
1265               # there; that either means they didn't specify the
1266               # right directory or are confused about whether kerberos
1267               # is, in fact, installed.  Report the error and give up.
1268               #
1269               AC_MSG_ERROR([kerberos header not found in directory specified in --with-krb5])
1270             else
1271               if test "x$want_krb5" = "xyes"
1272               then
1273                 #
1274                 # The user tried to force us to use the library, but we
1275                 # couldn't find the header file; report an error.
1276                 #
1277                 AC_MSG_ERROR(Header file krb5.h not found.)
1278               else
1279                 #
1280                 # We couldn't find the header file; don't use the
1281                 # library, as it's probably not present.
1282                 #
1283                 want_krb5=no
1284                 AC_MSG_RESULT(No Heimdal or MIT header found - disabling dissection for some kerberos data in packet decoding)
1285               fi
1286             fi
1287           ])
1288
1289         if test "x$want_krb5" != "xno"
1290         then
1291             #
1292             # Well, we at least have the krb5 header file.
1293             # Check whether this is Heimdal or MIT.
1294             #
1295             AC_MSG_CHECKING(whether the Kerberos library is Heimdal or MIT)
1296             if test "x$ac_krb5_version" = "xHEIMDAL" -o "x$ac_krb5_version" = "xMIT"
1297             then
1298                 #
1299                 # Yes.
1300                 # Check whether we have krb5_kt_resolve - and whether
1301                 # we need to link with -lresolv when linking with
1302                 # the Kerberos library.
1303                 #
1304                 AC_MSG_RESULT($ac_krb5_version)
1305                 wireshark_save_LIBS="$LIBS"
1306                 found_krb5_kt_resolve=no
1307                 for extras in "" "-lresolv"
1308                 do
1309                     LIBS="$KRB5_LIBS $extras"
1310                     if test -z "$extras"
1311                     then
1312                         AC_MSG_CHECKING([whether $ac_krb5_version includes krb5_kt_resolve])
1313                     else
1314                         AC_MSG_CHECKING([whether $ac_krb5_version includes krb5_kt_resolve (linking with $extras)])
1315                     fi
1316                     AC_TRY_LINK(
1317                         [
1318                         ],
1319                         [
1320                             krb5_kt_resolve();
1321                         ],
1322                         [
1323                             #
1324                             # We found "krb5_kt_resolve()", and required
1325                             # the libraries in extras as well.
1326                             #
1327                             AC_MSG_RESULT(yes)
1328                             KRB5_LIBS="$LIBS"
1329                             AC_DEFINE(HAVE_KERBEROS, 1, [Define to use kerberos])
1330                             if test "x$ac_krb5_version" = "xHEIMDAL"
1331                             then
1332                                 AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1, [Define to use heimdal kerberos])
1333                             elif test "x$ac_krb5_version" = "xMIT"
1334                             then
1335                                 AC_DEFINE(HAVE_MIT_KERBEROS, 1, [Define to use MIT kerberos])
1336                             fi
1337                             found_krb5_kt_resolve=yes
1338                             break
1339                         ],
1340                         [
1341                             AC_MSG_RESULT(no)
1342                         ])
1343                 done
1344                 if test "$found_krb5_kt_resolve" = no
1345                 then
1346                     #
1347                     # We didn't find "krb5_kt_resolve()" in the
1348                     # Kerberos library, even when we tried linking
1349                     # with -lresolv; we can't link with kerberos.
1350                     #
1351                     if test "x$want_krb5" = "xyes"
1352                     then
1353                         #
1354                         # The user tried to force us to use the library,
1355                         # but we can't do so; report an error.
1356                         #
1357                         AC_MSG_ERROR(Usable $ac_krb5_version not found)
1358                     else
1359                         #
1360                         # Restore the versions of CPPFLAGS from before we
1361                         # added the flags for Kerberos.
1362                         #
1363                         AC_MSG_RESULT(Usable $ac_krb5_version not found - disabling dissection for some kerberos data in packet decoding)
1364                         CPPFLAGS="$wireshark_save_CPPFLAGS"
1365                         KRB5_LIBS=""
1366                         want_krb5=no
1367                     fi
1368                 else
1369                     #
1370                     # We can link with Kerberos; see whether krb5.h
1371                     # defines KEYTYPE_ARCFOUR_56 (where "defines" means
1372                     # "as a #define or as an enum member).
1373                     #
1374                     AC_MSG_CHECKING([whether krb5.h defines KEYTYPE_ARCFOUR_56])
1375                     AC_COMPILE_IFELSE(
1376                       [
1377                         AC_LANG_SOURCE(
1378                           [[
1379                             #include <krb5.h>
1380                             #include <stdio.h>
1381
1382                             main()
1383                             {
1384                               printf("%u\n", KEYTYPE_ARCFOUR_56);
1385                             }
1386                           ]])
1387                       ],
1388                       [
1389                         AC_MSG_RESULT(yes)
1390                         AC_DEFINE(HAVE_KEYTYPE_ARCFOUR_56, 1, [Define if krb5.h defines KEYTYPE_ARCFOUR_56])
1391                       ],
1392                       [
1393                         AC_MSG_RESULT(no)
1394                       ])
1395                 fi
1396                 LIBS="$wireshark_save_LIBS"
1397             else
1398                 #
1399                 # It's not Heimdal or MIT.
1400                 #
1401                 AC_MSG_RESULT(no)
1402                 if test "x$want_krb5" = "xyes"
1403                 then
1404                     #
1405                     # The user tried to force us to use the library,
1406                     # but we can't do so; report an error.
1407                     #
1408                     AC_MSG_ERROR(Kerberos not found)
1409                 else
1410                     #
1411                     # Restore the versions of CPPFLAGS from before we
1412                     # added the flags for Kerberos.
1413                     #
1414                     AC_MSG_RESULT(Kerberos not found - disabling dissection for some kerberos data in packet decoding)
1415                     CPPFLAGS="$wireshark_save_CPPFLAGS"
1416                     KRB5_LIBS=""
1417                     want_krb5=no
1418                 fi
1419             fi
1420         else
1421             #
1422             # The user asked us not to use Kerberos, or they didn't
1423             # say whether they wanted us to use it but we found
1424             # that we couldn't.
1425             #
1426             # Restore the versions of CPPFLAGS from before we added
1427             # the flags for Kerberos.
1428             #
1429             CPPFLAGS="$wireshark_save_CPPFLAGS"
1430             KRB5_LIBS=""
1431             want_krb5=no
1432         fi
1433         AC_SUBST(KRB5_LIBS)
1434 ])
1435
1436 #
1437 # AC_WIRESHARK_GEOIP_CHECK
1438 #
1439 AC_DEFUN([AC_WIRESHARK_GEOIP_CHECK],
1440 [
1441         want_geoip=defaultyes
1442
1443         if test "x$want_geoip" = "xdefaultyes"; then
1444                 want_geoip=yes
1445                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1446                         withval=/usr/local
1447                         if test -d "$withval"; then
1448                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1449                         fi
1450                 fi
1451         fi
1452
1453         if test "x$want_geoip" = "xyes"; then
1454                 AC_CHECK_LIB(GeoIP, GeoIP_new,
1455                   [
1456                     GEOIP_LIBS=-lGeoIP
1457                 AC_DEFINE(HAVE_GEOIP, 1, [Define to use GeoIP library])
1458                 have_good_geoip=yes
1459                   ],,
1460                 )
1461                 if test "x$have_good_geoip" = "xyes"; then
1462                         AC_CHECK_LIB(GeoIP, GeoIP_country_name_by_ipnum_v6,
1463                           [
1464                                 AC_DEFINE(HAVE_GEOIP_V6, 1, [Define if GeoIP supports IPv6 (GeoIP 1.4.5 and later)])
1465                           ],,
1466                         )
1467                 fi
1468         else
1469                 AC_MSG_RESULT(not required)
1470         fi
1471 ])
1472
1473 #AC_WIRESHARK_LDFLAGS_CHECK
1474 #
1475 # $1 : ldflag(s) to test
1476 #
1477 # We attempt to compile and link a test program with the specified linker
1478 # flag. The defined flag is added to LDFLAGS only if the link succeeds.
1479 #
1480 AC_DEFUN([AC_WIRESHARK_LDFLAGS_CHECK],
1481 [LD_OPTION="$1"
1482 AC_MSG_CHECKING(whether we can add $LD_OPTION to LDFLAGS)
1483 LDFLAGS_saved="$LDFLAGS"
1484 LDFLAGS="$LDFLAGS $LD_OPTION"
1485 AC_LINK_IFELSE(
1486   [
1487     AC_LANG_SOURCE([[main() { return; }]])
1488   ],
1489   [
1490     AC_MSG_RESULT(yes)
1491   ],
1492   [
1493     AC_MSG_RESULT(no)
1494     LDFLAGS="$LDFLAGS_saved"
1495   ])
1496 ])
1497
1498 dnl
1499 dnl Check whether, if you pass an unknown warning option to the
1500 dnl compiler, it fails or just prints a warning message and succeeds.
1501 dnl Set ac_wireshark_unknown_warning_option_error to the appropriate flag
1502 dnl to force an error if it would otherwise just print a warning message
1503 dnl and succeed.
1504 dnl
1505 AC_DEFUN([AC_WIRESHARK_CHECK_UNKNOWN_WARNING_OPTION_ERROR],
1506     [
1507         AC_MSG_CHECKING([whether the compiler fails when given an unknown warning option])
1508         save_CFLAGS="$CFLAGS"
1509         CFLAGS="$CFLAGS -Wxyzzy-this-will-never-succeed-xyzzy"
1510         AC_TRY_COMPILE(
1511             [],
1512             [return 0],
1513             [
1514                 AC_MSG_RESULT([no, adding -Werror=unknown-warning-option])
1515                 #
1516                 # We're assuming this is clang, where
1517                 # -Werror=unknown-warning-option is the appropriate
1518                 # option to force the compiler to fail.
1519                 #
1520                 ac_wireshark_unknown_warning_option_error="-Werror=unknown-warning-option"
1521             ],
1522             [
1523                 AC_MSG_RESULT([yes])
1524             ])
1525         CFLAGS="$save_CFLAGS"
1526     ])
1527
1528 dnl
1529 dnl Check whether, if you pass a valid-for-C-but-not-C++ option to the
1530 dnl compiler, it fails or just prints a warning message and succeeds.
1531 dnl Set ac_wireshark_non_cxx_warning_option_error to the appropriate flag
1532 dnl to force an error if it would otherwise just print a warning message
1533 dnl and succeed.
1534 dnl
1535 AC_DEFUN([AC_WIRESHARK_CHECK_NON_CXX_WARNING_OPTION_ERROR],
1536     [
1537         AC_MSG_CHECKING([whether the compiler fails when given an warning option not supported for C++])
1538         #
1539         # Some C+ compilers warn about -Wmissing-prototypes, and some warn
1540         # about -Wmissing-declarations.  Check both.
1541         #
1542         AC_LANG_PUSH(C++)
1543         save_CXXFLAGS="$CXXFLAGS"
1544         for flag in -Wmissing-prototypes -Wmissing-declarations; do
1545             CXXFLAGS="$save_CXXFLAGS $flag"
1546             AC_TRY_COMPILE(
1547                 [],
1548                 [return 0],
1549                 [
1550                     #
1551                     # We're assuming this is g++, where -Werror is the
1552                     # appropriate option to force the compiler to fail.
1553                     # Check whether it fails with -Werror.
1554                     #
1555                     # NOTE: it's important to put -Werror *before*
1556                     # the flag, otherwise, when it sees the flag,
1557                     # it doesn't yet know that warnings should be
1558                     # treated as errors, and doesn't treat the
1559                     # "that's C-only" warning as an error.
1560                     #
1561                     CXXFLAGS="$save_CXXFLAGS -Werror $flag"
1562                     AC_TRY_COMPILE(
1563                         [],
1564                         [return 0],
1565                         [
1566                             #
1567                             # No, so this option is actually OK
1568                             # with our C++ compiler.
1569                             #
1570                             # (We need an empty command here to
1571                             # prevent some versions of autoconf
1572                             # from generating a script with an
1573                             # empty "then" clause for an if statement.)
1574                             #
1575                             :
1576                         ],
1577                         [
1578                             #
1579                             # Yes, so we need -Werror for the tests.
1580                             #
1581                             ac_wireshark_non_cxx_warning_option_error="-Werror"
1582                             break
1583                         ])
1584                 ])
1585         done
1586         CXXFLAGS="$save_CXXFLAGS"
1587         AC_LANG_POP
1588         if test x$ac_wireshark_non_cxx_warning_option_error = x; then
1589             AC_MSG_RESULT([yes])
1590         else
1591             AC_MSG_RESULT([no, adding -Werror])
1592         fi
1593     ])
1594
1595 #
1596 # AC_WIRESHARK_COMPILER_FLAGS_CHECK
1597 #
1598 # $1 : flags to test
1599 # $2 : if supplied, C for C-only flags, CXX for C++-only flags
1600 # $3 : if supplied, a program to try to compile with the flag
1601 #      and, if the compile fails when -Werror is turned on,
1602 #      we don't add the flag - used for warning flags that
1603 #      issue incorrect or non-useful warnings with some
1604 #      compiler versions
1605 # $4 : must be supplied if $3 is supplied - a message describing
1606 #      for what the test program is testing
1607 #
1608 # The macro first determines if the compiler supports GCC-style flags.
1609 # Then it attempts to compile with the defined cflags.  The defined
1610 # flags are added to CFLAGS only if the compilation succeeds.
1611 #
1612 # We do this because not all such options are necessarily supported by
1613 # the version of the particular compiler we're using.
1614 #
1615 AC_DEFUN([AC_WIRESHARK_COMPILER_FLAGS_CHECK],
1616 [GCC_OPTION="$1"
1617 can_add_to_cflags=""
1618 can_add_to_cxxflags=""
1619 if test "x$ac_supports_gcc_flags" = "xyes" ; then
1620   if test "$2" != CXX ; then
1621     #
1622     # Not C++-only; if this can be added to the C compiler flags, add them.
1623     #
1624     # If the option begins with "-W", add
1625     # $ac_wireshark_unknown_warning_option_error to make sure that
1626     # we'll get an error if it's an unknown warning option; not all
1627     # compilers treat unknown warning options as errors (I'm looking at
1628     # you, clang).
1629     #
1630     # If the option begins with "-f" or "-m", add -Werror to make sure
1631     # that we'll get an error if we get "argument unused during compilation"
1632     # warnings, as those will either cause a failure for files compiled
1633     # with -Werror or annoying noise for files compiled without it.
1634     # (Yeah, you, clang.)
1635     #
1636     AC_MSG_CHECKING(whether we can add $GCC_OPTION to CFLAGS)
1637     CFLAGS_saved="$CFLAGS"
1638     if expr "x$GCC_OPTION" : "x-W.*" >/dev/null
1639     then
1640       CFLAGS="$CFLAGS $ac_wireshark_unknown_warning_option_error $GCC_OPTION"
1641     elif expr "x$GCC_OPTION" : "x-f.*" >/dev/null
1642     then
1643       CFLAGS="$CFLAGS -Werror $GCC_OPTION"
1644     elif expr "x$GCC_OPTION" : "x-m.*" >/dev/null
1645     then
1646       CFLAGS="$CFLAGS -Werror $GCC_OPTION"
1647     else
1648       CFLAGS="$CFLAGS $GCC_OPTION"
1649     fi
1650     AC_COMPILE_IFELSE(
1651       [
1652         AC_LANG_SOURCE([[int foo;]])
1653       ],
1654       [
1655         AC_MSG_RESULT(yes)
1656         can_add_to_cflags=yes
1657         #
1658         # OK, do we have a test program?  If so, check
1659         # whether it fails with this option and -Werror,
1660         # and, if so, don't include it.
1661         #
1662         # We test arg 4 here because arg 3 is a program which
1663         # could contain quotes (breaking the comparison).
1664         #
1665         if test "x$4" != "x" ; then
1666           CFLAGS="$CFLAGS -Werror"
1667           AC_MSG_CHECKING(whether $GCC_OPTION $4)
1668           AC_COMPILE_IFELSE(
1669             [AC_LANG_SOURCE($3)],
1670             [
1671               AC_MSG_RESULT(no)
1672               #
1673               # Remove "force an error for a warning" options, if we
1674               # added them, by setting CFLAGS to the saved value plus
1675               # just the new option.
1676               #
1677               CFLAGS="$CFLAGS_saved $GCC_OPTION"
1678               if test "$CC" = "$CC_FOR_BUILD"; then
1679                 #
1680                 # We're building the build tools with the same compiler
1681                 # with which we're building Wireshark, so add the flags
1682                 # to the flags for that compiler as well.
1683                 #
1684                 CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD $GCC_OPTION"
1685               fi
1686             ],
1687             [
1688               AC_MSG_RESULT(yes)
1689               CFLAGS="$CFLAGS_saved"
1690             ])
1691         else
1692           #
1693           # Remove "force an error for a warning" options, if we
1694           # added them, by setting CFLAGS to the saved value plus
1695           # just the new option.
1696           #
1697           CFLAGS="$CFLAGS_saved $GCC_OPTION"
1698           if test "$CC" = "$CC_FOR_BUILD"; then
1699             #
1700             # We're building the build tools with the same compiler
1701             # with which we're building Wireshark, so add the flags
1702             # to the flags for that compiler as well.
1703             #
1704             CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD $GCC_OPTION"
1705           fi
1706         fi
1707       ],
1708       [
1709         AC_MSG_RESULT(no)
1710         can_add_to_cflags=no
1711         CFLAGS="$CFLAGS_saved"
1712       ])
1713   fi
1714   if test "$2" != C ; then
1715     #
1716     # Not C-only; if this can be added to the C++ compiler flags, add them.
1717     #
1718     # If the option begins with "-W", add
1719     # $ac_wireshark_unknown_warning_option_error, as per the above, and
1720     # also add $ac_wireshark_non_cxx_warning_option_error, because at
1721     # lease some versions of g++ whine about -Wmissing-prototypes, the
1722     # fact that at least one of those versions refuses to warn about
1723     # function declarations without an earlier declaration nonwithstanding;
1724     # perhaps there's a reason not to warn about that with C++ even though
1725     # warning about it can be a Good Idea with C, but it's not obvious to
1726     # me).
1727     #
1728     # If the option begins with "-f" or "-m", add -Werror to make sure
1729     # that we'll get an error if we get "argument unused during compilation"
1730     # warnings, as those will either cause a failure for files compiled
1731     # with -Werror or annoying noise for files compiled without it.
1732     # (Yeah, you, clang++.)
1733     #
1734     AC_MSG_CHECKING(whether we can add $GCC_OPTION to CXXFLAGS)
1735     CXXFLAGS_saved="$CXXFLAGS"
1736     if expr "x$GCC_OPTION" : "x-W.*" >/dev/null
1737     then
1738       CXXFLAGS="$CXXFLAGS $ac_wireshark_unknown_warning_option_error $ac_wireshark_non_cxx_warning_option_error $GCC_OPTION"
1739     elif expr "x$GCC_OPTION" : "x-f.*" >/dev/null
1740     then
1741       CXXFLAGS="$CXXFLAGS -Werror $GCC_OPTION"
1742     elif expr "x$GCC_OPTION" : "x-m.*" >/dev/null
1743     then
1744       CXXFLAGS="$CXXFLAGS -Werror $GCC_OPTION"
1745     else
1746       CXXFLAGS="$CXXFLAGS $GCC_OPTION"
1747     fi
1748     AC_LANG_PUSH([C++])
1749     AC_COMPILE_IFELSE(
1750       [
1751         AC_LANG_SOURCE([[int foo;]])
1752       ],
1753       [
1754         AC_MSG_RESULT(yes)
1755         can_add_to_cxxflags=yes
1756         #
1757         # OK, do we have a test program?  If so, check
1758         # whether it fails with this option and -Werror,
1759         # and, if so, don't include it.
1760         #
1761         # We test arg 4 here because arg 3 is a program which
1762         # could contain quotes (breaking the comparison).
1763         #
1764         if test "x$4" != "x" ; then
1765           CXXFLAGS="$CXXFLAGS -Werror"
1766           AC_MSG_CHECKING(whether $GCC_OPTION $4)
1767           AC_COMPILE_IFELSE(
1768             [AC_LANG_SOURCE($3)],
1769             [
1770               AC_MSG_RESULT(no)
1771               #
1772               # Remove "force an error for a warning" options, if we
1773               # added them, by setting CXXFLAGS to the saved value plus
1774               # just the new option.
1775               #
1776               CXXFLAGS="$CXXFLAGS_saved $GCC_OPTION"
1777             ],
1778             [
1779               AC_MSG_RESULT(yes)
1780               CXXFLAGS="$CXXFLAGS_saved"
1781             ])
1782         else
1783           #
1784           # Remove "force an error for a warning" options, if we
1785           # added them, by setting CXXFLAGS to the saved value plus
1786           # just the new option.
1787           #
1788           CXXFLAGS="$CXXFLAGS_saved $GCC_OPTION"
1789         fi
1790       ],
1791       [
1792         AC_MSG_RESULT(no)
1793         can_add_to_cxxflags=no
1794         CXXFLAGS="$CXXFLAGS_saved"
1795       ])
1796     AC_LANG_POP([C++])
1797   fi
1798   if test "(" "$can_add_to_cflags" = "yes" -a "$can_add_to_cxxflags" = "no" ")" \
1799        -o "(" "$can_add_to_cflags" = "no" -a "$can_add_to_cxxflags" = "yes" ")"
1800   then
1801     #
1802     # Confusingly, some C++ compilers like -Wmissing-prototypes but
1803     # don't like -Wmissing-declarations and others like
1804     # -Wmissing-declarations but don't like -Wmissing-prototypes,
1805     # the fact that the corresponding C compiler likes both.  Don't
1806     # warn about them.
1807     #
1808     if test "(" x$GCC_OPTION != x-Wmissing-prototypes ")" \
1809          -a "(" x$GCC_OPTION != x-Wmissing-declarations ")"
1810     then
1811        AC_MSG_WARN([$CC and $CXX appear to be a mismatched pair])
1812     fi
1813   fi
1814 fi
1815 ])
1816
1817 # AC_WIRESHARK_GCC_FORTIFY_SOURCE_CHECK
1818 #
1819 # Checks if '-D_FORTIFY_SOURCE=...' is OK to use in CPPFLAGS.
1820 #  Use '-D_FORTIFY_SOURCE=...' in CPPFLAGS only if the GCC 'optimization level' is > 0.
1821 #  The use of '-D_FORTIFY_SOURCE=...' will cause a warning with at least some versions
1822 #    of glibc if the  GCC "optimization level" is 0 (default or -O or -O0)
1823 #    when using GCC to compile a source file which references the macro definition.
1824 #
1825 # See: http://gcc.gnu.org/ml/gcc-patches/2004-09/msg02055.html
1826 # See: http://sourceware.org/bugzilla/show_bug.cgi?id=13979
1827 #
1828 #   We'll use '-D_FORTIFY_SOURCE=2' only if there's no warning; Among other things this means
1829 #    that the  use of '-D_FORTIFY_SOURCE=2' with '-Werror' and '-O0' won't cause
1830 #    the compiler to stop on error.
1831 #   Assumption: CFLAGS already contains whatever optimization option including none) is
1832 #    to be used.
1833 #
1834
1835 AC_DEFUN([AC_WIRESHARK_GCC_FORTIFY_SOURCE_CHECK],
1836 [
1837 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
1838   AC_MSG_CHECKING([whether -D_FORTIFY_SOURCE=... can be used (without generating a warning)])
1839   CFLAGS_saved="$CFLAGS"
1840   CPPFLAGS_saved="$CPPFLAGS"
1841   CFLAGS="$CFLAGS -Werror"
1842   CPPFLAGS="$CPPFLAGS -D_FORTIFY_SOURCE=2"
1843   AC_COMPILE_IFELSE([
1844     AC_LANG_SOURCE([[
1845                   #include <stdio.h>
1846                       int foo;
1847                   ]])],
1848                   [
1849                     AC_MSG_RESULT(yes)
1850                     #
1851                     # (CPPFLAGS contains _D_FORTIFY_SOURCE=2)
1852                     #
1853                   ],
1854                   [
1855                     AC_MSG_RESULT(no)
1856                     # Remove -D_FORTIFY_SOURCE=2
1857                     CPPFLAGS="$CPPFLAGS_saved"
1858                   ])
1859   CFLAGS="$CFLAGS_saved"
1860 fi
1861 ])
1862
1863 #
1864 # AC_WIRESHARK_OSX_INTEGRATION_CHECK
1865 #
1866 # Checks for the presence of OS X integration functions in the GTK+ framework
1867 # or as a separate library.
1868 #
1869 # GTK+ for MAC OS X now lives on www.gtk.org at:
1870 #
1871 #   http://www.gtk.org/download/macos.php
1872 #
1873 # Details on building with GTK-OSX are available at:
1874 #
1875 #   http://live.gnome.org/GTK%2B/OSX/Building
1876 #
1877 # The GTK-OSX library has been renamed to gtkmacintegration.
1878 # It was previously named igemacintegration.
1879 #
1880 # http://live.gnome.org/GTK%2B/OSX/Integration
1881 #    for the old Carbon-based integration functions
1882 #
1883 AC_DEFUN([AC_WIRESHARK_OSX_INTEGRATION_CHECK],
1884 [
1885         ac_save_CFLAGS="$CFLAGS"
1886         ac_save_LIBS="$LIBS"
1887         CFLAGS="$CFLAGS $GTK_CFLAGS"
1888         LIBS="$GTK_LIBS $LIBS"
1889
1890         #
1891         # Check for the new integration functions in a -lgtkmacintegration
1892         # library.
1893         #
1894         AC_CHECK_LIB(gtkmacintegration, gtkosx_application_set_menu_bar,
1895         [
1896                 AC_DEFINE(HAVE_GTKOSXAPPLICATION, 1,
1897                         [Define to 1 if -lgtkmacintegration includes the GtkOSXApplication Integration functions.])
1898                 have_ige_mac=yes
1899                 # We don't want gtk stuff in LIBS (which is reset below) so
1900                 # manually set GTK_LIBS (which is more appropriate)
1901                 GTK_LIBS="$GTK_LIBS -lgtkmacintegration"
1902         ])
1903
1904         if test x$have_ige_mac = x
1905         then
1906                 #
1907                 # Not found - check for the old integration functions in
1908                 # the Gtk framework.
1909                 #
1910                 AC_CHECK_LIB(Gtk, gtk_mac_menu_set_menu_bar,
1911                 [
1912                         AC_DEFINE(HAVE_IGE_MAC_INTEGRATION, 1,
1913                                 [Define to 1 if the the Gtk+ framework or a separate library includes the Imendio IGE Mac OS X Integration functions.])
1914                         have_ige_mac=yes
1915                         # We don't want gtk stuff in LIBS (which is reset below) so
1916                         # manually set GTK_LIBS (which is more appropriate)
1917                         GTK_LIBS="$GTK_LIBS -lGtk"
1918                 ])
1919         fi
1920
1921         if test x$have_ige_mac = x
1922         then
1923                 #
1924                 # Not found - check for the old integration functions in
1925                 # a -lgtkmacintegration library.
1926                 #
1927                 AC_CHECK_LIB(gtkmacintegration, gtk_mac_menu_set_menu_bar,
1928                 [
1929                         AC_DEFINE(HAVE_IGE_MAC_INTEGRATION, 1,
1930                                 [Define to 1 if the the Gtk+ framework or a separate library includes the Imendio IGE Mac OS X Integration functions.])
1931                         have_ige_mac=yes
1932                         # We don't want gtk stuff in LIBS (which is reset below) so
1933                         # manually set GTK_LIBS (which is more appropriate)
1934                         GTK_LIBS="$GTK_LIBS -lgtkmacintegration"
1935                 ])
1936         fi
1937         CFLAGS="$ac_save_CFLAGS"
1938         LIBS="$ac_save_LIBS"
1939 ])
1940
1941 # Based on AM_PATH_GTK in gtk-2.0.m4.
1942
1943 dnl AC_WIRESHARK_QT_MODULE_CHECK([MODULE, MINIMUM-VERSION, [ACTION-IF-FOUND,
1944 dnl     [ACTION-IF-NOT-FOUND]]])
1945 dnl Test for a particular Qt module and add the flags and libraries
1946 dnl for it to Qt_CFLAGS and Qt_LIBS.
1947 dnl
1948 AC_DEFUN([AC_WIRESHARK_QT_MODULE_CHECK],
1949 [
1950         #
1951         # Version of the module we're checking for.
1952         # Default to 4.0.0.
1953         #
1954         min_qt_version=ifelse([$2], ,4.0.0,$2)
1955
1956         #
1957         # Prior to Qt 5, modules were named QtXXX.
1958         # In Qt 5, they're named Qt5XXX.
1959         #
1960         # Try the Qt 5 version first.
1961         # (And be prepared to add Qt6 at some point....)
1962         #
1963         for modprefix in Qt5 Qt
1964         do
1965                 pkg_config_module="${modprefix}$1"
1966                 AC_MSG_CHECKING(for $pkg_config_module - version >= $min_qt_version)
1967                 if $PKG_CONFIG --atleast-version $min_qt_version $pkg_config_module; then
1968                         mod_version=`$PKG_CONFIG --modversion $pkg_config_module`
1969                         AC_MSG_RESULT(yes (version $mod_version))
1970                         Qt_CFLAGS="$Qt_CFLAGS `$PKG_CONFIG --cflags $pkg_config_module`"
1971                         Qt_LIBS="$Qt_LIBS `$PKG_CONFIG --libs $pkg_config_module`"
1972                         found_$1=yes
1973                         break
1974                 else
1975                         AC_MSG_RESULT(no)
1976                 fi
1977         done
1978
1979         if test "x$found_$1" = "xyes"; then
1980                 # Run Action-If-Found
1981                 ifelse([$3], , :, [$3])
1982         else
1983                 # Run Action-If-Not-Found
1984                 ifelse([$4], , :, [$4])
1985         fi
1986 ])
1987
1988 dnl AC_WIRESHARK_QT_CHECK([MINIMUM-VERSION, [ACTION-IF-FOUND,
1989 dnl     [ACTION-IF-NOT-FOUND]]])
1990 dnl Test for Qt and define Qt_CFLAGS and Qt_LIBS.
1991 dnl
1992 AC_DEFUN([AC_WIRESHARK_QT_CHECK],
1993 [
1994         no_qt=""
1995
1996         AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1997
1998         if test x$PKG_CONFIG != xno ; then
1999                 if pkg-config --atleast-pkgconfig-version 0.7 ; then
2000                         :
2001                 else
2002                         echo *** pkg-config too old; version 0.7 or better required.
2003                         no_qt=yes
2004                         PKG_CONFIG=no
2005                 fi
2006         else
2007                 no_qt=yes
2008         fi
2009
2010         if test x"$no_qt" = x ; then
2011                 #
2012                 # OK, we have an adequate version of pkg-config.
2013                 #
2014                 # Check for the Core module; if we don't have that,
2015                 # we don't have Qt.
2016                 #
2017                 AC_WIRESHARK_QT_MODULE_CHECK(Core, $1, , [no_qt=yes])
2018         fi
2019
2020         if test x"$no_qt" = x ; then
2021                 #
2022                 # We need the Gui module as well.
2023                 #
2024                 AC_WIRESHARK_QT_MODULE_CHECK(Gui, $1, , [no_qt=yes])
2025         fi
2026
2027         if test x"$no_qt" = x ; then
2028                 #
2029                 # Qt 5.0 appears to move the widgets out of Qt GUI
2030                 # to Qt Widgets; look for the Widgets module, but
2031                 # don't fail if we don't have it.
2032                 #
2033                 AC_WIRESHARK_QT_MODULE_CHECK(Widgets, $1)
2034
2035                 #
2036                 # Qt 5.0 also appears to move the printing support into
2037                 # the Qt PrintSupport module.
2038                 #
2039                 AC_WIRESHARK_QT_MODULE_CHECK(PrintSupport, $1)
2040
2041                 #
2042                 # Qt 5.0 added multimedia widgets in the Qt
2043                 # MultimediaWidgets module.
2044                 #
2045                 AC_WIRESHARK_QT_MODULE_CHECK(MultimediaWidgets, $1,
2046                         AC_DEFINE(QT_MULTIMEDIAWIDGETS_LIB, 1, [Define if we have QtMultimediaWidgets]))
2047
2048                 #
2049                 # While we're at it, look for QtMacExtras.  (Presumably
2050                 # if we're not building for OS X, it won't be present.)
2051                 #
2052                 # XXX - is there anything in QtX11Extras or QtWinExtras
2053                 # that we should be using?
2054                 #
2055                 AC_WIRESHARK_QT_MODULE_CHECK(MacExtras, $1,
2056                         AC_DEFINE(QT_MACEXTRAS_LIB, 1, [Define if we have QtMacExtras]))
2057
2058                 AC_SUBST(Qt_LIBS)
2059
2060                 # Run Action-If-Found
2061                 ifelse([$2], , :, [$2])
2062         else
2063                 # Run Action-If-Not-Found
2064                 ifelse([$3], , :, [$3])
2065         fi
2066
2067 ])