pidl/lib/Parse/Pidl/Samba3/ClientNDR.pm

   1 ###################################################
   2 # Samba3 client generator for IDL structures
   3 # on top of Samba4 style NDR functions
   4 # Copyright jelmer@samba.org 2005-2006
   5 # Copyright gd@samba.org 2008
   6 # released under the GNU GPL
   7
   8 package Parse::Pidl::Samba3::ClientNDR;
   9
  10 use Exporter;
  11 @ISA = qw(Exporter);
  12 @EXPORT_OK = qw(ParseFunction $res $res_hdr ParseOutputArgument);
  13
  14 use strict;
  15 use Parse::Pidl qw(fatal warning error);
  16 use Parse::Pidl::Util qw(has_property ParseExpr);
  17 use Parse::Pidl::Samba4 qw(DeclLong);
  18 use Parse::Pidl::Samba4::Header qw(GenerateFunctionInEnv);
  19
  20 use vars qw($VERSION);
  21 $VERSION = '0.01';
  22
  23 sub indent($) { my ($self) = @_; $self->{tabs}.="\t"; }
  24 sub deindent($) { my ($self) = @_; $self->{tabs} = substr($self->{tabs}, 1); }
  25 sub pidl($$) { my ($self,$txt) = @_; $self->{res} .= $txt ? "$self->{tabs}$txt\n" : "\n"; }
  26 sub pidl_hdr($$) { my ($self, $txt) = @_; $self->{res_hdr} .= "$txt\n"; }
  27 sub fn_declare($$) { my ($self,$n) = @_; $self->pidl($n); $self->pidl_hdr("$n;"); }
  28
  29 sub genpad($)
  30 {
  31         my ($s) = @_;
  32         my $nt = int((length($s)+1)/8);
  33         my $lt = ($nt*8)-1;
  34         my $ns = (length($s)-$lt);
  35         return "\t"x($nt)." "x($ns);
  36 }
  37
  38 sub new($)
  39 {
  40         my ($class) = shift;
  41         my $self = { res => "", res_hdr => "", tabs => "" };
  42         bless($self, $class);
  43 }
  44
  45 sub ElementDirection($)
  46 {
  47         my ($e) = @_;
  48
  49         return "[in,out]" if (has_property($e, "in") and has_property($e, "out"));
  50         return "[in]" if (has_property($e, "in"));
  51         return "[out]" if (has_property($e, "out"));
  52         return "[in,out]";
  53 }
  54
  55 sub HeaderProperties($$)
  56 {
  57         my($props,$ignores) = @_;
  58         my $ret = "";
  59
  60         foreach my $d (keys %{$props}) {
  61                 next if (grep(/^$d$/, @$ignores));
  62                 if($props->{$d} ne "1") {
  63                         $ret.= "$d($props->{$d}),";
  64                 } else {
  65                         $ret.="$d,";
  66                 }
  67         }
  68
  69         if ($ret) {
  70                 return "[" . substr($ret, 0, -1) . "]";
  71         }
  72 }
  73
  74 sub ParseOutputArgument($$$)
  75 {
  76         my ($self, $fn, $e) = @_;
  77         my $level = 0;
  78
  79         if ($e->{LEVELS}[0]->{TYPE} ne "POINTER" and $e->{LEVELS}[0]->{TYPE} ne "ARRAY") {
  80                 $self->pidl("return NT_STATUS_NOT_SUPPORTED;");
  81                 error($e->{ORIGINAL}, "[out] argument is not a pointer or array");
  82                 return;
  83         }
  84
  85         if ($e->{LEVELS}[0]->{TYPE} eq "POINTER") {
  86                 $level = 1;
  87                 if ($e->{LEVELS}[0]->{POINTER_TYPE} ne "ref") {
  88                         $self->pidl("if ($e->{NAME} && r.out.$e->{NAME}) {");
  89                         $self->indent;
  90                 }
  91         }
  92
  93         if ($e->{LEVELS}[$level]->{TYPE} eq "ARRAY") {
  94                 # This is a call to GenerateFunctionInEnv intentionally.
  95                 # Since the data is being copied into a user-provided data
  96                 # structure, the user should be able to know the size beforehand
  97                 # to allocate a structure of the right size.
  98                 my $env = GenerateFunctionInEnv($fn, "r.");
  99                 my $size_is = ParseExpr($e->{LEVELS}[$level]->{SIZE_IS}, $env, $e->{ORIGINAL});
 100                 if (has_property($e, "charset")) {
 101                     $self->pidl("memcpy(CONST_DISCARD(char *, $e->{NAME}), r.out.$e->{NAME}, $size_is * sizeof(*$e->{NAME}));");
 102                 } else {
 103                     $self->pidl("memcpy($e->{NAME}, r.out.$e->{NAME}, $size_is * sizeof(*$e->{NAME}));");
 104                 }
 105         } else {
 106                 $self->pidl("*$e->{NAME} = *r.out.$e->{NAME};");
 107         }
 108
 109         if ($e->{LEVELS}[0]->{TYPE} eq "POINTER") {
 110                 if ($e->{LEVELS}[0]->{POINTER_TYPE} ne "ref") {
 111                         $self->deindent;
 112                         $self->pidl("}");
 113                 }
 114         }
 115 }
 116
 117 sub ParseFunction($$$)
 118 {
 119         my ($self, $if, $fn) = @_;
 120
 121         my $fn_args = "";
 122         my $uif = uc($if);
 123         my $ufn = "NDR_".uc($fn->{NAME});
 124         my $fn_str = "NTSTATUS rpccli_$fn->{NAME}";
 125         my $pad = genpad($fn_str);
 126
 127         $fn_args .= "struct rpc_pipe_client *cli,\n" . $pad . "TALLOC_CTX *mem_ctx";
 128
 129         foreach (@{$fn->{ELEMENTS}}) {
 130                 my $dir = ElementDirection($_);
 131                 my $prop = HeaderProperties($_->{PROPERTIES}, ["in", "out"]);
 132                 $fn_args .= ",\n" . $pad . DeclLong($_) . " /* $dir $prop */";
 133         }
 134
 135         if (defined($fn->{RETURN_TYPE}) && ($fn->{RETURN_TYPE} eq "WERROR")) {
 136                 $fn_args .= ",\n" . $pad . "WERROR *werror";
 137         }
 138
 139         $self->fn_declare("$fn_str($fn_args)");
 140         $self->pidl("{");
 141         $self->indent;
 142         $self->pidl("struct $fn->{NAME} r;");
 143         $self->pidl("NTSTATUS status;");
 144         $self->pidl("");
 145         $self->pidl("/* In parameters */");
 146
 147         foreach (@{$fn->{ELEMENTS}}) {
 148                 if (grep(/in/, @{$_->{DIRECTION}})) {
 149                         $self->pidl("r.in.$_->{NAME} = $_->{NAME};");
 150                 }
 151         }
 152
 153         $self->pidl("");
 154         $self->pidl("if (DEBUGLEVEL >= 10) {");
 155         $self->indent;
 156         $self->pidl("NDR_PRINT_IN_DEBUG($fn->{NAME}, &r);");
 157         $self->deindent;
 158         $self->pidl("}");
 159         $self->pidl("");
 160         $self->pidl("status = cli->dispatch(cli,");
 161         $self->pidl("\t\t\tmem_ctx,");
 162         $self->pidl("\t\t\t&ndr_table_$if,");
 163         $self->pidl("\t\t\t$ufn,");
 164         $self->pidl("\t\t\t&r);");
 165         $self->pidl("");
 166
 167         $self->pidl("if (!NT_STATUS_IS_OK(status)) {");
 168         $self->indent;
 169         $self->pidl("return status;");
 170         $self->deindent;
 171         $self->pidl("}");
 172
 173         $self->pidl("");
 174         $self->pidl("if (DEBUGLEVEL >= 10) {");
 175         $self->indent;
 176         $self->pidl("NDR_PRINT_OUT_DEBUG($fn->{NAME}, &r);");
 177         $self->deindent;
 178         $self->pidl("}");
 179         $self->pidl("");
 180         $self->pidl("if (NT_STATUS_IS_ERR(status)) {");
 181         $self->indent;
 182         $self->pidl("return status;");
 183         $self->deindent;
 184         $self->pidl("}");
 185         $self->pidl("");
 186         $self->pidl("/* Return variables */");
 187         foreach my $e (@{$fn->{ELEMENTS}}) {
 188                 next unless (grep(/out/, @{$e->{DIRECTION}}));
 189
 190                 $self->ParseOutputArgument($fn, $e);
 191
 192         }
 193
 194         $self->pidl("");
 195         $self->pidl("/* Return result */");
 196         if (not $fn->{RETURN_TYPE}) {
 197                 $self->pidl("return NT_STATUS_OK;");
 198         } elsif ($fn->{RETURN_TYPE} eq "NTSTATUS") {
 199                 $self->pidl("return r.out.result;");
 200         } elsif ($fn->{RETURN_TYPE} eq "WERROR") {
 201                 $self->pidl("if (werror) {");
 202                 $self->indent;
 203                 $self->pidl("*werror = r.out.result;");
 204                 $self->deindent;
 205                 $self->pidl("}");
 206                 $self->pidl("");
 207                 $self->pidl("return werror_to_ntstatus(r.out.result);");
 208         } else {
 209                 warning($fn->{ORIGINAL}, "Unable to convert $fn->{RETURN_TYPE} to NTSTATUS");
 210                 $self->pidl("return NT_STATUS_OK;");
 211         }
 212
 213         $self->deindent;
 214         $self->pidl("}");
 215         $self->pidl("");
 216 }
 217
 218 sub ParseInterface($$)
 219 {
 220         my ($self, $if) = @_;
 221
 222         my $uif = uc($if->{NAME});
 223
 224         $self->pidl_hdr("#ifndef __CLI_$uif\__");
 225         $self->pidl_hdr("#define __CLI_$uif\__");
 226         foreach (@{$if->{FUNCTIONS}}) {
 227                 next if ($_->{PROPERTIES}{noopnum});
 228                 $self->ParseFunction($if->{NAME}, $_);
 229         }
 230         $self->pidl_hdr("#endif /* __CLI_$uif\__ */");
 231 }
 232
 233 sub Parse($$$$)
 234 {
 235         my($self,$ndr,$header,$ndr_header) = @_;
 236
 237         $self->pidl("/*");
 238         $self->pidl(" * Unix SMB/CIFS implementation.");
 239         $self->pidl(" * client auto-generated by pidl. DO NOT MODIFY!");
 240         $self->pidl(" */");
 241         $self->pidl("");
 242         $self->pidl("#include \"includes.h\"");
 243         $self->pidl("#include \"$header\"");
 244         $self->pidl_hdr("#include \"$ndr_header\"");
 245         $self->pidl("");
 246
 247         foreach (@$ndr) {
 248                 $self->ParseInterface($_) if ($_->{TYPE} eq "INTERFACE");
 249         }
 250
 251         return ($self->{res}, $self->{res_hdr});
 252 }
 253
 254 1;