ConfigureChecks.cmake

   1 include(CheckIncludeFile)
   2 include(CheckSymbolExists)
   3 include(CheckFunctionExists)
   4 include(CheckLibraryExists)
   5 include(CheckTypeSize)
   6 include(CheckStructHasMember)
   7 include(CheckPrototypeDefinition)
   8 include(TestBigEndian)
   9
  10 set(PACKAGE ${APPLICATION_NAME})
  11 set(VERSION ${APPLICATION_VERSION})
  12 set(DATADIR ${DATA_INSTALL_DIR})
  13 set(LIBDIR ${LIB_INSTALL_DIR})
  14 set(PLUGINDIR "${PLUGIN_INSTALL_DIR}-${LIBRARY_SOVERSION}")
  15 set(SYSCONFDIR ${SYSCONF_INSTALL_DIR})
  16
  17 set(BINARYDIR ${CMAKE_BINARY_DIR})
  18 set(SOURCEDIR ${CMAKE_SOURCE_DIR})
  19
  20 function(COMPILER_DUMPVERSION _OUTPUT_VERSION)
  21     # Remove whitespaces from the argument.
  22     # This is needed for CC="ccache gcc" cmake ..
  23     string(REPLACE " " "" _C_COMPILER_ARG "${CMAKE_C_COMPILER_ARG1}")
  24
  25     execute_process(
  26         COMMAND
  27             ${CMAKE_C_COMPILER} ${_C_COMPILER_ARG} -dumpversion
  28         OUTPUT_VARIABLE _COMPILER_VERSION
  29     )
  30
  31     string(REGEX REPLACE "([0-9])\\.([0-9])(\\.[0-9])?" "\\1\\2"
  32            _COMPILER_VERSION "${_COMPILER_VERSION}")
  33
  34     set(${_OUTPUT_VERSION} ${_COMPILER_VERSION} PARENT_SCOPE)
  35 endfunction()
  36
  37 if(CMAKE_COMPILER_IS_GNUCC AND NOT MINGW AND NOT OS2)
  38     compiler_dumpversion(GNUCC_VERSION)
  39     if (NOT GNUCC_VERSION EQUAL 34)
  40         set(CMAKE_REQUIRED_FLAGS "-fvisibility=hidden")
  41         check_c_source_compiles(
  42 "void __attribute__((visibility(\"default\"))) test() {}
  43 int main(void){ return 0; }
  44 " WITH_VISIBILITY_HIDDEN)
  45         set(CMAKE_REQUIRED_FLAGS "")
  46     endif (NOT GNUCC_VERSION EQUAL 34)
  47 endif(CMAKE_COMPILER_IS_GNUCC AND NOT MINGW AND NOT OS2)
  48
  49 # HEADERS
  50 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  51 check_include_file(resolv.h HAVE_RESOLV_H)
  52
  53 # FUNCTIONS
  54 check_library_exists(resolv res_send "" RES_SEND_IN_LIBRESOLV)
  55 check_library_exists(resolv __res_send "" __RES_SEND_IN_LIBRESOLV)
  56 if (RES_SEND_IN_LIBRESOLV OR __RES_SEND_IN_LIBRESOLV)
  57     set(HAVE_LIBRESOLV TRUE)
  58     set(CMAKE_REQUIRED_LIBRARIES resolv)
  59 endif()
  60
  61 check_function_exists(res_init HAVE_RES_INIT)
  62 check_function_exists(__res_init HAVE___RES_INIT)
  63
  64 check_function_exists(res_ninit HAVE_RES_NINIT)
  65 check_function_exists(__res_ninit HAVE___RES_NINIT)
  66
  67 check_function_exists(res_close HAVE_RES_CLOSE)
  68 check_function_exists(__res_close HAVE___RES_CLOSE)
  69
  70 check_function_exists(res_nclose HAVE_RES_NCLOSE)
  71 check_function_exists(__res_nclose HAVE___RES_NCLOSE)
  72
  73 check_function_exists(res_query HAVE_RES_QUERY)
  74 check_function_exists(__res_query HAVE___RES_QUERY)
  75
  76 check_function_exists(res_nquery HAVE_RES_NQUERY)
  77 check_function_exists(__res_nquery HAVE___RES_NQUERY)
  78
  79 check_function_exists(res_search HAVE_RES_SEARCH)
  80 check_function_exists(__res_search HAVE___RES_SEARCH)
  81
  82 check_function_exists(res_nsearch HAVE_RES_NSEARCH)
  83 check_function_exists(__res_nsearch HAVE___RES_NSEARCH)
  84
  85 set(CMAKE_REQUIRED_LIBRARIES)
  86
  87 check_library_exists(dl dlopen "" HAVE_LIBDL)
  88 if (HAVE_LIBDL)
  89     find_library(DLFCN_LIBRARY dl)
  90     set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} ${DLFCN_LIBRARY})
  91 endif (HAVE_LIBDL)
  92
  93 # IPV6
  94 check_c_source_compiles("
  95     #include <stdlib.h>
  96     #include <sys/socket.h>
  97     #include <netdb.h>
  98     #include <netinet/in.h>
  99     #include <net/if.h>
 100
 101 int main(void) {
 102     struct sockaddr_storage sa_store;
 103     struct addrinfo *ai = NULL;
 104     struct in6_addr in6addr;
 105     int idx = if_nametoindex(\"iface1\");
 106     int s = socket(AF_INET6, SOCK_STREAM, 0);
 107     int ret = getaddrinfo(NULL, NULL, NULL, &ai);
 108     if (ret != 0) {
 109         const char *es = gai_strerror(ret);
 110     }
 111
 112     freeaddrinfo(ai);
 113     {
 114         int val = 1;
 115 #ifdef HAVE_LINUX_IPV6_V6ONLY_26
 116 #define IPV6_V6ONLY 26
 117 #endif
 118         ret = setsockopt(s, IPPROTO_IPV6, IPV6_V6ONLY,
 119                          (const void *)&val, sizeof(val));
 120     }
 121
 122     return 0;
 123 }" HAVE_IPV6)
 124
 125 check_struct_has_member("struct __res_state" _u._ext.nsaddrs resolv.h HAVE_RESOLV_IPV6_NSADDRS)
 126
 127 check_c_source_compiles("
 128 void log_fn(const char *format, ...) __attribute__ ((format (printf, 1, 2)));
 129
 130 int main(void) {
 131     return 0;
 132 }" HAVE_ATTRIBUTE_PRINTF_FORMAT)
 133
 134 check_c_source_compiles("
 135 void test_destructor_attribute(void) __attribute__ ((destructor));
 136
 137 void test_destructor_attribute(void)
 138 {
 139     return;
 140 }
 141
 142 int main(void) {
 143     return 0;
 144 }" HAVE_DESTRUCTOR_ATTRIBUTE)
 145
 146 # ENDIAN
 147 test_big_endian(WORDS_BIGENDIAN)
 148
 149 set(RWRAP_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} CACHE INTERNAL "resolv_wrapper required system libraries")