CMakeLists.txt

   1 # CMakeLists.txt
   2 #
   3 # Wireshark - Network traffic analyzer
   4 # By Gerald Combs <gerald@wireshark.org>
   5 # Copyright 1998 Gerald Combs
   6 #
   7 # SPDX-License-Identifier: GPL-2.0-or-later
   8 #
   9
  10 project(Wireshark C CXX)
  11
  12 # Updated by make-version.pl
  13 set(GIT_REVISION 0)
  14 set(PROJECT_MAJOR_VERSION 2)
  15 set(PROJECT_MINOR_VERSION 9)
  16 set(PROJECT_PATCH_VERSION 0)
  17 set(PROJECT_BUILD_VERSION ${GIT_REVISION})
  18 set(PROJECT_VERSION_EXTENSION "")
  19 set(PROJECT_RELEASE_VERSION "${PROJECT_MAJOR_VERSION}.${PROJECT_MINOR_VERSION}")
  20
  21 if(DEFINED ENV{WIRESHARK_VERSION_EXTRA})
  22         set(PROJECT_VERSION_EXTENSION "$ENV{WIRESHARK_VERSION_EXTRA}")
  23 endif()
  24
  25 set(PROJECT_VERSION "${PROJECT_MAJOR_VERSION}.${PROJECT_MINOR_VERSION}.${PROJECT_PATCH_VERSION}${PROJECT_VERSION_EXTENSION}")
  26
  27 # packaging information
  28 if(WIN32)
  29         set(CPACK_PACKAGE_NAME Wireshark)
  30 else()
  31         set(CPACK_PACKAGE_NAME wireshark)
  32 endif()
  33
  34 set(CPACK_PACKAGE_VERSION "${PROJECT_VERSION}")
  35
  36 message(STATUS "Generating build using CMake ${CMAKE_VERSION}")
  37 if(WIN32)
  38         # Needed for GREATER_EQUAL operator
  39         cmake_minimum_required(VERSION 3.7)
  40 else()
  41         cmake_minimum_required(VERSION 3.5)
  42 endif()
  43
  44 #Where to find local cmake scripts
  45 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  46
  47 # If our target platform is enforced by our generator, set
  48 # WIRESHARK_TARGET_PLATFORM accordingly. Otherwise use
  49 # %WIRESHARK_TARGET_PLATFORM%.
  50
  51 if(WIN32)
  52         find_package(PowerShell REQUIRED)
  53
  54         if(CMAKE_CL_64 OR CMAKE_GENERATOR MATCHES "Win64")
  55                 set(WIRESHARK_TARGET_PLATFORM win64)
  56         elseif(CMAKE_GENERATOR MATCHES "Visual Studio")
  57                 set(WIRESHARK_TARGET_PLATFORM win32)
  58         else()
  59                 set(WIRESHARK_TARGET_PLATFORM $ENV{WIRESHARK_TARGET_PLATFORM})
  60         endif()
  61
  62         if(WIRESHARK_TARGET_PLATFORM MATCHES "win64")
  63                 set(WIRESHARK_TARGET_PROCESSOR_ARCHITECTURE amd64)
  64         else()
  65                 set(WIRESHARK_TARGET_PROCESSOR_ARCHITECTURE x86)
  66         endif()
  67
  68         # Sanity check
  69         if(DEFINED ENV{PLATFORM})
  70                 string(TOLOWER $ENV{PLATFORM} _vs_platform)
  71         else()
  72                 set(_vs_platform "[undefined]") # x86
  73         endif()
  74         if(
  75                 (_vs_platform STREQUAL "x64" AND NOT WIRESHARK_TARGET_PLATFORM STREQUAL "win64")
  76                 OR
  77                 (_vs_platform STREQUAL "[undefined]" AND NOT WIRESHARK_TARGET_PLATFORM STREQUAL "win32")
  78         )
  79                 message(FATAL_ERROR "The PLATFORM environment variable (${_vs_platform})"
  80                         " doesn't match the generator platform (${WIRESHARK_TARGET_PLATFORM})")
  81         endif()
  82         message(STATUS "Building for ${WIRESHARK_TARGET_PLATFORM} using ${CMAKE_GENERATOR}")
  83
  84         # Determine where the 3rd party libraries will be
  85         if( DEFINED ENV{WIRESHARK_LIB_DIR} )
  86                 # The buildbots set WIRESHARK_LIB_DIR but not WIRESHARK_BASE_DIR.
  87                 file( TO_CMAKE_PATH "$ENV{WIRESHARK_LIB_DIR}" _PROJECT_LIB_DIR )
  88         elseif( DEFINED ENV{WIRESHARK_BASE_DIR} )
  89                 file( TO_CMAKE_PATH "$ENV{WIRESHARK_BASE_DIR}" _WS_BASE_DIR )
  90                 set( _PROJECT_LIB_DIR "${_WS_BASE_DIR}/wireshark-${WIRESHARK_TARGET_PLATFORM}-libs" )
  91         else()
  92                 # Don't know what to do
  93                 message(FATAL_ERROR "Neither WIRESHARK_BASE_DIR or WIRESHARK_LIB_DIR are defined")
  94         endif()
  95
  96         # Download third-party libraries
  97         file (TO_NATIVE_PATH ${CMAKE_SOURCE_DIR}/tools/win-setup.ps1 _win_setup)
  98         file (TO_NATIVE_PATH ${_PROJECT_LIB_DIR} _ws_lib_dir)
  99
 100         # Is it possible to have a one-time, non-cached option in CMake? If
 101         # so, we could add a "-DFORCE_WIN_SETUP" which passes -Force to
 102         # win-setup.ps1.
 103         execute_process(
 104                 COMMAND ${POWERSHELL_COMMAND} "\"${_win_setup}\"" -Destination "${_ws_lib_dir}" -Platform ${WIRESHARK_TARGET_PLATFORM}
 105                 RESULT_VARIABLE _win_setup_failed
 106         )
 107         if(_win_setup_failed)
 108                 message(FATAL_ERROR "Windows setup (win-setup.ps1) failed.")
 109         endif()
 110
 111         # XXX Add a dependency on ${_ws_lib_dir}/current_tag.txt?
 112
 113         # Head off any attempts to use Cygwin's Python.
 114         include(LocatePythonExecutable)
 115
 116         # Prepopulate some ConfigureChecks values. Compilation checks
 117         # on Windows can be slow.
 118         set(HAVE_FCNTL_H TRUE)
 119         set(HAVE_FLOORL TRUE)
 120         set(HAVE_LRINT TRUE)
 121
 122         # It looks like we call check_type_size somewhere, which checks
 123         # for these.
 124         set(HAVE_SYS_TYPES_H TRUE)
 125         set(HAVE_STDINT_H TRUE)
 126         set(HAVE_STDDEF_H TRUE)
 127 endif(WIN32)
 128
 129 include(UseCustomIncludes)
 130 ADD_CUSTOM_CMAKE_INCLUDE()
 131
 132 # This cannot be implemented via option(...)
 133 if( NOT CMAKE_BUILD_TYPE )
 134         set( CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 135                 "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
 136                 FORCE)
 137 endif()
 138 message(STATUS "Configuration types: ${CMAKE_CONFIGURATION_TYPES}")
 139 string(TOUPPER "${CMAKE_BUILD_TYPE}" _build_type)
 140 message(STATUS "CMAKE_C_FLAGS_${_build_type}: ${CMAKE_C_FLAGS_${_build_type}}")
 141 message(STATUS "CMAKE_CXX_FLAGS_${_build_type}: ${CMAKE_CXX_FLAGS_${_build_type}}")
 142
 143 # Ensure that all executables and libraries end up in the same directory. Actual
 144 # files might end up in a configuration subdirectory, e.g. run/Debug or
 145 # run/Release. We try to set DATAFILE_DIR to actual location below.
 146 if(NOT ARCHIVE_OUTPUT_PATH)
 147         set(ARCHIVE_OUTPUT_PATH ${Wireshark_BINARY_DIR}/run CACHE INTERNAL
 148                    "Single output directory for building all archives.")
 149 endif()
 150 if(NOT EXECUTABLE_OUTPUT_PATH)
 151         set(EXECUTABLE_OUTPUT_PATH ${Wireshark_BINARY_DIR}/run CACHE INTERNAL
 152                    "Single output directory for building all executables.")
 153 endif()
 154 if(NOT LIBRARY_OUTPUT_PATH)
 155         set(LIBRARY_OUTPUT_PATH ${Wireshark_BINARY_DIR}/run CACHE INTERNAL
 156                    "Single output directory for building all libraries.")
 157 endif()
 158
 159 #
 160 # The release mode (CMAKE_BUILD_TYPE=release) defines NDEBUG for
 161 # the Unix Makefile generator.
 162 #
 163
 164 #Defines CMAKE_INSTALL_BINDIR, CMAKE_INSTALL_DATADIR, etc ...
 165 include(GNUInstallDirs)
 166 # Make sure our executables can can load our libraries if we install into
 167 # a non-default directory on Unix-like systems other than macOS.
 168 # https://cmake.org/Wiki/CMake_RPATH_handling
 169 if(NOT CMAKE_INSTALL_RPATH AND NOT (WIN32 OR APPLE))
 170         LIST(FIND CMAKE_C_IMPLICIT_LINK_DIRECTORIES "${CMAKE_INSTALL_FULL_LIBDIR}" IS_SYSTEM_DIR)
 171         if(IS_SYSTEM_DIR STREQUAL "-1")
 172                 SET(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_FULL_LIBDIR}")
 173                 SET(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 174         endif()
 175 endif()
 176
 177 # Banner shown at top right of Qt welcome screen.
 178 if(DEFINED ENV{WIRESHARK_VERSION_FLAVOR})
 179         set(VERSION_FLAVOR "$ENV{WIRESHARK_VERSION_FLAVOR}")
 180 else()
 181         set(VERSION_FLAVOR "Development Build")
 182 endif()
 183
 184 # These are required in .rc files and manifests
 185 set(VERSION_MAJOR ${PROJECT_MAJOR_VERSION})
 186 set(VERSION_MINOR ${PROJECT_MINOR_VERSION})
 187 set(VERSION_MICRO ${PROJECT_PATCH_VERSION})
 188 set(VERSION_BUILD ${PROJECT_BUILD_VERSION})
 189 set(RC_VERSION ${PROJECT_MAJOR_VERSION},${PROJECT_MINOR_VERSION},${PROJECT_PATCH_VERSION},${PROJECT_BUILD_VERSION})
 190
 191 message(STATUS "V: ${PROJECT_VERSION}, MaV: ${PROJECT_MAJOR_VERSION}, MiV: ${PROJECT_MINOR_VERSION}, PL: ${PROJECT_PATCH_VERSION}, EV: ${PROJECT_VERSION_EXTENSION}.")
 192
 193 include(UseLemon)
 194 include(UseMakePluginReg)
 195 include(UseMakeTaps)
 196 include(UseAsn2Wrs)
 197
 198 # The following snippet has been taken from
 199 # https://github.com/USESystemEngineeringBV/cmake-eclipse-helper/wiki/HowToWorkaroundIndexer
 200 # The eclipse indexer otherwise assumes __cplusplus=199711L which will lead to broken
 201 # lookup tables for the epan libraries
 202 # Check if CXX flags have been set to c++11 -> Setup Eclipse Indexer correctly!
 203 # Also setup the project slightly different
 204 if(CMAKE_EXTRA_GENERATOR MATCHES "Eclipse CDT4")
 205         SET(CXX_ENABLED 0)
 206         LIST(LENGTH CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS LIST_LEN)
 207         if(LIST_LEN GREATER 0)
 208                 SET(CXX_ENABLED 1)
 209         endif()
 210         SET(C_ENABLED 0)
 211         LIST(LENGTH CMAKE_EXTRA_GENERATOR_C_SYSTEM_DEFINED_MACROS LIST_LEN)
 212         if(LIST_LEN GREATER 0)
 213                 SET(C_ENABLED 1)
 214         endif()
 215         if(C_ENABLED EQUAL 1 AND CXX_ENABLED EQUAL 1)
 216                 # Combined project (C and CXX). This will confuse the indexer. For that reason
 217                 # we unsert set the __cplusplus variable for the indexer
 218                 list(FIND CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS "__cplusplus" GEN_MACRO_INDEX)
 219                 if(GEN_MACRO_INDEX GREATER -1)
 220                         list(REMOVE_AT CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS ${GEN_MACRO_INDEX})
 221                         list(REMOVE_AT CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS ${GEN_MACRO_INDEX})
 222                 endif()
 223                 SET(CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS ${CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS} CACHE INTERNAL "")
 224         elseif((CXX_ENABLED EQUAL 1) AND (CMAKE_CXX_FLAGS MATCHES ".*-std=c\\+\\+11.*"))
 225                 #add_definitions (-D__cplusplus=201103L)
 226                 # CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS
 227                 list(FIND CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS "199711L" GEN_MACRO_INDEX)
 228                 if(GEN_MACRO_INDEX GREATER -1)
 229                         list(REMOVE_AT CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS ${GEN_MACRO_INDEX})
 230                         list(INSERT CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS ${GEN_MACRO_INDEX} "201103L")
 231                         SET(CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS ${CMAKE_EXTRA_GENERATOR_CXX_SYSTEM_DEFINED_MACROS} CACHE INTERNAL "")
 232                 endif()
 233         endif()
 234 endif()
 235
 236 include_directories(
 237         ${CMAKE_BINARY_DIR}
 238         ${CMAKE_SOURCE_DIR}
 239 )
 240
 241 include( CMakeOptions.txt )
 242 if( DUMPCAP_INSTALL_OPTION STREQUAL "suid" )
 243         set( DUMPCAP_SETUID "SETUID" )
 244 else()
 245         set( DUMPCAP_SETUID )
 246 endif()
 247 if( NOT CMAKE_SYSTEM_NAME STREQUAL "Linux" AND
 248         DUMPCAP_INSTALL_OPTION STREQUAL "capabilities" )
 249         message( WARNING "Capabilities are only supported on Linux" )
 250         set( DUMPCAP_INSTALL_OPTION )
 251 endif()
 252
 253 if(APPLE AND EXISTS /usr/local/opt/qt5)
 254         # Homebrew installs Qt5 (up to at least 5.11.0) in
 255         # /usr/local/qt5. Ensure that it can be found by CMake
 256         # since it is not in the default /usr/local prefix.
 257         # Add it to PATHS so that it doesn't override the
 258         # CMAKE_PREFIX_PATH environment variable.
 259         # QT_FIND_PACKAGE_OPTIONS should be passed to find_package,
 260         # e.g. find_package(Qt5Core ${QT_FIND_PACKAGE_OPTIONS})
 261         set (QT_FIND_PACKAGE_OPTIONS PATHS /usr/local/opt/qt5)
 262 endif()
 263
 264 # Always enable position-independent code when compiling, even for
 265 # executables, so you can build position-independent executables.
 266 # -pie is added below for non-MSVC.
 267 # Needed when either:
 268 # - Qt5_POSITION_INDEPENDENT_CODE is set and CMake < 2.8.11
 269 # - PIE is wanted (-pie) and you want to add -fPIC/-fPIE automatically.
 270 # This option only has an effect on CMake >= 2.8.9
 271 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 272
 273 # Path to our generated executables (or wrapper scripts)
 274 if(WIN32)
 275         set(WS_PROGRAM_PATH ./run/$<CONFIG>)
 276 else()
 277         set(WS_PROGRAM_PATH ./run)
 278 endif()
 279
 280 if( CMAKE_C_COMPILER_ID MATCHES "MSVC")
 281         if ((MSVC_VERSION LESS "1900") OR (MSVC_VERSION GREATER_EQUAL "2000"))
 282                 message(FATAL_ERROR "You are using an unsupported version of MSVC")
 283         endif()
 284
 285         add_definitions(
 286                 /DWIN32_LEAN_AND_MEAN
 287                 /D_CRT_SECURE_NO_DEPRECATE
 288                 # NOMINMAX keeps windows.h from defining "min" and "max" via windef.h.
 289                 # This avoids conflicts with the C++ standard library.
 290                 /DNOMINMAX
 291                 # -DPSAPI_VERSION=1                 Programs that must run on earlier versions of Windows as well as Windows 7 and later
 292                 #                                   versions should always call this function as GetProcessMemoryInfo. To ensure correct
 293                 #                                   resolution of symbols, add Psapi.lib to the TARGETLIBS macro and compile the program
 294                 #                                   with -DPSAPI_VERSION=1.To use run-time dynamic linking, load Psapi.dll.
 295                 #                                   http://msdn.microsoft.com/en-us/library/windows/desktop/ms683219(v=vs.85).aspx
 296                 # -D_ALLOW_KEYWORD_MACROS           For VS2012 onwards the, C++ STL does not permit macro redefinitions of keywords
 297                 #                                   (see http://msdn.microsoft.com/en-us/library/bb531344(v=vs.110).aspx)
 298                 #                                   This definition prevents the complaint about the redefinition of inline by WinPCap
 299                 #                                   in pcap-stdinc.h when compiling C++ files, e.g. the Qt UI
 300                 /DPSAPI_VERSION=1
 301                 /D_ALLOW_KEYWORD_MACROS
 302         )
 303
 304         if(NOT WIRESHARK_TARGET_PLATFORM STREQUAL "win64")
 305                 add_definitions("/D_BIND_TO_CURRENT_CRT_VERSION=1")
 306         endif()
 307
 308         # FIXME: WINPCAP_VERSION cannot be determined from source or executable.
 309         set(WINPCAP_VERSION "4_1_3")
 310         add_definitions("/DWINPCAP_VERSION=${WINPCAP_VERSION}")
 311
 312         set(LOCAL_CFLAGS
 313                 /MP
 314         )
 315
 316         set(WS_LINK_FLAGS "/LARGEADDRESSAWARE /MANIFEST:NO /INCREMENTAL:NO /RELEASE")
 317
 318         # To do: Add /external:... See https://blogs.msdn.microsoft.com/vcblog/2017/12/13/broken-warnings-theory/
 319         #
 320         # /Zo                               Enhanced debugging of optimised code
 321         # /utf-8                            Set Source and Executable character sets to UTF-8
 322         #                                   VS2015(MSVC14): On by default when /Zi or /Z7 used.
 323         # /guard:cf                         Control Flow Guard (compile and link).
 324         #                                   See https://msdn.microsoft.com/en-us/library/windows/desktop/mt637065.aspx
 325         #                                   Note: This requires CMake 3.9.0 or newer.
 326         #                                   https://gitlab.kitware.com/cmake/cmake/commit/f973d49ab9d4c59b93f6dac812a94bb130200836
 327         # /Qspectre                         Speculative execution attack mitigation
 328         #                                   See https://blogs.msdn.microsoft.com/vcblog/2018/01/15/spectre-mitigations-in-msvc/
 329         list(APPEND LOCAL_CFLAGS /Zo /utf-8 /guard:cf)
 330         set(WS_LINK_FLAGS "${WS_LINK_FLAGS} /guard:cf")
 331         # /Qspectre is not available for VS2015 or older VS2017. Test for its availability.
 332         set(WIRESHARK_COMMON_FLAGS /Qspectre)
 333
 334         if(ENABLE_CODE_ANALYSIS)
 335                 list(APPEND LOCAL_CFLAGS /analyze:WX-)
 336         endif()
 337
 338         # Additional compiler warnings to be treated as "Level 3"
 339         # when compiling Wireshark sources. (Selected from "level 4" warnings).
 340         ## 4295: array is too small to include a terminating null character
 341         ## 4189: local variable is initialized but not referenced
 342         # Disable warnings about about use of flexible array members:
 343         ## 4200: nonstandard extension used : zero-sized array in struct/union
 344         list(APPEND LOCAL_CFLAGS /w34295 /w34189 /wd4200)
 345
 346         # We've matched these to specific compiler versions using the
 347         # checks above. There's no need to pass them to check_c_compiler_flag
 348         # or check_cxx_compiler_flag, which can be slow.
 349         string(REPLACE ";" " " _flags "${LOCAL_CFLAGS}")
 350         set(CMAKE_C_FLAGS "${_flags} ${CMAKE_C_FLAGS}")
 351         set(CMAKE_CXX_FLAGS "${_flags} ${CMAKE_CXX_FLAGS}")
 352
 353 else() # ! MSVC
 354         if(CMAKE_OSX_DEPLOYMENT_TARGET)
 355                 if(APPLE)
 356                         if(CMAKE_OSX_DEPLOYMENT_TARGET STREQUAL "10.0")
 357                                 message(FATAL_ERROR "We don't support building for Mac OS X 10.0")
 358                         elseif(CMAKE_OSX_DEPLOYMENT_TARGET STREQUAL "10.1")
 359                                 message(FATAL_ERROR "We don't support building for Mac OS X 10.1")
 360                         elseif(CMAKE_OSX_DEPLOYMENT_TARGET STREQUAL "10.2")
 361                                 message(FATAL_ERROR "We don't support building for Mac OS X 10.2")
 362                         elseif(CMAKE_OSX_DEPLOYMENT_TARGET STREQUAL "10.4" OR CMAKE_OSX_DEPLOYMENT_TARGET STREQUAL "10.5")
 363                                 #
 364                                 # Only 32-bit builds are supported.  10.5
 365                                 # (and 10.4?) had a bug that causes some BPF
 366                                 # functions not to work with 64-bit userland
 367                                 # code, so capturing won't work.
 368                                 #
 369                                 set(CMAKE_C_FLAGS "-m32 ${CMAKE_C_FLAGS}")
 370                                 set(CMAKE_CXX_FLAGS "-m32 ${CMAKE_CXX_FLAGS}")
 371                                 set(WS_LINK_FLAGS "-m32 ${WS_LINK_FLAGS}")
 372                         endif()
 373                         message(STATUS "Building for Mac OS X/OS X/macOS ${CMAKE_OSX_DEPLOYMENT_TARGET}")
 374                 else()
 375                         message(FATAL_ERROR "CMAKE_OSX_DEPLOYMENT_TARGET only applies when building for macOS")
 376                 endif()
 377         endif()
 378
 379         #
 380         # Do whatever is necessary to enable as much C99 support as
 381         # possible in the C compiler.  Newer versions of compilers
 382         # might default to supporting C99, but older versions may
 383         # require a special flag.
 384         #
 385         # We do not want strict C99 support, as we may also want to
 386         # use compiler extensions.
 387         #
 388         # Prior to CMake 3.1, setting CMAKE_C_STANDARD will not have
 389         # any effect, so, unless and until we require CMake 3.1 or
 390         # later, we have to do it ourselves on pre-3.1 CMake, so we
 391         # just do it ourselves on all versions of CMake.
 392         #
 393         # Note: with CMake 3.1 through 3.5, the only compilers for
 394         # which CMake handles CMAKE_C_STANDARD are GCC and Clang.
 395         # 3.6 adds support only for Intel C; 3.9 adds support for
 396         # PGI C, Sun C, and IBM XL C, and 3.10 adds support for
 397         # Cray C and IAR C, but no version of CMake has support for
 398         # HP C.  Therefore, even if we use CMAKE_C_STANDARD with
 399         # compilers for which CMake supports it, we may still have
 400         # to do it ourselves on other compilers.
 401         #
 402         # In addition, CMake 3.5.2 seems to think that GCC versions
 403         # less than 4.4 don't support -std=gnu99, which we need in
 404         # order to get support for "for (int i = 0; i < n; i++) ;",
 405         # which is another reason not to rely on CMake's CMAKE_C_STANDARD
 406         # support.
 407         #
 408         # See the CMake documentation for the CMAKE_<LANG>_COMPILER_ID
 409         # variables for a list of compiler IDs.
 410         #
 411         # We don't worry about MSVC; it doesn't have such a flag -
 412         # either it doesn't support the C99 features we need at all,
 413         # or it supports them regardless of the compiler flag.
 414         #
 415         # XXX - we add the flag for a given compiler to CMAKE_C_FLAGS,
 416         # so we test whether it works and add it if we do.  We don't
 417         # test whether it's necessary in order to get the C99 features
 418         # that we use; if we ever have a user who tries to compile with
 419         # a compiler that can't be made to support those features, we
 420         # can add a test to make sure we actually *have* C99 support.
 421         #
 422         if(CMAKE_C_COMPILER_ID MATCHES "GNU" OR
 423            CMAKE_C_COMPILER_ID MATCHES "Clang")
 424                 #
 425                 # We use -std=gnu99 rather than -std=c99 because, for
 426                 # some older compilers such as GCC 4.4.7, -std=gnu99
 427                 # is required to avoid errors about C99 constructs
 428                 # such as "for (int i = 0; i < n; i++) ;".
 429                 #
 430                 set(CMAKE_C_FLAGS "-std=gnu99 ${CMAKE_C_FLAGS}")
 431         elseif(CMAKE_C_COMPILER_ID MATCHES "XL")
 432                 #
 433                 # We want support for extensions picked up for
 434                 # GNU C compatibility, so we use -qlanglvl=extc99.
 435                 #
 436                 set(CMAKE_C_FLAGS "-qlanglvl=extc99 ${CMAKE_C_FLAGS}")
 437         elseif(CMAKE_C_COMPILER_ID MATCHES "HP")
 438                 #
 439                 # We also need to add -Wp,-H200000 to handle some large
 440                 # #defines we have; that flag is not necessary for the
 441                 # C++ compiler unless the "legacy" C++ preprocessor is
 442                 # being used (+legacy_cpp).  We don't want the legacy
 443                 # preprocessor if it's not the default, so we just add
 444                 # -Wp,-H200000 to the C flags.  (If there are older
 445                 # versions of aC++ that only support the legacy
 446                 # preprocessor, and require that we boost the table
 447                 # size, we'd have to check whether -Wp,-H200000 is
 448                 # supported by the C++ compiler and add it only if it is.)
 449                 #
 450                 set(CMAKE_C_FLAGS "-AC99 -Wp,-H200000 $WS_CFLAGS ${CMAKE_C_FLAGS}")
 451         elseif(CMAKE_C_COMPILER_ID MATCHES "Sun")
 452                 #
 453                 # We also crank up the warning level.
 454                 #
 455                 set(CMAKE_C_FLAGS "-xc99 -v ${CMAKE_C_FLAGS}")
 456         elseif(CMAKE_C_COMPILER_ID MATCHES "Intel")
 457                 set(CMAKE_C_FLAGS "-c99 ${CMAKE_C_FLAGS}")
 458         endif()
 459
 460         if(CMAKE_C_COMPILER_ID MATCHES "Clang")
 461                 set(WIRESHARK_COMMON_FLAGS ${WIRESHARK_COMMON_FLAGS}
 462                         # avoid "argument unused during compilation" warnings
 463                         # (for example, when getting the -gsplit-dwarf option or
 464                         # when combining -fwrapv with -fno-strict-overflow)
 465                         -Qunused-arguments
 466                 )
 467         else()
 468                 set(WIRESHARK_COMMON_FLAGS ${WIRESHARK_COMMON_FLAGS}
 469                         -fexcess-precision=fast
 470                 )
 471         endif()
 472
 473         list(APPEND WIRESHARK_COMMON_FLAGS
 474                 # The following are for C and C++
 475                 # -O<X> and -g get set by the CMAKE_BUILD_TYPE
 476                 -Wall
 477                 -Wextra
 478                 -Wextra-semi
 479                 -Wendif-labels
 480                 -Wpointer-arith
 481                 -Wformat-security
 482                 -fwrapv
 483                 -fno-strict-overflow
 484                 -Wvla
 485                 -Waddress
 486                 -Wattributes
 487                 -Wdiv-by-zero
 488                 -Wignored-qualifiers
 489                 -Wpragmas
 490                 -Wno-overlength-strings
 491                 -Wno-long-long
 492                 -Wheader-guard
 493                 -Wcomma
 494                 -Wshorten-64-to-32
 495         )
 496
 497         #
 498         # Code that may be worth looking into (coding practices)
 499         #
 500         if((NOT ENABLE_ASAN) AND (NOT ENABLE_TSAN) AND (NOT ENABLE_UBSAN) AND (NOT DISABLE_FRAME_LARGER_THAN_WARNING))
 501                 #
 502                 # Only do this if none of ASan, TSan, and UBSan are
 503                 # enabled; the instrumentation they add increases
 504                 # the stack usage - we only care about stack
 505                 # usage in normal operation.
 506                 #
 507                 set(WIRESHARK_COMMON_FLAGS ${WIRESHARK_COMMON_FLAGS}
 508                         -Wframe-larger-than=32768
 509                 )
 510         endif()
 511
 512         list(APPEND WIRESHARK_C_ONLY_FLAGS
 513                 # The following are C only, not C++
 514                 -Wc++-compat
 515                 -Wunused-const-variable
 516                 #
 517                 # XXX - some versions of GCC, including the one in at
 518                 # least some Xcode versions that come with Mac OS X
 519                 # 10.5, complain about variables in function and
 520                 # function pointer *declarations* shadowing other
 521                 # variables.  The autoconf script checked for that; we
 522                 # don't.
 523                 -Wshadow
 524                 -Wno-pointer-sign
 525                 -Wold-style-definition
 526                 -Wstrict-prototypes
 527                 #
 528                 # Some versions of GCC, such as 4.3.2 and 4.4.5,
 529                 # generate logical-op warnings when strchr() is given a
 530                 # constant string.  The autoconf script checked for that;
 531                 # we don't.
 532                 #
 533                 -Wlogical-op
 534                 -Wjump-misses-init
 535                 #
 536                 # Implicit function declarations are an error in C++ and most
 537                 # likely a programming error in C. Turn -Wimplicit-int and
 538                 # -Wimplicit-function-declaration into an error by default.
 539                 #
 540                 -Werror=implicit
 541         )
 542
 543         list(APPEND WIRESHARK_CXX_ONLY_FLAGS
 544         )
 545
 546         #
 547         # These are not enabled by default, because the warnings they
 548         # produce are very hard or impossible to eliminate.
 549         #
 550         if(ENABLE_EXTRA_COMPILER_WARNINGS)   # This overrides -Werror
 551                 list(APPEND WIRESHARK_COMMON_FLAGS
 552                         # The following are for C and C++
 553                         -Wpedantic
 554                         #
 555                         # As we use variadic macros, we don't want warnings
 556                         # about them, even with -Wpedantic.
 557                         #
 558                         -Wno-variadic-macros
 559                         #
 560                         # Various code blocks this one.
 561                         #
 562                         -Woverflow
 563                         -fstrict-overflow -Wstrict-overflow=4
 564                         #
 565                         # Due to various places where APIs we don't control
 566                         # require us to cast away constness, we can probably
 567                         # never enable this one with -Werror.
 568                         #
 569                         -Wcast-qual
 570                         #
 571                         # Some generated ASN.1 dissectors block this one;
 572                         # multiple function declarations for the same
 573                         # function are being generated.
 574                         #
 575                         -Wredundant-decls
 576                         #
 577                         # Some loops are safe, but it's hard to convince the
 578                         # compiler of that.
 579                         #
 580                         -Wunsafe-loop-optimizations
 581                         #
 582                         # All the registration functions block these for now.
 583                         #
 584                         -Wmissing-prototypes
 585                         -Wmissing-declarations
 586                         #
 587                         # A bunch of "that might not work on SPARC" code blocks
 588                         # this one for now; some of it is code that *will* work
 589                         # on SPARC, such as casts of "struct sockaddr *" to
 590                         # "struct sockaddr_in *", which are required by some
 591                         # APIs such as getifaddrs().
 592                         #
 593                         -Wcast-align
 594                         #
 595                         # Works only with Clang
 596                         #
 597                         -Wunreachable-code
 598                         #
 599                         # Works only with Clang but generates a lot of warnings
 600                         # (about glib library not using Doxygen)
 601                         #
 602                         -Wdocumentation
 603                         #
 604                         # Works only with GCC 7
 605                         #
 606                         -Wduplicated-branches
 607                         #
 608                         # No longer supported by El Capitan clang on C++
 609                         # XXX - is this one of those where CMake's check
 610                         # doesn't fail, so it won't reject this?
 611                         #
 612                         -fno-delete-null-pointer-checks
 613                 )
 614
 615                 list(APPEND WIRESHARK_C_ONLY_FLAGS
 616                         # The following are C only, not C++
 617                         #
 618                         # Due to various places where APIs we don't control
 619                         # require us to cast away constness, we can probably
 620                         # never enable this one with -Werror.
 621                         #
 622                         -Wbad-function-cast
 623                 )
 624
 625                 list(APPEND WIRESHARK_CXX_ONLY_FLAGS
 626                 )
 627         endif()
 628
 629         add_definitions(
 630                 -DG_DISABLE_DEPRECATED
 631                 -DG_DISABLE_SINGLE_INCLUDES
 632         )
 633
 634         set(WIRESHARK_LD_FLAGS
 635                 # See also CheckCLinkerFlag.cmake
 636                 -Wl,--as-needed
 637                 # -flto
 638                 # -fwhopr
 639                 # -fwhole-program
 640                 # XXX: This is applicable only when linking executables.
 641                 -pie
 642         )
 643 endif() # ! MSVC
 644
 645 # Counterhack to work around some cache magic in CHECK_C_SOURCE_COMPILES
 646 include(CheckCCompilerFlag)
 647 include(CheckCXXCompilerFlag)
 648
 649 if(ENABLE_STATIC)
 650         set(BUILD_SHARED_LIBS 0)
 651 else()
 652         set(BUILD_SHARED_LIBS 1)
 653 endif()
 654
 655 function(test_compiler_flag _lang _this_flag _valid_flags_var)
 656         string(MAKE_C_IDENTIFIER "${_lang}${_this_flag}_VALID" _flag_var)
 657         set(_test_flags "${${_valid_flags_var}} ${_this_flag}")
 658         if(_lang STREQUAL "C")
 659                 check_c_compiler_flag("${_test_flags}" ${_flag_var})
 660         elseif(_lang STREQUAL "CXX")
 661                 check_cxx_compiler_flag("${_test_flags}" ${_flag_var})
 662         else()
 663                 message(FATAL_ERROR "Language must be C or CXX")
 664         endif()
 665         if (${_flag_var})
 666                 set(${_valid_flags_var} "${_test_flags}" PARENT_SCOPE)
 667         endif()
 668 endfunction()
 669
 670 foreach(THIS_FLAG ${WIRESHARK_COMMON_FLAGS} ${WIRESHARK_C_ONLY_FLAGS})
 671         test_compiler_flag(C ${THIS_FLAG} ADDED_CMAKE_C_FLAGS)
 672 endforeach()
 673 set(CMAKE_C_FLAGS "${ADDED_CMAKE_C_FLAGS} ${CMAKE_C_FLAGS}")
 674
 675 foreach(THIS_FLAG ${WIRESHARK_COMMON_FLAGS} ${WIRESHARK_CXX_ONLY_FLAGS})
 676         test_compiler_flag(CXX ${THIS_FLAG} ADDED_CMAKE_CXX_FLAGS)
 677 endforeach()
 678 set(CMAKE_CXX_FLAGS "${ADDED_CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 679
 680 include(CMakePushCheckState)
 681
 682 if(ENABLE_ASAN)
 683         cmake_push_check_state()
 684         set(CMAKE_REQUIRED_LIBRARIES "-fsanitize=address")
 685         check_c_compiler_flag(-fsanitize=address C__fsanitize_address_VALID)
 686         check_cxx_compiler_flag(-fsanitize=address CXX__fsanitize_address_VALID)
 687         cmake_pop_check_state()
 688         if(NOT C__fsanitize_address_VALID OR NOT CXX__fsanitize_address_VALID)
 689                 message(FATAL_ERROR "ENABLE_ASAN was requested, but not supported!")
 690         endif()
 691         set(CMAKE_C_FLAGS "-fsanitize=address ${CMAKE_C_FLAGS}")
 692         set(CMAKE_CXX_FLAGS "-fsanitize=address ${CMAKE_CXX_FLAGS}")
 693         # Disable ASAN for build-time tools, e.g. lemon
 694         check_c_compiler_flag(-fno-sanitize=all C__fno_sanitize_all_VALID)
 695         if(C__fno_sanitize_all_VALID)
 696                 set(NO_SANITIZE_CFLAGS "-fno-sanitize=all")
 697                 set(NO_SANITIZE_LDFLAGS "-fno-sanitize=all")
 698         endif()
 699 endif()
 700
 701 if(ENABLE_TSAN)
 702         # Available since Clang >= 3.2 and GCC >= 4.8
 703         cmake_push_check_state()
 704         set(CMAKE_REQUIRED_LIBRARIES "-fsanitize=thread")
 705         check_c_compiler_flag(-fsanitize=thread C__fsanitize_thread_VALID)
 706         check_cxx_compiler_flag(-fsanitize=thread CXX__fsanitize_thread_VALID)
 707         cmake_pop_check_state()
 708         if(NOT C__fsanitize_thread_VALID OR NOT CXX__fsanitize_thread_VALID)
 709                 message(FATAL_ERROR "ENABLE_TSAN was requested, but not supported!")
 710         endif()
 711         set(CMAKE_C_FLAGS "-fsanitize=thread ${CMAKE_C_FLAGS}")
 712         set(CMAKE_CXX_FLAGS "-fsanitize=thread ${CMAKE_CXX_FLAGS}")
 713         set(WS_LINK_FLAGS "-fsanitize=thread ${WS_LINK_FLAGS}")
 714 endif()
 715
 716 if(ENABLE_UBSAN)
 717         # Available since Clang >= 3.3 and GCC >= 4.9
 718         cmake_push_check_state()
 719         set(CMAKE_REQUIRED_LIBRARIES "-fsanitize=undefined")
 720         check_c_compiler_flag(-fsanitize=undefined C__fsanitize_undefined_VALID)
 721         check_cxx_compiler_flag(-fsanitize=undefined CXX__fsanitize_undefined_VALID)
 722         cmake_pop_check_state()
 723         if(NOT C__fsanitize_undefined_VALID OR NOT CXX__fsanitize_undefined_VALID)
 724                 message(FATAL_ERROR "ENABLE_UBSAN was requested, but not supported!")
 725         endif()
 726         set(CMAKE_C_FLAGS "-fsanitize=undefined ${CMAKE_C_FLAGS}")
 727         set(CMAKE_CXX_FLAGS "-fsanitize=undefined ${CMAKE_CXX_FLAGS}")
 728 endif()
 729
 730 set(WERROR_COMMON_FLAGS "")
 731 if(NOT DISABLE_WERROR AND NOT ENABLE_EXTRA_COMPILER_WARNINGS)
 732         if(CMAKE_C_COMPILER_ID MATCHES "MSVC")
 733                 set(WERROR_COMMON_FLAGS "/WX")
 734         else()
 735                 #
 736                 # If a warning has been enabled by -Wall or -W,
 737                 # and have specified -Werror, there appears to be
 738                 # no way, in Apple's llvm-gcc, to prevent that
 739                 # particular warning from giving an error - not
 740                 # with a pragma, not with -Wno-{warning}, and not
 741                 # with -Wno-error={warning}.
 742                 #
 743                 # Therefore, with that compiler, we just disable
 744                 # -Werror.
 745                 #
 746                 if ((NOT APPLE) OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 747                         check_c_compiler_flag(-Werror WERROR)
 748                         if (WERROR)
 749                                 set(WERROR_COMMON_FLAGS "-Werror")
 750                         endif()
 751                 endif()
 752         endif()
 753 endif()
 754
 755 #
 756 # Try to have the compiler default to hiding symbols, so that only
 757 # symbols explicitly exported with WS_DLL_PUBLIC will be visible
 758 # outside (shared) libraries; that way, more UN*X builds will catch
 759 # failures to export symbols, rather than having that fail only on
 760 # Windows.
 761 #
 762 # We don't need that with MSVC, as that's the default.
 763 #
 764 if( NOT CMAKE_C_COMPILER_ID MATCHES "MSVC")
 765         #
 766         # Try the GCC-and-compatible -fvisibility-hidden first.
 767         #
 768         check_c_compiler_flag(-fvisibility=hidden FVHIDDEN)
 769         if(FVHIDDEN)
 770                 set(CMAKE_C_FLAGS "-fvisibility=hidden ${CMAKE_C_FLAGS}")
 771         else()
 772                 #
 773                 # OK, try the Sun^WOracle C -xldscope=hidden
 774                 #
 775                 check_c_compiler_flag(-xldscope=hidden XLDSCOPEHIDDEN)
 776                 if(XLDSCOPEHIDDEN)
 777                         set(CMAKE_C_FLAGS "-xldscope=hidden ${CMAKE_C_FLAGS}")
 778                 else()
 779                         #
 780                         # Anything else?
 781                         # If there is anything else, we might want to
 782                         # make a list of options to try, and try them
 783                         # in a loop.
 784                         #
 785                         message(WARNING "Hiding shared library symbols is not supported by the compiler."
 786                                 " All shared library symbols will be exported.")
 787                 endif()
 788         endif()
 789 endif()
 790
 791 include(CheckCLinkerFlag)
 792
 793 foreach(THIS_FLAG ${WIRESHARK_LD_FLAGS})
 794         string(MAKE_C_IDENTIFIER "LINK${THIS_FLAG}_VALID" _flag_var)
 795         check_c_linker_flag(${THIS_FLAG} ${_flag_var})
 796         if (${_flag_var})
 797                 set(WS_LINK_FLAGS "${WS_LINK_FLAGS} ${THIS_FLAG}")
 798         endif()
 799 endforeach()
 800 message(STATUS "Linker flags: ${WS_LINK_FLAGS}")
 801
 802 if(APPLE AND EXISTS /usr/local/opt/gettext)
 803         # GLib on macOS requires libintl. Homebrew installs gettext (and
 804         # libintl) in /usr/local/opt/gettext
 805         include_directories(/usr/local/opt/gettext/include)
 806         link_directories(/usr/local/opt/gettext/lib)
 807 endif()
 808
 809 # The packagelist is doing some magic: If we add XXX to the packagelist, we
 810 # - may optionally set XXX_OPTIONS to pass to the find_package command
 811 # - will call FindXXX.cmake or find_package
 812 # - return found libraries in XXX_LIBRARIES
 813 # - return found include in XXX_INCLUDE_DIRS
 814 # - set HAVE_XXX
 815
 816 # The minimum package list
 817 set(PACKAGELIST Git GLIB2 GMODULE2 GTHREAD2 GCRYPT LEX YACC Perl PythonInterp)
 818 set(LEX_OPTIONS REQUIRED)
 819 set(GLIB2_OPTIONS REQUIRED)
 820 set(GLIB2_FIND_OPTIONS REQUIRED)
 821 set(GLIB2_MIN_VERSION 2.32.0)
 822 set(GTHREAD2_OPTIONS REQUIRED)
 823 set(GCRYPT_OPTIONS "1.4.2" REQUIRED)
 824 set(Perl_OPTIONS REQUIRED)
 825 set(PythonInterp_FIND_VERSION 2)
 826 set(Python_ADDITIONAL_VERSIONS 3)
 827 set(YACC_OPTIONS REQUIRED)
 828
 829 if (NOT WIN32)
 830         set(PACKAGELIST ${PACKAGELIST} Gettext M)
 831         set(M_OPTIONS REQUIRED)
 832 endif()
 833
 834 set(PACKAGELIST ${PACKAGELIST} LIBSSH)
 835 set(LIBSSH_OPTIONS "0.6")
 836
 837 set(PACKAGELIST ${PACKAGELIST} JSONGLIB)
 838
 839 if(ENABLE_PCAP)
 840         set(PACKAGELIST ${PACKAGELIST} PCAP)
 841 endif()
 842
 843 if(ENABLE_AIRPCAP)
 844         set(PACKAGELIST ${PACKAGELIST} AIRPCAP)
 845 endif()
 846
 847 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
 848         set(PACKAGELIST ${PACKAGELIST} Systemd)
 849 endif()
 850
 851 # Build the Qt GUI?
 852 if(BUILD_wireshark)
 853         # Untested, may not work if CMAKE_PREFIX_PATH gets overwritten
 854         # somewhere. The if WIN32 in this place is annoying as well.
 855         if( WIN32 )
 856                 set( QT5_BASE_PATH "$ENV{QT5_BASE_DIR}" )
 857                 set( CMAKE_PREFIX_PATH "${QT5_BASE_PATH}" )
 858         endif()
 859         list (INSERT QT_FIND_PACKAGE_OPTIONS 0 REQUIRED)
 860         set(PACKAGELIST ${PACKAGELIST}
 861                 Qt5Core
 862                 Qt5LinguistTools
 863                 Qt5Multimedia
 864                 Qt5PrintSupport
 865                 Qt5Svg
 866                 Qt5Widgets
 867         )
 868         set(Qt5Core_OPTIONS ${QT_FIND_PACKAGE_OPTIONS})
 869         set(Qt5LinguistTools_OPTIONS ${QT_FIND_PACKAGE_OPTIONS})
 870         set(Qt5Multimedia_OPTIONS ${QT_FIND_PACKAGE_OPTIONS})
 871         set(Qt5PrintSupport_OPTIONS ${QT_FIND_PACKAGE_OPTIONS})
 872         set(Qt5Svg_OPTIONS ${QT_FIND_PACKAGE_OPTIONS})
 873         set(Qt5Widgets_OPTIONS ${QT_FIND_PACKAGE_OPTIONS})
 874         if (APPLE)
 875                 set(PACKAGELIST ${PACKAGELIST} Qt5MacExtras)
 876                 set(Qt5MacExtras_OPTIONS ${QT_FIND_PACKAGE_OPTIONS})
 877         endif()
 878         if( WIN32 )
 879                 set(PACKAGELIST ${PACKAGELIST} Qt5WinExtras)
 880                 set(Qt5WinExtras_OPTIONS ${QT_FIND_PACKAGE_OPTIONS})
 881         endif()
 882 endif()
 883
 884 # MaxMind DB address resolution
 885 if(BUILD_mmdbresolve)
 886         set(PACKAGELIST ${PACKAGELIST} MaxMindDB)
 887 endif()
 888
 889 # SMI SNMP
 890 if(ENABLE_SMI)
 891         set(PACKAGELIST ${PACKAGELIST} SMI)
 892 endif()
 893
 894 # GNU SSL/TLS support
 895 if(ENABLE_GNUTLS)
 896         set(PACKAGELIST ${PACKAGELIST} GNUTLS)
 897         # Minimum version needed.
 898         set(GNUTLS_OPTIONS "2.12.0")
 899 endif()
 900
 901 # Kerberos
 902 if(ENABLE_KERBEROS)
 903         set(PACKAGELIST ${PACKAGELIST} KERBEROS)
 904 endif()
 905
 906 # C Asynchronous resolver
 907 if(ENABLE_CARES)
 908         set(PACKAGELIST ${PACKAGELIST} CARES)
 909         # Minimum version needed.
 910         set(CARES_OPTIONS "1.5.0")
 911 endif()
 912
 913 # Zlib compression
 914 if(ENABLE_ZLIB)
 915         if (WIN32)
 916                 # On Windows we build our own version of zlib, so add the paths
 917                 set(ZLIB_SRC_DIR "${_PROJECT_LIB_DIR}/zlib-1.2.11-ws")
 918                 set(SKIP_INSTALL_ALL True) # We copy the DLL ourselves.
 919                 add_subdirectory("${ZLIB_SRC_DIR}" "${CMAKE_BINARY_DIR}/zlib")
 920                 unset(SKIP_INSTALL_ALL)
 921                 set(ZLIB_INCLUDE_DIR  "${ZLIB_SRC_DIR}" "${CMAKE_BINARY_DIR}/zlib")
 922                 set(ZLIB_LIBRARY zlib)
 923                 set(ZLIB_DLL "zlib1.dll")
 924                 set_target_properties(zlib PROPERTIES FOLDER "Libs/zlib")
 925                 # Annoyingly zlib also builds some other stuff we aren't interested in
 926                 set_target_properties(zlibstatic PROPERTIES
 927                         FOLDER "Libs/zlib"
 928                         EXCLUDE_FROM_ALL True
 929                         EXCLUDE_FROM_DEFAULT_BUILD True
 930                 )
 931         endif()
 932         set(PACKAGELIST ${PACKAGELIST} ZLIB)
 933 endif()
 934
 935 # LZ4 compression
 936 if(ENABLE_LZ4)
 937         set(PACKAGELIST ${PACKAGELIST} LZ4)
 938 endif()
 939
 940 # Snappy compression
 941 if(ENABLE_SNAPPY)
 942         set(PACKAGELIST ${PACKAGELIST} SNAPPY)
 943 endif()
 944
 945 # Enhanced HTTP/2 dissection
 946 if(ENABLE_NGHTTP2)
 947         set(PACKAGELIST ${PACKAGELIST} NGHTTP2)
 948 endif()
 949
 950 # Embedded Lua interpreter
 951 if(ENABLE_LUA)
 952         set(PACKAGELIST ${PACKAGELIST} LUA)
 953         set(LUA_OPTIONS "5.1")
 954 endif()
 955
 956 if(ENABLE_NETLINK)
 957         set(PACKAGELIST ${PACKAGELIST} NL)
 958 endif()
 959
 960 if(ENABLE_SBC)
 961         set(PACKAGELIST ${PACKAGELIST} SBC)
 962 endif()
 963
 964 if(ENABLE_SPANDSP)
 965         set(PACKAGELIST ${PACKAGELIST} SPANDSP)
 966 endif()
 967
 968 if(ENABLE_BCG729)
 969         set(PACKAGELIST ${PACKAGELIST} BCG729)
 970 endif()
 971
 972 if(ENABLE_LIBXML2)
 973         set(PACKAGELIST ${PACKAGELIST} LibXml2)
 974 endif()
 975
 976 # Capabilities
 977 if(ENABLE_CAP)
 978         set(PACKAGELIST ${PACKAGELIST} CAP SETCAP)
 979 endif()
 980
 981 # Windows version updates
 982 if(ENABLE_WINSPARKLE)
 983         set(PACKAGELIST ${PACKAGELIST} WINSPARKLE)
 984 endif()
 985
 986 set(PACKAGELIST ${PACKAGELIST} POD)
 987
 988 set(PACKAGELIST ${PACKAGELIST} DOXYGEN)
 989
 990 set(PROGLIST)
 991
 992 # Sort the package list
 993 list(SORT PACKAGELIST)
 994 string(REPLACE ";" " " _package_list "${PACKAGELIST}")
 995 message(STATUS "Package List: ${_package_list}")
 996 # Let's loop the package list
 997 foreach(PACKAGE ${PACKAGELIST})
 998         # Most packages export uppercase variables, but there are exceptions.
 999         if(PACKAGE MATCHES "^(Qt5)")
1000                 set(PACKAGE_VAR "${PACKAGE}")
1001         else()
1002                 string(TOUPPER "${PACKAGE}" PACKAGE_VAR)
1003         endif()
1004         if(${PACKAGE}_OPTIONS)
1005                 find_package(${PACKAGE} ${${PACKAGE}_OPTIONS})
1006         else()
1007                 find_package(${PACKAGE})
1008         endif()
1009         if (${PACKAGE_VAR}_FOUND)
1010                 message(STATUS "${PACKAGE_VAR} FOUND")
1011                 set(HAVE_LIB${PACKAGE_VAR} 1)
1012                 if (NOT DEFINED ${PACKAGE_VAR}_INCLUDE_DIRS AND ${PACKAGE_VAR}_INCLUDE_DIR)
1013                         set(${PACKAGE_VAR}_INCLUDE_DIRS ${${PACKAGE_VAR}_INCLUDE_DIR})
1014                 endif()
1015                 if (${PACKAGE_VAR}_INCLUDE_DIRS)
1016                         include_directories(SYSTEM ${${PACKAGE_VAR}_INCLUDE_DIRS})
1017                         message(STATUS "${PACKAGE} includes: ${${PACKAGE_VAR}_INCLUDE_DIRS}")
1018                 endif()
1019                 if (${PACKAGE_VAR}_LIBRARIES)
1020                         message(STATUS "${PACKAGE} libs: ${${PACKAGE_VAR}_LIBRARIES}")
1021                 endif()
1022                 if (${PACKAGE_VAR}_DEFINITIONS)
1023                         message(STATUS "${PACKAGE} definitions: ${${PACKAGE_VAR}_DEFINITIONS}")
1024                         string(REPLACE ";" " " _definitions "${${PACKAGE_VAR}_DEFINITIONS}")
1025                         set(CMAKE_C_FLAGS "${_definitions} ${CMAKE_C_FLAGS}")
1026                         set(CMAKE_CXX_FLAGS "${_definitions} ${CMAKE_CXX_FLAGS}")
1027                 endif()
1028                 if (${PACKAGE_VAR}_LINK_FLAGS)
1029                         string(REPLACE ";" " " _link_flags "${${PACKAGE_VAR}_LINK_FLAGS}")
1030                         set(WS_LINK_FLAGS "${_link_flags} ${WS_LINK_FLAGS}")
1031                         message(STATUS "${PACKAGE} other link flags: ${_link_flags}")
1032                 endif()
1033                 if (${PACKAGE_VAR}_EXECUTABLE)
1034                         message(STATUS "${PACKAGE} executable: ${${PACKAGE_VAR}_EXECUTABLE}")
1035                 endif()
1036         else()
1037                 #
1038                 # Not finding a package is only a fatal error if the
1039                 # package is required; if it's required, then its
1040                 # XXX_OPTIONS variable contains REQUIRED, and the above
1041                 # code will pass REQUIRED to find_package, and the
1042                 # configure will fail if the package isn't found.
1043                 #
1044                 # Do *NOT* report this as an error!
1045                 #
1046                 message(STATUS "${PACKAGE_VAR} NOT FOUND")
1047         endif()
1048 endforeach()
1049
1050 # Provide Windows system lib names
1051 include( UseWinLibs )
1052
1053 # dist target that prepares source dir
1054 # XXX Duplicated in the RPM section below.
1055 add_custom_target(dist
1056         COMMAND ./tools/git-export-release.sh -d "${CMAKE_BINARY_DIR}"
1057         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
1058 )
1059
1060
1061 if(HAVE_LIBAIRPCAP)
1062         set(HAVE_AIRPCAP 1)
1063 endif()
1064 if(HAVE_LIBLUA)
1065         set(HAVE_LUA_H 1)
1066         set(HAVE_LUA 1)
1067 endif()
1068 if(HAVE_LIBKERBEROS)
1069         set(HAVE_KERBEROS 1)
1070 endif()
1071 if(MAXMINDDB_FOUND)
1072         set(HAVE_MAXMINDDB 1)
1073 endif()
1074 if(LIBSSH_FOUND)
1075         set(HAVE_LIBSSH 1)
1076 endif()
1077 if(JSONGLIB_FOUND)
1078         set(HAVE_JSONGLIB 1)
1079 endif()
1080 if(NGHTTP2_FOUND)
1081         set(HAVE_NGHTTP2 1)
1082 endif()
1083 if(HAVE_LIBCARES)
1084         set(HAVE_C_ARES 1)
1085 endif()
1086 if(NOT HAVE_LIBCARES)
1087         message(WARNING "Not using c-ares.")
1088         message(WARNING "DNS name resolution for captures will be disabled.")
1089 endif()
1090 if(HAVE_LIBNL AND HAVE_AIRPCAP)
1091         message(ERROR "Airpcap and Libnl support are mutually exclusive")
1092 endif()
1093 if(HAVE_LIBSBC)
1094         set(HAVE_SBC 1)
1095 endif()
1096 if(SPANDSP_FOUND)
1097         set(HAVE_SPANDSP 1)
1098 endif()
1099 if(BCG729_FOUND)
1100         set(HAVE_BCG729 1)
1101 endif()
1102 if(LIBXML2_FOUND)
1103         set(HAVE_LIBXML2 1)
1104 else()
1105         # The (official) FindLibXml2.cmake file sets this cache variable to a
1106         # non-empty value, be sure to clear it when not found.
1107         set(LIBXML2_LIBRARIES "")
1108 endif()
1109
1110 if (HAVE_LIBWINSPARKLE)
1111         set(HAVE_SOFTWARE_UPDATE 1)
1112 endif()
1113
1114 if(HAVE_LIBZLIB)
1115         set(HAVE_ZLIB 1)
1116         # Always include the "true" zlib includes first. This works around a
1117         # bug in the Windows setup of GTK[23] which has a faulty zconf.h.
1118         include_directories(BEFORE ${ZLIB_INCLUDE_DIRS})
1119 endif()
1120 if(HAVE_LIBLZ4)
1121         set(HAVE_LZ4 1)
1122 endif()
1123 if(SNAPPY_FOUND)
1124         set(HAVE_SNAPPY 1)
1125 endif()
1126 if (Qt5Widgets_FOUND)
1127         if (Qt5Widgets_VERSION VERSION_LESS 5.2)
1128                 message(FATAL_ERROR "Qt 5.2 or later is required.")
1129         endif()
1130         if (Qt5Widgets_VERSION VERSION_GREATER 5.6
1131             AND (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang"))
1132                 # Qt 5.7 and later require C++ 11.
1133                 set(CMAKE_CXX_STANDARD 11)
1134                 set(CMAKE_CXX_STANDARD_REQUIRED ON)
1135         endif()
1136         set (QT_FOUND ON)
1137         set (QT_LIBRARIES ${Qt5Widgets_LIBRARIES} ${Qt5PrintSupport_LIBRARIES})
1138         if(Qt5Multimedia_FOUND)
1139                 set (QT_LIBRARIES ${QT_LIBRARIES} ${Qt5Multimedia_LIBRARIES})
1140                 # That's the name autotools used
1141                 set(QT_MULTIMEDIA_LIB 1)
1142         endif()
1143         if(Qt5Svg_FOUND)
1144                 set (QT_LIBRARIES ${QT_LIBRARIES} ${Qt5Svg_LIBRARIES})
1145                 # That's the name autotools used
1146                 set(QT_SVG_LIB 1)
1147         endif()
1148         if(Qt5MacExtras_FOUND)
1149                 set (QT_LIBRARIES ${QT_LIBRARIES} ${Qt5MacExtras_LIBRARIES})
1150                 # That's the name autotools used
1151                 set(QT_MACEXTRAS_LIB 1)
1152         endif()
1153         if(Qt5WinExtras_FOUND)
1154                 set (QT_LIBRARIES ${QT_LIBRARIES} ${Qt5WinExtras_LIBRARIES})
1155                 # set(QT_WINEXTRAS_LIB 1) # Not needed?
1156         endif()
1157         if(NOT DEFINED MOC_OPTIONS)
1158                 # Squelch moc verbose "nothing to do" output
1159                 set(MOC_OPTIONS -nn)
1160         endif()
1161
1162         # CMake uses qmake to find Qt4. It relies on Qt's CMake modules
1163         # to find Qt5. This means that we can't assume that the qmake
1164         # in our PATH is the correct one. We can fetch qmake's location
1165         # from Qt5::qmake, which is is defined in Qt5CoreConfigExtras.cmake.
1166         get_target_property(QT_QMAKE_EXECUTABLE Qt5::qmake IMPORTED_LOCATION)
1167         get_filename_component(_qt_bin_path "${QT_QMAKE_EXECUTABLE}" DIRECTORY)
1168         set(QT_BIN_PATH "${_qt_bin_path}" CACHE INTERNAL
1169                 "Path to qmake, macdeployqt, windeployqt, and other Qt utilities."
1170         )
1171         # Use qmake to find windeployqt and macdeployqt. Ideally one of
1172         # the modules in ${QTDIR}/lib/cmake would do this for us.
1173         if(WIN32)
1174                 find_program(QT_WINDEPLOYQT_EXECUTABLE windeployqt
1175                         HINTS "${QT_BIN_PATH}"
1176                         DOC "Path to the windeployqt utility."
1177                 )
1178         elseif(APPLE)
1179                 find_program(QT_MACDEPLOYQT_EXECUTABLE macdeployqt
1180                         HINTS "${QT_BIN_PATH}"
1181                         DOC "Path to the macdeployqt utility."
1182                 )
1183         endif()
1184
1185 endif()
1186
1187 if(ENABLE_CHECKHF_CONFLICT)
1188         set(ENABLE_CHECK_FILTER 1)
1189 endif()
1190
1191 if(APPLE)
1192         #
1193         # We assume that APPLE means macOS so that we have the macOS
1194         # frameworks.
1195         #
1196         set(HAVE_MACOS_FRAMEWORKS 1)
1197         FIND_LIBRARY (APPLE_APPLICATION_SERVICES_LIBRARY ApplicationServices)
1198         FIND_LIBRARY (APPLE_APPKIT_LIBRARY AppKit)
1199         FIND_LIBRARY (APPLE_CORE_FOUNDATION_LIBRARY CoreFoundation)
1200         FIND_LIBRARY (APPLE_SYSTEM_CONFIGURATION_LIBRARY SystemConfiguration)
1201 endif()
1202
1203 include(ConfigureChecks.cmake)
1204
1205 # Global properties
1206 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
1207
1208 if(ENABLE_CCACHE AND (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang"))
1209         # http://stackoverflow.com/a/24305849/82195
1210         find_program(CCACHE_EXECUTABLE ccache)
1211         if(CCACHE_EXECUTABLE)
1212                 set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_EXECUTABLE}")
1213                 set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK "${CCACHE_EXECUTABLE}")
1214         endif()
1215 endif()
1216
1217 # The top level checkAPIs target, add before subdirectory calls so it's avaiable to all
1218 add_custom_target(checkAPI)
1219 set_target_properties(checkAPI
1220         PROPERTIES
1221                 FOLDER "Auxiliary"
1222                 EXCLUDE_FROM_ALL True
1223                 EXCLUDE_FROM_DEFAULT_BUILD True
1224 )
1225
1226 include( UseCheckAPI )
1227
1228 # Target platform locations
1229 # UN*X in general, including macOS if not building an app bundle:
1230 # $DESTDIR/lib/wireshark/extcap
1231 # Windows: $DESTDIR/extcap
1232 # macOS app bundle: Wireshark.app/Contents/Resources/share/wireshark/extcap
1233 if (WIN32)
1234         set(EXTCAP_INSTALL_LIBDIR "extcap" CACHE INTERNAL "The extcap dir")
1235 else ()
1236         set(EXTCAP_INSTALL_LIBDIR "${CMAKE_INSTALL_LIBDIR}/${CPACK_PACKAGE_NAME}/extcap" CACHE INTERNAL "The extcap dir")
1237 endif()
1238
1239 # Directory where plugins and Lua dissectors can be found.
1240 if(WIN32)
1241         set(PLUGIN_INSTALL_LIBDIR "plugins" CACHE INTERNAL "The plugin dir")
1242 else()
1243         set(PLUGIN_INSTALL_LIBDIR "${CMAKE_INSTALL_LIBDIR}/${CPACK_PACKAGE_NAME}/plugins" CACHE INTERNAL "The plugin dir")
1244 endif()
1245 set(PLUGIN_INSTALL_VERSION_LIBDIR "${PLUGIN_INSTALL_LIBDIR}/${PROJECT_RELEASE_VERSION}")
1246 set(PLUGIN_VERSION_DIR "plugins/${PROJECT_RELEASE_VERSION}")
1247
1248 add_subdirectory( capchild )
1249 add_subdirectory( caputils )
1250 add_subdirectory( codecs )
1251 add_subdirectory( doc )
1252 add_subdirectory( docbook EXCLUDE_FROM_ALL )
1253 add_subdirectory( epan )
1254 add_subdirectory( extcap )
1255 add_subdirectory( randpkt_core )
1256 add_subdirectory( tools/lemon )
1257 add_subdirectory( ui )
1258 add_subdirectory( wiretap )
1259 add_subdirectory( writecap )
1260
1261 # Location of our data files. This should be set to a value that allows
1262 # running from the build directory on Windows, on macOS when building an
1263 # application bundle, and on UNIX in general if
1264 # WIRESHARK_RUN_FROM_BUILD_DIRECTORY is set.
1265 if(ENABLE_APPLICATION_BUNDLE)
1266         if(CMAKE_CFG_INTDIR STREQUAL ".")
1267                 set(_datafile_dir "${CMAKE_BINARY_DIR}/run/Wireshark.app/Contents/Resources/share/wireshark")
1268         else()
1269                 # Xcode
1270                 set(_datafile_dir "${CMAKE_BINARY_DIR}/run/${CMAKE_CFG_INTDIR}/Wireshark.app/Contents/Resources/share/wireshark")
1271         endif()
1272 elseif(NOT CMAKE_CFG_INTDIR STREQUAL ".")
1273         # Visual Studio, Xcode, etc.
1274         set(_datafile_dir "${CMAKE_BINARY_DIR}/run/${CMAKE_CFG_INTDIR}")
1275 else()
1276         # Makefile, Ninja, etc.
1277         set(_datafile_dir "${CMAKE_BINARY_DIR}/run")
1278 endif()
1279
1280 set(DATAFILE_DIR ${_datafile_dir} CACHE INTERNAL "Build time data file location.")
1281
1282 # wsutil must be added after DATAFILE_DIR is set such that filesystem.c can
1283 # learn about the directory location.
1284 add_subdirectory( wsutil )
1285
1286 if(NOT WIN32)
1287         add_custom_target(dumpabi DEPENDS dumpabi-libwireshark dumpabi-libwiretap dumpabi-libwsutil)
1288 endif()
1289
1290 if(BUILD_wireshark AND QT_FOUND)
1291         add_subdirectory( ui/qt )
1292 endif()
1293
1294 # Location of our plugins. PLUGIN_DIR should allow running
1295 # from the build directory similar to DATAFILE_DIR above.
1296 if(ENABLE_PLUGINS)
1297         # Target platform locations
1298         # UN*X in general, including macOS if not building an app bundle:
1299         # $DESTDIR/lib/wireshark/plugins/$VERSION
1300         # Windows: $DESTDIR/wireshark/plugins/$VERSION
1301         # macOS app bundle: Wireshark.app/Contents/PlugIns/wireshark
1302         set(HAVE_PLUGINS 1)
1303         add_custom_target(plugins)
1304         set_target_properties(plugins PROPERTIES FOLDER "Plugins")
1305         set(PLUGIN_SRC_DIRS
1306                 plugins/epan/ethercat
1307                 plugins/epan/gryphon
1308                 plugins/epan/irda
1309                 plugins/epan/mate
1310                 plugins/epan/opcua
1311                 plugins/epan/profinet
1312                 plugins/epan/stats_tree
1313                 plugins/epan/transum
1314                 plugins/epan/unistim
1315                 plugins/epan/wimax
1316                 plugins/epan/wimaxasncp
1317                 plugins/epan/wimaxmacphy
1318                 plugins/wiretap/usbdump
1319                 plugins/codecs/l16_mono
1320                 ${CUSTOM_PLUGIN_SRC_DIR}
1321         )
1322
1323         # Build demo plugin, only if asked explicitly
1324         if(ENABLE_PLUGIN_IFDEMO)
1325                 set(PLUGIN_SRC_DIRS
1326                         ${PLUGIN_SRC_DIRS}
1327                         plugins/epan/pluginifdemo
1328                 )
1329         endif()
1330
1331 else()
1332         set(PLUGIN_SRC_DIRS )
1333 endif()
1334
1335 if(ENABLE_APPLICATION_BUNDLE)
1336         if(CMAKE_CFG_INTDIR STREQUAL ".")
1337                 set(_plugin_dir "${CMAKE_BINARY_DIR}/run/Wireshark.app/Contents/PlugIns/wireshark/${PROJECT_RELEASE_VERSION}")
1338         else()
1339           # Xcode
1340                 set(_plugin_dir "${CMAKE_BINARY_DIR}/run/$<CONFIG>/Wireshark.app/Contents/PlugIns/wireshark/${PROJECT_RELEASE_VERSION}")
1341         endif()
1342 elseif(WIN32 AND NOT CMAKE_CFG_INTDIR STREQUAL ".")
1343         set(_plugin_dir "${CMAKE_BINARY_DIR}/run/$<CONFIG>/${PLUGIN_VERSION_DIR}")
1344 else()
1345         set(_plugin_dir "${DATAFILE_DIR}/${PLUGIN_VERSION_DIR}")
1346 endif()
1347 set (PLUGIN_DIR ${_plugin_dir} CACHE INTERNAL "Build time plugin location.")
1348
1349 foreach(_plugin_src_dir ${PLUGIN_SRC_DIRS})
1350         add_subdirectory( ${_plugin_src_dir} )
1351 endforeach()
1352
1353 if(ENABLE_PCAP_NG_DEFAULT)
1354         set(PCAP_NG_DEFAULT 1)
1355 endif()
1356
1357 # Large file support (e.g. make off_t 64 bit if supported)
1358 include(gmxTestLargeFiles)
1359 gmx_test_large_files(GMX_LARGEFILES)
1360
1361 set( VERSION ${PROJECT_VERSION} )
1362 add_custom_target(version
1363         BYPRODUCTS version.h
1364         COMMAND ${PERL_EXECUTABLE}
1365                 ${CMAKE_SOURCE_DIR}/make-version.pl
1366                 ${CMAKE_SOURCE_DIR}
1367 )
1368 set_target_properties(version PROPERTIES FOLDER "Auxiliary")
1369
1370 set( configure_input "Built with CMake ${CMAKE_VERSION}" )
1371 configure_file(${CMAKE_SOURCE_DIR}/cmakeconfig.h.in ${CMAKE_BINARY_DIR}/config.h)
1372
1373 configure_file(${CMAKE_SOURCE_DIR}/ws_version.h.in ${CMAKE_BINARY_DIR}/ws_version.h)
1374
1375 set( prefix "${CMAKE_INSTALL_PREFIX}" )
1376 set( exec_prefix "\${prefix}" )
1377 set( libdir "\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}" )
1378 set( includedir  "\${prefix}/include" )
1379 set( plugindir "\${libdir}/wireshark/${PLUGIN_VERSION_DIR}" )
1380
1381 # Doxygen variables
1382 file(GLOB TOP_LEVEL_SOURCE_LIST *.c *.cpp *.h)
1383 string (REPLACE ";" " " DOXYGEN_TOP_LEVEL_SOURCES "${TOP_LEVEL_SOURCE_LIST}")
1384 set(DOXYGEN_INPUT_DIRECTORY ${CMAKE_SOURCE_DIR})
1385 set(DOXYGEN_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
1386
1387 set(ICON_PATH "${CMAKE_SOURCE_DIR}/image/")
1388 set( IN_FILES
1389         doxygen.cfg.in
1390         image/libwireshark.rc.in
1391         image/text2pcap.rc.in
1392         image/capinfos.rc.in
1393         image/wireshark.rc.in
1394         image/mergecap.rc.in
1395         image/tshark.rc.in
1396         image/dumpcap.rc.in
1397         image/reordercap.rc.in
1398         image/rawshark.rc.in
1399         image/file_dlg_win32.rc
1400         image/tfshark.rc.in
1401         image/editcap.rc.in
1402         image/captype.rc.in
1403         image/libwscodecs.rc.in
1404         image/libwsutil.rc.in
1405         image/wiretap.rc.in
1406         image/wireshark.exe.manifest.in
1407         packaging/macosx/Info.plist.in
1408         packaging/macosx/osx-app.sh.in
1409         packaging/macosx/osx-dmg.sh.in
1410         packaging/macosx/Wireshark_package.pmdoc/index.xml.in
1411         wireshark.pc.in
1412 )
1413 foreach( _in_file ${IN_FILES} )
1414         get_filename_component( _path ${_in_file} PATH )
1415         string( REGEX REPLACE "(.*)\\.in" "\\1" _outfile ${_in_file}  )
1416         configure_file( ${CMAKE_SOURCE_DIR}/${_in_file} ${CMAKE_BINARY_DIR}/${_outfile} @ONLY )
1417 endforeach()
1418
1419 include(FeatureSummary)
1420 set_package_properties(SBC PROPERTIES
1421         DESCRIPTION "Bluetooth low-complexity, subband codec (SBC) decoder"
1422         URL "https://git.kernel.org/pub/scm/bluetooth/sbc.git"
1423         PURPOSE "Support for playing SBC codec in RTP player"
1424 )
1425 set_package_properties(SPANDSP PROPERTIES
1426         DESCRIPTION "a library of many DSP functions for telephony"
1427         URL "http://www.soft-switch.org/"
1428         PURPOSE "Support for G.722 and G.726 codecs in RTP player"
1429 )
1430 set_package_properties(BCG729 PROPERTIES
1431         DESCRIPTION "G.729 decoder"
1432         URL "https://www.linphone.org/technical-corner/bcg729/overview"
1433         PURPOSE "Support for G.729 codec in RTP player"
1434 )
1435 set_package_properties(LIBXML2 PROPERTIES
1436         DESCRIPTION "XML parsing library"
1437         URL "http://xmlsoft.org/"
1438         PURPOSE "Read XML configuration files in EPL dissector"
1439 )
1440 set_package_properties(LIBSSH PROPERTIES
1441         DESCRIPTION "Library for implementing SSH clients"
1442         URL "https://www.libssh.org/"
1443         PURPOSE "extcap remote SSH interfaces (sshdump, ciscodump)"
1444 )
1445 set_package_properties(LZ4 PROPERTIES
1446         DESCRIPTION "LZ4 is lossless compression algorithm used in some protocol (CQL...)"
1447         URL "http://www.lz4.org"
1448         PURPOSE "LZ4 decompression in CQL and Kafka dissectors"
1449 )
1450 set_package_properties(SNAPPY PROPERTIES
1451         DESCRIPTION "A fast compressor/decompressor from Google"
1452         URL "http://google.github.io/snappy/"
1453         PURPOSE "Snappy decompression in CQL and Kafka dissectors"
1454 )
1455 set_package_properties(NGHTTP2 PROPERTIES
1456         DESCRIPTION "HTTP/2 C library and tools"
1457         URL "https://nghttp2.org"
1458         PURPOSE "Header decompression in HTTP2"
1459 )
1460
1461 message(STATUS "C-Flags: ${CMAKE_C_FLAGS}")
1462 message(STATUS "CXX-Flags: ${CMAKE_CXX_FLAGS}")
1463 message(STATUS "Warnings as errors: ${WERROR_COMMON_FLAGS}")
1464
1465 feature_summary(WHAT ALL)
1466
1467 link_directories(
1468         ${CMAKE_BINARY_DIR}/ui
1469         ${CMAKE_BINARY_DIR}/ui/qt
1470         ${CMAKE_BINARY_DIR}/capchild
1471         ${CMAKE_BINARY_DIR}/caputils
1472         ${CMAKE_BINARY_DIR}/codecs
1473         ${CMAKE_BINARY_DIR}/epan
1474         ${CMAKE_BINARY_DIR}/randpkt_core
1475         ${CMAKE_BINARY_DIR}/wiretap
1476         ${CMAKE_BINARY_DIR}/writecap
1477         ${CMAKE_BINARY_DIR}/wsutil
1478 )
1479
1480 if(WIN32)
1481         set(PLATFORM_UI_SRC
1482                 ui/win32/console_win32.c
1483                 ui/win32/file_dlg_win32.c
1484         )
1485         set(PLATFORM_UI_RC_FILES
1486                 image/file_dlg_win32.rc
1487         )
1488 elseif(APPLE)
1489         set(PLATFORM_UI_SRC
1490                 ui/macosx/cocoa_bridge.mm
1491         )
1492 endif()
1493
1494 # sources common for wireshark, tshark, rawshark and sharkd
1495 set(SHARK_COMMON_SRC
1496         cfile.c
1497         file_packet_provider.c
1498         frame_tvbuff.c
1499         sync_pipe_write.c
1500         version_info.c
1501         extcap.c
1502         extcap_parser.c
1503 )
1504
1505 set(TSHARK_TAP_SRC
1506         ${CMAKE_SOURCE_DIR}/ui/cli/tap-camelsrt.c
1507         ${CMAKE_SOURCE_DIR}/ui/cli/tap-diameter-avp.c
1508         ${CMAKE_SOURCE_DIR}/ui/cli/tap-expert.c
1509         ${CMAKE_SOURCE_DIR}/ui/cli/tap-exportobject.c
1510         ${CMAKE_SOURCE_DIR}/ui/cli/tap-endpoints.c
1511         ${CMAKE_SOURCE_DIR}/ui/cli/tap-flow.c
1512         ${CMAKE_SOURCE_DIR}/ui/cli/tap-follow.c
1513         ${CMAKE_SOURCE_DIR}/ui/cli/tap-funnel.c
1514         ${CMAKE_SOURCE_DIR}/ui/cli/tap-gsm_astat.c
1515         ${CMAKE_SOURCE_DIR}/ui/cli/tap-hosts.c
1516         ${CMAKE_SOURCE_DIR}/ui/cli/tap-httpstat.c
1517         ${CMAKE_SOURCE_DIR}/ui/cli/tap-icmpstat.c
1518         ${CMAKE_SOURCE_DIR}/ui/cli/tap-icmpv6stat.c
1519         ${CMAKE_SOURCE_DIR}/ui/cli/tap-iostat.c
1520         ${CMAKE_SOURCE_DIR}/ui/cli/tap-iousers.c
1521         ${CMAKE_SOURCE_DIR}/ui/cli/tap-macltestat.c
1522         ${CMAKE_SOURCE_DIR}/ui/cli/tap-protocolinfo.c
1523         ${CMAKE_SOURCE_DIR}/ui/cli/tap-protohierstat.c
1524         ${CMAKE_SOURCE_DIR}/ui/cli/tap-rlcltestat.c
1525         ${CMAKE_SOURCE_DIR}/ui/cli/tap-rpcprogs.c
1526         ${CMAKE_SOURCE_DIR}/ui/cli/tap-rtd.c
1527         ${CMAKE_SOURCE_DIR}/ui/cli/tap-rtp.c
1528         ${CMAKE_SOURCE_DIR}/ui/cli/tap-rtspstat.c
1529         ${CMAKE_SOURCE_DIR}/ui/cli/tap-sctpchunkstat.c
1530         ${CMAKE_SOURCE_DIR}/ui/cli/tap-simple_stattable.c
1531         ${CMAKE_SOURCE_DIR}/ui/cli/tap-sipstat.c
1532         ${CMAKE_SOURCE_DIR}/ui/cli/tap-smbsids.c
1533         ${CMAKE_SOURCE_DIR}/ui/cli/tap-srt.c
1534         ${CMAKE_SOURCE_DIR}/ui/cli/tap-stats_tree.c
1535         ${CMAKE_SOURCE_DIR}/ui/cli/tap-sv.c
1536         ${CMAKE_SOURCE_DIR}/ui/cli/tap-wspstat.c
1537 )
1538
1539 set(INSTALL_DIRS
1540         diameter
1541         dtds
1542         ${DATAFILE_DIR}/help
1543         profiles
1544         radius
1545         tpncp
1546         wimaxasncp
1547 )
1548
1549 set(INSTALL_FILES
1550         cfilters
1551         colorfilters
1552         dfilters
1553         enterprises.tsv
1554         manuf
1555         pdml2html.xsl
1556         services
1557         smi_modules
1558         wka
1559         docbook/ws.css
1560         ${CMAKE_BINARY_DIR}/doc/AUTHORS-SHORT
1561         ${CMAKE_BINARY_DIR}/doc/androiddump.html
1562         ${CMAKE_BINARY_DIR}/doc/udpdump.html
1563         ${CMAKE_BINARY_DIR}/doc/capinfos.html
1564         ${CMAKE_BINARY_DIR}/doc/captype.html
1565         ${CMAKE_BINARY_DIR}/doc/ciscodump.html
1566         ${CMAKE_BINARY_DIR}/doc/dftest.html
1567         ${CMAKE_BINARY_DIR}/doc/dumpcap.html
1568         ${CMAKE_BINARY_DIR}/doc/editcap.html
1569         ${CMAKE_BINARY_DIR}/doc/extcap.html
1570         ${CMAKE_BINARY_DIR}/doc/mergecap.html
1571         ${CMAKE_BINARY_DIR}/doc/randpkt.html
1572         ${CMAKE_BINARY_DIR}/doc/randpktdump.html
1573         ${CMAKE_BINARY_DIR}/doc/rawshark.html
1574         ${CMAKE_BINARY_DIR}/doc/reordercap.html
1575         ${CMAKE_BINARY_DIR}/doc/sshdump.html
1576         ${CMAKE_BINARY_DIR}/doc/text2pcap.html
1577         ${CMAKE_BINARY_DIR}/doc/tshark.html
1578         ${CMAKE_BINARY_DIR}/doc/wireshark.html
1579         ${CMAKE_BINARY_DIR}/doc/wireshark-filter.html
1580 )
1581
1582 if(MAXMINDDB_FOUND)
1583         list(APPEND INSTALL_FILES ${CMAKE_BINARY_DIR}/doc/mmdbresolve.html)
1584 endif()
1585
1586 if (BUILD_corbaidl2wrs)
1587         list(APPEND INSTALL_FILES ${CMAKE_BINARY_DIR}/doc/idl2wrs.html)
1588 endif()
1589 if (BUILD_xxx2deb)
1590         list(APPEND INSTALL_FILES
1591                 ${CMAKE_BINARY_DIR}/doc/asn2deb.html
1592                 ${CMAKE_BINARY_DIR}/doc/idl2deb.html
1593         )
1594 endif()
1595
1596 if(WIN32)
1597         set(TEXTIFY_FILES COPYING NEWS README.windows)
1598         set(TEXTIFY_MD_FILES README.md)
1599         foreach(_text_file ${TEXTIFY_FILES} ${TEXTIFY_MD_FILES})
1600                 string(REGEX REPLACE ".md$" "" _out_file ${_text_file})
1601                 set(INSTALL_FILES ${CMAKE_BINARY_DIR}/${_out_file}.txt ${INSTALL_FILES})
1602         endforeach()
1603 else()
1604         set(INSTALL_FILES COPYING ${INSTALL_FILES})
1605 endif()
1606
1607 set(LIBEPAN_LIBS
1608                 epan
1609                 ${AIRPCAP_LIBRARIES}
1610                 ${PCAP_LIBRARIES}
1611                 ${CARES_LIBRARIES}
1612                 ${KERBEROS_LIBRARIES}
1613                 ${LUA_LIBRARIES}
1614                 ${PYTHON_LIBRARIES}
1615                 ${GEOIP_LIBRARIES}
1616                 ${GCRYPT_LIBRARIES}
1617                 ${GNUTLS_LIBRARIES}
1618                 ${SMI_LIBRARIES}
1619                 ${ZLIB_LIBRARIES}
1620                 ${LZ4_LIBRARIES}
1621                 ${SNAPPY_LIBRARIES}
1622                 ${M_LIBRARIES}
1623                 ${WINSPARKLE_LIBRARIES}
1624 )
1625
1626 if(WIN32)
1627         set(_dll_output_dir "${DATAFILE_DIR}")
1628         add_custom_target(copy_cli_dlls)
1629         set_target_properties(copy_cli_dlls PROPERTIES FOLDER "Copy Tasks")
1630         add_custom_command(TARGET copy_cli_dlls PRE_BUILD
1631                 COMMAND ${CMAKE_COMMAND} -E make_directory "${_dll_output_dir}"
1632         )
1633
1634         # XXX Can (and should) we iterate over these similar to the way
1635         # the top-level CMakeLists.txt iterates over the package list?
1636
1637         # Required DLLs.
1638         # The gio, gnutls, png, and other OBS-generated DLLs depend on
1639         # zlib1.dll. We compile zlib locally but the Debug configuration
1640         # (the default) creates zlibd1.dll.
1641         add_custom_command(TARGET copy_cli_dlls PRE_BUILD
1642                 COMMAND ${CMAKE_COMMAND} -E copy_if_different
1643                         ${GLIB2_DLLS} $<$<CONFIG:Debug>:zlib1.dll>
1644                         "${_dll_output_dir}"
1645                 WORKING_DIRECTORY "${GLIB2_DLL_DIR}"
1646         )
1647
1648         # Optional DLLs.
1649         set (OPTIONAL_DLLS)
1650         if (AIRPCAP_FOUND)
1651                 list (APPEND OPTIONAL_DLLS "${AIRPCAP_DLL_DIR}/${AIRPCAP_DLL}")
1652         endif(AIRPCAP_FOUND)
1653         if (CARES_FOUND)
1654                 list (APPEND OPTIONAL_DLLS "${CARES_DLL_DIR}/${CARES_DLL}")
1655         endif(CARES_FOUND)
1656         if (MAXMINDDB_FOUND)
1657                 list (APPEND OPTIONAL_DLLS "${MAXMINDDB_DLL_DIR}/${MAXMINDDB_DLL}")
1658         endif(MAXMINDDB_FOUND)
1659         if (LIBSSH_FOUND)
1660                 list (APPEND OPTIONAL_DLLS "${LIBSSH_DLL_DIR}/${LIBSSH_DLL}")
1661         endif(LIBSSH_FOUND)
1662         if (JSONGLIB_FOUND)
1663                 list (APPEND OPTIONAL_DLLS "${JSONGLIB_DLL_DIR}/${JSONGLIB_DLL}")
1664         endif(JSONGLIB_FOUND)
1665         foreach( _dll ${GCRYPT_DLLS} )
1666                 list (APPEND OPTIONAL_DLLS "${GCRYPT_DLL_DIR}/${_dll}")
1667         endforeach(_dll)
1668         foreach( _dll ${GNUTLS_DLLS} )
1669                 list (APPEND OPTIONAL_DLLS "${GNUTLS_DLL_DIR}/${_dll}")
1670         endforeach(_dll)
1671         foreach( _dll ${KERBEROS_DLLS} )
1672                 list (APPEND OPTIONAL_DLLS "${KERBEROS_DLL_DIR}/${_dll}")
1673         endforeach(_dll)
1674         if (LUA_FOUND)
1675                 list (APPEND OPTIONAL_DLLS "${LUA_DLL_DIR}/${LUA_DLL}")
1676         endif(LUA_FOUND)
1677         if (LZ4_FOUND)
1678                 list (APPEND OPTIONAL_DLLS "${LZ4_DLL_DIR}/${LZ4_DLL}")
1679         endif(LZ4_FOUND)
1680         if (NGHTTP2_FOUND)
1681                 list (APPEND OPTIONAL_DLLS "${NGHTTP2_DLL_DIR}/${NGHTTP2_DLL}")
1682         endif(NGHTTP2_FOUND)
1683         if (SBC_FOUND)
1684                 list (APPEND OPTIONAL_DLLS "${SBC_DLL_DIR}/${SBC_DLL}")
1685         endif(SBC_FOUND)
1686         if (SPANDSP_FOUND)
1687                 list (APPEND OPTIONAL_DLLS "${SPANDSP_DLL_DIR}/${SPANDSP_DLL}")
1688         endif(SPANDSP_FOUND)
1689         if (BCG729_FOUND)
1690                 list (APPEND OPTIONAL_DLLS "${BCG729_DLL_DIR}/${BCG729_DLL}")
1691         endif(BCG729_FOUND)
1692         if (LIBXML2_FOUND)
1693                 list (APPEND OPTIONAL_DLLS "${LIBXML2_DLL_DIR}/${LIBXML2_DLL}")
1694         endif(LIBXML2_FOUND)
1695         if (SMI_FOUND)
1696                 list (APPEND OPTIONAL_DLLS "${SMI_DLL_DIR}/${SMI_DLL}")
1697                 # Wireshark.nsi wants SMI_DIR which is the base SMI directory
1698                 get_filename_component(SMI_DIR ${SMI_DLL_DIR} DIRECTORY)
1699                 add_custom_command(TARGET copy_cli_dlls PRE_BUILD
1700                         COMMAND ${CMAKE_COMMAND} -E make_directory
1701                                 "${_dll_output_dir}/snmp"
1702                         COMMAND ${CMAKE_COMMAND} -E make_directory
1703                                 "${_dll_output_dir}/snmp/mibs"
1704                         COMMAND ${CMAKE_COMMAND} -E copy_directory
1705                                 "${SMI_SHARE_DIR}/mibs/iana"
1706                                 "${_dll_output_dir}/snmp/mibs"
1707                         COMMAND ${CMAKE_COMMAND} -E copy_directory
1708                                 "${SMI_SHARE_DIR}/mibs/ietf"
1709                                 "${_dll_output_dir}/snmp/mibs"
1710                         COMMAND ${CMAKE_COMMAND} -E copy_directory
1711                                 "${SMI_SHARE_DIR}/mibs/irtf"
1712                                 "${_dll_output_dir}/snmp/mibs"
1713                         COMMAND ${CMAKE_COMMAND} -E copy_directory
1714                                 "${SMI_SHARE_DIR}/mibs/site"
1715                                 "${_dll_output_dir}/snmp/mibs"
1716                         COMMAND ${CMAKE_COMMAND} -E copy_directory
1717                                 "${SMI_SHARE_DIR}/mibs/tubs"
1718                                 "${_dll_output_dir}/snmp/mibs"
1719                         COMMAND ${CMAKE_COMMAND} -E copy_directory
1720                                 "${SMI_SHARE_DIR}/pibs"
1721                                 "${_dll_output_dir}/snmp/mibs"
1722                         COMMAND ${CMAKE_COMMAND} -E copy_directory
1723                                 "${SMI_SHARE_DIR}/yang"
1724                                 "${_dll_output_dir}/snmp/mibs"
1725                         #remove the extra directories copied (shallow copying the above would remove the need for this)
1726                         COMMAND ${CMAKE_COMMAND} -E remove_directory
1727                                 "${_dll_output_dir}/snmp/mibs/iana"
1728                         COMMAND ${CMAKE_COMMAND} -E remove_directory
1729                                 "${_dll_output_dir}/snmp/mibs/ietf"
1730                         COMMAND ${CMAKE_COMMAND} -E remove_directory
1731                                 "${_dll_output_dir}/snmp/mibs/site"
1732                         COMMAND ${CMAKE_COMMAND} -E remove_directory
1733                                 "${_dll_output_dir}/snmp/mibs/tubs"
1734                 )
1735         endif(SMI_FOUND)
1736         if (SNAPPY_FOUND)
1737                 list (APPEND OPTIONAL_DLLS "${SNAPPY_DLL_DIR}/${SNAPPY_DLL}")
1738         endif(SNAPPY_FOUND)
1739         if (WINSPARKLE_FOUND)
1740                 list (APPEND OPTIONAL_DLLS "${WINSPARKLE_DLL_DIR}/${WINSPARKLE_DLL}")
1741         endif(WINSPARKLE_FOUND)
1742
1743         # With libs downloaded to c:/wireshark-win64-libs this currently
1744         # (early 2018) expands to about 1900 characters.
1745         if (OPTIONAL_DLLS)
1746                 add_custom_command(TARGET copy_cli_dlls PRE_BUILD
1747                         COMMAND ${CMAKE_COMMAND} -E copy_if_different
1748                                 ${OPTIONAL_DLLS}
1749                                 "${_dll_output_dir}"
1750                         VERBATIM
1751                 )
1752         endif(OPTIONAL_DLLS)
1753
1754         add_dependencies(epan copy_cli_dlls)
1755
1756         # We have a lot of choices for creating zip archives:
1757         # - 7z, WinZip, etc., which require a separate download+install.
1758         # - Cygwin's zip, which requires Cygwin.
1759         # - "CMake -E tar cz", which creates a tar file.
1760         # - CPack, which requires a CPack configuration.
1761         # - PowerShell via PSCX or System.IO.Compression.FileSystem.
1762         # - Python via zipfile.
1763         # For now, just look for 7z. It's installed on the Windows builders,
1764         # which might be the only systems that use this target.
1765         find_program(ZIP_EXECUTABLE 7z
1766                 PATH "$ENV{PROGRAMFILES}/7-Zip" "$ENV{PROGRAMW6432}/7-Zip"
1767                 DOC "Path to the 7z utility."
1768         )
1769         if(ZIP_EXECUTABLE)
1770                 add_custom_target(pdb_zip_package COMMENT "This packages .PDBs but will not create them.")
1771                 set_target_properties(pdb_zip_package PROPERTIES FOLDER "Packaging")
1772                 set(_pdb_zip "${CMAKE_BINARY_DIR}/Wireshark-pdb-${WIRESHARK_TARGET_PLATFORM}-${VERSION}.zip")
1773                 file(TO_NATIVE_PATH "${_pdb_zip}" _pdb_zip_win)
1774                 add_custom_command(TARGET pdb_zip_package POST_BUILD
1775                         COMMAND ${CMAKE_COMMAND} -E remove -f "${_pdb_zip}"
1776                         COMMAND ${ZIP_EXECUTABLE} a -tzip -mmt=on "${_pdb_zip_win}"
1777                                 *.pdb *.lib
1778                                 extcap/*.pdb
1779                                 ${PLUGIN_VERSION_DIR}/epan/*.pdb
1780                                 ${PLUGIN_VERSION_DIR}/wiretap/*.pdb
1781                         WORKING_DIRECTORY "${_dll_output_dir}"
1782                 )
1783         endif()
1784 endif(WIN32)
1785
1786 # List of extra dependencies for the "copy_data_files" target
1787 set(copy_data_files_depends)
1788
1789 # glob patterns relative to the source directory that should be copied to
1790 # ${DATAFILE_DIR} (including directory prefixes)
1791 set(DATA_FILES_SRC
1792         "help/toc"
1793 )
1794
1795 if(WIN32)
1796         foreach(_text_file ${TEXTIFY_FILES})
1797                 add_custom_command(OUTPUT ${CMAKE_BINARY_DIR}/${_text_file}.txt
1798                         COMMAND ${POWERSHELL_COMMAND} "${CMAKE_SOURCE_DIR}/tools/textify.ps1"
1799                                 -Destination ${CMAKE_BINARY_DIR}
1800                                 ${CMAKE_SOURCE_DIR}/${_text_file}
1801                         DEPENDS
1802                                 ${CMAKE_SOURCE_DIR}/${_text_file}
1803                 )
1804         endforeach()
1805         foreach(_md_file ${TEXTIFY_MD_FILES})
1806                 string(REGEX REPLACE ".md$" ".txt" _text_file ${_md_file})
1807                 add_custom_command(OUTPUT ${CMAKE_BINARY_DIR}/${_text_file}
1808                         COMMAND ${POWERSHELL_COMMAND} "${CMAKE_SOURCE_DIR}/tools/textify.ps1"
1809                                 -Destination ${CMAKE_BINARY_DIR}
1810                                 ${CMAKE_SOURCE_DIR}/${_md_file}
1811                         COMMAND ${CMAKE_COMMAND} -E rename
1812                                 ${CMAKE_BINARY_DIR}/${_md_file}.txt
1813                                 ${CMAKE_BINARY_DIR}/${_text_file}
1814                         DEPENDS
1815                                 ${CMAKE_SOURCE_DIR}/${_text_file}
1816                 )
1817         endforeach()
1818 endif()
1819
1820 foreach(_install_file ${INSTALL_FILES})
1821         get_filename_component(_install_file_src "${_install_file}" ABSOLUTE)
1822         get_filename_component(_install_basename "${_install_file}" NAME)
1823         set(_output_file "${DATAFILE_DIR}/${_install_basename}")
1824         add_custom_command(OUTPUT "${_output_file}"
1825                 COMMAND ${CMAKE_COMMAND} -E copy_if_different
1826                         "${_install_file_src}"
1827                         "${_output_file}"
1828                 DEPENDS
1829                         docs
1830                         "${_install_file}"
1831         )
1832         list(APPEND copy_data_files_depends "${_output_file}")
1833 endforeach()
1834
1835 # faq.txt is handled separately below.
1836 set(_help_source_files
1837         help/capture_filters.txt
1838         help/capturing.txt
1839         help/display_filters.txt
1840         help/getting_started.txt
1841         help/overview.txt
1842 )
1843
1844 if(WIN32)
1845         file(TO_NATIVE_PATH "${DATAFILE_DIR}/help" _help_dest_dir)
1846         foreach(_help_file IN LISTS _help_source_files)
1847                 add_custom_command(OUTPUT "${DATAFILE_DIR}/${_help_file}"
1848                         COMMAND ${CMAKE_COMMAND} -E make_directory "${DATAFILE_DIR}/help"
1849                         COMMAND ${POWERSHELL_COMMAND} "${CMAKE_SOURCE_DIR}/tools/textify.ps1"
1850                                 -Destination "${_help_dest_dir}"
1851                                 "${CMAKE_SOURCE_DIR}/${_help_file}"
1852                         DEPENDS
1853                                 "${CMAKE_SOURCE_DIR}/${_help_file}"
1854                 )
1855                 list(APPEND copy_data_files_depends "${DATAFILE_DIR}/${_help_file}")
1856         endforeach()
1857 else()
1858         list(APPEND DATA_FILES_SRC ${_help_source_files})
1859 endif(WIN32)
1860
1861 # Create help/faq.txt when missing
1862 add_custom_command(OUTPUT "${DATAFILE_DIR}/help/faq.txt"
1863         COMMAND ${CMAKE_COMMAND} -E make_directory "${DATAFILE_DIR}/help"
1864         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_SOURCE_DIR}/help/faq.py -b > faq.tmp.html
1865         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_SOURCE_DIR}/tools/html2text.py
1866                 faq.tmp.html > "${DATAFILE_DIR}/help/faq.txt"
1867         COMMAND ${CMAKE_COMMAND} -E remove faq.tmp.html
1868         DEPENDS
1869                 "${CMAKE_SOURCE_DIR}/help/faq.py"
1870                 "${CMAKE_SOURCE_DIR}/tools/html2text.py"
1871 )
1872 list(APPEND copy_data_files_depends "${DATAFILE_DIR}/help/faq.txt")
1873
1874 # Install LUA files in staging directory such that LUA can used when Wireshark
1875 # is ran from the build directory. For install targets, see
1876 # epan/wslua/CMakeLists.txt
1877 if(LUA_FOUND AND ENABLE_LUA)
1878         set(_lua_files
1879                 "${CMAKE_BINARY_DIR}/epan/wslua/init.lua"
1880                 "${CMAKE_SOURCE_DIR}/epan/wslua/console.lua"
1881                 "${CMAKE_SOURCE_DIR}/epan/wslua/dtd_gen.lua"
1882         )
1883         foreach(_lua_file ${_lua_files})
1884                 get_filename_component(_lua_filename "${_lua_file}" NAME)
1885                 list(APPEND copy_data_files_depends
1886                         "${DATAFILE_DIR}/${_lua_filename}")
1887                 add_custom_command(OUTPUT "${DATAFILE_DIR}/${_lua_filename}"
1888                         COMMAND ${CMAKE_COMMAND} -E copy_if_different
1889                                 "${_lua_file}"
1890                                 "${DATAFILE_DIR}/${_lua_filename}"
1891                         DEPENDS
1892                                 wsluaauxiliary
1893                                 "${_lua_file}"
1894                 )
1895         endforeach()
1896 endif(LUA_FOUND AND ENABLE_LUA)
1897 # doc/*.html handled elsewhere.
1898
1899 # TODO shouldn't this use full (relative) paths instead of glob patterns?
1900 list(APPEND DATA_FILES_SRC
1901         "tpncp/tpncp.dat"
1902         "wimaxasncp/*.dtd"
1903         "wimaxasncp/*.xml"
1904 )
1905
1906 # Copy all paths from the source tree to the data directory. Directories are
1907 # automatically created if missing as the filename is given.
1908 file(GLOB _data_files RELATIVE "${CMAKE_SOURCE_DIR}" ${DATA_FILES_SRC})
1909 foreach(_data_file ${_data_files})
1910         add_custom_command(OUTPUT "${DATAFILE_DIR}/${_data_file}"
1911                 COMMAND ${CMAKE_COMMAND} -E copy_if_different
1912                         "${CMAKE_SOURCE_DIR}/${_data_file}"
1913                         "${DATAFILE_DIR}/${_data_file}"
1914                 DEPENDS
1915                         "${CMAKE_SOURCE_DIR}/${_data_file}"
1916         )
1917         list(APPEND copy_data_files_depends "${DATAFILE_DIR}/${_data_file}")
1918 endforeach()
1919
1920 file(GLOB _dtds_src_files RELATIVE "${CMAKE_SOURCE_DIR}" "dtds/*.dtd")
1921
1922 set (_dtds_data_files)
1923 foreach(_data_file ${_dtds_src_files})
1924         list(APPEND _dtds_data_files "${DATAFILE_DIR}/${_data_file}")
1925 endforeach()
1926
1927 add_custom_command(
1928         OUTPUT ${_dtds_data_files}
1929         COMMAND ${CMAKE_COMMAND} -E make_directory "${DATAFILE_DIR}/dtds"
1930         COMMAND ${CMAKE_COMMAND} -E copy_if_different
1931                 ${_dtds_src_files}
1932                 "${DATAFILE_DIR}/dtds"
1933         VERBATIM
1934         DEPENDS ${_dtds_src_files}
1935         WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}"
1936 )
1937
1938 file(GLOB _diameter_src_files RELATIVE "${CMAKE_SOURCE_DIR}"
1939         diameter/*.dtd
1940         diameter/*.xml
1941 )
1942
1943 set (_diameter_data_files)
1944 foreach(_data_file ${_diameter_src_files})
1945         list(APPEND _diameter_data_files "${DATAFILE_DIR}/${_data_file}")
1946 endforeach()
1947
1948 add_custom_command(
1949         OUTPUT ${_diameter_data_files}
1950         COMMAND ${CMAKE_COMMAND} -E make_directory "${DATAFILE_DIR}/diameter"
1951         COMMAND ${CMAKE_COMMAND} -E copy_if_different
1952                 ${_diameter_src_files}
1953                 "${DATAFILE_DIR}/diameter"
1954         VERBATIM
1955         DEPENDS ${_diameter_src_files}
1956         WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}"
1957 )
1958
1959 file(GLOB _radius_src_files RELATIVE "${CMAKE_SOURCE_DIR}"
1960         radius/README.radius_dictionary
1961         radius/custom.includes
1962         radius/dictionary
1963         radius/dictionary.*
1964 )
1965
1966 set (_radius_data_files)
1967 foreach(_data_file ${_radius_src_files})
1968         list(APPEND _radius_data_files "${DATAFILE_DIR}/${_data_file}")
1969 endforeach()
1970
1971 add_custom_command(
1972         OUTPUT ${_radius_data_files}
1973         COMMAND ${CMAKE_COMMAND} -E make_directory "${DATAFILE_DIR}/radius"
1974         COMMAND ${CMAKE_COMMAND} -E copy_if_different
1975                 ${_radius_src_files}
1976                 "${DATAFILE_DIR}/radius"
1977         VERBATIM
1978         DEPENDS ${_radius_src_files}
1979         WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}"
1980 )
1981
1982 file(GLOB _profiles_src_files RELATIVE "${CMAKE_SOURCE_DIR}" profiles/*/*)
1983 set (_profiles_data_files)
1984 foreach(_data_file ${_profiles_src_files})
1985         list(APPEND _profiles_data_files "${DATAFILE_DIR}/${_data_file}")
1986 endforeach()
1987
1988 add_custom_command(
1989         OUTPUT ${_profiles_data_files}
1990         COMMAND ${CMAKE_COMMAND} -E copy_directory
1991                 "${CMAKE_SOURCE_DIR}/profiles" "${DATAFILE_DIR}/profiles"
1992 )
1993
1994 list(APPEND copy_data_files_depends
1995         ${_dtds_data_files}
1996         ${_diameter_data_files}
1997         ${_radius_data_files}
1998         ${_profiles_data_files}
1999 )
2000
2001 # Copy files including ${INSTALL_FILES} and ${INSTALL_DIRS} to ${DATAFILE_DIR}
2002 add_custom_target(copy_data_files ALL DEPENDS ${copy_data_files_depends} )
2003 set_target_properties(copy_data_files PROPERTIES FOLDER "Copy Tasks")
2004
2005 if(BUILD_wireshark AND QT_FOUND)
2006         set(WIRESHARK_SRC
2007                 capture_info.c
2008                 capture_opts.c
2009                 file.c
2010                 fileset.c
2011                 ${SHARK_COMMON_SRC}
2012                 ${PLATFORM_UI_SRC}
2013         )
2014         set(wireshark_FILES
2015                 ${WIRESHARK_SRC}
2016                 ${CMAKE_BINARY_DIR}/image/wireshark.rc
2017                 ${PLATFORM_UI_RC_FILES}
2018         )
2019 endif()
2020
2021 if(ENABLE_APPLICATION_BUNDLE)
2022         #
2023         # Add -Wl,-single_module to the LDFLAGS used with shared
2024         # libraries, to fix some error that show up in some cases;
2025         # some Apple documentation recommends it for most shared
2026         # libraries.
2027         #
2028         set( CMAKE_SHARED_LINKER_FLAGS "-Wl,-single_module ${CMAKE_SHARED_LINKER_FLAGS}" )
2029         #
2030         # Add -Wl,-headerpad_max_install_names to the LDFLAGS, as
2031         # code-signing issues is running out of padding space.
2032         #
2033         # Add -Wl,-search_paths_first to make sure that if we search
2034         # directories A and B, in that order, for a given library, a
2035         # non-shared version in directory A, rather than a shared
2036         # version in directory B, is chosen (so we can use
2037         # --with-pcap=/usr/local to force all programs to be linked
2038         # with a static version installed in /usr/local/lib rather than
2039         # the system version in /usr/lib).
2040         #
2041
2042         set(CMAKE_EXE_LINKER_FLAGS
2043         "-Wl,-headerpad_max_install_names -Wl,-search_paths_first ${CMAKE_EXE_LINKER_FLAGS}"
2044         )
2045
2046         # Add files to the app bundle
2047         # Wireshark.app/Contents
2048         file(WRITE ${CMAKE_BINARY_DIR}/packaging/macosx/PkgInfo "APPLWshk\n")
2049         set(BUNDLE_CONTENTS_FILES
2050                 ${CMAKE_BINARY_DIR}/packaging/macosx/PkgInfo
2051         )
2052         set_source_files_properties(${BUNDLE_CONTENTS_FILES} PROPERTIES
2053                 MACOSX_PACKAGE_LOCATION .
2054         )
2055
2056         # Wireshark.app/Contents/Resources
2057         set(BUNDLE_RESOURCE_FILES
2058                 ${CMAKE_SOURCE_DIR}/packaging/macosx/Wireshark.icns
2059                 ${CMAKE_SOURCE_DIR}/packaging/macosx/Wiresharkdoc.icns
2060         )
2061         set_source_files_properties(${BUNDLE_RESOURCE_FILES} PROPERTIES
2062                 MACOSX_PACKAGE_LOCATION Resources
2063         )
2064
2065         # Wireshark.app/Contents/Resources/share/man/man1
2066         set_source_files_properties(${BUNDLE_RESOURCE_SHARE_MAN1_FILES} PROPERTIES
2067                 MACOSX_PACKAGE_LOCATION Resources/share/man/man1
2068                 GENERATED 1
2069         )
2070
2071         # Wireshark.app/Contents/Resources/share/man/man4
2072         set_source_files_properties(${BUNDLE_RESOURCE_SHARE_MAN4_FILES} PROPERTIES
2073                 MACOSX_PACKAGE_LOCATION Resources/share/man/man4
2074                 GENERATED 1
2075         )
2076
2077         # INSTALL_FILES and INSTALL_DIRS are handled by copy_data_files
2078
2079         set(EXTRA_BUNDLE_FILES
2080                 ${BUNDLE_CONTENTS_FILES}
2081                 ${BUNDLE_RESOURCE_FILES}
2082                 ${BUNDLE_RESOURCE_SHARE_MAN1_FILES}
2083                 ${BUNDLE_RESOURCE_SHARE_MAN4_FILES}
2084         )
2085 else()
2086         set(EXTRA_BUNDLE_FILES)
2087 endif()
2088
2089 if(BUILD_wireshark AND QT_FOUND)
2090         set(wireshark_LIBS
2091                 qtui
2092                 ui
2093                 capchild
2094                 caputils
2095                 wiretap
2096                 ${QT_LIBRARIES}
2097                 ${GTHREAD2_LIBRARIES}
2098                 wscodecs
2099                 ${LIBEPAN_LIBS}
2100                 ${APPLE_APPLICATION_SERVICES_LIBRARY}
2101                 ${APPLE_APPKIT_LIBRARY}
2102                 ${APPLE_CORE_FOUNDATION_LIBRARY}
2103                 ${APPLE_SYSTEM_CONFIGURATION_LIBRARY}
2104                 ${NL_LIBRARIES}
2105                 ${WIN_VERSION_LIBRARY}
2106         )
2107
2108         add_executable(wireshark WIN32 MACOSX_BUNDLE ${wireshark_FILES} ${EXTRA_BUNDLE_FILES})
2109         add_dependencies(wireshark version)
2110         set(PROGLIST ${PROGLIST} wireshark)
2111         if(CMAKE_VERSION VERSION_LESS "2.8.12"
2112             AND (CMAKE_CXX_COMPILER_ID STREQUAL "GNU"
2113             AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS 5.0))
2114                 #
2115                 # https://doc.qt.io/qt-5/cmake-manual.html says that for CMake
2116                 # versions older than 2.8.12,
2117                 # Qt5<Module>_EXECUTABLE_COMPILE_FLAGS must be added such that
2118                 # -fPIC is included. We should not do add this to
2119                 # CMAKE_CXX_FLAGS though since it may end up before the -fPIE
2120                 # option. Instead, add it to the target COMPILE_FLAGS. This
2121                 # option is deprecated in newer CMake versions and not necessary
2122                 # either since Qt uses the INTERFACE_COMPILE_OPTIONS property.
2123                 #
2124                 set_target_properties(wireshark PROPERTIES COMPILE_FLAGS "${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
2125         endif()
2126         set_target_properties(wireshark PROPERTIES
2127                 LINK_FLAGS "${WS_LINK_FLAGS}"
2128                 FOLDER "Executables"
2129         )
2130         if(ENABLE_APPLICATION_BUNDLE OR WIN32)
2131                 set_target_properties(wireshark PROPERTIES OUTPUT_NAME Wireshark)
2132         endif()
2133
2134         if(ENABLE_APPLICATION_BUNDLE)
2135                 add_dependencies(wireshark manpages)
2136                 set_target_properties(
2137                         wireshark PROPERTIES
2138                                 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_BINARY_DIR}/packaging/macosx/Info.plist
2139                 )
2140                 if(CMAKE_CFG_INTDIR STREQUAL ".")
2141                         # Add a wrapper script which opens the bundle. This adds
2142                         # convenience but makes debugging more difficult.
2143                         # It is not created if using Xcode
2144                         file(REMOVE ${CMAKE_BINARY_DIR}/run/wireshark)
2145                         file(WRITE ${CMAKE_BINARY_DIR}/run/wireshark "#!/bin/sh\n")
2146                         file(APPEND ${CMAKE_BINARY_DIR}/run/wireshark "# Generated by ${CMAKE_CURRENT_LIST_FILE}\n")
2147                         file(APPEND ${CMAKE_BINARY_DIR}/run/wireshark "exec ${CMAKE_BINARY_DIR}/run/Wireshark.app/Contents/MacOS/Wireshark \"\$\@\"\n")
2148                         execute_process(COMMAND chmod a+x ${CMAKE_BINARY_DIR}/run/wireshark)
2149                 endif()
2150         endif()
2151
2152         target_link_libraries(wireshark ${wireshark_LIBS})
2153         install(
2154                 TARGETS wireshark
2155                 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
2156                 BUNDLE DESTINATION ${CMAKE_INSTALL_BINDIR}
2157         )
2158
2159         if(QT_WINDEPLOYQT_EXECUTABLE)
2160                 add_custom_target(copy_qt_dlls ALL)
2161                 set_target_properties(copy_qt_dlls PROPERTIES FOLDER "Copy Tasks")
2162                 # Will we ever need to use --debug? Windeployqt seems to
2163                 # be smart enough to copy debug DLLs when needed.
2164                 add_custom_command(TARGET copy_qt_dlls
2165                         POST_BUILD
2166                         COMMAND set "PATH=${QT_BIN_PATH};%PATH%"
2167                         COMMAND "${QT_WINDEPLOYQT_EXECUTABLE}"
2168                                 $<$<CONFIG:Debug>:--debug>
2169                                 $<$<NOT:$<CONFIG:Debug>>:--release>
2170                                 --no-compiler-runtime
2171                                 --verbose 10
2172                                 "$<TARGET_FILE:wireshark>"
2173                 )
2174                 add_dependencies(copy_qt_dlls wireshark)
2175         endif(QT_WINDEPLOYQT_EXECUTABLE)
2176 endif()
2177
2178 # Common properties for CLI executables
2179 macro(set_extra_executable_properties _executable _folder)
2180         set_target_properties(${_executable} PROPERTIES
2181                 LINK_FLAGS "${WS_LINK_FLAGS}"
2182                 FOLDER ${_folder}
2183         )
2184
2185         set(PROGLIST ${PROGLIST} ${_executable})
2186
2187         if(ENABLE_APPLICATION_BUNDLE)
2188                 if(NOT CMAKE_CFG_INTDIR STREQUAL ".")
2189                         # Xcode
2190                         set_target_properties(${_executable} PROPERTIES
2191                                 RUNTIME_OUTPUT_DIRECTORY run/$<CONFIG>/Wireshark.app/Contents/MacOS
2192                         )
2193                 else ()
2194                         set_target_properties(${_executable} PROPERTIES
2195                                 RUNTIME_OUTPUT_DIRECTORY run/Wireshark.app/Contents/MacOS
2196                         )
2197                         # Add a wrapper script which runs each executable from the
2198                         # correct location. This adds convenience but makes debugging
2199                         # more difficult.
2200                         file(REMOVE ${CMAKE_BINARY_DIR}/run/${_executable})
2201                         file(WRITE ${CMAKE_BINARY_DIR}/run/${_executable} "#!/bin/sh\n")
2202                         file(APPEND ${CMAKE_BINARY_DIR}/run/${_executable} "exec ${CMAKE_BINARY_DIR}/run/Wireshark.app/Contents/MacOS/${_executable} \"\$\@\"\n")
2203                         execute_process(COMMAND chmod a+x ${CMAKE_BINARY_DIR}/run/${_executable})
2204                 endif()
2205         endif()
2206 endmacro()
2207
2208 register_tap_files(tshark-tap-register.c
2209         ${TSHARK_TAP_SRC}
2210 )
2211
2212 if(BUILD_tshark)
2213         set(tshark_LIBS
2214                 ui
2215                 capchild
2216                 caputils
2217                 wiretap
2218                 ${LIBEPAN_LIBS}
2219                 ${APPLE_CORE_FOUNDATION_LIBRARY}
2220                 ${APPLE_SYSTEM_CONFIGURATION_LIBRARY}
2221         )
2222         set(tshark_FILES
2223                 capture_opts.c
2224                 tshark-tap-register.c
2225                 tshark.c
2226                 ${TSHARK_TAP_SRC}
2227                 ${SHARK_COMMON_SRC}
2228                 ${CMAKE_BINARY_DIR}/image/tshark.rc
2229         )
2230
2231         add_executable(tshark ${tshark_FILES})
2232         add_dependencies(tshark version)
2233         set_extra_executable_properties(tshark "Executables")
2234         target_link_libraries(tshark ${tshark_LIBS})
2235         install(TARGETS tshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
2236 endif()
2237
2238 if(BUILD_tfshark)
2239         set(tfshark_LIBS
2240                 ui
2241                 wiretap
2242                 ${LIBEPAN_LIBS}
2243                 ${APPLE_CORE_FOUNDATION_LIBRARY}
2244                 ${APPLE_SYSTEM_CONFIGURATION_LIBRARY}
2245         )
2246         set(tfshark_FILES
2247                 tfshark.c
2248                 ${TSHARK_TAP_SRC}
2249                 ${SHARK_COMMON_SRC}
2250                 ${CMAKE_BINARY_DIR}/image/tfshark.rc
2251         )
2252         add_executable(tfshark ${tfshark_FILES})
2253         add_dependencies(tfshark version)
2254         set_extra_executable_properties(tfshark "Executables")
2255         target_link_libraries(tfshark ${tfshark_LIBS})
2256         install(TARGETS tfshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
2257 endif()
2258
2259 if(BUILD_rawshark AND PCAP_FOUND)
2260         set(rawshark_LIBS
2261                 caputils
2262                 ui
2263                 wiretap
2264                 ${LIBEPAN_LIBS}
2265                 ${APPLE_CORE_FOUNDATION_LIBRARY}
2266                 ${APPLE_SYSTEM_CONFIGURATION_LIBRARY}
2267         )
2268         set(rawshark_FILES
2269                 ${SHARK_COMMON_SRC}
2270                 rawshark.c
2271                 ${CMAKE_BINARY_DIR}/image/rawshark.rc
2272         )
2273         add_executable(rawshark ${rawshark_FILES})
2274         add_dependencies(rawshark version)
2275         set_extra_executable_properties(rawshark "Executables")
2276         target_link_libraries(rawshark ${rawshark_LIBS})
2277         install(TARGETS rawshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
2278 endif()
2279
2280 if(BUILD_sharkd)
2281         set(sharkd_LIBS
2282                 ui
2283                 wscodecs
2284                 wiretap
2285                 ${LIBEPAN_LIBS}
2286                 ${APPLE_CORE_FOUNDATION_LIBRARY}
2287                 ${APPLE_SYSTEM_CONFIGURATION_LIBRARY}
2288         )
2289         set(sharkd_FILES
2290                 sharkd.c
2291                 sharkd_daemon.c
2292                 sharkd_session.c
2293                 ${SHARK_COMMON_SRC}
2294         )
2295         add_executable(sharkd ${sharkd_FILES})
2296         add_dependencies(sharkd version)
2297         set_extra_executable_properties(sharkd "Executables")
2298         target_link_libraries(sharkd ${sharkd_LIBS})
2299         install(TARGETS sharkd RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
2300 endif()
2301
2302 if(BUILD_dftest)
2303         set(dftest_LIBS
2304                 ui
2305                 wiretap
2306                 ${LIBEPAN_LIBS}
2307         )
2308         set(dftest_FILES
2309                 dftest.c
2310         )
2311         add_executable(dftest ${dftest_FILES})
2312         add_dependencies(dftest version)
2313         set_extra_executable_properties(dftest "Tests")
2314         target_link_libraries(dftest ${dftest_LIBS})
2315 endif()
2316
2317 if(BUILD_randpkt)
2318         set(randpkt_LIBS
2319                 randpkt_core
2320                 ui
2321                 wiretap
2322                 wsutil
2323                 ${M_LIBRARIES}
2324                 ${PCAP_LIBRARIES}
2325                 ${CARES_LIBRARIES}
2326                 ${ZLIB_LIBRARIES}
2327         )
2328         set(randpkt_FILES
2329                 randpkt.c
2330                 version_info.c
2331         )
2332         add_executable(randpkt ${randpkt_FILES})
2333         add_dependencies(randpkt version)
2334         set_extra_executable_properties(randpkt "Executables")
2335         target_link_libraries(randpkt ${randpkt_LIBS})
2336         install(TARGETS randpkt RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
2337 endif()
2338
2339 if(BUILD_fuzzshark)
2340         set(fuzzshark_LIBS
2341                 wiretap
2342                 ${LIBEPAN_LIBS}
2343         )
2344         set(fuzzshark_FILES
2345                 tools/oss-fuzzshark/fuzzshark.c
2346                 tools/oss-fuzzshark/StandaloneFuzzTargetMain.c
2347                 version_info.c
2348         )
2349         add_executable(fuzzshark ${fuzzshark_FILES})
2350         add_dependencies(fuzzshark version)
2351         set_extra_executable_properties(fuzzshark "Executables")
2352         target_link_libraries(fuzzshark ${fuzzshark_LIBS})
2353 endif()
2354
2355 if(BUILD_text2pcap)
2356         set(text2pcap_LIBS
2357                 writecap
2358                 wsutil
2359                 ${M_LIBRARIES}
2360                 ${ZLIB_LIBRARIES}
2361         )
2362         set(text2pcap_FILES
2363                 text2pcap.c
2364                 version_info.c
2365         )
2366         add_lex_files(text2pcap_LEX_FILES text2pcap_FILES
2367                 text2pcap-scanner.l
2368         )
2369         add_executable(text2pcap ${text2pcap_FILES}
2370                 ${CMAKE_BINARY_DIR}/image/text2pcap.rc)
2371         add_dependencies(text2pcap version)
2372         set_extra_executable_properties(text2pcap "Executables")
2373         target_link_libraries(text2pcap ${text2pcap_LIBS})
2374         install(TARGETS text2pcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
2375 endif()
2376
2377 if(BUILD_mergecap)
2378         set(mergecap_LIBS
2379                 ui
2380                 wiretap
2381                 ${ZLIB_LIBRARIES}
2382                 ${CMAKE_DL_LIBS}
2383         )
2384         set(mergecap_FILES
2385                 mergecap.c
2386                 version_info.c
2387                 ${CMAKE_BINARY_DIR}/image/mergecap.rc
2388         )
2389         add_executable(mergecap ${mergecap_FILES})
2390         add_dependencies(mergecap version)
2391         set_extra_executable_properties(mergecap "Executables")
2392         target_link_libraries(mergecap ${mergecap_LIBS})
2393         install(TARGETS mergecap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
2394 endif()
2395
2396 if(BUILD_reordercap)
2397         set(reordercap_LIBS
2398                 ui
2399                 wiretap
2400                 ${ZLIB_LIBRARIES}
2401                 ${CMAKE_DL_LIBS}
2402         )
2403         set(reordercap_FILES
2404                 reordercap.c
2405                 version_info.c
2406                 ${CMAKE_BINARY_DIR}/image/reordercap.rc
2407         )
2408         add_executable(reordercap ${reordercap_FILES})
2409         add_dependencies(reordercap version)
2410         set_extra_executable_properties(reordercap "Executables")
2411         target_link_libraries(reordercap ${reordercap_LIBS})
2412         install(TARGETS reordercap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
2413 endif()
2414
2415 if(BUILD_capinfos)
2416         set(capinfos_LIBS
2417                 ui
2418                 wiretap
2419                 wsutil
2420                 ${ZLIB_LIBRARIES}
2421                 ${GCRYPT_LIBRARIES}
2422                 ${CMAKE_DL_LIBS}
2423         )
2424         set(capinfos_FILES
2425                 capinfos.c
2426                 version_info.c
2427                 ${CMAKE_BINARY_DIR}/image/capinfos.rc
2428         )
2429         add_executable(capinfos ${capinfos_FILES})
2430         add_dependencies(capinfos version)
2431         set_extra_executable_properties(capinfos "Executables")
2432         target_link_libraries(capinfos ${capinfos_LIBS})
2433         install(TARGETS capinfos RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
2434 endif()
2435
2436 if(BUILD_captype)
2437         set(captype_LIBS
2438                 ui
2439                 wiretap
2440                 wsutil
2441                 ${ZLIB_LIBRARIES}
2442                 ${CMAKE_DL_LIBS}
2443         )
2444         set(captype_FILES
2445                 captype.c
2446                 version_info.c
2447                 ${CMAKE_BINARY_DIR}/image/captype.rc
2448         )
2449         add_executable(captype ${captype_FILES})
2450         add_dependencies(captype version)
2451         set_extra_executable_properties(captype "Executables")
2452         target_link_libraries(captype ${captype_LIBS})
2453         install(TARGETS captype RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
2454 endif()
2455
2456 if(BUILD_editcap)
2457         set(editcap_LIBS
2458                 ui
2459                 wiretap
2460                 ${ZLIB_LIBRARIES}
2461                 ${GCRYPT_LIBRARIES}
2462                 ${CMAKE_DL_LIBS}
2463         )
2464         set(editcap_FILES
2465                 editcap.c
2466                 version_info.c
2467                 ${CMAKE_BINARY_DIR}/image/editcap.rc
2468         )
2469         add_executable(editcap ${editcap_FILES})
2470         add_dependencies(editcap version)
2471         set_extra_executable_properties(editcap "Executables")
2472         target_link_libraries(editcap ${editcap_LIBS})
2473         install(TARGETS editcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
2474 endif()
2475
2476 if(BUILD_dumpcap AND PCAP_FOUND)
2477         set(dumpcap_LIBS
2478                 writecap
2479                 wsutil
2480                 caputils
2481                 ui
2482                 ${PCAP_LIBRARIES}
2483                 ${CAP_LIBRARIES}
2484                 ${GLIB2_LIBRARIES}
2485                 ${GTHREAD2_LIBRARIES}
2486                 ${ZLIB_LIBRARIES}
2487                 ${APPLE_CORE_FOUNDATION_LIBRARY}
2488                 ${APPLE_SYSTEM_CONFIGURATION_LIBRARY}
2489                 ${NL_LIBRARIES}
2490         )
2491         set(dumpcap_FILES
2492                 capture_opts.c
2493                 capture_stop_conditions.c
2494                 conditions.c
2495                 dumpcap.c
2496                 ringbuffer.c
2497                 sync_pipe_write.c
2498                 version_info.c
2499                 ${CMAKE_BINARY_DIR}/image/dumpcap.rc
2500         )
2501         add_executable(dumpcap ${dumpcap_FILES})
2502         add_dependencies(dumpcap version)
2503         set_extra_executable_properties(dumpcap "Executables")
2504         target_link_libraries(dumpcap ${dumpcap_LIBS})
2505         install(TARGETS dumpcap
2506                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
2507                         PERMISSIONS ${DUMPCAP_SETUID}
2508                                 OWNER_READ OWNER_WRITE OWNER_EXECUTE
2509                                 GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE
2510         )
2511         if(ENABLE_DUMPCAP_GROUP)
2512                 install(CODE "execute_process(COMMAND chgrp ${DUMPCAP_INSTALL_GROUP} ${CMAKE_INSTALL_FULL_BINDIR}/dumpcap)")
2513                 install(CODE "execute_process(COMMAND chmod o-x ${CMAKE_INSTALL_FULL_BINDIR}/dumpcap)")
2514         endif()
2515         if(DUMPCAP_INSTALL_OPTION STREQUAL "capabilities")
2516                 install( CODE "execute_process(
2517                         COMMAND
2518                                 ${SETCAP_EXECUTABLE}
2519                                 cap_net_raw,cap_net_admin+ep
2520                                 ${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_BINDIR}/dumpcap${CMAKE_EXECUTABLE_SUFFIX}
2521                         RESULT_VARIABLE
2522                                 _SETCAP_RESULT
2523                         )
2524                         if( _SETCAP_RESULT )
2525                                 message( WARNING \"setcap failed (${_SETCAP_RESULT}).\")
2526                         endif()"
2527                 )
2528         endif()
2529 endif()
2530
2531 # We have two idl2wrs utilities: this and the CORBA version in tools.
2532 # We probably shouldn't do that.
2533 if(BUILD_dcerpcidl2wrs)
2534         set(idl2wrs_LIBS
2535                 ${GLIB2_LIBRARIES}
2536                 wsutil
2537         )
2538         set(idl2wrs_FILES
2539                 epan/dissectors/dcerpc/idl2wrs.c
2540         )
2541
2542         add_executable(idl2wrs ${idl2wrs_FILES})
2543         set_target_properties(idl2wrs PROPERTIES FOLDER "Executables")
2544         set_extra_executable_properties(idl2wrs "Executables")
2545         target_link_libraries(idl2wrs ${idl2wrs_LIBS})
2546         install(TARGETS idl2wrs RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
2547 endif()
2548
2549 if (WIN32)
2550         find_package( MSVC_REDIST )
2551
2552         # Must come after executable targets are defined.
2553         find_package( NSIS )
2554
2555         if(MAKENSIS_EXECUTABLE)
2556                 add_subdirectory( packaging/nsis EXCLUDE_FROM_ALL )
2557                 ADD_NSIS_UNINSTALLER_TARGET()
2558                 ADD_NSIS_PACKAGE_TARGET()
2559         endif()
2560
2561         find_package( WiX )
2562
2563         if(WIX_CANDLE_EXECUTABLE)
2564                 add_subdirectory( packaging/wix EXCLUDE_FROM_ALL )
2565                 ADD_WIX_PACKAGE_TARGET()
2566         endif()
2567
2568         find_package( PortableApps )
2569         if(PORTABLEAPPS_LAUNCHER_GENERATOR_EXECUTABLE AND PORTABLEAPPS_INSTALLER_EXECUTABLE)
2570                 add_subdirectory( packaging/portableapps EXCLUDE_FROM_ALL )
2571                 ADD_PORTABLEAPPS_PACKAGE_TARGET()
2572         endif()
2573 endif()
2574
2575 if (MAXMINDDB_FOUND)
2576         set(mmdbresolve_LIBS
2577                 # Note: libmaxminddb is not GPL-2 compatible.
2578                 ${MAXMINDDB_LIBRARY}
2579         )
2580         set(mmdbresolve_FILES
2581                 mmdbresolve.c
2582         )
2583         add_executable(mmdbresolve ${mmdbresolve_FILES})
2584         set_extra_executable_properties(mmdbresolve "Executables")
2585         target_link_libraries(mmdbresolve ${mmdbresolve_LIBS})
2586         target_include_directories(mmdbresolve PUBLIC ${MAXMINDDB_INCLUDE_DIR})
2587         install(TARGETS mmdbresolve RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
2588 endif()
2589
2590 if(ENABLE_APPLICATION_BUNDLE)
2591         add_custom_target(app_bundle)
2592         set_target_properties(app_bundle PROPERTIES FOLDER "Copy Tasks")
2593         add_custom_command(TARGET app_bundle
2594                 POST_BUILD
2595                 COMMAND "${CMAKE_BINARY_DIR}/packaging/macosx/osx-app.sh"
2596                 WORKING_DIRECTORY "${CMAKE_BINARY_DIR}/run"
2597         )
2598         add_dependencies(app_bundle ${PROGLIST})
2599
2600         add_custom_target(dmg_package_prep DEPENDS app_bundle)
2601
2602         ADD_CUSTOM_COMMAND(
2603                 OUTPUT ${CMAKE_BINARY_DIR}/packaging/macosx/PkgInfo
2604                 COMMAND ${CMAKE_COMMAND} -E echo APPLWshk > ${CMAKE_BINARY_DIR}/packaging/macosx/PkgInfo
2605         )
2606
2607         ADD_CUSTOM_TARGET( dmg_package
2608                 COMMAND ${CMAKE_COMMAND} -E copy_directory
2609                                         ${CMAKE_SOURCE_DIR}/packaging/macosx/ChmodBPF
2610                                         ${CMAKE_BINARY_DIR}/run/ChmodBPF
2611                 COMMAND ${CMAKE_COMMAND} -E copy_directory
2612                                         ${CMAKE_SOURCE_DIR}/packaging/macosx/Scripts
2613                                         ${CMAKE_BINARY_DIR}/run/Scripts
2614                 COMMAND ${CMAKE_COMMAND} -E copy_directory
2615                                         ${CMAKE_SOURCE_DIR}/packaging/macosx/utility-launcher
2616                                         ${CMAKE_BINARY_DIR}/run/utility-launcher
2617                 COMMAND ${CMAKE_COMMAND} -E copy_if_different
2618                                         ${CMAKE_SOURCE_DIR}/COPYING
2619                                         ${CMAKE_BINARY_DIR}/run/COPYING.txt
2620                 COMMAND ${CMAKE_COMMAND} -E copy_directory
2621                                         ${CMAKE_SOURCE_DIR}/packaging/macosx/Wireshark_package.pmdoc
2622                                         ${CMAKE_BINARY_DIR}/run/Wireshark_package.pmdoc
2623                 COMMAND ${CMAKE_COMMAND} -E copy_if_different
2624                                         ${CMAKE_BINARY_DIR}/packaging/macosx/Wireshark_package.pmdoc/index.xml
2625                                         ${CMAKE_BINARY_DIR}/run/Wireshark_package.pmdoc/index.xml
2626                 COMMAND ${CMAKE_COMMAND} -E copy_if_different
2627                                         ${CMAKE_SOURCE_DIR}/packaging/macosx/dmg_background.png
2628                                         ${CMAKE_BINARY_DIR}/run/dmg_background.png
2629                 COMMAND bash -x ${CMAKE_BINARY_DIR}/packaging/macosx/osx-dmg.sh
2630                         --source-directory ${CMAKE_SOURCE_DIR}/packaging/macosx
2631                 # Unlike nsis_package_prep + nsis_package, we can add a direct
2632                 # dependency here.
2633                 DEPENDS dmg_package_prep
2634                 # We create Wireshark.app in "run". Do our work there.
2635                 WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/run
2636         )
2637
2638 endif()
2639
2640 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
2641         find_program(RPMBUILD_EXECUTABLE rpmbuild)
2642         find_program(DPKG_BUILDPACKAGE_EXECUTABLE dpkg-buildpackage)
2643         find_program(GIT_EXECUTABLE git)
2644 endif()
2645
2646 function(_SET_GITVERSION_CMAKE_VARIABLE OUTPUT_VARIABLE)
2647         # Load version string and write it to a cmake variable so it can be accessed from cmake.
2648         FILE(READ "${CMAKE_CURRENT_BINARY_DIR}/version.h" VERSION_H_FILE_CONTENT)
2649         string(REPLACE "\n" "" VERSION_H_FILE_CONTENT ${VERSION_H_FILE_CONTENT})
2650         #define VCSVERSION "v2.9.0rc0-305-gb8e8aa87"
2651         string(SUBSTRING "${VERSION_H_FILE_CONTENT}" 21 -1 VERSION_STRING)
2652         STRING(REGEX REPLACE "\"" "" VERSION_STRING "${VERSION_STRING}")
2653         MESSAGE(STATUS "Version string created from version.h: ${VERSION_STRING}")
2654         SET(${OUTPUT_VARIABLE} "${VERSION_STRING}"  CACHE INTERNAL "${OUTPUT_VARIABLE}")
2655 endfunction(_SET_GITVERSION_CMAKE_VARIABLE)
2656
2657
2658 if(RPMBUILD_EXECUTABLE)
2659         foreach(_rpm_dir BUILD RPMS SOURCES SPECS SRPMS)
2660                 file(MAKE_DIRECTORY "${CMAKE_BINARY_DIR}/packaging/rpm/${_rpm_dir}")
2661         endforeach()
2662
2663         set(_rpmbuild_with_args)
2664         if(CMAKE_GENERATOR STREQUAL "Ninja")
2665                 list(APPEND _rpmbuild_with_args --with ninja)
2666         endif()
2667         if(CCACHE_EXECUTABLE)
2668                 list(APPEND _rpmbuild_with_args --with ccache)
2669         endif()
2670         if (BUILD_wireshark)
2671                 list(APPEND _rpmbuild_with_args --with qt5)
2672         endif()
2673         if (MAXMINDDB_FOUND)
2674                 list(APPEND _rpmbuild_with_args --with mmdbresolve)
2675         endif()
2676         if (LUA_FOUND)
2677                 list(APPEND _rpmbuild_with_args --with lua)
2678         endif()
2679         if (LZ4_FOUND AND SNAPPY_FOUND)
2680                 list(APPEND _rpmbuild_with_args --with lz4_and_snappy)
2681         endif()
2682         if (CARES_FOUND)
2683                 list(APPEND _rpmbuild_with_args --with c_ares)
2684         endif()
2685         if (SPANDSP_FOUND)
2686                 list(APPEND _rpmbuild_with_args --with spandsp)
2687         endif()
2688         if (BCG729_FOUND)
2689                 list(APPEND _rpmbuild_with_args --with bcg729)
2690         endif()
2691         if (LIBXML2_FOUND)
2692                 list(APPEND _rpmbuild_with_args --with libxml2)
2693         endif()
2694         if (NGHTTP2_FOUND)
2695                 list(APPEND _rpmbuild_with_args --with nghttp2)
2696         endif()
2697         if (SYSTEMD_FOUND)
2698                 list(APPEND _rpmbuild_with_args --with sdjournal)
2699         endif()
2700
2701         execute_process(
2702                 COMMAND ${PERL_EXECUTABLE}
2703                         ${CMAKE_SOURCE_DIR}/make-version.pl
2704                         ${CMAKE_SOURCE_DIR}
2705         )
2706
2707         _SET_GITVERSION_CMAKE_VARIABLE(_git_description)
2708
2709         if (NOT _git_description)
2710                 # We're building the rpm outside the source. Guess the version from the dirname.
2711                 get_filename_component(CMAKE_SOURCE_DIR_NAME ${CMAKE_SOURCE_DIR} NAME)
2712                 # XXX this assumes the directory to start with "wireshark-"
2713                 string(SUBSTRING "${CMAKE_SOURCE_DIR_NAME}" 10 -1 _git_description)
2714         endif()
2715         string(REPLACE "-" "_" RPM_VERSION "${_git_description}")
2716         configure_file(packaging/rpm/wireshark.spec.in ${CMAKE_BINARY_DIR}/packaging/rpm/SPECS/wireshark.spec)
2717
2718         # XXX Replace with the "dist" target?
2719         set(_export_tarball "${CPACK_PACKAGE_NAME}-${_git_description}.tar.xz")
2720         add_custom_command(
2721                 OUTPUT "${CMAKE_BINARY_DIR}/packaging/rpm/SOURCES/${_export_tarball}"
2722                 COMMAND ./tools/git-export-release.sh
2723                         -d "${CMAKE_BINARY_DIR}/packaging/rpm/SOURCES"
2724                         "${_git_description}"
2725                 # XXX Add an option to git-export-release.sh to write to a
2726                 # specific directory so that we can get rid of `ln` below.
2727                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
2728         )
2729         add_custom_target(rpm-package
2730                 COMMAND ${RPMBUILD_EXECUTABLE}
2731                         --define "_topdir ${CMAKE_BINARY_DIR}/packaging/rpm"
2732                         --define "_prefix ${CMAKE_INSTALL_PREFIX}"
2733                         ${_rpmbuild_with_args}
2734                         --clean -ba SPECS/wireshark.spec
2735                 DEPENDS "${CMAKE_BINARY_DIR}/packaging/rpm/SOURCES/${_export_tarball}"
2736                 WORKING_DIRECTORY "${CMAKE_BINARY_DIR}/packaging/rpm"
2737                 COMMENT "Create a tarball from the current git commit."
2738         )
2739 endif()
2740
2741 if(DPKG_BUILDPACKAGE_EXECUTABLE)
2742         add_custom_target(deb-package
2743                 COMMAND ${DPKG_BUILDPACKAGE_EXECUTABLE} -us -uc
2744                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
2745         )
2746 endif()
2747
2748 set(CLEAN_C_FILES
2749         ${dumpcap_FILES}
2750         ${wireshark_FILES}
2751         ${tshark_FILES}
2752         ${rawshark_FILES}
2753         ${dftest_FILES}
2754         ${randpkt_FILES}
2755         ${randpktdump_FILES}
2756         ${udpdump_FILES}
2757         ${text2pcap_FILES}
2758         ${mergecap_FILES}
2759         ${capinfos_FILES}
2760         ${captype_FILES}
2761         ${editcap_FILES}
2762         ${idl2wrs_FILES}
2763         ${mmdbresolve_FILES}
2764 )
2765
2766 # Make sure we don't pass /WX to rc.exe. Rc doesn't have a /WX flag,
2767 # but it does have /W (warn about invalid code pages) and /X (ignore
2768 # the INCLUDE environment variable).
2769 # This should apparently be handled for us via CMAKE_RC_FLAG_REGEX
2770 # in CMakeRCInformation.cmake but that doesn't appear to work.
2771 if (WIN32)
2772         list(FILTER CLEAN_C_FILES EXCLUDE REGEX ".*\\.rc")
2773 endif (WIN32)
2774
2775 set_source_files_properties(
2776         ${CLEAN_C_FILES}
2777         PROPERTIES
2778         COMPILE_FLAGS "${WERROR_COMMON_FLAGS}"
2779 )
2780
2781 install(
2782         FILES
2783                 ${INSTALL_FILES}
2784         PERMISSIONS
2785                 OWNER_WRITE OWNER_READ
2786                 GROUP_READ
2787                 WORLD_READ
2788         DESTINATION
2789                 ${CMAKE_INSTALL_DATADIR}/${CPACK_PACKAGE_NAME}
2790 )
2791
2792 set(SHARK_PUBLIC_HEADERS
2793         cfile.h
2794         file.h
2795         globals.h
2796         log.h
2797         ws_attributes.h
2798         ws_compiler_tests.h
2799         ws_diag_control.h
2800         ws_symbol_export.h
2801         version_info.h
2802         ${CMAKE_BINARY_DIR}/ws_version.h
2803 )
2804
2805 if(NOT WIN32)
2806         install(
2807                 FILES
2808                         ${SHARK_PUBLIC_HEADERS}
2809                 DESTINATION
2810                         ${CMAKE_INSTALL_INCLUDEDIR}/${CPACK_PACKAGE_NAME}
2811         )
2812 endif()
2813
2814 # Install icons and other desktop files for Freedesktop.org-compliant desktops.
2815 if((BUILD_wireshark AND QT_FOUND) AND NOT (WIN32 OR APPLE))
2816         install(FILES wireshark-mime-package.xml
2817                 DESTINATION "${CMAKE_INSTALL_DATADIR}/mime/packages"
2818                 RENAME wireshark.xml
2819         )
2820         install(FILES wireshark.appdata.xml
2821                 DESTINATION "${CMAKE_INSTALL_DATADIR}/appdata"
2822         )
2823         if(BUILD_wireshark AND QT_FOUND)
2824                 install(FILES wireshark.desktop
2825                         DESTINATION "${CMAKE_INSTALL_DATADIR}/applications")
2826         endif()
2827         foreach(size 16 24 32 48 64 128 256)
2828                 install(FILES image/wsicon${size}.png
2829                         DESTINATION "${CMAKE_INSTALL_DATADIR}/icons/hicolor/${size}x${size}/apps"
2830                         RENAME wireshark.png)
2831                 install(FILES image/WiresharkDoc-${size}.png
2832                         DESTINATION "${CMAKE_INSTALL_DATADIR}/icons/hicolor/${size}x${size}/mimetypes"
2833                         RENAME application-wireshark-doc.png)
2834         endforeach()
2835         install(FILES image/wsicon.svg
2836                 DESTINATION "${CMAKE_INSTALL_DATADIR}/icons/hicolor/scalable/apps"
2837                 RENAME wireshark.svg)
2838 endif()
2839
2840 install(
2841         FILES
2842                 "${CMAKE_BINARY_DIR}/wireshark.pc"
2843         DESTINATION
2844                 ${CMAKE_INSTALL_LIBDIR}/pkgconfig
2845 )
2846
2847 install(
2848         DIRECTORY
2849                 ${INSTALL_DIRS}
2850         DESTINATION
2851                 ${CMAKE_INSTALL_DATADIR}/${CPACK_PACKAGE_NAME}
2852         FILE_PERMISSIONS
2853                 OWNER_WRITE OWNER_READ
2854                 GROUP_READ
2855                 WORLD_READ
2856         DIRECTORY_PERMISSIONS
2857                 OWNER_EXECUTE OWNER_WRITE OWNER_READ
2858                 GROUP_EXECUTE GROUP_READ
2859                 WORLD_EXECUTE WORLD_READ
2860         PATTERN ".git" EXCLUDE
2861         PATTERN ".svn" EXCLUDE
2862         PATTERN "Makefile.*" EXCLUDE
2863 )
2864
2865 set(CMAKE_INSTALL_MODULES_DIR "${CMAKE_INSTALL_LIBDIR}/${CPACK_PACKAGE_NAME}/cmake")
2866 install(
2867         FILES
2868                 ${CMAKE_MODULE_PATH}/FindGLIB2.cmake
2869                 ${CMAKE_MODULE_PATH}/FindWSWinLibs.cmake
2870                 ${CMAKE_MODULE_PATH}/UseAsn2Wrs.cmake
2871                 ${CMAKE_MODULE_PATH}/LocatePythonModule.cmake
2872                 ${CMAKE_MODULE_PATH}/UseMakePluginReg.cmake
2873         DESTINATION
2874                 ${CMAKE_INSTALL_MODULES_DIR}
2875 )
2876
2877 include(CMakePackageConfigHelpers)
2878
2879 configure_package_config_file(WiresharkConfig.cmake.in
2880         ${CMAKE_BINARY_DIR}/WiresharkConfig.cmake
2881         INSTALL_DESTINATION ${CMAKE_INSTALL_MODULES_DIR}
2882         PATH_VARS
2883                 CMAKE_INSTALL_LIBDIR
2884                 CMAKE_INSTALL_INCLUDEDIR
2885                 PLUGIN_INSTALL_VERSION_LIBDIR
2886                 EXTCAP_INSTALL_LIBDIR
2887 )
2888
2889 write_basic_package_version_file(
2890         ${CMAKE_BINARY_DIR}/WiresharkConfigVersion.cmake
2891         COMPATIBILITY AnyNewerVersion
2892 )
2893
2894 # XXX On Windows wsutil depends on a CMake zlib target for which there are no
2895 # exports.
2896 if(NOT WIN32)
2897         install(
2898                 FILES
2899                         ${CMAKE_BINARY_DIR}/WiresharkConfig.cmake
2900                         ${CMAKE_BINARY_DIR}/WiresharkConfigVersion.cmake
2901                 DESTINATION
2902                         ${CMAKE_INSTALL_MODULES_DIR}
2903         )
2904
2905         install(EXPORT WiresharkTargets
2906                 DESTINATION ${CMAKE_INSTALL_MODULES_DIR}
2907         )
2908 endif()
2909
2910 if (DOXYGEN_EXECUTABLE)
2911         # API reference
2912         # We don't have a good way of tracking dependencies, so we simply
2913         # recreate the whole thing from scratch each time.
2914         add_custom_target(wsar_html
2915                 COMMAND ${CMAKE_COMMAND} -E remove_directory wsar_html
2916                 COMMAND ${DOXYGEN_EXECUTABLE} doxygen.cfg
2917         )
2918
2919         add_custom_target(wsar_html_zip
2920                 COMMAND ${CMAKE_COMMAND} -E tar "cfv" "wsar_html.zip" --format=zip wsar_html
2921                 DEPENDS wsar_html
2922         )
2923         set_target_properties(wsar_html wsar_html_zip PROPERTIES
2924                 FOLDER "Docs"
2925                 EXCLUDE_FROM_DEFAULT_BUILD True
2926         )
2927 endif(DOXYGEN_EXECUTABLE)
2928
2929 add_custom_target(test-programs
2930         DEPENDS exntest
2931                 oids_test
2932                 reassemble_test
2933                 tvbtest
2934                 wmem_test
2935         COMMENT "Building unit test programs and wrapper"
2936 )
2937 set_target_properties(test-programs PROPERTIES
2938         FOLDER "Tests"
2939         EXCLUDE_FROM_DEFAULT_BUILD True
2940 )
2941
2942 # Test suites
2943 enable_testing()
2944 # We could try to build this list dynamically, but given that we tend to
2945 # go years between adding suites just run
2946 #     test/test.py --list-groups | sort
2947 # and paste the output here.
2948 set(_test_group_list
2949         suite_capture
2950         suite_clopts
2951         suite_decryption
2952         suite_dfilter.group_bytes_ether
2953         suite_dfilter.group_bytes_ipv6
2954         suite_dfilter.group_bytes_type
2955         suite_dfilter.group_double
2956         suite_dfilter.group_integer
2957         suite_dfilter.group_integer_1byte
2958         suite_dfilter.group_ipv4
2959         suite_dfilter.group_membership
2960         suite_dfilter.group_range_method
2961         suite_dfilter.group_scanner
2962         suite_dfilter.group_string_type
2963         suite_dfilter.group_stringz
2964         suite_dfilter.group_time_relative
2965         suite_dfilter.group_time_type
2966         suite_dfilter.group_tvb
2967         suite_dfilter.group_uint64
2968         suite_dissection
2969         suite_fileformats
2970         suite_follow
2971         suite_io
2972         suite_mergecap
2973         suite_nameres
2974         suite_text2pcap
2975         suite_sharkd
2976         suite_unittests
2977         suite_wslua
2978 )
2979
2980 # We don't currently handle spaces in arguments. On Windows this
2981 # means that you will probably have to pass in an interface index
2982 # instead of a name.
2983 set(TEST_EXTRA_ARGS "" CACHE STRING "Extra arguments to pass to test/test.py")
2984 separate_arguments(TEST_EXTRA_ARGS)
2985
2986 foreach(_group_name ${_test_group_list})
2987         add_test(
2988                 NAME ${_group_name}
2989                 COMMAND ${CMAKE_COMMAND} -E env PYTHONIOENCODING=UTF-8
2990                         ${PYTHON_EXECUTABLE} ${CMAKE_SOURCE_DIR}/test/test.py
2991                         --verbose
2992                         --program-path ${WS_PROGRAM_PATH}
2993                         ${TEST_EXTRA_ARGS}
2994                         ${_group_name}
2995                 )
2996         set_tests_properties(${_group_name} PROPERTIES TIMEOUT 600)
2997 endforeach()
2998
2999 if (GIT_EXECUTABLE)
3000         # Update AUTHORS file with entries from git shortlog
3001         add_custom_target(
3002                 gen-authors
3003                 COMMAND ${PERL_EXECUTABLE} tools/generate_authors.pl AUTHORS.src > AUTHORS
3004                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
3005         )
3006 else (GIT_EXECUTABLE)
3007         add_custom_target( gen-authors COMMAND ${CMAKE_COMMAND} -E echo "Git not found." )
3008 endif (GIT_EXECUTABLE)
3009 set_target_properties(gen-authors PROPERTIES FOLDER "Docs")
3010
3011 if (WIN32)
3012         file (TO_NATIVE_PATH ${CMAKE_SOURCE_DIR}/tools/Get-HardenFlags.ps1 _win_harden_flags)
3013         add_custom_target(hardening-check
3014                 COMMAND ${POWERSHELL_COMMAND} "${_win_harden_flags}" "${_dll_output_dir_win}"
3015                 DEPENDS ${PROGLIST}
3016                 COMMENT "Checking binaries for security features"
3017         )
3018         set_target_properties(hardening-check PROPERTIES FOLDER "Tests")
3019 else ()
3020         find_program(HARDENING_CHECK_EXECUTABLE hardening-check
3021                 DOC "Path to the hardening-check utility."
3022         )
3023         if(HARDENING_CHECK_EXECUTABLE)
3024                 foreach(_prog ${PROGLIST})
3025                         get_target_property(_prog_dir ${_prog} RUNTIME_OUTPUT_DIRECTORY)
3026                         if(NOT _prog_dir)
3027                                 set(_prog_dir "${CMAKE_BINARY_DIR}/run")
3028                         endif()
3029                         set(_prog_paths ${_prog_paths} "${_prog_dir}/${_prog}")
3030                 endforeach()
3031                 add_custom_target(hardening-check
3032                         COMMAND ${HARDENING_CHECK_EXECUTABLE} ${_prog_paths}
3033                         DEPENDS ${PROGLIST}
3034                         COMMENT "Checking binaries for security features"
3035                 )
3036         endif()
3037 endif()
3038
3039 CHECKAPI(
3040         NAME
3041           main
3042         SWITCHES
3043           -build
3044         SOURCES
3045           ${WIRESHARK_SRC}
3046           ${TSHARK_TAP_SRC}
3047 )
3048
3049 find_program(SHELLCHECK_EXECUTABLE shellcheck
3050         DOC "Path to the shellcheck utility."
3051 )
3052 if(SHELLCHECK_EXECUTABLE)
3053         add_custom_target(shellcheck)
3054         set_target_properties(shellcheck PROPERTIES FOLDER "Tests")
3055         # --external-sources requires 0.4.0 or later.
3056         add_custom_command(TARGET shellcheck POST_BUILD
3057                 COMMAND shellcheck --external-sources
3058                         image/stock_icons/svg-to-png.sh
3059                         packaging/macosx/osx-app.sh.in
3060                         packaging/macosx/osx-dmg.sh.in
3061                         tools/compress-pngs.sh
3062                         tools/debian-setup.sh
3063                         tools/git-export-release.sh
3064                         tools/fuzz-test.sh
3065                         tools/gen-bugnote
3066                         tools/pre-commit
3067                         tools/randpkt-test.sh
3068                         tools/release-update-debian-soversions.sh
3069                         tools/test-captures.sh
3070                         tools/update-tx
3071                         tools/valgrind-wireshark.sh
3072                 WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}"
3073         )
3074 endif()
3075
3076 #
3077 # Editor modelines  -  http://www.wireshark.org/tools/modelines.html
3078 #
3079 # Local variables:
3080 # c-basic-offset: 8
3081 # tab-width: 8
3082 # indent-tabs-mode: t
3083 # End:
3084 #
3085 # vi: set shiftwidth=8 tabstop=8 noexpandtab:
3086 # :indentSize=8:tabSize=8:noTabs=false:
3087 #