CMakeLists.txt

   1 # CMakeLists.txt
   2 #
   3 # $Id$
   4 #
   5 # Wireshark - Network traffic analyzer
   6 # By Gerald Combs <gerald@wireshark.org>
   7 # Copyright 1998 Gerald Combs
   8 #
   9 # This program is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU General Public License
  11 # as published by the Free Software Foundation; either version 2
  12 # of the License, or (at your option) any later version.
  13 #
  14 # This program is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program; if not, write to the Free Software
  21 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  22 #
  23
  24 project(Wireshark C CXX)
  25
  26 cmake_minimum_required(VERSION 2.6)
  27 set(CMAKE_BACKWARDS_COMPATIBILITY 2.6)
  28
  29 # Needs to be set after cmake_minimum_required or cmake_policy(VERSION)
  30 if(COMMAND cmake_policy)
  31         # Backward compatibility for versions < 2.6.3
  32         cmake_policy(SET CMP0011 OLD)
  33 #       cmake_policy(SET CMP0015 NEW)
  34 endif(COMMAND cmake_policy)
  35
  36 # set(PROJECT_MAJOR_VERSION 1)
  37 # set(PROJECT_MINOR_VERSION 9)
  38 # set(PROJECT_PATCH_VERSION 0)
  39 # set(PROJECT_VERSION_EXTENSION "-rc5")
  40 # If not set, copy over Wireshark version from configure.ac
  41 if(NOT PROJECT_MAJOR_VERSION)
  42         file(STRINGS
  43                 ${CMAKE_SOURCE_DIR}/configure.ac
  44                 PROJECT_MAJOR_VERSION_TMP
  45                 REGEX "^m4_define\\(\\[?version_major\\]?, *\\[?[0-9]+\\]?\\)"
  46         )
  47         file(STRINGS
  48                 ${CMAKE_SOURCE_DIR}/configure.ac
  49                 PROJECT_MINOR_VERSION_TMP
  50                 REGEX "^m4_define\\(\\[?version_minor\\]?, *\\[?[0-9]+\\]?\\)"
  51         )
  52         file(STRINGS
  53                 ${CMAKE_SOURCE_DIR}/configure.ac
  54                 PROJECT_PATCH_VERSION_TMP
  55                 REGEX "^m4_define\\(\\[?version_micro\\]?, *\\[?[0-9]+\\]?\\)"
  56         )
  57         # XXX pull VERSION_EXTENSION out of configure.ac ?
  58
  59         string(REGEX REPLACE "m4_define\\(\\[?version_major\\]?, *\\[?([0-9]+)\\]?\\)"
  60                 "\\1"
  61                 PROJECT_MAJOR_VERSION
  62                 ${PROJECT_MAJOR_VERSION_TMP}
  63         )
  64         string(REGEX REPLACE "m4_define\\(\\[?version_minor\\]?, *\\[?([0-9]+)\\]?\\)"
  65                 "\\1"
  66                 PROJECT_MINOR_VERSION
  67                 ${PROJECT_MINOR_VERSION_TMP}
  68         )
  69         string(REGEX REPLACE "m4_define\\(\\[?version_micro\\]?, *\\[?([0-9]+)\\]?\\)"
  70                 "\\1"
  71                 PROJECT_PATCH_VERSION
  72                 ${PROJECT_PATCH_VERSION_TMP}
  73         )
  74 endif()
  75
  76
  77 if(PROJECT_VERSION_EXTENSION)
  78         set(PROJECT_VERSION ${PROJECT_MAJOR_VERSION}.${PROJECT_MINOR_VERSION}.${PROJECT_PATCH_VERSION}${PROJECT_VERSION_EXTENSION})
  79 else()
  80         set(PROJECT_VERSION ${PROJECT_MAJOR_VERSION}.${PROJECT_MINOR_VERSION}.${PROJECT_PATCH_VERSION})
  81 endif()
  82
  83 message(STATUS "V: ${PROJECT_VERSION}, MaV: ${PROJECT_MAJOR_VERSION}, MiV: ${PROJECT_MINOR_VERSION}, PL: ${PROJECT_PATCH_VERSION}, EV: ${PROJECT_VERSION_EXTENSION}.")
  84
  85 #Where to find local cmake scripts
  86 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  87 INCLUDE(UseLemon)
  88 INCLUDE(UseMakeDissectorReg)
  89 INCLUDE(UseMakeTapReg)
  90
  91 # Under linux the release mode (CMAKE_BUILD_TYPE=release) defines NDEBUG
  92
  93 # Enable with: "make VERBOSE=1"
  94 set(CMAKE_VERBOSE_MAKEFILE OFF)
  95
  96 #Defines CMAKE_INSTALL_BINDIR, CMAKE_INSTALL_DATADIR, etc ...
  97 include(CMakeInstallDirs)
  98
  99 include_directories(
 100         ${CMAKE_BINARY_DIR}
 101         ${CMAKE_SOURCE_DIR}
 102         ${CMAKE_SOURCE_DIR}/epan
 103         ${CMAKE_SOURCE_DIR}/tools/lemon
 104         ${CMAKE_SOURCE_DIR}/wiretap
 105 )
 106
 107 #Where to put libraries
 108 if(NOT LIBRARY_OUTPUT_PATH)
 109         set(LIBRARY_OUTPUT_PATH ${Wireshark_BINARY_DIR}/lib CACHE INTERNAL
 110                    "Single output directory for building all libraries.")
 111 endif()
 112
 113
 114 include(CMakeOptions.txt)
 115
 116
 117 set(WIRESHARK_C_FLAGS
 118         -O2
 119         -g
 120         -Wall
 121         -W
 122         -Wextra
 123         -Wendif-labels
 124         -Wpointer-arith
 125         -Warray-bounds
 126         -Wcast-align
 127         -Wformat-security
 128         -fexcess-precision=fast
 129         # -fvisibility=hidden
 130 )
 131
 132 set(WIRESHARK_C_ONLY_FLAGS
 133         # The following are C only, not C++
 134         -Wdeclaration-after-statement
 135         -Wno-pointer-sign
 136         -Wold-style-definition
 137 )
 138
 139 set(WIRESHARK_EXTRA_C_FLAGS
 140         -pedantic
 141         -Woverflow
 142         -Wlogical-op
 143         -Wno-overlength-strings
 144         -fstrict-overflow -Wstrict-overflow=4
 145         -Wunreachable-code
 146         -Wunsafe-loop-optimizations
 147         -Wno-long-long
 148         -Wcast-qual
 149         -Waddress
 150         -Warray-bounds
 151         -Wattributes
 152         -Wdiv-by-zero
 153         -Wformat-security
 154         -Wignored-qualifiers
 155         -Wpragmas
 156         -Wredundant-decls
 157         -Wvla
 158         # packet-ncp2222.inc prevents this from going into all warnings
 159         -Wwrite-strings
 160         # All the registration functions block these for now.
 161         -Wmissing-declarations
 162         # Problem with packet-afs.c
 163         -Wshadow
 164         # More cleanup needed for this on LP64
 165         -Wshorten-64-to-32
 166
 167 )
 168
 169 set(WIRESHARK_EXTRA_C_ONLY_FLAGS
 170         # The following are C only, not C++
 171         -Wbad-function-cast
 172         -Wc++-compat
 173         -Wjump-misses-init
 174         # GLib blocks this for now.
 175         -Wstrict-prototypes
 176         # All the registration functions block these for now.
 177         -Wmissing-prototypes
 178 )
 179
 180 if(ENABLE_EXTRA_GCC_CHECKS)   # This overrides -Werror
 181         set(WIRESHARK_C_FLAGS ${WIRESHARK_C_FLAGS} ${WIRESHARK_EXTRA_C_FLAGS})
 182         set(WIRESHARK_C_ONLY_FLAGS ${WIRESHARK_C_ONLY_FLAGS} ${WIRESHARK_EXTRA_C_ONLY_FLAGS})
 183 endif()
 184
 185 add_definitions(
 186         -DG_DISABLE_DEPRECATED
 187         -DG_DISABLE_SINGLE_INCLUDES
 188 )
 189
 190 # Counterhack to work around some cache magic in CHECK_C_SOURCE_COMPILES
 191 include(CheckCCompilerFlag)
 192 set(C 0)
 193 # Sigh: Have to use THIS_FLAG instead of ${F} for some reason
 194 foreach(THIS_FLAG ${WIRESHARK_C_FLAGS})
 195         set(F WS_C_FLAG_${C})
 196         set(${F} ${THIS_FLAG})
 197         set(V WS_C_FLAG_VALID${C})
 198         check_c_compiler_flag(${${F}} ${V})
 199         if (${${V}})
 200                 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${${F}}")
 201                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${${F}}")
 202         endif()
 203         math(EXPR C "${C} + 1")
 204 endforeach()
 205 # Continue increasing C from previous loop
 206 foreach(THIS_FLAG ${WIRESHARK_C_ONLY_FLAGS})
 207         set(F WS_C_FLAG_${C})
 208         set(${F} ${THIS_FLAG})
 209         set(V WS_C_FLAG_VALID${C})
 210         check_c_compiler_flag(${${F}} ${V})
 211         if (${${V}})
 212                 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${${F}}")
 213         endif()
 214         math(EXPR C "${C} + 1")
 215 endforeach()
 216 message(STATUS "C-Flags: ${CMAKE_C_FLAGS}\nCXX-Flags: ${CMAKE_CXX_FLAGS}")
 217
 218 if(NOT DISABLE_WERROR AND NOT ENABLE_EXTRA_GCC_CHECKS)
 219         check_c_compiler_flag(-Werror WERROR)
 220 else()
 221         unset(WERROR)
 222 endif()
 223
 224 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_CXX_COMPILER MATCHES ".*clang")
 225         set (C_UNUSED "__attribute__((unused))" )
 226 else()
 227         set (C_UNUSED "" )
 228 endif()
 229
 230 set(WIRESHARK_LD_FLAGS
 231         -Wl,--as-needed
 232         # -flto
 233         # -fwhopr
 234         # -fwhole-program
 235 )
 236
 237 include(CheckCLinkerFlag)
 238 set(C 0)
 239 # Sigh: Have to use THIS_FLAG instead of ${F} for some reason
 240 foreach(THIS_FLAG ${WIRESHARK_LD_FLAGS})
 241         set(F WS_LD_FLAG_${C})
 242         set(${F} ${THIS_FLAG})
 243         set(V WS_LD_FLAG_VALID${C})
 244         check_c_linker_flag(${${F}} ${V})
 245         if (${${V}})
 246                 set(WS_LINK_FLAGS ${WS_LINK_FLAGS} ${${F}})
 247         endif()
 248         math(EXPR C "${C} + 1")
 249 endforeach()
 250
 251 if(ENABLE_STATIC)
 252   set(LINK_MODE_LIB STATIC)
 253   set(LINK_MODE_MODULE STATIC)
 254 else()
 255   set(LINK_MODE_LIB SHARED)
 256   set(LINK_MODE_MODULE MODULE)
 257 endif()
 258
 259 # The packagelist is doing some magic:  If we add XXX to the packagelist, we
 260 # - may optionally set XXX_OPTIONS to pass to the find_package command
 261 # - will call FindXXX.cmake
 262 # - return found libraries in XXX_LIBRARIES
 263 # - return found include in XXX_INCLUDE_DIRS
 264 # - set HAVE_XXX
 265
 266 #The minimum package list
 267 set(PACKAGELIST GLIB2 GMODULE2 GTHREAD2 M LEX YACC Perl SH PythonInterp)
 268 set(GLIB2_FIND_REQUIRED)
 269 set(GLIB2_MIN_VERSION 2.14.0)
 270 set(GTHREAD2_REQUIRED)
 271 set(PCAP_REQUIRED)
 272 set(M_REQUIRED)
 273
 274 set(PACKAGELIST ${PACKAGELIST} HtmlViewer)
 275
 276 if(ENABLE_PCAP)
 277         set(PACKAGELIST ${PACKAGELIST} PCAP)
 278 endif()
 279
 280 # Build the GTK-GUI?
 281 if(BUILD_wireshark)
 282         if(ENABLE_GTK3)
 283                 set(PACKAGELIST ${PACKAGELIST} GTK3)
 284         else()
 285                 set(PACKAGELIST ${PACKAGELIST} GTK2)
 286                 set(GTK2_OPTIONS COMPONENTS gtk)
 287                 set(GTK2_FIND_VERSION 2.12)
 288                 set(GTK2_DEBUG false)
 289         endif()
 290 endif()
 291
 292 # Build the Qt GUI?
 293 if(BUILD_qtshark)
 294         set(PACKAGELIST ${PACKAGELIST} QT)
 295         # set(QT_OPTIONS 4.7.1 REQUIRED QtCore QtGui)
 296 endif()
 297
 298 # SMI SNMP
 299 if(ENABLE_SMI)
 300         set(PACKAGELIST ${PACKAGELIST} SMI)
 301 endif()
 302
 303 # GNU crypto
 304 if(ENABLE_GCRYPT)
 305         set(PACKAGELIST ${PACKAGELIST} GCRYPT)
 306 endif()
 307
 308 # GNU SSL/TLS support
 309 if(ENABLE_GNUTLS)
 310         set(PACKAGELIST ${PACKAGELIST} GNUTLS)
 311 endif()
 312
 313 # Kerberos
 314 if(ENABLE_KERBEROS)
 315         set(PACKAGELIST ${PACKAGELIST} KERBEROS)
 316 endif()
 317
 318 # Portable audio
 319 if(ENABLE_PORTAUDIO)
 320         set(PACKAGELIST ${PACKAGELIST} PORTAUDIO)
 321 endif()
 322
 323
 324 # Prefer c-ares over adns
 325 if(ENABLE_CARES)        # C Asynchronouse resolver
 326         set(PACKAGELIST ${PACKAGELIST} CARES)
 327 elseif(ENABLE_ADNS)     # Gnu asynchronous DNS
 328         set(PACKAGELIST ${PACKAGELIST} ADNS)
 329 endif()
 330
 331 # Zlib compression
 332 if(ENABLE_ZLIB)
 333         set(PACKAGELIST ${PACKAGELIST} ZLIB)
 334 endif()
 335
 336 # Lua 5.1 dissectors
 337 if(ENABLE_LUA)
 338         set(PACKAGELIST ${PACKAGELIST} LUA)
 339 endif()
 340
 341 # GeoIP address resolving
 342 if(ENABLE_GEOIP)
 343         set(PACKAGELIST ${PACKAGELIST} GEOIP)
 344 endif()
 345
 346 if(ENABLE_NETLINK)
 347         set(PACKAGELIST ${PACKAGELIST} NL)
 348 endif()
 349
 350 # Capabilities
 351 if(ENABLE_CAP)
 352         set(PACKAGELIST ${PACKAGELIST} CAP)
 353 endif()
 354
 355 if(ENABLE_PYTHON)
 356         set(PACKAGELIST ${PACKAGELIST} PYTHON)
 357 endif()
 358
 359 set(PACKAGELIST ${PACKAGELIST} YAPP)
 360
 361 set(PACKAGELIST ${PACKAGELIST} POD)
 362
 363
 364 set(PROGLIST text2pcap mergecap capinfos editcap reordercap dumpcap)
 365
 366 #Let's loop the package list
 367 foreach(PACKAGE ${PACKAGELIST})
 368         if(${PACKAGE} STREQUAL "QT")
 369                 set(PACKAGE_NAME "Qt4")
 370         else()
 371                 set(PACKAGE_NAME ${PACKAGE})
 372         endif()
 373         if(${PACKAGE}_OPTIONS)
 374                 find_package(${PACKAGE_NAME} ${${PACKAGE}_OPTIONS})
 375         elseif(${PACKAGE}_REQUIRED)
 376                 find_package(${PACKAGE_NAME} REQUIRED)
 377         else()
 378                 find_package(${PACKAGE_NAME})
 379         endif()
 380         message(${PACKAGE}_FOUND)
 381         if (${PACKAGE}_FOUND)
 382                 set(HAVE_LIB${PACKAGE} 1)
 383                 include_directories(${${PACKAGE}_INCLUDE_DIRS})
 384                 message(STATUS "${PACKAGE} includes: ${${PACKAGE}_INCLUDE_DIRS}")
 385                 message(STATUS "${PACKAGE} libs: ${${PACKAGE}_LIBRARIES}")
 386         endif()
 387 endforeach()
 388
 389 #packaging
 390 include(CPackConfig.txt)
 391
 392 if(HAVE_LIBPYTHON)
 393         set(HAVE_PYTHON 1)
 394         set(PYTHON_DIR "${CMAKE_INSTALL_PREFIX}/lib/wireshark/python/${CPACK_PACKAGE_VERSION}")
 395 endif()
 396 if(HAVE_LIBLUA)
 397         set(HAVE_LUA_H 1)
 398         set(HAVE_LUA 1)
 399 endif()
 400 if(HAVE_LIBKERBEROS)
 401         set(HAVE_KERBEROS 1)
 402         # HAVE_HEIMDAL_KERBEROS
 403         set(HAVE_MIT_KERBEROS 1)
 404         set(HAVE_KEYTYPE_ARCFOUR_56 1)
 405 endif()
 406 if(HAVE_LIBGEOIP)
 407         set(HAVE_GEOIP 1)
 408 endif()
 409 if(HAVE_LIBCARES)
 410         set(HAVE_C_ARES 1)
 411 endif()
 412 if(HAVE_LIBADNS)
 413         set(HAVE_GNU_ADNS 1)
 414 endif()
 415 if(ENABLE_AIRPCAP)
 416         set(HAVE_AIRPCAP 1)
 417 endif()
 418 if(HAVE_LIBNL AND ENABLE_AIRPCAP)
 419         message(ERROR "Airpcap and Libnl support are mutually exclusive")
 420 endif()
 421 # No matter which version of GTK is present
 422 if(GTK2_FOUND OR GTK3_FOUND)
 423         set(GTK_FOUND ON)
 424 endif()
 425 # That's the name autofoo uses
 426 if(HAVE_LIBZLIB)
 427         set(HAVE_LIBZ 1)
 428 endif()
 429 # QT_LIBRARIES and QT_INCLUDES are not set above. They require extra magic:
 430 if(QT_FOUND)
 431         include(${QT_USE_FILE})
 432         include_directories(${QT_INCLUDE_DIR})
 433         message(STATUS "QT includes: ${QT_INCLUDE_DIR}")
 434         message(STATUS "QT libs: ${QT_LIBRARIES}")
 435 endif()
 436
 437 include(ConfigureChecks.cmake)
 438
 439 #Big or little endian ?
 440 include(TestBigEndian)
 441 test_big_endian(WORDS_BIGENDIAN)
 442
 443 set(DATAFILE_DIR "${CMAKE_INSTALL_PREFIX}/share/${CPACK_PACKAGE_NAME}")
 444
 445 if(ENABLE_PLUGINS)
 446         set(HAVE_PLUGINS 1)
 447         set(PLUGIN_DIR="${DATAFILE_DIR}/plugins/${CPACK_PACKAGE_VERSION}")
 448         set(PLUGIN_SRC_DIRS
 449                 plugins/asn1
 450                 plugins/docsis
 451                 plugins/ethercat
 452                 plugins/gryphon
 453                 plugins/irda
 454                 plugins/m2m
 455                 plugins/mate
 456                 plugins/opcua
 457                 plugins/profinet
 458                 plugins/stats_tree
 459                 plugins/unistim
 460                 plugins/wimax
 461                 plugins/wimaxasncp
 462                 plugins/wimaxmacphy
 463         )
 464 # It seems this stuff doesn't build with autofoo either...
 465 #       if(YAPP_FOUND)
 466 #               set(PLUGIN_SRC_DIRS
 467 #                       ${PLUGIN_SRC_DIRS}
 468 #                       plugins/tpg
 469 #               )
 470 #       endif()
 471 else()
 472         set(PLUGIN_SRC_DIRS )
 473 endif()
 474
 475 foreach(PLUGIN_DIR ${PLUGIN_SRC_DIRS})
 476         add_subdirectory( ${PLUGIN_DIR} )
 477 endforeach()
 478
 479 add_subdirectory( codecs )
 480 add_subdirectory( epan )
 481 add_subdirectory( tools/lemon )
 482 add_subdirectory( wiretap )
 483 add_subdirectory( wsutil )
 484
 485 if((BUILD_wireshark AND GTK_FOUND) OR (BUILD_qtshark AND QT_FOUND))
 486         add_subdirectory( ui )
 487 endif()
 488
 489 if(BUILD_wireshark AND GTK_FOUND)
 490         add_subdirectory( ui/gtk )
 491 endif()
 492
 493 if(BUILD_qtshark AND QT_FOUND)
 494         add_subdirectory( ui/qt )
 495 endif()
 496
 497
 498 # Basedir where to install guides
 499 set(DOC_DIR "$ENV{docdir}" CACHE FILEPATH "Installation directory for ug and dg pdfs.")
 500 message(STATUS "docdir: ${DOC_DIR}")
 501
 502 if(ENABLE_GUIDES)
 503         add_subdirectory( docbook )
 504 endif()
 505
 506 if(ENABLE_PCAP_NG_DEFAULT)
 507         set(PCAP_NG_DEFAULT 1)
 508 endif()
 509
 510 #Platform specific
 511 if(UNIX)
 512         if(CMAKE_COMPILER_IS_GNUCC)
 513                 # set(WS_VAR_IMPORT "__attribute__((visibility(\"default\")))" )
 514                 set(WS_VAR_IMPORT "extern")
 515         else()
 516                 set(WS_VAR_IMPORT "extern")
 517         endif()
 518 endif()
 519
 520 if(APPLE)
 521         #
 522         # We assume that APPLE means OS X so that we have the OS X
 523         # frameworks.
 524         #
 525         set(HAVE_OS_X_FRAMEWORKS 1)
 526         FIND_LIBRARY (APPLE_APPLICATION_SERVICES_LIBRARY ApplicationServices)
 527         FIND_LIBRARY (APPLE_CORE_FOUNDATION_LIBRARY CoreFoundation)
 528         FIND_LIBRARY (APPLE_SYSTEM_CONFIGURATION_LIBRARY SystemConfiguration)
 529 endif()
 530
 531 if(WIN32)
 532         add_definitions(-D_NEED_VAR_IMPORT_)
 533         set(WS_VAR_IMPORT "__declspec(dllimport) extern")
 534         set(WS_MSVC_NORETURN "__declspec(noreturn)")
 535
 536         # Disable deprecation
 537         if(MSVC80 OR MSVC90)
 538                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 539         endif()
 540 else()
 541         set(WS_MSVC_NORETURN " ")
 542 endif()
 543
 544 configure_file(${CMAKE_SOURCE_DIR}/cmakeconfig.h.in ${CMAKE_BINARY_DIR}/config.h)
 545
 546 set( configure_input "Built with CMake ${CMAKE_VERSION}" )
 547 set( VERSION ${PROJECT_VERSION} )
 548
 549 configure_file(
 550         ${CMAKE_SOURCE_DIR}/packaging/macosx/Info.plist.in
 551         ${CMAKE_SOURCE_DIR}/packaging/macosx/Info.plist
 552         @ONLY)
 553
 554 include(FeatureSummary)
 555 #SET_FEATURE_INFO(NAME DESCRIPTION [URL [COMMENT] ]
 556 #FEATURE_SUMMARY(WHAT ALL) Requires removal of our local copy of FeatureSummary
 557 PRINT_ENABLED_FEATURES()
 558 PRINT_DISABLED_FEATURES()
 559
 560 link_directories(
 561         ${CMAKE_BINARY_DIR}/ui
 562         ${CMAKE_BINARY_DIR}/ui/gtk
 563         ${CMAKE_BINARY_DIR}/ui/qt
 564         ${CMAKE_BINARY_DIR}/codecs
 565         ${CMAKE_BINARY_DIR}/epan
 566         ${CMAKE_BINARY_DIR}/wiretap
 567         ${CMAKE_BINARY_DIR}/wsutil
 568 )
 569
 570 ADD_CUSTOM_TARGET(
 571         svnversion ALL
 572         COMMAND ${PERL}
 573                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 574                 ${CMAKE_CURRENT_SOURCE_DIR}
 575         DEPENDS
 576                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 577 )
 578
 579 ADD_CUSTOM_COMMAND(
 580         OUTPUT  svnversion.h
 581         COMMAND ${PERL}
 582                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 583                 ${CMAKE_CURRENT_SOURCE_DIR}
 584         DEPENDS
 585                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 586 )
 587
 588 ADD_CUSTOM_COMMAND(
 589         OUTPUT  ps.c
 590         COMMAND ${PYTHON_EXECUTABLE}
 591                 ${CMAKE_CURRENT_SOURCE_DIR}/tools/rdps.py
 592                 ${CMAKE_CURRENT_SOURCE_DIR}/print.ps
 593                 ps.c
 594         DEPENDS
 595                 ${CMAKE_CURRENT_SOURCE_DIR}/tools/rdps.py
 596                 ${CMAKE_CURRENT_SOURCE_DIR}/print.ps
 597 )
 598
 599 if(UNIX)
 600         set(PLATFORM_SRC
 601                 capture-pcap-util-unix.c capture_unix_ifnames.c
 602         )
 603 endif()
 604
 605 if(WIN32)
 606         set(PLATFORM_SRC
 607                 capture-wpcap.c capture_wpcap_packet.c capture_win_ifnames.c
 608         )
 609 endif()
 610
 611 set(WTAP_PLUGIN_SOURCES
 612         epan/plugins.c
 613         epan/report_err.c
 614         epan/filesystem.c
 615 )
 616
 617 set(SHARK_COMMON_CAPTURE_SRC
 618         capture_ifinfo.c
 619         capture_ui_utils.c
 620 )
 621
 622 set(WIRESHARK_COMMON_SRC
 623         ${PLATFORM_SRC}
 624         capture-pcap-util.c
 625         cfile.c
 626         cfutils.c
 627         clopts_common.c
 628         disabled_protos.c
 629         frame_data_sequence.c
 630         packet-range.c
 631         print.c
 632         ps.c
 633         svnversion.h
 634         sync_pipe_write.c
 635         timestats.c
 636         tap-megaco-common.c
 637         tap-rtp-common.c
 638         version_info.c
 639 )
 640
 641 set(TSHARK_TAP_SRC
 642         ui/cli/tap-afpstat.c
 643         ui/cli/tap-ansi_astat.c
 644         ui/cli/tap-bootpstat.c
 645         ui/cli/tap-camelcounter.c
 646         ui/cli/tap-camelsrt.c
 647         ui/cli/tap-comparestat.c
 648         ui/cli/tap-dcerpcstat.c
 649         ui/cli/tap-diameter-avp.c
 650         ui/cli/tap-expert.c
 651         ui/cli/tap-follow.c
 652         ui/cli/tap-funnel.c
 653         ui/cli/tap-gsm_astat.c
 654         ui/cli/tap-h225counter.c
 655         ui/cli/tap-h225rassrt.c
 656         ui/cli/tap-hosts.c
 657         ui/cli/tap-httpstat.c
 658         ui/cli/tap-icmpstat.c
 659         ui/cli/tap-icmpv6stat.c
 660         ui/cli/tap-iostat.c
 661         ui/cli/tap-iousers.c
 662         ui/cli/tap-macltestat.c
 663         ui/cli/tap-mgcpstat.c
 664         ui/cli/tap-megacostat.c
 665         ui/cli/tap-protocolinfo.c
 666         ui/cli/tap-protohierstat.c
 667         ui/cli/tap-radiusstat.c
 668         ui/cli/tap-rlcltestat.c
 669         ui/cli/tap-rpcstat.c
 670         ui/cli/tap-rpcprogs.c
 671         ui/cli/tap-rtp.c
 672         ui/cli/tap-rtspstat.c
 673         ui/cli/tap-scsistat.c
 674         ui/cli/tap-sctpchunkstat.c
 675         ui/cli/tap-sipstat.c
 676         ui/cli/tap-smbsids.c
 677         ui/cli/tap-smbstat.c
 678         ui/cli/tap-stats_tree.c
 679         ui/cli/tap-sv.c
 680         ui/cli/tap-wspstat.c
 681 )
 682
 683 set(INSTALL_DIRS
 684         diameter
 685         dtds
 686         help
 687         radius
 688         tpncp
 689         wimaxasncp
 690 )
 691
 692 set(INSTALL_FILES
 693         ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 694         COPYING
 695         ${CMAKE_BINARY_DIR}/capinfos.html
 696         cfilters
 697         colorfilters
 698         dfilters
 699         ${CMAKE_BINARY_DIR}/dftest.html
 700         ${CMAKE_BINARY_DIR}/dumpcap.html
 701         ${CMAKE_BINARY_DIR}/editcap.html
 702         ${CMAKE_BINARY_DIR}/idl2wrs.html
 703         ipmap.html
 704         manuf
 705         ${CMAKE_BINARY_DIR}/mergecap.html
 706         pdml2html.xsl
 707         ${CMAKE_BINARY_DIR}/randpkt.html
 708         ${CMAKE_BINARY_DIR}/rawshark.html
 709         ${CMAKE_BINARY_DIR}/reordercap.html
 710         services
 711         smi_modules
 712         ${CMAKE_BINARY_DIR}/text2pcap.html
 713         ${CMAKE_BINARY_DIR}/tshark.html
 714         ${CMAKE_BINARY_DIR}/wireshark-filter.html
 715         ${CMAKE_BINARY_DIR}/wireshark.html
 716         docbook/ws.css
 717 )
 718
 719 set(LIBEPAN_LIBS
 720 #               @NSL_LIBS@      # -lnsl
 721 #               @SOCKET_LIBS@   # -lsocket
 722 #               @SSL_LIBS@      # -lcrypto
 723                 epan
 724 #               $(plugin_ldadd) # in case of static
 725                 ${PCAP_LIBRARIES}
 726                 ${CARES_LIBRARIES}
 727                 ${ADNS_LIBRARIES}
 728                 ${KERBEROS_LIBRARIES}
 729                 ${LUA_LIBRARIES}
 730                 ${PYTHON_LIBRARIES}
 731                 ${GEOIP_LIBRARIES}
 732                 ${GCRYPT_LIBRARIES}
 733                 ${GNUTLS_LIBRARIES}
 734                 ${SMI_LIBRARIES}
 735                 ${ZLIB_LIBRARIES}
 736                 ${M_LIBRARIES}
 737 )
 738
 739 if( (BUILD_wireshark AND GTK_FOUND) OR (BUILD_qtshark AND QT_FOUND) )
 740         set(wireshark_FILES
 741                 airpcap_loader.c
 742                 capture.c
 743                 capture_info.c
 744                 capture_opts.c
 745                 capture_sync.c
 746                 color_filters.c
 747                 file.c
 748                 fileset.c
 749                 filters.c
 750                 g711.c
 751                 iface_monitor.c
 752                 merge.c
 753                 proto_hier_stats.c
 754                 summary.c
 755                 tempfile.c
 756                 u3.c
 757                 ws80211_utils.c
 758                 ${SHARK_COMMON_CAPTURE_SRC}
 759                 ${WIRESHARK_COMMON_SRC}
 760         )
 761 endif()
 762
 763 if(BUILD_wireshark AND GTK_FOUND)
 764         set(wireshark_LIBS
 765                 gtkui
 766                 ui
 767                 ui_dirty
 768                 ${GTK2_LIBRARIES}
 769                 ${GTK3_LIBRARIES}
 770                 ${GTHREAD2_LIBRARIES}
 771                 codecs
 772                 ${PORTAUDIO_LIBRARIES}
 773                 ${LIBEPAN_LIBS}
 774                 ${APPLE_APPLICATION_SERVICES_LIBRARY}
 775                 ${APPLE_CORE_SERVICES_LIBRARY}
 776                 ${APPLE_SYSTEM_CONFIGURATION_LIBRARY}
 777                 ${NL_LIBRARIES}
 778         )
 779         # qtshark and wireshark share wireshark_FILES
 780
 781         add_executable(wireshark ${wireshark_FILES})
 782         add_dependencies(wireshark svnversion)
 783         set_target_properties(wireshark PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 784         target_link_libraries(wireshark ${wireshark_LIBS})
 785         install(TARGETS wireshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 786 endif()
 787
 788 if(BUILD_qtshark AND QT_FOUND)
 789         set(qtshark_LIBS
 790                 qtui
 791                 ui
 792                 ui_dirty
 793                 ${QT_LIBRARIES}
 794                 ${GTHREAD2_LIBRARIES}
 795                 codecs
 796                 ${PORTAUDIO_LIBRARIES}
 797                 ${LIBEPAN_LIBS}
 798                 ${APPLE_APPLICATION_SERVICES_LIBRARY}
 799                 ${APPLE_CORE_FOUNDATION_LIBRARY}
 800                 ${APPLE_SYSTEM_CONFIGURATION_LIBRARY}
 801                 ${NL_LIBRARIES}
 802         )
 803         # qtshark and wireshark share wireshark_FILES
 804
 805         add_executable(qtshark ${wireshark_FILES})
 806         add_dependencies(qtshark svnversion)
 807         set_target_properties(qtshark PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 808         target_link_libraries(qtshark ${qtshark_LIBS})
 809         install(TARGETS qtshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 810 endif()
 811
 812 register_tap_files(tshark-tap-register.c
 813         ${TSHARK_TAP_SRC}
 814 )
 815
 816 if(BUILD_tshark)
 817         set(tshark_LIBS
 818                 ${LIBEPAN_LIBS}
 819                 ${APPLE_CORE_FOUNDATION_LIBRARY}
 820                 ${APPLE_SYSTEM_CONFIGURATION_LIBRARY}
 821         )
 822         set(tshark_FILES
 823                 capture_opts.c
 824                 capture_sync.c
 825                 tempfile.c
 826                 tshark-tap-register.c
 827                 tshark.c
 828                 ui/util.c
 829                 ${TSHARK_TAP_SRC}
 830                 ${SHARK_COMMON_CAPTURE_SRC}
 831                 ${WIRESHARK_COMMON_SRC}
 832         )
 833         add_executable(tshark ${tshark_FILES})
 834         add_dependencies(tshark svnversion)
 835         set_target_properties(tshark PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 836         target_link_libraries(tshark ${tshark_LIBS})
 837         install(TARGETS tshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 838 endif()
 839
 840 if(BUILD_rawshark AND PCAP_FOUND)
 841         set(rawshark_LIBS
 842                 ${LIBEPAN_LIBS}
 843                 ${APPLE_CORE_FOUNDATION_LIBRARY}
 844                 ${APPLE_SYSTEM_CONFIGURATION_LIBRARY}
 845         )
 846         set(rawshark_FILES
 847                 ${WIRESHARK_COMMON_SRC}
 848                 rawshark.c
 849                 ui/util.c
 850         )
 851         add_executable(rawshark ${rawshark_FILES})
 852         add_dependencies(rawshark svnversion)
 853         set_target_properties(rawshark PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 854         target_link_libraries(rawshark ${rawshark_LIBS})
 855         install(TARGETS rawshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 856 endif()
 857
 858 if(BUILD_dftest)
 859         set(dftest_LIBS
 860                 ${LIBEPAN_LIBS}
 861         )
 862         set(dftest_FILES
 863                 dftest.c
 864                 ui/util.c
 865         )
 866         add_executable(dftest ${dftest_FILES})
 867         set_target_properties(dftest PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 868         target_link_libraries(dftest ${dftest_LIBS})
 869         install(TARGETS dftest RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 870 endif()
 871
 872 if(BUILD_randpkt)
 873         set(randpkt_LIBS
 874                 wiretap
 875                 ${M_LIBRARIES}
 876                 ${PCAP_LIBRARIES}
 877 #               @SOCKET_LIBS@
 878 #               @NSL_LIBS@
 879                 ${CARES_LIBRARIES}
 880                 ${ADNS_LIBRARIES}
 881                 ${ZLIB_LIBRARIES}
 882         )
 883         set(randpkt_FILES
 884                 randpkt.c
 885         )
 886         add_executable(randpkt ${randpkt_FILES})
 887         set_target_properties(randpkt PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 888         target_link_libraries(randpkt ${randpkt_LIBS})
 889         install(TARGETS randpkt RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 890 endif()
 891
 892 if(BUILD_text2pcap)
 893         set(text2pcap_LIBS
 894                 wsutil
 895                 ${M_LIBRARIES}
 896                 ${ZLIB_LIBRARIES}
 897         )
 898         set(text2pcap_CLEAN_FILES
 899                 text2pcap.c
 900                 pcapio.c
 901         )
 902         set(text2pcap_FILES
 903                 ${text2pcap_CLEAN_FILES}
 904         )
 905         add_lex_files(text2pcap_FILES
 906                 text2pcap-scanner.l
 907         )
 908         add_executable(text2pcap ${text2pcap_FILES})
 909         add_dependencies(text2pcap svnversion)
 910         set_target_properties(text2pcap PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 911         target_link_libraries(text2pcap ${text2pcap_LIBS})
 912         install(TARGETS text2pcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 913 endif()
 914
 915 if(BUILD_mergecap)
 916         set(mergecap_LIBS
 917                 wiretap
 918                 ${ZLIB_LIBRARIES}
 919         )
 920         set(mergecap_FILES
 921                 mergecap.c
 922                 merge.c
 923                 svnversion.h
 924                 ${WTAP_PLUGIN_SOURCES}
 925         )
 926         add_executable(mergecap ${mergecap_FILES})
 927         add_dependencies(mergecap svnversion)
 928         set_target_properties(mergecap PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 929         target_link_libraries(mergecap ${mergecap_LIBS})
 930         install(TARGETS mergecap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 931 endif()
 932
 933 if(BUILD_reordercap)
 934         set(reordercap_LIBS
 935                 wiretap
 936                 ${ZLIB_LIBRARIES}
 937         )
 938         set(reordercap_FILES
 939                 reordercap.c
 940                 svnversion.h
 941                 ${WTAP_PLUGIN_SOURCES}
 942         )
 943         add_executable(reordercap ${reordercap_FILES})
 944         add_dependencies(reordercap svnversion)
 945         set_target_properties(reordercap PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 946         target_link_libraries(reordercap ${reordercap_LIBS})
 947         install(TARGETS reordercap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 948 endif()
 949
 950 if(BUILD_capinfos)
 951         set(capinfos_LIBS
 952                 wiretap
 953                 wsutil
 954                 ${ZLIB_LIBRARIES}
 955                 ${GCRYPT_LIBRARIES}
 956         )
 957         set(capinfos_FILES
 958                 capinfos.c
 959                 ${WTAP_PLUGIN_SOURCES}
 960         )
 961         add_executable(capinfos ${capinfos_FILES})
 962         add_dependencies(capinfos svnversion)
 963         set_target_properties(capinfos PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 964         target_link_libraries(capinfos ${capinfos_LIBS})
 965         install(TARGETS capinfos RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 966 endif()
 967
 968 if(BUILD_editcap)
 969         set(editcap_LIBS
 970                 wiretap
 971                 ${ZLIB_LIBRARIES}
 972         )
 973         set(editcap_FILES
 974                 editcap.c
 975                 epan/crypt/md5.c
 976                 epan/nstime.c
 977                 ${WTAP_PLUGIN_SOURCES}
 978         )
 979         add_executable(editcap ${editcap_FILES})
 980         add_dependencies(editcap svnversion)
 981         set_target_properties(editcap PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 982         target_link_libraries(editcap ${editcap_LIBS})
 983         install(TARGETS editcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 984 endif()
 985
 986 if(BUILD_dumpcap AND PCAP_FOUND)
 987         set(dumpcap_LIBS
 988 #               @INET_NTOP_LO@
 989                 wsutil
 990                 ${PCAP_LIBRARIES}
 991                 ${CAP_LIBRARIES}
 992 #               @SOCKET_LIBS@
 993 #               @NSL_LIBS@
 994                 ${GLIB2_LIBRARIES}
 995                 ${GTHREAD2_LIBRARIES}
 996                 ${ZLIB_LIBRARIES}
 997                 ${APPLE_CORE_FOUNDATION_LIBRARY}
 998                 ${APPLE_SYSTEM_CONFIGURATION_LIBRARY}
 999                 ${NL_LIBRARIES}
1000         )
1001         set(dumpcap_FILES
1002                 svnversion.h
1003                 capture_opts.c
1004                 capture-pcap-util.c
1005                 capture_stop_conditions.c
1006                 cfutils.c
1007                 clopts_common.c
1008                 conditions.c
1009                 dumpcap.c
1010                 pcapio.c
1011                 ringbuffer.c
1012                 sync_pipe_write.c
1013                 tempfile.c
1014                 version_info.c
1015                 ws80211_utils.c
1016                 ${PLATFORM_SRC}
1017         )
1018         add_executable(dumpcap ${dumpcap_FILES})
1019         add_dependencies(dumpcap svnversion)
1020         set_target_properties(dumpcap PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
1021         target_link_libraries(dumpcap ${dumpcap_LIBS})
1022         install(TARGETS dumpcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
1023 endif()
1024
1025 ADD_CUSTOM_COMMAND(
1026         OUTPUT  ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
1027         COMMAND ${PERL}
1028                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
1029                 ${CMAKE_SOURCE_DIR}/doc/make-authors-short.pl
1030                 < ${CMAKE_SOURCE_DIR}/AUTHORS
1031                 > ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
1032         DEPENDS
1033                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
1034                 ${CMAKE_SOURCE_DIR}/doc/make-authors-short.pl
1035                 ${CMAKE_SOURCE_DIR}/AUTHORS
1036 )
1037
1038 ADD_CUSTOM_COMMAND(
1039         OUTPUT  ${CMAKE_BINARY_DIR}/AUTHORS-SHORT-FORMAT
1040                 ${CMAKE_BINARY_DIR}/wireshark.pod
1041         COMMAND ${PERL}
1042                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
1043                 ${CMAKE_SOURCE_DIR}/doc/make-authors-format.pl
1044                 < ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
1045                 > ${CMAKE_BINARY_DIR}/AUTHORS-SHORT-FORMAT
1046         COMMAND cat
1047                 ${CMAKE_SOURCE_DIR}/doc/wireshark.pod.template
1048                 ${CMAKE_BINARY_DIR}/AUTHORS-SHORT-FORMAT
1049                 > ${CMAKE_BINARY_DIR}/wireshark.pod
1050         DEPENDS
1051                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
1052                 ${CMAKE_SOURCE_DIR}/doc/make-authors-format.pl
1053                 ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
1054                 ${CMAKE_SOURCE_DIR}/doc/wireshark.pod.template
1055 )
1056
1057 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/capinfos 1 )
1058 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/dftest 1 )
1059 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/dumpcap 1 )
1060 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/editcap 1 )
1061 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/idl2wrs 1 )
1062 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/mergecap 1 )
1063 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/randpkt 1 )
1064 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/rawshark 1 )
1065 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/reordercap 1 )
1066 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/text2pcap 1 )
1067 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/tshark 1 )
1068 pod2manhtml( wireshark 1 )
1069 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/wireshark-filter 4 )
1070
1071 add_custom_target(
1072         auxiliary ALL
1073         DEPENDS
1074                 AUTHORS-SHORT
1075                 capinfos.html
1076                 dftest.html
1077                 dumpcap.html
1078                 editcap.html
1079                 idl2wrs.html
1080                 mergecap.html
1081                 randpkt.html
1082                 rawshark.html
1083                 reordercap.html
1084                 text2pcap.html
1085                 tshark.html
1086                 wireshark.html
1087                 wireshark-filter.html
1088 )
1089
1090 set(MAN1_FILES
1091         ${CMAKE_BINARY_DIR}/capinfos.1
1092         ${CMAKE_BINARY_DIR}/dftest.1
1093         ${CMAKE_BINARY_DIR}/dumpcap.1
1094         ${CMAKE_BINARY_DIR}/editcap.1
1095         ${CMAKE_BINARY_DIR}/idl2wrs.1
1096         ${CMAKE_BINARY_DIR}/mergecap.1
1097         ${CMAKE_BINARY_DIR}/randpkt.1
1098         ${CMAKE_BINARY_DIR}/rawshark.1
1099         ${CMAKE_BINARY_DIR}/reordercap.1
1100         ${CMAKE_BINARY_DIR}/text2pcap.1
1101         ${CMAKE_BINARY_DIR}/tshark.1
1102         ${CMAKE_BINARY_DIR}/wireshark.1
1103 )
1104
1105 set(MAN4_FILES
1106         ${CMAKE_BINARY_DIR}/wireshark-filter.4
1107 )
1108
1109 set(CLEAN_FILES
1110         ${wireshark_FILES}
1111         ${tshark_FILES}
1112         ${rawshark_FILES}
1113         ${dftest_FILES}
1114         ${randpkt_FILES}
1115         ${text2pcap_CLEAN_FILES}
1116         ${mergecap_FILES}
1117         ${capinfos_FILES}
1118         ${editcap_FILES}
1119         ${dumpcap_FILES}
1120 )
1121
1122 if (WERROR)
1123         set_source_files_properties(
1124                 ${CLEAN_FILES}
1125                 PROPERTIES
1126                 COMPILE_FLAGS -Werror
1127         )
1128 endif()
1129
1130 install(
1131         FILES
1132                 ${INSTALL_FILES}
1133         DESTINATION
1134                 ${CMAKE_INSTALL_DATADIR}/${CPACK_PACKAGE_NAME}
1135 )
1136
1137 install(
1138         FILES
1139                 ${MAN1_FILES}
1140         DESTINATION
1141                 ${CMAKE_INSTALL_MANDIR}/man1
1142 )
1143
1144 install(
1145         FILES
1146                 ${MAN4_FILES}
1147         DESTINATION
1148                 ${CMAKE_INSTALL_MANDIR}/man4
1149 )
1150
1151 install(
1152         DIRECTORY
1153                 ${INSTALL_DIRS}
1154         DIRECTORY_PERMISSIONS
1155                 OWNER_EXECUTE OWNER_WRITE OWNER_READ
1156                 GROUP_EXECUTE GROUP_READ
1157                 WORLD_EXECUTE WORLD_READ
1158         DESTINATION
1159                 ${CMAKE_INSTALL_DATADIR}/${CPACK_PACKAGE_NAME}
1160         PATTERN ".svn" EXCLUDE
1161         PATTERN "Makefile.*" EXCLUDE
1162         PATTERN "faq.py" EXCLUDE
1163 )
1164
1165
1166 if(DOC_DIR)
1167         message(STATUS "Docdir install: ${DOC_DIR}")
1168         INSTALL(
1169                 DIRECTORY
1170                         ${CMAKE_BINARY_DIR}/docbook/
1171                 DIRECTORY_PERMISSIONS
1172                         OWNER_EXECUTE OWNER_WRITE OWNER_READ
1173                         GROUP_EXECUTE GROUP_READ
1174                         WORLD_EXECUTE WORLD_READ
1175                 DESTINATION
1176                         ${DOC_DIR}/guides
1177                 FILES_MATCHING
1178                 PATTERN "*.pdf"
1179         )
1180 endif()