acinclude.m4

   1 dnl Macros that test for specific features.
   2 dnl This file is part of the Autoconf packaging for Ethereal.
   3 dnl Copyright (C) 1998-2000 by Gerald Combs.
   4 dnl
   5 dnl $Id$
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2, or (at your option)
  10 dnl any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20 dnl 02111-1307, USA.
  21 dnl
  22 dnl As a special exception, the Free Software Foundation gives unlimited
  23 dnl permission to copy, distribute and modify the configure scripts that
  24 dnl are the output of Autoconf.  You need not follow the terms of the GNU
  25 dnl General Public License when using or distributing such scripts, even
  26 dnl though portions of the text of Autoconf appear in them.  The GNU
  27 dnl General Public License (GPL) does govern all other use of the material
  28 dnl that constitutes the Autoconf program.
  29 dnl
  30 dnl Certain portions of the Autoconf source text are designed to be copied
  31 dnl (in certain cases, depending on the input) into the output of
  32 dnl Autoconf.  We call these the "data" portions.  The rest of the Autoconf
  33 dnl source text consists of comments plus executable code that decides which
  34 dnl of the data portions to output in any given case.  We call these
  35 dnl comments and executable code the "non-data" portions.  Autoconf never
  36 dnl copies any of the non-data portions into its output.
  37 dnl
  38 dnl This special exception to the GPL applies to versions of Autoconf
  39 dnl released by the Free Software Foundation.  When you make and
  40 dnl distribute a modified version of Autoconf, you may extend this special
  41 dnl exception to the GPL to apply to your modified version as well, *unless*
  42 dnl your modified version has the potential to copy into its output some
  43 dnl of the text that was the non-data portion of the version that you started
  44 dnl with.  (In other words, unless your change moves or copies text from
  45 dnl the non-data portions to the data portions.)  If your modification has
  46 dnl such potential, you must delete any notice of this special exception
  47 dnl to the GPL from your modified version.
  48 dnl
  49 dnl Written by David MacKenzie, with help from
  50 dnl Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
  51 dnl Roland McGrath, Noah Friedman, david d zuhn, and many others.
  52
  53 #
  54 # AC_ETHEREAL_ADD_DASH_L
  55 #
  56 # Add to the variable specified as the first argument a "-L" flag for the
  57 # directory specified as the second argument, and, on Solaris, add a
  58 # "-R" flag for it as well.
  59 #
  60 # XXX - IRIX, and other OSes, may require some flag equivalent to
  61 # "-R" here.
  62 #
  63 AC_DEFUN([AC_ETHEREAL_ADD_DASH_L],
  64 [$1="$$1 -L$2"
  65 case "$host_os" in
  66   solaris*)
  67     $1="$$1 -R$2"
  68   ;;
  69 esac
  70 ])
  71
  72
  73 #
  74 # AC_ETHEREAL_STRUCT_SA_LEN
  75 #
  76 dnl AC_STRUCT_ST_BLKSIZE extracted from the file in question,
  77 dnl "acspecific.m4" in GNU Autoconf 2.12, and turned into
  78 dnl AC_ETHEREAL_STRUCT_SA_LEN, which checks if "struct sockaddr"
  79 dnl has the 4.4BSD "sa_len" member, and defines HAVE_SA_LEN; that's
  80 dnl what's in this file.
  81 dnl Done by Guy Harris <guy@alum.mit.edu> on 1998-11-14.
  82
  83 dnl ### Checks for structure members
  84
  85 AC_DEFUN([AC_ETHEREAL_STRUCT_SA_LEN],
  86 [AC_CACHE_CHECK([for sa_len in struct sockaddr], ac_cv_ethereal_struct_sa_len,
  87 [AC_TRY_COMPILE([#include <sys/types.h>
  88 #include <sys/socket.h>], [struct sockaddr s; s.sa_len;],
  89 ac_cv_ethereal_struct_sa_len=yes, ac_cv_ethereal_struct_sa_len=no)])
  90 if test $ac_cv_ethereal_struct_sa_len = yes; then
  91   AC_DEFINE(HAVE_SA_LEN, 1, [Define if sa_len field exists in struct sockaddr])
  92 fi
  93 ])
  94
  95
  96 dnl
  97 dnl Check whether a given format can be used to print 64-bit integers
  98 dnl
  99 AC_DEFUN([AC_ETHEREAL_CHECK_64BIT_FORMAT],
 100 [
 101   AC_MSG_CHECKING([whether %$1x can be used to format 64-bit integers])
 102   AC_RUN_IFELSE(
 103     [
 104       AC_LANG_SOURCE(
 105         [[
 106 #         ifdef HAVE_INTTYPES_H
 107           #include <inttypes.h>
 108 #         endif
 109           #include <glibconfig.h>
 110           #include <stdio.h>
 111           #include <sys/types.h>
 112
 113           main()
 114           {
 115             guint64 t = 1;
 116             char strbuf[16+1];
 117             sprintf(strbuf, "%016$1x", t << 32);
 118             if (strcmp(strbuf, "0000000100000000") == 0)
 119               exit(0);
 120             else
 121               exit(1);
 122           }
 123         ]])
 124     ],
 125     [
 126       AC_DEFINE(PRId64, "$1d", [Format for printing 64-bit signed decimal numbers])
 127       AC_DEFINE(PRIo64, "$1o", [Format for printing 64-bit unsigned octal numbers])
 128       AC_DEFINE(PRIx64, "$1x", [Format for printing 64-bit unsigned hexadecimal numbers (lower-case)])
 129       AC_DEFINE(PRIX64, "$1X", [Format for printing 64-bit unsigned hexadecimal numbers (upper-case)])
 130       AC_DEFINE(PRIu64, "$1u", [Format for printing 64-bit unsigned decimal numbers])
 131       AC_MSG_RESULT(yes)
 132     ],
 133     [
 134       AC_MSG_RESULT(no)
 135       $2
 136     ])
 137 ])
 138
 139 #
 140 # AC_ETHEREAL_IPV6_STACK
 141 #
 142 # By Jun-ichiro "itojun" Hagino, <itojun@iijlab.net>
 143 #
 144 AC_DEFUN([AC_ETHEREAL_IPV6_STACK],
 145 [
 146         v6type=unknown
 147         v6lib=none
 148
 149         AC_MSG_CHECKING([ipv6 stack type])
 150         for i in v6d toshiba kame inria zeta linux linux-glibc solaris8; do
 151                 case $i in
 152                 v6d)
 153                         AC_EGREP_CPP(yes, [
 154 #include </usr/local/v6/include/sys/types.h>
 155 #ifdef __V6D__
 156 yes
 157 #endif],
 158                                 [v6type=$i; v6lib=v6;
 159                                 v6libdir=/usr/local/v6/lib;
 160                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 161                         ;;
 162                 toshiba)
 163                         AC_EGREP_CPP(yes, [
 164 #include <sys/param.h>
 165 #ifdef _TOSHIBA_INET6
 166 yes
 167 #endif],
 168                                 [v6type=$i; v6lib=inet6;
 169                                 v6libdir=/usr/local/v6/lib;
 170                                 CFLAGS="-DINET6 $CFLAGS"])
 171                         ;;
 172                 kame)
 173                         AC_EGREP_CPP(yes, [
 174 #include <netinet/in.h>
 175 #ifdef __KAME__
 176 yes
 177 #endif],
 178                                 [v6type=$i; v6lib=inet6;
 179                                 v6libdir=/usr/local/v6/lib;
 180                                 CFLAGS="-DINET6 $CFLAGS"])
 181                         ;;
 182                 inria)
 183                         AC_EGREP_CPP(yes, [
 184 #include <netinet/in.h>
 185 #ifdef IPV6_INRIA_VERSION
 186 yes
 187 #endif],
 188                                 [v6type=$i; CFLAGS="-DINET6 $CFLAGS"])
 189                         ;;
 190                 zeta)
 191                         AC_EGREP_CPP(yes, [
 192 #include <sys/param.h>
 193 #ifdef _ZETA_MINAMI_INET6
 194 yes
 195 #endif],
 196                                 [v6type=$i; v6lib=inet6;
 197                                 v6libdir=/usr/local/v6/lib;
 198                                 CFLAGS="-DINET6 $CFLAGS"])
 199                         ;;
 200                 linux)
 201                         if test -d /usr/inet6; then
 202                                 v6type=$i
 203                                 v6lib=inet6
 204                                 v6libdir=/usr/inet6
 205                                 CFLAGS="-DINET6 $CFLAGS"
 206                         fi
 207                         ;;
 208                 linux-glibc)
 209                         AC_EGREP_CPP(yes, [
 210 #include <features.h>
 211 #if defined(__GLIBC__) && defined(__GLIBC_MINOR__)
 212 #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || __GLIBC__ > 2
 213 yes
 214 #endif
 215 #endif],
 216                         [v6type=$i; v6lib=inet6; CFLAGS="-DINET6 $CFLAGS"])
 217                         ;;
 218                 solaris8)
 219                         if test "`uname -s`" = "SunOS" && test "`uname -r`" = "5.8"; then
 220                                 v6type=$i
 221                                 v6lib=inet6
 222                                 [CFLAGS="-DINET6 -DSOLARIS8_INET6 $CFLAGS"]
 223                         fi
 224                         ;;
 225                 esac
 226                 if test "$v6type" != "unknown"; then
 227                         break
 228                 fi
 229         done
 230
 231         if test "$v6lib" != "none"; then
 232                 for dir in $v6libdir /usr/local/v6/lib /usr/local/lib; do
 233                         if test -d $dir -a -f $dir/lib$v6lib.a; then
 234                                 LIBS="-L$dir $LIBS -l$v6lib"
 235                                 break
 236                         fi
 237                 done
 238                 enable_ipv6="yes"
 239         else
 240                 enable_ipv6="no"
 241         fi
 242         AC_MSG_RESULT(["$v6type, $v6lib"])
 243 ])
 244
 245 #
 246 # AC_ETHEREAL_GETHOSTBY_LIB_CHECK
 247 #
 248 # Checks whether we need "-lnsl" to get "gethostby*()", which we use
 249 # in "resolv.c".
 250 #
 251 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 252 # GNU Autoconf 2.13; the comment came from there.
 253 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 254 #
 255 AC_DEFUN([AC_ETHEREAL_GETHOSTBY_LIB_CHECK],
 256 [
 257     # msh@cis.ufl.edu says -lnsl (and -lsocket) are needed for his 386/AT,
 258     # to get the SysV transport functions.
 259     # chad@anasazi.com says the Pyramid MIS-ES running DC/OSx (SVR4)
 260     # needs -lnsl.
 261     # The nsl library prevents programs from opening the X display
 262     # on Irix 5.2, according to dickey@clark.net.
 263     AC_CHECK_FUNC(gethostbyname, ,
 264         AC_CHECK_LIB(nsl, gethostbyname, NSL_LIBS="-lnsl"))
 265     AC_SUBST(NSL_LIBS)
 266 ])
 267
 268 #
 269 # AC_ETHEREAL_SOCKET_LIB_CHECK
 270 #
 271 # Checks whether we need "-lsocket" to get "socket()", which is used
 272 # by libpcap on some platforms - and, in effect, "gethostby*()" on
 273 # most if not all platforms (so that it can use NIS or DNS or...
 274 # to look up host names).
 275 #
 276 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 277 # GNU Autoconf 2.13; the comment came from there.
 278 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 279 #
 280 # We use "connect" because that's what AC_PATH_XTRA did.
 281 #
 282 AC_DEFUN([AC_ETHEREAL_SOCKET_LIB_CHECK],
 283 [
 284     # lieder@skyler.mavd.honeywell.com says without -lsocket,
 285     # socket/setsockopt and other routines are undefined under SCO ODT
 286     # 2.0.  But -lsocket is broken on IRIX 5.2 (and is not necessary
 287     # on later versions), says simon@lia.di.epfl.ch: it contains
 288     # gethostby* variants that don't use the nameserver (or something).
 289     # -lsocket must be given before -lnsl if both are needed.
 290     # We assume that if connect needs -lnsl, so does gethostbyname.
 291     AC_CHECK_FUNC(connect, ,
 292       AC_CHECK_LIB(socket, connect, SOCKET_LIBS="-lsocket",
 293                 AC_MSG_ERROR(Function 'socket' not found.), $NSL_LIBS))
 294     AC_SUBST(SOCKET_LIBS)
 295 ])
 296
 297 #
 298 # AC_ETHEREAL_PCAP_CHECK
 299 #
 300 AC_DEFUN([AC_ETHEREAL_PCAP_CHECK],
 301 [
 302         if test -z "$pcap_dir"
 303         then
 304           # Pcap header checks
 305           # XXX need to set a var AC_CHECK_HEADER(pcap.h,,)
 306
 307           #
 308           # The user didn't specify a directory in which libpcap resides;
 309           # we assume that the current library search path will work,
 310           # but we may have to look for the header in a "pcap"
 311           # subdirectory of "/usr/include" or "/usr/local/include",
 312           # as some systems apparently put "pcap.h" in a "pcap"
 313           # subdirectory, and we also check "$prefix/include" - and
 314           # "$prefix/include/pcap", in case $prefix is set to
 315           # "/usr/include" or "/usr/local/include".
 316           #
 317           # XXX - should we just add "$prefix/include" to the include
 318           # search path and "$prefix/lib" to the library search path?
 319           #
 320           AC_MSG_CHECKING(for extraneous pcap header directories)
 321           found_pcap_dir=""
 322           pcap_dir_list="/usr/include/pcap $prefix/include/pcap $prefix/include"
 323           if test "x$ac_cv_enable_usr_local" = "xyes" ; then
 324             pcap_dir_list="$pcap_dir_list /usr/local/include/pcap"
 325           fi
 326           for pcap_dir in $pcap_dir_list
 327           do
 328             if test -d $pcap_dir ; then
 329                 if test x$pcap_dir != x/usr/include -a x$pcap_dir != x/usr/local/include ; then
 330                     CFLAGS="$CFLAGS -I$pcap_dir"
 331                     CPPFLAGS="$CPPFLAGS -I$pcap_dir"
 332                 fi
 333                 found_pcap_dir=" $found_pcap_dir -I$pcap_dir"
 334                 break
 335             fi
 336           done
 337
 338           if test "$found_pcap_dir" != "" ; then
 339             AC_MSG_RESULT(found --$found_pcap_dir added to CFLAGS)
 340           else
 341             AC_MSG_RESULT(not found)
 342           fi
 343         else
 344           #
 345           # The user specified a directory in which libpcap resides,
 346           # so add the "include" subdirectory of that directory to
 347           # the include file search path and the "lib" subdirectory
 348           # of that directory to the library search path.
 349           #
 350           # XXX - if there's also a libpcap in a directory that's
 351           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 352           # make us find the version in the specified directory,
 353           # as the compiler and/or linker will search that other
 354           # directory before it searches the specified directory.
 355           #
 356           CFLAGS="$CFLAGS -I$pcap_dir/include"
 357           CPPFLAGS="$CPPFLAGS -I$pcap_dir/include"
 358           AC_ETHEREAL_ADD_DASH_L(LDFLAGS, $pcap_dir/lib)
 359         fi
 360
 361         # Pcap header check
 362         AC_CHECK_HEADER(pcap.h,,
 363             AC_MSG_ERROR([[Header file pcap.h not found; if you installed libpcap
 364 from source, did you also do \"make install-incl\", and if you installed a
 365 binary package of libpcap, is there also a developer's package of libpcap,
 366 and did you also install that package?]]))
 367
 368         #
 369         # Check to see if we find "pcap_open_live" in "-lpcap".
 370         #
 371         AC_CHECK_LIB(pcap, pcap_open_live,
 372           [
 373             PCAP_LIBS=-lpcap
 374             AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 375           ], [
 376             AC_MSG_CHECKING([for pcap_open_live in -lpcap -lcfg -lodm])
 377             ac_save_LIBS="$LIBS"
 378             LIBS="-lpcap -lcfg -lodm"
 379             AC_TRY_LINK(
 380                 [
 381 #       include <pcap.h>
 382                 ],
 383                 [
 384         pcap_open_live(NULL, 0, 0, 0, NULL);
 385                 ],
 386                 [
 387                 AC_MSG_RESULT([yes])
 388                 PCAP_LIBS="-lpcap -lcfg -lodm"
 389                 AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 390                 ],
 391                 [
 392                 AC_MSG_RESULT([no])
 393                 AC_MSG_ERROR([Library libpcap not found.])
 394                 ])
 395             LIBS=$ac_save_LIBS
 396           ], $SOCKET_LIBS $NSL_LIBS)
 397         AC_SUBST(PCAP_LIBS)
 398
 399         #
 400         # Check whether various variables and functions are defined by
 401         # libpcap.
 402         #
 403         ac_save_LIBS="$LIBS"
 404         AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 405         LIBS="$PCAP_LIBS $SOCKET_LIBS $NSL_LIBS $LIBS"
 406         AC_TRY_LINK(
 407            [
 408 #       include <stdio.h>
 409         extern char *pcap_version;
 410            ],
 411            [
 412         printf ("%s\n", pcap_version);
 413            ],
 414            ac_cv_pcap_version_defined=yes,
 415            ac_cv_pcap_version_defined=no,
 416            [echo $ac_n "cross compiling; assumed OK... $ac_c"])
 417         if test "$ac_cv_pcap_version_defined" = yes ; then
 418                 AC_MSG_RESULT(yes)
 419                 AC_DEFINE(HAVE_PCAP_VERSION, 1, [Define if libpcap version is known])
 420         else
 421                 AC_MSG_RESULT(no)
 422         fi
 423         AC_CHECK_FUNCS(pcap_open_dead pcap_freecode)
 424         #
 425         # Later versions of Mac OS X 10.3[.x] ship a pcap.h that
 426         # doesn't define pcap_if_t but ship an 0.8[.x] libpcap,
 427         # so the library has "pcap_findalldevs()", but pcap.h
 428         # doesn't define "pcap_if_t" so you can't actually *use*
 429         # "pcap_findalldevs()".
 430         #
 431         # That even appears to be true of systems shipped with
 432         # 10.3.4, so it doesn't appear only to be a case of
 433         # Software Update not updating header files.
 434         #
 435         # (You can work around this by installing the 0.8 header
 436         # files.)
 437         #
 438         AC_CACHE_CHECK([whether pcap_findalldevs is present and usable],
 439           [ac_cv_func_pcap_findalldevs],
 440           [
 441             AC_LINK_IFELSE(
 442               [
 443                 AC_LANG_SOURCE(
 444                   [[
 445                     #include <pcap.h>
 446                     main()
 447                     {
 448                       pcap_if_t *devpointer;
 449                       char errbuf[1];
 450
 451                       pcap_findalldevs(&devpointer, errbuf);
 452                     }
 453                   ]])
 454               ],
 455               [
 456                 ac_cv_func_pcap_findalldevs=yes
 457               ],
 458               [
 459                 ac_cv_func_pcap_findalldevs=no
 460               ])
 461           ])
 462         #
 463         # Don't check for other new routines that showed up after
 464         # "pcap_findalldevs()" if we don't have a usable
 465         # "pcap_findalldevs()", so we don't end up using them if the
 466         # "pcap.h" is crufty and old and doesn't declare them.
 467         #
 468         if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 469           AC_DEFINE(HAVE_PCAP_FINDALLDEVS, 1,
 470            [Define to 1 if you have the `pcap_findalldevs' function and a pcap.h that declares pcap_if_t.])
 471           AC_CHECK_FUNCS(pcap_datalink_val_to_name pcap_datalink_name_to_val)
 472           AC_CHECK_FUNCS(pcap_list_datalinks pcap_set_datalink pcap_lib_version)
 473           AC_CHECK_FUNCS(pcap_get_selectable_fd)
 474         fi
 475         LIBS="$ac_save_LIBS"
 476 ])
 477
 478 #
 479 # AC_ETHEREAL_ZLIB_CHECK
 480 #
 481 AC_DEFUN([AC_ETHEREAL_ZLIB_CHECK],
 482 [
 483         if test "x$zlib_dir" != "x"
 484         then
 485           #
 486           # The user specified a directory in which zlib resides,
 487           # so add the "include" subdirectory of that directory to
 488           # the include file search path and the "lib" subdirectory
 489           # of that directory to the library search path.
 490           #
 491           # XXX - if there's also a zlib in a directory that's
 492           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 493           # make us find the version in the specified directory,
 494           # as the compiler and/or linker will search that other
 495           # directory before it searches the specified directory.
 496           #
 497           ethereal_save_CFLAGS="$CFLAGS"
 498           CFLAGS="$CFLAGS -I$zlib_dir/include"
 499           ethereal_save_CPPFLAGS="$CPPFLAGS"
 500           CPPFLAGS="$CPPFLAGS -I$zlib_dir/include"
 501           ethereal_save_LIBS="$LIBS"
 502           AC_ETHEREAL_ADD_DASH_L(LIBS, $zlib_dir/lib)
 503         fi
 504
 505         #
 506         # Make sure we have "zlib.h".  If we don't, it means we probably
 507         # don't have zlib, so don't use it.
 508         #
 509         AC_CHECK_HEADER(zlib.h,,
 510           [
 511             if test "x$zlib_dir" != "x"
 512             then
 513               #
 514               # The user used "--with-zlib=" to specify a directory
 515               # containing zlib, but we didn't find the header file
 516               # there; that either means they didn't specify the
 517               # right directory or are confused about whether zlib
 518               # is, in fact, installed.  Report the error and give up.
 519               #
 520               AC_MSG_ERROR([zlib header not found in directory specified in --with-zlib])
 521             else
 522               if test "x$want_zlib" = "xyes"
 523               then
 524                 #
 525                 # The user tried to force us to use the library, but we
 526                 # couldn't find the header file; report an error.
 527                 #
 528                 AC_MSG_ERROR(Header file zlib.h not found.)
 529               else
 530                 #
 531                 # We couldn't find the header file; don't use the
 532                 # library, as it's probably not present.
 533                 #
 534                 want_zlib=no
 535               fi
 536             fi
 537           ])
 538
 539         if test "x$want_zlib" != "xno"
 540         then
 541                 #
 542                 # Well, we at least have the zlib header file.
 543                 #
 544                 # Check for "gzgets()" in zlib, because we need it, but
 545                 # some older versions of zlib don't have it.  It appears
 546                 # from the zlib ChangeLog that any released version of zlib
 547                 # with "gzgets()" should have the other routines we
 548                 # depend on, such as "gzseek()", "gztell()", and "zError()".
 549                 #
 550                 # Another reason why we require "gzgets()" is that
 551                 # some versions of zlib that didn't have it, such
 552                 # as 1.0.8, had a bug in "gzseek()" that meant that it
 553                 # doesn't work correctly on uncompressed files; this
 554                 # means we cannot use version 1.0.8.  (Unfortunately,
 555                 # that's the version that comes with recent X11 source,
 556                 # and many people who install XFree86 on their Slackware
 557                 # boxes don't realize that they should configure it to
 558                 # use the native zlib rather than building and installing
 559                 # the crappy old version that comes with XFree86.)
 560                 #
 561                 # I.e., we can't just avoid using "gzgets()", as
 562                 # versions of zlib without "gzgets()" are likely to have
 563                 # a broken "gzseek()".
 564                 #
 565                 AC_CHECK_LIB(z, gzgets,
 566                 [
 567                         if test "x$zlib_dir" != "x"
 568                         then
 569                                 #
 570                                 # Put the "-I" and "-L" flags for zlib at
 571                                 # the beginning of CFLAGS, CPPFLAGS, and
 572                                 # LIBS.
 573                                 #
 574                                 LIBS=""
 575                                 AC_ETHEREAL_ADD_DASH_L(LIBS, $zlib_dir/lib)
 576                                 LIBS="$LIBS -lz $ethereal_save_LIBS"
 577                         else
 578                                 LIBS="-lz $LIBS"
 579                         fi
 580                         AC_DEFINE(HAVE_LIBZ, 1, [Define to use libz library])
 581                 ],[
 582                         if test "x$zlib_dir" != "x"
 583                         then
 584                                 #
 585                                 # Restore the versions of CFLAGS, CPPFLAGS,
 586                                 # and LIBS before we added the "-with-zlib="
 587                                 # directory, as we didn't actually find
 588                                 # zlib there, or didn't find a zlib that
 589                                 # contains gzgets there.
 590                                 #
 591                                 CFLAGS="$ethereal_save_CFLAGS"
 592                                 CPPFLAGS="$ethereal_save_CPPFLAGS"
 593                                 LIBS="$ethereal_save_LIBS"
 594                         fi
 595                         want_zlib=no
 596                 ])
 597         fi
 598
 599         if test "x$want_zlib" != "xno"
 600         then
 601                 #
 602                 # Well, we at least have the zlib header file and a zlib
 603                 # with "gzgets()".
 604                 #
 605                 # Now check for "gzgets()" in zlib when linking with the
 606                 # linker flags for GTK+ applications; people often grab
 607                 # XFree86 source and build and install it on their systems,
 608                 # and they appear sometimes to misconfigure XFree86 so that,
 609                 # even on systems with zlib, it assumes there is no zlib,
 610                 # so the XFree86 build process builds and installs its
 611                 # own zlib in the X11 library directory.
 612                 #
 613                 # The XFree86 zlib is an older version that lacks
 614                 # "gzgets()", and that's the zlib with which Ethereal
 615                 # gets linked, so the build of Ethereal fails.
 616                 #
 617                 ac_save_CFLAGS="$CFLAGS"
 618                 ac_save_LIBS="$LIBS"
 619                 CFLAGS="$CFLAGS $GTK_CFLAGS"
 620                 LIBS="$GTK_LIBS -lz $LIBS"
 621                 AC_MSG_CHECKING([for gzgets missing when linking with X11])
 622                 AC_TRY_LINK_FUNC(gzgets, AC_MSG_RESULT(no),
 623                   [
 624                     AC_MSG_RESULT(yes)
 625                     AC_MSG_ERROR(old zlib found when linking with X11 - get rid of old zlib.)
 626                   ])
 627                 CFLAGS="$ac_save_CFLAGS"
 628                 LIBS="$ac_save_LIBS"
 629         fi
 630 ])
 631
 632 #
 633 # AC_ETHEREAL_LIBPCRE_CHECK
 634 #
 635 AC_DEFUN([AC_ETHEREAL_LIBPCRE_CHECK],
 636 [
 637         if test "x$pcre_dir" != "x"
 638         then
 639           #
 640           # The user specified a directory in which libpcre resides,
 641           # so add the "include" subdirectory of that directory to
 642           # the include file search path and the "lib" subdirectory
 643           # of that directory to the library search path.
 644           #
 645           # XXX - if there's also a libpcre in a directory that's
 646           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 647           # make us find the version in the specified directory,
 648           # as the compiler and/or linker will search that other
 649           # directory before it searches the specified directory.
 650           #
 651           ethereal_save_CFLAGS="$CFLAGS"
 652           CFLAGS="$CFLAGS -I$pcre_dir/include"
 653           ethereal_save_CPPFLAGS="$CPPFLAGS"
 654           CPPFLAGS="$CPPFLAGS -I$pcre_dir/include"
 655           ethereal_save_LIBS="$LIBS"
 656           LIBS="$LIBS -lpcre"
 657           ethereal_save_LDFLAGS="$LDFLAGS"
 658           LDFLAGS="$LDFLAGS -L$pcre_dir/lib"
 659         fi
 660
 661         #
 662         # Make sure we have "pcre.h".  If we don't, it means we probably
 663         # don't have libpcre, so don't use it.
 664         #
 665         AC_CHECK_HEADER(pcre.h,,
 666           [
 667             if test "x$pcre_dir" != "x"
 668             then
 669               #
 670               # The user used "--with-pcre=" to specify a directory
 671               # containing libpcre, but we didn't find the header file
 672               # there; that either means they didn't specify the
 673               # right directory or are confused about whether libpcre
 674               # is, in fact, installed.  Report the error and give up.
 675               #
 676               AC_MSG_ERROR([libpcre header not found in directory specified in --with-pcre])
 677             else
 678               if test "x$want_pcre" = "xyes"
 679               then
 680                 #
 681                 # The user tried to force us to use the library, but we
 682                 # couldn't find the header file; report an error.
 683                 #
 684                 AC_MSG_ERROR(Header file pcre.h not found.)
 685               else
 686                 #
 687                 # We couldn't find the header file; don't use the
 688                 # library, as it's probably not present.
 689                 #
 690                 want_pcre=no
 691               fi
 692             fi
 693           ])
 694
 695         if test "x$want_pcre" != "xno"
 696         then
 697                 #
 698                 # Well, we at least have the pcre header file.
 699                 #
 700                 # We're only using standard functions from libpcre,
 701                 # so we don't need to perform extra checks.
 702                 #
 703                 AC_CHECK_LIB(pcre, pcre_compile,
 704                 [
 705                         if test "x$pcre_dir" != "x"
 706                         then
 707                                 #
 708                                 # Put the "-I" and "-L" flags for pcre at
 709                                 # the beginning of CFLAGS, CPPFLAGS,
 710                                 # LDFLAGS, and LIBS.
 711                                 #
 712                                 PCRE_LIBS="-L$pcre_dir/lib -lpcre $ethereal_save_LIBS"
 713                         else
 714                                 PCRE_LIBS="-lpcre"
 715                         fi
 716                         AC_DEFINE(HAVE_LIBPCRE, 1, [Define to use libpcre library])
 717                 ],[
 718                         if test "x$pcre_dir" != "x"
 719                         then
 720                                 #
 721                                 # Restore the versions of CFLAGS, CPPFLAGS,
 722                                 # LDFLAGS, and LIBS before we added the
 723                                 # "--with-pcre=" directory, as we didn't
 724                                 # actually find pcre there.
 725                                 #
 726                                 CFLAGS="$ethereal_save_CFLAGS"
 727                                 CPPFLAGS="$ethereal_save_CPPFLAGS"
 728                                 LDFLAGS="$ethereal_save_LDFLAGS"
 729                                 LIBS="$ethereal_save_LIBS"
 730                                 PCRE_LIBS=""
 731                         fi
 732                         want_pcre=no
 733                 ])
 734                 AC_SUBST(PCRE_LIBS)
 735         fi
 736 ])
 737
 738 #
 739 # AC_ETHEREAL_NETSNMP_CHECK
 740 #
 741 AC_DEFUN([AC_ETHEREAL_NETSNMP_CHECK],
 742 [
 743         dnl get the net-snmp-config binary
 744         if test "x$netsnmpconfig" = "x" ; then
 745                 #
 746                 # The user didn't specify where net-snmp-config is
 747                 # located; search for it.
 748                 #
 749                 AC_PATH_PROG(NETSNMPCONFIG, net-snmp-config)
 750         else
 751                 NETSNMPCONFIG=$netsnmpconfig
 752                 if test ! -x $NETSNMPCONFIG -o ! -f $NETSNMPCONFIG ; then
 753                         NETSNMPCONFIG=$netsnmpconfig/bin/net-snmp-config
 754                         if test ! -x $NETSNMPCONFIG -o ! -f $NETSNMPCONFIG ; then
 755                                 AC_MSG_ERROR(Invalid net-snmp-config: $netsnmpconfig)
 756                         fi
 757                 fi
 758         fi
 759
 760         #
 761         # XXX - check whether $NETSNMPCONFIG is executable?
 762         # if test "x$NETSNMPCONFIG" != "xno" -a "x$NETSNMPCONFIG" != "x" -a -x "$NETSNMPCONFIG" ; then
 763         # We already did that if it was set; presumably AC_PATH_PROG
 764         # will fail if it doesn't find an executable version.
 765         #
 766         if test "x$NETSNMPCONFIG" != "x" ; then
 767                 dnl other choices for flags to use here: could also use
 768                 dnl --prefix or --exec-prefix if you don't want the full list.
 769
 770                 #
 771                 # Save the current settings of CFLAGS and CPPFLAGS, and add
 772                 # the output of "$NETSNMPCONFIG --cflags" to it, so that when
 773                 # searching for the Net-SNMP headers, we look in whatever
 774                 # directory that output specifies.
 775                 #
 776                 ethereal_save_CFLAGS="$CFLAGS"
 777                 ethereal_save_CPPFLAGS="$CPPFLAGS"
 778                 CFLAGS="$CFLAGS `$NETSNMPCONFIG --cflags`"
 779                 CPPFLAGS="$CPPFLAGS `$NETSNMPCONFIG --cflags`"
 780
 781                 AC_CHECK_HEADERS(net-snmp/net-snmp-config.h net-snmp/library/default_store.h)
 782                 if test "x$ac_cv_header_net_snmp_net_snmp_config_h" = "xyes" -a "x$ac_cv_header_net_snmp_library_default_store_h" = "xyes" ; then
 783                         SNMP_LIBS=`$NETSNMPCONFIG --libs`
 784                         if echo "$SNMP_LIBS" | grep crypto >/dev/null  && test "x$SSL_LIBS" = "x"; then
 785                                 if test "x$want_netsnmp" = "xyes" ; then
 786                                         AC_MSG_ERROR(Net-SNMP requires openssl but ssl not enabled)
 787                                 else
 788                                         AC_MSG_RESULT(Net-SNMP requires openssl but ssl not enabled - disabling Net-SNMP)
 789                                 fi
 790                                 CFLAGS="$ethereal_save_CFLAGS"
 791                                 CPPFLAGS="$ethereal_save_CPPFLAGS"
 792                                 SNMP_LIBS=
 793                         else
 794                                 AC_DEFINE(HAVE_NET_SNMP, 1, [Define to enable support for Net-SNMP])
 795                                 have_net_snmp="yes"
 796                         fi
 797                 else
 798                         if test "x$want_netsnmp" = "xyes" ; then
 799                                 AC_MSG_ERROR(Net-SNMP not found)
 800                         else
 801                                 #
 802                                 # Restore the versions of CFLAGS and
 803                                 # CPPFLAGS before we added the output
 804                                 # of '$NETSNMPCONFIG --cflags", as we
 805                                 # didn't actually find Net-SNMP there.
 806                                 #
 807                                 CFLAGS="$ethereal_save_CFLAGS"
 808                                 CPPFLAGS="$ethereal_save_CPPFLAGS"
 809                         fi
 810                 fi
 811         fi
 812 ])
 813
 814 #
 815 # AC_ETHEREAL_UCDSNMP_CHECK
 816 #
 817 AC_DEFUN([AC_ETHEREAL_UCDSNMP_CHECK],
 818 [
 819         if test "x$ucdsnmp_dir" != "x"
 820         then
 821                 #
 822                 # The user specified a directory in which UCD SNMP resides,
 823                 # so add the "include" subdirectory of that directory to
 824                 # the include file search path and the "lib" subdirectory
 825                 # of that directory to the library search path.
 826                 #
 827                 # XXX - if there's also a libpcap in a directory that's
 828                 # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 829                 # make us find the version in the specified directory,
 830                 # as the compiler and/or linker will search that other
 831                 # directory before it searches the specified directory.
 832                 #
 833                 CFLAGS="$CFLAGS -I$ucdsnmp_dir/include"
 834                 CPPFLAGS="$CPPFLAGS -I$ucdsnmp_dir/include"
 835                 AC_ETHEREAL_ADD_DASH_L(LDFLAGS, $ucdsnmp_dir/lib)
 836         fi
 837
 838         #
 839         # Check for one of the UCD SNMP header files we include,
 840         # to see whether we have UCD SNMP installed.
 841         #
 842         AC_CHECK_HEADER(ucd-snmp/ucd-snmp-config.h,
 843         [
 844                 #
 845                 # UCD SNMP or Net-SNMP might require various helper
 846                 # libraries on various platforms, such as "-ldes425"
 847                 # in "/usr/kerberos/lib" on some versions of Red
 848                 # Hat Linux, or "-lkstat" on Solaris.
 849                 #
 850                 # It might also require "-lcrypto" on some platforms;
 851                 # if the user didn't specify --with-ssl, we check
 852                 # whether it would have made a difference and, if so,
 853                 # we tell the user that they needed to request it.
 854                 # (There are annoying licensing issues with it and
 855                 # GPL'ed code, so we don't include it by default.)
 856                 #
 857                 # XXX - autoconf really needs a way to test for
 858                 # a given routine in a given library *and* to test
 859                 # whether additional "-L"/"-R"/whatever flags are
 860                 # needed *before* the "-l" flag for the library
 861                 # and to test whether additional libraries are
 862                 # needed after the library *and* to cache all that
 863                 # information.
 864                 #
 865                 ethereal_save_LIBS="$LIBS"
 866                 found_sprint_realloc_objid=no
 867                 for extras in "" "-L/usr/kerberos/lib -ldes425" "-lkstat"
 868                 do
 869                         LIBS="-lsnmp $extras $SOCKET_LIBS $NSL_LIBS $SSL_LIBS"
 870                         if test -z "$extras"
 871                         then
 872                                 AC_MSG_CHECKING([whether UCD SNMP includes sprint_realloc_objid])
 873                         else
 874                                 AC_MSG_CHECKING([whether UCD SNMP includes sprint_realloc_objid (linking with $extras)])
 875                         fi
 876                         AC_TRY_LINK(
 877                             [
 878                             ],
 879                             [
 880                                 sprint_realloc_objid();
 881                             ],
 882                             [
 883                                 #
 884                                 # We found "sprint_realloc_objid()",
 885                                 # and required the libraries in
 886                                 # extras as well.
 887                                 #
 888                                 AC_MSG_RESULT(yes)
 889                                 SNMP_LIBS="-lsnmp $extras"; break;
 890                                 found_sprint_realloc_objid=yes
 891                                 break
 892                             ],
 893                             [
 894                                 #
 895                                 # The link failed.  If they didn't ask
 896                                 # for SSL, try linking with -lcrypto
 897                                 # as well, and if *that* succeeds,
 898                                 # tell them they'll need to specify
 899                                 # --want-ssl.
 900                                 #
 901                                 AC_MSG_RESULT(no)
 902                                 if test "x$want_ssl" = "xno"
 903                                 then
 904                                         LIBS="$LIBS -lcrypto"
 905                                         AC_TRY_LINK(
 906                                             [
 907                                             ],
 908                                             [
 909                                                 sprint_realloc_objid();
 910                                             ],
 911                                             [
 912                                                 #
 913                                                 # It worked with -lcrypto; tell
 914                                                 # them they'll need to specify
 915                                                 # --with-ssl.
 916                                                 #
 917                                                 AC_MSG_ERROR([UCD SNMP requires -lcrypto but --with-ssl not specified])
 918                                             ])
 919                                 fi
 920                             ])
 921                 done
 922                 LIBS="$ethereal_save_LIBS"
 923
 924                 #
 925                 # If we didn't find "sprint_realloc_objid()", fail.
 926                 # Either the user needs a newer version of UCD SNMP
 927                 # with "sprint_realloc_objid()", or they may need to
 928                 # specify "--with-ssl".
 929                 #
 930                 if test "$found_snmp_sprint_realloc_objid" = no; then
 931                     AC_MSG_ERROR([UCD SNMP header files found, but sprint_realloc_objid not found in SNMP library.])
 932                 fi
 933
 934                 #
 935                 # We found it, so we have UCD SNMP.
 936                 #
 937                 AC_DEFINE(HAVE_UCD_SNMP, 1, [Define to enable support for UCD-SNMP])
 938                 have_ucd_snmp="yes"
 939         ],[
 940                 #
 941                 # No, we don't have it.
 942                 # If the user explicitly asked for UCD SNMP, fail,
 943                 # otherwise just don't use the UCD SNMP library.
 944                 #
 945                 if test "x$want_ucdsnmp" = "xyes" ; then
 946                         AC_MSG_ERROR(Header file ucd-snmp/snmp.h not found.)
 947                 fi
 948         ])
 949 ])
 950
 951 #
 952 # AC_ETHEREAL_RPM_CHECK
 953 # Looks for the rpm program, and checks to see if we can redefine "_topdir".
 954 #
 955 AC_DEFUN([AC_ETHEREAL_RPM_CHECK],
 956 [
 957         AC_CHECK_PROG(ac_cv_ethereal_have_rpm, rpm, "yes", "no")
 958         if test "x$ac_cv_ethereal_have_rpm" = "xyes"; then
 959                 rpm --define '_topdir /tmp' > /dev/null 2>&1
 960                 AC_MSG_CHECKING(to see if we can redefine _topdir)
 961                 if test $? -eq 0 ; then
 962                         AC_MSG_RESULT(yes)
 963                         HAVE_RPM=yes
 964                 else
 965                         AC_MSG_RESULT(no.  You'll have to build packages manually.)
 966                         HAVE_RPM=no
 967                 fi
 968         fi
 969 ])
 970
 971 #
 972 # AC_ETHEREAL_GNU_SED_CHECK
 973 # Checks if GNU sed is the first sed in PATH.
 974 #
 975 AC_DEFUN([AC_ETHEREAL_GNU_SED_CHECK],
 976 [
 977         AC_MSG_CHECKING(for GNU sed as first sed in PATH)
 978         if  ( sh -c "sed --version" </dev/null 2> /dev/null | grep "GNU sed" 2>&1 > /dev/null ) ;  then
 979                 AC_MSG_RESULT(yes)
 980                 HAVE_GNU_SED=yes
 981         else
 982                 AC_MSG_RESULT(no)
 983                 HAVE_GNU_SED=no
 984         fi
 985 ])
 986
 987 #
 988 # AC_ETHEREAL_ADNS_CHECK
 989 #
 990 AC_DEFUN([AC_ETHEREAL_ADNS_CHECK],
 991 [
 992         want_adns=defaultyes
 993
 994         if test "x$want_adns" = "xdefaultyes"; then
 995                 want_adns=yes
 996                 withval=/usr/local
 997                 if test -d "$withval"; then
 998                         AC_ETHEREAL_ADD_DASH_L(LDFLAGS, ${withval}/lib)
 999                 fi
1000         fi
1001
1002         if test "x$want_adns" = "xyes"; then
1003                 AC_CHECK_LIB(adns, adns_init,
1004                   [
1005                     ADNS_LIBS=-ladns
1006                 AC_DEFINE(HAVE_GNU_ADNS, 1, [Define to use GNU ADNS library])
1007                 have_good_adns=yes
1008                   ],, $SOCKET_LIBS $NSL_LIBS
1009                 )
1010         else
1011                 AC_MSG_RESULT(not required)
1012         fi
1013 ])
1014
1015
1016 #
1017 # AC_ETHEREAL_KRB5_CHECK
1018 #
1019 AC_DEFUN([AC_ETHEREAL_KRB5_CHECK],
1020 [
1021         ethereal_save_CFLAGS="$CFLAGS"
1022         ethereal_save_CPPFLAGS="$CPPFLAGS"
1023         if test "x$krb5_dir" != "x"
1024         then
1025           #
1026           # The user specified a directory in which kerberos resides,
1027           # so add the "include" subdirectory of that directory to
1028           # the include file search path and the "lib" subdirectory
1029           # of that directory to the library search path.
1030           #
1031           # XXX - if there's also a kerberos in a directory that's
1032           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
1033           # make us find the version in the specified directory,
1034           # as the compiler and/or linker will search that other
1035           # directory before it searches the specified directory.
1036           #
1037           CFLAGS="$CFLAGS -I$krb5_dir/include"
1038           CPPFLAGS="$CPPFLAGS -I$krb5_dir/include"
1039           ac_heimdal_version=`grep heimdal $krb5_dir/include/krb5.h | head -n 1 | sed 's/^.*heimdal.*$/HEIMDAL/'`
1040           ac_mit_version=`grep 'Massachusetts Institute of Technology' $krb5_dir/include/krb5.h | head -n 1 | sed 's/^.*Massachusetts Institute of Technology.*$/MIT/'`
1041           ac_krb5_version="$ac_heimdal_version$ac_mit_version"
1042           if test "x$ac_krb5_version" = "xHEIMDAL"
1043               KRB5_LIBS="-L$krb5_dir/lib -lkrb5 -lasn1 $SSL_LIBS -lroken -lcrypt"
1044           then
1045               KRB5_LIBS="-L$krb5_dir/lib -lkrb5 -lk5crypto -lcom_err"
1046           fi
1047           if test "x$ac_krb5_version" = "xMIT"
1048           then
1049             AC_DEFINE(HAVE_MIT_KERBEROS, 1, [Define to use MIT kerberos])
1050           fi
1051         else
1052           AC_PATH_PROG(KRB5_CONFIG, krb5-config)
1053           if test -x "$KRB5_CONFIG"
1054           then
1055             KRB5_FLAGS=`"$KRB5_CONFIG" --cflags`
1056             KRB5_LIBS=`"$KRB5_CONFIG" --libs`
1057             CFLAGS="$CFLAGS $KRB5_FLAGS"
1058             CPPFLAGS="$CPPFLAGS $KRB5_FLAGS"
1059             #
1060             # If -lcrypto is in KRB5_FLAGS, we require it to build
1061             # with Heimdal/MIT.  We don't want to built with it by
1062             # default, due to annoying license incompatibilities
1063             # between the OpenSSL license and the GPL, so:
1064             #
1065             #   if SSL_LIBS is set to a non-empty string, we
1066             #   remove -lcrypto from KRB5_LIBS and replace
1067             #   it with SSL_LIBS;
1068             #
1069             #   if SSL_LIBS is not set to a non-empty string
1070             #   we fail with an appropriate error message.
1071             #
1072             case "$KRB5_LIBS" in
1073             *-lcrypto*)
1074                 if test ! -z "$SSL_LIBS"
1075                 then
1076                     KRB5_LIBS=`echo $KRB5_LIBS | sed 's/-lcrypto//'`
1077                     KRB5_LIBS="$KRB5_LIBS $SSL_LIBS"
1078                 else
1079                     AC_MSG_ERROR([Kerberos library requires -lcrypto but --with-ssl not specified])
1080                 fi
1081                 ;;
1082             esac
1083             ac_krb5_version=`"$KRB5_CONFIG" --version | head -n 1 | sed -e 's/^.*heimdal.*$/HEIMDAL/' -e 's/^Kerberos .*$/MIT/'`
1084           fi
1085         fi
1086
1087         #
1088         # Make sure we have "krb5.h".  If we don't, it means we probably
1089         # don't have kerberos, so don't use it.
1090         #
1091         AC_CHECK_HEADER(krb5.h,,
1092           [
1093             if test "x$krb5_dir" != "x"
1094             then
1095               #
1096               # The user used "--with-krb5=" to specify a directory
1097               # containing kerberos, but we didn't find the header file
1098               # there; that either means they didn't specify the
1099               # right directory or are confused about whether kerberos
1100               # is, in fact, installed.  Report the error and give up.
1101               #
1102               AC_MSG_ERROR([kerberos header not found in directory specified in --with-krb5])
1103             else
1104               if test "x$want_krb5" = "xyes"
1105               then
1106                 #
1107                 # The user tried to force us to use the library, but we
1108                 # couldn't find the header file; report an error.
1109                 #
1110                 AC_MSG_ERROR(Header file krb5.h not found.)
1111               else
1112                 #
1113                 # We couldn't find the header file; don't use the
1114                 # library, as it's probably not present.
1115                 #
1116                 want_krb5=no
1117                 AC_MSG_RESULT(No Heimdal or MIT header found - disabling dissection for some kerberos data in packet decoding)
1118               fi
1119             fi
1120           ])
1121
1122         if test "x$want_krb5" != "xno"
1123         then
1124             #
1125             # Well, we at least have the krb5 header file.
1126             # Check whether this is Heimdal or MIT.
1127             #
1128             AC_MSG_CHECKING(whether the Kerberos library is Heimdal or MIT)
1129             if test "x$ac_krb5_version" = "xHEIMDAL" -o "x$ac_krb5_version" = "xMIT"
1130             then
1131                 #
1132                 # Yes.
1133                 # Check whether we have krb5_kt_resolve - and whether
1134                 # we need to link with -lresolv when linking with
1135                 # the Kerberos library.
1136                 #
1137                 AC_MSG_RESULT($ac_krb5_version)
1138                 ethereal_save_LIBS="$LIBS"
1139                 found_krb5_kt_resolve=no
1140                 for extras in "" "-lresolv"
1141                 do
1142                     LIBS="$KRB5_LIBS $extras"
1143                     if test -z "$extras"
1144                     then
1145                         AC_MSG_CHECKING([whether $ac_krb5_version includes krb5_kt_resolve])
1146                     else
1147                         AC_MSG_CHECKING([whether $ac_krb5_version includes krb5_kt_resolve (linking with $extras)])
1148                     fi
1149                     AC_TRY_LINK(
1150                         [
1151                         ],
1152                         [
1153                             krb5_kt_resolve();
1154                         ],
1155                         [
1156                             #
1157                             # We found "krb5_kt_resolve()", and required
1158                             # the libraries in extras as well.
1159                             #
1160                             AC_MSG_RESULT(yes)
1161                             KRB5_LIBS="$LIBS"
1162                             AC_DEFINE(HAVE_KERBEROS, 1, [Define to use kerberos])
1163                             if test "x$ac_krb5_version" = "xHEIMDAL"
1164                             then
1165                                 AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1, [Define to use heimdal kerberos])
1166                             elif test "x$ac_krb5_version" = "xMIT"
1167                             then
1168                                 AC_DEFINE(HAVE_MIT_KERBEROS, 1, [Define to use MIT kerberos])
1169                             fi
1170                             found_krb5_kt_resolve=yes
1171                             break
1172                         ],
1173                         [
1174                             AC_MSG_RESULT(no)
1175                         ])
1176                 done
1177                 if test "$found_krb5_kt_resolve" = no
1178                 then
1179                     #
1180                     # We didn't find "krb5_kt_resolve()" in the
1181                     # Kerberos library, even when we tried linking
1182                     # with -lresolv; we can't link with kerberos.
1183                     #
1184                     if test "x$want_krb5" = "xyes"
1185                     then
1186                         #
1187                         # The user tried to force us to use the library,
1188                         # but we can't do so; report an error.
1189                         #
1190                         AC_MSG_ERROR(Usable $ac_krb5_version not found)
1191                     else
1192                         #
1193                         # Restore the versions of CFLAGS and CPPFLAGS
1194                         # from before we added the flags for Kerberos.
1195                         #
1196                         AC_MSG_RESULT(Usable $ac_krb5_version not found - disabling dissection for some kerberos data in packet decoding)
1197                         CFLAGS="$ethereal_save_CFLAGS"
1198                         CPPFLAGS="$ethereal_save_CPPFLAGS"
1199                         KRB5_LIBS=""
1200                         want_krb5=no
1201                     fi
1202                 else
1203                     #
1204                     # We can link with Kerberos; see whether krb5.h
1205                     # defines KEYTYPE_ARCFOUR_56 (where "defines" means
1206                     # "as a #define or as an enum member).
1207                     #
1208                     AC_MSG_CHECKING([whether krb5.h defines KEYTYPE_ARCFOUR_56])
1209                     AC_COMPILE_IFELSE(
1210                       [
1211                         AC_LANG_SOURCE(
1212                           [[
1213                             #include <krb5.h>
1214                             #include <stdio.h>
1215
1216                             main()
1217                             {
1218                               printf("%u\n", KEYTYPE_ARCFOUR_56);
1219                             }
1220                           ]])
1221                       ],
1222                       [
1223                         AC_MSG_RESULT(yes)
1224                         AC_DEFINE(HAVE_KEYTYPE_ARCFOUR_56, 1, [Define if krb5.h defines KEYTYPE_ARCFOUR_56])
1225                       ],
1226                       [
1227                         AC_MSG_RESULT(no)
1228                       ])
1229                 fi
1230                 LIBS="$ethereal_save_LIBS"
1231             else
1232                 #
1233                 # It's not Heimdal or MIT.
1234                 #
1235                 AC_MSG_RESULT(no)
1236                 if test "x$want_krb5" = "xyes"
1237                 then
1238                     #
1239                     # The user tried to force us to use the library,
1240                     # but we can't do so; report an error.
1241                     #
1242                     AC_MSG_ERROR(Kerberos not found)
1243                 else
1244                     #
1245                     # Restore the versions of CFLAGS and CPPFLAGS
1246                     # from before we added the flags for Kerberos.
1247                     #
1248                     AC_MSG_RESULT(Kerberos not found - disabling dissection for some kerberos data in packet decoding)
1249                     CFLAGS="$ethereal_save_CFLAGS"
1250                     CPPFLAGS="$ethereal_save_CPPFLAGS"
1251                     KRB5_LIBS=""
1252                     want_krb5=no
1253                 fi
1254             fi
1255         else
1256             #
1257             # The user asked us not to use Kerberos, or they didn't
1258             # say whether they wanted us to use it but we found
1259             # that we couldn't.
1260             #
1261             # Restore the versions of CFLAGS and CPPFLAGS
1262             # from before we added the flags for Kerberos.
1263             #
1264             CFLAGS="$ethereal_save_CFLAGS"
1265             CPPFLAGS="$ethereal_save_CPPFLAGS"
1266             KRB5_LIBS=""
1267             want_krb5=no
1268         fi
1269         AC_SUBST(KRB5_LIBS)
1270 ])