configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.2.0dev],[http://rsync.samba.org/bugzilla.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_EGREP
  45 AC_PROG_INSTALL
  46 AC_PROG_MKDIR_P
  47 AC_PROG_CC_STDC
  48 AC_SUBST(SHELL)
  49 AC_PATH_PROG([PERL], [perl])
  50
  51 AC_DEFINE([_GNU_SOURCE], 1,
  52           [Define _GNU_SOURCE so that we get all necessary prototypes])
  53
  54 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  55         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  56 fi
  57
  58 AC_ARG_ENABLE(profile,
  59         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  60 if test x"$enable_profile" = x"yes"; then
  61         CFLAGS="$CFLAGS -pg"
  62 fi
  63
  64
  65 # Specifically, this turns on panic_action handling.
  66 AC_ARG_ENABLE(maintainer-mode,
  67         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
  68 if test x"$enable_maintainer_mode" = x"yes"; then
  69         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  70 fi
  71
  72
  73 # This is needed for our included version of popt.  Kind of silly, but
  74 # I don't want our version too far out of sync.
  75 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  76
  77 # If GCC, turn on warnings.
  78 if test x"$GCC" = x"yes"; then
  79         CFLAGS="$CFLAGS -Wall -W"
  80 fi
  81
  82 AC_ARG_WITH(included-popt,
  83         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
  84
  85 AC_ARG_WITH(included-zlib,
  86         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
  87
  88 AC_ARG_WITH(protected-args,
  89         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
  90 if test x"$with_protected_args" = x"yes"; then
  91         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
  92 fi
  93
  94 AC_ARG_WITH(rsync-path,
  95         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
  96         [ RSYNC_PATH="$with_rsync_path" ],
  97         [ RSYNC_PATH="rsync" ])
  98
  99 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 100
 101 AC_ARG_WITH(rsyncd-conf,
 102         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 103         [ if test ! -z "$with_rsyncd_conf" ; then
 104                 case $with_rsyncd_conf in
 105                         yes|no)
 106                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 107                                 ;;
 108                         /*)
 109                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 110                                 ;;
 111                         *)
 112                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 113                                 ;;
 114                 esac
 115         else
 116                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 117         fi ],
 118         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 119
 120 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 121
 122 AC_ARG_WITH(rsh,
 123         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 124
 125 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 126 if test x$HAVE_REMSH = x1; then
 127         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 128 fi
 129
 130 if test x"$with_rsh" != x; then
 131         RSYNC_RSH="$with_rsh"
 132 else
 133         RSYNC_RSH="ssh"
 134 fi
 135 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 136
 137 AC_CHECK_PROG(HAVE_YODL2MAN, yodl2man, 1, 0)
 138 if test x$HAVE_YODL2MAN = x1; then
 139     MAKE_MAN=man
 140 else
 141     MAKE_MAN=man-copy
 142 fi
 143
 144 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 145 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 146 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 147
 148 AC_ARG_WITH(nobody-group,
 149     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 150     [ NOBODY_GROUP="$with_nobody_group" ])
 151
 152 if test x"$with_nobody_group" = x; then
 153     AC_MSG_CHECKING([the group for user "nobody"])
 154     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 155         NOBODY_GROUP=nobody
 156     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 157         NOBODY_GROUP=nogroup
 158     else
 159         NOBODY_GROUP=nobody # test for others?
 160     fi
 161     AC_MSG_RESULT($NOBODY_GROUP)
 162 fi
 163
 164 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 165 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 166
 167 # arrgh. libc in some old debian version screwed up the largefile
 168 # stuff, getting byte range locking wrong
 169 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 170 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 171 #define _FILE_OFFSET_BITS 64
 172 #include <stdio.h>
 173 #include <fcntl.h>
 174 #include <sys/types.h>
 175 #include <sys/wait.h>
 176 #if HAVE_UNISTD_H
 177 #include <unistd.h>
 178 #endif
 179
 180 int main(void)
 181 {
 182         struct flock lock;
 183         int status;
 184         char tpl[32] = "/tmp/locktest.XXXXXX";
 185         int fd = mkstemp(tpl);
 186         if (fd < 0) {
 187                 strcpy(tpl, "conftest.dat");
 188                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 189         }
 190
 191         lock.l_type = F_WRLCK;
 192         lock.l_whence = SEEK_SET;
 193         lock.l_start = 0;
 194         lock.l_len = 1;
 195         lock.l_pid = 0;
 196         fcntl(fd,F_SETLK,&lock);
 197         if (fork() == 0) {
 198                 lock.l_start = 1;
 199                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 200         }
 201         wait(&status);
 202         unlink(tpl);
 203         return WEXITSTATUS(status);
 204 }
 205 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 206 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 207    AC_SYS_LARGEFILE
 208 fi
 209
 210 ipv6type=unknown
 211 ipv6lib=none
 212 ipv6trylibc=yes
 213
 214 AC_ARG_ENABLE(ipv6,
 215         AS_HELP_STRING([--disable-ipv6],[do not even try to use IPv6]))
 216 if test x"$enable_ipv6" != x"no"; then
 217         AC_MSG_CHECKING([ipv6 stack type])
 218         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 219                 case $i in
 220                 inria)
 221                         # http://www.kame.net/
 222                         AC_EGREP_CPP(yes, [
 223 #include <netinet/in.h>
 224 #ifdef IPV6_INRIA_VERSION
 225 yes
 226 #endif],
 227                                 [ipv6type=$i;
 228                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 229                                 ])
 230                         ;;
 231                 kame)
 232                         # http://www.kame.net/
 233                         AC_EGREP_CPP(yes, [
 234 #include <netinet/in.h>
 235 #ifdef __KAME__
 236 yes
 237 #endif],
 238                                 [ipv6type=$i;
 239                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 240                         ;;
 241                 linux-glibc)
 242                         # http://www.v6.linux.or.jp/
 243                         AC_EGREP_CPP(yes, [
 244 #include <features.h>
 245 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 246 yes
 247 #endif],
 248                                 [ipv6type=$i;
 249 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 250                         ;;
 251                 linux-inet6)
 252                         # http://www.v6.linux.or.jp/
 253                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 254                                 ipv6type=$i
 255                                 ipv6lib=inet6
 256                                 ipv6libdir=/usr/inet6/lib
 257                                 ipv6trylibc=yes;
 258                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 259                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 260                         fi
 261                         ;;
 262                 solaris)
 263                         # http://www.sun.com
 264                         AC_EGREP_CPP(yes, [
 265 #include <netinet/ip6.h>
 266 #ifdef __sun
 267 yes
 268 #endif],
 269                                 [ipv6type=$i;
 270                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 271                         ;;
 272                 toshiba)
 273                         AC_EGREP_CPP(yes, [
 274 #include <sys/param.h>
 275 #ifdef _TOSHIBA_INET6
 276 yes
 277 #endif],
 278                                 [ipv6type=$i;
 279                                 ipv6lib=inet6;
 280                                 ipv6libdir=/usr/local/v6/lib;
 281                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 282                         ;;
 283                 v6d)
 284                         AC_EGREP_CPP(yes, [
 285 #include </usr/local/v6/include/sys/v6config.h>
 286 #ifdef __V6D__
 287 yes
 288 #endif],
 289                                 [ipv6type=$i;
 290                                 ipv6lib=v6;
 291                                 ipv6libdir=/usr/local/v6/lib;
 292                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 293                         ;;
 294                 zeta)
 295                         AC_EGREP_CPP(yes, [
 296 #include <sys/param.h>
 297 #ifdef _ZETA_MINAMI_INET6
 298 yes
 299 #endif],
 300                                 [ipv6type=$i;
 301                                 ipv6lib=inet6;
 302                                 ipv6libdir=/usr/local/v6/lib;
 303                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 304                         ;;
 305                 cygwin)
 306                         AC_EGREP_CPP(yes, [
 307 #include <netinet/in.h>
 308 #ifdef _CYGWIN_IN6_H
 309 yes
 310 #endif],
 311                                 [ipv6type=$i;
 312                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 313                         ;;
 314                 esac
 315                 if test "$ipv6type" != "unknown"; then
 316                         break
 317                 fi
 318         done
 319         AC_MSG_RESULT($ipv6type)
 320
 321         AC_SEARCH_LIBS(getaddrinfo, inet6)
 322 fi
 323
 324 dnl Do you want to disable use of locale functions
 325 AC_ARG_ENABLE([locale],
 326         AS_HELP_STRING([--disable-locale],[disable locale features]))
 327 AH_TEMPLATE([CONFIG_LOCALE],
 328 [Undefine if you do not want locale features.  By default this is defined.])
 329 if test x"$enable_locale" != x"no"; then
 330         AC_DEFINE(CONFIG_LOCALE)
 331 fi
 332
 333 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 334 case $host_os in
 335         *cygwin* ) AC_MSG_RESULT(yes)
 336                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 337                             [Define to 1 if sockets need to be shutdown])
 338                    ;;
 339                * ) AC_MSG_RESULT(no);;
 340 esac
 341
 342 AC_C_BIGENDIAN
 343 AC_HEADER_DIRENT
 344 AC_HEADER_TIME
 345 AC_HEADER_SYS_WAIT
 346 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 347     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 348     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 349     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 350     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 351     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 352     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 353     zlib.h)
 354 AC_HEADER_MAJOR_FIXED
 355
 356 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 357 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 358 #include <sys/types.h>
 359 #ifdef MAJOR_IN_MKDEV
 360 #include <sys/mkdev.h>
 361 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 362 #  define makedev mkdev
 363 # endif
 364 #elif defined MAJOR_IN_SYSMACROS
 365 #include <sys/sysmacros.h>
 366 #endif
 367
 368 int main(void)
 369 {
 370         dev_t dev = makedev(0, 5, 7);
 371         if (major(dev) != 5 || minor(dev) != 7)
 372                 return 1;
 373         return 0;
 374 }
 375 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 376 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 377    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 378 fi
 379
 380 AC_CHECK_SIZEOF(int)
 381 AC_CHECK_SIZEOF(long)
 382 AC_CHECK_SIZEOF(long long)
 383 AC_CHECK_SIZEOF(short)
 384 AC_CHECK_SIZEOF(int16_t)
 385 AC_CHECK_SIZEOF(uint16_t)
 386 AC_CHECK_SIZEOF(int32_t)
 387 AC_CHECK_SIZEOF(uint32_t)
 388 AC_CHECK_SIZEOF(int64_t)
 389 AC_CHECK_SIZEOF(off_t)
 390 AC_CHECK_SIZEOF(off64_t)
 391 AC_CHECK_SIZEOF(time_t)
 392 AC_CHECK_SIZEOF(char*)
 393
 394 AC_C_INLINE
 395
 396 AC_TYPE_LONG_DOUBLE_WIDER
 397 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 398 if test $ac_cv_c_long_double = yes; then
 399   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 400 fi
 401
 402 AC_TYPE_UID_T
 403 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 404 AC_TYPE_GETGROUPS
 405 AC_CHECK_MEMBERS([struct stat.st_rdev,
 406                   struct stat.st_mtimensec,
 407                   struct stat.st_mtimespec.tv_nsec,
 408                   struct stat.st_mtim.tv_nsec],,,[
 409 #ifdef HAVE_SYS_TYPES_H
 410 #include <sys/types.h>
 411 #endif
 412 #ifdef HAVE_SYS_STAT_H
 413 #include <sys/stat.h>
 414 #endif
 415 #ifdef HAVE_UNISTD_H
 416 #include <unistd.h>
 417 #endif])
 418
 419 TYPE_SOCKLEN_T
 420
 421 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 422     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 423 if test x"$rsync_cv_errno" = x"yes"; then
 424    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 425 fi
 426
 427 # The following test taken from the cvs sources
 428 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 429 # These need checks to be before checks for any other functions that
 430 #    might be in the same libraries.
 431 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 432 # libsocket.so which has a bad implementation of gethostbyname (it
 433 # only looks in /etc/hosts), so we only look for -lsocket if we need
 434 # it.
 435 AC_CHECK_FUNCS(connect)
 436 if test x"$ac_cv_func_connect" = x"no"; then
 437     case "$LIBS" in
 438     *-lnsl*) ;;
 439     *) AC_CHECK_LIB(nsl_s, printf) ;;
 440     esac
 441     case "$LIBS" in
 442     *-lnsl*) ;;
 443     *) AC_CHECK_LIB(nsl, printf) ;;
 444     esac
 445     case "$LIBS" in
 446     *-lsocket*) ;;
 447     *) AC_CHECK_LIB(socket, connect) ;;
 448     esac
 449     case "$LIBS" in
 450     *-linet*) ;;
 451     *) AC_CHECK_LIB(inet, connect) ;;
 452     esac
 453     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 454     dnl has been cached.
 455     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 456        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 457         # ac_cv_func_connect=yes
 458         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 459         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 460     fi
 461 fi
 462
 463 AC_SEARCH_LIBS(inet_ntop, resolv)
 464
 465 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 466 # accept either iconv_open or libiconv_open, since some include files map
 467 # the former to the latter.
 468 AC_SEARCH_LIBS(iconv_open, iconv)
 469 AC_SEARCH_LIBS(libiconv_open, iconv)
 470
 471 AC_MSG_CHECKING([for iconv declaration])
 472 AC_CACHE_VAL(am_cv_proto_iconv, [
 473     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 474 #include <stdlib.h>
 475 #include <iconv.h>
 476 extern
 477 #ifdef __cplusplus
 478 "C"
 479 #endif
 480 #if defined(__STDC__) || defined(__cplusplus)
 481 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 482 #else
 483 size_t iconv();
 484 #endif
 485 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 486       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 487     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 488 AC_MSG_RESULT([$]{ac_t:-
 489          }[$]am_cv_proto_iconv)
 490 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 491                    [Define as const if the declaration of iconv() needs const.])
 492
 493 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 494
 495 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 496
 497 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 498 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 499 #include <sys/socket.h>])
 500
 501 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 502 #   builtin getaddrinfo if one of the defines don't exist
 503 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 504                rsync_cv_HAVE_GETADDR_DEFINES,[
 505                         AC_EGREP_CPP(yes, [
 506                         #include <sys/types.h>
 507                         #include <sys/socket.h>
 508                         #include <netdb.h>
 509                         #ifdef AI_PASSIVE
 510                         yes
 511                         #endif],
 512                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 513                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 514 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 515         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 516         # something else so we must include <netdb.h> to get the
 517         # redefinition.
 518         AC_CHECK_FUNCS(getaddrinfo, ,
 519                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 520                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 521                 #include <sys/socket.h>
 522                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 523                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 524                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 525                         AC_LIBOBJ([getaddrinfo])])])
 526     ],[AC_LIBOBJ([getaddrinfo])])
 527
 528 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 529                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 530                 [],
 531                 [
 532 #include <sys/types.h>
 533 #include <sys/socket.h>
 534 ])
 535
 536 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 537                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 538                 [],
 539                 [
 540 #include <sys/types.h>
 541 #include <sys/socket.h>
 542 #include <netinet/in.h>
 543 ])
 544
 545 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 546                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 547                 [],
 548                 [
 549 #include <sys/types.h>
 550 #include <sys/socket.h>
 551 #include <netinet/in.h>
 552 ])
 553
 554 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 555                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 556                 [],
 557                 [
 558 #include <sys/types.h>
 559 #include <sys/socket.h>
 560 #include <netinet/in.h>
 561 ])
 562
 563 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 564 #if HAVE_SYS_TYPES_H
 565 # include <sys/types.h>
 566 #endif
 567 #if HAVE_SYS_STAT_H
 568 # include <sys/stat.h>
 569 #endif
 570 #if STDC_HEADERS
 571 # include <stdlib.h>
 572 # include <stddef.h>
 573 #else
 574 # if HAVE_STDLIB_H
 575 #  include <stdlib.h>
 576 # endif
 577 #endif
 578 ])
 579
 580 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 581 #
 582 AC_CHECK_FUNCS(strcasecmp)
 583 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 584     AC_CHECK_LIB(resolv, strcasecmp)
 585 fi
 586
 587 AC_CHECK_FUNCS(aclsort)
 588 if test x"$ac_cv_func_aclsort" = x"no"; then
 589     AC_CHECK_LIB(sec, aclsort)
 590 fi
 591
 592 dnl At the moment we don't test for a broken memcmp(), because all we
 593 dnl need to do is test for equality, not comparison, and it seems that
 594 dnl every platform has a memcmp that can do at least that.
 595 dnl AC_FUNC_MEMCMP
 596
 597 AC_FUNC_UTIME_NULL
 598 AC_FUNC_ALLOCA
 599 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 600     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 601     chflags getattrlist \
 602     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 603     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 604     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 605     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 606     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 607     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep)
 608
 609 dnl cygwin iconv.h defines iconv_open as libiconv_open
 610 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 611     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 612 fi
 613
 614 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 615
 616 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 617 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 618 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 619 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 620     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 621 fi
 622
 623 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 624 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 625         #define _GNU_SOURCE 1
 626         #include <linux/falloc.h>
 627         #ifndef FALLOC_FL_PUNCH_HOLE
 628         #error FALLOC_FL_PUNCH_HOLE is missing
 629         #endif
 630     ]])], [
 631         AC_MSG_RESULT([yes])
 632         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 633     ], [
 634         AC_MSG_RESULT([no])
 635     ]
 636 )
 637
 638 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 639 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 640         #define _GNU_SOURCE 1
 641         #include <linux/falloc.h>
 642         #ifndef FALLOC_FL_ZERO_RANGE
 643         #error FALLOC_FL_ZERO_RANGE is missing
 644         #endif
 645     ]])], [
 646         AC_MSG_RESULT([yes])
 647         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 648     ], [
 649         AC_MSG_RESULT([no])
 650     ]
 651 )
 652
 653 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 654 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 655 #include <unistd.h>
 656 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 657 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 658     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 659 fi
 660
 661 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 662     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 663     case $host_os in
 664     *cygwin*)
 665         AC_MSG_RESULT(yes)
 666         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 667                   [Define if posix_fallocate is efficient (Cygwin)])
 668         ;;
 669     *)
 670         AC_MSG_RESULT(no)
 671         ;;
 672     esac
 673 fi
 674
 675 dnl End of preallocation stuff
 676
 677 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 678 if test $ac_cv_func_getpgrp = yes; then
 679     AC_FUNC_GETPGRP
 680 fi
 681
 682 AC_ARG_ENABLE(iconv-open,
 683     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 684     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 685
 686 if test x"$enable_iconv_open" != x"no"; then
 687     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 688 fi
 689
 690 AC_ARG_ENABLE(iconv,
 691     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 692     [], [enable_iconv=$enable_iconv_open])
 693 AH_TEMPLATE([ICONV_OPTION],
 694 [Define if you want the --iconv option.  Specifing a value will set the
 695 default iconv setting (a NULL means no --iconv processing by default).])
 696 if test x"$enable_iconv" != x"no"; then
 697         if test x"$enable_iconv" = x"yes"; then
 698                 AC_DEFINE(ICONV_OPTION, NULL)
 699         else
 700                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 701         fi
 702         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 703 fi
 704
 705 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 706   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 707 #if HAVE_UNISTD_H
 708 # include <unistd.h>
 709 #endif
 710 #include <stdlib.h>
 711 #include <errno.h>
 712 int main(void) {
 713         char const *dangling_symlink = "conftest.dangle";
 714         unlink(dangling_symlink);
 715         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 716         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 717         return 0;
 718     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 719 if test $rsync_cv_chown_modifies_symlink = yes; then
 720   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 721 fi
 722
 723 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 724   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 725 #if HAVE_UNISTD_H
 726 # include <unistd.h>
 727 #endif
 728 #include <stdlib.h>
 729 #include <errno.h>
 730 #define FILENAME "conftest.dangle"
 731 int main(void) {
 732         unlink(FILENAME);
 733         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 734         unlink(FILENAME "2");
 735         if (link(FILENAME, FILENAME "2") < 0) return 1;
 736         return 0;
 737     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 738 if test $rsync_cv_can_hardlink_symlink = yes; then
 739   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 740 fi
 741
 742 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 743   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 744 #if HAVE_UNISTD_H
 745 # include <unistd.h>
 746 #endif
 747 #ifdef HAVE_SYS_STAT_H
 748 #include <sys/stat.h>
 749 #endif
 750 #include <stdlib.h>
 751 #include <errno.h>
 752 #define FILENAME "conftest.fifi"
 753 int main(void) {
 754         unlink(FILENAME);
 755         if (mkfifo(FILENAME, 0777) < 0) abort();
 756         unlink(FILENAME "2");
 757         if (link(FILENAME, FILENAME "2") < 0) return 1;
 758         return 0;
 759     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 760 if test $rsync_cv_can_hardlink_special = yes; then
 761     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 762 fi
 763
 764 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 765 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 766 #include <sys/types.h>
 767 #include <sys/socket.h>
 768
 769 int main(void) {
 770        int fd[2];
 771        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
 772 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 773 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 774     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 775 fi
 776
 777 AC_REPLACE_FUNCS([getpass])
 778
 779 if test x"$with_included_popt" != x"yes"; then
 780     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 781 fi
 782 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 783     # If the system has /usr/include/popt/popt.h, we enable the
 784     # included popt because an attempt to "#include <popt/popt.h>"
 785     # would use our included header file anyway (due to -I.), and
 786     # might conflict with the system popt.
 787     with_included_popt=yes
 788 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 789     with_included_popt=yes
 790 fi
 791
 792 AC_MSG_CHECKING([whether to use included libpopt])
 793 if test x"$with_included_popt" = x"yes"; then
 794     AC_MSG_RESULT($srcdir/popt)
 795     BUILD_POPT='$(popt_OBJS)'
 796     CFLAGS="-I$srcdir/popt $CFLAGS"
 797     if test x"$ALLOCA" != x
 798     then
 799         # this can be removed when/if we add an included alloca.c;
 800         #  see autoconf documentation on AC_FUNC_ALLOCA
 801         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 802     fi
 803 else
 804     AC_MSG_RESULT(no)
 805 fi
 806
 807 # We default to using our zlib unless --with-included-zlib=no is given.
 808 if test x"$with_included_zlib" != x"no"; then
 809     with_included_zlib=yes
 810 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
 811     with_included_zlib=yes
 812 fi
 813 if test x"$with_included_zlib" != x"yes"; then
 814     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
 815 fi
 816
 817 AC_MSG_CHECKING([whether to use included zlib])
 818 if test x"$with_included_zlib" = x"yes"; then
 819     AC_MSG_RESULT($srcdir/zlib)
 820     BUILD_ZLIB='$(zlib_OBJS)'
 821     CFLAGS="-I$srcdir/zlib $CFLAGS"
 822 else
 823     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
 824     AC_MSG_RESULT(no)
 825 fi
 826
 827 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 828 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
 829 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 830     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 831 fi
 832
 833 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 834 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
 835 #include <dirent.h>
 836 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 837 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 838 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
 839 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 840     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 841 fi
 842
 843 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
 844 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 845 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
 846 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
 847     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 848 fi
 849
 850 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 851 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
 852 #include <unistd.h>]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
 853 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 854     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 855 fi
 856
 857 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 858 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 859 #include <sys/types.h>
 860 #include <stdarg.h>
 861 #include <stdio.h>
 862 #include <stdlib.h>
 863 #include <string.h>
 864 void foo(const char *format, ...) {
 865        va_list ap;
 866        int len;
 867        char buf[5];
 868
 869        va_start(ap, format);
 870        len = vsnprintf(0, 0, format, ap);
 871        va_end(ap);
 872        if (len != 5) exit(1);
 873
 874        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 875 }
 876 int main(void) { foo("hello"); return 0; }
 877 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
 878 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 879     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 880 fi
 881
 882
 883 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 884 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 885 #include <sys/types.h>
 886 #include <sys/stat.h>
 887 #include <unistd.h>
 888 int main(void) {
 889   struct stat st;
 890   char tpl[20]="/tmp/test.XXXXXX";
 891   int fd = mkstemp(tpl);
 892   if (fd == -1) return 1;
 893   unlink(tpl);
 894   if (fstat(fd, &st) != 0) return 1;
 895   if ((st.st_mode & 0777) != 0600) return 1;
 896   return 0;
 897 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
 898 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 899     case $host_os in
 900     hpux*)
 901         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 902         dnl so we noisily skip using it.  See HP change request JAGaf34426
 903         dnl for details. (sbonds)
 904         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 905         ;;
 906     *)
 907         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 908         ;;
 909     esac
 910 fi
 911
 912
 913 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 914 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 915 #include <stdio.h>
 916 #include <sys/stat.h>
 917 #include <errno.h>
 918 #if HAVE_UNISTD_H
 919 # include <unistd.h>
 920 #endif
 921 int main(void) { int rc, ec; char *fn = "fifo-test";
 922 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 923 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 924 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
 925 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 926     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 927 fi
 928
 929 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 930 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 931 #include <stdio.h>
 932 #include <sys/stat.h>
 933 #include <errno.h>
 934 #if HAVE_UNISTD_H
 935 # include <unistd.h>
 936 #endif
 937 int main(void) { int rc, ec; char *fn = "sock-test";
 938 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 939 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 940 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
 941 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 942     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 943 fi
 944
 945 #
 946 # The following test was mostly taken from the tcl/tk plus patches
 947 #
 948 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 949 rm -rf conftest*
 950 cat > conftest.$ac_ext <<EOF
 951 int main(void) { return 0; }
 952 EOF
 953 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 954 if test -f conftest..o; then
 955     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 956 else
 957     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 958 fi
 959 rm -rf conftest*
 960 ])
 961 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 962     OBJ_SAVE="#"
 963     OBJ_RESTORE="#"
 964     CC_SHOBJ_FLAG='-o $@'
 965 else
 966     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 967     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 968     CC_SHOBJ_FLAG=""
 969 fi
 970
 971 AC_SUBST(OBJ_SAVE)
 972 AC_SUBST(OBJ_RESTORE)
 973 AC_SUBST(CC_SHOBJ_FLAG)
 974 AC_SUBST(BUILD_POPT)
 975 AC_SUBST(BUILD_ZLIB)
 976 AC_SUBST(MAKE_MAN)
 977
 978 AC_CHECK_FUNCS(_acl __acl _facl __facl)
 979 #################################################
 980 # check for ACL support
 981
 982 AC_MSG_CHECKING([whether to support ACLs])
 983 AC_ARG_ENABLE(acl-support,
 984         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
 985
 986 if test x"$enable_acl_support" = x"no"; then
 987     AC_MSG_RESULT(no)
 988 else
 989     case "$host_os" in
 990     *sysv5*)
 991         AC_MSG_RESULT(Using UnixWare ACLs)
 992         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
 993         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
 994         ;;
 995     solaris*)
 996         AC_MSG_RESULT(Using solaris ACLs)
 997         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
 998         AC_DEFINE(SUPPORT_ACLS, 1)
 999         ;;
1000     *hpux*)
1001         AC_MSG_RESULT(Using HPUX ACLs)
1002         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1003         AC_DEFINE(SUPPORT_ACLS, 1)
1004         ;;
1005     *irix*)
1006         AC_MSG_RESULT(Using IRIX ACLs)
1007         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1008         AC_DEFINE(SUPPORT_ACLS, 1)
1009         ;;
1010     *aix*)
1011         AC_MSG_RESULT(Using AIX ACLs)
1012         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1013         AC_DEFINE(SUPPORT_ACLS, 1)
1014         ;;
1015     *osf*)
1016         AC_MSG_RESULT(Using Tru64 ACLs)
1017         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1018         AC_DEFINE(SUPPORT_ACLS, 1)
1019         LIBS="$LIBS -lpacl"
1020         ;;
1021     darwin*)
1022         AC_MSG_RESULT(Using OS X ACLs)
1023         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1024         AC_DEFINE(SUPPORT_ACLS, 1)
1025         ;;
1026     *)
1027         AC_MSG_RESULT(running tests:)
1028         AC_CHECK_LIB(acl,acl_get_file)
1029         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1030             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1031 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1032         AC_MSG_CHECKING(ACL test results)
1033         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1034             AC_MSG_RESULT(Using posix ACLs)
1035             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1036             AC_DEFINE(SUPPORT_ACLS, 1)
1037             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1038                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1039 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1040             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1041                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1042             fi
1043         else
1044             if test x"$enable_acl_support" = x"yes"; then
1045                 AC_MSG_ERROR(Failed to find ACL support)
1046             else
1047                 AC_MSG_RESULT(No ACL support found)
1048             fi
1049         fi
1050         ;;
1051     esac
1052 fi
1053
1054 #################################################
1055 # check for extended attribute support
1056 AC_MSG_CHECKING(whether to support extended attributes)
1057 AC_ARG_ENABLE(xattr-support,
1058     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1059     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1060         *yes*) enable_xattr_support=maybe ;;
1061         *) enable_xattr_support=no ;;
1062         esac])
1063 AH_TEMPLATE([SUPPORT_XATTRS],
1064 [Define to 1 to add support for extended attributes])
1065 if test x"$enable_xattr_support" = x"no"; then
1066     AC_MSG_RESULT(no)
1067 else
1068     case "$host_os" in
1069     *linux*|*netbsd*)
1070         AC_MSG_RESULT(Using Linux xattrs)
1071         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1072         AC_DEFINE(SUPPORT_XATTRS, 1)
1073         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1074         AC_CHECK_LIB(attr,getxattr)
1075         ;;
1076     darwin*)
1077         AC_MSG_RESULT(Using OS X xattrs)
1078         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1079         AC_DEFINE(SUPPORT_XATTRS, 1)
1080         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1081         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1082         ;;
1083     freebsd*)
1084         AC_MSG_RESULT(Using FreeBSD extattrs)
1085         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1086         AC_DEFINE(SUPPORT_XATTRS, 1)
1087         ;;
1088     solaris*)
1089         AC_MSG_RESULT(Using Solaris xattrs)
1090         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1091         AC_DEFINE(SUPPORT_XATTRS, 1)
1092         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1093         ;;
1094     *)
1095         if test x"$enable_xattr_support" = x"yes"; then
1096             AC_MSG_ERROR(Failed to find extended attribute support)
1097         else
1098             AC_MSG_RESULT(No extended attribute support found)
1099         fi
1100         ;;
1101     esac
1102 fi
1103
1104 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1105     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1106     OLD_CFLAGS="$CFLAGS"
1107     CFLAGS="$CFLAGS -Wno-unused-parameter"
1108     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1109     AC_MSG_RESULT([$rsync_warn_flag])
1110     if test x"$rsync_warn_flag" = x"no"; then
1111         CFLAGS="$OLD_CFLAGS"
1112     fi
1113 fi
1114
1115 case "$CC" in
1116 ' checker'*|checker*)
1117     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1118     ;;
1119 esac
1120
1121 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1122 AC_OUTPUT
1123
1124 AC_MSG_RESULT()
1125 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1126 AC_MSG_RESULT()
1127 if test x$HAVE_YODL2MAN != x1; then
1128     AC_MSG_RESULT([    Note that yodl2man was not found, so pre-existing manpage files will be])
1129     AC_MSG_RESULT([    used w/o change (if available) -- no .yo file changes will be used.])
1130     AC_MSG_RESULT()
1131 fi