acinclude.m4

   1 dnl Macros that test for specific features.
   2 dnl This file is part of the Autoconf packaging for Wireshark.
   3 dnl Copyright (C) 1998-2000 by Gerald Combs.
   4 dnl
   5 dnl $Id$
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2, or (at your option)
  10 dnl any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20 dnl 02111-1307, USA.
  21 dnl
  22 dnl As a special exception, the Free Software Foundation gives unlimited
  23 dnl permission to copy, distribute and modify the configure scripts that
  24 dnl are the output of Autoconf.  You need not follow the terms of the GNU
  25 dnl General Public License when using or distributing such scripts, even
  26 dnl though portions of the text of Autoconf appear in them.  The GNU
  27 dnl General Public License (GPL) does govern all other use of the material
  28 dnl that constitutes the Autoconf program.
  29 dnl
  30 dnl Certain portions of the Autoconf source text are designed to be copied
  31 dnl (in certain cases, depending on the input) into the output of
  32 dnl Autoconf.  We call these the "data" portions.  The rest of the Autoconf
  33 dnl source text consists of comments plus executable code that decides which
  34 dnl of the data portions to output in any given case.  We call these
  35 dnl comments and executable code the "non-data" portions.  Autoconf never
  36 dnl copies any of the non-data portions into its output.
  37 dnl
  38 dnl This special exception to the GPL applies to versions of Autoconf
  39 dnl released by the Free Software Foundation.  When you make and
  40 dnl distribute a modified version of Autoconf, you may extend this special
  41 dnl exception to the GPL to apply to your modified version as well, *unless*
  42 dnl your modified version has the potential to copy into its output some
  43 dnl of the text that was the non-data portion of the version that you started
  44 dnl with.  (In other words, unless your change moves or copies text from
  45 dnl the non-data portions to the data portions.)  If your modification has
  46 dnl such potential, you must delete any notice of this special exception
  47 dnl to the GPL from your modified version.
  48 dnl
  49 dnl Written by David MacKenzie, with help from
  50 dnl Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
  51 dnl Roland McGrath, Noah Friedman, david d zuhn, and many others.
  52
  53 #
  54 # AC_WIRESHARK_ADD_DASH_L
  55 #
  56 # Add to the variable specified as the first argument a "-L" flag for the
  57 # directory specified as the second argument, and, on Solaris, add a
  58 # "-R" flag for it as well.
  59 #
  60 # XXX - IRIX, and other OSes, may require some flag equivalent to
  61 # "-R" here.
  62 #
  63 AC_DEFUN([AC_WIRESHARK_ADD_DASH_L],
  64 [$1="$$1 -L$2"
  65 case "$host_os" in
  66   solaris*)
  67     $1="$$1 -R$2"
  68   ;;
  69 esac
  70 ])
  71
  72 #
  73 # AC_WIRESHARK_TIMEZONE_ABBREV
  74 #
  75
  76 AC_DEFUN([AC_WIRESHARK_TIMEZONE_ABBREV],
  77 [
  78   AC_CACHE_CHECK([for tm_zone in struct tm],
  79     ac_cv_wireshark_have_tm_zone,
  80     [
  81       AC_TRY_COMPILE(
  82         [#include <time.h>],
  83         [struct tm t; t.tm_zone;],
  84         ac_cv_wireshark_have_tm_zone=yes,
  85         ac_cv_wireshark_have_tm_zone=no)
  86     ])
  87   if test $ac_cv_wireshark_have_tm_zone = yes; then
  88     AC_DEFINE(HAVE_TM_ZONE, 1, [Define if tm_zone field exists in struct tm])
  89   else
  90     AC_CACHE_CHECK([for tzname],
  91       ac_cv_wireshark_have_tzname,
  92       [
  93         AC_TRY_LINK(
  94 [#include <time.h>
  95 #include <stdio.h>],
  96           [printf("%s", tzname[0]);],
  97           ac_cv_wireshark_have_tzname=yes,
  98           ac_cv_wireshark_have_tzname=no)
  99       ])
 100     if test $ac_cv_wireshark_have_tzname = yes; then
 101       AC_DEFINE(HAVE_TZNAME, 1, [Define if tzname array exists])
 102     fi
 103   fi
 104 ])
 105
 106
 107 #
 108 # AC_WIRESHARK_STRUCT_ST_FLAGS
 109 #
 110 dnl AC_STRUCT_ST_BLKSIZE extracted from the file in question,
 111 dnl "acspecific.m4" in GNU Autoconf 2.12, and turned into
 112 dnl AC_WIRESHARK_STRUCT_ST_FLAGS, which checks if "struct stat"
 113 dnl has the 4.4BSD "st_flags" member, and defines HAVE_ST_FLAGS; that's
 114 dnl what's in this file.
 115 dnl Done by Guy Harris <guy@alum.mit.edu> on 2012-06-02.
 116
 117 dnl ### Checks for structure members
 118
 119 AC_DEFUN([AC_WIRESHARK_STRUCT_ST_FLAGS],
 120 [AC_CACHE_CHECK([for st_flags in struct stat], ac_cv_wireshark_struct_st_flags,
 121 [AC_TRY_COMPILE([#include <sys/stat.h>], [struct stat s; s.st_flags;],
 122 ac_cv_wireshark_struct_st_flags=yes, ac_cv_wireshark_struct_st_flags=no)])
 123 if test $ac_cv_wireshark_struct_st_flags = yes; then
 124   AC_DEFINE(HAVE_ST_FLAGS, 1, [Define if st_flags field exists in struct stat])
 125 fi
 126 ])
 127
 128
 129 #
 130 # AC_WIRESHARK_STRUCT_SA_LEN
 131 #
 132 dnl AC_STRUCT_ST_BLKSIZE extracted from the file in question,
 133 dnl "acspecific.m4" in GNU Autoconf 2.12, and turned into
 134 dnl AC_WIRESHARK_STRUCT_SA_LEN, which checks if "struct sockaddr"
 135 dnl has the 4.4BSD "sa_len" member, and defines HAVE_SA_LEN; that's
 136 dnl what's in this file.
 137 dnl Done by Guy Harris <guy@alum.mit.edu> on 1998-11-14.
 138
 139 dnl ### Checks for structure members
 140
 141 AC_DEFUN([AC_WIRESHARK_STRUCT_SA_LEN],
 142 [AC_CACHE_CHECK([for sa_len in struct sockaddr], ac_cv_wireshark_struct_sa_len,
 143 [AC_TRY_COMPILE([#include <sys/types.h>
 144 #include <sys/socket.h>], [struct sockaddr s; s.sa_len;],
 145 ac_cv_wireshark_struct_sa_len=yes, ac_cv_wireshark_struct_sa_len=no)])
 146 if test $ac_cv_wireshark_struct_sa_len = yes; then
 147   AC_DEFINE(HAVE_SA_LEN, 1, [Define if sa_len field exists in struct sockaddr])
 148 fi
 149 ])
 150
 151
 152 #
 153 # AC_WIRESHARK_IPV6_STACK
 154 #
 155 # By Jun-ichiro "itojun" Hagino, <itojun@iijlab.net>
 156 #
 157 AC_DEFUN([AC_WIRESHARK_IPV6_STACK],
 158 [
 159         v6type=unknown
 160         v6lib=none
 161
 162         AC_MSG_CHECKING([ipv6 stack type])
 163         for i in v6d toshiba kame inria zeta linux linux-glibc solaris; do
 164                 case $i in
 165                 v6d)
 166                         AC_EGREP_CPP(yes, [
 167 #include </usr/local/v6/include/sys/types.h>
 168 #ifdef __V6D__
 169 yes
 170 #endif],
 171                                 [v6type=$i; v6lib=v6;
 172                                 v6libdir=/usr/local/v6/lib;
 173                                 #
 174                                 # XXX - this doesn't define INET6;
 175                                 # is that a mistake?
 176                                 #
 177                                 CPPFLAGS="-I/usr/local/v6/include $CPPFLAGS"])
 178                         ;;
 179                 toshiba)
 180                         AC_EGREP_CPP(yes, [
 181 #include <sys/param.h>
 182 #ifdef _TOSHIBA_INET6
 183 yes
 184 #endif],
 185                                 [v6type=$i; v6lib=inet6;
 186                                 v6libdir=/usr/local/v6/lib;
 187                                 AC_DEFINE(INET6, 1, [Define if the platform supports IPv6])])
 188                         ;;
 189                 kame)
 190                         AC_EGREP_CPP(yes, [
 191 #include <netinet/in.h>
 192 #ifdef __KAME__
 193 yes
 194 #endif],
 195                                 [v6type=$i; v6lib=inet6;
 196                                 v6libdir=/usr/local/v6/lib;
 197                                 AC_DEFINE(INET6, 1, [Define if the platform supports IPv6])])
 198                         ;;
 199                 inria)
 200                         AC_EGREP_CPP(yes, [
 201 #include <netinet/in.h>
 202 #ifdef IPV6_INRIA_VERSION
 203 yes
 204 #endif],
 205                                 [v6type=$i;
 206                                 AC_DEFINE(INET6, 1, [Define if the platform supports IPv6])])
 207                         ;;
 208                 zeta)
 209                         AC_EGREP_CPP(yes, [
 210 #include <sys/param.h>
 211 #ifdef _ZETA_MINAMI_INET6
 212 yes
 213 #endif],
 214                                 [v6type=$i; v6lib=inet6;
 215                                 v6libdir=/usr/local/v6/lib;
 216                                 AC_DEFINE(INET6, 1, [Define if the platform supports IPv6])])
 217                         ;;
 218                 linux)
 219                         if test -d /usr/inet6; then
 220                                 v6type=$i
 221                                 v6lib=inet6
 222                                 v6libdir=/usr/inet6
 223                                 AC_DEFINE(INET6, 1, [Define if the platform supports IPv6])
 224                         fi
 225                         ;;
 226                 linux-glibc)
 227                         AC_EGREP_CPP(yes, [
 228 #include <features.h>
 229 #if defined(__GLIBC__) && defined(__GLIBC_MINOR__)
 230 #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || __GLIBC__ > 2
 231 yes
 232 #endif
 233 #endif],
 234                         [v6type=$i; v6lib=inet6;
 235                         AC_DEFINE(INET6, 1, [Define if the platform supports IPv6])])
 236                         ;;
 237                 solaris)
 238                         #
 239                         # There's nothing we can check for in the header
 240                         # file, so we just check for SunOS (pre-SunOS 5
 241                         # versions didn't include IPv6 support, so we
 242                         # just check the OS, not the version).
 243                         #
 244                         if test "`uname -s`" = "SunOS"; then
 245                                 v6type=$i
 246                                 v6lib=inet6
 247                                 AC_DEFINE(INET6, 1, [Define if the platform supports IPv6])
 248                         fi
 249                         ;;
 250                 esac
 251                 if test "$v6type" != "unknown"; then
 252                         break
 253                 fi
 254         done
 255
 256         if test "$v6lib" != "none"; then
 257                 for dir in $v6libdir /usr/local/v6/lib /usr/local/lib; do
 258                         if test -d $dir -a -f $dir/lib$v6lib.a; then
 259                                 LIBS="-L$dir $LIBS -l$v6lib"
 260                                 break
 261                         fi
 262                 done
 263                 enable_ipv6="yes"
 264         else
 265                 enable_ipv6="no"
 266         fi
 267         AC_MSG_RESULT(["$v6type, $v6lib"])
 268 ])
 269
 270 #
 271 # AC_WIRESHARK_GETHOSTBY_LIB_CHECK
 272 #
 273 # Checks whether we need "-lnsl" to get "gethostby*()", which we use
 274 # in "resolv.c".
 275 #
 276 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 277 # GNU Autoconf 2.13; the comment came from there.
 278 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 279 #
 280 AC_DEFUN([AC_WIRESHARK_GETHOSTBY_LIB_CHECK],
 281 [
 282     # msh@cis.ufl.edu says -lnsl (and -lsocket) are needed for his 386/AT,
 283     # to get the SysV transport functions.
 284     # chad@anasazi.com says the Pyramid MIS-ES running DC/OSx (SVR4)
 285     # needs -lnsl.
 286     # The nsl library prevents programs from opening the X display
 287     # on Irix 5.2, according to dickey@clark.net.
 288     AC_CHECK_FUNC(gethostbyname, ,
 289         AC_CHECK_LIB(nsl, gethostbyname, NSL_LIBS="-lnsl"))
 290     AC_SUBST(NSL_LIBS)
 291 ])
 292
 293 #
 294 # AC_WIRESHARK_SOCKET_LIB_CHECK
 295 #
 296 # Checks whether we need "-lsocket" to get "socket()", which is used
 297 # by libpcap on some platforms - and, in effect, "gethostby*()" on
 298 # most if not all platforms (so that it can use NIS or DNS or...
 299 # to look up host names).
 300 #
 301 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 302 # GNU Autoconf 2.13; the comment came from there.
 303 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 304 #
 305 # We use "connect" because that's what AC_PATH_XTRA did.
 306 #
 307 AC_DEFUN([AC_WIRESHARK_SOCKET_LIB_CHECK],
 308 [
 309     # lieder@skyler.mavd.honeywell.com says without -lsocket,
 310     # socket/setsockopt and other routines are undefined under SCO ODT
 311     # 2.0.  But -lsocket is broken on IRIX 5.2 (and is not necessary
 312     # on later versions), says simon@lia.di.epfl.ch: it contains
 313     # gethostby* variants that don't use the nameserver (or something).
 314     # -lsocket must be given before -lnsl if both are needed.
 315     # We assume that if connect needs -lnsl, so does gethostbyname.
 316     AC_CHECK_FUNC(connect, ,
 317       AC_CHECK_LIB(socket, connect, SOCKET_LIBS="-lsocket",
 318                 AC_MSG_ERROR(Function 'socket' not found.), $NSL_LIBS))
 319     AC_SUBST(SOCKET_LIBS)
 320 ])
 321
 322 #
 323 # AC_WIRESHARK_BREAKLOOP_TRY_LINK
 324 #
 325 AC_DEFUN([AC_WIRESHARK_PCAP_BREAKLOOP_TRY_LINK],
 326 [
 327   AC_LINK_IFELSE(
 328   [
 329       AC_LANG_SOURCE(
 330       [[
 331 #       include <pcap.h>
 332         int main(void)
 333         {
 334           pcap_t  *pct = NULL;
 335           pcap_breakloop(pct);
 336           return 0;
 337         }
 338       ]])
 339   ],
 340   [
 341     ws_breakloop_compiled=yes
 342   ],
 343   [
 344     ws_breakloop_compiled=no
 345   ])
 346 ])
 347
 348
 349
 350 #
 351 # AC_WIRESHARK_PCAP_CHECK
 352 #
 353 AC_DEFUN([AC_WIRESHARK_PCAP_CHECK],
 354 [
 355         if test -z "$pcap_dir"
 356         then
 357           # Pcap header checks
 358           # XXX need to set a var AC_CHECK_HEADER(pcap.h,,)
 359
 360           #
 361           # The user didn't specify a directory in which libpcap resides.
 362           # First, look for a pcap-config script.
 363           #
 364           AC_PATH_PROG(PCAP_CONFIG, pcap-config)
 365
 366           if test -n "$PCAP_CONFIG" ; then
 367             #
 368             # Found it.
 369             #
 370             # Now check whether it's the libpcap 1.0 version, which
 371             # put a space after "-L" - on some platforms, that doesn't
 372             # work.
 373             #
 374             AC_MSG_CHECKING(for broken pcap-config)
 375             case "`\"$PCAP_CONFIG\" --libs`" in
 376
 377             "-L "*)
 378               #
 379               # Space after -L.  Pretend pcap-config doesn't exist.
 380               #
 381               AC_MSG_RESULT(yes)
 382               PCAP_CONFIG=""
 383               ;;
 384
 385             *)
 386               #
 387               # No space after -L.
 388               #
 389               AC_MSG_RESULT(no)
 390               ;;
 391             esac
 392           fi
 393           if test -n "$PCAP_CONFIG" ; then
 394             #
 395             # Found it, and it's usable; use it to get the include flags
 396             # for libpcap.
 397             #
 398             CPPFLAGS="$CPPFLAGS `\"$PCAP_CONFIG\" --cflags`"
 399           else
 400             #
 401             # Didn't find it; we have to look for libpcap ourselves.
 402             # We assume that the current library search path will work,
 403             # but we may have to look for the header in a "pcap"
 404             # subdirectory of "/usr/include" or "/usr/local/include",
 405             # as some systems apparently put "pcap.h" in a "pcap"
 406             # subdirectory, and we also check "$prefix/include" - and
 407             # "$prefix/include/pcap", in case $prefix is set to
 408             # "/usr/include" or "/usr/local/include".
 409             #
 410             # XXX - should we just add "$prefix/include" to the include
 411             # search path and "$prefix/lib" to the library search path?
 412             #
 413             AC_MSG_CHECKING(for extraneous pcap header directories)
 414             found_pcap_dir=""
 415             pcap_dir_list="/usr/include/pcap $prefix/include/pcap $prefix/include"
 416             if test "x$ac_cv_enable_usr_local" = "xyes" ; then
 417               pcap_dir_list="$pcap_dir_list /usr/local/include/pcap"
 418             fi
 419             for pcap_dir in $pcap_dir_list
 420             do
 421               if test -d $pcap_dir ; then
 422                 if test x$pcap_dir != x/usr/include -a x$pcap_dir != x/usr/local/include ; then
 423                     CPPFLAGS="$CPPFLAGS -I$pcap_dir"
 424                 fi
 425                 found_pcap_dir=" $found_pcap_dir -I$pcap_dir"
 426                 break
 427               fi
 428             done
 429
 430             if test "$found_pcap_dir" != "" ; then
 431               AC_MSG_RESULT(found --$found_pcap_dir added to CFLAGS)
 432             else
 433               AC_MSG_RESULT(not found)
 434             fi
 435           fi
 436         else
 437           #
 438           # The user specified a directory in which libpcap resides,
 439           # so add the "include" subdirectory of that directory to
 440           # the include file search path and the "lib" subdirectory
 441           # of that directory to the library search path.
 442           #
 443           # XXX - if there's also a libpcap in a directory that's
 444           # already in CPPFLAGS or LDFLAGS, this won't make us find
 445           # the version in the specified directory, as the compiler
 446           # and/or linker will search that other directory before it
 447           # searches the specified directory.
 448           #
 449           CPPFLAGS="$CPPFLAGS -I$pcap_dir/include"
 450           AC_WIRESHARK_ADD_DASH_L(LDFLAGS, $pcap_dir/lib)
 451         fi
 452
 453         # Pcap header check
 454         AC_CHECK_HEADER(pcap.h,,
 455             AC_MSG_ERROR([[Header file pcap.h not found; if you installed libpcap
 456 from source, did you also do \"make install-incl\", and if you installed a
 457 binary package of libpcap, is there also a developer's package of libpcap,
 458 and did you also install that package?]]))
 459
 460         if test -n "$PCAP_CONFIG" ; then
 461           #
 462           # We have pcap-config; we assume that means we have libpcap
 463           # installed and that pcap-config will tell us whatever
 464           # libraries libpcap needs.
 465           #
 466           if test x$enable_static = xyes; then
 467             PCAP_LIBS="`\"$PCAP_CONFIG\" --libs --static`"
 468           else
 469             PCAP_LIBS="`\"$PCAP_CONFIG\" --libs`"
 470           fi
 471           AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 472         else
 473           #
 474           # Check to see if we find "pcap_open_live" in "-lpcap".
 475           # Also check for various additional libraries that libpcap might
 476           # require.
 477           #
 478           AC_CHECK_LIB(pcap, pcap_open_live,
 479             [
 480               PCAP_LIBS=-lpcap
 481               AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 482             ], [
 483               ac_wireshark_extras_found=no
 484               ac_save_LIBS="$LIBS"
 485               for extras in "-lcfg -lodm" "-lpfring"
 486               do
 487                 AC_MSG_CHECKING([for pcap_open_live in -lpcap with $extras])
 488                 LIBS="-lpcap $extras"
 489                 #
 490                 # XXX - can't we use AC_CHECK_LIB here?
 491                 #
 492                 AC_TRY_LINK(
 493                     [
 494 #       include <pcap.h>
 495                     ],
 496                     [
 497         pcap_open_live(NULL, 0, 0, 0, NULL);
 498                     ],
 499                     [
 500                         ac_wireshark_extras_found=yes
 501                         AC_MSG_RESULT([yes])
 502                         PCAP_LIBS="-lpcap $extras"
 503                         AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 504                     ],
 505                     [
 506                         AC_MSG_RESULT([no])
 507                     ])
 508                 if test x$ac_wireshark_extras_found = xyes
 509                 then
 510                     break
 511                 fi
 512               done
 513               if test x$ac_wireshark_extras_found = xno
 514               then
 515                 AC_MSG_ERROR([Can't link with library libpcap.])
 516               fi
 517               LIBS=$ac_save_LIBS
 518             ], $SOCKET_LIBS $NSL_LIBS)
 519         fi
 520         AC_SUBST(PCAP_LIBS)
 521
 522         #
 523         # Check whether various variables and functions are defined by
 524         # libpcap.
 525         #
 526         ac_save_LIBS="$LIBS"
 527         LIBS="$PCAP_LIBS $SOCKET_LIBS $NSL_LIBS $LIBS"
 528         AC_CHECK_FUNCS(pcap_open_dead pcap_freecode)
 529         #
 530         # pcap_breakloop may be present in the library but not declared
 531         # in the pcap.h header file.  If it's not declared in the header
 532         # file, attempts to use it will get warnings, and, if we're
 533         # building with warnings treated as errors, that warning will
 534         # cause compilation to fail.
 535         #
 536         # We are therefore first testing whether the function is present
 537         # and then, if we're compiling with warnings as errors, testing
 538         # whether it is usable.  It is usable if it compiles without
 539         # a -Wimplicit warning (the "compile with warnings as errors"
 540         # option requires GCC). If it is not usable, we fail and tell
 541         # the user that the pcap.h header needs to be updated.
 542         #
 543         # Ceteris paribus, this should only happen with Mac OS X 10.3[.x] which
 544         # can have an up-to-date pcap library without the corresponding pcap
 545         # header.
 546         #
 547         # However, it might also happen on some others OSes with some erroneous
 548         # system manipulations where multiple versions of libpcap might co-exist
 549         # e.g. hand made symbolic link from libpcap.so -> libpcap.so.0.8 but
 550         # having the pcap header version 0.7.
 551         #
 552         AC_MSG_CHECKING([whether pcap_breakloop is present])
 553         ac_CFLAGS_saved="$CFLAGS"
 554         AC_WIRESHARK_PCAP_BREAKLOOP_TRY_LINK
 555         if test "x$ws_breakloop_compiled" = "xyes"; then
 556           AC_MSG_RESULT(yes)
 557           AC_DEFINE(HAVE_PCAP_BREAKLOOP, 1, [Define if pcap_breakloop is known])
 558           if test "x$with_warnings_as_errors" = "xyes"; then
 559             AC_MSG_CHECKING([whether pcap_breakloop is usable])
 560             CFLAGS="$CFLAGS -Werror -Wimplicit"
 561             AC_WIRESHARK_PCAP_BREAKLOOP_TRY_LINK
 562             if test "x$ws_breakloop_compiled" = "xyes"; then
 563               AC_MSG_RESULT(yes)
 564             else
 565               AC_MSG_RESULT(no)
 566               AC_MSG_ERROR(
 567 [Your pcap library is more recent than your pcap header.
 568 As you are building with compiler warnings treated as errors, Wireshark
 569 won't be able to use functions not declared in that header.
 570 If you wish to build with compiler warnings treated as errors, You should
 571 install a newer version of the header file.])
 572             fi
 573             CFLAGS="$ac_CFLAGS_saved"
 574           fi
 575         else
 576           AC_MSG_RESULT(no)
 577         fi
 578
 579         #
 580         # Later versions of Mac OS X 10.3[.x] ship a pcap.h that
 581         # doesn't define pcap_if_t but ship an 0.8[.x] libpcap,
 582         # so the library has "pcap_findalldevs()", but pcap.h
 583         # doesn't define "pcap_if_t" so you can't actually *use*
 584         # "pcap_findalldevs()".
 585         #
 586         # That even appears to be true of systems shipped with
 587         # 10.3.4, so it doesn't appear only to be a case of
 588         # Software Update not updating header files.
 589         #
 590         # (You can work around this by installing the 0.8 header
 591         # files.)
 592         #
 593         AC_CACHE_CHECK([whether pcap_findalldevs is present and usable],
 594           [ac_cv_func_pcap_findalldevs],
 595           [
 596             AC_LINK_IFELSE(
 597               [
 598                 AC_LANG_SOURCE(
 599                   [[
 600                     #include <pcap.h>
 601                     main()
 602                     {
 603                       pcap_if_t *devpointer;
 604                       char errbuf[1];
 605
 606                       pcap_findalldevs(&devpointer, errbuf);
 607                     }
 608                   ]])
 609               ],
 610               [
 611                 ac_cv_func_pcap_findalldevs=yes
 612               ],
 613               [
 614                 ac_cv_func_pcap_findalldevs=no
 615               ])
 616           ])
 617         #
 618         # Don't check for other new routines that showed up after
 619         # "pcap_findalldevs()" if we don't have a usable
 620         # "pcap_findalldevs()", so we don't end up using them if the
 621         # "pcap.h" is crufty and old and doesn't declare them.
 622         #
 623         if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 624           AC_DEFINE(HAVE_PCAP_FINDALLDEVS, 1,
 625            [Define to 1 if you have the `pcap_findalldevs' function and a pcap.h that declares pcap_if_t.])
 626           AC_CHECK_FUNCS(pcap_datalink_val_to_name pcap_datalink_name_to_val)
 627           AC_CHECK_FUNCS(pcap_datalink_val_to_description)
 628           AC_CHECK_FUNCS(pcap_list_datalinks pcap_set_datalink pcap_lib_version)
 629           AC_CHECK_FUNCS(pcap_get_selectable_fd pcap_free_datalinks)
 630           AC_CHECK_FUNCS(pcap_create bpf_image pcap_set_tstamp_precision)
 631         fi
 632         LIBS="$ac_save_LIBS"
 633 ])
 634
 635 AC_DEFUN([AC_WIRESHARK_PCAP_REMOTE_CHECK],
 636 [
 637     ac_save_LIBS="$LIBS"
 638     LIBS="$PCAP_LIBS $SOCKET_LIBS $NSL_LIBS $LIBS"
 639     AC_DEFINE(HAVE_REMOTE, 1, [Define to 1 to enable remote
 640               capturing feature in WinPcap library])
 641     AC_CHECK_FUNCS(pcap_open)
 642     if test $ac_cv_func_pcap_open = "yes" ; then
 643         AC_DEFINE(HAVE_PCAP_REMOTE, 1,
 644             [Define to 1 if you have WinPcap remote capturing support and prefer to use these new API features.])
 645     fi
 646     AC_CHECK_FUNCS(pcap_setsampling)
 647     LIBS="$ac_save_LIBS"
 648 ])
 649
 650 #
 651 # AC_WIRESHARK_ZLIB_CHECK
 652 #
 653 AC_DEFUN([AC_WIRESHARK_ZLIB_CHECK],
 654 [
 655         if test "x$zlib_dir" != "x"
 656         then
 657           #
 658           # The user specified a directory in which zlib resides,
 659           # so add the "include" subdirectory of that directory to
 660           # the include file search path and the "lib" subdirectory
 661           # of that directory to the library search path.
 662           #
 663           # XXX - if there's also a zlib in a directory that's
 664           # already in CPPFLAGS or LDFLAGS, this won't make us find
 665           # the version in the specified directory, as the compiler
 666           # and/or linker will search that other directory before it
 667           # searches the specified directory.
 668           #
 669           wireshark_save_CPPFLAGS="$CPPFLAGS"
 670           CPPFLAGS="$CPPFLAGS -I$zlib_dir/include"
 671           wireshark_save_LIBS="$LIBS"
 672           AC_WIRESHARK_ADD_DASH_L(LIBS, $zlib_dir/lib)
 673         fi
 674
 675         #
 676         # Make sure we have "zlib.h".  If we don't, it means we probably
 677         # don't have zlib, so don't use it.
 678         #
 679         AC_CHECK_HEADER(zlib.h,,
 680           [
 681             if test "x$zlib_dir" != "x"
 682             then
 683               #
 684               # The user used "--with-zlib=" to specify a directory
 685               # containing zlib, but we didn't find the header file
 686               # there; that either means they didn't specify the
 687               # right directory or are confused about whether zlib
 688               # is, in fact, installed.  Report the error and give up.
 689               #
 690               AC_MSG_ERROR([zlib header not found in directory specified in --with-zlib])
 691             else
 692               if test "x$want_zlib" = "xyes"
 693               then
 694                 #
 695                 # The user tried to force us to use the library, but we
 696                 # couldn't find the header file; report an error.
 697                 #
 698                 AC_MSG_ERROR(Header file zlib.h not found.)
 699               else
 700                 #
 701                 # We couldn't find the header file; don't use the
 702                 # library, as it's probably not present.
 703                 #
 704                 want_zlib=no
 705               fi
 706             fi
 707           ])
 708
 709         if test "x$want_zlib" != "xno"
 710         then
 711                 #
 712                 # Well, we at least have the zlib header file.
 713                 # We link with zlib to support uncompression of
 714                 # gzipped network traffic, e.g. in an HTTP request
 715                 # or response body.
 716                 #
 717                 if test "x$zlib_dir" != "x"
 718                 then
 719                         #
 720                         # Put the "-L" flags for zlib at the beginning
 721                         # of LIBS.
 722                         #
 723                         LIBS=""
 724                         AC_WIRESHARK_ADD_DASH_L(LIBS, $zlib_dir/lib)
 725                         LIBS="$LIBS -lz $wireshark_save_LIBS"
 726                 else
 727                         LIBS="-lz $LIBS"
 728                 fi
 729                 AC_DEFINE(HAVE_LIBZ, 1, [Define to use libz library])
 730
 731                 #
 732                 # Check for "inflatePrime()" in zlib, which we need
 733                 # in order to read compressed capture files.
 734                 #
 735                 AC_CHECK_FUNCS(inflatePrime)
 736
 737                 if test "x$ac_cv_func_inflatePrime" = "xyes" ; then
 738                         #
 739                         # Now check for "inflatePrime()" in zlib when
 740                         # linking with the linker flags for GTK+
 741                         # applications; people often grab XFree86 source
 742                         # and build and install it on their systems,
 743                         # and they appear sometimes to misconfigure
 744                         # XFree86 so that, even on systems with zlib,
 745                         # it assumes there is no zlib, so the XFree86
 746                         # build process builds and installs its
 747                         # own zlib in the X11 library directory.
 748                         #
 749                         # The zlib in at least some versions of XFree86
 750                         # is an older version that may lack "inflatePrime()",
 751                         # and that's the zlib with which Wireshark gets
 752                         # linked, so the build of Wireshark fails.
 753                         #
 754                         AC_MSG_CHECKING([for inflatePrime missing when linking with X11])
 755                         AC_TRY_LINK_FUNC(inflatePrime, AC_MSG_RESULT(no),
 756                           [
 757                             AC_MSG_RESULT(yes)
 758                             AC_MSG_ERROR(old zlib found when linking with X11 - get rid of old zlib.)
 759                           ])
 760                 fi
 761         else
 762                 #
 763                 # Restore the versions of CPPFLAGS and LIBS before
 764                 # we added the "-with-zlib=" directory, as we didn't
 765                 # actually find zlib there.
 766                 #
 767                 CPPFLAGS="$wireshark_save_CPPFLAGS"
 768                 LIBS="$wireshark_save_LIBS"
 769                 want_zlib=no
 770         fi
 771 ])
 772
 773 #
 774 # AC_WIRESHARK_LIBLUA_CHECK
 775 #
 776 AC_DEFUN([AC_WIRESHARK_LIBLUA_CHECK],[
 777         lua_ver=5.2
 778         if test "x$lua_dir" != "x"
 779         then
 780                 #
 781                 # The user specified a directory in which liblua resides,
 782                 # so add the "include" subdirectory of that directory to
 783                 # the include file search path and the "lib" subdirectory
 784                 # of that directory to the library search path.
 785                 #
 786                 # XXX - if there's also a liblua in a directory that's
 787                 # already in CPPFLAGS or LDFLAGS, this won't make us find
 788                 # the version in the specified directory, as the compiler
 789                 # and/or linker will search that other directory before it
 790                 # searches the specified directory.
 791                 #
 792                 wireshark_save_CPPFLAGS="$CPPFLAGS"
 793                 CPPFLAGS="$CPPFLAGS -I$lua_dir/include"
 794                 wireshark_save_LIBS="$LIBS"
 795                 LIBS="$LIBS -L$lua_dir/lib -llua -lm"
 796                 wireshark_save_LDFLAGS="$LDFLAGS"
 797                 LDFLAGS="$LDFLAGS -L$lua_dir/lib"
 798
 799                 #
 800                 # Determine Lua version by reading the LUA_VERSION_NUM definition
 801                 # from lua.h under the given Lua directory. The value is 501 for
 802                 # Lua 5.1, 502 for Lua 5.2, etc.
 803                 #
 804                 AC_MSG_CHECKING(Lua version)
 805                 [[ -d "$lua_dir/include" ]] && grep -rq 'LUA_VERSION_NUM.*501' "$lua_dir/include" && lua_ver=5.1
 806                 AC_MSG_RESULT(Lua ${lua_ver})
 807         else
 808                 #
 809                 # The user specified no directory in which liblua resides,
 810                 # we try to find out the lua version by looking at pathnames
 811                 # and we just add "-llua -lliblua" to the used libs.
 812                 #
 813                 AC_MSG_CHECKING(Lua version)
 814                 for i in 5.0 5.1 5.2
 815                 do
 816                         [[ -d "/usr/include/lua$i" ]] && lua_ver=$i
 817                 done
 818                 AC_MSG_RESULT(Lua ${lua_ver})
 819                 wireshark_save_CPPFLAGS="$CPPFLAGS"
 820                 wireshark_save_LDFLAGS="$LDFLAGS"
 821                 wireshark_save_LIBS="$LIBS"
 822                 LIBS="$LIBS -llua -lm"
 823         fi
 824
 825         #
 826         # Make sure we have "lua.h", "lualib.h" and "lauxlib.h".  If we don't, it means we probably
 827         # don't have liblua, so don't use it.
 828         #
 829         AC_CHECK_HEADERS(lua.h lualib.h lauxlib.h,,
 830         [
 831                 AC_CHECK_HEADERS(lua${lua_ver}/lua.h lua${lua_ver}/lualib.h lua${lua_ver}/lauxlib.h,
 832                 [
 833                         if test "x$lua_dir" != "x"
 834                         then
 835                                 LUA_INCLUDES="-I$lua_dir/include/lua${lua_ver}"
 836                         else
 837                                 #
 838                                 # The user didn't specify a directory in which liblua resides;
 839                                 # we must look for the headers in a "lua${lua_ver}" subdirectory of
 840                                 # "/usr/include", "/usr/local/include", or "$prefix/include"
 841                                 # as some systems apparently put the headers in a "lua${lua_ver}"
 842                                 # subdirectory.
 843                                 AC_MSG_CHECKING(for extraneous lua header directories)
 844                                 found_lua_dir=""
 845                                 lua_dir_list="/usr/include/lua${lua_ver} $prefix/include/lua${lua_ver}"
 846                                 if test "x$ac_cv_enable_usr_local" = "xyes"
 847                                 then
 848                                         lua_dir_list="$lua_dir_list /usr/local/include/lua${lua_ver}"
 849                                 fi
 850                                 for lua_dir_ent in $lua_dir_list
 851                                 do
 852                                         if test -d $lua_dir_ent
 853                                         then
 854                                                 LUA_INCLUDES="-I$lua_dir_ent"
 855                                                 found_lua_dir="$lua_dir_ent"
 856                                                 break
 857                                         fi
 858                                 done
 859
 860                                 if test "x$found_lua_dir" != "x"
 861                                 then
 862                                         AC_MSG_RESULT(found -- $found_lua_dir)
 863                                 else
 864                                         AC_MSG_RESULT(not found)
 865                                         #
 866                                         # Restore the versions of CPPFLAGS,
 867                                         # LDFLAGS, and LIBS before we added the
 868                                         # "--with-lua=" directory, as we didn't
 869                                         # actually find lua there.
 870                                         #
 871                                         CPPFLAGS="$wireshark_save_CPPFLAGS"
 872                                         LDFLAGS="$wireshark_save_LDFLAGS"
 873                                         LIBS="$wireshark_save_LIBS"
 874                                         LUA_LIBS=""
 875                                         if test "x$want_lua" = "xyes"
 876                                         then
 877                                                 # we found lua${lua_ver}/lua.h, but we don't know which include dir contains it
 878                                                 AC_MSG_ERROR(Header file lua.h was found as lua${lua_ver}/lua.h but we can't locate the include directory. Please set the DIR for the --with-lua configure parameter.)
 879                                         else
 880                                                 #
 881                                                 # We couldn't find the header file; don't use the
 882                                                 # library, as it's probably not present.
 883                                                 #
 884                                                 want_lua=no
 885                                         fi
 886                                 fi
 887                         fi
 888                 ],
 889                 [
 890                         #
 891                         # Restore the versions of CPPFLAGS, LDFLAGS,
 892                         # and LIBS before we added the "--with-lua="
 893                         # directory, as we didn't actually find lua
 894                         # there.
 895                         #
 896                         CPPFLAGS="$wireshark_save_CPPFLAGS"
 897                         LDFLAGS="$wireshark_save_LDFLAGS"
 898                         LIBS="$wireshark_save_LIBS"
 899                         LUA_LIBS=""
 900                         if test "x$lua_dir" != "x"
 901                         then
 902                                 #
 903                                 # The user used "--with-lua=" to specify a directory
 904                                 # containing liblua, but we didn't find the header file
 905                                 # there; that either means they didn't specify the
 906                                 # right directory or are confused about whether liblua
 907                                 # is, in fact, installed.  Report the error and give up.
 908                                 #
 909                                 AC_MSG_ERROR([liblua header not found in directory specified in --with-lua])
 910                         else
 911                                 if test "x$want_lua" = "xyes"
 912                                 then
 913                                         #
 914                                         # The user tried to force us to use the library, but we
 915                                         # couldn't find the header file; report an error.
 916                                         #
 917                                         AC_MSG_ERROR(Header file lua.h not found.)
 918                                 else
 919                                         #
 920                                         # We couldn't find the header file; don't use the
 921                                         # library, as it's probably not present.
 922                                         #
 923                                         want_lua=no
 924                                 fi
 925                         fi
 926                 ])
 927         ])
 928
 929         if test "x$want_lua" != "xno"
 930         then
 931                 #
 932                 # Well, we at least have the lua header file.
 933                 #
 934                 # let's check if the libs are there
 935                 #
 936
 937                 # At least on Suse 9.3 systems, liblualib needs linking
 938                 # against libm.
 939                 LIBS="$LIBS $LUA_LIBS -lm"
 940
 941                 AC_CHECK_LIB(lua, luaL_openlibs,
 942                 [
 943                         #
 944                         #  Lua found
 945                         #
 946                         if test "x$lua_dir" != "x"
 947                         then
 948                                 #
 949                                 # Put the "-I" and "-L" flags for lua into
 950                                 # LUA_INCLUDES and LUA_LIBS, respectively.
 951                                 #
 952                                 LUA_LIBS="-L$lua_dir/lib -llua -lm"
 953                                 LUA_INCLUDES="-I$lua_dir/include"
 954                         else
 955                                 LUA_LIBS="-llua -lm"
 956                                 LUA_INCLUDES=""
 957                         fi
 958                         AC_DEFINE(HAVE_LUA, 1, [Define to use Lua])
 959                         want_lua=yes
 960
 961                 ],[
 962                         #
 963                         # We could not find the libs, maybe we have version number in the lib name
 964                         #
 965
 966                         LIBS="$wireshark_save_LIBS -llua${lua_ver} -lm"
 967
 968                         AC_CHECK_LIB(lua${lua_ver}, luaL_openlibs,
 969                         [
 970                             #
 971                             #  Lua found
 972                             #
 973                             LUA_LIBS=" -llua${lua_ver} -lm"
 974                             AC_DEFINE(HAVE_LUA, 1, [Define to use Lua])
 975                             want_lua=yes
 976                         ],[
 977                                 #
 978                                 # Restore the versions of CPPFLAGS, LDFLAGS,
 979                                 # and LIBS before we added the "--with-lua="
 980                                 # directory, as we didn't actually find lua
 981                                 # there.
 982                                 #
 983                                 CPPFLAGS="$wireshark_save_CPPFLAGS"
 984                                 LDFLAGS="$wireshark_save_LDFLAGS"
 985                                 LIBS="$wireshark_save_LIBS"
 986                                 LUA_LIBS=""
 987                                 # User requested --with-lua but it isn't available
 988                                 if test "x$want_lua" = "xyes"
 989                                 then
 990                                         AC_MSG_ERROR(Linking with liblua failed.)
 991                                 fi
 992                                 want_lua=no
 993                         ])
 994                 ])
 995
 996         CPPFLAGS="$wireshark_save_CPPFLAGS"
 997         LDFLAGS="$wireshark_save_LDFLAGS"
 998         LIBS="$wireshark_save_LIBS"
 999         AC_SUBST(LUA_LIBS)
1000         AC_SUBST(LUA_INCLUDES)
1001
1002         fi
1003 ])
1004
1005 #
1006 # AC_WIRESHARK_LIBPORTAUDIO_CHECK
1007 #
1008 AC_DEFUN([AC_WIRESHARK_LIBPORTAUDIO_CHECK],[
1009
1010         if test "x$portaudio_dir" != "x"
1011         then
1012                 #
1013                 # The user specified a directory in which libportaudio
1014                 # resides, so add the "include" subdirectory of that directory to
1015                 # the include file search path and the "lib" subdirectory
1016                 # of that directory to the library search path.
1017                 #
1018                 # XXX - if there's also a libportaudio in a directory that's
1019                 # already in CPPFLAGS or LDFLAGS, this won't make us find
1020                 # the version in the specified directory, as the compiler
1021                 # and/or linker will search that other directory before it
1022                 # searches the specified directory.
1023                 #
1024                 wireshark_save_CPPFLAGS="$CPPFLAGS"
1025                 CPPFLAGS="$CPPFLAGS -I$portaudio_dir/include"
1026                 wireshark_save_LIBS="$LIBS"
1027                 LIBS="$LIBS -L$portaudio_dir/lib -lportaudio"
1028                 wireshark_save_LDFLAGS="$LDFLAGS"
1029                 LDFLAGS="$LDFLAGS -L$portaudio_dir/lib"
1030         else
1031                 #
1032                 # The user specified no directory in which libportaudio resides,
1033                 # so just add "-lportaudio" to the used libs.
1034                 #
1035                 wireshark_save_CPPFLAGS="$CPPFLAGS"
1036                 wireshark_save_LDFLAGS="$LDFLAGS"
1037                 wireshark_save_LIBS="$LIBS"
1038                 LIBS="$LIBS -lportaudio"
1039         fi
1040
1041         #
1042         # Make sure we have "portaudio.h".  If we don't, it means we probably
1043         # don't have libportaudio, so don't use it.
1044         #
1045         AC_CHECK_HEADERS(portaudio.h,,
1046         [
1047                 if test "x$portaudio_dir" != "x"
1048                 then
1049                         #
1050                         # The user used "--with-portaudio=" to specify a directory
1051                         # containing libportaudio, but we didn't find the header file
1052                         # there; that either means they didn't specify the
1053                         # right directory or are confused about whether libportaudio
1054                         # is, in fact, installed.  Report the error and give up.
1055                         #
1056                         AC_MSG_ERROR([libportaudio header not found in directory specified in --with-portaudio])
1057                 else
1058                         CPPFLAGS="$wireshark_save_CPPFLAGS"
1059                         LDFLAGS="$wireshark_save_LDFLAGS"
1060                         LIBS="$wireshark_save_LIBS"
1061                         PORTAUDIO_LIBS=""
1062                         if test "x$want_portaudio" = "xyes"
1063                         then
1064                                 #
1065                                 # The user tried to force us to use the library, but we
1066                                 # couldn't find the header file; report an error.
1067                                 #
1068                                 AC_MSG_ERROR(Header file portaudio.h not found.)
1069                         else
1070                                 #
1071                                 # We couldn't find the header file; don't use the
1072                                 # library, as it's probably not present.
1073                                 #
1074                                 want_portaudio=no
1075                         fi
1076                 fi
1077         ])
1078
1079         #
1080         # Check whether we have the right version of portaudio
1081         #
1082         if test "x$want_portaudio" != "xno"
1083         then
1084                 AC_CHECK_TYPE(PortAudioStream,
1085                 AC_DEFINE(PORTAUDIO_API_1, 1, [Define if we are using version of of the Portaudio library API]),
1086                 ,
1087                 [#include <portaudio.h>])
1088         fi
1089
1090         if test "x$want_portaudio" != "xno"
1091         then
1092                 #
1093                 # Well, we at least have the portaudio header file.
1094                 #
1095                 # let's check if the libs are there
1096                 #
1097
1098                 AC_CHECK_LIB(portaudio, Pa_Initialize,
1099                 [
1100                         if test "x$portaudio_dir" != "x"
1101                         then
1102                                 #
1103                                 # Put the "-I" and "-L" flags for portaudio
1104                                 # into PORTAUDIO_INCLUDES and PORTAUDIO_LIBS,
1105                                 # respectively.
1106                                 #
1107                                 PORTAUDIO_LIBS="-L$portaudio_dir/lib -lportaudio"
1108                                 PORTAUDIO_INCLUDES="-I$portaudio_dir/include"
1109                         else
1110                                 PORTAUDIO_LIBS="-lportaudio"
1111                                 PORTAUDIO_INCLUDES=""
1112                         fi
1113                         AC_DEFINE(HAVE_LIBPORTAUDIO, 1, [Define to use libportaudio library])
1114                         want_portaudio=yes
1115                 ],[
1116                         #
1117                         # Restore the versions of CPPFLAGS, LDFLAGS, and
1118                         # LIBS before we added the "--with-portaudio="
1119                         # directory, as we didn't actually find portaudio
1120                         # there.
1121                         #
1122                         CPPFLAGS="$wireshark_save_CPPFLAGS"
1123                         LDFLAGS="$wireshark_save_LDFLAGS"
1124                         LIBS="$wireshark_save_LIBS"
1125                         PORTAUDIO_LIBS=""
1126                         # User requested --with-portaudio but it isn't available
1127                         if test "x$want_portaudio" = "xyes"
1128                         then
1129                                 AC_MSG_ERROR(Linking with libportaudio failed.)
1130                         fi
1131                         want_portaudio=no
1132                 ])
1133
1134         CPPFLAGS="$wireshark_save_CPPFLAGS"
1135         LDFLAGS="$wireshark_save_LDFLAGS"
1136         LIBS="$wireshark_save_LIBS"
1137         AC_SUBST(PORTAUDIO_LIBS)
1138         AC_SUBST(PORTAUDIO_INCLUDES)
1139
1140         fi
1141 ])
1142
1143 #
1144 # AC_WIRESHARK_RPM_CHECK
1145 # Looks for the rpm program, and checks to see if we can redefine "_topdir".
1146 #
1147 AC_DEFUN([AC_WIRESHARK_RPM_CHECK],
1148 [
1149         AC_CHECK_PROG(ac_cv_wireshark_have_rpm, rpm, "yes", "no")
1150         if test "x$ac_cv_wireshark_have_rpm" = "xyes"; then
1151                 rpm --define '_topdir /tmp' > /dev/null 2>&1
1152                 AC_MSG_CHECKING(to see if we can redefine _topdir)
1153                 if test $? -eq 0 ; then
1154                         AC_MSG_RESULT(yes)
1155                         HAVE_RPM=yes
1156                 else
1157                         AC_MSG_RESULT(no.  You'll have to build packages manually.)
1158                         HAVE_RPM=no
1159                 fi
1160         fi
1161 ])
1162
1163 #
1164 # AC_WIRESHARK_GNU_SED_CHECK
1165 # Checks if GNU sed is the first sed in PATH.
1166 #
1167 AC_DEFUN([AC_WIRESHARK_GNU_SED_CHECK],
1168 [
1169         AC_MSG_CHECKING(for GNU sed as first sed in PATH)
1170         if  ( sh -c "sed --version" </dev/null 2> /dev/null | grep "GNU sed" 2>&1 > /dev/null ) ;  then
1171                 AC_MSG_RESULT(yes)
1172                 HAVE_GNU_SED=yes
1173         else
1174                 AC_MSG_RESULT(no)
1175                 HAVE_GNU_SED=no
1176         fi
1177 ])
1178
1179 #
1180 # AC_WIRESHARK_C_ARES_CHECK
1181 #
1182 AC_DEFUN([AC_WIRESHARK_C_ARES_CHECK],
1183 [
1184         want_c_ares=defaultyes
1185
1186         if test "x$want_c_ares" = "xdefaultyes"; then
1187                 want_c_ares=yes
1188                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1189                         withval=/usr/local
1190                         if test -d "$withval"; then
1191                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1192                         fi
1193                 fi
1194         fi
1195
1196         if test "x$want_c_ares" = "xyes"; then
1197                 AC_CHECK_LIB(cares, ares_init,
1198                   [
1199                     C_ARES_LIBS=-lcares
1200                 AC_DEFINE(HAVE_C_ARES, 1, [Define to use c-ares library])
1201                 have_good_c_ares=yes
1202                   ],, $SOCKET_LIBS $NSL_LIBS
1203                 )
1204         else
1205                 AC_MSG_RESULT(not required)
1206         fi
1207 ])
1208
1209
1210 #
1211 # AC_WIRESHARK_ADNS_CHECK
1212 #
1213 AC_DEFUN([AC_WIRESHARK_ADNS_CHECK],
1214 [
1215         want_adns=defaultyes
1216
1217         if test "x$want_adns" = "xdefaultyes"; then
1218                 want_adns=yes
1219                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1220                         withval=/usr/local
1221                         if test -d "$withval"; then
1222                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1223                         fi
1224                 fi
1225         fi
1226
1227         if test "x$want_adns" = "xyes"; then
1228                 AC_CHECK_LIB(adns, adns_init,
1229                   [
1230                     ADNS_LIBS=-ladns
1231                 AC_DEFINE(HAVE_GNU_ADNS, 1, [Define to use GNU ADNS library])
1232                 have_good_adns=yes
1233                   ],, $SOCKET_LIBS $NSL_LIBS
1234                 )
1235         else
1236                 AC_MSG_RESULT(not required)
1237         fi
1238 ])
1239
1240
1241 #
1242 # AC_WIRESHARK_LIBCAP_CHECK
1243 #
1244 AC_DEFUN([AC_WIRESHARK_LIBCAP_CHECK],
1245 [
1246         want_libcap=defaultyes
1247
1248         if test "x$want_libcap" = "xdefaultyes"; then
1249                 want_libcap=yes
1250                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1251                         withval=/usr/local
1252                         if test -d "$withval"; then
1253                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1254                         fi
1255                 fi
1256         fi
1257
1258         if test "x$want_libcap" = "xyes"; then
1259                 AC_CHECK_LIB(cap, cap_set_flag,
1260                   [
1261                     LIBCAP_LIBS=-lcap
1262                 AC_DEFINE(HAVE_LIBCAP, 1, [Define to use the libcap library])
1263                 have_good_libcap=yes
1264                   ],,
1265                 )
1266         else
1267                 AC_MSG_RESULT(not required)
1268         fi
1269 ])
1270
1271
1272 #
1273 # AC_WIRESHARK_KRB5_CHECK
1274 #
1275 AC_DEFUN([AC_WIRESHARK_KRB5_CHECK],
1276 [
1277         wireshark_save_CPPFLAGS="$CPPFLAGS"
1278         if test "x$krb5_dir" != "x"
1279         then
1280           #
1281           # The user specified a directory in which kerberos resides,
1282           # so add the "include" subdirectory of that directory to
1283           # the include file search path and the "lib" subdirectory
1284           # of that directory to the library search path.
1285           #
1286           # XXX - if there's also a kerberos in a directory that's
1287           # already in CPPFLAGS or LDFLAGS, this won't make us find
1288           # the version in the specified directory, as the compiler
1289           # and/or linker will search that other directory before it
1290           # searches the specified directory.
1291           #
1292           CPPFLAGS="$CPPFLAGS -I$krb5_dir/include"
1293           ac_heimdal_version=`grep heimdal $krb5_dir/include/krb5.h | head -n 1 | sed 's/^.*heimdal.*$/HEIMDAL/'`
1294           # MIT Kerberos moved krb5.h to krb5/krb5.h starting with release 1.5
1295           ac_mit_version_olddir=`grep 'Massachusetts' $krb5_dir/include/krb5.h | head -n 1 | sed 's/^.*Massachusetts.*$/MIT/'`
1296           ac_mit_version_newdir=`grep 'Massachusetts' $krb5_dir/include/krb5/krb5.h | head -n 1 | sed 's/^.*Massachusetts.*$/MIT/'`
1297           ac_krb5_version="$ac_heimdal_version$ac_mit_version_olddir$ac_mit_version_newdir"
1298           if test "x$ac_krb5_version" = "xHEIMDAL"
1299           then
1300               KRB5_LIBS="-L$krb5_dir/lib -lkrb5 -lasn1 $SSL_LIBS -lroken -lcrypt"
1301           else
1302               KRB5_LIBS="-L$krb5_dir/lib -lkrb5 -lk5crypto -lcom_err"
1303           fi
1304           if test "x$ac_krb5_version" = "xMIT"
1305           then
1306             AC_DEFINE(HAVE_MIT_KERBEROS, 1, [Define to use MIT kerberos])
1307           fi
1308         else
1309           AC_PATH_PROG(KRB5_CONFIG, krb5-config)
1310           if test -x "$KRB5_CONFIG"
1311           then
1312             KRB5_FLAGS=`"$KRB5_CONFIG" --cflags`
1313             KRB5_LIBS=`"$KRB5_CONFIG" --libs`
1314             CPPFLAGS="$CPPFLAGS $KRB5_FLAGS"
1315             #
1316             # If -lcrypto is in KRB5_FLAGS, we require it to build
1317             # with Heimdal/MIT.  We don't want to built with it by
1318             # default, due to annoying license incompatibilities
1319             # between the OpenSSL license and the GPL, so:
1320             #
1321             #   if SSL_LIBS is set to a non-empty string, we
1322             #   remove -lcrypto from KRB5_LIBS and replace
1323             #   it with SSL_LIBS;
1324             #
1325             #   if SSL_LIBS is not set to a non-empty string
1326             #   we fail with an appropriate error message.
1327             #
1328             case "$KRB5_LIBS" in
1329             *-lcrypto*)
1330                 if test ! -z "$SSL_LIBS"
1331                 then
1332                     KRB5_LIBS=`echo $KRB5_LIBS | sed 's/-lcrypto//'`
1333                     KRB5_LIBS="$KRB5_LIBS $SSL_LIBS"
1334                 else
1335                     AC_MSG_ERROR([Kerberos library requires -lcrypto, so you must specify --with-ssl])
1336                 fi
1337                 ;;
1338             esac
1339             ac_krb5_version=`"$KRB5_CONFIG" --version | head -n 1 | sed -e 's/^.*heimdal.*$/HEIMDAL/' -e 's/^Kerberos .*$/MIT/' -e 's/^Solaris Kerberos .*$/MIT/'`
1340           fi
1341         fi
1342
1343         #
1344         # Make sure we have "krb5.h".  If we don't, it means we probably
1345         # don't have kerberos, so don't use it.
1346         #
1347         AC_CHECK_HEADER(krb5.h,,
1348           [
1349             if test "x$krb5_dir" != "x"
1350             then
1351               #
1352               # The user used "--with-krb5=" to specify a directory
1353               # containing kerberos, but we didn't find the header file
1354               # there; that either means they didn't specify the
1355               # right directory or are confused about whether kerberos
1356               # is, in fact, installed.  Report the error and give up.
1357               #
1358               AC_MSG_ERROR([kerberos header not found in directory specified in --with-krb5])
1359             else
1360               if test "x$want_krb5" = "xyes"
1361               then
1362                 #
1363                 # The user tried to force us to use the library, but we
1364                 # couldn't find the header file; report an error.
1365                 #
1366                 AC_MSG_ERROR(Header file krb5.h not found.)
1367               else
1368                 #
1369                 # We couldn't find the header file; don't use the
1370                 # library, as it's probably not present.
1371                 #
1372                 want_krb5=no
1373                 AC_MSG_RESULT(No Heimdal or MIT header found - disabling dissection for some kerberos data in packet decoding)
1374               fi
1375             fi
1376           ])
1377
1378         if test "x$want_krb5" != "xno"
1379         then
1380             #
1381             # Well, we at least have the krb5 header file.
1382             # Check whether this is Heimdal or MIT.
1383             #
1384             AC_MSG_CHECKING(whether the Kerberos library is Heimdal or MIT)
1385             if test "x$ac_krb5_version" = "xHEIMDAL" -o "x$ac_krb5_version" = "xMIT"
1386             then
1387                 #
1388                 # Yes.
1389                 # Check whether we have krb5_kt_resolve - and whether
1390                 # we need to link with -lresolv when linking with
1391                 # the Kerberos library.
1392                 #
1393                 AC_MSG_RESULT($ac_krb5_version)
1394                 wireshark_save_LIBS="$LIBS"
1395                 found_krb5_kt_resolve=no
1396                 for extras in "" "-lresolv"
1397                 do
1398                     LIBS="$KRB5_LIBS $extras"
1399                     if test -z "$extras"
1400                     then
1401                         AC_MSG_CHECKING([whether $ac_krb5_version includes krb5_kt_resolve])
1402                     else
1403                         AC_MSG_CHECKING([whether $ac_krb5_version includes krb5_kt_resolve (linking with $extras)])
1404                     fi
1405                     AC_TRY_LINK(
1406                         [
1407                         ],
1408                         [
1409                             krb5_kt_resolve();
1410                         ],
1411                         [
1412                             #
1413                             # We found "krb5_kt_resolve()", and required
1414                             # the libraries in extras as well.
1415                             #
1416                             AC_MSG_RESULT(yes)
1417                             KRB5_LIBS="$LIBS"
1418                             AC_DEFINE(HAVE_KERBEROS, 1, [Define to use kerberos])
1419                             if test "x$ac_krb5_version" = "xHEIMDAL"
1420                             then
1421                                 AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1, [Define to use heimdal kerberos])
1422                             elif test "x$ac_krb5_version" = "xMIT"
1423                             then
1424                                 AC_DEFINE(HAVE_MIT_KERBEROS, 1, [Define to use MIT kerberos])
1425                             fi
1426                             found_krb5_kt_resolve=yes
1427                             break
1428                         ],
1429                         [
1430                             AC_MSG_RESULT(no)
1431                         ])
1432                 done
1433                 if test "$found_krb5_kt_resolve" = no
1434                 then
1435                     #
1436                     # We didn't find "krb5_kt_resolve()" in the
1437                     # Kerberos library, even when we tried linking
1438                     # with -lresolv; we can't link with kerberos.
1439                     #
1440                     if test "x$want_krb5" = "xyes"
1441                     then
1442                         #
1443                         # The user tried to force us to use the library,
1444                         # but we can't do so; report an error.
1445                         #
1446                         AC_MSG_ERROR(Usable $ac_krb5_version not found)
1447                     else
1448                         #
1449                         # Restore the versions of CPPFLAGS from before we
1450                         # added the flags for Kerberos.
1451                         #
1452                         AC_MSG_RESULT(Usable $ac_krb5_version not found - disabling dissection for some kerberos data in packet decoding)
1453                         CPPFLAGS="$wireshark_save_CPPFLAGS"
1454                         KRB5_LIBS=""
1455                         want_krb5=no
1456                     fi
1457                 else
1458                     #
1459                     # We can link with Kerberos; see whether krb5.h
1460                     # defines KEYTYPE_ARCFOUR_56 (where "defines" means
1461                     # "as a #define or as an enum member).
1462                     #
1463                     AC_MSG_CHECKING([whether krb5.h defines KEYTYPE_ARCFOUR_56])
1464                     AC_COMPILE_IFELSE(
1465                       [
1466                         AC_LANG_SOURCE(
1467                           [[
1468                             #include <krb5.h>
1469                             #include <stdio.h>
1470
1471                             main()
1472                             {
1473                               printf("%u\n", KEYTYPE_ARCFOUR_56);
1474                             }
1475                           ]])
1476                       ],
1477                       [
1478                         AC_MSG_RESULT(yes)
1479                         AC_DEFINE(HAVE_KEYTYPE_ARCFOUR_56, 1, [Define if krb5.h defines KEYTYPE_ARCFOUR_56])
1480                       ],
1481                       [
1482                         AC_MSG_RESULT(no)
1483                       ])
1484                 fi
1485                 LIBS="$wireshark_save_LIBS"
1486             else
1487                 #
1488                 # It's not Heimdal or MIT.
1489                 #
1490                 AC_MSG_RESULT(no)
1491                 if test "x$want_krb5" = "xyes"
1492                 then
1493                     #
1494                     # The user tried to force us to use the library,
1495                     # but we can't do so; report an error.
1496                     #
1497                     AC_MSG_ERROR(Kerberos not found)
1498                 else
1499                     #
1500                     # Restore the versions of CPPFLAGS from before we
1501                     # added the flags for Kerberos.
1502                     #
1503                     AC_MSG_RESULT(Kerberos not found - disabling dissection for some kerberos data in packet decoding)
1504                     CPPFLAGS="$wireshark_save_CPPFLAGS"
1505                     KRB5_LIBS=""
1506                     want_krb5=no
1507                 fi
1508             fi
1509         else
1510             #
1511             # The user asked us not to use Kerberos, or they didn't
1512             # say whether they wanted us to use it but we found
1513             # that we couldn't.
1514             #
1515             # Restore the versions of CPPFLAGS from before we added
1516             # the flags for Kerberos.
1517             #
1518             CPPFLAGS="$wireshark_save_CPPFLAGS"
1519             KRB5_LIBS=""
1520             want_krb5=no
1521         fi
1522         AC_SUBST(KRB5_LIBS)
1523 ])
1524
1525 #
1526 # AC_WIRESHARK_GEOIP_CHECK
1527 #
1528 AC_DEFUN([AC_WIRESHARK_GEOIP_CHECK],
1529 [
1530         want_geoip=defaultyes
1531
1532         if test "x$want_geoip" = "xdefaultyes"; then
1533                 want_geoip=yes
1534                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1535                         withval=/usr/local
1536                         if test -d "$withval"; then
1537                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1538                         fi
1539                 fi
1540         fi
1541
1542         if test "x$want_geoip" = "xyes"; then
1543                 AC_CHECK_LIB(GeoIP, GeoIP_new,
1544                   [
1545                     GEOIP_LIBS=-lGeoIP
1546                 AC_DEFINE(HAVE_GEOIP, 1, [Define to use GeoIP library])
1547                 have_good_geoip=yes
1548                   ],,
1549                 )
1550                 if test "x$have_good_geoip" = "xyes"; then
1551                         AC_CHECK_LIB(GeoIP, GeoIP_country_name_by_ipnum_v6,
1552                           [
1553                                 AC_DEFINE(HAVE_GEOIP_V6, 1, [Define if GeoIP supports IPv6 (GeoIP 1.4.5 and later)])
1554                           ],,
1555                         )
1556                 fi
1557         else
1558                 AC_MSG_RESULT(not required)
1559         fi
1560 ])
1561
1562 #AC_WIRESHARK_LDFLAGS_CHECK
1563 #
1564 # $1 : ldflag(s) to test
1565 #
1566 # We attempt to compile and link a test program with the specified linker
1567 # flag. The defined flag is added to LDFLAGS only if the link succeeds.
1568 #
1569 AC_DEFUN([AC_WIRESHARK_LDFLAGS_CHECK],
1570 [LD_OPTION="$1"
1571 AC_MSG_CHECKING(whether we can add $LD_OPTION to LDFLAGS)
1572 LDFLAGS_saved="$LDFLAGS"
1573 LDFLAGS="$LDFLAGS $LD_OPTION"
1574 AC_LINK_IFELSE(
1575   [
1576     AC_LANG_SOURCE([[main() { return; }]])
1577   ],
1578   [
1579     AC_MSG_RESULT(yes)
1580   ],
1581   [
1582     AC_MSG_RESULT(no)
1583     LDFLAGS="$LDFLAGS_saved"
1584   ])
1585 ])
1586
1587 dnl
1588 dnl Check whether, if you pass an unknown warning option to the
1589 dnl compiler, it fails or just prints a warning message and succeeds.
1590 dnl Set ac_wireshark_unknown_warning_option_error to the appropriate flag
1591 dnl to force an error if it would otherwise just print a warning message
1592 dnl and succeed.
1593 dnl
1594 AC_DEFUN([AC_WIRESHARK_CHECK_UNKNOWN_WARNING_OPTION_ERROR],
1595     [
1596         AC_MSG_CHECKING([whether the compiler fails when given an unknown warning option])
1597         save_CFLAGS="$CFLAGS"
1598         CFLAGS="$CFLAGS -Wxyzzy-this-will-never-succeed-xyzzy"
1599         AC_TRY_COMPILE(
1600             [],
1601             [return 0],
1602             [
1603                 AC_MSG_RESULT([no, adding -Werror=unknown-warning-option])
1604                 #
1605                 # We're assuming this is clang, where
1606                 # -Werror=unknown-warning-option is the appropriate
1607                 # option to force the compiler to fail.
1608                 #
1609                 ac_wireshark_unknown_warning_option_error="-Werror=unknown-warning-option"
1610             ],
1611             [
1612                 AC_MSG_RESULT([yes])
1613             ])
1614         CFLAGS="$save_CFLAGS"
1615     ])
1616
1617 dnl
1618 dnl Check whether, if you pass a valid-for-C-but-not-C++ option to the
1619 dnl compiler, it fails or just prints a warning message and succeeds.
1620 dnl Set ac_wireshark_non_cxx_warning_option_error to the appropriate flag
1621 dnl to force an error if it would otherwise just print a warning message
1622 dnl and succeed.
1623 dnl
1624 AC_DEFUN([AC_WIRESHARK_CHECK_NON_CXX_WARNING_OPTION_ERROR],
1625     [
1626         AC_MSG_CHECKING([whether the compiler fails when given an warning option not supported for C++])
1627         #
1628         # Some C+ compilers warn about -Wmissing-prototypes, and some warn
1629         # about -Wmissing-declarations.  Check both.
1630         #
1631         AC_LANG_PUSH(C++)
1632         save_CXXFLAGS="$CXXFLAGS"
1633         for flag in -Wmissing-prototypes -Wmissing-declarations; do
1634             CXXFLAGS="$save_CXXFLAGS $flag"
1635             AC_TRY_COMPILE(
1636                 [],
1637                 [return 0],
1638                 [
1639                     #
1640                     # We're assuming this is g++, where -Werror is the
1641                     # appropriate option to force the compiler to fail.
1642                     # Check whether it fails with -Werror.
1643                     #
1644                     # NOTE: it's important to put -Werror *before*
1645                     # the flag, otherwise, when it sees the flag,
1646                     # it doesn't yet know that warnings should be
1647                     # treated as errors, and doesn't treat the
1648                     # "that's C-only" warning as an error.
1649                     #
1650                     CXXFLAGS="$save_CXXFLAGS -Werror $flag"
1651                     AC_TRY_COMPILE(
1652                         [],
1653                         [return 0],
1654                         [
1655                             #
1656                             # No, so this option is actually OK
1657                             # with our C++ compiler.
1658                             #
1659                             # (We need an empty command here to
1660                             # prevent some versions of autoconf
1661                             # from generating a script with an
1662                             # empty "then" clause for an if statement.)
1663                             #
1664                             :
1665                         ],
1666                         [
1667                             #
1668                             # Yes, so we need -Werror for the tests.
1669                             #
1670                             ac_wireshark_non_cxx_warning_option_error="-Werror"
1671                             break
1672                         ])
1673                 ])
1674         done
1675         CXXFLAGS="$save_CXXFLAGS"
1676         AC_LANG_POP
1677         if test x$ac_wireshark_non_cxx_warning_option_error = x; then
1678             AC_MSG_RESULT([yes])
1679         else
1680             AC_MSG_RESULT([no, adding -Werror])
1681         fi
1682     ])
1683
1684 #
1685 # AC_WIRESHARK_COMPILER_FLAGS_CHECK
1686 #
1687 # $1 : flags to test
1688 # $2 : if supplied, C for C-only flags, CXX for C++-only flags
1689 # $3 : if supplied, a program to try to compile with the flag
1690 #      and, if the compile fails when -Werror is turned on,
1691 #      we don't add the flag - used for warning flags that
1692 #      issue incorrect or non-useful warnings with some
1693 #      compiler versions
1694 # $4 : must be supplied if $3 is supplied - a message describing
1695 #      for what the test program is testing
1696 #
1697 # The macro first determines if the compiler supports GCC-style flags.
1698 # Then it attempts to compile with the defined cflags.  The defined
1699 # flags are added to CFLAGS only if the compilation succeeds.
1700 #
1701 # We do this because not all such options are necessarily supported by
1702 # the version of the particular compiler we're using.
1703 #
1704 AC_DEFUN([AC_WIRESHARK_COMPILER_FLAGS_CHECK],
1705 [GCC_OPTION="$1"
1706 can_add_to_cflags=""
1707 can_add_to_cxxflags=""
1708 if test "x$ac_supports_gcc_flags" = "xyes" ; then
1709   if test "$2" != CXX ; then
1710     #
1711     # Not C++-only; if this can be added to the C compiler flags, add them.
1712     #
1713     # If the option begins with "-W", add
1714     # $ac_wireshark_unknown_warning_option_error to make sure that
1715     # we'll get an error if it's an unknown warning option; not all
1716     # compilers treat unknown warning options as errors (I'm looking at
1717     # you, clang).
1718     #
1719     # If the option begins with "-f" or "-m", add -Werror to make sure
1720     # that we'll get an error if we get "argument unused during compilation"
1721     # warnings, as those will either cause a failure for files compiled
1722     # with -Werror or annoying noise for files compiled without it.
1723     # (Yeah, you, clang.)
1724     #
1725     AC_MSG_CHECKING(whether we can add $GCC_OPTION to CFLAGS)
1726     CFLAGS_saved="$CFLAGS"
1727     if expr "x$GCC_OPTION" : "x-W.*" >/dev/null
1728     then
1729       CFLAGS="$CFLAGS $ac_wireshark_unknown_warning_option_error $GCC_OPTION"
1730     elif expr "x$GCC_OPTION" : "x-f.*" >/dev/null
1731     then
1732       CFLAGS="$CFLAGS -Werror $GCC_OPTION"
1733     elif expr "x$GCC_OPTION" : "x-m.*" >/dev/null
1734     then
1735       CFLAGS="$CFLAGS -Werror $GCC_OPTION"
1736     else
1737       CFLAGS="$CFLAGS $GCC_OPTION"
1738     fi
1739     AC_COMPILE_IFELSE(
1740       [
1741         AC_LANG_SOURCE([[int foo;]])
1742       ],
1743       [
1744         AC_MSG_RESULT(yes)
1745         can_add_to_cflags=yes
1746         #
1747         # OK, do we have a test program?  If so, check
1748         # whether it fails with this option and -Werror,
1749         # and, if so, don't include it.
1750         #
1751         # We test arg 4 here because arg 3 is a program which
1752         # could contain quotes (breaking the comparison).
1753         #
1754         if test "x$4" != "x" ; then
1755           CFLAGS="$CFLAGS -Werror"
1756           AC_MSG_CHECKING(whether $GCC_OPTION $4)
1757           AC_COMPILE_IFELSE(
1758             [AC_LANG_SOURCE($3)],
1759             [
1760               AC_MSG_RESULT(no)
1761               #
1762               # Remove "force an error for a warning" options, if we
1763               # added them, by setting CFLAGS to the saved value plus
1764               # just the new option.
1765               #
1766               CFLAGS="$CFLAGS_saved $GCC_OPTION"
1767               #
1768               # Add it to the flags we use when building build tools.
1769               #
1770               CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD $GCC_OPTION"
1771             ],
1772             [
1773               AC_MSG_RESULT(yes)
1774               CFLAGS="$CFLAGS_saved"
1775             ])
1776         else
1777           #
1778           # Remove "force an error for a warning" options, if we
1779           # added them, by setting CFLAGS to the saved value plus
1780           # just the new option.
1781           #
1782           CFLAGS="$CFLAGS_saved $GCC_OPTION"
1783           #
1784           # Add it to the flags we use when building build tools.
1785           #
1786           CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD $GCC_OPTION"
1787         fi
1788       ],
1789       [
1790         AC_MSG_RESULT(no)
1791         can_add_to_cflags=no
1792         CFLAGS="$CFLAGS_saved"
1793       ])
1794   fi
1795   if test "$2" != C ; then
1796     #
1797     # Not C-only; if this can be added to the C++ compiler flags, add them.
1798     #
1799     # If the option begins with "-W", add
1800     # $ac_wireshark_unknown_warning_option_error, as per the above, and
1801     # also add $ac_wireshark_non_cxx_warning_option_error, because at
1802     # lease some versions of g++ whine about -Wmissing-prototypes, the
1803     # fact that at least one of those versions refuses to warn about
1804     # function declarations without an earlier declaration nonwithstanding;
1805     # perhaps there's a reason not to warn about that with C++ even though
1806     # warning about it can be a Good Idea with C, but it's not obvious to
1807     # me).
1808     #
1809     # If the option begins with "-f" or "-m", add -Werror to make sure
1810     # that we'll get an error if we get "argument unused during compilation"
1811     # warnings, as those will either cause a failure for files compiled
1812     # with -Werror or annoying noise for files compiled without it.
1813     # (Yeah, you, clang++.)
1814     #
1815     AC_MSG_CHECKING(whether we can add $GCC_OPTION to CXXFLAGS)
1816     CXXFLAGS_saved="$CXXFLAGS"
1817     if expr "x$GCC_OPTION" : "x-W.*" >/dev/null
1818     then
1819       CXXFLAGS="$CXXFLAGS $ac_wireshark_unknown_warning_option_error $ac_wireshark_non_cxx_warning_option_error $GCC_OPTION"
1820     elif expr "x$GCC_OPTION" : "x-f.*" >/dev/null
1821     then
1822       CXXFLAGS="$CXXFLAGS -Werror $GCC_OPTION"
1823     elif expr "x$GCC_OPTION" : "x-m.*" >/dev/null
1824     then
1825       CXXFLAGS="$CXXFLAGS -Werror $GCC_OPTION"
1826     else
1827       CXXFLAGS="$CXXFLAGS $GCC_OPTION"
1828     fi
1829     AC_LANG_PUSH([C++])
1830     AC_COMPILE_IFELSE(
1831       [
1832         AC_LANG_SOURCE([[int foo;]])
1833       ],
1834       [
1835         AC_MSG_RESULT(yes)
1836         can_add_to_cxxflags=yes
1837         #
1838         # OK, do we have a test program?  If so, check
1839         # whether it fails with this option and -Werror,
1840         # and, if so, don't include it.
1841         #
1842         # We test arg 4 here because arg 3 is a program which
1843         # could contain quotes (breaking the comparison).
1844         #
1845         if test "x$4" != "x" ; then
1846           CXXFLAGS="$CXXFLAGS -Werror"
1847           AC_MSG_CHECKING(whether $GCC_OPTION $4)
1848           AC_COMPILE_IFELSE(
1849             [AC_LANG_SOURCE($3)],
1850             [
1851               AC_MSG_RESULT(no)
1852               #
1853               # Remove "force an error for a warning" options, if we
1854               # added them, by setting CXXFLAGS to the saved value plus
1855               # just the new option.
1856               #
1857               CXXFLAGS="$CXXFLAGS_saved $GCC_OPTION"
1858             ],
1859             [
1860               AC_MSG_RESULT(yes)
1861               CXXFLAGS="$CXXFLAGS_saved"
1862             ])
1863         else
1864           #
1865           # Remove "force an error for a warning" options, if we
1866           # added them, by setting CXXFLAGS to the saved value plus
1867           # just the new option.
1868           #
1869           CXXFLAGS="$CXXFLAGS_saved $GCC_OPTION"
1870         fi
1871       ],
1872       [
1873         AC_MSG_RESULT(no)
1874         can_add_to_cxxflags=no
1875         CXXFLAGS="$CXXFLAGS_saved"
1876       ])
1877     AC_LANG_POP([C++])
1878   fi
1879   if test "(" "$can_add_to_cflags" = "yes" -a "$can_add_to_cxxflags" = "no" ")" \
1880        -o "(" "$can_add_to_cflags" = "no" -a "$can_add_to_cxxflags" = "yes" ")"
1881   then
1882     #
1883     # Confusingly, some C++ compilers like -Wmissing-prototypes but
1884     # don't like -Wmissing-declarations and others like
1885     # -Wmissing-declarations but don't like -Wmissing-prototypes,
1886     # the fact that the corresponding C compiler likes both.  Don't
1887     # warn about them.
1888     #
1889     if test "(" x$GCC_OPTION != x-Wmissing-prototypes ")" \
1890          -a "(" x$GCC_OPTION != x-Wmissing-declarations ")"
1891     then
1892        AC_MSG_WARN([$CC and $CXX appear to be a mismatched pair])
1893     fi
1894   fi
1895 fi
1896 ])
1897
1898 # AC_WIRESHARK_GCC_FORTIFY_SOURCE_CHECK
1899 #
1900 # Checks if '-D_FORTIFY_SOURCE=...' is OK to use in CPPFLAGS.
1901 #  Use '-D_FORTIFY_SOURCE=...' in CPPFLAGS only if the GCC 'optimization level' is > 0.
1902 #  The use of '-D_FORTIFY_SOURCE=...' will cause a warning with at least some versions
1903 #    of glibc if the  GCC "optimization level" is 0 (default or -O or -O0)
1904 #    when using GCC to compile a source file which references the macro definition.
1905 #
1906 # See: http://gcc.gnu.org/ml/gcc-patches/2004-09/msg02055.html
1907 # See: http://sourceware.org/bugzilla/show_bug.cgi?id=13979
1908 #
1909 #   We'll use '-D_FORTIFY_SOURCE=2' only if there's no warning; Among other things this means
1910 #    that the  use of '-D_FORTIFY_SOURCE=2' with '-Werror' and '-O0' won't cause
1911 #    the compiler to stop on error.
1912 #   Assumption: CFLAGS already contains whatever optimization option including none) is
1913 #    to be used.
1914 #
1915
1916 AC_DEFUN([AC_WIRESHARK_GCC_FORTIFY_SOURCE_CHECK],
1917 [
1918 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
1919   AC_MSG_CHECKING([whether -D_FORTIFY_SOURCE=... can be used (without generating a warning)])
1920   CFLAGS_saved="$CFLAGS"
1921   CPPFLAGS_saved="$CPPFLAGS"
1922   CFLAGS="$CFLAGS -Werror"
1923   CPPFLAGS="$CPPFLAGS -D_FORTIFY_SOURCE=2"
1924   AC_COMPILE_IFELSE([
1925     AC_LANG_SOURCE([[
1926                   #include <stdio.h>
1927                       int foo;
1928                   ]])],
1929                   [
1930                     AC_MSG_RESULT(yes)
1931                     #
1932                     # (CPPFLAGS contains _D_FORTIFY_SOURCE=2)
1933                     #
1934                   ],
1935                   [
1936                     AC_MSG_RESULT(no)
1937                     # Remove -D_FORTIFY_SOURCE=2
1938                     CPPFLAGS="$CPPFLAGS_saved"
1939                   ])
1940   CFLAGS="$CFLAGS_saved"
1941 fi
1942 ])
1943
1944 #
1945 # AC_WIRESHARK_OSX_INTEGRATION_CHECK
1946 #
1947 # Checks for the presence of OS X integration functions in the GTK+ framework
1948 # or as a separate library.
1949 #
1950 # GTK+ for MAC OS X now lives on www.gtk.org at:
1951 #
1952 #   http://www.gtk.org/download/macos.php
1953 #
1954 # Details on building with GTK-OSX are available at:
1955 #
1956 #   http://live.gnome.org/GTK%2B/OSX/Building
1957 #
1958 # The GTK-OSX library has been renamed to gtkmacintegration.
1959 # It was previously named igemacintegration.
1960 #
1961 # http://live.gnome.org/GTK%2B/OSX/Integration
1962 #    for the old Carbon-based integration functions
1963 #
1964 AC_DEFUN([AC_WIRESHARK_OSX_INTEGRATION_CHECK],
1965 [
1966         ac_save_CFLAGS="$CFLAGS"
1967         ac_save_LIBS="$LIBS"
1968         CFLAGS="$CFLAGS $GTK_CFLAGS"
1969         LIBS="$GTK_LIBS $LIBS"
1970
1971         #
1972         # Check for the new integration functions in a -lgtkmacintegration
1973         # library.
1974         #
1975         AC_CHECK_LIB(gtkmacintegration, gtkosx_application_set_menu_bar,
1976         [
1977                 AC_DEFINE(HAVE_GTKOSXAPPLICATION, 1,
1978                         [Define to 1 if -lgtkmacintegration includes the GtkOSXApplication Integration functions.])
1979                 have_ige_mac=yes
1980                 # We don't want gtk stuff in LIBS (which is reset below) so
1981                 # manually set GTK_LIBS (which is more appropriate)
1982                 GTK_LIBS="$GTK_LIBS -lgtkmacintegration"
1983         ])
1984
1985         if test x$have_ige_mac = x
1986         then
1987                 #
1988                 # Not found - check for the old integration functions in
1989                 # the Gtk framework.
1990                 #
1991                 AC_CHECK_LIB(Gtk, gtk_mac_menu_set_menu_bar,
1992                 [
1993                         AC_DEFINE(HAVE_IGE_MAC_INTEGRATION, 1,
1994                                 [Define to 1 if the the Gtk+ framework or a separate library includes the Imendio IGE Mac OS X Integration functions.])
1995                         have_ige_mac=yes
1996                         # We don't want gtk stuff in LIBS (which is reset below) so
1997                         # manually set GTK_LIBS (which is more appropriate)
1998                         GTK_LIBS="$GTK_LIBS -lGtk"
1999                 ])
2000         fi
2001
2002         if test x$have_ige_mac = x
2003         then
2004                 #
2005                 # Not found - check for the old integration functions in
2006                 # a -lgtkmacintegration library.
2007                 #
2008                 AC_CHECK_LIB(gtkmacintegration, gtk_mac_menu_set_menu_bar,
2009                 [
2010                         AC_DEFINE(HAVE_IGE_MAC_INTEGRATION, 1,
2011                                 [Define to 1 if the the Gtk+ framework or a separate library includes the Imendio IGE Mac OS X Integration functions.])
2012                         have_ige_mac=yes
2013                         # We don't want gtk stuff in LIBS (which is reset below) so
2014                         # manually set GTK_LIBS (which is more appropriate)
2015                         GTK_LIBS="$GTK_LIBS -lgtkmacintegration"
2016                 ])
2017         fi
2018         CFLAGS="$ac_save_CFLAGS"
2019         LIBS="$ac_save_LIBS"
2020 ])
2021
2022 # Based on AM_PATH_GTK in gtk-2.0.m4.
2023
2024 dnl AC_WIRESHARK_QT_MODULE_CHECK([MODULE, MINIMUM-VERSION, [ACTION-IF-FOUND,
2025 dnl     [ACTION-IF-NOT-FOUND]]])
2026 dnl Test for a particular Qt module and add the flags and libraries
2027 dnl for it to Qt_CFLAGS and Qt_LIBS.
2028 dnl
2029 AC_DEFUN([AC_WIRESHARK_QT_MODULE_CHECK],
2030 [
2031         #
2032         # Version of the module we're checking for.
2033         # Default to 4.0.0.
2034         #
2035         min_qt_version=ifelse([$2], ,4.0.0,$2)
2036
2037         #
2038         # Prior to Qt 5, modules were named QtXXX.
2039         # In Qt 5, they're named Qt5XXX.
2040         #
2041         # Try the Qt 5 version first.
2042         # (And be prepared to add Qt6 at some point....)
2043         #
2044         for modprefix in Qt5 Qt
2045         do
2046                 pkg_config_module="${modprefix}$1"
2047                 AC_MSG_CHECKING(for $pkg_config_module - version >= $min_qt_version)
2048                 if $PKG_CONFIG --atleast-version $min_qt_version $pkg_config_module; then
2049                         mod_version=`$PKG_CONFIG --modversion $pkg_config_module`
2050                         AC_MSG_RESULT(yes (version $mod_version))
2051                         Qt_CFLAGS="$Qt_CFLAGS `$PKG_CONFIG --cflags $pkg_config_module`"
2052                         Qt_LIBS="$Qt_LIBS `$PKG_CONFIG --libs $pkg_config_module`"
2053                         found_$1=yes
2054                         break
2055                 else
2056                         AC_MSG_RESULT(no)
2057                 fi
2058         done
2059
2060         if test "x$found_$1" = "xyes"; then
2061                 # Run Action-If-Found
2062                 ifelse([$3], , :, [$3])
2063         else
2064                 # Run Action-If-Not-Found
2065                 ifelse([$4], , :, [$4])
2066         fi
2067 ])
2068
2069 dnl AC_WIRESHARK_QT_CHECK([MINIMUM-VERSION, [ACTION-IF-FOUND,
2070 dnl     [ACTION-IF-NOT-FOUND]]])
2071 dnl Test for Qt and define Qt_CFLAGS and Qt_LIBS.
2072 dnl
2073 AC_DEFUN([AC_WIRESHARK_QT_CHECK],
2074 [
2075         no_qt=""
2076
2077         AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
2078
2079         if test x$PKG_CONFIG != xno ; then
2080                 if pkg-config --atleast-pkgconfig-version 0.7 ; then
2081                         :
2082                 else
2083                         echo *** pkg-config too old; version 0.7 or better required.
2084                         no_qt=yes
2085                         PKG_CONFIG=no
2086                 fi
2087         else
2088                 no_qt=yes
2089         fi
2090
2091         if test x"$no_qt" = x ; then
2092                 #
2093                 # OK, we have an adequate version of pkg-config.
2094                 #
2095                 # Check for the Core module; if we don't have that,
2096                 # we don't have Qt.
2097                 #
2098                 AC_WIRESHARK_QT_MODULE_CHECK(Core, $1, , [no_qt=yes])
2099         fi
2100
2101         if test x"$no_qt" = x ; then
2102                 #
2103                 # We need the Gui module as well.
2104                 #
2105                 AC_WIRESHARK_QT_MODULE_CHECK(Gui, $1, , [no_qt=yes])
2106         fi
2107
2108         if test x"$no_qt" = x ; then
2109                 #
2110                 # Qt 5.0 appears to move the widgets out of Qt GUI
2111                 # to Qt Widgets; look for the Widgets module, but
2112                 # don't fail if we don't have it.
2113                 #
2114                 AC_WIRESHARK_QT_MODULE_CHECK(Widgets, $1)
2115
2116                 #
2117                 # Qt 5.0 also appears to move the printing support into
2118                 # the Qt PrintSupport module.
2119                 #
2120                 AC_WIRESHARK_QT_MODULE_CHECK(PrintSupport, $1)
2121
2122                 #
2123                 # Qt 5.0 added multimedia widgets in the Qt
2124                 # MultimediaWidgets module.
2125                 #
2126                 AC_WIRESHARK_QT_MODULE_CHECK(MultimediaWidgets, $1,
2127                         AC_DEFINE(QT_MULTIMEDIAWIDGETS_LIB, 1, [Define if we have QtMultimediaWidgets]))
2128
2129                 #
2130                 # While we're at it, look for QtMacExtras.  (Presumably
2131                 # if we're not building for OS X, it won't be present.)
2132                 #
2133                 # XXX - is there anything in QtX11Extras or QtWinExtras
2134                 # that we should be using?
2135                 #
2136                 AC_WIRESHARK_QT_MODULE_CHECK(MacExtras, $1,
2137                         AC_DEFINE(QT_MACEXTRAS_LIB, 1, [Define if we have QtMacExtras]))
2138
2139                 AC_SUBST(Qt_LIBS)
2140
2141                 # Run Action-If-Found
2142                 ifelse([$2], , :, [$2])
2143         else
2144                 # Run Action-If-Not-Found
2145                 ifelse([$3], , :, [$3])
2146         fi
2147
2148 ])