configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.2.0pre3],[http://rsync.samba.org/bugzilla.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_CXX
  45 AC_PROG_AWK
  46 AC_PROG_EGREP
  47 AC_PROG_INSTALL
  48 AC_PROG_MKDIR_P
  49 AC_PROG_CC_STDC
  50 AC_SUBST(SHELL)
  51 AC_PATH_PROG([PERL], [perl])
  52 AC_PATH_PROG([PYTHON3], [python3])
  53
  54 AC_DEFINE([_GNU_SOURCE], 1,
  55           [Define _GNU_SOURCE so that we get all necessary prototypes])
  56
  57 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  58         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  59 fi
  60
  61 AC_ARG_ENABLE(profile,
  62         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  63 if test x"$enable_profile" = x"yes"; then
  64         CFLAGS="$CFLAGS -pg"
  65 fi
  66
  67 AC_MSG_CHECKING([if md2man can create man pages])
  68 if test x"$ac_cv_path_PYTHON3" = x; then
  69     AC_MSG_RESULT(no - python3 not found)
  70     md2man_works=no
  71 else
  72     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync.1.md" 2>&1`
  73     if test $? = 0; then
  74         AC_MSG_RESULT(yes)
  75         md2man_works=yes
  76     else
  77         AC_MSG_RESULT(no)
  78         md2man_works=no
  79         echo "$md2man_out"
  80     fi
  81 fi
  82
  83 AC_MSG_CHECKING([if we require man-page building])
  84 AC_ARG_ENABLE([md2man],
  85         AS_HELP_STRING([--disable-md2man],[disable md2man for man page creation]))
  86 if test x"$enable_md2man" != x"no"; then
  87     if test -f "$srcdir/rsync.1"; then
  88         AC_MSG_RESULT(optional)
  89     else
  90         AC_MSG_RESULT(required)
  91         if test x"$md2man_works" = x"no"; then
  92             AC_MSG_ERROR(You need python3 and the cmarkgfm OR commonmark python3 lib in order to build man pages.
  93 You can specify --disable-md2man if you want to skip building them.)
  94         fi
  95     fi
  96     MAKE_MAN=man
  97 else
  98     AC_MSG_RESULT(no)
  99     MAKE_MAN=''
 100 fi
 101
 102 # Specifically, this turns on panic_action handling.
 103 AC_ARG_ENABLE(maintainer-mode,
 104         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
 105 if test x"$enable_maintainer_mode" = x"yes"; then
 106         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 107 fi
 108
 109 # This is needed for our included version of popt.  Kind of silly, but
 110 # I don't want our version too far out of sync.
 111 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 112
 113 # If GCC, turn on warnings.
 114 if test x"$GCC" = x"yes"; then
 115         CFLAGS="$CFLAGS -Wall -W"
 116 fi
 117
 118 AC_ARG_WITH(included-popt,
 119         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 120
 121 AC_ARG_WITH(included-zlib,
 122         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 123
 124 AC_ARG_WITH(protected-args,
 125         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
 126 if test x"$with_protected_args" = x"yes"; then
 127         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
 128 fi
 129
 130 AC_ARG_WITH(rsync-path,
 131         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 132         [ RSYNC_PATH="$with_rsync_path" ],
 133         [ RSYNC_PATH="rsync" ])
 134
 135 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 136
 137 AC_ARG_WITH(rsyncd-conf,
 138         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 139         [ if test ! -z "$with_rsyncd_conf" ; then
 140                 case $with_rsyncd_conf in
 141                         yes|no)
 142                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 143                                 ;;
 144                         /*)
 145                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 146                                 ;;
 147                         *)
 148                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 149                                 ;;
 150                 esac
 151         else
 152                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 153         fi ],
 154         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 155
 156 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 157
 158 AC_ARG_WITH(rsh,
 159         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 160
 161 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 162 if test x$HAVE_REMSH = x1; then
 163         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 164 fi
 165
 166 if test x"$with_rsh" != x; then
 167         RSYNC_RSH="$with_rsh"
 168 else
 169         RSYNC_RSH="ssh"
 170 fi
 171 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 172
 173 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 174 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 175 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 176
 177 AC_ARG_WITH(nobody-group,
 178     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 179     [ NOBODY_GROUP="$with_nobody_group" ])
 180
 181 if test x"$with_nobody_group" = x; then
 182     AC_MSG_CHECKING([the group for user "nobody"])
 183     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 184         NOBODY_GROUP=nobody
 185     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 186         NOBODY_GROUP=nogroup
 187     else
 188         NOBODY_GROUP=nobody # test for others?
 189     fi
 190     AC_MSG_RESULT($NOBODY_GROUP)
 191 fi
 192
 193 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 194 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 195
 196 # SIMD optimizations
 197 SIMD=
 198
 199 AC_MSG_CHECKING([whether to enable SIMD optimizations])
 200 AC_ARG_ENABLE(simd,
 201     AS_HELP_STRING([--enable-simd],[enable SIMD optimizations (requires c++)]))
 202
 203 if test x"$enable_simd" = x"yes"; then
 204     # For x86-64 SIMD, g++ >=5 or clang++ >=7 is required
 205     if test x"$build_cpu" = x"x86_64"; then
 206         if test x"$CXX" != x""; then
 207             CXX_OK=
 208             CXX_VERSION=`$CXX --version | head -n 1`
 209             case "$CXX_VERSION" in
 210             g++*)
 211                 CXX_VERSION=`$CXX -dumpversion | sed 's/\..*//g'`
 212                 if test "$CXX_VERSION" -ge "5"; then
 213                     CXX_OK=yes
 214                 fi
 215                 ;;
 216             *clang*)
 217                 # $CXX -dumpversion would have been ideal, but is broken on older clang
 218                 CXX_VERSION=`echo "$CXX_VERSION" | sed 's/.*version //g' | sed 's/\..*//g'`
 219                 if test "$CXX_VERSION" -ge "7"; then
 220                     CXX_OK=yes
 221                 fi
 222                 ;;
 223             esac
 224
 225             if test x"$CXX_OK" = x"yes"; then
 226                 # AC_MSG_RESULT() is called below.
 227                 SIMD="$SIMD x86_64"
 228             else
 229                 AC_MSG_RESULT(error)
 230                 AC_MSG_ERROR([Failed to find g++ >=5 or clang++ >=7 for SIMD optimizations.
 231 Omit --enable-simd to continue without it. ($CXX, $CXX_VERSION)])
 232             fi
 233         fi
 234     else
 235         AC_MSG_RESULT(unavailable)
 236         AC_MSG_ERROR(The SIMD optimizations are currently x86_64 only.
 237 Omit --enable-simd to continue.)
 238     fi
 239 fi
 240
 241 if test x"$SIMD" != x""; then
 242     SIMD=`echo "$SIMD" | sed 's/^ *//'`
 243     AC_MSG_RESULT([yes ($SIMD)])
 244     AC_DEFINE(HAVE_SIMD, 1, [Define to 1 to enable SIMD optimizations])
 245     SIMD=`echo "\\\$(SIMD_$SIMD)" | sed 's/ /) $(SIMD_/g'`
 246     # We only use c++ for its target attribute dispatching, disable unneeded bulky features
 247     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 248 else
 249     AC_MSG_RESULT(no)
 250 fi
 251
 252 AC_SUBST(SIMD)
 253
 254 # arrgh. libc in some old debian version screwed up the largefile
 255 # stuff, getting byte range locking wrong
 256 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 257 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 258 #define _FILE_OFFSET_BITS 64
 259 #include <stdio.h>
 260 #include <fcntl.h>
 261 #include <sys/types.h>
 262 #include <sys/wait.h>
 263 #if HAVE_UNISTD_H
 264 #include <unistd.h>
 265 #endif
 266
 267 int main(void)
 268 {
 269         struct flock lock;
 270         int status;
 271         char tpl[32] = "/tmp/locktest.XXXXXX";
 272         int fd = mkstemp(tpl);
 273         if (fd < 0) {
 274                 strcpy(tpl, "conftest.dat");
 275                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 276         }
 277
 278         lock.l_type = F_WRLCK;
 279         lock.l_whence = SEEK_SET;
 280         lock.l_start = 0;
 281         lock.l_len = 1;
 282         lock.l_pid = 0;
 283         fcntl(fd,F_SETLK,&lock);
 284         if (fork() == 0) {
 285                 lock.l_start = 1;
 286                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 287         }
 288         wait(&status);
 289         unlink(tpl);
 290         return WEXITSTATUS(status);
 291 }
 292 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 293 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 294    AC_SYS_LARGEFILE
 295 fi
 296
 297 ipv6type=unknown
 298 ipv6lib=none
 299 ipv6trylibc=yes
 300
 301 AC_ARG_ENABLE(ipv6,
 302         AS_HELP_STRING([--disable-ipv6],[turn off IPv6 support]))
 303 if test x"$enable_ipv6" != x"no"; then
 304         AC_MSG_CHECKING([ipv6 stack type])
 305         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 306                 case $i in
 307                 inria)
 308                         # http://www.kame.net/
 309                         AC_EGREP_CPP(yes, [
 310 #include <netinet/in.h>
 311 #ifdef IPV6_INRIA_VERSION
 312 yes
 313 #endif],
 314                                 [ipv6type=$i;
 315                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 316                                 ])
 317                         ;;
 318                 kame)
 319                         # http://www.kame.net/
 320                         AC_EGREP_CPP(yes, [
 321 #include <netinet/in.h>
 322 #ifdef __KAME__
 323 yes
 324 #endif],
 325                                 [ipv6type=$i;
 326                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 327                         ;;
 328                 linux-glibc)
 329                         # http://www.v6.linux.or.jp/
 330                         AC_EGREP_CPP(yes, [
 331 #include <features.h>
 332 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 333 yes
 334 #endif],
 335                                 [ipv6type=$i;
 336 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 337                         ;;
 338                 linux-inet6)
 339                         # http://www.v6.linux.or.jp/
 340                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 341                                 ipv6type=$i
 342                                 ipv6lib=inet6
 343                                 ipv6libdir=/usr/inet6/lib
 344                                 ipv6trylibc=yes;
 345                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 346                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 347                         fi
 348                         ;;
 349                 solaris)
 350                         # http://www.sun.com
 351                         AC_EGREP_CPP(yes, [
 352 #include <netinet/ip6.h>
 353 #ifdef __sun
 354 yes
 355 #endif],
 356                                 [ipv6type=$i;
 357                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 358                         ;;
 359                 toshiba)
 360                         AC_EGREP_CPP(yes, [
 361 #include <sys/param.h>
 362 #ifdef _TOSHIBA_INET6
 363 yes
 364 #endif],
 365                                 [ipv6type=$i;
 366                                 ipv6lib=inet6;
 367                                 ipv6libdir=/usr/local/v6/lib;
 368                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 369                         ;;
 370                 v6d)
 371                         AC_EGREP_CPP(yes, [
 372 #include </usr/local/v6/include/sys/v6config.h>
 373 #ifdef __V6D__
 374 yes
 375 #endif],
 376                                 [ipv6type=$i;
 377                                 ipv6lib=v6;
 378                                 ipv6libdir=/usr/local/v6/lib;
 379                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 380                         ;;
 381                 zeta)
 382                         AC_EGREP_CPP(yes, [
 383 #include <sys/param.h>
 384 #ifdef _ZETA_MINAMI_INET6
 385 yes
 386 #endif],
 387                                 [ipv6type=$i;
 388                                 ipv6lib=inet6;
 389                                 ipv6libdir=/usr/local/v6/lib;
 390                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 391                         ;;
 392                 cygwin)
 393                         AC_EGREP_CPP(yes, [
 394 #include <netinet/in.h>
 395 #ifdef _CYGWIN_IN6_H
 396 yes
 397 #endif],
 398                                 [ipv6type=$i;
 399                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 400                         ;;
 401                 esac
 402                 if test "$ipv6type" != "unknown"; then
 403                         break
 404                 fi
 405         done
 406         AC_MSG_RESULT($ipv6type)
 407
 408         AC_SEARCH_LIBS(getaddrinfo, inet6)
 409 fi
 410
 411 dnl Do you want to disable use of locale functions
 412 AC_ARG_ENABLE([locale],
 413         AS_HELP_STRING([--disable-locale],[disable locale features]))
 414 AH_TEMPLATE([CONFIG_LOCALE],
 415 [Undefine if you do not want locale features.  By default this is defined.])
 416 if test x"$enable_locale" != x"no"; then
 417         AC_DEFINE(CONFIG_LOCALE)
 418 fi
 419
 420 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 421 case $host_os in
 422         *cygwin* ) AC_MSG_RESULT(yes)
 423                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 424                             [Define to 1 if sockets need to be shutdown])
 425                    ;;
 426                * ) AC_MSG_RESULT(no);;
 427 esac
 428
 429 AC_C_BIGENDIAN
 430 AC_HEADER_DIRENT
 431 AC_HEADER_TIME
 432 AC_HEADER_SYS_WAIT
 433 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 434     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 435     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 436     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 437     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 438     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 439     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 440     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h)
 441 AC_HEADER_MAJOR_FIXED
 442
 443 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 444 AC_ARG_ENABLE([openssl],
 445         AS_HELP_STRING([--disable-openssl],[disable openssl crypto library]))
 446 AH_TEMPLATE([USE_OPENSSL],
 447 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 448 if test x"$enable_openssl" != x"no"; then
 449     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 450       AC_MSG_RESULT(yes)
 451       AC_SEARCH_LIBS(MD5_Init, crypto,
 452           [AC_DEFINE(USE_OPENSSL)],
 453           [AC_MSG_ERROR(Failed to find MD5_Init function in openssl crypto lib.
 454 Use --disable-openssl to continue without openssl crypto lib support.)])
 455     else
 456         AC_MSG_RESULT(no)
 457         AC_MSG_ERROR(Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support.
 458 Use --disable-openssl to continue without it.)
 459     fi
 460 else
 461     AC_MSG_RESULT(no)
 462 fi
 463
 464 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 465 AC_ARG_ENABLE([xxhash],
 466         AS_HELP_STRING([--disable-xxhash],[disable xxhash checksums]))
 467 AH_TEMPLATE([SUPPORT_XXHASH],
 468 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 469 if test x"$enable_xxhash" != x"no"; then
 470     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 471         AC_MSG_RESULT(yes)
 472         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 473             [AC_DEFINE(SUPPORT_XXHASH)],
 474             [AC_MSG_ERROR(Failed to find XXH64_createState function in xxhash lib.
 475 Use --disable-xxhash to continue without xxhash checksums.)])
 476     else
 477         AC_MSG_RESULT(no)
 478         AC_MSG_ERROR(Failed to find xxhash.h for xxhash checksum support.
 479 Use --disable-xxhash to continue without it.)
 480     fi
 481 else
 482     AC_MSG_RESULT(no)
 483 fi
 484
 485 AC_MSG_CHECKING([whether to enable zstd compression])
 486 AC_ARG_ENABLE([zstd],
 487         AC_HELP_STRING([--disable-zstd], [disable zstd compression]))
 488 AH_TEMPLATE([SUPPORT_ZSTD],
 489 [Undefine if you do not want zstd compression.  By default this is defined.])
 490 if test x"$enable_zstd" != x"no"; then
 491     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 492         AC_MSG_RESULT(yes)
 493         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 494             [AC_DEFINE(SUPPORT_ZSTD)],
 495             [AC_MSG_ERROR(Failed to find ZSTD_minCLevel function in zstd lib.
 496 Use --disable-zstd to continue without zstd compression.)])
 497     else
 498         AC_MSG_RESULT(no)
 499         AC_MSG_ERROR(Failed to find zstd.h for zstd compression support.
 500 Use --disable-zstd to continue without it.)
 501     fi
 502 else
 503     AC_MSG_RESULT(no)
 504 fi
 505
 506 AC_MSG_CHECKING([whether to enable LZ4 compression])
 507 AC_ARG_ENABLE([lz4],
 508         AC_HELP_STRING([--disable-lz4], [disable LZ4 compression]))
 509 AH_TEMPLATE([SUPPORT_LZ4],
 510 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 511 if test x"$enable_lz4" != x"no"; then
 512     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 513         AC_MSG_RESULT(yes)
 514         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 515             [AC_DEFINE(SUPPORT_LZ4)],
 516             [AC_MSG_ERROR(Failed to find LZ4_compress_default function in lz4 lib.
 517 Use --disable-lz4 to continue without lz4 compression.)])
 518     else
 519         AC_MSG_RESULT(no)
 520         AC_MSG_ERROR(Failed to find lz4.h for lz4 compression support.
 521 Use --disable-lz4 to continue without it.)
 522     fi
 523 else
 524     AC_MSG_RESULT(no)
 525 fi
 526
 527 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 528 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 529 #include <sys/types.h>
 530 #ifdef MAJOR_IN_MKDEV
 531 #include <sys/mkdev.h>
 532 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 533 #  define makedev mkdev
 534 # endif
 535 #elif defined MAJOR_IN_SYSMACROS
 536 #include <sys/sysmacros.h>
 537 #endif
 538
 539 int main(void)
 540 {
 541         dev_t dev = makedev(0, 5, 7);
 542         if (major(dev) != 5 || minor(dev) != 7)
 543                 return 1;
 544         return 0;
 545 }
 546 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 547 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 548    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 549 fi
 550
 551 AC_CHECK_SIZEOF(int)
 552 AC_CHECK_SIZEOF(long)
 553 AC_CHECK_SIZEOF(long long)
 554 AC_CHECK_SIZEOF(short)
 555 AC_CHECK_SIZEOF(int16_t)
 556 AC_CHECK_SIZEOF(uint16_t)
 557 AC_CHECK_SIZEOF(int32_t)
 558 AC_CHECK_SIZEOF(uint32_t)
 559 AC_CHECK_SIZEOF(int64_t)
 560 AC_CHECK_SIZEOF(off_t)
 561 AC_CHECK_SIZEOF(off64_t)
 562 AC_CHECK_SIZEOF(time_t)
 563 AC_CHECK_SIZEOF(char*)
 564
 565 AC_C_INLINE
 566
 567 AC_TYPE_LONG_DOUBLE_WIDER
 568 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 569 if test $ac_cv_c_long_double = yes; then
 570   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 571 fi
 572
 573 AC_TYPE_UID_T
 574 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 575 AC_TYPE_GETGROUPS
 576 AC_CHECK_MEMBERS([struct stat.st_rdev,
 577                   struct stat.st_mtimensec,
 578                   struct stat.st_mtimespec.tv_nsec,
 579                   struct stat.st_mtim.tv_nsec],,,[
 580 #ifdef HAVE_SYS_TYPES_H
 581 #include <sys/types.h>
 582 #endif
 583 #ifdef HAVE_SYS_STAT_H
 584 #include <sys/stat.h>
 585 #endif
 586 #ifdef HAVE_UNISTD_H
 587 #include <unistd.h>
 588 #endif])
 589
 590 TYPE_SOCKLEN_T
 591
 592 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 593     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 594 if test x"$rsync_cv_errno" = x"yes"; then
 595    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 596 fi
 597
 598 # The following test taken from the cvs sources
 599 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 600 # These need checks to be before checks for any other functions that
 601 #    might be in the same libraries.
 602 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 603 # libsocket.so which has a bad implementation of gethostbyname (it
 604 # only looks in /etc/hosts), so we only look for -lsocket if we need
 605 # it.
 606 AC_CHECK_FUNCS(connect)
 607 if test x"$ac_cv_func_connect" = x"no"; then
 608     case "$LIBS" in
 609     *-lnsl*) ;;
 610     *) AC_CHECK_LIB(nsl_s, printf) ;;
 611     esac
 612     case "$LIBS" in
 613     *-lnsl*) ;;
 614     *) AC_CHECK_LIB(nsl, printf) ;;
 615     esac
 616     case "$LIBS" in
 617     *-lsocket*) ;;
 618     *) AC_CHECK_LIB(socket, connect) ;;
 619     esac
 620     case "$LIBS" in
 621     *-linet*) ;;
 622     *) AC_CHECK_LIB(inet, connect) ;;
 623     esac
 624     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 625     dnl has been cached.
 626     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 627        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 628         # ac_cv_func_connect=yes
 629         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 630         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 631     fi
 632 fi
 633
 634 AC_SEARCH_LIBS(inet_ntop, resolv)
 635
 636 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 637 # accept either iconv_open or libiconv_open, since some include files map
 638 # the former to the latter.
 639 AC_SEARCH_LIBS(iconv_open, iconv)
 640 AC_SEARCH_LIBS(libiconv_open, iconv)
 641
 642 AC_MSG_CHECKING([for iconv declaration])
 643 AC_CACHE_VAL(am_cv_proto_iconv, [
 644     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 645 #include <stdlib.h>
 646 #include <iconv.h>
 647 extern
 648 #ifdef __cplusplus
 649 "C"
 650 #endif
 651 #if defined(__STDC__) || defined(__cplusplus)
 652 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 653 #else
 654 size_t iconv();
 655 #endif
 656 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 657       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 658     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed 's/( /(/'`
 659 AC_MSG_RESULT([$]{ac_t:-
 660          }[$]am_cv_proto_iconv)
 661 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 662                    [Define as const if the declaration of iconv() needs const.])
 663
 664 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 665
 666 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 667
 668 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 669 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 670 #include <sys/socket.h>])
 671
 672 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 673 #   builtin getaddrinfo if one of the defines don't exist
 674 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 675                rsync_cv_HAVE_GETADDR_DEFINES,[
 676                         AC_EGREP_CPP(yes, [
 677                         #include <sys/types.h>
 678                         #include <sys/socket.h>
 679                         #include <netdb.h>
 680                         #ifdef AI_PASSIVE
 681                         yes
 682                         #endif],
 683                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 684                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 685 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 686         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 687         # something else so we must include <netdb.h> to get the
 688         # redefinition.
 689         AC_CHECK_FUNCS(getaddrinfo, ,
 690                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 691                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 692                 #include <sys/socket.h>
 693                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 694                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 695                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 696                         AC_LIBOBJ([getaddrinfo])])])
 697     ],[AC_LIBOBJ([getaddrinfo])])
 698
 699 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 700                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 701                 [],
 702                 [
 703 #include <sys/types.h>
 704 #include <sys/socket.h>
 705 ])
 706
 707 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 708                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 709                 [],
 710                 [
 711 #include <sys/types.h>
 712 #include <sys/socket.h>
 713 #include <netinet/in.h>
 714 ])
 715
 716 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 717                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 718                 [],
 719                 [
 720 #include <sys/types.h>
 721 #include <sys/socket.h>
 722 #include <netinet/in.h>
 723 ])
 724
 725 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 726                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 727                 [],
 728                 [
 729 #include <sys/types.h>
 730 #include <sys/socket.h>
 731 #include <netinet/in.h>
 732 ])
 733
 734 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 735 #if HAVE_SYS_TYPES_H
 736 # include <sys/types.h>
 737 #endif
 738 #if HAVE_SYS_STAT_H
 739 # include <sys/stat.h>
 740 #endif
 741 #if STDC_HEADERS
 742 # include <stdlib.h>
 743 # include <stddef.h>
 744 #else
 745 # if HAVE_STDLIB_H
 746 #  include <stdlib.h>
 747 # endif
 748 #endif
 749 ])
 750
 751 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 752 #
 753 AC_CHECK_FUNCS(strcasecmp)
 754 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 755     AC_CHECK_LIB(resolv, strcasecmp)
 756 fi
 757
 758 AC_CHECK_FUNCS(aclsort)
 759 if test x"$ac_cv_func_aclsort" = x"no"; then
 760     AC_CHECK_LIB(sec, aclsort)
 761 fi
 762
 763 dnl At the moment we don't test for a broken memcmp(), because all we
 764 dnl need to do is test for equality, not comparison, and it seems that
 765 dnl every platform has a memcmp that can do at least that.
 766 dnl AC_FUNC_MEMCMP
 767
 768 AC_FUNC_UTIME_NULL
 769 AC_FUNC_ALLOCA
 770 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 771     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 772     chflags getattrlist \
 773     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 774     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 775     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 776     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 777     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 778     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep)
 779
 780 dnl cygwin iconv.h defines iconv_open as libiconv_open
 781 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 782     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 783 fi
 784
 785 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 786
 787 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 788 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 789 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 790 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 791     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 792 fi
 793
 794 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 795 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 796         #define _GNU_SOURCE 1
 797         #include <linux/falloc.h>
 798         #ifndef FALLOC_FL_PUNCH_HOLE
 799         #error FALLOC_FL_PUNCH_HOLE is missing
 800         #endif
 801     ]])], [
 802         AC_MSG_RESULT([yes])
 803         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 804     ], [
 805         AC_MSG_RESULT([no])
 806     ]
 807 )
 808
 809 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 810 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 811         #define _GNU_SOURCE 1
 812         #include <linux/falloc.h>
 813         #ifndef FALLOC_FL_ZERO_RANGE
 814         #error FALLOC_FL_ZERO_RANGE is missing
 815         #endif
 816     ]])], [
 817         AC_MSG_RESULT([yes])
 818         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 819     ], [
 820         AC_MSG_RESULT([no])
 821     ]
 822 )
 823
 824 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 825 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 826 #include <unistd.h>
 827 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 828 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 829     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 830 fi
 831
 832 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 833     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 834     case $host_os in
 835     *cygwin*)
 836         AC_MSG_RESULT(yes)
 837         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 838                   [Define if posix_fallocate is efficient (Cygwin)])
 839         ;;
 840     *)
 841         AC_MSG_RESULT(no)
 842         ;;
 843     esac
 844 fi
 845
 846 dnl End of preallocation stuff
 847
 848 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 849 if test $ac_cv_func_getpgrp = yes; then
 850     AC_FUNC_GETPGRP
 851 fi
 852
 853 AC_ARG_ENABLE(iconv-open,
 854     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 855     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 856
 857 if test x"$enable_iconv_open" != x"no"; then
 858     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 859 fi
 860
 861 AC_ARG_ENABLE(iconv,
 862     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 863     [], [enable_iconv=$enable_iconv_open])
 864 AH_TEMPLATE([ICONV_OPTION],
 865 [Define if you want the --iconv option.  Specifying a value will set the
 866 default iconv setting (a NULL means no --iconv processing by default).])
 867 if test x"$enable_iconv" != x"no"; then
 868         if test x"$enable_iconv" = x"yes"; then
 869                 AC_DEFINE(ICONV_OPTION, NULL)
 870         else
 871                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 872         fi
 873         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 874 fi
 875
 876 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 877   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 878 #if HAVE_UNISTD_H
 879 # include <unistd.h>
 880 #endif
 881 #include <stdlib.h>
 882 #include <errno.h>
 883 int main(void) {
 884         char const *dangling_symlink = "conftest.dangle";
 885         unlink(dangling_symlink);
 886         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 887         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 888         return 0;
 889     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 890 if test $rsync_cv_chown_modifies_symlink = yes; then
 891   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 892 fi
 893
 894 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 895   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 896 #if HAVE_UNISTD_H
 897 # include <unistd.h>
 898 #endif
 899 #include <stdlib.h>
 900 #include <errno.h>
 901 #define FILENAME "conftest.dangle"
 902 int main(void) {
 903         unlink(FILENAME);
 904         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 905         unlink(FILENAME "2");
 906         if (link(FILENAME, FILENAME "2") < 0) return 1;
 907         return 0;
 908     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 909 if test $rsync_cv_can_hardlink_symlink = yes; then
 910   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 911 fi
 912
 913 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 914   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 915 #if HAVE_UNISTD_H
 916 # include <unistd.h>
 917 #endif
 918 #ifdef HAVE_SYS_STAT_H
 919 #include <sys/stat.h>
 920 #endif
 921 #include <stdlib.h>
 922 #include <errno.h>
 923 #define FILENAME "conftest.fifi"
 924 int main(void) {
 925         unlink(FILENAME);
 926         if (mkfifo(FILENAME, 0777) < 0) abort();
 927         unlink(FILENAME "2");
 928         if (link(FILENAME, FILENAME "2") < 0) return 1;
 929         return 0;
 930     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 931 if test $rsync_cv_can_hardlink_special = yes; then
 932     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 933 fi
 934
 935 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 936 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 937 #include <sys/types.h>
 938 #include <sys/socket.h>
 939
 940 int main(void) {
 941        int fd[2];
 942        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
 943 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 944 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 945     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 946 fi
 947
 948 AC_REPLACE_FUNCS([getpass])
 949
 950 if test x"$with_included_popt" != x"yes"; then
 951     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 952 fi
 953 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 954     # If the system has /usr/include/popt/popt.h, we enable the
 955     # included popt because an attempt to "#include <popt/popt.h>"
 956     # would use our included header file anyway (due to -I.), and
 957     # might conflict with the system popt.
 958     with_included_popt=yes
 959 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 960     with_included_popt=yes
 961 fi
 962
 963 AC_MSG_CHECKING([whether to use included libpopt])
 964 if test x"$with_included_popt" = x"yes"; then
 965     AC_MSG_RESULT($srcdir/popt)
 966     BUILD_POPT='$(popt_OBJS)'
 967     CFLAGS="-I$srcdir/popt $CFLAGS"
 968     if test x"$ALLOCA" != x
 969     then
 970         # this can be removed when/if we add an included alloca.c;
 971         #  see autoconf documentation on AC_FUNC_ALLOCA
 972         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 973     fi
 974 else
 975     AC_MSG_RESULT(no)
 976 fi
 977
 978 # We default to using our zlib unless --with-included-zlib=no is given.
 979 if test x"$with_included_zlib" != x"no"; then
 980     with_included_zlib=yes
 981 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
 982     with_included_zlib=yes
 983 fi
 984 if test x"$with_included_zlib" != x"yes"; then
 985     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
 986 fi
 987
 988 AC_MSG_CHECKING([whether to use included zlib])
 989 if test x"$with_included_zlib" = x"yes"; then
 990     AC_MSG_RESULT($srcdir/zlib)
 991     BUILD_ZLIB='$(zlib_OBJS)'
 992     CFLAGS="-I$srcdir/zlib $CFLAGS"
 993 else
 994     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
 995     AC_MSG_RESULT(no)
 996 fi
 997
 998 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 999 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
1000 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
1001     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
1002 fi
1003
1004 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
1005 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
1006 #include <dirent.h>
1007 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
1008 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
1009 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
1010 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
1011     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
1012 fi
1013
1014 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
1015 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1016 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
1017 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
1018     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
1019 fi
1020
1021 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1022 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1023 #include <unistd.h>]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1024 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1025     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1026 fi
1027
1028 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1029 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1030 #include <sys/types.h>
1031 #include <stdarg.h>
1032 #include <stdio.h>
1033 #include <stdlib.h>
1034 #include <string.h>
1035 void foo(const char *format, ...) {
1036        va_list ap;
1037        int len;
1038        static char buf[] = "12345678901234567890";
1039
1040        va_start(ap, format);
1041        len = vsnprintf(0, 0, format, ap);
1042        va_end(ap);
1043        if (len != 5) exit(1);
1044
1045        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1046 }
1047 int main(void) { foo("hello"); return 0; }
1048 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1049 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1050     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1051 fi
1052
1053
1054 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1055 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1056 #include <sys/types.h>
1057 #include <sys/stat.h>
1058 #include <unistd.h>
1059 int main(void) {
1060   struct stat st;
1061   char tpl[20]="/tmp/test.XXXXXX";
1062   int fd = mkstemp(tpl);
1063   if (fd == -1) return 1;
1064   unlink(tpl);
1065   if (fstat(fd, &st) != 0) return 1;
1066   if ((st.st_mode & 0777) != 0600) return 1;
1067   return 0;
1068 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1069 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1070     case $host_os in
1071     hpux*)
1072         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1073         dnl so we noisily skip using it.  See HP change request JAGaf34426
1074         dnl for details. (sbonds)
1075         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1076         ;;
1077     *)
1078         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1079         ;;
1080     esac
1081 fi
1082
1083
1084 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1085 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1086 #include <stdio.h>
1087 #include <sys/stat.h>
1088 #include <errno.h>
1089 #if HAVE_UNISTD_H
1090 # include <unistd.h>
1091 #endif
1092 int main(void) { int rc, ec; char *fn = "fifo-test";
1093 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1094 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1095 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1096 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1097     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1098 fi
1099
1100 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1101 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1102 #include <stdio.h>
1103 #include <sys/stat.h>
1104 #include <errno.h>
1105 #if HAVE_UNISTD_H
1106 # include <unistd.h>
1107 #endif
1108 int main(void) { int rc, ec; char *fn = "sock-test";
1109 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1110 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1111 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1112 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1113     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1114 fi
1115
1116 #
1117 # The following test was mostly taken from the tcl/tk plus patches
1118 #
1119 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1120 rm -rf conftest*
1121 cat > conftest.$ac_ext <<EOF
1122 int main(void) { return 0; }
1123 EOF
1124 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1125 if test -f conftest..o; then
1126     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1127 else
1128     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1129 fi
1130 rm -rf conftest*
1131 ])
1132 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1133     OBJ_SAVE="#"
1134     OBJ_RESTORE="#"
1135     CC_SHOBJ_FLAG='-o $@'
1136 else
1137     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1138     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1139     CC_SHOBJ_FLAG=""
1140 fi
1141
1142 AC_SUBST(OBJ_SAVE)
1143 AC_SUBST(OBJ_RESTORE)
1144 AC_SUBST(CC_SHOBJ_FLAG)
1145 AC_SUBST(BUILD_POPT)
1146 AC_SUBST(BUILD_ZLIB)
1147 AC_SUBST(MAKE_MAN)
1148
1149 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1150 #################################################
1151 # check for ACL support
1152
1153 AC_MSG_CHECKING([whether to support ACLs])
1154 AC_ARG_ENABLE(acl-support,
1155         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
1156
1157 if test x"$enable_acl_support" = x"no"; then
1158     AC_MSG_RESULT(no)
1159 else
1160     case "$host_os" in
1161     *sysv5*)
1162         AC_MSG_RESULT(Using UnixWare ACLs)
1163         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1164         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1165         ;;
1166     solaris*)
1167         AC_MSG_RESULT(Using solaris ACLs)
1168         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1169         AC_DEFINE(SUPPORT_ACLS, 1)
1170         ;;
1171     *hpux*)
1172         AC_MSG_RESULT(Using HPUX ACLs)
1173         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1174         AC_DEFINE(SUPPORT_ACLS, 1)
1175         ;;
1176     *irix*)
1177         AC_MSG_RESULT(Using IRIX ACLs)
1178         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1179         AC_DEFINE(SUPPORT_ACLS, 1)
1180         ;;
1181     *aix*)
1182         AC_MSG_RESULT(Using AIX ACLs)
1183         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1184         AC_DEFINE(SUPPORT_ACLS, 1)
1185         ;;
1186     *osf*)
1187         AC_MSG_RESULT(Using Tru64 ACLs)
1188         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1189         AC_DEFINE(SUPPORT_ACLS, 1)
1190         LIBS="$LIBS -lpacl"
1191         ;;
1192     darwin*)
1193         AC_MSG_RESULT(Using OS X ACLs)
1194         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1195         AC_DEFINE(SUPPORT_ACLS, 1)
1196         ;;
1197     *)
1198         AC_MSG_RESULT(running tests:)
1199         AC_CHECK_LIB(acl,acl_get_file)
1200         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1201             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1202 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1203         AC_MSG_CHECKING(ACL test results)
1204         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1205             AC_MSG_RESULT(Using posix ACLs)
1206             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1207             AC_DEFINE(SUPPORT_ACLS, 1)
1208             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1209                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1210 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1211             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1212                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1213             fi
1214         else
1215             if test x"$enable_acl_support" = x"yes"; then
1216                 AC_MSG_ERROR(Failed to find ACL support)
1217             else
1218                 AC_MSG_RESULT(No ACL support found)
1219             fi
1220         fi
1221         ;;
1222     esac
1223 fi
1224
1225 #################################################
1226 # check for extended attribute support
1227 AC_MSG_CHECKING(whether to support extended attributes)
1228 AC_ARG_ENABLE(xattr-support,
1229     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1230     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1231         *yes*) enable_xattr_support=maybe ;;
1232         *) enable_xattr_support=no ;;
1233         esac])
1234 AH_TEMPLATE([SUPPORT_XATTRS],
1235 [Define to 1 to add support for extended attributes])
1236 if test x"$enable_xattr_support" = x"no"; then
1237     AC_MSG_RESULT(no)
1238 else
1239     case "$host_os" in
1240     *linux*|*netbsd*)
1241         AC_MSG_RESULT(Using Linux xattrs)
1242         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1243         AC_DEFINE(SUPPORT_XATTRS, 1)
1244         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1245         AC_CHECK_LIB(attr,getxattr)
1246         ;;
1247     darwin*)
1248         AC_MSG_RESULT(Using OS X xattrs)
1249         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1250         AC_DEFINE(SUPPORT_XATTRS, 1)
1251         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1252         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1253         ;;
1254     freebsd*)
1255         AC_MSG_RESULT(Using FreeBSD extattrs)
1256         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1257         AC_DEFINE(SUPPORT_XATTRS, 1)
1258         ;;
1259     solaris*)
1260         AC_MSG_RESULT(Using Solaris xattrs)
1261         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1262         AC_DEFINE(SUPPORT_XATTRS, 1)
1263         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1264         ;;
1265     *)
1266         if test x"$enable_xattr_support" = x"yes"; then
1267             AC_MSG_ERROR(Failed to find extended attribute support)
1268         else
1269             AC_MSG_RESULT(No extended attribute support found)
1270         fi
1271         ;;
1272     esac
1273 fi
1274
1275 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1276     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1277     OLD_CFLAGS="$CFLAGS"
1278     CFLAGS="$CFLAGS -Wno-unused-parameter"
1279     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1280     AC_MSG_RESULT([$rsync_warn_flag])
1281     if test x"$rsync_warn_flag" = x"no"; then
1282         CFLAGS="$OLD_CFLAGS"
1283     fi
1284 fi
1285
1286 case "$CC" in
1287 ' checker'*|checker*)
1288     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1289     ;;
1290 esac
1291
1292 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1293 AC_OUTPUT
1294
1295 AC_MSG_RESULT()
1296 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1297 AC_MSG_RESULT()