configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[ ],[https://rsync.samba.org/bug-tracking.html])
   4
   5 AC_C_BIGENDIAN
   6 AC_HEADER_DIRENT
   7 AC_HEADER_TIME
   8 AC_HEADER_SYS_WAIT
   9 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
  10     unistd.h utime.h compat.h sys/param.h ctype.h sys/wait.h sys/stat.h \
  11     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h grp.h \
  12     sys/un.h sys/attr.h arpa/inet.h arpa/nameser.h locale.h sys/types.h \
  13     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h mcheck.h \
  14     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h dl.h \
  15     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netgroup.h \
  16     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h sys/file.h)
  17 AC_CHECK_HEADERS([netinet/ip.h], [], [], [[#include <netinet/in.h>]])
  18 AC_HEADER_MAJOR_FIXED
  19
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_SRCDIR([byteorder.h])
  22 AC_CONFIG_HEADER(config.h)
  23 AC_PREREQ([2.69])
  24
  25 PACKAGE_VERSION=`sed 's/.*"\(.*\)".*/\1/' <$srcdir/version.h`
  26
  27 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  28
  29 LDFLAGS=${LDFLAGS-""}
  30
  31 AC_CANONICAL_HOST
  32
  33 dnl define the directory for replacement function since AC_LIBOBJ does not
  34 dnl officially support subdirs and fails with automake
  35 AC_CONFIG_LIBOBJ_DIR([lib])
  36
  37 # We must decide this before testing the compiler.
  38
  39 # Please allow this to default to yes, so that your users have more
  40 # chance of getting a useful stack trace if problems occur.
  41
  42 AC_MSG_CHECKING([whether to include debugging symbols])
  43 AC_ARG_ENABLE(debug,
  44         AS_HELP_STRING([--disable-debug],[disable to omit debugging symbols and features]))
  45
  46 if test x"$enable_debug" = x"no"; then
  47     AC_MSG_RESULT(no)
  48     ac_cv_prog_cc_g=no
  49 else
  50     AC_MSG_RESULT([yes])
  51     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  52     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  53 fi
  54
  55 dnl Checks for programs.
  56 AC_PROG_CC
  57 AC_PROG_CPP
  58 AC_PROG_CXX
  59 AC_PROG_AWK
  60 AC_PROG_EGREP
  61 AC_PROG_INSTALL
  62 AC_PROG_MKDIR_P
  63 AC_PROG_CC_STDC
  64 AC_SUBST(SHELL)
  65 AC_PATH_PROG([PERL], [perl])
  66 AC_PATH_PROG([PYTHON3], [python3])
  67
  68 AC_DEFINE([_GNU_SOURCE], 1,
  69           [Define _GNU_SOURCE so that we get all necessary prototypes])
  70
  71 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  72         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  73 fi
  74
  75 no_lib=''
  76 err_msg=''
  77 nl='
  78 '
  79
  80 AC_ARG_ENABLE(profile,
  81         AS_HELP_STRING([--enable-profile],[enable to turn on CPU profiling]))
  82 if test x"$enable_profile" = x"yes"; then
  83         CFLAGS="$CFLAGS -pg"
  84 fi
  85
  86 AC_MSG_CHECKING([if md2man can create man pages])
  87 if test x"$ac_cv_path_PYTHON3" = x; then
  88     AC_MSG_RESULT(no - python3 not found)
  89     md2man_works=no
  90 else
  91     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync-ssl.1.md" 2>&1`
  92     if test $? = 0; then
  93         AC_MSG_RESULT(yes)
  94         md2man_works=yes
  95     else
  96         AC_MSG_RESULT(no)
  97         md2man_works=no
  98         echo "$md2man_out"
  99     fi
 100 fi
 101
 102 AC_MSG_CHECKING([if we require man-page building])
 103 AC_ARG_ENABLE([md2man],
 104         AS_HELP_STRING([--disable-md2man],[disable to omit man page creation]))
 105 if test x"$enable_md2man" != x"no"; then
 106     if test -f "$srcdir/rsync.1"; then
 107         AC_MSG_RESULT(optional)
 108     else
 109         AC_MSG_RESULT(required)
 110         if test x"$md2man_works" = x"no"; then
 111             err_msg="$err_msg$nl- You need python3 and either the cmarkgfm OR commonmark python3 lib in order"
 112             err_msg="$err_msg$nl  to build man pages based on the git source (man pages are included in the"
 113             err_msg="$err_msg$nl  official release tar files)."
 114             no_lib="$no_lib md2man"
 115         fi
 116     fi
 117     MAKE_MAN=man
 118 else
 119     AC_MSG_RESULT(no)
 120 fi
 121
 122 # Specifically, this turns on panic_action handling.
 123 AC_ARG_ENABLE(maintainer-mode,
 124         AS_HELP_STRING([--enable-maintainer-mode],[enable to turn on extra debug features]))
 125 if test x"$enable_maintainer_mode" = x"yes"; then
 126         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 127 fi
 128
 129 # This is needed for our included version of popt.  Kind of silly, but
 130 # I don't want our version too far out of sync.
 131 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 132
 133 # If GCC, turn on warnings.
 134 if test x"$GCC" = x"yes"; then
 135         CFLAGS="$CFLAGS -Wall -W"
 136 fi
 137
 138 AC_ARG_WITH(rrsync,
 139         AS_HELP_STRING([--with-rrsync],[also install the rrsync script and its man page]))
 140 if test x"$with_rrsync" != x"yes"; then
 141     with_rrsync=no
 142 else
 143     MAKE_RRSYNC='rrsync'
 144     MAKE_RRSYNC_1='rrsync.1'
 145 fi
 146 AC_SUBST(with_rrsync)
 147
 148 AC_ARG_WITH(included-popt,
 149         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 150
 151 AC_ARG_WITH(included-zlib,
 152         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 153
 154 AC_ARG_WITH(protected-args,
 155         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
 156 if test x"$with_protected_args" = x"yes"; then
 157         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
 158 fi
 159
 160 AC_ARG_WITH(rsync-path,
 161         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 162         [ RSYNC_PATH="$with_rsync_path" ],
 163         [ RSYNC_PATH="rsync" ])
 164
 165 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 166
 167 AC_ARG_WITH(rsyncd-conf,
 168         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 169         [ if test ! -z "$with_rsyncd_conf" ; then
 170                 case $with_rsyncd_conf in
 171                         yes|no)
 172                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 173                                 ;;
 174                         /*)
 175                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 176                                 ;;
 177                         *)
 178                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 179                                 ;;
 180                 esac
 181         else
 182                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 183         fi ],
 184         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 185
 186 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 187
 188 AC_ARG_WITH(rsh,
 189         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 190
 191 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 192 if test x$HAVE_REMSH = x1; then
 193         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 194 fi
 195
 196 if test x"$with_rsh" != x; then
 197         RSYNC_RSH="$with_rsh"
 198 else
 199         RSYNC_RSH="ssh"
 200 fi
 201 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 202
 203 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 204 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 205 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 206
 207 AC_ARG_WITH(nobody-user,
 208     AS_HELP_STRING([--with-nobody-user=USER],[set the default unprivileged user (default nobody)]),
 209     [ NOBODY_USER="$with_nobody_user" ],
 210     [ NOBODY_USER="nobody" ])
 211
 212 AC_ARG_WITH(nobody-group,
 213     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 214     [ NOBODY_GROUP="$with_nobody_group" ])
 215
 216 if test x"$with_nobody_group" = x; then
 217     AC_MSG_CHECKING([the group for user "nobody"])
 218     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 219         NOBODY_GROUP=nobody
 220     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 221         NOBODY_GROUP=nogroup
 222     else
 223         NOBODY_GROUP=nobody # test for others?
 224     fi
 225     AC_MSG_RESULT($NOBODY_GROUP)
 226 fi
 227
 228 AC_DEFINE_UNQUOTED(NOBODY_USER, "$NOBODY_USER", [unprivileged user--e.g. nobody])
 229 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 230
 231 # SIMD optimizations
 232 SIMD=
 233
 234 AC_MSG_CHECKING([whether to enable SIMD optimizations])
 235 AC_ARG_ENABLE(simd,
 236     AS_HELP_STRING([--enable-simd],[enable/disable to control SIMD optimizations (requires c++)]))
 237
 238 # Clag is crashing with -g -O2, so we'll get rid of -g for now.
 239 CXXFLAGS=`echo "$CXXFLAGS" | sed 's/-g //'`
 240 m4_define(SIMD_X86_64_TEST, [[#include <stdio.h>
 241 #if HAVE_STDLIB_H
 242 #include <stdlib.h>
 243 #endif
 244 #include <immintrin.h>
 245 __attribute__ ((target("default"))) int test_ssse3(int x) { return x; }
 246 __attribute__ ((target("default"))) int test_sse2(int x) { return x; }
 247 __attribute__ ((target("default"))) int test_avx2(int x) { return x; }
 248 __attribute__ ((target("ssse3"))) int test_ssse3(int x) { return x; }
 249 __attribute__ ((target("sse2"))) int test_sse2(int x) { return x; }
 250 __attribute__ ((target("avx2"))) int test_avx2(int x) { return x; }
 251 typedef long long __m128i_u __attribute__((__vector_size__(16), __may_alias__, __aligned__(1)));
 252 typedef long long __m256i_u __attribute__((__vector_size__(32), __may_alias__, __aligned__(1)));
 253 __attribute__ ((target("default"))) void more_testing(char* buf, int len) { }
 254 __attribute__ ((target("ssse3"))) void more_testing(char* buf, int len)
 255 {
 256     int i;
 257     for (i = 0; i < (len-32); i+=32) {
 258         __m128i in8_1, in8_2;
 259         in8_1 = _mm_lddqu_si128((__m128i_u*)&buf[i]);
 260         in8_2 = _mm_lddqu_si128((__m128i_u*)&buf[i + 16]);
 261     }
 262 }
 263 ]])
 264
 265 if test x"$enable_simd" = x""; then
 266     case "$host_os" in
 267         *linux*) ;;
 268         *) enable_simd=no ;;
 269     esac
 270 fi
 271
 272 if test x"$enable_simd" != x"no"; then
 273     # For x86-64 SIMD, g++ >=5 or clang++ >=7 is required
 274     if test x"$host_cpu" = x"x86_64" || test x"$host_cpu" = x"amd64"; then
 275         AC_LANG(C++)
 276         if test x"$host" = x"$build"; then
 277             AC_RUN_IFELSE([AC_LANG_PROGRAM([SIMD_X86_64_TEST],[[if (test_ssse3(42) != 42 || test_sse2(42) != 42 || test_avx2(42) != 42) exit(1);]])],
 278                 [CXX_OK=yes],[CXX_OK=no])
 279         else
 280             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([SIMD_X86_64_TEST])],[CXX_OK=yes],[CXX_OK=no])
 281         fi
 282         AC_LANG(C)
 283         if test x"$CXX_OK" = x"yes"; then
 284             # AC_MSG_RESULT() is called below.
 285             SIMD="$host_cpu"
 286         elif test x"$enable_simd" = x"yes"; then
 287             AC_MSG_RESULT(error)
 288             AC_MSG_ERROR(The SIMD compilation test failed.
 289 Omit --enable-simd to continue without it.)
 290         fi
 291     elif test x"$enable_simd" = x"yes"; then
 292         AC_MSG_RESULT(unavailable)
 293         AC_MSG_ERROR(The SIMD optimizations are currently x86_64|amd64 only.
 294 Omit --enable-simd to continue without it.)
 295     fi
 296 fi
 297
 298 if test x"$SIMD" != x""; then
 299     AC_MSG_RESULT([yes ($SIMD)])
 300     AC_DEFINE(HAVE_SIMD, 1, [Define to 1 to enable SIMD optimizations])
 301     SIMD='$(SIMD_'"$SIMD)"
 302     # We only use c++ for its target attribute dispatching, disable unneeded bulky features
 303     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 304     # Apple often has "g++" as a symlink for clang. Try to find out the truth.
 305     CXX_VERSION=`$CXX --version 2>/dev/null | head -n 2`
 306     case "$CXX_VERSION" in
 307     *clang*) CXXFLAGS="$CXXFLAGS -fno-slp-vectorize" ;; # avoid a performance hit
 308     esac
 309 else
 310     AC_MSG_RESULT(no)
 311 fi
 312
 313 AC_SUBST(SIMD)
 314
 315 AC_MSG_CHECKING([if assembler accepts noexecstack])
 316 OLD_CFLAGS="$CFLAGS"
 317 CFLAGS="$CFLAGS -Wa,--noexecstack"
 318 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ ]], [[return 0;]])],
 319 [ NOEXECSTACK='-Wa,--noexecstack' ; AC_MSG_RESULT(yes) ],
 320 [ NOEXECSTACK='' ; AC_MSG_RESULT(no) ])
 321 CFLAGS="$OLD_CFLAGS"
 322 AC_SUBST(NOEXECSTACK)
 323
 324 ASM=
 325
 326 AC_MSG_CHECKING([whether to enable ASM optimizations])
 327 AC_ARG_ENABLE(asm,
 328     AS_HELP_STRING([--enable-asm],[enable/disable to control ASM optimizations]))
 329
 330 if test x"$enable_asm" = x""; then
 331     case "$host_os" in
 332         *linux*) ;;
 333         *) enable_asm=no ;;
 334     esac
 335 fi
 336
 337 if test x"$enable_asm" != x"no"; then
 338     if test x"$host_cpu" = x"x86_64" || test x"$host_cpu" = x"amd64"; then
 339         ASM="$host_cpu"
 340     elif test x"$enable_asm" = x"yes"; then
 341         AC_MSG_RESULT(unavailable)
 342         AC_MSG_ERROR(The ASM optimizations are currently x86_64|amd64 only.
 343 Omit --enable-asm to continue without it.)
 344     fi
 345 fi
 346
 347 if test x"$ASM" != x""; then
 348     AC_MSG_RESULT([yes ($ASM)])
 349     AC_DEFINE(HAVE_ASM, 1, [Define to 1 to enable ASM optimizations])
 350     ASM='$(ASM_'"$ASM)"
 351 else
 352     AC_MSG_RESULT(no)
 353 fi
 354
 355 AC_SUBST(ASM)
 356
 357 # arrgh. libc in some old debian version screwed up the largefile
 358 # stuff, getting byte range locking wrong
 359 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 360 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 361 #define _FILE_OFFSET_BITS 64
 362 #include <stdio.h>
 363 #include <fcntl.h>
 364 #ifdef HAVE_SYS_TYPES_H
 365 #include <sys/types.h>
 366 #endif
 367 #include <sys/wait.h>
 368 #if HAVE_UNISTD_H
 369 #include <unistd.h>
 370 #endif
 371
 372 int main(void)
 373 {
 374         struct flock lock;
 375         int status;
 376         char tpl[32] = "/tmp/locktest.XXXXXX";
 377         int fd = mkstemp(tpl);
 378         if (fd < 0) {
 379                 strcpy(tpl, "conftest.dat");
 380                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 381         }
 382
 383         lock.l_type = F_WRLCK;
 384         lock.l_whence = SEEK_SET;
 385         lock.l_start = 0;
 386         lock.l_len = 1;
 387         lock.l_pid = 0;
 388         fcntl(fd,F_SETLK,&lock);
 389         if (fork() == 0) {
 390                 lock.l_start = 1;
 391                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 392         }
 393         wait(&status);
 394         unlink(tpl);
 395         return WEXITSTATUS(status);
 396 }
 397 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 398 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 399    AC_SYS_LARGEFILE
 400 fi
 401
 402 AC_MSG_CHECKING([whether to enable ipv6])
 403 AC_ARG_ENABLE(ipv6,
 404 AS_HELP_STRING([--disable-ipv6],[disable to omit ipv6 support]),
 405 [ case "$enableval" in
 406   no)
 407         AC_MSG_RESULT(no)
 408         ;;
 409   *)    AC_MSG_RESULT(yes)
 410         AC_DEFINE(INET6, 1, [true if you have IPv6])
 411         ;;
 412   esac ],
 413
 414   AC_TRY_RUN([ /* AF_INET6 avalable check */
 415 #include <stdlib.h>
 416 #include <sys/types.h>
 417 #include <sys/socket.h>
 418 main()
 419 {
 420    if (socket(AF_INET6, SOCK_STREAM, 0) < 0)
 421      exit(1);
 422    else
 423      exit(0);
 424 }
 425 ],
 426   AC_MSG_RESULT(yes)
 427   AC_DEFINE(INET6, 1, [true if you have IPv6]),
 428   AC_MSG_RESULT(no),
 429   AC_MSG_RESULT(no)
 430 ))
 431
 432 dnl Do you want to disable use of locale functions
 433 AC_ARG_ENABLE([locale],
 434         AS_HELP_STRING([--disable-locale],[disable to omit locale features]))
 435 AH_TEMPLATE([CONFIG_LOCALE],
 436 [Undefine if you do not want locale features.  By default this is defined.])
 437 if test x"$enable_locale" != x"no"; then
 438         AC_DEFINE(CONFIG_LOCALE)
 439 fi
 440
 441 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 442 case $host_os in
 443         *cygwin* ) AC_MSG_RESULT(yes)
 444                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 445                             [Define to 1 if sockets need to be shutdown])
 446                    ;;
 447                * ) AC_MSG_RESULT(no);;
 448 esac
 449
 450 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 451 AC_ARG_ENABLE([openssl],
 452         AS_HELP_STRING([--disable-openssl],[disable to omit openssl crypto library]))
 453 AH_TEMPLATE([USE_OPENSSL],
 454 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 455 if test x"$enable_openssl" != x"no"; then
 456     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 457       AC_MSG_RESULT(yes)
 458       AC_SEARCH_LIBS(MD5_Init, crypto,
 459           [AC_DEFINE(USE_OPENSSL)],
 460           [err_msg="$err_msg$nl- Failed to find MD5_Init function in openssl crypto lib.";
 461            no_lib="$no_lib openssl"])
 462     else
 463         AC_MSG_RESULT(no)
 464         err_msg="$err_msg$nl- Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support."
 465         no_lib="$no_lib openssl"
 466     fi
 467 else
 468     AC_MSG_RESULT(no)
 469 fi
 470
 471 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 472 AC_ARG_ENABLE([xxhash],
 473         AS_HELP_STRING([--disable-xxhash],[disable to omit xxhash checksums]))
 474 AH_TEMPLATE([SUPPORT_XXHASH],
 475 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 476 if test x"$enable_xxhash" != x"no"; then
 477     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 478         AC_MSG_RESULT(yes)
 479         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 480             [AC_DEFINE(SUPPORT_XXHASH)],
 481             [err_msg="$err_msg$nl- Failed to find XXH64_createState function in xxhash lib.";
 482              no_lib="$no_lib xxhash"])
 483     else
 484         AC_MSG_RESULT(no)
 485         err_msg="$err_msg$nl- Failed to find xxhash.h for xxhash checksum support.";
 486         no_lib="$no_lib xxhash"
 487     fi
 488 else
 489     AC_MSG_RESULT(no)
 490 fi
 491
 492 AC_MSG_CHECKING([whether to enable zstd compression])
 493 AC_ARG_ENABLE([zstd],
 494         AC_HELP_STRING([--disable-zstd], [disable to omit zstd compression]))
 495 AH_TEMPLATE([SUPPORT_ZSTD],
 496 [Undefine if you do not want zstd compression.  By default this is defined.])
 497 if test x"$enable_zstd" != x"no"; then
 498     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 499         AC_MSG_RESULT(yes)
 500         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 501             [AC_DEFINE(SUPPORT_ZSTD)],
 502             [err_msg="$err_msg$nl- Failed to find ZSTD_minCLevel function in zstd lib.";
 503              no_lib="$no_lib zstd"])
 504     else
 505         AC_MSG_RESULT(no)
 506         err_msg="$err_msg$nl- Failed to find zstd.h for zstd compression support.";
 507         no_lib="$no_lib zstd"
 508     fi
 509 else
 510     AC_MSG_RESULT(no)
 511 fi
 512
 513 AC_MSG_CHECKING([whether to enable LZ4 compression])
 514 AC_ARG_ENABLE([lz4],
 515         AC_HELP_STRING([--disable-lz4], [disable to omit LZ4 compression]))
 516 AH_TEMPLATE([SUPPORT_LZ4],
 517 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 518 if test x"$enable_lz4" != x"no"; then
 519     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 520         AC_MSG_RESULT(yes)
 521         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 522             [AC_DEFINE(SUPPORT_LZ4)],
 523             [err_msg="$err_msg$nl- Failed to find LZ4_compress_default function in lz4 lib.";
 524              no_lib="$no_lib lz4"])
 525     else
 526         AC_MSG_RESULT(no)
 527         err_msg="$err_msg$nl- Failed to find lz4.h for lz4 compression support."
 528         no_lib="$no_lib lz4"
 529     fi
 530 else
 531     AC_MSG_RESULT(no)
 532 fi
 533
 534 if test x"$no_lib" != x; then
 535     echo ""
 536     echo "Configure found the following issues:"
 537     echo "$err_msg"
 538     echo ""
 539     echo "See the INSTALL file for hints on how to install the missing libraries and/or"
 540     echo "how to generate (or fetch) man pages:"
 541     echo "    https://github.com/WayneD/rsync/blob/master/INSTALL.md"
 542     echo ""
 543     echo "To disable one or more features, the relevant configure options are:"
 544     for lib in $no_lib; do
 545         echo "    --disable-$lib"
 546     done
 547     echo ""
 548     AC_MSG_ERROR(Aborting configure run)
 549 fi
 550
 551 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 552 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 553 #ifdef HAVE_SYS_TYPES_H
 554 #include <sys/types.h>
 555 #endif
 556 #ifdef MAJOR_IN_MKDEV
 557 #include <sys/mkdev.h>
 558 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 559 #  define makedev mkdev
 560 # endif
 561 #elif defined MAJOR_IN_SYSMACROS
 562 #include <sys/sysmacros.h>
 563 #endif
 564
 565 int main(void)
 566 {
 567         dev_t dev = makedev(0, 5, 7);
 568         if (major(dev) != 5 || minor(dev) != 7)
 569                 return 1;
 570         return 0;
 571 }
 572 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 573 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 574    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 575 fi
 576
 577 AC_CHECK_SIZEOF(int)
 578 AC_CHECK_SIZEOF(long)
 579 AC_CHECK_SIZEOF(long long)
 580 AC_CHECK_SIZEOF(short)
 581 AC_CHECK_SIZEOF(int16_t)
 582 AC_CHECK_SIZEOF(uint16_t)
 583 AC_CHECK_SIZEOF(int32_t)
 584 AC_CHECK_SIZEOF(uint32_t)
 585 AC_CHECK_SIZEOF(int64_t)
 586 AC_CHECK_SIZEOF(off_t)
 587 AC_CHECK_SIZEOF(off64_t)
 588 AC_CHECK_SIZEOF(time_t)
 589 AC_CHECK_SIZEOF(char*)
 590
 591 AC_C_INLINE
 592
 593 AC_TYPE_LONG_DOUBLE_WIDER
 594 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 595 if test $ac_cv_c_long_double = yes; then
 596   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 597 fi
 598
 599 AC_TYPE_UID_T
 600 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 601 AC_TYPE_GETGROUPS
 602 AC_CHECK_MEMBERS([struct stat.st_rdev,
 603                   struct stat.st_mtimensec,
 604                   struct stat.st_mtimespec.tv_nsec,
 605                   struct stat.st_mtim.tv_nsec],,,[
 606 #ifdef HAVE_SYS_TYPES_H
 607 #include <sys/types.h>
 608 #endif
 609 #ifdef HAVE_SYS_STAT_H
 610 #include <sys/stat.h>
 611 #endif
 612 #ifdef HAVE_UNISTD_H
 613 #include <unistd.h>
 614 #endif])
 615
 616 TYPE_SOCKLEN_T
 617
 618 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 619     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 620 if test x"$rsync_cv_errno" = x"yes"; then
 621    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 622 fi
 623
 624 # The following test taken from the cvs sources
 625 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 626 # These need checks to be before checks for any other functions that
 627 #    might be in the same libraries.
 628 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 629 # libsocket.so which has a bad implementation of gethostbyname (it
 630 # only looks in /etc/hosts), so we only look for -lsocket if we need
 631 # it.
 632 AC_CHECK_FUNCS(connect)
 633 if test x"$ac_cv_func_connect" = x"no"; then
 634     case "$LIBS" in
 635     *-lnsl*) ;;
 636     *) AC_CHECK_LIB(nsl_s, printf) ;;
 637     esac
 638     case "$LIBS" in
 639     *-lnsl*) ;;
 640     *) AC_CHECK_LIB(nsl, printf) ;;
 641     esac
 642     case "$LIBS" in
 643     *-lsocket*) ;;
 644     *) AC_CHECK_LIB(socket, connect) ;;
 645     esac
 646     case "$LIBS" in
 647     *-linet*) ;;
 648     *) AC_CHECK_LIB(inet, connect) ;;
 649     esac
 650     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 651     dnl has been cached.
 652     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 653        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 654         # ac_cv_func_connect=yes
 655         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 656         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 657     fi
 658 fi
 659
 660 AC_SEARCH_LIBS(inet_ntop, resolv)
 661
 662 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 663 # accept either iconv_open or libiconv_open, since some include files map
 664 # the former to the latter.
 665 AC_SEARCH_LIBS(iconv_open, iconv)
 666 AC_SEARCH_LIBS(libiconv_open, iconv)
 667
 668 AC_MSG_CHECKING([for iconv declaration])
 669 AC_CACHE_VAL(am_cv_proto_iconv, [
 670     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 671 #if HAVE_STDLIB_H
 672 #include <stdlib.h>
 673 #endif
 674 #include <iconv.h>
 675 extern
 676 #ifdef __cplusplus
 677 "C"
 678 #endif
 679 #if defined(__STDC__) || defined(__cplusplus)
 680 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 681 #else
 682 size_t iconv();
 683 #endif
 684 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 685       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 686     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed 's/( /(/'`
 687 AC_MSG_RESULT([$]{ac_t:-
 688          }[$]am_cv_proto_iconv)
 689 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 690                    [Define as const if the declaration of iconv() needs const.])
 691
 692 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 693
 694 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 695
 696 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 697 AC_HAVE_TYPE([struct sockaddr_storage], [
 698 #ifdef HAVE_SYS_TYPES_H
 699 #include <sys/types.h>
 700 #endif
 701 #ifdef HAVE_SYS_SOCKET_H
 702 #include <sys/socket.h>
 703 #endif])
 704
 705 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 706 #   builtin getaddrinfo if one of the defines don't exist
 707 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 708                rsync_cv_HAVE_GETADDR_DEFINES,[
 709                         AC_EGREP_CPP(yes, [
 710 #ifdef HAVE_SYS_TYPES_H
 711 #include <sys/types.h>
 712 #endif
 713 #ifdef HAVE_SYS_SOCKET_H
 714 #include <sys/socket.h>
 715 #endif
 716 #ifdef HAVE_NETDB_H
 717 #include <netdb.h>
 718 #endif
 719 #ifdef AI_PASSIVE
 720 yes
 721 #endif],
 722                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 723                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 724 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" && test x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 725         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 726         # something else so we must include <netdb.h> to get the
 727         # redefinition.
 728         AC_CHECK_FUNCS(getaddrinfo, ,
 729                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 730                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 731 #ifdef HAVE_SYS_TYPES_H
 732 #include <sys/types.h>
 733 #endif
 734 #ifdef HAVE_SYS_SOCKET_H
 735 #include <sys/socket.h>
 736 #endif
 737 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 738                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 739                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 740                         AC_LIBOBJ([getaddrinfo])])])
 741     ],[AC_LIBOBJ([getaddrinfo])])
 742
 743 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 744                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 745                 [],
 746                 [
 747 #ifdef HAVE_SYS_TYPES_H
 748 #include <sys/types.h>
 749 #endif
 750 #ifdef HAVE_SYS_SOCKET_H
 751 #include <sys/socket.h>
 752 #endif
 753 ])
 754
 755 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 756                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 757                 [],
 758                 [
 759 #ifdef HAVE_SYS_TYPES_H
 760 #include <sys/types.h>
 761 #endif
 762 #ifdef HAVE_SYS_SOCKET_H
 763 #include <sys/socket.h>
 764 #endif
 765 #include <netinet/in.h>
 766 ])
 767
 768 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 769                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 770                 [],
 771                 [
 772 #ifdef HAVE_SYS_TYPES_H
 773 #include <sys/types.h>
 774 #endif
 775 #ifdef HAVE_SYS_SOCKET_H
 776 #include <sys/socket.h>
 777 #endif
 778 #include <netinet/in.h>
 779 ])
 780
 781 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 782                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 783                 [],
 784                 [
 785 #ifdef HAVE_SYS_TYPES_H
 786 #include <sys/types.h>
 787 #endif
 788 #ifdef HAVE_SYS_SOCKET_H
 789 #include <sys/socket.h>
 790 #endif
 791 #include <netinet/in.h>
 792 ])
 793
 794 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 795 #if HAVE_SYS_TYPES_H
 796 # include <sys/types.h>
 797 #endif
 798 #if HAVE_SYS_STAT_H
 799 # include <sys/stat.h>
 800 #endif
 801 #if STDC_HEADERS
 802 # include <stdlib.h>
 803 # include <stddef.h>
 804 #else
 805 # if HAVE_STDLIB_H
 806 #  include <stdlib.h>
 807 # endif
 808 #endif
 809 ])
 810
 811 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 812 #
 813 AC_CHECK_FUNCS(strcasecmp)
 814 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 815     AC_CHECK_LIB(resolv, strcasecmp)
 816 fi
 817
 818 AC_CHECK_FUNCS(aclsort)
 819 if test x"$ac_cv_func_aclsort" = x"no"; then
 820     AC_CHECK_LIB(sec, aclsort)
 821 fi
 822
 823 dnl At the moment we don't test for a broken memcmp(), because all we
 824 dnl need to do is test for equality, not comparison, and it seems that
 825 dnl every platform has a memcmp that can do at least that.
 826 dnl AC_FUNC_MEMCMP
 827
 828 AC_FUNC_UTIME_NULL
 829 AC_FUNC_ALLOCA
 830 AC_CHECK_FUNCS(waitpid wait4 getcwd chown chmod lchmod mknod mkfifo \
 831     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 832     chflags getattrlist mktime innetgr linkat \
 833     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 834     strlcat strlcpy strtol mallinfo mallinfo2 getgroups setgroups geteuid getegid \
 835     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 836     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 837     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 838     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep \
 839     setenv unsetenv)
 840
 841 dnl cygwin iconv.h defines iconv_open as libiconv_open
 842 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 843     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 844 fi
 845
 846 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 847
 848 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 849 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 850 #ifdef HAVE_SYS_TYPES_H
 851 #include <sys/types.h>
 852 #endif]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 853 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 854     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 855 fi
 856
 857 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 858 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 859         #define _GNU_SOURCE 1
 860         #include <linux/falloc.h>
 861         #ifndef FALLOC_FL_PUNCH_HOLE
 862         #error FALLOC_FL_PUNCH_HOLE is missing
 863         #endif
 864     ]])], [
 865         AC_MSG_RESULT([yes])
 866         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 867     ], [
 868         AC_MSG_RESULT([no])
 869     ]
 870 )
 871
 872 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 873 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 874         #define _GNU_SOURCE 1
 875         #include <linux/falloc.h>
 876         #ifndef FALLOC_FL_ZERO_RANGE
 877         #error FALLOC_FL_ZERO_RANGE is missing
 878         #endif
 879     ]])], [
 880         AC_MSG_RESULT([yes])
 881         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 882     ], [
 883         AC_MSG_RESULT([no])
 884     ]
 885 )
 886
 887 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 888 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 889 #ifdef HAVE_UNISTD_H
 890 #include <unistd.h>
 891 #endif
 892 #ifdef HAVE_SYS_TYPES_H
 893 #include <sys/types.h>
 894 #endif]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 895 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 896     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 897 fi
 898
 899 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 900     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 901     case $host_os in
 902     *cygwin*)
 903         AC_MSG_RESULT(yes)
 904         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 905                   [Define if posix_fallocate is efficient (Cygwin)])
 906         ;;
 907     *)
 908         AC_MSG_RESULT(no)
 909         ;;
 910     esac
 911 fi
 912
 913 dnl End of preallocation stuff
 914
 915 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 916 if test $ac_cv_func_getpgrp = yes; then
 917     AC_FUNC_GETPGRP
 918 fi
 919
 920 AC_ARG_ENABLE(iconv-open,
 921     AS_HELP_STRING([--disable-iconv-open],[disable to avoid all use of iconv_open()]),
 922     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 923
 924 if test x"$enable_iconv_open" != x"no"; then
 925     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 926 fi
 927
 928 AC_ARG_ENABLE(iconv,
 929     AS_HELP_STRING([--disable-iconv],[disable to omit the --iconv option]),
 930     [], [enable_iconv=$enable_iconv_open])
 931 AH_TEMPLATE([ICONV_OPTION],
 932 [Define if you want the --iconv option.  Specifying a value will set the
 933 default iconv setting (a NULL means no --iconv processing by default).])
 934 if test x"$enable_iconv" != x"no"; then
 935         if test x"$enable_iconv" = x"yes"; then
 936                 AC_DEFINE(ICONV_OPTION, NULL)
 937         else
 938                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 939         fi
 940         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 941 fi
 942
 943 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 944   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 945 #if HAVE_UNISTD_H
 946 # include <unistd.h>
 947 #endif
 948 #include <stdlib.h>
 949 #include <errno.h>
 950 int main(void) {
 951         char const *dangling_symlink = "conftest.dangle";
 952         unlink(dangling_symlink);
 953         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 954         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 955         return 0;
 956     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 957 if test $rsync_cv_chown_modifies_symlink = yes; then
 958   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 959 fi
 960
 961 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 962   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 963 #ifdef HAVE_FCNTL_H
 964 # include <fcntl.h>
 965 #elif defined HAVE_SYS_FCNTL_H
 966 # include <sys/fcntl.h>
 967 #endif
 968 #if HAVE_UNISTD_H
 969 # include <unistd.h>
 970 #endif
 971 #include <stdlib.h>
 972 #include <errno.h>
 973 #define FILENAME "conftest.dangle"
 974 int main(void) {
 975         unlink(FILENAME);
 976         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 977         unlink(FILENAME "2");
 978 #ifdef HAVE_LINKAT
 979         if (linkat(AT_FDCWD, FILENAME, AT_FDCWD, FILENAME "2", 0) < 0) return 1;
 980 #else
 981         if (link(FILENAME, FILENAME "2") < 0) return 1;
 982 #endif
 983         return 0;
 984     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 985 if test $rsync_cv_can_hardlink_symlink = yes; then
 986   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 987 fi
 988
 989 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 990   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 991 #if HAVE_UNISTD_H
 992 # include <unistd.h>
 993 #endif
 994 #ifdef HAVE_SYS_STAT_H
 995 #include <sys/stat.h>
 996 #endif
 997 #include <stdlib.h>
 998 #include <errno.h>
 999 #define FILENAME "conftest.fifi"
1000 int main(void) {
1001         unlink(FILENAME);
1002         if (mkfifo(FILENAME, 0777) < 0) abort();
1003         unlink(FILENAME "2");
1004         if (link(FILENAME, FILENAME "2") < 0) return 1;
1005         return 0;
1006     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
1007 if test $rsync_cv_can_hardlink_special = yes; then
1008     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
1009 fi
1010
1011 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
1012 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1013 #ifdef HAVE_SYS_TYPES_H
1014 #include <sys/types.h>
1015 #endif
1016 #ifdef HAVE_SYS_SOCKET_H
1017 #include <sys/socket.h>
1018 #endif
1019
1020 int main(void) {
1021        int fd[2];
1022        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
1023 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
1024 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
1025     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
1026 fi
1027
1028 AC_REPLACE_FUNCS([getpass])
1029
1030 if test x"$with_included_popt" != x"yes"; then
1031     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
1032 fi
1033 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
1034     # If the system has /usr/include/popt/popt.h, we enable the
1035     # included popt because an attempt to "#include <popt/popt.h>"
1036     # would use our included header file anyway (due to -I.), and
1037     # might conflict with the system popt.
1038     with_included_popt=yes
1039 elif test x"$ac_cv_header_popt_h" != x"yes"; then
1040     with_included_popt=yes
1041 fi
1042
1043 if test x"$GCC" = x"yes"; then
1044     if test x"$with_included_popt" != x"yes"; then
1045         # Turn pedantic warnings into errors to ensure an array-init overflow is an error.
1046         CFLAGS="$CFLAGS -pedantic-errors"
1047     else
1048         # Our internal popt code cannot be compiled with pedantic warnings as errors, so try to
1049         # turn off pedantic warnings (which will not lose the error for array-init overflow).
1050         # Older gcc versions don't understand -Wno-pedantic, so check if --help=warnings lists
1051         # -Wpedantic and use that as a flag.
1052         case `$CC --help=warnings 2>/dev/null | grep Wpedantic` in
1053             *-Wpedantic*) CFLAGS="$CFLAGS -pedantic-errors -Wno-pedantic" ;;
1054         esac
1055     fi
1056 fi
1057
1058 AC_MSG_CHECKING([whether to use included libpopt])
1059 if test x"$with_included_popt" = x"yes"; then
1060     AC_MSG_RESULT($srcdir/popt)
1061     BUILD_POPT='$(popt_OBJS)'
1062     CFLAGS="-I$srcdir/popt $CFLAGS"
1063     if test x"$ALLOCA" != x
1064     then
1065         # this can be removed when/if we add an included alloca.c;
1066         #  see autoconf documentation on AC_FUNC_ALLOCA
1067         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
1068     fi
1069 else
1070     AC_MSG_RESULT(no)
1071 fi
1072
1073 # We default to using our zlib unless --with-included-zlib=no is given.
1074 if test x"$with_included_zlib" != x"no"; then
1075     with_included_zlib=yes
1076 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
1077     with_included_zlib=yes
1078 fi
1079 if test x"$with_included_zlib" != x"yes"; then
1080     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
1081 fi
1082
1083 AC_MSG_CHECKING([whether to use included zlib])
1084 if test x"$with_included_zlib" = x"yes"; then
1085     AC_MSG_RESULT($srcdir/zlib)
1086     BUILD_ZLIB='$(zlib_OBJS)'
1087     CFLAGS="-I$srcdir/zlib $CFLAGS"
1088 else
1089     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
1090     AC_MSG_RESULT(no)
1091 fi
1092
1093 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
1094 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
1095 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
1096     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
1097 fi
1098
1099 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
1100 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1101 #ifdef HAVE_SYS_TYPES_H
1102 #include <sys/types.h>
1103 #endif
1104 #include <dirent.h>
1105 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
1106 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
1107 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
1108 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
1109     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
1110 fi
1111
1112 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
1113 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1114 #ifdef HAVE_SYS_TYPES_H
1115 #include <sys/types.h>
1116 #endif
1117 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
1118 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
1119     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
1120 fi
1121
1122 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1123 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1124 #ifdef HAVE_UNISTD_H
1125 #include <unistd.h>
1126 #endif]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1127 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1128     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1129 fi
1130
1131 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1132 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1133 #ifdef HAVE_SYS_TYPES_H
1134 #include <sys/types.h>
1135 #endif
1136 #include <stdarg.h>
1137 #include <stdio.h>
1138 #if HAVE_STDLIB_H
1139 #include <stdlib.h>
1140 #endif
1141 #include <string.h>
1142 void foo(const char *format, ...) {
1143        va_list ap;
1144        int len;
1145        static char buf[] = "12345678901234567890";
1146
1147        va_start(ap, format);
1148        len = vsnprintf(0, 0, format, ap);
1149        va_end(ap);
1150        if (len != 5) exit(1);
1151
1152        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1153 }
1154 int main(void) { foo("hello"); return 0; }
1155 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1156 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1157     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1158 fi
1159
1160
1161 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1162 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1163 #ifdef HAVE_SYS_TYPES_H
1164 #include <sys/types.h>
1165 #endif
1166 #include <sys/stat.h>
1167 #ifdef HAVE_UNISTD_H
1168 #include <unistd.h>
1169 #endif
1170 int main(void) {
1171   struct stat st;
1172   char tpl[20]="/tmp/test.XXXXXX";
1173   int fd = mkstemp(tpl);
1174   if (fd == -1) return 1;
1175   unlink(tpl);
1176   if (fstat(fd, &st) != 0) return 1;
1177   if ((st.st_mode & 0777) != 0600) return 1;
1178   return 0;
1179 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1180 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1181     case $host_os in
1182     hpux*)
1183         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1184         dnl so we noisily skip using it.  See HP change request JAGaf34426
1185         dnl for details. (sbonds)
1186         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1187         ;;
1188     *)
1189         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1190         ;;
1191     esac
1192 fi
1193
1194
1195 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1196 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1197 #include <stdio.h>
1198 #include <sys/stat.h>
1199 #include <errno.h>
1200 #if HAVE_UNISTD_H
1201 # include <unistd.h>
1202 #endif
1203 int main(void) { int rc, ec; char *fn = "fifo-test";
1204 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1205 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1206 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1207 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1208     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1209 fi
1210
1211 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1212 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1213 #include <stdio.h>
1214 #include <sys/stat.h>
1215 #include <errno.h>
1216 #if HAVE_UNISTD_H
1217 # include <unistd.h>
1218 #endif
1219 int main(void) { int rc, ec; char *fn = "sock-test";
1220 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1221 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1222 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1223 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1224     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1225 fi
1226
1227 #
1228 # The following test was mostly taken from the tcl/tk plus patches
1229 #
1230 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1231 rm -rf conftest*
1232 cat > conftest.$ac_ext <<EOF
1233 int main(void) { return 0; }
1234 EOF
1235 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1236 if test -f conftest..o; then
1237     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1238 else
1239     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1240 fi
1241 rm -rf conftest*
1242 ])
1243 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1244     OBJ_SAVE="#"
1245     OBJ_RESTORE="#"
1246     CC_SHOBJ_FLAG='-o $@'
1247 else
1248     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1249     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1250     CC_SHOBJ_FLAG=""
1251 fi
1252
1253 AC_SUBST(OBJ_SAVE)
1254 AC_SUBST(OBJ_RESTORE)
1255 AC_SUBST(CC_SHOBJ_FLAG)
1256 AC_SUBST(BUILD_POPT)
1257 AC_SUBST(BUILD_ZLIB)
1258 AC_SUBST(MAKE_RRSYNC)
1259 AC_SUBST(MAKE_RRSYNC_1)
1260 AC_SUBST(MAKE_MAN)
1261
1262 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1263 #################################################
1264 # check for ACL support
1265
1266 AC_MSG_CHECKING([whether to support ACLs])
1267 AC_ARG_ENABLE(acl-support,
1268         AS_HELP_STRING([--disable-acl-support],[disable to omit ACL support]))
1269
1270 if test x"$enable_acl_support" = x"no"; then
1271     AC_MSG_RESULT(no)
1272 else
1273     case "$host_os" in
1274     *sysv5*)
1275         AC_MSG_RESULT(Using UnixWare ACLs)
1276         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1277         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1278         ;;
1279     solaris*)
1280         AC_MSG_RESULT(Using solaris ACLs)
1281         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1282         AC_DEFINE(SUPPORT_ACLS, 1)
1283         ;;
1284     *irix*)
1285         AC_MSG_RESULT(Using IRIX ACLs)
1286         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1287         AC_DEFINE(SUPPORT_ACLS, 1)
1288         ;;
1289     *aix*)
1290         AC_MSG_RESULT(Using AIX ACLs)
1291         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1292         AC_DEFINE(SUPPORT_ACLS, 1)
1293         ;;
1294     *osf*)
1295         AC_MSG_RESULT(Using Tru64 ACLs)
1296         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1297         AC_DEFINE(SUPPORT_ACLS, 1)
1298         LIBS="$LIBS -lpacl"
1299         ;;
1300     darwin*)
1301         AC_MSG_RESULT(Using OS X ACLs)
1302         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1303         AC_DEFINE(SUPPORT_ACLS, 1)
1304         ;;
1305     *hpux*|*nsk*)
1306         AC_MSG_RESULT(Using HPUX ACLs)
1307         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1308         AC_DEFINE(SUPPORT_ACLS, 1)
1309         ;;
1310     *)
1311         AC_MSG_RESULT(running tests:)
1312         AC_CHECK_LIB(acl,acl_get_file)
1313         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1314             AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1315 #ifdef HAVE_SYS_TYPES_H
1316 #include <sys/types.h>
1317 #endif
1318 #ifdef HAVE_SYS_ACL_H
1319 #include <sys/acl.h>
1320 #endif]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1321         AC_MSG_CHECKING(ACL test results)
1322         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1323             AC_MSG_RESULT(Using posix ACLs)
1324             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1325             AC_DEFINE(SUPPORT_ACLS, 1)
1326             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1327                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1328 #ifdef HAVE_SYS_TYPES_H
1329 #include <sys/types.h>
1330 #endif
1331 #ifdef HAVE_SYS_ACL_H
1332 #include <sys/acl.h>
1333 #endif]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1334             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1335                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1336             fi
1337         else
1338             if test x"$enable_acl_support" = x"yes"; then
1339                 AC_MSG_ERROR(Failed to find ACL support)
1340             else
1341                 AC_MSG_RESULT(No ACL support found)
1342             fi
1343         fi
1344         ;;
1345     esac
1346 fi
1347
1348 #################################################
1349 # check for extended attribute support
1350 AC_MSG_CHECKING(whether to support extended attributes)
1351 AC_ARG_ENABLE(xattr-support,
1352     AS_HELP_STRING([--disable-xattr-support],[disable to omit extended attributes]),
1353     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1354         *yes*) enable_xattr_support=maybe ;;
1355         *) enable_xattr_support=no ;;
1356         esac])
1357 AH_TEMPLATE([SUPPORT_XATTRS],
1358 [Define to 1 to add support for extended attributes])
1359 if test x"$enable_xattr_support" = x"no"; then
1360     AC_MSG_RESULT(no)
1361 else
1362     case "$host_os" in
1363     *linux*|*netbsd*|*cygwin*)
1364         AC_MSG_RESULT(Using Linux xattrs)
1365         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1366         AC_DEFINE(SUPPORT_XATTRS, 1)
1367         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1368         AC_CHECK_LIB(attr,getxattr)
1369         ;;
1370     darwin*)
1371         AC_MSG_RESULT(Using OS X xattrs)
1372         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1373         AC_DEFINE(SUPPORT_XATTRS, 1)
1374         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1375         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1376         ;;
1377     freebsd*)
1378         AC_MSG_RESULT(Using FreeBSD extattrs)
1379         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1380         AC_DEFINE(SUPPORT_XATTRS, 1)
1381         ;;
1382     solaris*)
1383         AC_MSG_RESULT(Using Solaris xattrs)
1384         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1385         AC_DEFINE(SUPPORT_XATTRS, 1)
1386         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1387         ;;
1388     *)
1389         if test x"$enable_xattr_support" = x"yes"; then
1390             AC_MSG_ERROR(Failed to find extended attribute support)
1391         else
1392             AC_MSG_RESULT(No extended attribute support found)
1393         fi
1394         ;;
1395     esac
1396 fi
1397
1398 if test x"$enable_acl_support" = x"no" || test x"$enable_xattr_support" = x"no" || test x"$enable_iconv" = x"no"; then
1399     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1400     OLD_CFLAGS="$CFLAGS"
1401     CFLAGS="$CFLAGS -Wno-unused-parameter"
1402     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1403     AC_MSG_RESULT([$rsync_warn_flag])
1404     if test x"$rsync_warn_flag" = x"no"; then
1405         CFLAGS="$OLD_CFLAGS"
1406     fi
1407 fi
1408
1409 case "$CC" in
1410 ' checker'*|checker*)
1411     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1412     ;;
1413 esac
1414
1415 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1416 AC_OUTPUT
1417
1418 AC_MSG_RESULT()
1419 AC_MSG_RESULT([    rsync $PACKAGE_VERSION configuration successful])
1420 AC_MSG_RESULT()