acinclude.m4

   1 dnl Macros that test for specific features.
   2 dnl This file is part of the Autoconf packaging for Wireshark.
   3 dnl Copyright (C) 1998-2000 by Gerald Combs.
   4 dnl
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 2, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; if not, write to the Free Software
  17 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  18 dnl 02111-1307, USA.
  19 dnl
  20 dnl As a special exception, the Free Software Foundation gives unlimited
  21 dnl permission to copy, distribute and modify the configure scripts that
  22 dnl are the output of Autoconf.  You need not follow the terms of the GNU
  23 dnl General Public License when using or distributing such scripts, even
  24 dnl though portions of the text of Autoconf appear in them.  The GNU
  25 dnl General Public License (GPL) does govern all other use of the material
  26 dnl that constitutes the Autoconf program.
  27 dnl
  28 dnl Certain portions of the Autoconf source text are designed to be copied
  29 dnl (in certain cases, depending on the input) into the output of
  30 dnl Autoconf.  We call these the "data" portions.  The rest of the Autoconf
  31 dnl source text consists of comments plus executable code that decides which
  32 dnl of the data portions to output in any given case.  We call these
  33 dnl comments and executable code the "non-data" portions.  Autoconf never
  34 dnl copies any of the non-data portions into its output.
  35 dnl
  36 dnl This special exception to the GPL applies to versions of Autoconf
  37 dnl released by the Free Software Foundation.  When you make and
  38 dnl distribute a modified version of Autoconf, you may extend this special
  39 dnl exception to the GPL to apply to your modified version as well, *unless*
  40 dnl your modified version has the potential to copy into its output some
  41 dnl of the text that was the non-data portion of the version that you started
  42 dnl with.  (In other words, unless your change moves or copies text from
  43 dnl the non-data portions to the data portions.)  If your modification has
  44 dnl such potential, you must delete any notice of this special exception
  45 dnl to the GPL from your modified version.
  46 dnl
  47 dnl Written by David MacKenzie, with help from
  48 dnl Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
  49 dnl Roland McGrath, Noah Friedman, david d zuhn, and many others.
  50
  51 #
  52 # AC_WIRESHARK_ADD_DASH_L
  53 #
  54 # Add to the variable specified as the first argument a "-L" flag for the
  55 # directory specified as the second argument, and, on Solaris, add a
  56 # "-R" flag for it as well.
  57 #
  58 # XXX - IRIX, and other OSes, may require some flag equivalent to
  59 # "-R" here.
  60 #
  61 AC_DEFUN([AC_WIRESHARK_ADD_DASH_L],
  62 [AX_APPEND_FLAG(-L$2, $1)
  63 case "$host_os" in
  64   solaris*)
  65     AX_APPEND_FLAG(-R$2, $1)
  66   ;;
  67 esac
  68 ])
  69
  70 #
  71 # AC_WIRESHARK_PUSH_FLAGS
  72 #
  73 # Push our flags to CFLAGS/etc.
  74 #
  75 AC_DEFUN([AC_WIRESHARK_PUSH_FLAGS],
  76 [
  77   ac_ws_CPPLAGS_saved="$CPPFLAGS"
  78   ac_ws_CFLAGS_saved="$CFLAGS"
  79   ac_ws_CXXFLAGS_saved="$CXXFLAGS"
  80   ac_ws_LDFLAGS_saved="$LDFLAGS"
  81   CPPFLAGS="$WS_CPPFLAGS $CPPFLAGS"
  82   CFLAGS="$WS_CFLAGS $CFLAGS"
  83   CXXFLAGS="$WS_CXXFLAGS $CXXFLAGS"
  84   LDFLAGS="$WS_LDFLAGS $LDFLAGS"
  85 ])
  86
  87 #
  88 # AC_WIRESHARK_POP_FLAGS
  89 #
  90 # Restore user build flags.
  91 #
  92 AC_DEFUN([AC_WIRESHARK_POP_FLAGS],
  93 [
  94   CPPFLAGS="$ac_ws_CPPLAGS_saved"
  95   CFLAGS="$ac_ws_CFLAGS_saved"
  96   CXXFLAGS="$ac_ws_CXXFLAGS_saved"
  97   LDFLAGS="$ac_ws_LDFLAGS_saved"
  98 ])
  99
 100
 101 #
 102 # AC_WIRESHARK_BREAKLOOP_TRY_LINK
 103 #
 104 AC_DEFUN([AC_WIRESHARK_PCAP_BREAKLOOP_TRY_LINK],
 105 [
 106   AC_LINK_IFELSE(
 107   [
 108       AC_LANG_SOURCE(
 109       [[
 110 #       include <pcap.h>
 111         int main(void)
 112         {
 113           pcap_t  *pct = NULL;
 114           pcap_breakloop(pct);
 115           return 0;
 116         }
 117       ]])
 118   ],
 119   [
 120     ws_breakloop_compiled=yes
 121   ],
 122   [
 123     ws_breakloop_compiled=no
 124   ])
 125 ])
 126
 127
 128
 129 #
 130 # AC_WIRESHARK_PCAP_CHECK
 131 #
 132 AC_DEFUN([AC_WIRESHARK_PCAP_CHECK],
 133 [
 134         AC_WIRESHARK_PUSH_FLAGS
 135
 136         if test -z "$pcap_dir"
 137         then
 138           # Pcap header checks
 139           # XXX need to set a var AC_CHECK_HEADER(pcap.h,,)
 140
 141           #
 142           # The user didn't specify a directory in which libpcap resides.
 143           # First, look for a pcap-config script.
 144           #
 145           AC_PATH_TOOL(PCAP_CONFIG, pcap-config)
 146
 147           if test -n "$PCAP_CONFIG" ; then
 148             #
 149             # Found it.
 150             #
 151             # Now check whether it's the libpcap 1.0 version, which
 152             # put a space after "-L" - on some platforms, that doesn't
 153             # work.
 154             #
 155             AC_MSG_CHECKING(for broken pcap-config)
 156             case "`\"$PCAP_CONFIG\" --libs`" in
 157
 158             "-L "*)
 159               #
 160               # Space after -L.  Pretend pcap-config doesn't exist.
 161               #
 162               AC_MSG_RESULT(yes)
 163               PCAP_CONFIG=""
 164               ;;
 165
 166             *)
 167               #
 168               # No space after -L.
 169               #
 170               AC_MSG_RESULT(no)
 171               ;;
 172             esac
 173           fi
 174           if test -n "$PCAP_CONFIG" ; then
 175             #
 176             # Found it, and it's usable; use it to get the include flags
 177             # for libpcap.
 178             #
 179             CPPFLAGS="$CPPFLAGS `\"$PCAP_CONFIG\" --cflags`"
 180           else
 181             #
 182             # Didn't find it; we have to look for libpcap ourselves.
 183             # We assume that the current library search path will work,
 184             # but we may have to look for the header in a "pcap"
 185             # subdirectory of "/usr/include" or "/usr/local/include",
 186             # as some systems apparently put "pcap.h" in a "pcap"
 187             # subdirectory, and we also check "$prefix/include" - and
 188             # "$prefix/include/pcap", in case $prefix is set to
 189             # "/usr/include" or "/usr/local/include".
 190             #
 191             # XXX - should we just add "$prefix/include" to the include
 192             # search path and "$prefix/lib" to the library search path?
 193             #
 194             AC_MSG_CHECKING(for extraneous pcap header directories)
 195             found_pcap_dir=""
 196             pcap_dir_list="/usr/local/include/pcap /usr/include/pcap $prefix/include/pcap $prefix/include"
 197             for pcap_dir in $pcap_dir_list
 198             do
 199               if test -d $pcap_dir ; then
 200                 if test x$pcap_dir != x/usr/include -a x$pcap_dir != x/usr/local/include ; then
 201                     CPPFLAGS="$CPPFLAGS -I$pcap_dir"
 202                 fi
 203                 found_pcap_dir=" $found_pcap_dir -I$pcap_dir"
 204                 break
 205               fi
 206             done
 207
 208             if test "$found_pcap_dir" != "" ; then
 209               AC_MSG_RESULT(found --$found_pcap_dir added to CFLAGS)
 210             else
 211               AC_MSG_RESULT(not found)
 212             fi
 213           fi
 214         else
 215           #
 216           # The user specified a directory in which libpcap resides,
 217           # so add the "include" subdirectory of that directory to
 218           # the include file search path and the "lib" subdirectory
 219           # of that directory to the library search path.
 220           #
 221           # XXX - if there's also a libpcap in a directory that's
 222           # already in CPPFLAGS or LDFLAGS, this won't make us find
 223           # the version in the specified directory, as the compiler
 224           # and/or linker will search that other directory before it
 225           # searches the specified directory.
 226           #
 227           CPPFLAGS="$CPPFLAGS -I$pcap_dir/include"
 228           AC_WIRESHARK_ADD_DASH_L(LDFLAGS, $pcap_dir/lib)
 229         fi
 230
 231         # Pcap header check
 232         AC_CHECK_HEADER(pcap.h,,
 233             AC_MSG_ERROR([[Header file pcap.h not found; if you installed libpcap
 234 from source, did you also do \"make install-incl\", and if you installed a
 235 binary package of libpcap, is there also a developer's package of libpcap,
 236 and did you also install that package?]]))
 237
 238         if test -n "$PCAP_CONFIG" ; then
 239           #
 240           # We have pcap-config; we assume that means we have libpcap
 241           # installed and that pcap-config will tell us whatever
 242           # libraries libpcap needs.
 243           #
 244           if test x$enable_static = xyes; then
 245             PCAP_LIBS="`\"$PCAP_CONFIG\" --libs --static`"
 246           else
 247             PCAP_LIBS="`\"$PCAP_CONFIG\" --libs`"
 248           fi
 249           AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 250         else
 251           #
 252           # Check to see if we find "pcap_open_live" in "-lpcap".
 253           # Also check for various additional libraries that libpcap might
 254           # require.
 255           #
 256           AC_CHECK_LIB(pcap, pcap_open_live,
 257             [
 258               PCAP_LIBS=-lpcap
 259               AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 260             ], [
 261               ac_wireshark_extras_found=no
 262               ac_save_LIBS="$LIBS"
 263               for extras in "-lcfg -lodm" "-lpfring"
 264               do
 265                 AC_MSG_CHECKING([for pcap_open_live in -lpcap with $extras])
 266                 LIBS="-lpcap $extras $ac_save_LIBS"
 267                 #
 268                 # XXX - can't we use AC_CHECK_LIB here?
 269                 #
 270                 AC_TRY_LINK(
 271                     [
 272 #       include <pcap.h>
 273                     ],
 274                     [
 275         pcap_open_live(NULL, 0, 0, 0, NULL);
 276                     ],
 277                     [
 278                         ac_wireshark_extras_found=yes
 279                         AC_MSG_RESULT([yes])
 280                         PCAP_LIBS="-lpcap $extras"
 281                         AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 282                     ],
 283                     [
 284                         AC_MSG_RESULT([no])
 285                     ])
 286                 if test x$ac_wireshark_extras_found = xyes
 287                 then
 288                     break
 289                 fi
 290               done
 291               if test x$ac_wireshark_extras_found = xno
 292               then
 293                 AC_MSG_ERROR([Can't link with library libpcap.])
 294               fi
 295               LIBS=$ac_save_LIBS
 296             ])
 297         fi
 298         AC_SUBST(PCAP_LIBS)
 299
 300         #
 301         # Check whether various variables and functions are defined by
 302         # libpcap.
 303         #
 304         ac_save_LIBS="$LIBS"
 305         LIBS="$PCAP_LIBS $LIBS"
 306         AC_CHECK_FUNCS(pcap_open_dead pcap_freecode)
 307         #
 308         # pcap_breakloop may be present in the library but not declared
 309         # in the pcap.h header file.  If it's not declared in the header
 310         # file, attempts to use it will get warnings, and, if we're
 311         # building with warnings treated as errors, that warning will
 312         # cause compilation to fail.
 313         #
 314         # We are therefore first testing whether the function is present
 315         # and then, if we're compiling with warnings as errors, testing
 316         # whether it is usable.  It is usable if it compiles without
 317         # a -Wimplicit warning (the "compile with warnings as errors"
 318         # option requires GCC). If it is not usable, we fail and tell
 319         # the user that the pcap.h header needs to be updated.
 320         #
 321         # Ceteris paribus, this should only happen with Mac OS X 10.3[.x] which
 322         # can have an up-to-date pcap library without the corresponding pcap
 323         # header.
 324         #
 325         # However, it might also happen on some others OSes with some erroneous
 326         # system manipulations where multiple versions of libpcap might co-exist
 327         # e.g. hand made symbolic link from libpcap.so -> libpcap.so.0.8 but
 328         # having the pcap header version 0.7.
 329         #
 330         AC_MSG_CHECKING([whether pcap_breakloop is present])
 331         ac_CFLAGS_saved="$CFLAGS"
 332         AC_WIRESHARK_PCAP_BREAKLOOP_TRY_LINK
 333         if test "x$ws_breakloop_compiled" = "xyes"; then
 334           AC_MSG_RESULT(yes)
 335           AC_DEFINE(HAVE_PCAP_BREAKLOOP, 1, [Define if pcap_breakloop is known])
 336           if test "x$with_warnings_as_errors" = "xyes"; then
 337             AC_MSG_CHECKING([whether pcap_breakloop is usable])
 338             CFLAGS="$CFLAGS -Werror -Wimplicit"
 339             AC_WIRESHARK_PCAP_BREAKLOOP_TRY_LINK
 340             if test "x$ws_breakloop_compiled" = "xyes"; then
 341               AC_MSG_RESULT(yes)
 342             else
 343               AC_MSG_RESULT(no)
 344               AC_MSG_ERROR(
 345 [Your pcap library is more recent than your pcap header.
 346 As you are building with compiler warnings treated as errors, Wireshark
 347 won't be able to use functions not declared in that header.
 348 If you wish to build with compiler warnings treated as errors, You should
 349 install a newer version of the header file.])
 350             fi
 351             CFLAGS="$ac_CFLAGS_saved"
 352           fi
 353         else
 354           AC_MSG_RESULT(no)
 355         fi
 356
 357         #
 358         # Later versions of Mac OS X 10.3[.x] ship a pcap.h that
 359         # doesn't define pcap_if_t but ship an 0.8[.x] libpcap,
 360         # so the library has "pcap_findalldevs()", but pcap.h
 361         # doesn't define "pcap_if_t" so you can't actually *use*
 362         # "pcap_findalldevs()".
 363         #
 364         # That even appears to be true of systems shipped with
 365         # 10.3.4, so it doesn't appear only to be a case of
 366         # Software Update not updating header files.
 367         #
 368         # (You can work around this by installing the 0.8 header
 369         # files.)
 370         #
 371         AC_CACHE_CHECK([whether pcap_findalldevs is present and usable],
 372           [ac_cv_func_pcap_findalldevs],
 373           [
 374             AC_LINK_IFELSE(
 375               [
 376                 AC_LANG_SOURCE(
 377                   [[
 378                     #include <pcap.h>
 379                     int main()
 380                     {
 381                       pcap_if_t *devpointer;
 382                       char errbuf[1];
 383
 384                       pcap_findalldevs(&devpointer, errbuf);
 385                     }
 386                   ]])
 387               ],
 388               [
 389                 ac_cv_func_pcap_findalldevs=yes
 390               ],
 391               [
 392                 ac_cv_func_pcap_findalldevs=no
 393               ])
 394           ])
 395         #
 396         # Don't check for other new routines that showed up after
 397         # "pcap_findalldevs()" if we don't have a usable
 398         # "pcap_findalldevs()", so we don't end up using them if the
 399         # "pcap.h" is crufty and old and doesn't declare them.
 400         #
 401         if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 402           AC_DEFINE(HAVE_PCAP_FINDALLDEVS, 1,
 403            [Define to 1 if you have the `pcap_findalldevs' function and a pcap.h that declares pcap_if_t.])
 404           AC_CHECK_FUNCS(pcap_datalink_val_to_name pcap_datalink_name_to_val)
 405           AC_CHECK_FUNCS(pcap_datalink_val_to_description)
 406           AC_CHECK_FUNCS(pcap_list_datalinks pcap_set_datalink pcap_lib_version)
 407           AC_CHECK_FUNCS(pcap_get_selectable_fd pcap_free_datalinks)
 408           AC_CHECK_FUNC(pcap_create,
 409           [
 410             AC_DEFINE(HAVE_PCAP_CREATE, 1,
 411              [Define to 1 if you have the `pcap_create' function.])
 412             AC_DEFINE(CAN_SET_CAPTURE_BUFFER_SIZE, 1,
 413              [Define to 1 if the capture buffer size can be set.])
 414           ])
 415           AC_CHECK_FUNCS(bpf_image pcap_set_tstamp_precision)
 416         fi
 417
 418         AC_WIRESHARK_POP_FLAGS
 419         LIBS="$ac_save_LIBS"
 420 ])
 421
 422 AC_DEFUN([AC_WIRESHARK_PCAP_REMOTE_CHECK],
 423 [
 424     ac_save_LIBS="$LIBS"
 425     LIBS="$PCAP_LIBS $LIBS"
 426     AC_CHECK_FUNCS(pcap_open)
 427     if test $ac_cv_func_pcap_open = "yes" ; then
 428         AC_DEFINE(HAVE_PCAP_REMOTE, 1,
 429             [Define to 1 if you have libpcap/WinPcap remote capturing support and prefer to use these new API features.])
 430     fi
 431     AC_CHECK_FUNCS(pcap_setsampling)
 432     LIBS="$ac_save_LIBS"
 433 ])
 434
 435 #
 436 # AC_WIRESHARK_ZLIB_CHECK
 437 #
 438 AC_DEFUN([AC_WIRESHARK_ZLIB_CHECK],
 439 [
 440         AC_WIRESHARK_PUSH_FLAGS
 441
 442         if test "x$zlib_dir" != "x"
 443         then
 444           #
 445           # The user specified a directory in which zlib resides,
 446           # so add the "include" subdirectory of that directory to
 447           # the include file search path and the "lib" subdirectory
 448           # of that directory to the library search path.
 449           #
 450           # XXX - if there's also a zlib in a directory that's
 451           # already in CPPFLAGS or LDFLAGS, this won't make us find
 452           # the version in the specified directory, as the compiler
 453           # and/or linker will search that other directory before it
 454           # searches the specified directory.
 455           #
 456           CPPFLAGS="$CPPFLAGS -I$zlib_dir/include"
 457           AC_WIRESHARK_ADD_DASH_L(LDFLAGS, $zlib_dir/lib)
 458         fi
 459
 460         #
 461         # Make sure we have "zlib.h".  If we don't, it means we probably
 462         # don't have zlib, so don't use it.
 463         #
 464         AC_CHECK_HEADER(zlib.h,,
 465           [
 466             if test "x$zlib_dir" != "x"
 467             then
 468               #
 469               # The user used "--with-zlib=" to specify a directory
 470               # containing zlib, but we didn't find the header file
 471               # there; that either means they didn't specify the
 472               # right directory or are confused about whether zlib
 473               # is, in fact, installed.  Report the error and give up.
 474               #
 475               AC_MSG_ERROR([zlib header not found in directory specified in --with-zlib])
 476             else
 477               if test "x$want_zlib" = "xyes"
 478               then
 479                 #
 480                 # The user tried to force us to use the library, but we
 481                 # couldn't find the header file; report an error.
 482                 #
 483                 AC_MSG_ERROR(Header file zlib.h not found.)
 484               else
 485                 #
 486                 # We couldn't find the header file; don't use the
 487                 # library, as it's probably not present.
 488                 #
 489                 want_zlib=no
 490               fi
 491             fi
 492           ])
 493
 494         if test "x$want_zlib" != "xno"
 495         then
 496                 #
 497                 # Well, we at least have the zlib header file.
 498                 # We link with zlib to support uncompression of
 499                 # gzipped network traffic, e.g. in an HTTP request
 500                 # or response body.
 501                 #
 502                 if test "x$zlib_dir" != "x"
 503                 then
 504                   WS_CPPFLAGS="$WS_CPPFLAGS -I$zlib_dir/include"
 505                   AC_WIRESHARK_ADD_DASH_L(WS_LDFLAGS, $zlib_dir/lib)
 506                 fi
 507                 LIBS="-lz $LIBS"
 508                 AC_DEFINE(HAVE_ZLIB, 1, [Define to use zlib library])
 509                 #
 510                 # Check for "inflatePrime()" in zlib, which we need
 511                 # in order to read compressed capture files.
 512                 #
 513                 AC_CHECK_FUNCS(inflatePrime)
 514
 515                 if test "x$ac_cv_func_inflatePrime" = "xyes" ; then
 516                         #
 517                         # Now check for "inflatePrime()" in zlib when
 518                         # linking with the linker flags for GTK+
 519                         # applications; people often grab XFree86 source
 520                         # and build and install it on their systems,
 521                         # and they appear sometimes to misconfigure
 522                         # XFree86 so that, even on systems with zlib,
 523                         # it assumes there is no zlib, so the XFree86
 524                         # build process builds and installs its
 525                         # own zlib in the X11 library directory.
 526                         #
 527                         # The zlib in at least some versions of XFree86
 528                         # is an older version that may lack "inflatePrime()",
 529                         # and that's the zlib with which Wireshark gets
 530                         # linked, so the build of Wireshark fails.
 531                         #
 532                         AC_MSG_CHECKING([for inflatePrime missing when linking with X11])
 533                         AC_TRY_LINK_FUNC(inflatePrime, AC_MSG_RESULT(no),
 534                           [
 535                             AC_MSG_RESULT(yes)
 536                             AC_MSG_ERROR(old zlib found when linking with X11 - get rid of old zlib.)
 537                           ])
 538                 fi
 539         fi
 540
 541         AC_WIRESHARK_POP_FLAGS
 542 ])
 543
 544 #
 545 # AC_WIRESHARK_LIBLUA_CHECK
 546 #
 547 # Sets $have_lua to yes or no.
 548 # If it's yes, it also sets $LUA_CFLAGS and $LUA_LIBS.
 549 AC_DEFUN([AC_WIRESHARK_LIBLUA_CHECK],[
 550
 551         AC_WIRESHARK_PUSH_FLAGS
 552
 553         if test "x$want_lua_dir" = "x"
 554         then
 555                 # The user didn't tell us where to find Lua.  Let's go look for it.
 556
 557                 # First, try the standard (pkg-config) way.
 558                 # Unfortunately Lua's pkg-config file isn't standardly named.
 559                 # Some distributions allow installation of multiple versions of
 560                 # Lua at the same time.  On such systems each version has its
 561                 # own package name.
 562                 #
 563                 # We use a for loop instead of giving all the package names to
 564                 # PKG_CHECK_MODULES because doing the latter doesn't appear to
 565                 # work reliably (some package names are not searched for).
 566                 for pkg in "lua < 5.3" lua5.2 lua-5.2 lua52 lua5.1 lua-5.1 lua51 lua5.0 lua-5.0 lua50
 567                 do
 568                         AC_MSG_CHECKING(if you have $pkg)
 569                         PKG_CHECK_EXISTS($pkg,
 570                         [
 571                          AC_MSG_RESULT(yes)
 572                          have_lua=yes
 573                         ],
 574                         [
 575                          AC_MSG_RESULT(no)
 576                         ])
 577
 578                         if test "x$have_lua" = "xyes"
 579                         then
 580                                 PKG_WIRESHARK_CHECK_SYSTEM_MODULES(LUA, $pkg)
 581                                 CPPFLAGS="$LUA_CFLAGS $CPPFLAGS"
 582                                 AC_CHECK_HEADERS(lua.h lualib.h lauxlib.h)
 583                                 break
 584                         fi
 585                 done
 586         fi
 587
 588         if test "x$have_lua" != "xyes"
 589         then
 590                 # We don't have pkg-config or the user specified the path to
 591                 # Lua (in $want_lua_dir).
 592                 # Let's look for the header file.
 593
 594                 AC_MSG_CHECKING(for the location of lua.h)
 595                 if test "x$want_lua_dir" = "x"
 596                 then
 597                         # The user didn't tell us where to look so we'll look in some
 598                         # standard locations.
 599                         want_lua_dir="/usr/local /usr $prefix"
 600                 fi
 601                 for dir in $want_lua_dir
 602                 do
 603                         if test -r "$dir/include/lua.h"
 604                         then
 605                                 header_dir="$dir/include"
 606                                 lua_dir=$dir
 607                                 break
 608                         fi
 609
 610                         for ver in 5.2 52 5.1 51 5.0 50
 611                         do
 612                                 if test -r "$dir/include/lua$ver/lua.h"
 613                                 then
 614                                         header_dir="$dir/include/lua$ver"
 615                                         lua_dir=$dir
 616                                         break
 617                                 fi
 618                         done
 619                 done
 620
 621                 if test "x$header_dir" = "x"
 622                 then
 623                         have_lua=no
 624                         AC_MSG_RESULT(not found)
 625                 else
 626                         AC_MSG_RESULT($header_dir)
 627
 628                         AC_MSG_CHECKING(the Lua version)
 629                         lua_ver=`$AWK AS_ESCAPE('/LUA_VERSION_NUM/ { print $NF; }' $header_dir/lua.h | sed 's/0/./')`
 630
 631                         if test "x$lua_ver" = "x5.3"
 632                         then
 633                                 # Wireshark doesn't compile with Lua 5.3 today
 634                                 AC_MSG_RESULT($lua_ver - disabling Lua support)
 635                                 have_lua=no
 636                         else
 637                                 AC_MSG_RESULT($lua_ver)
 638
 639                                 CPPFLAGS="$CPPFLAGS -I$header_dir"
 640                                 AC_CHECK_HEADERS(lua.h lualib.h lauxlib.h, ,
 641                                 [
 642                                         have_lua=no
 643                                 ])
 644                         fi
 645
 646                         if test "x$have_lua" = "x"
 647                         then
 648                                 # Set LUA_CFLAGS
 649                                 LUA_CFLAGS="-I$header_dir"
 650
 651                                 # We have the header files and they work.  Now let's check if we
 652                                 # have the library and it works.
 653                                 #
 654                                 # XXX - if there's also a liblua in a directory that's
 655                                 # already in CPPFLAGS or LDFLAGS, this won't make us find
 656                                 # the version in the specified directory, as the compiler
 657                                 # and/or linker will search that other directory before it
 658                                 # searches the specified directory.
 659                                 #
 660                                 # XXX - lib64?
 661                                 LDFLAGS="-L$lua_dir/lib $LDFLAGS"
 662                                 AC_SEARCH_LIBS(luaL_openlibs, [lua-${lua_ver} lua${lua_ver} lua],
 663                                 [
 664                                         LUA_LIBS="-L$lua_dir/lib $ac_cv_search_luaL_openlibs -lm"
 665                                         have_lua=yes
 666                                 ],[
 667                                         have_lua=no
 668                                 ], -lm)
 669                         fi
 670                 fi
 671         fi
 672
 673         AC_WIRESHARK_POP_FLAGS
 674 ])
 675
 676 #
 677 # AC_WIRESHARK_LIBPORTAUDIO_CHECK
 678 #
 679 AC_DEFUN([AC_WIRESHARK_LIBPORTAUDIO_CHECK],[
 680
 681         AC_WIRESHARK_PUSH_FLAGS
 682         wireshark_save_LIBS="$LIBS"
 683
 684         if test "x$portaudio_dir" != "x"
 685         then
 686                 #
 687                 # The user specified a directory in which libportaudio
 688                 # resides, so add the "include" subdirectory of that directory to
 689                 # the include file search path and the "lib" subdirectory
 690                 # of that directory to the library search path.
 691                 #
 692                 # XXX - if there's also a libportaudio in a directory that's
 693                 # already in CPPFLAGS or LDFLAGS, this won't make us find
 694                 # the version in the specified directory, as the compiler
 695                 # and/or linker will search that other directory before it
 696                 # searches the specified directory.
 697                 #
 698                 CPPFLAGS="$CPPFLAGS -I$portaudio_dir/include"
 699                 LDFLAGS="$LDFLAGS -L$portaudio_dir/lib"
 700         fi
 701         LIBS="-lportaudio $LIBS"
 702
 703         #
 704         # Make sure we have "portaudio.h".  If we don't, it means we probably
 705         # don't have libportaudio, so don't use it.
 706         #
 707         AC_CHECK_HEADERS(portaudio.h,,
 708         [
 709                 if test "x$portaudio_dir" != "x"
 710                 then
 711                         #
 712                         # The user used "--with-portaudio=" to specify a directory
 713                         # containing libportaudio, but we didn't find the header file
 714                         # there; that either means they didn't specify the
 715                         # right directory or are confused about whether libportaudio
 716                         # is, in fact, installed.  Report the error and give up.
 717                         #
 718                         AC_MSG_ERROR([libportaudio header not found in directory specified in --with-portaudio])
 719                 else
 720                         if test "x$want_portaudio" = "xyes"
 721                         then
 722                                 #
 723                                 # The user tried to force us to use the library, but we
 724                                 # couldn't find the header file; report an error.
 725                                 #
 726                                 AC_MSG_ERROR(Header file portaudio.h not found.)
 727                         else
 728                                 #
 729                                 # We couldn't find the header file; don't use the
 730                                 # library, as it's probably not present.
 731                                 #
 732                                 want_portaudio=no
 733                         fi
 734                 fi
 735         ])
 736
 737         #
 738         # Check whether we have the right version of portaudio
 739         #
 740         if test "x$want_portaudio" != "xno"
 741         then
 742                 AC_CHECK_TYPE(PortAudioStream,
 743                 AC_DEFINE(PORTAUDIO_API_1, 1, [Define if we are using version of of the Portaudio library API]),
 744                 ,
 745                 [#include <portaudio.h>])
 746         fi
 747
 748         if test "x$want_portaudio" != "xno"
 749         then
 750                 #
 751                 # Well, we at least have the portaudio header file.
 752                 #
 753                 # let's check if the libs are there
 754                 #
 755                 PORTAUDIO_LIBS=""
 756                 PORTAUDIO_INCLUDES=""
 757
 758                 AC_CHECK_LIB(portaudio, Pa_Initialize,
 759                 [
 760                         if test "x$portaudio_dir" != "x"
 761                         then
 762                                 #
 763                                 # Put the "-I" and "-L" flags for portaudio
 764                                 # into PORTAUDIO_INCLUDES and PORTAUDIO_LIBS,
 765                                 # respectively.
 766                                 #
 767                                 PORTAUDIO_LIBS="-L$portaudio_dir/lib -lportaudio"
 768                                 PORTAUDIO_INCLUDES="-I$portaudio_dir/include"
 769                         else
 770                                 PORTAUDIO_LIBS="-lportaudio"
 771                         fi
 772                         AC_DEFINE(HAVE_LIBPORTAUDIO, 1, [Define to use libportaudio library])
 773                         want_portaudio=yes
 774                 ],[
 775                         # User requested --with-portaudio but it isn't available
 776                         if test "x$want_portaudio" = "xyes"
 777                         then
 778                                 AC_MSG_ERROR(Linking with libportaudio failed.)
 779                         fi
 780                         want_portaudio=no
 781                 ])
 782                 AC_SUBST(PORTAUDIO_LIBS)
 783                 AC_SUBST(PORTAUDIO_INCLUDES)
 784
 785         fi
 786
 787         LIBS="$wireshark_save_LIBS"
 788         AC_WIRESHARK_POP_FLAGS
 789 ])
 790
 791
 792 #
 793 # AC_WIRESHARK_C_ARES_CHECK
 794 #
 795 AC_DEFUN([AC_WIRESHARK_C_ARES_CHECK],
 796 [
 797         want_c_ares=defaultyes
 798
 799         if test "x$want_c_ares" = "xdefaultyes"; then
 800                 want_c_ares=yes
 801         fi
 802
 803         if test "x$want_c_ares" = "xyes"; then
 804                 AC_CHECK_LIB(cares, ares_init,
 805                   [
 806                     C_ARES_LIBS=-lcares
 807                     AC_DEFINE(HAVE_C_ARES, 1, [Define to use c-ares library])
 808                     have_good_c_ares=yes
 809                   ])
 810         else
 811                 AC_MSG_RESULT(not required)
 812         fi
 813 ])
 814
 815
 816 #
 817 # AC_WIRESHARK_LIBCAP_CHECK
 818 #
 819 AC_DEFUN([AC_WIRESHARK_LIBCAP_CHECK],
 820 [
 821         want_libcap=defaultyes
 822
 823         if test "x$want_libcap" = "xdefaultyes"; then
 824                 want_libcap=yes
 825         fi
 826
 827         if test "x$want_libcap" = "xyes"; then
 828                 AC_CHECK_LIB(cap, cap_set_flag,
 829                   [
 830                     LIBCAP_LIBS=-lcap
 831                     AC_DEFINE(HAVE_LIBCAP, 1, [Define to use the libcap library])
 832                     have_good_libcap=yes
 833                   ],,
 834                 )
 835         else
 836                 AC_MSG_RESULT(not required)
 837         fi
 838 ])
 839
 840
 841 #
 842 # AC_WIRESHARK_KRB5_CHECK
 843 #
 844 AC_DEFUN([AC_WIRESHARK_KRB5_CHECK],
 845 [
 846         AC_WIRESHARK_PUSH_FLAGS
 847         wireshark_save_LIBS="$LIBS"
 848
 849         if test "x$krb5_dir" != "x"
 850         then
 851           #
 852           # The user specified a directory in which kerberos resides,
 853           # so add the "include" subdirectory of that directory to
 854           # the include file search path and the "lib" subdirectory
 855           # of that directory to the library search path.
 856           #
 857           # XXX - if there's also a kerberos in a directory that's
 858           # already in CPPFLAGS or LDFLAGS, this won't make us find
 859           # the version in the specified directory, as the compiler
 860           # and/or linker will search that other directory before it
 861           # searches the specified directory.
 862           #
 863           KRB5_CFLAGS="-I$krb5_dir/include"
 864           ac_heimdal_version=`grep heimdal $krb5_dir/include/krb5.h | head -n 1 | sed 's/^.*heimdal.*$/HEIMDAL/'`
 865           # MIT Kerberos moved krb5.h to krb5/krb5.h starting with release 1.5
 866           ac_mit_version_olddir=`grep 'Massachusetts' $krb5_dir/include/krb5.h | head -n 1 | sed 's/^.*Massachusetts.*$/MIT/'`
 867           ac_mit_version_newdir=`grep 'Massachusetts' $krb5_dir/include/krb5/krb5.h | head -n 1 | sed 's/^.*Massachusetts.*$/MIT/'`
 868           ac_krb5_version="$ac_heimdal_version$ac_mit_version_olddir$ac_mit_version_newdir"
 869           if test "x$ac_krb5_version" = "xHEIMDAL"
 870           then
 871               KRB5_LIBS="-L$krb5_dir/lib -lkrb5 -lasn1 $SSL_LIBS -lroken -lcrypt"
 872           else
 873               KRB5_LIBS="-L$krb5_dir/lib -lkrb5 -lk5crypto -lcom_err"
 874           fi
 875           if test "x$ac_krb5_version" = "xMIT"
 876           then
 877             AC_DEFINE(HAVE_MIT_KERBEROS, 1, [Define to use MIT kerberos])
 878           fi
 879         else
 880           AC_PATH_TOOL(KRB5_CONFIG, krb5-config)
 881           if test -x "$KRB5_CONFIG"
 882           then
 883             KRB5_CFLAGS=`"$KRB5_CONFIG" --cflags`
 884             KRB5_LIBS=`"$KRB5_CONFIG" --libs`
 885             #
 886             # If -lcrypto is in KRB5_FLAGS, we require it to build
 887             # with Heimdal/MIT.  We don't want to built with it by
 888             # default, due to annoying license incompatibilities
 889             # between the OpenSSL license and the GPL, so:
 890             #
 891             #   if SSL_LIBS is set to a non-empty string, we
 892             #   remove -lcrypto from KRB5_LIBS and replace
 893             #   it with SSL_LIBS;
 894             #
 895             #   if SSL_LIBS is not set to a non-empty string
 896             #   we fail with an appropriate error message.
 897             #
 898             case "$KRB5_LIBS" in
 899             *-lcrypto*)
 900                 if test ! -z "$SSL_LIBS"
 901                 then
 902                     KRB5_LIBS=`echo $KRB5_LIBS | sed 's/-lcrypto//'`
 903                     KRB5_LIBS="$KRB5_LIBS $SSL_LIBS"
 904                 else
 905                     AC_MSG_ERROR([Kerberos library requires -lcrypto, so you must specify --with-ssl])
 906                 fi
 907                 ;;
 908             esac
 909             ac_krb5_version=`"$KRB5_CONFIG" --version | head -n 1 | sed -e 's/^.*heimdal.*$/HEIMDAL/' -e 's/^Kerberos .*$/MIT/' -e 's/^Solaris Kerberos .*$/MIT/'`
 910           fi
 911         fi
 912
 913         CPPFLAGS="$CPPFLAGS $KRB5_CFLAGS"
 914
 915         #
 916         # Make sure we have "krb5.h".  If we don't, it means we probably
 917         # don't have kerberos, so don't use it.
 918         #
 919         AC_CHECK_HEADER(krb5.h,,
 920           [
 921             if test "x$krb5_dir" != "x"
 922             then
 923               #
 924               # The user used "--with-krb5=" to specify a directory
 925               # containing kerberos, but we didn't find the header file
 926               # there; that either means they didn't specify the
 927               # right directory or are confused about whether kerberos
 928               # is, in fact, installed.  Report the error and give up.
 929               #
 930               AC_MSG_ERROR([kerberos header not found in directory specified in --with-krb5])
 931             else
 932               if test "x$want_krb5" = "xyes"
 933               then
 934                 #
 935                 # The user tried to force us to use the library, but we
 936                 # couldn't find the header file; report an error.
 937                 #
 938                 AC_MSG_ERROR(Header file krb5.h not found.)
 939               else
 940                 #
 941                 # We couldn't find the header file; don't use the
 942                 # library, as it's probably not present.
 943                 #
 944                 KRB5_CFLAGS=""
 945                 KRB5_LIBS=""
 946                 want_krb5=no
 947                 AC_MSG_RESULT(No Heimdal or MIT header found - disabling dissection for some kerberos data in packet decoding)
 948               fi
 949             fi
 950           ])
 951
 952         if test "x$want_krb5" != "xno"
 953         then
 954             #
 955             # Well, we at least have the krb5 header file.
 956             # Check whether this is Heimdal or MIT.
 957             #
 958             AC_MSG_CHECKING(whether the Kerberos library is Heimdal or MIT)
 959             if test "x$ac_krb5_version" = "xHEIMDAL" -o "x$ac_krb5_version" = "xMIT"
 960             then
 961                 #
 962                 # Yes.
 963                 # Check whether we have krb5_kt_resolve - and whether
 964                 # we need to link with -lresolv when linking with
 965                 # the Kerberos library.
 966                 #
 967                 AC_MSG_RESULT($ac_krb5_version)
 968                 found_krb5_kt_resolve=no
 969                 for extras in "" "-lresolv"
 970                 do
 971                     LIBS="$KRB5_LIBS $extras $wireshark_save_LIBS"
 972                     if test -z "$extras"
 973                     then
 974                         AC_MSG_CHECKING([whether $ac_krb5_version includes krb5_kt_resolve])
 975                     else
 976                         AC_MSG_CHECKING([whether $ac_krb5_version includes krb5_kt_resolve (linking with $extras)])
 977                     fi
 978                     AC_TRY_LINK(
 979                         [
 980 #       include <krb5.h>
 981                         ],
 982                         [
 983                             krb5_kt_resolve(0, 0, 0);
 984                         ],
 985                         [
 986                             #
 987                             # We found "krb5_kt_resolve()".
 988                             #
 989                             AC_MSG_RESULT(yes)
 990                             if test -n "$extras"; then
 991                               KRB5_LIBS="$KRB5_LIBS $extras"
 992                             fi
 993                             AC_DEFINE(HAVE_KERBEROS, 1, [Define to use kerberos])
 994                             if test "x$ac_krb5_version" = "xHEIMDAL"
 995                             then
 996                                 AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1, [Define to use heimdal kerberos])
 997                             elif test "x$ac_krb5_version" = "xMIT"
 998                             then
 999                                 AC_DEFINE(HAVE_MIT_KERBEROS, 1, [Define to use MIT kerberos])
1000                             fi
1001                             found_krb5_kt_resolve=yes
1002                             break
1003                         ],
1004                         [
1005                             AC_MSG_RESULT(no)
1006                         ])
1007                 done
1008                 if test "$found_krb5_kt_resolve" = no
1009                 then
1010                     #
1011                     # We didn't find "krb5_kt_resolve()" in the
1012                     # Kerberos library, even when we tried linking
1013                     # with -lresolv; we can't link with kerberos.
1014                     #
1015                     if test "x$want_krb5" = "xyes"
1016                     then
1017                         #
1018                         # The user tried to force us to use the library,
1019                         # but we can't do so; report an error.
1020                         #
1021                         AC_MSG_ERROR(Usable $ac_krb5_version not found)
1022                     else
1023                         #
1024                         # Don't use
1025                         #
1026                         AC_MSG_RESULT(Usable $ac_krb5_version not found - disabling dissection for some kerberos data in packet decoding)
1027                         KRB5_CFLAGS=""
1028                         KRB5_LIBS=""
1029                         want_krb5=no
1030                     fi
1031                 else
1032                     #
1033                     # We can link with Kerberos; see whether krb5.h
1034                     # defines KEYTYPE_ARCFOUR_56 (where "defines" means
1035                     # "as a #define or as an enum member).
1036                     #
1037                     AC_MSG_CHECKING([whether krb5.h defines KEYTYPE_ARCFOUR_56])
1038                     AC_COMPILE_IFELSE(
1039                       [
1040                         AC_LANG_SOURCE(
1041                           [[
1042                             #include <krb5.h>
1043                             #include <stdio.h>
1044
1045                             int main()
1046                             {
1047                               printf("%u\n", KEYTYPE_ARCFOUR_56);
1048                             }
1049                           ]])
1050                       ],
1051                       [
1052                         AC_MSG_RESULT(yes)
1053                         AC_DEFINE(HAVE_KEYTYPE_ARCFOUR_56, 1, [Define if krb5.h defines KEYTYPE_ARCFOUR_56])
1054                       ],
1055                       [
1056                         AC_MSG_RESULT(no)
1057                       ])
1058                 fi
1059             else
1060                 #
1061                 # It's not Heimdal or MIT.
1062                 #
1063                 AC_MSG_RESULT(no)
1064                 if test "x$want_krb5" = "xyes"
1065                 then
1066                     #
1067                     # The user tried to force us to use the library,
1068                     # but we can't do so; report an error.
1069                     #
1070                     AC_MSG_ERROR(Kerberos not found)
1071                 else
1072                     #
1073                     # Don't use.
1074                     #
1075                     AC_MSG_RESULT(Kerberos not found - disabling dissection for some kerberos data in packet decoding)
1076                     KRB5_CFLAGS=""
1077                     KRB5_LIBS=""
1078                     want_krb5=no
1079                 fi
1080             fi
1081         else
1082             #
1083             # The user asked us not to use Kerberos, or they didn't
1084             # say whether they wanted us to use it but we found
1085             # that we couldn't.
1086             #
1087             KRB5_CFLAGS=""
1088             KRB5_LIBS=""
1089             want_krb5=no
1090         fi
1091         AC_SUBST(KRB5_CFLAGS)
1092         AC_SUBST(KRB5_LIBS)
1093
1094         LIBS="$wireshark_save_LIBS"
1095         AC_WIRESHARK_POP_FLAGS
1096 ])
1097
1098 #
1099 # AC_WIRESHARK_GEOIP_CHECK
1100 #
1101 AC_DEFUN([AC_WIRESHARK_GEOIP_CHECK],
1102 [
1103         want_geoip=defaultyes
1104
1105         if test "x$want_geoip" = "xdefaultyes"; then
1106                 want_geoip=yes
1107         fi
1108
1109         if test "x$want_geoip" = "xyes"; then
1110                 AC_CHECK_LIB(GeoIP, GeoIP_new,
1111                   [
1112                     GEOIP_LIBS=-lGeoIP
1113                 AC_DEFINE(HAVE_GEOIP, 1, [Define to use GeoIP library])
1114                 have_good_geoip=yes
1115                   ],,
1116                 )
1117                 if test "x$have_good_geoip" = "xyes"; then
1118                         AC_CHECK_LIB(GeoIP, GeoIP_country_name_by_ipnum_v6,
1119                           [
1120                                 AC_DEFINE(HAVE_GEOIP_V6, 1, [Define if GeoIP supports IPv6 (GeoIP 1.4.5 and later)])
1121                           ],,
1122                         )
1123                         AC_CHECK_LIB(GeoIP, GeoIP_free,
1124                           [
1125                                 AC_DEFINE(HAVE_GEOIP_FREE, 1, [Define if GeoIP has GeoIP_free (not available upstream with 1.6.10 or earlier)])
1126                           ],,
1127                         )
1128                 fi
1129         else
1130                 AC_MSG_RESULT(not required)
1131         fi
1132 ])
1133
1134 #
1135 # AC_WIRESHARK_LIBSSH_CHECK
1136 #
1137 AC_DEFUN([AC_WIRESHARK_LIBSSH_CHECK],
1138 [
1139         want_libssh=defaultyes
1140
1141         if test "x$want_libssh" = "xdefaultyes"; then
1142                 want_libssh=yes
1143         fi
1144
1145         if test "x$want_libssh" = "xyes"; then
1146                 AC_CHECK_LIB(ssh, ssh_new,
1147                   [
1148                     LIBSSH_LIBS=-lssh
1149                         AC_DEFINE(HAVE_LIBSSH, 1, [Define to use libssh library])
1150                         have_good_libssh=yes
1151                   ],,
1152                 )
1153                 AC_MSG_CHECKING([whether libssh >= 0.6.0 for sshdump, ciscodump])
1154                 PKG_CHECK_EXISTS([libssh >= 0.6.0],
1155                   [
1156                    AC_MSG_RESULT(yes)
1157                    AC_DEFINE(HAVE_LIBSSH_POINTSIX, 1, [Defined if libssh >= 0.6.0])
1158                    have_libssh_pointsix=yes
1159                   ],
1160                   [AC_MSG_RESULT(no)]
1161                 )
1162                 if test "x$have_libssh_pointsix" = "xyes"; then
1163                         # ssh_userauth_agent exists only >= 0.6.0, but not on Windows
1164                         # so check explicitly
1165                         AC_CHECK_LIB(ssh, ssh_userauth_agent,
1166                           [
1167                             AC_DEFINE(HAVE_SSH_USERAUTH_AGENT, 1, [Libssh library has ssh_userauth_agent])
1168                             have_ssh_userauth_agent=yes
1169                           ],,
1170                         )
1171                 fi
1172         else
1173                 AC_MSG_RESULT(not required)
1174         fi
1175 ])
1176
1177 #
1178 # AC_WIRESHARK_NGHTTP2_CHECK
1179 #
1180 AC_DEFUN([AC_WIRESHARK_NGHTTP2_CHECK],
1181 [
1182         want_nghttp2=defaultyes
1183
1184         if test "x$want_nghttp2" = "xdefaultyes"; then
1185                 want_nghttp2=yes
1186         fi
1187
1188         if test "x$want_nghttp2" = "xyes"; then
1189                 AC_CHECK_LIB(nghttp2, nghttp2_hd_inflate_new,
1190                         [
1191                                 AC_CHECK_HEADERS(nghttp2/nghttp2.h,
1192                                         [
1193                                                 NGHTTP2_LIBS=-lnghttp2
1194                                                 AC_DEFINE(HAVE_NGHTTP2, 1, [Define to use nghttp2 library])
1195                                                 have_good_nghttp2=yes
1196                                         ],,
1197                                 )
1198                         ],,
1199                 )
1200         else
1201                 AC_MSG_RESULT(not required)
1202         fi
1203 ])
1204
1205 #AC_WIRESHARK_LDFLAGS_CHECK
1206 #
1207 # $1 : ldflag(s) to test
1208 #
1209 # We attempt to compile and link a test program with the specified linker
1210 # flag. The defined flag is added to LDFLAGS only if the link succeeds.
1211 #
1212 AC_DEFUN([AC_WIRESHARK_LDFLAGS_CHECK],
1213 [LD_OPTION="$1"
1214 AC_MSG_CHECKING(whether we can add $LD_OPTION to LDFLAGS)
1215 AC_WIRESHARK_PUSH_FLAGS
1216 LDFLAGS="$LDFLAGS $LD_OPTION"
1217 can_add_to_ldflags=""
1218 AC_LINK_IFELSE(
1219   [
1220     AC_LANG_SOURCE([[int main() { return 0; }]])
1221   ],
1222   [
1223     AC_MSG_RESULT(yes)
1224     AX_APPEND_FLAG([$LD_OPTION], [WS_LDFLAGS])
1225     can_add_to_ldflags=yes
1226   ],
1227   [
1228     AC_MSG_RESULT(no)
1229     can_add_to_ldflags=no
1230   ])
1231   AC_WIRESHARK_POP_FLAGS
1232 ])
1233
1234 dnl
1235 dnl Check whether, if you pass an unknown warning option to the
1236 dnl compiler, it fails or just prints a warning message and succeeds.
1237 dnl Set ac_wireshark_unknown_warning_option_error to the appropriate flag
1238 dnl to force an error if it would otherwise just print a warning message
1239 dnl and succeed.
1240 dnl
1241 AC_DEFUN([AC_WIRESHARK_CHECK_UNKNOWN_WARNING_OPTION_ERROR],
1242     [
1243         AC_MSG_CHECKING([whether the compiler fails when given an unknown warning option])
1244         AC_WIRESHARK_PUSH_FLAGS
1245         CFLAGS="$CFLAGS -Wxyzzy-this-will-never-succeed-xyzzy"
1246         AC_TRY_COMPILE(
1247             [],
1248             [return 0],
1249             [
1250                 AC_MSG_RESULT([no, adding -Werror=unknown-warning-option])
1251                 #
1252                 # We're assuming this is clang, where
1253                 # -Werror=unknown-warning-option is the appropriate
1254                 # option to force the compiler to fail.
1255                 #
1256                 ac_wireshark_unknown_warning_option_error="-Werror=unknown-warning-option"
1257             ],
1258             [
1259                 AC_MSG_RESULT([yes])
1260             ])
1261         AC_WIRESHARK_POP_FLAGS
1262     ])
1263
1264 dnl
1265 dnl Check whether, if you pass a valid-for-C-but-not-C++ option to the
1266 dnl compiler, it fails or just prints a warning message and succeeds.
1267 dnl Set ac_wireshark_non_cxx_warning_option_error to the appropriate flag
1268 dnl to force an error if it would otherwise just print a warning message
1269 dnl and succeed.
1270 dnl
1271 AC_DEFUN([AC_WIRESHARK_CHECK_NON_CXX_WARNING_OPTION_ERROR],
1272     [
1273         AC_MSG_CHECKING([whether the compiler fails when given an warning option not supported for C++])
1274         #
1275         # Some C+ compilers warn about -Wmissing-prototypes, and some warn
1276         # about -Wmissing-declarations.  Check both.
1277         #
1278         AC_LANG_PUSH(C++)
1279         AC_WIRESHARK_PUSH_FLAGS
1280         save_CXXFLAGS="$CXXFLAGS"
1281         for flag in -Wmissing-prototypes -Wmissing-declarations; do
1282             CXXFLAGS="$save_CXXFLAGS $flag"
1283             AC_TRY_COMPILE(
1284                 [],
1285                 [return 0],
1286                 [
1287                     #
1288                     # We're assuming this is g++, where -Werror is the
1289                     # appropriate option to force the compiler to fail.
1290                     # Check whether it fails with -Werror.
1291                     #
1292                     # NOTE: it's important to put -Werror *before*
1293                     # the flag, otherwise, when it sees the flag,
1294                     # it doesn't yet know that warnings should be
1295                     # treated as errors, and doesn't treat the
1296                     # "that's C-only" warning as an error.
1297                     #
1298                     CXXFLAGS="$save_CXXFLAGS -Werror $flag"
1299                     AC_TRY_COMPILE(
1300                         [],
1301                         [return 0],
1302                         [
1303                             #
1304                             # No, so this option is actually OK
1305                             # with our C++ compiler.
1306                             #
1307                             # (We need an empty command here to
1308                             # prevent some versions of autoconf
1309                             # from generating a script with an
1310                             # empty "then" clause for an if statement.)
1311                             #
1312                             :
1313                         ],
1314                         [
1315                             #
1316                             # Yes, so we need -Werror for the tests.
1317                             #
1318                             ac_wireshark_non_cxx_warning_option_error="-Werror"
1319                             break
1320                         ])
1321                 ])
1322         done
1323         AC_WIRESHARK_POP_FLAGS
1324         AC_LANG_POP
1325         if test x$ac_wireshark_non_cxx_warning_option_error = x; then
1326             AC_MSG_RESULT([yes])
1327         else
1328             AC_MSG_RESULT([no, adding -Werror])
1329         fi
1330     ])
1331
1332 #
1333 # AC_WIRESHARK_COMPILER_FLAGS_CHECK
1334 #
1335 # $1 : flags to test
1336 # $2 : if supplied, C for C-only flags, CXX for C++-only flags
1337 # $3 : if supplied, a program to try to compile with the flag
1338 #      and, if the compile fails when -Werror is turned on,
1339 #      we don't add the flag - used for warning flags that
1340 #      issue incorrect or non-useful warnings with some
1341 #      compiler versions
1342 # $4 : must be supplied if $3 is supplied - a message describing
1343 #      for what the test program is testing
1344 #
1345 # The macro first determines if the compiler supports GCC-style flags.
1346 # Then it attempts to compile with the defined cflags.  The defined
1347 # flags are added to WS_CHECKED_CFLAGS only if the compilation succeeds.
1348 # CFLAGS remains unchanged. can_add_to_cflags is set to "no" when the
1349 # flag is checked but unavailable. (Like-wise for CXXFLAGS.)
1350 #
1351 # We do this because not all such options are necessarily supported by
1352 # the version of the particular compiler we're using.
1353 #
1354 AC_DEFUN([AC_WIRESHARK_COMPILER_FLAGS_CHECK],
1355 [GCC_OPTION="$1"
1356 can_add_to_cflags=""
1357 can_add_to_cxxflags=""
1358 if test "x$ac_supports_gcc_flags" = "xyes" ; then
1359   if test "$2" != CXX ; then
1360     #
1361     # Not C++-only; if this can be added to the C compiler flags, add them.
1362     #
1363     # If the option begins with "-W", add
1364     # $ac_wireshark_unknown_warning_option_error to make sure that
1365     # we'll get an error if it's an unknown warning option; not all
1366     # compilers treat unknown warning options as errors (I'm looking at
1367     # you, clang).
1368     #
1369     # If the option begins with "-f" or "-m", add -Werror to make sure
1370     # that we'll get an error if we get "argument unused during compilation"
1371     # warnings, as those will either cause a failure for files compiled
1372     # with -Werror or annoying noise for files compiled without it.
1373     # (Yeah, you, clang.)
1374     #
1375     AC_MSG_CHECKING(whether we can add $GCC_OPTION to CFLAGS)
1376     AC_WIRESHARK_PUSH_FLAGS
1377     if expr "x$GCC_OPTION" : "x-W.*" >/dev/null
1378     then
1379       CFLAGS="$CFLAGS $ac_wireshark_unknown_warning_option_error $GCC_OPTION"
1380     elif expr "x$GCC_OPTION" : "x-f.*" >/dev/null
1381     then
1382       CFLAGS="$CFLAGS -Werror $GCC_OPTION"
1383     elif expr "x$GCC_OPTION" : "x-m.*" >/dev/null
1384     then
1385       CFLAGS="$CFLAGS -Werror $GCC_OPTION"
1386     else
1387       CFLAGS="$CFLAGS $GCC_OPTION"
1388     fi
1389     AC_COMPILE_IFELSE(
1390       [
1391         AC_LANG_SOURCE([[int foo;]])
1392       ],
1393       [
1394         AC_MSG_RESULT(yes)
1395         can_add_to_cflags=yes
1396         #
1397         # OK, do we have a test program?  If so, check
1398         # whether it fails with this option and -Werror,
1399         # and, if so, don't include it.
1400         #
1401         # We test arg 4 here because arg 3 is a program which
1402         # could contain quotes (breaking the comparison).
1403         #
1404         if test "x$4" != "x" ; then
1405           CFLAGS="$CFLAGS -Werror"
1406           AC_MSG_CHECKING(whether $GCC_OPTION $4)
1407           AC_COMPILE_IFELSE(
1408             [AC_LANG_SOURCE($3)],
1409             [
1410               AC_MSG_RESULT(no)
1411               #
1412               # Remove "force an error for a warning" options, if we
1413               # added them, by setting CFLAGS to the saved value plus
1414               # just the new option.
1415               #
1416               AX_APPEND_FLAG([$GCC_OPTION], [WS_CFLAGS])
1417               if test "$CC" = "$CC_FOR_BUILD"; then
1418                 #
1419                 # We're building the build tools with the same compiler
1420                 # with which we're building Wireshark, so add the flags
1421                 # to the flags for that compiler as well.
1422                 #
1423                 AX_APPEND_FLAG([$GCC_OPTION], [WS_CFLAGS_FOR_BUILD])
1424               fi
1425             ],
1426             [
1427               AC_MSG_RESULT(yes)
1428             ])
1429         else
1430           #
1431           # Remove "force an error for a warning" options, if we
1432           # added them, by setting CFLAGS to the saved value plus
1433           # just the new option.
1434           #
1435           AX_APPEND_FLAG([$GCC_OPTION], [WS_CFLAGS])
1436           if test "$CC" = "$CC_FOR_BUILD"; then
1437             #
1438             # We're building the build tools with the same compiler
1439             # with which we're building Wireshark, so add the flags
1440             # to the flags for that compiler as well.
1441             #
1442             AX_APPEND_FLAG([$GCC_OPTION], [WS_CFLAGS_FOR_BUILD])
1443           fi
1444         fi
1445       ],
1446       [
1447         AC_MSG_RESULT(no)
1448         can_add_to_cflags=no
1449       ])
1450       AC_WIRESHARK_POP_FLAGS
1451   fi
1452   #
1453   # Did we find a C++ compiler?
1454   #
1455   if test "x$CXX" != "x" ; then
1456     #
1457     # Yes.  Is this option only for the C compiler?
1458     #
1459     if test "$2" != C ; then
1460       #
1461       # Not C-only; if this option can be added to the C++ compiler
1462       # options, add it.
1463       #
1464       # If the option begins with "-W", add
1465       # $ac_wireshark_unknown_warning_option_error, as per the above, and
1466       # also add $ac_wireshark_non_cxx_warning_option_error, because at
1467       # lease some versions of g++ whine about -Wmissing-prototypes, the
1468       # fact that at least one of those versions refuses to warn about
1469       # function declarations without an earlier declaration nonwithstanding;
1470       # perhaps there's a reason not to warn about that with C++ even though
1471       # warning about it can be a Good Idea with C, but it's not obvious to
1472       # me).
1473       #
1474       # If the option begins with "-f" or "-m", add -Werror to make sure
1475       # that we'll get an error if we get "argument unused during compilation"
1476       # warnings, as those will either cause a failure for files compiled
1477       # with -Werror or annoying noise for files compiled without it.
1478       # (Yeah, you, clang++.)
1479       #
1480       AC_MSG_CHECKING(whether we can add $GCC_OPTION to CXXFLAGS)
1481       AC_WIRESHARK_PUSH_FLAGS
1482       if expr "x$GCC_OPTION" : "x-W.*" >/dev/null
1483       then
1484         CXXFLAGS="$CXXFLAGS $ac_wireshark_unknown_warning_option_error $ac_wireshark_non_cxx_warning_option_error $GCC_OPTION"
1485       elif expr "x$GCC_OPTION" : "x-f.*" >/dev/null
1486       then
1487         CXXFLAGS="$CXXFLAGS -Werror $GCC_OPTION"
1488       elif expr "x$GCC_OPTION" : "x-m.*" >/dev/null
1489       then
1490         CXXFLAGS="$CXXFLAGS -Werror $GCC_OPTION"
1491       else
1492         CXXFLAGS="$CXXFLAGS $GCC_OPTION"
1493       fi
1494       AC_LANG_PUSH([C++])
1495       AC_COMPILE_IFELSE(
1496         [
1497           AC_LANG_SOURCE([[int foo;]])
1498         ],
1499         [
1500           AC_MSG_RESULT(yes)
1501           can_add_to_cxxflags=yes
1502           #
1503           # OK, do we have a test program?  If so, check
1504           # whether it fails with this option and -Werror,
1505           # and, if so, don't include it.
1506           #
1507           # We test arg 4 here because arg 3 is a program which
1508           # could contain quotes (breaking the comparison).
1509           #
1510           if test "x$4" != "x" ; then
1511             CXXFLAGS="$CXXFLAGS -Werror"
1512             AC_MSG_CHECKING(whether $GCC_OPTION $4)
1513             AC_COMPILE_IFELSE(
1514               [AC_LANG_SOURCE($3)],
1515               [
1516                 AC_MSG_RESULT(no)
1517                 #
1518                 # Remove "force an error for a warning" options, if we
1519                 # added them, by setting CXXFLAGS to the saved value plus
1520                 # just the new option.
1521                 #
1522                 AX_APPEND_FLAG([$GCC_OPTION], [WS_CXXFLAGS])
1523               ],
1524               [
1525                 AC_MSG_RESULT(yes)
1526               ])
1527           else
1528             #
1529             # Remove "force an error for a warning" options, if we
1530             # added them, by setting CXXFLAGS to the saved value plus
1531             # just the new option.
1532             #
1533             AX_APPEND_FLAG([$GCC_OPTION], [WS_CXXFLAGS])
1534           fi
1535         ],
1536         [
1537           AC_MSG_RESULT(no)
1538           can_add_to_cxxflags=no
1539         ])
1540       AC_WIRESHARK_POP_FLAGS
1541       AC_LANG_POP([C++])
1542     fi
1543     if test "(" "$can_add_to_cflags" = "yes" -a "$can_add_to_cxxflags" = "no" ")" \
1544          -o "(" "$can_add_to_cflags" = "no" -a "$can_add_to_cxxflags" = "yes" ")"
1545     then
1546       #
1547       # Confusingly, some C++ compilers like -Wmissing-prototypes but
1548       # don't like -Wmissing-declarations and others like
1549       # -Wmissing-declarations but don't like -Wmissing-prototypes,
1550       # the fact that the corresponding C compiler likes both.  Don't
1551       # warn about them.
1552       #
1553       if test "(" x$GCC_OPTION != x-Wmissing-prototypes ")" \
1554            -a "(" x$GCC_OPTION != x-Wmissing-declarations ")"
1555       then
1556          AC_MSG_WARN([$CC and $CXX appear to be a mismatched pair])
1557       fi
1558     fi
1559   fi
1560 fi
1561 ])
1562
1563 # AC_WIRESHARK_GCC_FORTIFY_SOURCE_CHECK
1564 #
1565 # Checks if '-D_FORTIFY_SOURCE=...' is OK to use in CPPFLAGS.
1566 #  Use '-D_FORTIFY_SOURCE=...' in CPPFLAGS only if the GCC 'optimization level' is > 0.
1567 #  The use of '-D_FORTIFY_SOURCE=...' will cause a warning with at least some versions
1568 #    of glibc if the  GCC "optimization level" is 0 (default or -O or -O0)
1569 #    when using GCC to compile a source file which references the macro definition.
1570 #
1571 # See: http://gcc.gnu.org/ml/gcc-patches/2004-09/msg02055.html
1572 # See: http://sourceware.org/bugzilla/show_bug.cgi?id=13979
1573 #
1574 #   We'll use '-D_FORTIFY_SOURCE=2' only if there's no warning; Among other things this means
1575 #    that the  use of '-D_FORTIFY_SOURCE=2' with '-Werror' and '-O0' won't cause
1576 #    the compiler to stop on error.
1577 #   Assumption: CFLAGS already contains whatever optimization option including none) is
1578 #    to be used.
1579 #
1580
1581 AC_DEFUN([AC_WIRESHARK_GCC_FORTIFY_SOURCE_CHECK],
1582 [
1583 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
1584   AC_MSG_CHECKING([whether -D_FORTIFY_SOURCE=2 can be used (without generating a warning)])
1585   AC_WIRESHARK_PUSH_FLAGS
1586   CFLAGS="$CFLAGS -Werror"
1587   CPPFLAGS="$CPPFLAGS -D_FORTIFY_SOURCE=2"
1588   AC_COMPILE_IFELSE([
1589     AC_LANG_SOURCE([[
1590                   #include <stdio.h>
1591                       int foo;
1592                   ]])],
1593                   [
1594                     AC_MSG_RESULT(yes)
1595                     AX_APPEND_FLAG([-D_FORTIFY_SOURCE=2], [WS_CPPFLAGS])
1596                   ],
1597                   [
1598                     AC_MSG_RESULT(no)
1599                   ])
1600   AC_WIRESHARK_POP_FLAGS
1601 fi
1602 ])
1603
1604 #
1605 # AC_WIRESHARK_GCC_SYSTEM_INCLUDE
1606 #
1607 # Replace -I include flag for -isystem in FLAGS argument
1608 #
1609 AC_DEFUN([AC_WIRESHARK_GCC_SYSTEM_INCLUDE],
1610 [
1611         if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
1612                 $1=`echo " $$1" \
1613                         | sed -e 's/  *-I *\// -isystem\//g' -e 's/^ *//'`
1614         fi
1615 ])
1616
1617 #
1618 # PKG_WIRESHARK_CHECK_SYSTEM_MODULES
1619 #
1620 AC_DEFUN([PKG_WIRESHARK_CHECK_SYSTEM_MODULES],
1621 [
1622         PKG_CHECK_MODULES($@)
1623         AC_WIRESHARK_GCC_SYSTEM_INCLUDE($1_CFLAGS)
1624 ])
1625
1626 # Based on AM_PATH_GTK in gtk-2.0.m4.
1627
1628 dnl AC_WIRESHARK_QT_MODULE_CHECK_WITH_QT_VERSION([MODULE, MINIMUM-VERSION,
1629 dnl     REQUESTED-MAJOR_VERSION, [ACTION-IF-FOUND, [ACTION-IF-NOT-FOUND]]])
1630 dnl Test for a particular Qt module, for a particular Qt major version,
1631 dnl and, if we find it add the flags and libraries for it to Qt_CFLAGS
1632 dnl and Qt_LIBS.
1633 dnl
1634 AC_DEFUN([AC_WIRESHARK_QT_MODULE_CHECK_WITH_QT_VERSION],
1635 [
1636         case "$3" in
1637
1638         4)
1639                 #
1640                 # Check for Qt 4.
1641                 #
1642                 modprefix="Qt"
1643                 #
1644                 # Version of the module we're checking for.
1645                 # Default to 4.0.0.
1646                 #
1647                 min_qt_version=ifelse([$2], ,4.0.0,$2)
1648                 ;;
1649
1650         5)
1651                 #
1652                 # Check for Qt 5.
1653                 #
1654                 modprefix="Qt5"
1655                 #
1656                 # Version of the module we're checking for.
1657                 # Default to 5.0.0.
1658                 #
1659                 min_qt_version=5.0.0
1660                 ;;
1661
1662         *)
1663                 AC_MSG_ERROR([Qt version $3 is not a known Qt version])
1664                 ;;
1665         esac
1666
1667         pkg_config_module="${modprefix}$1"
1668         AC_MSG_CHECKING(for $pkg_config_module - version >= $min_qt_version)
1669         if $PKG_CONFIG --atleast-version $min_qt_version $pkg_config_module; then
1670                 mod_version=`$PKG_CONFIG --modversion $pkg_config_module`
1671                 AC_MSG_RESULT(yes (version $mod_version))
1672                 mod_cflags=`$PKG_CONFIG --cflags $pkg_config_module`
1673                 AC_WIRESHARK_GCC_SYSTEM_INCLUDE(mod_cflags)
1674                 Qt_CFLAGS="$Qt_CFLAGS $mod_cflags"
1675                 Qt_LIBS="$Qt_LIBS `$PKG_CONFIG --libs $pkg_config_module`"
1676                 # Run Action-If-Found
1677                 ifelse([$4], , :, [$4])
1678         else
1679                 AC_MSG_RESULT(no)
1680                 # Run Action-If-Not-Found
1681                 ifelse([$5], , :, [$5])
1682         fi
1683 ])
1684
1685 dnl AC_WIRESHARK_QT_MODULE_CHECK([MODULE, MINIMUM-VERSION,
1686 dnl     REQUESTED-MAJOR_VERSION, [ACTION-IF-FOUND, [ACTION-IF-NOT-FOUND]]])
1687 dnl Test for a particular Qt module and add the flags and libraries
1688 dnl for it to Qt_CFLAGS and Qt_LIBS.
1689 dnl
1690 AC_DEFUN([AC_WIRESHARK_QT_MODULE_CHECK],
1691 [
1692         #
1693         # Prior to Qt 5, modules were named QtXXX.
1694         # In Qt 5, they're named Qt5XXX.
1695         # This will need to change to handle future major Qt releases.
1696         #
1697         case "$3" in
1698
1699         yes|unspecified)
1700                 #
1701                 # Check for all versions of Qt we support.
1702                 # Try the Qt 5 version first.
1703                 #
1704                 versions="5 4"
1705                 ;;
1706
1707         4)
1708                 #
1709                 # Check for Qt 4.
1710                 #
1711                 versions="4"
1712                 ;;
1713
1714         5)
1715                 #
1716                 # Check for Qt 5.
1717                 #
1718                 versions="5"
1719                 ;;
1720
1721         *)
1722                 AC_MSG_ERROR([Qt version $3 is not a known Qt version])
1723                 ;;
1724         esac
1725
1726         for version in $versions
1727         do
1728                 AC_WIRESHARK_QT_MODULE_CHECK_WITH_QT_VERSION($1, $2,
1729                     $version, [foundit=yes], [foundit=no])
1730                 if test "x$foundit" = "xyes"; then
1731                         break
1732                 fi
1733         done
1734
1735         if test "x$foundit" = "xyes"; then
1736                 # Remember which version of Qt we found
1737                 qt_version=$version
1738                 # Run Action-If-Found
1739                 ifelse([$4], , :, [$4])
1740         else
1741                 # Run Action-If-Not-Found
1742                 ifelse([$5], , :, [$5])
1743         fi
1744 ])
1745
1746 AC_DEFUN([AC_WIRESHARK_QT_ADD_PIC_IF_NEEDED],
1747 [
1748     AC_LANG_PUSH([C++])
1749         AC_WIRESHARK_PUSH_FLAGS
1750         CPPFLAGS="$CPPFLAGS $Qt_CFLAGS"
1751         AC_MSG_CHECKING([whether Qt works without -fPIC])
1752         AC_PREPROC_IFELSE(
1753                 [AC_LANG_SOURCE([[#include <QtCore>]])],
1754                 [AC_MSG_RESULT(yes)],
1755                 [
1756                         AC_MSG_RESULT(no)
1757                         AC_MSG_CHECKING([whether Qt works with -fPIC])
1758                         CPPFLAGS="$CPPFLAGS -fPIC"
1759                         AC_PREPROC_IFELSE(
1760                                 [AC_LANG_SOURCE([[#include <QtCore>]])],
1761                                 [
1762                                         AC_MSG_RESULT(yes)
1763                                         Qt_CFLAGS="$Qt_CFLAGS -fPIC"
1764                                 ],
1765                                 [
1766                                         AC_MSG_RESULT(no)
1767                                         AC_MSG_ERROR(Couldn't compile Qt without -fPIC nor with -fPIC)
1768                                 ])
1769                 ])
1770         AC_WIRESHARK_POP_FLAGS
1771     AC_LANG_POP([C++])
1772 ])
1773
1774 dnl AC_WIRESHARK_QT_CHECK([MINIMUM-VERSION, REQUESTED-MAJOR_VERSION,
1775 dnl     [ACTION-IF-FOUND, [ACTION-IF-NOT-FOUND]]])
1776 dnl Test for Qt and define Qt_CFLAGS and Qt_LIBS.
1777 dnl
1778 AC_DEFUN([AC_WIRESHARK_QT_CHECK],
1779 [
1780         qt_version_to_check="$2"
1781
1782         #
1783         # Check for the Core module; if we don't have that,
1784         # we don't have Qt.  If we *do* have it, we know what
1785         # version it is, so only check for that version of
1786         # other modules.
1787         #
1788         AC_WIRESHARK_QT_MODULE_CHECK(Core, $1, $qt_version_to_check,
1789             [
1790               qt_version_to_check=$qt_version
1791               QT_VERSION=$mod_version
1792               QT_VERSION_MAJOR=`echo "$QT_VERSION" | cut -f1 -d.`
1793               QT_VERSION_MINOR=`echo "$QT_VERSION" | cut -f2 -d.`
1794               QT_VERSION_MICRO=`echo "$QT_VERSION" | cut -f3 -d.`
1795
1796               # Qt 5.7 and later requires C++11
1797               AS_IF([test $QT_VERSION_MAJOR -eq 5 -a $QT_VERSION_MINOR -ge 7],
1798                 [AS_IF([test "$HAVE_CXX11" -eq 0], [AC_MSG_ERROR([Qt 5.7 and later requires C++11])])])
1799
1800             ],
1801             [no_qt=yes])
1802
1803         if test x"$no_qt" = x ; then
1804                 #
1805                 # We need the Gui module as well.
1806                 #
1807                 AC_WIRESHARK_QT_MODULE_CHECK(Gui, $1, $qt_version_to_check, ,
1808                     [no_qt=yes])
1809         fi
1810
1811         if test x"$no_qt" = x ; then
1812                 #
1813                 # Qt 5.0 appears to move the widgets out of Qt GUI
1814                 # to Qt Widgets; look for the Widgets module, but
1815                 # don't fail if we don't have it.
1816                 #
1817                 AC_WIRESHARK_QT_MODULE_CHECK(Widgets, $1, $qt_version_to_check)
1818
1819                 #
1820                 # Qt 5.0 also appears to move the printing support into
1821                 # the Qt PrintSupport module.
1822                 #
1823                 AC_WIRESHARK_QT_MODULE_CHECK(PrintSupport, $1, $qt_version_to_check)
1824
1825                 #
1826                 # Qt 5.0 added multimedia in the Qt
1827                 # Multimedia module.
1828                 #
1829                 have_qt_multimedia_lib=no
1830                 AC_WIRESHARK_QT_MODULE_CHECK(Multimedia, $1, $qt_version_to_check,
1831                         have_qt_multimedia_lib=yes
1832                         AC_DEFINE(QT_MULTIMEDIA_LIB, 1, [Define if we have QtMultimedia]))
1833
1834                 #
1835                 # While we're at it, look for QtMacExtras.  (Presumably
1836                 # if we're not building for macOS, it won't be present.)
1837                 #
1838                 # XXX - is there anything in QtX11Extras or QtWinExtras
1839                 # that we should be using?
1840                 #
1841                 AC_WIRESHARK_QT_MODULE_CHECK(MacExtras, $1, $qt_version_to_check,
1842                         AC_DEFINE(QT_MACEXTRAS_LIB, 1, [Define if we have QtMacExtras]))
1843
1844                 AC_WIRESHARK_QT_ADD_PIC_IF_NEEDED
1845
1846                 # Run Action-If-Found
1847                 ifelse([$3], , :, [$3])
1848         else
1849                 # Run Action-If-Not-Found
1850                 ifelse([$4], , :, [$4])
1851         fi
1852
1853 ])
1854
1855 dnl AC_WIRESHARK_QT_TOOL_CHECK([TOOLPATHVAR, TOOL, REQUESTED-MAJOR_VERSION])
1856 dnl Test for a particular Qt tool for some specific version of Qt
1857 dnl
1858 AC_DEFUN([AC_WIRESHARK_QT_TOOL_CHECK],
1859 [
1860         #
1861         # At least in some versions of Debian/Ubuntu, and perhaps
1862         # other OSes, the Qt build tools are just links to a
1863         # program called "qtchooser", and even if you want to
1864         # build with Qt 5, running the tool might give you the
1865         # Qt 4 version of the tool unless you run the tool with
1866         # a -qt=5 argument.
1867         #
1868         # So we look for qtchooser and, if we find it, use the
1869         # -qt={version} argument, otherwise we look for particular
1870         # tool versions using tool name suffixes.
1871         #
1872         AC_PATH_PROG(QTCHOOSER, qtchooser)
1873         if test ! -z "$QTCHOOSER"; then
1874                 #
1875                 # We found qtchooser; we assume that means that
1876                 # the tool is linked to qtchooser, so that we
1877                 # can run it with the -qt={version} flag to get
1878                 # the appropriate version of the tool.
1879                 #
1880                 AC_PATH_PROG($1, $2)
1881                 if test "x$$1" = x; then
1882                         #
1883                         # We can't build Qt Wireshark without that
1884                         # tool..
1885                         #
1886                         AC_MSG_ERROR(I couldn't find $2; make sure it's installed and in your path)
1887                 fi
1888
1889                 #
1890                 # Add the -qt={version} argument to it.
1891                 #
1892                 $1="$$1 -qt=$qt_version"
1893         else
1894                 #
1895                 # Annoyingly, on some Linux distros (e.g. Debian)
1896                 # the Qt 5 tools have no suffix and the Qt 4 tools
1897                 # have suffix -qt4. On other distros (e.g. openSUSE)
1898                 # the Qt 5 tools have suffix -qt5 and the Qt 4 tools
1899                 # have no suffix.
1900                 #
1901                 # So we check for the tool first with the -qtN suffix
1902                 # and then with no suffix.
1903                 #
1904                 AC_PATH_PROGS($1, [$2-qt$qt_version $2])
1905                 if test "x$$1" = x; then
1906                         #
1907                         # We can't build Qt Wireshark without that
1908                         # tool..
1909                         #
1910                         AC_MSG_ERROR(I couldn't find $2-qt$qt_version or $2; make sure it's installed and in your path)
1911                 fi
1912         fi
1913 ])
1914
1915 AC_DEFUN([AC_WIRESHARK_QT_TOOL_CHECK_LRELEASE],
1916 [
1917   AC_WIRESHARK_QT_TOOL_CHECK(LRELEASE, lrelease, $2)
1918   AC_MSG_CHECKING(whether lrelease -version works)
1919   lrelease_version=`$LRELEASE -version 2>&AS_MESSAGE_LOG_FD`
1920   AS_IF([test $? -ne 0],
1921     [
1922       AC_MSG_RESULT(no)
1923       AC_MSG_ERROR([$LRELEASE -version returned non-zero exit status])
1924     ])
1925   AC_MSG_RESULT([ok, $lrelease_version])
1926 ])
1927
1928 #
1929 # AC_WIRESHARK_LZ4_CHECK
1930 #
1931 AC_DEFUN([AC_WIRESHARK_LZ4_CHECK],
1932 [
1933         AC_WIRESHARK_PUSH_FLAGS
1934
1935         if test "x$lz4_dir" != "x"
1936         then
1937           #
1938           # The user specified a directory in which lz4 resides,
1939           # so add the "include" subdirectory of that directory to
1940           # the include file search path and the "lib" subdirectory
1941           # of that directory to the library search path.
1942           #
1943           # XXX - if there's also a lz4 in a directory that's
1944           # already in CPPFLAGS or LDFLAGS, this won't make us find
1945           # the version in the specified directory, as the compiler
1946           # and/or linker will search that other directory before it
1947           # searches the specified directory.
1948           #
1949           LZ4_CFLAGS="-I$lz4_dir/include"
1950         fi
1951
1952         #
1953         # Make sure we have "lz4.h".  If we don't, it means we probably
1954         # don't have lz4, so don't use it.
1955         #
1956         AC_CHECK_HEADER(lz4.h,,
1957           [
1958             if test "x$lz4_dir" != "x"
1959             then
1960               #
1961               # The user used "--with-lz4=" to specify a directory
1962               # containing lz4, but we didn't find the header file
1963               # there; that either means they didn't specify the
1964               # right directory or are confused about whether lz4
1965               # is, in fact, installed.  Report the error and give up.
1966               #
1967               AC_MSG_ERROR([lz4 header not found in directory specified in --with-lz4])
1968             else
1969               if test "x$want_lz4" = "xyes"
1970               then
1971                 #
1972                 # The user tried to force us to use the library, but we
1973                 # couldn't find the header file; report an error.
1974                 #
1975                 AC_MSG_ERROR(Header file lz4.h not found.)
1976               else
1977                 #
1978                 # We couldn't find the header file; don't use the
1979                 # library, as it's probably not present.
1980                 #
1981                 want_lz4=no
1982               fi
1983             fi
1984           ])
1985
1986         if test "x$want_lz4" != "xno"
1987         then
1988                 #
1989                 # Well, we at least have the lz4 header file.
1990                 # We link with lz4 to support uncompression of
1991                 # CQL traffic.
1992                 #
1993                 LZ4_LIBS="-llz4"
1994                 ac_save_LIBS="$LIBS"
1995                 LIBS="$LZ4_LIBS $LIBS"
1996                 AC_DEFINE(HAVE_LZ4, 1, [Define to use lz4 library])
1997                 #
1998                 # Check for "LZ4_decompress_safe()" in lz4, which we need
1999                 # in order to read compressed capture files.
2000                 #
2001                 AC_CHECK_FUNCS(LZ4_decompress_safe)
2002                 LIBS="$ac_save_LIBS"
2003         fi
2004
2005         AC_WIRESHARK_POP_FLAGS
2006 ])
2007
2008 #
2009 # AC_WIRESHARK_SNAPPY_CHECK
2010 #
2011 AC_DEFUN([AC_WIRESHARK_SNAPPY_CHECK],
2012 [
2013         AC_WIRESHARK_PUSH_FLAGS
2014
2015         if test "x$snappy_dir" != "x"
2016         then
2017           #
2018           # The user specified a directory in which snappy resides,
2019           # so add the "include" subdirectory of that directory to
2020           # the include file search path and the "lib" subdirectory
2021           # of that directory to the library search path.
2022           #
2023           # XXX - if there's also a snappy in a directory that's
2024           # already in CPPFLAGS or LDFLAGS, this won't make us find
2025           # the version in the specified directory, as the compiler
2026           # and/or linker will search that other directory before it
2027           # searches the specified directory.
2028           #
2029           SNAPPY_CFLAGS="-I$snappy_dir/include"
2030         fi
2031
2032         #
2033         # Make sure we have "snappy-c.h".  If we don't, it means we probably
2034         # don't have snappy, so don't use it.
2035         #
2036         AC_CHECK_HEADER(snappy-c.h,,
2037           [
2038             if test "x$snappy_dir" != "x"
2039             then
2040               #
2041               # The user used "--with-snappy=" to specify a directory
2042               # containing snappy, but we didn't find the header file
2043               # there; that either means they didn't specify the
2044               # right directory or are confused about whether snappy
2045               # is, in fact, installed.  Report the error and give up.
2046               #
2047               AC_MSG_ERROR([snappy-c.header not found in directory specified in --with-snappy])
2048             else
2049               if test "x$want_snappy" = "xyes"
2050               then
2051                 #
2052                 # The user tried to force us to use the library, but we
2053                 # couldn't find the header file; report an error.
2054                 #
2055                 AC_MSG_ERROR(Header file snappy-c.h not found.)
2056               else
2057                 #
2058                 # We couldn't find the header file; don't use the
2059                 # library, as it's probably not present.
2060                 #
2061                 want_snappy=no
2062               fi
2063             fi
2064           ])
2065
2066         if test "x$want_snappy" != "xno"
2067         then
2068                 #
2069                 # Well, we at least have the snappy-c.header file.
2070                 # We link with snappy to support uncompression of
2071                 # compressed CQL traffic.
2072                 #
2073                 SNAPPY_LIBS=-lsnappy
2074                 ac_save_LIBS="$LIBS"
2075                 LIBS="$SNAPPY_LIBS $LIBS"
2076                 AC_DEFINE(HAVE_SNAPPY, 1, [Define to use snappy library])
2077                 #
2078                 # Check for "snappy_uncompress()" in snappy, which we need
2079                 # in order to read compressed capture files.
2080                 #
2081                 AC_CHECK_FUNCS(snappy_uncompress)
2082                 LIBS="$ac_save_LIBS"
2083         fi
2084
2085         AC_WIRESHARK_POP_FLAGS
2086 ])