configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.2.0],[http://rsync.samba.org/bugzilla.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_CXX
  45 AC_PROG_AWK
  46 AC_PROG_EGREP
  47 AC_PROG_INSTALL
  48 AC_PROG_MKDIR_P
  49 AC_PROG_CC_STDC
  50 AC_SUBST(SHELL)
  51 AC_PATH_PROG([PERL], [perl])
  52 AC_PATH_PROG([PYTHON3], [python3])
  53
  54 AC_DEFINE([_GNU_SOURCE], 1,
  55           [Define _GNU_SOURCE so that we get all necessary prototypes])
  56
  57 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  58         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  59 fi
  60
  61 AC_ARG_ENABLE(profile,
  62         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  63 if test x"$enable_profile" = x"yes"; then
  64         CFLAGS="$CFLAGS -pg"
  65 fi
  66
  67 AC_MSG_CHECKING([if md2man can create man pages])
  68 if test x"$ac_cv_path_PYTHON3" = x; then
  69     AC_MSG_RESULT(no - python3 not found)
  70     md2man_works=no
  71 else
  72     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync-ssl.1.md" 2>&1`
  73     if test $? = 0; then
  74         AC_MSG_RESULT(yes)
  75         md2man_works=yes
  76     else
  77         AC_MSG_RESULT(no)
  78         md2man_works=no
  79         echo "$md2man_out"
  80     fi
  81 fi
  82
  83 AC_MSG_CHECKING([if we require man-page building])
  84 AC_ARG_ENABLE([md2man],
  85         AS_HELP_STRING([--disable-md2man],[disable md2man for man page creation]))
  86 if test x"$enable_md2man" != x"no"; then
  87     if test -f "$srcdir/rsync.1"; then
  88         AC_MSG_RESULT(optional)
  89     else
  90         AC_MSG_RESULT(required)
  91         if test x"$md2man_works" = x"no"; then
  92             AC_MSG_ERROR(You need python3 and the cmarkgfm OR commonmark python3 lib in order to build man pages.
  93 You can specify --disable-md2man if you want to skip building them.)
  94         fi
  95     fi
  96     MAKE_MAN=man
  97 else
  98     AC_MSG_RESULT(no)
  99     MAKE_MAN=''
 100 fi
 101
 102 # Specifically, this turns on panic_action handling.
 103 AC_ARG_ENABLE(maintainer-mode,
 104         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
 105 if test x"$enable_maintainer_mode" = x"yes"; then
 106         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 107 fi
 108
 109 # This is needed for our included version of popt.  Kind of silly, but
 110 # I don't want our version too far out of sync.
 111 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 112
 113 # If GCC, turn on warnings.
 114 if test x"$GCC" = x"yes"; then
 115         CFLAGS="$CFLAGS -Wall -W"
 116 fi
 117
 118 AC_ARG_WITH(included-popt,
 119         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 120
 121 AC_ARG_WITH(included-zlib,
 122         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 123
 124 AC_ARG_WITH(protected-args,
 125         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
 126 if test x"$with_protected_args" = x"yes"; then
 127         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
 128 fi
 129
 130 AC_ARG_WITH(rsync-path,
 131         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 132         [ RSYNC_PATH="$with_rsync_path" ],
 133         [ RSYNC_PATH="rsync" ])
 134
 135 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 136
 137 AC_ARG_WITH(rsyncd-conf,
 138         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 139         [ if test ! -z "$with_rsyncd_conf" ; then
 140                 case $with_rsyncd_conf in
 141                         yes|no)
 142                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 143                                 ;;
 144                         /*)
 145                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 146                                 ;;
 147                         *)
 148                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 149                                 ;;
 150                 esac
 151         else
 152                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 153         fi ],
 154         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 155
 156 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 157
 158 AC_ARG_WITH(rsh,
 159         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 160
 161 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 162 if test x$HAVE_REMSH = x1; then
 163         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 164 fi
 165
 166 if test x"$with_rsh" != x; then
 167         RSYNC_RSH="$with_rsh"
 168 else
 169         RSYNC_RSH="ssh"
 170 fi
 171 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 172
 173 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 174 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 175 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 176
 177 AC_ARG_WITH(nobody-group,
 178     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 179     [ NOBODY_GROUP="$with_nobody_group" ])
 180
 181 if test x"$with_nobody_group" = x; then
 182     AC_MSG_CHECKING([the group for user "nobody"])
 183     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 184         NOBODY_GROUP=nobody
 185     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 186         NOBODY_GROUP=nogroup
 187     else
 188         NOBODY_GROUP=nobody # test for others?
 189     fi
 190     AC_MSG_RESULT($NOBODY_GROUP)
 191 fi
 192
 193 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 194 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 195
 196 # SIMD optimizations
 197 SIMD=
 198
 199 AC_MSG_CHECKING([whether to enable SIMD optimizations])
 200 AC_ARG_ENABLE(simd,
 201     AS_HELP_STRING([--disable-simd],[disable SIMD optimizations (requires c++)]))
 202
 203 if test x"$enable_simd" != x"no"; then
 204     # For x86-64 SIMD, g++ >=5 or clang++ >=7 is required
 205     if test x"$build_cpu" = x"x86_64"; then
 206         AC_LANG(C++)
 207         AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 208 #include <immintrin.h>
 209 __attribute__ ((target("default"))) int test_ssse3(int x) { return x; }
 210 __attribute__ ((target("default"))) int test_sse2(int x) { return x; }
 211 __attribute__ ((target("default"))) int test_avx2(int x) { return x; }
 212 __attribute__ ((target("ssse3"))) int test_ssse3(int x) { return x; }
 213 __attribute__ ((target("sse2"))) int test_sse2(int x) { return x; }
 214 __attribute__ ((target("avx2"))) int test_avx2(int x) { return x; }
 215 typedef long long __m128i_u __attribute__((__vector_size__(16), __may_alias__, __aligned__(1)));
 216 typedef long long __m256i_u __attribute__((__vector_size__(32), __may_alias__, __aligned__(1)));
 217 inline void more_testing(char* buf, int len)
 218 {
 219     int i;
 220     for (i = 0; i < (len-32); i+=32) {
 221         __m128i in8_1, in8_2;
 222         in8_1 = _mm_lddqu_si128((__m128i_u*)&buf[i]);
 223         in8_2 = _mm_lddqu_si128((__m128i_u*)&buf[i + 16]);
 224     }
 225 }
 226 ]], [[if (test_ssse3(42) != 42 || test_sse2(42) != 42 || test_avx2(42) != 42) exit(1);]])],[CXX_OK=yes],[CXX_OK=no])
 227         AC_LANG(C)
 228         if test x"$CXX_OK" = x"yes"; then
 229             # AC_MSG_RESULT() is called below.
 230             SIMD="$SIMD x86_64"
 231         elif test x"$enable_simd" = x"yes"; then
 232             AC_MSG_RESULT(error)
 233             AC_MSG_ERROR(The SIMD compilation test failed.
 234 Omit --enable-simd to continue without it.)
 235         fi
 236     elif test x"$enable_simd" = x"yes"; then
 237         AC_MSG_RESULT(unavailable)
 238         AC_MSG_ERROR(The SIMD optimizations are currently x86_64 only.
 239 Omit --enable-simd to continue without it.)
 240     fi
 241 fi
 242
 243 if test x"$SIMD" != x""; then
 244     SIMD=`echo "$SIMD" | sed 's/^ *//'`
 245     AC_MSG_RESULT([yes ($SIMD)])
 246     AC_DEFINE(HAVE_SIMD, 1, [Define to 1 to enable SIMD optimizations])
 247     SIMD=`echo '$(SIMD_'"$SIMD)" | sed 's/ /) $(SIMD_/g'`
 248     # We only use c++ for its target attribute dispatching, disable unneeded bulky features
 249     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 250 else
 251     AC_MSG_RESULT(no)
 252 fi
 253
 254 AC_SUBST(SIMD)
 255
 256 # arrgh. libc in some old debian version screwed up the largefile
 257 # stuff, getting byte range locking wrong
 258 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 259 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 260 #define _FILE_OFFSET_BITS 64
 261 #include <stdio.h>
 262 #include <fcntl.h>
 263 #include <sys/types.h>
 264 #include <sys/wait.h>
 265 #if HAVE_UNISTD_H
 266 #include <unistd.h>
 267 #endif
 268
 269 int main(void)
 270 {
 271         struct flock lock;
 272         int status;
 273         char tpl[32] = "/tmp/locktest.XXXXXX";
 274         int fd = mkstemp(tpl);
 275         if (fd < 0) {
 276                 strcpy(tpl, "conftest.dat");
 277                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 278         }
 279
 280         lock.l_type = F_WRLCK;
 281         lock.l_whence = SEEK_SET;
 282         lock.l_start = 0;
 283         lock.l_len = 1;
 284         lock.l_pid = 0;
 285         fcntl(fd,F_SETLK,&lock);
 286         if (fork() == 0) {
 287                 lock.l_start = 1;
 288                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 289         }
 290         wait(&status);
 291         unlink(tpl);
 292         return WEXITSTATUS(status);
 293 }
 294 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 295 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 296    AC_SYS_LARGEFILE
 297 fi
 298
 299 ipv6type=unknown
 300 ipv6lib=none
 301 ipv6trylibc=yes
 302
 303 AC_ARG_ENABLE(ipv6,
 304         AS_HELP_STRING([--disable-ipv6],[turn off IPv6 support]))
 305 if test x"$enable_ipv6" != x"no"; then
 306         AC_MSG_CHECKING([ipv6 stack type])
 307         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 308                 case $i in
 309                 inria)
 310                         # http://www.kame.net/
 311                         AC_EGREP_CPP(yes, [
 312 #include <netinet/in.h>
 313 #ifdef IPV6_INRIA_VERSION
 314 yes
 315 #endif],
 316                                 [ipv6type=$i;
 317                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 318                                 ])
 319                         ;;
 320                 kame)
 321                         # http://www.kame.net/
 322                         AC_EGREP_CPP(yes, [
 323 #include <netinet/in.h>
 324 #ifdef __KAME__
 325 yes
 326 #endif],
 327                                 [ipv6type=$i;
 328                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 329                         ;;
 330                 linux-glibc)
 331                         # http://www.v6.linux.or.jp/
 332                         AC_EGREP_CPP(yes, [
 333 #include <features.h>
 334 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 335 yes
 336 #endif],
 337                                 [ipv6type=$i;
 338 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 339                         ;;
 340                 linux-inet6)
 341                         # http://www.v6.linux.or.jp/
 342                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 343                                 ipv6type=$i
 344                                 ipv6lib=inet6
 345                                 ipv6libdir=/usr/inet6/lib
 346                                 ipv6trylibc=yes;
 347                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 348                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 349                         fi
 350                         ;;
 351                 solaris)
 352                         # http://www.sun.com
 353                         AC_EGREP_CPP(yes, [
 354 #include <netinet/ip6.h>
 355 #ifdef __sun
 356 yes
 357 #endif],
 358                                 [ipv6type=$i;
 359                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 360                         ;;
 361                 toshiba)
 362                         AC_EGREP_CPP(yes, [
 363 #include <sys/param.h>
 364 #ifdef _TOSHIBA_INET6
 365 yes
 366 #endif],
 367                                 [ipv6type=$i;
 368                                 ipv6lib=inet6;
 369                                 ipv6libdir=/usr/local/v6/lib;
 370                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 371                         ;;
 372                 v6d)
 373                         AC_EGREP_CPP(yes, [
 374 #include </usr/local/v6/include/sys/v6config.h>
 375 #ifdef __V6D__
 376 yes
 377 #endif],
 378                                 [ipv6type=$i;
 379                                 ipv6lib=v6;
 380                                 ipv6libdir=/usr/local/v6/lib;
 381                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 382                         ;;
 383                 zeta)
 384                         AC_EGREP_CPP(yes, [
 385 #include <sys/param.h>
 386 #ifdef _ZETA_MINAMI_INET6
 387 yes
 388 #endif],
 389                                 [ipv6type=$i;
 390                                 ipv6lib=inet6;
 391                                 ipv6libdir=/usr/local/v6/lib;
 392                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 393                         ;;
 394                 cygwin)
 395                         AC_EGREP_CPP(yes, [
 396 #include <netinet/in.h>
 397 #ifdef _CYGWIN_IN6_H
 398 yes
 399 #endif],
 400                                 [ipv6type=$i;
 401                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 402                         ;;
 403                 esac
 404                 if test "$ipv6type" != "unknown"; then
 405                         break
 406                 fi
 407         done
 408         AC_MSG_RESULT($ipv6type)
 409
 410         AC_SEARCH_LIBS(getaddrinfo, inet6)
 411 fi
 412
 413 dnl Do you want to disable use of locale functions
 414 AC_ARG_ENABLE([locale],
 415         AS_HELP_STRING([--disable-locale],[disable locale features]))
 416 AH_TEMPLATE([CONFIG_LOCALE],
 417 [Undefine if you do not want locale features.  By default this is defined.])
 418 if test x"$enable_locale" != x"no"; then
 419         AC_DEFINE(CONFIG_LOCALE)
 420 fi
 421
 422 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 423 case $host_os in
 424         *cygwin* ) AC_MSG_RESULT(yes)
 425                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 426                             [Define to 1 if sockets need to be shutdown])
 427                    ;;
 428                * ) AC_MSG_RESULT(no);;
 429 esac
 430
 431 AC_C_BIGENDIAN
 432 AC_HEADER_DIRENT
 433 AC_HEADER_TIME
 434 AC_HEADER_SYS_WAIT
 435 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 436     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 437     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 438     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 439     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 440     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 441     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 442     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h)
 443 AC_HEADER_MAJOR_FIXED
 444
 445 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 446 AC_ARG_ENABLE([openssl],
 447         AS_HELP_STRING([--disable-openssl],[disable openssl crypto library]))
 448 AH_TEMPLATE([USE_OPENSSL],
 449 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 450 if test x"$enable_openssl" != x"no"; then
 451     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 452       AC_MSG_RESULT(yes)
 453       AC_SEARCH_LIBS(MD5_Init, crypto,
 454           [AC_DEFINE(USE_OPENSSL)],
 455           [AC_MSG_ERROR(Failed to find MD5_Init function in openssl crypto lib.
 456 Use --disable-openssl to continue without openssl crypto lib support.)])
 457     else
 458         AC_MSG_RESULT(no)
 459         AC_MSG_ERROR(Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support.
 460 Use --disable-openssl to continue without it.)
 461     fi
 462 else
 463     AC_MSG_RESULT(no)
 464 fi
 465
 466 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 467 AC_ARG_ENABLE([xxhash],
 468         AS_HELP_STRING([--disable-xxhash],[disable xxhash checksums]))
 469 AH_TEMPLATE([SUPPORT_XXHASH],
 470 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 471 if test x"$enable_xxhash" != x"no"; then
 472     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 473         AC_MSG_RESULT(yes)
 474         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 475             [AC_DEFINE(SUPPORT_XXHASH)],
 476             [AC_MSG_ERROR(Failed to find XXH64_createState function in xxhash lib.
 477 Use --disable-xxhash to continue without xxhash checksums.)])
 478     else
 479         AC_MSG_RESULT(no)
 480         AC_MSG_ERROR(Failed to find xxhash.h for xxhash checksum support.
 481 Use --disable-xxhash to continue without it.)
 482     fi
 483 else
 484     AC_MSG_RESULT(no)
 485 fi
 486
 487 AC_MSG_CHECKING([whether to enable zstd compression])
 488 AC_ARG_ENABLE([zstd],
 489         AC_HELP_STRING([--disable-zstd], [disable zstd compression]))
 490 AH_TEMPLATE([SUPPORT_ZSTD],
 491 [Undefine if you do not want zstd compression.  By default this is defined.])
 492 if test x"$enable_zstd" != x"no"; then
 493     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 494         AC_MSG_RESULT(yes)
 495         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 496             [AC_DEFINE(SUPPORT_ZSTD)],
 497             [AC_MSG_ERROR(Failed to find ZSTD_minCLevel function in zstd lib.
 498 Use --disable-zstd to continue without zstd compression.)])
 499     else
 500         AC_MSG_RESULT(no)
 501         AC_MSG_ERROR(Failed to find zstd.h for zstd compression support.
 502 Use --disable-zstd to continue without it.)
 503     fi
 504 else
 505     AC_MSG_RESULT(no)
 506 fi
 507
 508 AC_MSG_CHECKING([whether to enable LZ4 compression])
 509 AC_ARG_ENABLE([lz4],
 510         AC_HELP_STRING([--disable-lz4], [disable LZ4 compression]))
 511 AH_TEMPLATE([SUPPORT_LZ4],
 512 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 513 if test x"$enable_lz4" != x"no"; then
 514     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 515         AC_MSG_RESULT(yes)
 516         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 517             [AC_DEFINE(SUPPORT_LZ4)],
 518             [AC_MSG_ERROR(Failed to find LZ4_compress_default function in lz4 lib.
 519 Use --disable-lz4 to continue without lz4 compression.)])
 520     else
 521         AC_MSG_RESULT(no)
 522         AC_MSG_ERROR(Failed to find lz4.h for lz4 compression support.
 523 Use --disable-lz4 to continue without it.)
 524     fi
 525 else
 526     AC_MSG_RESULT(no)
 527 fi
 528
 529 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 530 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 531 #include <sys/types.h>
 532 #ifdef MAJOR_IN_MKDEV
 533 #include <sys/mkdev.h>
 534 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 535 #  define makedev mkdev
 536 # endif
 537 #elif defined MAJOR_IN_SYSMACROS
 538 #include <sys/sysmacros.h>
 539 #endif
 540
 541 int main(void)
 542 {
 543         dev_t dev = makedev(0, 5, 7);
 544         if (major(dev) != 5 || minor(dev) != 7)
 545                 return 1;
 546         return 0;
 547 }
 548 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 549 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 550    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 551 fi
 552
 553 AC_CHECK_SIZEOF(int)
 554 AC_CHECK_SIZEOF(long)
 555 AC_CHECK_SIZEOF(long long)
 556 AC_CHECK_SIZEOF(short)
 557 AC_CHECK_SIZEOF(int16_t)
 558 AC_CHECK_SIZEOF(uint16_t)
 559 AC_CHECK_SIZEOF(int32_t)
 560 AC_CHECK_SIZEOF(uint32_t)
 561 AC_CHECK_SIZEOF(int64_t)
 562 AC_CHECK_SIZEOF(off_t)
 563 AC_CHECK_SIZEOF(off64_t)
 564 AC_CHECK_SIZEOF(time_t)
 565 AC_CHECK_SIZEOF(char*)
 566
 567 AC_C_INLINE
 568
 569 AC_TYPE_LONG_DOUBLE_WIDER
 570 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 571 if test $ac_cv_c_long_double = yes; then
 572   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 573 fi
 574
 575 AC_TYPE_UID_T
 576 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 577 AC_TYPE_GETGROUPS
 578 AC_CHECK_MEMBERS([struct stat.st_rdev,
 579                   struct stat.st_mtimensec,
 580                   struct stat.st_mtimespec.tv_nsec,
 581                   struct stat.st_mtim.tv_nsec],,,[
 582 #ifdef HAVE_SYS_TYPES_H
 583 #include <sys/types.h>
 584 #endif
 585 #ifdef HAVE_SYS_STAT_H
 586 #include <sys/stat.h>
 587 #endif
 588 #ifdef HAVE_UNISTD_H
 589 #include <unistd.h>
 590 #endif])
 591
 592 TYPE_SOCKLEN_T
 593
 594 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 595     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 596 if test x"$rsync_cv_errno" = x"yes"; then
 597    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 598 fi
 599
 600 # The following test taken from the cvs sources
 601 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 602 # These need checks to be before checks for any other functions that
 603 #    might be in the same libraries.
 604 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 605 # libsocket.so which has a bad implementation of gethostbyname (it
 606 # only looks in /etc/hosts), so we only look for -lsocket if we need
 607 # it.
 608 AC_CHECK_FUNCS(connect)
 609 if test x"$ac_cv_func_connect" = x"no"; then
 610     case "$LIBS" in
 611     *-lnsl*) ;;
 612     *) AC_CHECK_LIB(nsl_s, printf) ;;
 613     esac
 614     case "$LIBS" in
 615     *-lnsl*) ;;
 616     *) AC_CHECK_LIB(nsl, printf) ;;
 617     esac
 618     case "$LIBS" in
 619     *-lsocket*) ;;
 620     *) AC_CHECK_LIB(socket, connect) ;;
 621     esac
 622     case "$LIBS" in
 623     *-linet*) ;;
 624     *) AC_CHECK_LIB(inet, connect) ;;
 625     esac
 626     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 627     dnl has been cached.
 628     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 629        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 630         # ac_cv_func_connect=yes
 631         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 632         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 633     fi
 634 fi
 635
 636 AC_SEARCH_LIBS(inet_ntop, resolv)
 637
 638 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 639 # accept either iconv_open or libiconv_open, since some include files map
 640 # the former to the latter.
 641 AC_SEARCH_LIBS(iconv_open, iconv)
 642 AC_SEARCH_LIBS(libiconv_open, iconv)
 643
 644 AC_MSG_CHECKING([for iconv declaration])
 645 AC_CACHE_VAL(am_cv_proto_iconv, [
 646     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 647 #include <stdlib.h>
 648 #include <iconv.h>
 649 extern
 650 #ifdef __cplusplus
 651 "C"
 652 #endif
 653 #if defined(__STDC__) || defined(__cplusplus)
 654 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 655 #else
 656 size_t iconv();
 657 #endif
 658 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 659       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 660     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed 's/( /(/'`
 661 AC_MSG_RESULT([$]{ac_t:-
 662          }[$]am_cv_proto_iconv)
 663 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 664                    [Define as const if the declaration of iconv() needs const.])
 665
 666 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 667
 668 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 669
 670 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 671 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 672 #include <sys/socket.h>])
 673
 674 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 675 #   builtin getaddrinfo if one of the defines don't exist
 676 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 677                rsync_cv_HAVE_GETADDR_DEFINES,[
 678                         AC_EGREP_CPP(yes, [
 679                         #include <sys/types.h>
 680                         #include <sys/socket.h>
 681                         #include <netdb.h>
 682                         #ifdef AI_PASSIVE
 683                         yes
 684                         #endif],
 685                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 686                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 687 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 688         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 689         # something else so we must include <netdb.h> to get the
 690         # redefinition.
 691         AC_CHECK_FUNCS(getaddrinfo, ,
 692                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 693                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 694                 #include <sys/socket.h>
 695                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 696                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 697                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 698                         AC_LIBOBJ([getaddrinfo])])])
 699     ],[AC_LIBOBJ([getaddrinfo])])
 700
 701 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 702                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 703                 [],
 704                 [
 705 #include <sys/types.h>
 706 #include <sys/socket.h>
 707 ])
 708
 709 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 710                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 711                 [],
 712                 [
 713 #include <sys/types.h>
 714 #include <sys/socket.h>
 715 #include <netinet/in.h>
 716 ])
 717
 718 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 719                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 720                 [],
 721                 [
 722 #include <sys/types.h>
 723 #include <sys/socket.h>
 724 #include <netinet/in.h>
 725 ])
 726
 727 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 728                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 729                 [],
 730                 [
 731 #include <sys/types.h>
 732 #include <sys/socket.h>
 733 #include <netinet/in.h>
 734 ])
 735
 736 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 737 #if HAVE_SYS_TYPES_H
 738 # include <sys/types.h>
 739 #endif
 740 #if HAVE_SYS_STAT_H
 741 # include <sys/stat.h>
 742 #endif
 743 #if STDC_HEADERS
 744 # include <stdlib.h>
 745 # include <stddef.h>
 746 #else
 747 # if HAVE_STDLIB_H
 748 #  include <stdlib.h>
 749 # endif
 750 #endif
 751 ])
 752
 753 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 754 #
 755 AC_CHECK_FUNCS(strcasecmp)
 756 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 757     AC_CHECK_LIB(resolv, strcasecmp)
 758 fi
 759
 760 AC_CHECK_FUNCS(aclsort)
 761 if test x"$ac_cv_func_aclsort" = x"no"; then
 762     AC_CHECK_LIB(sec, aclsort)
 763 fi
 764
 765 dnl At the moment we don't test for a broken memcmp(), because all we
 766 dnl need to do is test for equality, not comparison, and it seems that
 767 dnl every platform has a memcmp that can do at least that.
 768 dnl AC_FUNC_MEMCMP
 769
 770 AC_FUNC_UTIME_NULL
 771 AC_FUNC_ALLOCA
 772 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 773     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 774     chflags getattrlist \
 775     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 776     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 777     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 778     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 779     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 780     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep)
 781
 782 dnl cygwin iconv.h defines iconv_open as libiconv_open
 783 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 784     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 785 fi
 786
 787 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 788
 789 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 790 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 791 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 792 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 793     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 794 fi
 795
 796 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 797 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 798         #define _GNU_SOURCE 1
 799         #include <linux/falloc.h>
 800         #ifndef FALLOC_FL_PUNCH_HOLE
 801         #error FALLOC_FL_PUNCH_HOLE is missing
 802         #endif
 803     ]])], [
 804         AC_MSG_RESULT([yes])
 805         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 806     ], [
 807         AC_MSG_RESULT([no])
 808     ]
 809 )
 810
 811 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 812 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 813         #define _GNU_SOURCE 1
 814         #include <linux/falloc.h>
 815         #ifndef FALLOC_FL_ZERO_RANGE
 816         #error FALLOC_FL_ZERO_RANGE is missing
 817         #endif
 818     ]])], [
 819         AC_MSG_RESULT([yes])
 820         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 821     ], [
 822         AC_MSG_RESULT([no])
 823     ]
 824 )
 825
 826 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 827 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 828 #include <unistd.h>
 829 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 830 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 831     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 832 fi
 833
 834 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 835     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 836     case $host_os in
 837     *cygwin*)
 838         AC_MSG_RESULT(yes)
 839         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 840                   [Define if posix_fallocate is efficient (Cygwin)])
 841         ;;
 842     *)
 843         AC_MSG_RESULT(no)
 844         ;;
 845     esac
 846 fi
 847
 848 dnl End of preallocation stuff
 849
 850 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 851 if test $ac_cv_func_getpgrp = yes; then
 852     AC_FUNC_GETPGRP
 853 fi
 854
 855 AC_ARG_ENABLE(iconv-open,
 856     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 857     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 858
 859 if test x"$enable_iconv_open" != x"no"; then
 860     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 861 fi
 862
 863 AC_ARG_ENABLE(iconv,
 864     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 865     [], [enable_iconv=$enable_iconv_open])
 866 AH_TEMPLATE([ICONV_OPTION],
 867 [Define if you want the --iconv option.  Specifying a value will set the
 868 default iconv setting (a NULL means no --iconv processing by default).])
 869 if test x"$enable_iconv" != x"no"; then
 870         if test x"$enable_iconv" = x"yes"; then
 871                 AC_DEFINE(ICONV_OPTION, NULL)
 872         else
 873                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 874         fi
 875         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 876 fi
 877
 878 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 879   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 880 #if HAVE_UNISTD_H
 881 # include <unistd.h>
 882 #endif
 883 #include <stdlib.h>
 884 #include <errno.h>
 885 int main(void) {
 886         char const *dangling_symlink = "conftest.dangle";
 887         unlink(dangling_symlink);
 888         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 889         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 890         return 0;
 891     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 892 if test $rsync_cv_chown_modifies_symlink = yes; then
 893   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 894 fi
 895
 896 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 897   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 898 #if HAVE_UNISTD_H
 899 # include <unistd.h>
 900 #endif
 901 #include <stdlib.h>
 902 #include <errno.h>
 903 #define FILENAME "conftest.dangle"
 904 int main(void) {
 905         unlink(FILENAME);
 906         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 907         unlink(FILENAME "2");
 908         if (link(FILENAME, FILENAME "2") < 0) return 1;
 909         return 0;
 910     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 911 if test $rsync_cv_can_hardlink_symlink = yes; then
 912   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 913 fi
 914
 915 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 916   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 917 #if HAVE_UNISTD_H
 918 # include <unistd.h>
 919 #endif
 920 #ifdef HAVE_SYS_STAT_H
 921 #include <sys/stat.h>
 922 #endif
 923 #include <stdlib.h>
 924 #include <errno.h>
 925 #define FILENAME "conftest.fifi"
 926 int main(void) {
 927         unlink(FILENAME);
 928         if (mkfifo(FILENAME, 0777) < 0) abort();
 929         unlink(FILENAME "2");
 930         if (link(FILENAME, FILENAME "2") < 0) return 1;
 931         return 0;
 932     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 933 if test $rsync_cv_can_hardlink_special = yes; then
 934     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 935 fi
 936
 937 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 938 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 939 #include <sys/types.h>
 940 #include <sys/socket.h>
 941
 942 int main(void) {
 943        int fd[2];
 944        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
 945 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 946 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 947     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 948 fi
 949
 950 AC_REPLACE_FUNCS([getpass])
 951
 952 if test x"$with_included_popt" != x"yes"; then
 953     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 954 fi
 955 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 956     # If the system has /usr/include/popt/popt.h, we enable the
 957     # included popt because an attempt to "#include <popt/popt.h>"
 958     # would use our included header file anyway (due to -I.), and
 959     # might conflict with the system popt.
 960     with_included_popt=yes
 961 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 962     with_included_popt=yes
 963 fi
 964
 965 AC_MSG_CHECKING([whether to use included libpopt])
 966 if test x"$with_included_popt" = x"yes"; then
 967     AC_MSG_RESULT($srcdir/popt)
 968     BUILD_POPT='$(popt_OBJS)'
 969     CFLAGS="-I$srcdir/popt $CFLAGS"
 970     if test x"$ALLOCA" != x
 971     then
 972         # this can be removed when/if we add an included alloca.c;
 973         #  see autoconf documentation on AC_FUNC_ALLOCA
 974         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 975     fi
 976 else
 977     AC_MSG_RESULT(no)
 978 fi
 979
 980 # We default to using our zlib unless --with-included-zlib=no is given.
 981 if test x"$with_included_zlib" != x"no"; then
 982     with_included_zlib=yes
 983 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
 984     with_included_zlib=yes
 985 fi
 986 if test x"$with_included_zlib" != x"yes"; then
 987     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
 988 fi
 989
 990 AC_MSG_CHECKING([whether to use included zlib])
 991 if test x"$with_included_zlib" = x"yes"; then
 992     AC_MSG_RESULT($srcdir/zlib)
 993     BUILD_ZLIB='$(zlib_OBJS)'
 994     CFLAGS="-I$srcdir/zlib $CFLAGS"
 995 else
 996     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
 997     AC_MSG_RESULT(no)
 998 fi
 999
1000 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
1001 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
1002 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
1003     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
1004 fi
1005
1006 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
1007 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
1008 #include <dirent.h>
1009 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
1010 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
1011 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
1012 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
1013     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
1014 fi
1015
1016 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
1017 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1018 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
1019 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
1020     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
1021 fi
1022
1023 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1024 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1025 #include <unistd.h>]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1026 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1027     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1028 fi
1029
1030 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1031 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1032 #include <sys/types.h>
1033 #include <stdarg.h>
1034 #include <stdio.h>
1035 #include <stdlib.h>
1036 #include <string.h>
1037 void foo(const char *format, ...) {
1038        va_list ap;
1039        int len;
1040        static char buf[] = "12345678901234567890";
1041
1042        va_start(ap, format);
1043        len = vsnprintf(0, 0, format, ap);
1044        va_end(ap);
1045        if (len != 5) exit(1);
1046
1047        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1048 }
1049 int main(void) { foo("hello"); return 0; }
1050 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1051 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1052     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1053 fi
1054
1055
1056 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1057 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1058 #include <sys/types.h>
1059 #include <sys/stat.h>
1060 #include <unistd.h>
1061 int main(void) {
1062   struct stat st;
1063   char tpl[20]="/tmp/test.XXXXXX";
1064   int fd = mkstemp(tpl);
1065   if (fd == -1) return 1;
1066   unlink(tpl);
1067   if (fstat(fd, &st) != 0) return 1;
1068   if ((st.st_mode & 0777) != 0600) return 1;
1069   return 0;
1070 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1071 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1072     case $host_os in
1073     hpux*)
1074         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1075         dnl so we noisily skip using it.  See HP change request JAGaf34426
1076         dnl for details. (sbonds)
1077         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1078         ;;
1079     *)
1080         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1081         ;;
1082     esac
1083 fi
1084
1085
1086 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1087 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1088 #include <stdio.h>
1089 #include <sys/stat.h>
1090 #include <errno.h>
1091 #if HAVE_UNISTD_H
1092 # include <unistd.h>
1093 #endif
1094 int main(void) { int rc, ec; char *fn = "fifo-test";
1095 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1096 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1097 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1098 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1099     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1100 fi
1101
1102 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1103 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1104 #include <stdio.h>
1105 #include <sys/stat.h>
1106 #include <errno.h>
1107 #if HAVE_UNISTD_H
1108 # include <unistd.h>
1109 #endif
1110 int main(void) { int rc, ec; char *fn = "sock-test";
1111 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1112 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1113 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1114 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1115     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1116 fi
1117
1118 #
1119 # The following test was mostly taken from the tcl/tk plus patches
1120 #
1121 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1122 rm -rf conftest*
1123 cat > conftest.$ac_ext <<EOF
1124 int main(void) { return 0; }
1125 EOF
1126 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1127 if test -f conftest..o; then
1128     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1129 else
1130     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1131 fi
1132 rm -rf conftest*
1133 ])
1134 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1135     OBJ_SAVE="#"
1136     OBJ_RESTORE="#"
1137     CC_SHOBJ_FLAG='-o $@'
1138 else
1139     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1140     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1141     CC_SHOBJ_FLAG=""
1142 fi
1143
1144 AC_SUBST(OBJ_SAVE)
1145 AC_SUBST(OBJ_RESTORE)
1146 AC_SUBST(CC_SHOBJ_FLAG)
1147 AC_SUBST(BUILD_POPT)
1148 AC_SUBST(BUILD_ZLIB)
1149 AC_SUBST(MAKE_MAN)
1150
1151 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1152 #################################################
1153 # check for ACL support
1154
1155 AC_MSG_CHECKING([whether to support ACLs])
1156 AC_ARG_ENABLE(acl-support,
1157         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
1158
1159 if test x"$enable_acl_support" = x"no"; then
1160     AC_MSG_RESULT(no)
1161 else
1162     case "$host_os" in
1163     *sysv5*)
1164         AC_MSG_RESULT(Using UnixWare ACLs)
1165         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1166         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1167         ;;
1168     solaris*)
1169         AC_MSG_RESULT(Using solaris ACLs)
1170         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1171         AC_DEFINE(SUPPORT_ACLS, 1)
1172         ;;
1173     *hpux*)
1174         AC_MSG_RESULT(Using HPUX ACLs)
1175         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1176         AC_DEFINE(SUPPORT_ACLS, 1)
1177         ;;
1178     *irix*)
1179         AC_MSG_RESULT(Using IRIX ACLs)
1180         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1181         AC_DEFINE(SUPPORT_ACLS, 1)
1182         ;;
1183     *aix*)
1184         AC_MSG_RESULT(Using AIX ACLs)
1185         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1186         AC_DEFINE(SUPPORT_ACLS, 1)
1187         ;;
1188     *osf*)
1189         AC_MSG_RESULT(Using Tru64 ACLs)
1190         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1191         AC_DEFINE(SUPPORT_ACLS, 1)
1192         LIBS="$LIBS -lpacl"
1193         ;;
1194     darwin*)
1195         AC_MSG_RESULT(Using OS X ACLs)
1196         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1197         AC_DEFINE(SUPPORT_ACLS, 1)
1198         ;;
1199     *)
1200         AC_MSG_RESULT(running tests:)
1201         AC_CHECK_LIB(acl,acl_get_file)
1202         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1203             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1204 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1205         AC_MSG_CHECKING(ACL test results)
1206         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1207             AC_MSG_RESULT(Using posix ACLs)
1208             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1209             AC_DEFINE(SUPPORT_ACLS, 1)
1210             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1211                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1212 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1213             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1214                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1215             fi
1216         else
1217             if test x"$enable_acl_support" = x"yes"; then
1218                 AC_MSG_ERROR(Failed to find ACL support)
1219             else
1220                 AC_MSG_RESULT(No ACL support found)
1221             fi
1222         fi
1223         ;;
1224     esac
1225 fi
1226
1227 #################################################
1228 # check for extended attribute support
1229 AC_MSG_CHECKING(whether to support extended attributes)
1230 AC_ARG_ENABLE(xattr-support,
1231     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1232     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1233         *yes*) enable_xattr_support=maybe ;;
1234         *) enable_xattr_support=no ;;
1235         esac])
1236 AH_TEMPLATE([SUPPORT_XATTRS],
1237 [Define to 1 to add support for extended attributes])
1238 if test x"$enable_xattr_support" = x"no"; then
1239     AC_MSG_RESULT(no)
1240 else
1241     case "$host_os" in
1242     *linux*|*netbsd*)
1243         AC_MSG_RESULT(Using Linux xattrs)
1244         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1245         AC_DEFINE(SUPPORT_XATTRS, 1)
1246         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1247         AC_CHECK_LIB(attr,getxattr)
1248         ;;
1249     darwin*)
1250         AC_MSG_RESULT(Using OS X xattrs)
1251         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1252         AC_DEFINE(SUPPORT_XATTRS, 1)
1253         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1254         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1255         ;;
1256     freebsd*)
1257         AC_MSG_RESULT(Using FreeBSD extattrs)
1258         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1259         AC_DEFINE(SUPPORT_XATTRS, 1)
1260         ;;
1261     solaris*)
1262         AC_MSG_RESULT(Using Solaris xattrs)
1263         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1264         AC_DEFINE(SUPPORT_XATTRS, 1)
1265         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1266         ;;
1267     *)
1268         if test x"$enable_xattr_support" = x"yes"; then
1269             AC_MSG_ERROR(Failed to find extended attribute support)
1270         else
1271             AC_MSG_RESULT(No extended attribute support found)
1272         fi
1273         ;;
1274     esac
1275 fi
1276
1277 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1278     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1279     OLD_CFLAGS="$CFLAGS"
1280     CFLAGS="$CFLAGS -Wno-unused-parameter"
1281     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1282     AC_MSG_RESULT([$rsync_warn_flag])
1283     if test x"$rsync_warn_flag" = x"no"; then
1284         CFLAGS="$OLD_CFLAGS"
1285     fi
1286 fi
1287
1288 case "$CC" in
1289 ' checker'*|checker*)
1290     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1291     ;;
1292 esac
1293
1294 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1295 AC_OUTPUT
1296
1297 AC_MSG_RESULT()
1298 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1299 AC_MSG_RESULT()