arch/arm64/kernel/head.S

   1 /* SPDX-License-Identifier: GPL-2.0-only */
   2 /*
   3  * Low-level CPU initialisation
   4  * Based on arch/arm/kernel/head.S
   5  *
   6  * Copyright (C) 1994-2002 Russell King
   7  * Copyright (C) 2003-2012 ARM Ltd.
   8  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   9  *              Will Deacon <will.deacon@arm.com>
  10  */
  11
  12 #include <linux/linkage.h>
  13 #include <linux/init.h>
  14 #include <linux/pgtable.h>
  15
  16 #include <asm/asm_pointer_auth.h>
  17 #include <asm/assembler.h>
  18 #include <asm/boot.h>
  19 #include <asm/ptrace.h>
  20 #include <asm/asm-offsets.h>
  21 #include <asm/cache.h>
  22 #include <asm/cputype.h>
  23 #include <asm/el2_setup.h>
  24 #include <asm/elf.h>
  25 #include <asm/image.h>
  26 #include <asm/kernel-pgtable.h>
  27 #include <asm/kvm_arm.h>
  28 #include <asm/memory.h>
  29 #include <asm/pgtable-hwdef.h>
  30 #include <asm/page.h>
  31 #include <asm/scs.h>
  32 #include <asm/smp.h>
  33 #include <asm/sysreg.h>
  34 #include <asm/thread_info.h>
  35 #include <asm/virt.h>
  36
  37 #include "efi-header.S"
  38
  39 #define __PHYS_OFFSET   KERNEL_START
  40
  41 #if (PAGE_OFFSET & 0x1fffff) != 0
  42 #error PAGE_OFFSET must be at least 2MB aligned
  43 #endif
  44
  45 /*
  46  * Kernel startup entry point.
  47  * ---------------------------
  48  *
  49  * The requirements are:
  50  *   MMU = off, D-cache = off, I-cache = on or off,
  51  *   x0 = physical address to the FDT blob.
  52  *
  53  * This code is mostly position independent so you call this at
  54  * __pa(PAGE_OFFSET).
  55  *
  56  * Note that the callee-saved registers are used for storing variables
  57  * that are useful before the MMU is enabled. The allocations are described
  58  * in the entry routines.
  59  */
  60         __HEAD
  61         /*
  62          * DO NOT MODIFY. Image header expected by Linux boot-loaders.
  63          */
  64         efi_signature_nop                       // special NOP to identity as PE/COFF executable
  65         b       primary_entry                   // branch to kernel start, magic
  66         .quad   0                               // Image load offset from start of RAM, little-endian
  67         le64sym _kernel_size_le                 // Effective size of kernel image, little-endian
  68         le64sym _kernel_flags_le                // Informative flags, little-endian
  69         .quad   0                               // reserved
  70         .quad   0                               // reserved
  71         .quad   0                               // reserved
  72         .ascii  ARM64_IMAGE_MAGIC               // Magic number
  73         .long   .Lpe_header_offset              // Offset to the PE header.
  74
  75         __EFI_PE_HEADER
  76
  77         __INIT
  78
  79         /*
  80          * The following callee saved general purpose registers are used on the
  81          * primary lowlevel boot path:
  82          *
  83          *  Register   Scope                      Purpose
  84          *  x21        primary_entry() .. start_kernel()        FDT pointer passed at boot in x0
  85          *  x23        primary_entry() .. start_kernel()        physical misalignment/KASLR offset
  86          *  x28        __create_page_tables()                   callee preserved temp register
  87          *  x19/x20    __primary_switch()                       callee preserved temp registers
  88          *  x24        __primary_switch() .. relocate_kernel()  current RELR displacement
  89          */
  90 SYM_CODE_START(primary_entry)
  91         bl      preserve_boot_args
  92         bl      init_kernel_el                  // w0=cpu_boot_mode
  93         adrp    x23, __PHYS_OFFSET
  94         and     x23, x23, MIN_KIMG_ALIGN - 1    // KASLR offset, defaults to 0
  95         bl      set_cpu_boot_mode_flag
  96         bl      __create_page_tables
  97         /*
  98          * The following calls CPU setup code, see arch/arm64/mm/proc.S for
  99          * details.
 100          * On return, the CPU will be ready for the MMU to be turned on and
 101          * the TCR will have been set.
 102          */
 103         bl      __cpu_setup                     // initialise processor
 104         b       __primary_switch
 105 SYM_CODE_END(primary_entry)
 106
 107 /*
 108  * Preserve the arguments passed by the bootloader in x0 .. x3
 109  */
 110 SYM_CODE_START_LOCAL(preserve_boot_args)
 111         mov     x21, x0                         // x21=FDT
 112
 113         adr_l   x0, boot_args                   // record the contents of
 114         stp     x21, x1, [x0]                   // x0 .. x3 at kernel entry
 115         stp     x2, x3, [x0, #16]
 116
 117         dmb     sy                              // needed before dc ivac with
 118                                                 // MMU off
 119
 120         mov     x1, #0x20                       // 4 x 8 bytes
 121         b       __inval_dcache_area             // tail call
 122 SYM_CODE_END(preserve_boot_args)
 123
 124 /*
 125  * Macro to create a table entry to the next page.
 126  *
 127  *      tbl:    page table address
 128  *      virt:   virtual address
 129  *      shift:  #imm page table shift
 130  *      ptrs:   #imm pointers per table page
 131  *
 132  * Preserves:   virt
 133  * Corrupts:    ptrs, tmp1, tmp2
 134  * Returns:     tbl -> next level table page address
 135  */
 136         .macro  create_table_entry, tbl, virt, shift, ptrs, tmp1, tmp2
 137         add     \tmp1, \tbl, #PAGE_SIZE
 138         phys_to_pte \tmp2, \tmp1
 139         orr     \tmp2, \tmp2, #PMD_TYPE_TABLE   // address of next table and entry type
 140         lsr     \tmp1, \virt, #\shift
 141         sub     \ptrs, \ptrs, #1
 142         and     \tmp1, \tmp1, \ptrs             // table index
 143         str     \tmp2, [\tbl, \tmp1, lsl #3]
 144         add     \tbl, \tbl, #PAGE_SIZE          // next level table page
 145         .endm
 146
 147 /*
 148  * Macro to populate page table entries, these entries can be pointers to the next level
 149  * or last level entries pointing to physical memory.
 150  *
 151  *      tbl:    page table address
 152  *      rtbl:   pointer to page table or physical memory
 153  *      index:  start index to write
 154  *      eindex: end index to write - [index, eindex] written to
 155  *      flags:  flags for pagetable entry to or in
 156  *      inc:    increment to rtbl between each entry
 157  *      tmp1:   temporary variable
 158  *
 159  * Preserves:   tbl, eindex, flags, inc
 160  * Corrupts:    index, tmp1
 161  * Returns:     rtbl
 162  */
 163         .macro populate_entries, tbl, rtbl, index, eindex, flags, inc, tmp1
 164 .Lpe\@: phys_to_pte \tmp1, \rtbl
 165         orr     \tmp1, \tmp1, \flags    // tmp1 = table entry
 166         str     \tmp1, [\tbl, \index, lsl #3]
 167         add     \rtbl, \rtbl, \inc      // rtbl = pa next level
 168         add     \index, \index, #1
 169         cmp     \index, \eindex
 170         b.ls    .Lpe\@
 171         .endm
 172
 173 /*
 174  * Compute indices of table entries from virtual address range. If multiple entries
 175  * were needed in the previous page table level then the next page table level is assumed
 176  * to be composed of multiple pages. (This effectively scales the end index).
 177  *
 178  *      vstart: virtual address of start of range
 179  *      vend:   virtual address of end of range
 180  *      shift:  shift used to transform virtual address into index
 181  *      ptrs:   number of entries in page table
 182  *      istart: index in table corresponding to vstart
 183  *      iend:   index in table corresponding to vend
 184  *      count:  On entry: how many extra entries were required in previous level, scales
 185  *                        our end index.
 186  *              On exit: returns how many extra entries required for next page table level
 187  *
 188  * Preserves:   vstart, vend, shift, ptrs
 189  * Returns:     istart, iend, count
 190  */
 191         .macro compute_indices, vstart, vend, shift, ptrs, istart, iend, count
 192         lsr     \iend, \vend, \shift
 193         mov     \istart, \ptrs
 194         sub     \istart, \istart, #1
 195         and     \iend, \iend, \istart   // iend = (vend >> shift) & (ptrs - 1)
 196         mov     \istart, \ptrs
 197         mul     \istart, \istart, \count
 198         add     \iend, \iend, \istart   // iend += (count - 1) * ptrs
 199                                         // our entries span multiple tables
 200
 201         lsr     \istart, \vstart, \shift
 202         mov     \count, \ptrs
 203         sub     \count, \count, #1
 204         and     \istart, \istart, \count
 205
 206         sub     \count, \iend, \istart
 207         .endm
 208
 209 /*
 210  * Map memory for specified virtual address range. Each level of page table needed supports
 211  * multiple entries. If a level requires n entries the next page table level is assumed to be
 212  * formed from n pages.
 213  *
 214  *      tbl:    location of page table
 215  *      rtbl:   address to be used for first level page table entry (typically tbl + PAGE_SIZE)
 216  *      vstart: start address to map
 217  *      vend:   end address to map - we map [vstart, vend]
 218  *      flags:  flags to use to map last level entries
 219  *      phys:   physical address corresponding to vstart - physical memory is contiguous
 220  *      pgds:   the number of pgd entries
 221  *
 222  * Temporaries: istart, iend, tmp, count, sv - these need to be different registers
 223  * Preserves:   vstart, vend, flags
 224  * Corrupts:    tbl, rtbl, istart, iend, tmp, count, sv
 225  */
 226         .macro map_memory, tbl, rtbl, vstart, vend, flags, phys, pgds, istart, iend, tmp, count, sv
 227         add \rtbl, \tbl, #PAGE_SIZE
 228         mov \sv, \rtbl
 229         mov \count, #0
 230         compute_indices \vstart, \vend, #PGDIR_SHIFT, \pgds, \istart, \iend, \count
 231         populate_entries \tbl, \rtbl, \istart, \iend, #PMD_TYPE_TABLE, #PAGE_SIZE, \tmp
 232         mov \tbl, \sv
 233         mov \sv, \rtbl
 234
 235 #if SWAPPER_PGTABLE_LEVELS > 3
 236         compute_indices \vstart, \vend, #PUD_SHIFT, #PTRS_PER_PUD, \istart, \iend, \count
 237         populate_entries \tbl, \rtbl, \istart, \iend, #PMD_TYPE_TABLE, #PAGE_SIZE, \tmp
 238         mov \tbl, \sv
 239         mov \sv, \rtbl
 240 #endif
 241
 242 #if SWAPPER_PGTABLE_LEVELS > 2
 243         compute_indices \vstart, \vend, #SWAPPER_TABLE_SHIFT, #PTRS_PER_PMD, \istart, \iend, \count
 244         populate_entries \tbl, \rtbl, \istart, \iend, #PMD_TYPE_TABLE, #PAGE_SIZE, \tmp
 245         mov \tbl, \sv
 246 #endif
 247
 248         compute_indices \vstart, \vend, #SWAPPER_BLOCK_SHIFT, #PTRS_PER_PTE, \istart, \iend, \count
 249         bic \count, \phys, #SWAPPER_BLOCK_SIZE - 1
 250         populate_entries \tbl, \count, \istart, \iend, \flags, #SWAPPER_BLOCK_SIZE, \tmp
 251         .endm
 252
 253 /*
 254  * Setup the initial page tables. We only setup the barest amount which is
 255  * required to get the kernel running. The following sections are required:
 256  *   - identity mapping to enable the MMU (low address, TTBR0)
 257  *   - first few MB of the kernel linear mapping to jump to once the MMU has
 258  *     been enabled
 259  */
 260 SYM_FUNC_START_LOCAL(__create_page_tables)
 261         mov     x28, lr
 262
 263         /*
 264          * Invalidate the init page tables to avoid potential dirty cache lines
 265          * being evicted. Other page tables are allocated in rodata as part of
 266          * the kernel image, and thus are clean to the PoC per the boot
 267          * protocol.
 268          */
 269         adrp    x0, init_pg_dir
 270         adrp    x1, init_pg_end
 271         sub     x1, x1, x0
 272         bl      __inval_dcache_area
 273
 274         /*
 275          * Clear the init page tables.
 276          */
 277         adrp    x0, init_pg_dir
 278         adrp    x1, init_pg_end
 279         sub     x1, x1, x0
 280 1:      stp     xzr, xzr, [x0], #16
 281         stp     xzr, xzr, [x0], #16
 282         stp     xzr, xzr, [x0], #16
 283         stp     xzr, xzr, [x0], #16
 284         subs    x1, x1, #64
 285         b.ne    1b
 286
 287         mov     x7, SWAPPER_MM_MMUFLAGS
 288
 289         /*
 290          * Create the identity mapping.
 291          */
 292         adrp    x0, idmap_pg_dir
 293         adrp    x3, __idmap_text_start          // __pa(__idmap_text_start)
 294
 295 #ifdef CONFIG_ARM64_VA_BITS_52
 296         mrs_s   x6, SYS_ID_AA64MMFR2_EL1
 297         and     x6, x6, #(0xf << ID_AA64MMFR2_LVA_SHIFT)
 298         mov     x5, #52
 299         cbnz    x6, 1f
 300 #endif
 301         mov     x5, #VA_BITS_MIN
 302 1:
 303         adr_l   x6, vabits_actual
 304         str     x5, [x6]
 305         dmb     sy
 306         dc      ivac, x6                // Invalidate potentially stale cache line
 307
 308         /*
 309          * VA_BITS may be too small to allow for an ID mapping to be created
 310          * that covers system RAM if that is located sufficiently high in the
 311          * physical address space. So for the ID map, use an extended virtual
 312          * range in that case, and configure an additional translation level
 313          * if needed.
 314          *
 315          * Calculate the maximum allowed value for TCR_EL1.T0SZ so that the
 316          * entire ID map region can be mapped. As T0SZ == (64 - #bits used),
 317          * this number conveniently equals the number of leading zeroes in
 318          * the physical address of __idmap_text_end.
 319          */
 320         adrp    x5, __idmap_text_end
 321         clz     x5, x5
 322         cmp     x5, TCR_T0SZ(VA_BITS_MIN) // default T0SZ small enough?
 323         b.ge    1f                      // .. then skip VA range extension
 324
 325         adr_l   x6, idmap_t0sz
 326         str     x5, [x6]
 327         dmb     sy
 328         dc      ivac, x6                // Invalidate potentially stale cache line
 329
 330 #if (VA_BITS < 48)
 331 #define EXTRA_SHIFT     (PGDIR_SHIFT + PAGE_SHIFT - 3)
 332 #define EXTRA_PTRS      (1 << (PHYS_MASK_SHIFT - EXTRA_SHIFT))
 333
 334         /*
 335          * If VA_BITS < 48, we have to configure an additional table level.
 336          * First, we have to verify our assumption that the current value of
 337          * VA_BITS was chosen such that all translation levels are fully
 338          * utilised, and that lowering T0SZ will always result in an additional
 339          * translation level to be configured.
 340          */
 341 #if VA_BITS != EXTRA_SHIFT
 342 #error "Mismatch between VA_BITS and page size/number of translation levels"
 343 #endif
 344
 345         mov     x4, EXTRA_PTRS
 346         create_table_entry x0, x3, EXTRA_SHIFT, x4, x5, x6
 347 #else
 348         /*
 349          * If VA_BITS == 48, we don't have to configure an additional
 350          * translation level, but the top-level table has more entries.
 351          */
 352         mov     x4, #1 << (PHYS_MASK_SHIFT - PGDIR_SHIFT)
 353         str_l   x4, idmap_ptrs_per_pgd, x5
 354 #endif
 355 1:
 356         ldr_l   x4, idmap_ptrs_per_pgd
 357         mov     x5, x3                          // __pa(__idmap_text_start)
 358         adr_l   x6, __idmap_text_end            // __pa(__idmap_text_end)
 359
 360         map_memory x0, x1, x3, x6, x7, x3, x4, x10, x11, x12, x13, x14
 361
 362         /*
 363          * Map the kernel image (starting with PHYS_OFFSET).
 364          */
 365         adrp    x0, init_pg_dir
 366         mov_q   x5, KIMAGE_VADDR                // compile time __va(_text)
 367         add     x5, x5, x23                     // add KASLR displacement
 368         mov     x4, PTRS_PER_PGD
 369         adrp    x6, _end                        // runtime __pa(_end)
 370         adrp    x3, _text                       // runtime __pa(_text)
 371         sub     x6, x6, x3                      // _end - _text
 372         add     x6, x6, x5                      // runtime __va(_end)
 373
 374         map_memory x0, x1, x5, x6, x7, x3, x4, x10, x11, x12, x13, x14
 375
 376         /*
 377          * Since the page tables have been populated with non-cacheable
 378          * accesses (MMU disabled), invalidate those tables again to
 379          * remove any speculatively loaded cache lines.
 380          */
 381         dmb     sy
 382
 383         adrp    x0, idmap_pg_dir
 384         adrp    x1, idmap_pg_end
 385         sub     x1, x1, x0
 386         bl      __inval_dcache_area
 387
 388         adrp    x0, init_pg_dir
 389         adrp    x1, init_pg_end
 390         sub     x1, x1, x0
 391         bl      __inval_dcache_area
 392
 393         ret     x28
 394 SYM_FUNC_END(__create_page_tables)
 395
 396 /*
 397  * The following fragment of code is executed with the MMU enabled.
 398  *
 399  *   x0 = __PHYS_OFFSET
 400  */
 401 SYM_FUNC_START_LOCAL(__primary_switched)
 402         adrp    x4, init_thread_union
 403         add     sp, x4, #THREAD_SIZE
 404         adr_l   x5, init_task
 405         msr     sp_el0, x5                      // Save thread_info
 406
 407         adr_l   x8, vectors                     // load VBAR_EL1 with virtual
 408         msr     vbar_el1, x8                    // vector table address
 409         isb
 410
 411         stp     xzr, x30, [sp, #-16]!
 412         mov     x29, sp
 413
 414 #ifdef CONFIG_SHADOW_CALL_STACK
 415         adr_l   scs_sp, init_shadow_call_stack  // Set shadow call stack
 416 #endif
 417
 418         str_l   x21, __fdt_pointer, x5          // Save FDT pointer
 419
 420         ldr_l   x4, kimage_vaddr                // Save the offset between
 421         sub     x4, x4, x0                      // the kernel virtual and
 422         str_l   x4, kimage_voffset, x5          // physical mappings
 423
 424         // Clear BSS
 425         adr_l   x0, __bss_start
 426         mov     x1, xzr
 427         adr_l   x2, __bss_stop
 428         sub     x2, x2, x0
 429         bl      __pi_memset
 430         dsb     ishst                           // Make zero page visible to PTW
 431
 432 #if defined(CONFIG_KASAN_GENERIC) || defined(CONFIG_KASAN_SW_TAGS)
 433         bl      kasan_early_init
 434 #endif
 435         mov     x0, x21                         // pass FDT address in x0
 436         bl      early_fdt_map                   // Try mapping the FDT early
 437         bl      init_feature_override           // Parse cpu feature overrides
 438 #ifdef CONFIG_RANDOMIZE_BASE
 439         tst     x23, ~(MIN_KIMG_ALIGN - 1)      // already running randomized?
 440         b.ne    0f
 441         bl      kaslr_early_init                // parse FDT for KASLR options
 442         cbz     x0, 0f                          // KASLR disabled? just proceed
 443         orr     x23, x23, x0                    // record KASLR offset
 444         ldp     x29, x30, [sp], #16             // we must enable KASLR, return
 445         ret                                     // to __primary_switch()
 446 0:
 447 #endif
 448         bl      switch_to_vhe                   // Prefer VHE if possible
 449         add     sp, sp, #16
 450         mov     x29, #0
 451         mov     x30, #0
 452         b       start_kernel
 453 SYM_FUNC_END(__primary_switched)
 454
 455         .pushsection ".rodata", "a"
 456 SYM_DATA_START(kimage_vaddr)
 457         .quad           _text
 458 SYM_DATA_END(kimage_vaddr)
 459 EXPORT_SYMBOL(kimage_vaddr)
 460         .popsection
 461
 462 /*
 463  * end early head section, begin head code that is also used for
 464  * hotplug and needs to have the same protections as the text region
 465  */
 466         .section ".idmap.text","awx"
 467
 468 /*
 469  * Starting from EL2 or EL1, configure the CPU to execute at the highest
 470  * reachable EL supported by the kernel in a chosen default state. If dropping
 471  * from EL2 to EL1, configure EL2 before configuring EL1.
 472  *
 473  * Since we cannot always rely on ERET synchronizing writes to sysregs (e.g. if
 474  * SCTLR_ELx.EOS is clear), we place an ISB prior to ERET.
 475  *
 476  * Returns either BOOT_CPU_MODE_EL1 or BOOT_CPU_MODE_EL2 in w0 if
 477  * booted in EL1 or EL2 respectively.
 478  */
 479 SYM_FUNC_START(init_kernel_el)
 480         mov_q   x0, INIT_SCTLR_EL1_MMU_OFF
 481         msr     sctlr_el1, x0
 482
 483         mrs     x0, CurrentEL
 484         cmp     x0, #CurrentEL_EL2
 485         b.eq    init_el2
 486
 487 SYM_INNER_LABEL(init_el1, SYM_L_LOCAL)
 488         isb
 489         mov_q   x0, INIT_PSTATE_EL1
 490         msr     spsr_el1, x0
 491         msr     elr_el1, lr
 492         mov     w0, #BOOT_CPU_MODE_EL1
 493         eret
 494
 495 SYM_INNER_LABEL(init_el2, SYM_L_LOCAL)
 496         mov_q   x0, HCR_HOST_NVHE_FLAGS
 497         msr     hcr_el2, x0
 498         isb
 499
 500         init_el2_state
 501
 502         /* Hypervisor stub */
 503         adr_l   x0, __hyp_stub_vectors
 504         msr     vbar_el2, x0
 505         isb
 506
 507         msr     elr_el2, lr
 508         mov     w0, #BOOT_CPU_MODE_EL2
 509         eret
 510 SYM_FUNC_END(init_kernel_el)
 511
 512 /*
 513  * Sets the __boot_cpu_mode flag depending on the CPU boot mode passed
 514  * in w0. See arch/arm64/include/asm/virt.h for more info.
 515  */
 516 SYM_FUNC_START_LOCAL(set_cpu_boot_mode_flag)
 517         adr_l   x1, __boot_cpu_mode
 518         cmp     w0, #BOOT_CPU_MODE_EL2
 519         b.ne    1f
 520         add     x1, x1, #4
 521 1:      str     w0, [x1]                        // This CPU has booted in EL1
 522         dmb     sy
 523         dc      ivac, x1                        // Invalidate potentially stale cache line
 524         ret
 525 SYM_FUNC_END(set_cpu_boot_mode_flag)
 526
 527 /*
 528  * These values are written with the MMU off, but read with the MMU on.
 529  * Writers will invalidate the corresponding address, discarding up to a
 530  * 'Cache Writeback Granule' (CWG) worth of data. The linker script ensures
 531  * sufficient alignment that the CWG doesn't overlap another section.
 532  */
 533         .pushsection ".mmuoff.data.write", "aw"
 534 /*
 535  * We need to find out the CPU boot mode long after boot, so we need to
 536  * store it in a writable variable.
 537  *
 538  * This is not in .bss, because we set it sufficiently early that the boot-time
 539  * zeroing of .bss would clobber it.
 540  */
 541 SYM_DATA_START(__boot_cpu_mode)
 542         .long   BOOT_CPU_MODE_EL2
 543         .long   BOOT_CPU_MODE_EL1
 544 SYM_DATA_END(__boot_cpu_mode)
 545 /*
 546  * The booting CPU updates the failed status @__early_cpu_boot_status,
 547  * with MMU turned off.
 548  */
 549 SYM_DATA_START(__early_cpu_boot_status)
 550         .quad   0
 551 SYM_DATA_END(__early_cpu_boot_status)
 552
 553         .popsection
 554
 555         /*
 556          * This provides a "holding pen" for platforms to hold all secondary
 557          * cores are held until we're ready for them to initialise.
 558          */
 559 SYM_FUNC_START(secondary_holding_pen)
 560         bl      init_kernel_el                  // w0=cpu_boot_mode
 561         bl      set_cpu_boot_mode_flag
 562         mrs     x0, mpidr_el1
 563         mov_q   x1, MPIDR_HWID_BITMASK
 564         and     x0, x0, x1
 565         adr_l   x3, secondary_holding_pen_release
 566 pen:    ldr     x4, [x3]
 567         cmp     x4, x0
 568         b.eq    secondary_startup
 569         wfe
 570         b       pen
 571 SYM_FUNC_END(secondary_holding_pen)
 572
 573         /*
 574          * Secondary entry point that jumps straight into the kernel. Only to
 575          * be used where CPUs are brought online dynamically by the kernel.
 576          */
 577 SYM_FUNC_START(secondary_entry)
 578         bl      init_kernel_el                  // w0=cpu_boot_mode
 579         bl      set_cpu_boot_mode_flag
 580         b       secondary_startup
 581 SYM_FUNC_END(secondary_entry)
 582
 583 SYM_FUNC_START_LOCAL(secondary_startup)
 584         /*
 585          * Common entry point for secondary CPUs.
 586          */
 587         bl      switch_to_vhe
 588         bl      __cpu_secondary_check52bitva
 589         bl      __cpu_setup                     // initialise processor
 590         adrp    x1, swapper_pg_dir
 591         bl      __enable_mmu
 592         ldr     x8, =__secondary_switched
 593         br      x8
 594 SYM_FUNC_END(secondary_startup)
 595
 596 SYM_FUNC_START_LOCAL(__secondary_switched)
 597         adr_l   x5, vectors
 598         msr     vbar_el1, x5
 599         isb
 600
 601         adr_l   x0, secondary_data
 602         ldr     x1, [x0, #CPU_BOOT_STACK]       // get secondary_data.stack
 603         cbz     x1, __secondary_too_slow
 604         mov     sp, x1
 605         ldr     x2, [x0, #CPU_BOOT_TASK]
 606         cbz     x2, __secondary_too_slow
 607         msr     sp_el0, x2
 608         scs_load x2, x3
 609         mov     x29, #0
 610         mov     x30, #0
 611
 612 #ifdef CONFIG_ARM64_PTR_AUTH
 613         ptrauth_keys_init_cpu x2, x3, x4, x5
 614 #endif
 615
 616         b       secondary_start_kernel
 617 SYM_FUNC_END(__secondary_switched)
 618
 619 SYM_FUNC_START_LOCAL(__secondary_too_slow)
 620         wfe
 621         wfi
 622         b       __secondary_too_slow
 623 SYM_FUNC_END(__secondary_too_slow)
 624
 625 /*
 626  * The booting CPU updates the failed status @__early_cpu_boot_status,
 627  * with MMU turned off.
 628  *
 629  * update_early_cpu_boot_status tmp, status
 630  *  - Corrupts tmp1, tmp2
 631  *  - Writes 'status' to __early_cpu_boot_status and makes sure
 632  *    it is committed to memory.
 633  */
 634
 635         .macro  update_early_cpu_boot_status status, tmp1, tmp2
 636         mov     \tmp2, #\status
 637         adr_l   \tmp1, __early_cpu_boot_status
 638         str     \tmp2, [\tmp1]
 639         dmb     sy
 640         dc      ivac, \tmp1                     // Invalidate potentially stale cache line
 641         .endm
 642
 643 /*
 644  * Enable the MMU.
 645  *
 646  *  x0  = SCTLR_EL1 value for turning on the MMU.
 647  *  x1  = TTBR1_EL1 value
 648  *
 649  * Returns to the caller via x30/lr. This requires the caller to be covered
 650  * by the .idmap.text section.
 651  *
 652  * Checks if the selected granule size is supported by the CPU.
 653  * If it isn't, park the CPU
 654  */
 655 SYM_FUNC_START(__enable_mmu)
 656         mrs     x2, ID_AA64MMFR0_EL1
 657         ubfx    x2, x2, #ID_AA64MMFR0_TGRAN_SHIFT, 4
 658         cmp     x2, #ID_AA64MMFR0_TGRAN_SUPPORTED_MIN
 659         b.lt    __no_granule_support
 660         cmp     x2, #ID_AA64MMFR0_TGRAN_SUPPORTED_MAX
 661         b.gt    __no_granule_support
 662         update_early_cpu_boot_status 0, x2, x3
 663         adrp    x2, idmap_pg_dir
 664         phys_to_ttbr x1, x1
 665         phys_to_ttbr x2, x2
 666         msr     ttbr0_el1, x2                   // load TTBR0
 667         offset_ttbr1 x1, x3
 668         msr     ttbr1_el1, x1                   // load TTBR1
 669         isb
 670
 671         set_sctlr_el1   x0
 672
 673         ret
 674 SYM_FUNC_END(__enable_mmu)
 675
 676 SYM_FUNC_START(__cpu_secondary_check52bitva)
 677 #ifdef CONFIG_ARM64_VA_BITS_52
 678         ldr_l   x0, vabits_actual
 679         cmp     x0, #52
 680         b.ne    2f
 681
 682         mrs_s   x0, SYS_ID_AA64MMFR2_EL1
 683         and     x0, x0, #(0xf << ID_AA64MMFR2_LVA_SHIFT)
 684         cbnz    x0, 2f
 685
 686         update_early_cpu_boot_status \
 687                 CPU_STUCK_IN_KERNEL | CPU_STUCK_REASON_52_BIT_VA, x0, x1
 688 1:      wfe
 689         wfi
 690         b       1b
 691
 692 #endif
 693 2:      ret
 694 SYM_FUNC_END(__cpu_secondary_check52bitva)
 695
 696 SYM_FUNC_START_LOCAL(__no_granule_support)
 697         /* Indicate that this CPU can't boot and is stuck in the kernel */
 698         update_early_cpu_boot_status \
 699                 CPU_STUCK_IN_KERNEL | CPU_STUCK_REASON_NO_GRAN, x1, x2
 700 1:
 701         wfe
 702         wfi
 703         b       1b
 704 SYM_FUNC_END(__no_granule_support)
 705
 706 #ifdef CONFIG_RELOCATABLE
 707 SYM_FUNC_START_LOCAL(__relocate_kernel)
 708         /*
 709          * Iterate over each entry in the relocation table, and apply the
 710          * relocations in place.
 711          */
 712         ldr     w9, =__rela_offset              // offset to reloc table
 713         ldr     w10, =__rela_size               // size of reloc table
 714
 715         mov_q   x11, KIMAGE_VADDR               // default virtual offset
 716         add     x11, x11, x23                   // actual virtual offset
 717         add     x9, x9, x11                     // __va(.rela)
 718         add     x10, x9, x10                    // __va(.rela) + sizeof(.rela)
 719
 720 0:      cmp     x9, x10
 721         b.hs    1f
 722         ldp     x12, x13, [x9], #24
 723         ldr     x14, [x9, #-8]
 724         cmp     w13, #R_AARCH64_RELATIVE
 725         b.ne    0b
 726         add     x14, x14, x23                   // relocate
 727         str     x14, [x12, x23]
 728         b       0b
 729
 730 1:
 731 #ifdef CONFIG_RELR
 732         /*
 733          * Apply RELR relocations.
 734          *
 735          * RELR is a compressed format for storing relative relocations. The
 736          * encoded sequence of entries looks like:
 737          * [ AAAAAAAA BBBBBBB1 BBBBBBB1 ... AAAAAAAA BBBBBB1 ... ]
 738          *
 739          * i.e. start with an address, followed by any number of bitmaps. The
 740          * address entry encodes 1 relocation. The subsequent bitmap entries
 741          * encode up to 63 relocations each, at subsequent offsets following
 742          * the last address entry.
 743          *
 744          * The bitmap entries must have 1 in the least significant bit. The
 745          * assumption here is that an address cannot have 1 in lsb. Odd
 746          * addresses are not supported. Any odd addresses are stored in the RELA
 747          * section, which is handled above.
 748          *
 749          * Excluding the least significant bit in the bitmap, each non-zero
 750          * bit in the bitmap represents a relocation to be applied to
 751          * a corresponding machine word that follows the base address
 752          * word. The second least significant bit represents the machine
 753          * word immediately following the initial address, and each bit
 754          * that follows represents the next word, in linear order. As such,
 755          * a single bitmap can encode up to 63 relocations in a 64-bit object.
 756          *
 757          * In this implementation we store the address of the next RELR table
 758          * entry in x9, the address being relocated by the current address or
 759          * bitmap entry in x13 and the address being relocated by the current
 760          * bit in x14.
 761          *
 762          * Because addends are stored in place in the binary, RELR relocations
 763          * cannot be applied idempotently. We use x24 to keep track of the
 764          * currently applied displacement so that we can correctly relocate if
 765          * __relocate_kernel is called twice with non-zero displacements (i.e.
 766          * if there is both a physical misalignment and a KASLR displacement).
 767          */
 768         ldr     w9, =__relr_offset              // offset to reloc table
 769         ldr     w10, =__relr_size               // size of reloc table
 770         add     x9, x9, x11                     // __va(.relr)
 771         add     x10, x9, x10                    // __va(.relr) + sizeof(.relr)
 772
 773         sub     x15, x23, x24                   // delta from previous offset
 774         cbz     x15, 7f                         // nothing to do if unchanged
 775         mov     x24, x23                        // save new offset
 776
 777 2:      cmp     x9, x10
 778         b.hs    7f
 779         ldr     x11, [x9], #8
 780         tbnz    x11, #0, 3f                     // branch to handle bitmaps
 781         add     x13, x11, x23
 782         ldr     x12, [x13]                      // relocate address entry
 783         add     x12, x12, x15
 784         str     x12, [x13], #8                  // adjust to start of bitmap
 785         b       2b
 786
 787 3:      mov     x14, x13
 788 4:      lsr     x11, x11, #1
 789         cbz     x11, 6f
 790         tbz     x11, #0, 5f                     // skip bit if not set
 791         ldr     x12, [x14]                      // relocate bit
 792         add     x12, x12, x15
 793         str     x12, [x14]
 794
 795 5:      add     x14, x14, #8                    // move to next bit's address
 796         b       4b
 797
 798 6:      /*
 799          * Move to the next bitmap's address. 8 is the word size, and 63 is the
 800          * number of significant bits in a bitmap entry.
 801          */
 802         add     x13, x13, #(8 * 63)
 803         b       2b
 804
 805 7:
 806 #endif
 807         ret
 808
 809 SYM_FUNC_END(__relocate_kernel)
 810 #endif
 811
 812 SYM_FUNC_START_LOCAL(__primary_switch)
 813 #ifdef CONFIG_RANDOMIZE_BASE
 814         mov     x19, x0                         // preserve new SCTLR_EL1 value
 815         mrs     x20, sctlr_el1                  // preserve old SCTLR_EL1 value
 816 #endif
 817
 818         adrp    x1, init_pg_dir
 819         bl      __enable_mmu
 820 #ifdef CONFIG_RELOCATABLE
 821 #ifdef CONFIG_RELR
 822         mov     x24, #0                         // no RELR displacement yet
 823 #endif
 824         bl      __relocate_kernel
 825 #ifdef CONFIG_RANDOMIZE_BASE
 826         ldr     x8, =__primary_switched
 827         adrp    x0, __PHYS_OFFSET
 828         blr     x8
 829
 830         /*
 831          * If we return here, we have a KASLR displacement in x23 which we need
 832          * to take into account by discarding the current kernel mapping and
 833          * creating a new one.
 834          */
 835         pre_disable_mmu_workaround
 836         msr     sctlr_el1, x20                  // disable the MMU
 837         isb
 838         bl      __create_page_tables            // recreate kernel mapping
 839
 840         tlbi    vmalle1                         // Remove any stale TLB entries
 841         dsb     nsh
 842         isb
 843
 844         set_sctlr_el1   x19                     // re-enable the MMU
 845
 846         bl      __relocate_kernel
 847 #endif
 848 #endif
 849         ldr     x8, =__primary_switched
 850         adrp    x0, __PHYS_OFFSET
 851         br      x8
 852 SYM_FUNC_END(__primary_switch)