arch/arm64/kernel/hyp-stub.S

   1 /* SPDX-License-Identifier: GPL-2.0-only */
   2 /*
   3  * Hypervisor stub
   4  *
   5  * Copyright (C) 2012 ARM Ltd.
   6  * Author:      Marc Zyngier <marc.zyngier@arm.com>
   7  */
   8
   9 #include <linux/init.h>
  10 #include <linux/linkage.h>
  11
  12 #include <asm/assembler.h>
  13 #include <asm/el2_setup.h>
  14 #include <asm/kvm_arm.h>
  15 #include <asm/kvm_asm.h>
  16 #include <asm/ptrace.h>
  17 #include <asm/virt.h>
  18
  19         .text
  20         .pushsection    .hyp.text, "ax"
  21
  22         .align 11
  23
  24 SYM_CODE_START(__hyp_stub_vectors)
  25         ventry  el2_sync_invalid                // Synchronous EL2t
  26         ventry  el2_irq_invalid                 // IRQ EL2t
  27         ventry  el2_fiq_invalid                 // FIQ EL2t
  28         ventry  el2_error_invalid               // Error EL2t
  29
  30         ventry  elx_sync                        // Synchronous EL2h
  31         ventry  el2_irq_invalid                 // IRQ EL2h
  32         ventry  el2_fiq_invalid                 // FIQ EL2h
  33         ventry  el2_error_invalid               // Error EL2h
  34
  35         ventry  elx_sync                        // Synchronous 64-bit EL1
  36         ventry  el1_irq_invalid                 // IRQ 64-bit EL1
  37         ventry  el1_fiq_invalid                 // FIQ 64-bit EL1
  38         ventry  el1_error_invalid               // Error 64-bit EL1
  39
  40         ventry  el1_sync_invalid                // Synchronous 32-bit EL1
  41         ventry  el1_irq_invalid                 // IRQ 32-bit EL1
  42         ventry  el1_fiq_invalid                 // FIQ 32-bit EL1
  43         ventry  el1_error_invalid               // Error 32-bit EL1
  44 SYM_CODE_END(__hyp_stub_vectors)
  45
  46         .align 11
  47
  48 SYM_CODE_START_LOCAL(elx_sync)
  49         cmp     x0, #HVC_SET_VECTORS
  50         b.ne    1f
  51         msr     vbar_el2, x1
  52         b       9f
  53
  54 1:      cmp     x0, #HVC_FINALISE_EL2
  55         b.eq    __finalise_el2
  56
  57 2:      cmp     x0, #HVC_SOFT_RESTART
  58         b.ne    3f
  59         mov     x0, x2
  60         mov     x2, x4
  61         mov     x4, x1
  62         mov     x1, x3
  63         br      x4                              // no return
  64
  65 3:      cmp     x0, #HVC_RESET_VECTORS
  66         beq     9f                              // Nothing to reset!
  67
  68         /* Someone called kvm_call_hyp() against the hyp-stub... */
  69         mov_q   x0, HVC_STUB_ERR
  70         eret
  71
  72 9:      mov     x0, xzr
  73         eret
  74 SYM_CODE_END(elx_sync)
  75
  76 SYM_CODE_START_LOCAL(__finalise_el2)
  77         finalise_el2_state
  78
  79         // nVHE? No way! Give me the real thing!
  80         // Sanity check: MMU *must* be off
  81         mrs     x1, sctlr_el2
  82         tbnz    x1, #0, 1f
  83
  84         // Needs to be VHE capable, obviously
  85         check_override id_aa64mmfr1 ID_AA64MMFR1_EL1_VH_SHIFT 2f 1f x1 x2
  86
  87 1:      mov_q   x0, HVC_STUB_ERR
  88         eret
  89 2:
  90         // Engage the VHE magic!
  91         mov_q   x0, HCR_HOST_VHE_FLAGS
  92         msr     hcr_el2, x0
  93         isb
  94
  95         // Use the EL1 allocated stack, per-cpu offset
  96         mrs     x0, sp_el1
  97         mov     sp, x0
  98         mrs     x0, tpidr_el1
  99         msr     tpidr_el2, x0
 100
 101         // FP configuration, vectors
 102         mrs_s   x0, SYS_CPACR_EL12
 103         msr     cpacr_el1, x0
 104         mrs_s   x0, SYS_VBAR_EL12
 105         msr     vbar_el1, x0
 106
 107         // Use EL2 translations for SPE & TRBE and disable access from EL1
 108         mrs     x0, mdcr_el2
 109         bic     x0, x0, #(MDCR_EL2_E2PB_MASK << MDCR_EL2_E2PB_SHIFT)
 110         bic     x0, x0, #(MDCR_EL2_E2TB_MASK << MDCR_EL2_E2TB_SHIFT)
 111         msr     mdcr_el2, x0
 112
 113         // Transfer the MM state from EL1 to EL2
 114         mrs_s   x0, SYS_TCR_EL12
 115         msr     tcr_el1, x0
 116         mrs_s   x0, SYS_TTBR0_EL12
 117         msr     ttbr0_el1, x0
 118         mrs_s   x0, SYS_TTBR1_EL12
 119         msr     ttbr1_el1, x0
 120         mrs_s   x0, SYS_MAIR_EL12
 121         msr     mair_el1, x0
 122         mrs     x1, REG_ID_AA64MMFR3_EL1
 123         ubfx    x1, x1, #ID_AA64MMFR3_EL1_TCRX_SHIFT, #4
 124         cbz     x1, .Lskip_tcr2
 125         mrs     x0, REG_TCR2_EL12
 126         msr     REG_TCR2_EL1, x0
 127
 128         // Transfer permission indirection state
 129         mrs     x1, REG_ID_AA64MMFR3_EL1
 130         ubfx    x1, x1, #ID_AA64MMFR3_EL1_S1PIE_SHIFT, #4
 131         cbz     x1, .Lskip_indirection
 132         mrs     x0, REG_PIRE0_EL12
 133         msr     REG_PIRE0_EL1, x0
 134         mrs     x0, REG_PIR_EL12
 135         msr     REG_PIR_EL1, x0
 136
 137 .Lskip_indirection:
 138 .Lskip_tcr2:
 139
 140         isb
 141
 142         // Hack the exception return to stay at EL2
 143         mrs     x0, spsr_el1
 144         and     x0, x0, #~PSR_MODE_MASK
 145         mov     x1, #PSR_MODE_EL2h
 146         orr     x0, x0, x1
 147         msr     spsr_el1, x0
 148
 149         b       enter_vhe
 150 SYM_CODE_END(__finalise_el2)
 151
 152         // At the point where we reach enter_vhe(), we run with
 153         // the MMU off (which is enforced by __finalise_el2()).
 154         // We thus need to be in the idmap, or everything will
 155         // explode when enabling the MMU.
 156
 157         .pushsection    .idmap.text, "ax"
 158
 159 SYM_CODE_START_LOCAL(enter_vhe)
 160         // Invalidate TLBs before enabling the MMU
 161         tlbi    vmalle1
 162         dsb     nsh
 163         isb
 164
 165         // Enable the EL2 S1 MMU, as set up from EL1
 166         mrs_s   x0, SYS_SCTLR_EL12
 167         set_sctlr_el1   x0
 168
 169         // Disable the EL1 S1 MMU for a good measure
 170         mov_q   x0, INIT_SCTLR_EL1_MMU_OFF
 171         msr_s   SYS_SCTLR_EL12, x0
 172
 173         mov     x0, xzr
 174
 175         eret
 176 SYM_CODE_END(enter_vhe)
 177
 178         .popsection
 179
 180 .macro invalid_vector   label
 181 SYM_CODE_START_LOCAL(\label)
 182         b \label
 183 SYM_CODE_END(\label)
 184 .endm
 185
 186         invalid_vector  el2_sync_invalid
 187         invalid_vector  el2_irq_invalid
 188         invalid_vector  el2_fiq_invalid
 189         invalid_vector  el2_error_invalid
 190         invalid_vector  el1_sync_invalid
 191         invalid_vector  el1_irq_invalid
 192         invalid_vector  el1_fiq_invalid
 193         invalid_vector  el1_error_invalid
 194
 195         .popsection
 196
 197 /*
 198  * __hyp_set_vectors: Call this after boot to set the initial hypervisor
 199  * vectors as part of hypervisor installation.  On an SMP system, this should
 200  * be called on each CPU.
 201  *
 202  * x0 must be the physical address of the new vector table, and must be
 203  * 2KB aligned.
 204  *
 205  * Before calling this, you must check that the stub hypervisor is installed
 206  * everywhere, by waiting for any secondary CPUs to be brought up and then
 207  * checking that is_hyp_mode_available() is true.
 208  *
 209  * If not, there is a pre-existing hypervisor, some CPUs failed to boot, or
 210  * something else went wrong... in such cases, trying to install a new
 211  * hypervisor is unlikely to work as desired.
 212  *
 213  * When you call into your shiny new hypervisor, sp_el2 will contain junk,
 214  * so you will need to set that to something sensible at the new hypervisor's
 215  * initialisation entry point.
 216  */
 217
 218 SYM_FUNC_START(__hyp_set_vectors)
 219         mov     x1, x0
 220         mov     x0, #HVC_SET_VECTORS
 221         hvc     #0
 222         ret
 223 SYM_FUNC_END(__hyp_set_vectors)
 224
 225 SYM_FUNC_START(__hyp_reset_vectors)
 226         mov     x0, #HVC_RESET_VECTORS
 227         hvc     #0
 228         ret
 229 SYM_FUNC_END(__hyp_reset_vectors)
 230
 231 /*
 232  * Entry point to finalise EL2 and switch to VHE if deemed capable
 233  *
 234  * w0: boot mode, as returned by init_kernel_el()
 235  */
 236 SYM_FUNC_START(finalise_el2)
 237         // Need to have booted at EL2
 238         cmp     w0, #BOOT_CPU_MODE_EL2
 239         b.ne    1f
 240
 241         // and still be at EL1
 242         mrs     x0, CurrentEL
 243         cmp     x0, #CurrentEL_EL1
 244         b.ne    1f
 245
 246         mov     x0, #HVC_FINALISE_EL2
 247         hvc     #0
 248 1:
 249         ret
 250 SYM_FUNC_END(finalise_el2)