configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.2.0pre3],[http://rsync.samba.org/bugzilla.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_CXX
  45 AC_PROG_EGREP
  46 AC_PROG_INSTALL
  47 AC_PROG_MKDIR_P
  48 AC_PROG_CC_STDC
  49 AC_SUBST(SHELL)
  50 AC_PATH_PROG([PERL], [perl])
  51 AC_PATH_PROG([PYTHON3], [python3])
  52
  53 AC_DEFINE([_GNU_SOURCE], 1,
  54           [Define _GNU_SOURCE so that we get all necessary prototypes])
  55
  56 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  57         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  58 fi
  59
  60 AC_ARG_ENABLE(profile,
  61         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  62 if test x"$enable_profile" = x"yes"; then
  63         CFLAGS="$CFLAGS -pg"
  64 fi
  65
  66 AC_MSG_CHECKING([if md2man can create man pages])
  67 if test x"$ac_cv_path_PYTHON3" = x; then
  68     AC_MSG_RESULT(no - python3 not found)
  69     md2man_works=no
  70 else
  71     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync.1.md" 2>&1`
  72     if test $? = 0; then
  73         AC_MSG_RESULT(yes)
  74         md2man_works=yes
  75     else
  76         AC_MSG_RESULT(no)
  77         md2man_works=no
  78         echo "$md2man_out"
  79     fi
  80 fi
  81
  82 AC_MSG_CHECKING([if we require man-page building])
  83 AC_ARG_ENABLE([md2man],
  84         AS_HELP_STRING([--disable-md2man],[disable md2man for man page creation]))
  85 if test x"$enable_md2man" != x"no"; then
  86     if test -f "$srcdir/rsync.1"; then
  87         AC_MSG_RESULT(optional)
  88     else
  89         AC_MSG_RESULT(required)
  90         if test x"$md2man_works" = x"no"; then
  91             AC_MSG_ERROR(You need python3 and the cmarkgfm OR commonmark python3 lib in order to build man pages.
  92 You can specify --disable-md2man if you want to skip building them.)
  93         fi
  94     fi
  95     MAKE_MAN=man
  96 else
  97     AC_MSG_RESULT(no)
  98     MAKE_MAN=''
  99 fi
 100
 101 # Specifically, this turns on panic_action handling.
 102 AC_ARG_ENABLE(maintainer-mode,
 103         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
 104 if test x"$enable_maintainer_mode" = x"yes"; then
 105         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 106 fi
 107
 108 # This is needed for our included version of popt.  Kind of silly, but
 109 # I don't want our version too far out of sync.
 110 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 111
 112 # If GCC, turn on warnings.
 113 if test x"$GCC" = x"yes"; then
 114         CFLAGS="$CFLAGS -Wall -W"
 115 fi
 116
 117 AC_ARG_WITH(included-popt,
 118         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 119
 120 AC_ARG_WITH(included-zlib,
 121         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 122
 123 AC_ARG_WITH(protected-args,
 124         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
 125 if test x"$with_protected_args" = x"yes"; then
 126         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
 127 fi
 128
 129 AC_ARG_WITH(rsync-path,
 130         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 131         [ RSYNC_PATH="$with_rsync_path" ],
 132         [ RSYNC_PATH="rsync" ])
 133
 134 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 135
 136 AC_ARG_WITH(rsyncd-conf,
 137         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 138         [ if test ! -z "$with_rsyncd_conf" ; then
 139                 case $with_rsyncd_conf in
 140                         yes|no)
 141                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 142                                 ;;
 143                         /*)
 144                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 145                                 ;;
 146                         *)
 147                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 148                                 ;;
 149                 esac
 150         else
 151                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 152         fi ],
 153         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 154
 155 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 156
 157 AC_ARG_WITH(rsh,
 158         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 159
 160 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 161 if test x$HAVE_REMSH = x1; then
 162         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 163 fi
 164
 165 if test x"$with_rsh" != x; then
 166         RSYNC_RSH="$with_rsh"
 167 else
 168         RSYNC_RSH="ssh"
 169 fi
 170 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 171
 172 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 173 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 174 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 175
 176 AC_ARG_WITH(nobody-group,
 177     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 178     [ NOBODY_GROUP="$with_nobody_group" ])
 179
 180 if test x"$with_nobody_group" = x; then
 181     AC_MSG_CHECKING([the group for user "nobody"])
 182     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 183         NOBODY_GROUP=nobody
 184     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 185         NOBODY_GROUP=nogroup
 186     else
 187         NOBODY_GROUP=nobody # test for others?
 188     fi
 189     AC_MSG_RESULT($NOBODY_GROUP)
 190 fi
 191
 192 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 193 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 194
 195 # SIMD optimizations
 196 SIMD=
 197
 198 AC_MSG_CHECKING([whether to enable SIMD optimizations])
 199 AC_ARG_ENABLE(simd,
 200     AS_HELP_STRING([--enable-simd],[enable SIMD optimizations (requires c++)]))
 201
 202 if test x"$enable_simd" = x"yes"; then
 203     # For x86-64 SIMD, g++ >=5 or clang++ >=7 is required
 204     if test x"$build_cpu" = x"x86_64"; then
 205         if test x"$CXX" != x""; then
 206             CXX_OK=
 207             CXX_VERSION=`$CXX --version | head -n 1`
 208             case "$CXX_VERSION" in
 209             g++*)
 210                 CXX_VERSION=`$CXX -dumpversion | sed 's/\..*//g'`
 211                 if test "$CXX_VERSION" -ge "5"; then
 212                     CXX_OK=yes
 213                 fi
 214                 ;;
 215             clang*)
 216                 # $CXX -dumpversion would have been ideal, but is broken on older clang
 217                 CXX_VERSION=`echo "$CXX_VERSION" | sed 's/.*version //g' | sed 's/\..*//g'`
 218                 if test "$CXX_VERSION" -ge "7"; then
 219                     CXX_OK=yes
 220                 fi
 221                 ;;
 222             esac
 223
 224             if test x"$CXX_OK" = x"yes"; then
 225                 # AC_MSG_RESULT() is called below.
 226                 SIMD="$SIMD x86_64"
 227             else
 228                 AC_MSG_RESULT(error)
 229                 AC_MSG_ERROR([Failed to find g++ >=5 or clang++ >=7 for SIMD optimizations.
 230 Omit --enable-simd to continue without it. ($CXX, $CXX_VERSION)])
 231             fi
 232         fi
 233     fi
 234 fi
 235
 236 if test x"$SIMD" != x""; then
 237     SIMD=`echo "$SIMD" | sed 's/^ *//'`
 238     AC_MSG_RESULT([yes ($SIMD)])
 239     AC_DEFINE(HAVE_SIMD, 1, [Define to 1 to enable SIMD optimizations])
 240     SIMD=`echo "\\\$(SIMD_$SIMD)" | sed 's/ /) $(SIMD_/g'`
 241     # We only use c++ for its target attribute dispatching, disable unneeded bulky features
 242     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 243 else
 244     AC_MSG_RESULT(no)
 245 fi
 246
 247 AC_SUBST(SIMD)
 248
 249 # arrgh. libc in some old debian version screwed up the largefile
 250 # stuff, getting byte range locking wrong
 251 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 252 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 253 #define _FILE_OFFSET_BITS 64
 254 #include <stdio.h>
 255 #include <fcntl.h>
 256 #include <sys/types.h>
 257 #include <sys/wait.h>
 258 #if HAVE_UNISTD_H
 259 #include <unistd.h>
 260 #endif
 261
 262 int main(void)
 263 {
 264         struct flock lock;
 265         int status;
 266         char tpl[32] = "/tmp/locktest.XXXXXX";
 267         int fd = mkstemp(tpl);
 268         if (fd < 0) {
 269                 strcpy(tpl, "conftest.dat");
 270                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 271         }
 272
 273         lock.l_type = F_WRLCK;
 274         lock.l_whence = SEEK_SET;
 275         lock.l_start = 0;
 276         lock.l_len = 1;
 277         lock.l_pid = 0;
 278         fcntl(fd,F_SETLK,&lock);
 279         if (fork() == 0) {
 280                 lock.l_start = 1;
 281                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 282         }
 283         wait(&status);
 284         unlink(tpl);
 285         return WEXITSTATUS(status);
 286 }
 287 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 288 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 289    AC_SYS_LARGEFILE
 290 fi
 291
 292 ipv6type=unknown
 293 ipv6lib=none
 294 ipv6trylibc=yes
 295
 296 AC_ARG_ENABLE(ipv6,
 297         AS_HELP_STRING([--disable-ipv6],[turn off IPv6 support]))
 298 if test x"$enable_ipv6" != x"no"; then
 299         AC_MSG_CHECKING([ipv6 stack type])
 300         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 301                 case $i in
 302                 inria)
 303                         # http://www.kame.net/
 304                         AC_EGREP_CPP(yes, [
 305 #include <netinet/in.h>
 306 #ifdef IPV6_INRIA_VERSION
 307 yes
 308 #endif],
 309                                 [ipv6type=$i;
 310                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 311                                 ])
 312                         ;;
 313                 kame)
 314                         # http://www.kame.net/
 315                         AC_EGREP_CPP(yes, [
 316 #include <netinet/in.h>
 317 #ifdef __KAME__
 318 yes
 319 #endif],
 320                                 [ipv6type=$i;
 321                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 322                         ;;
 323                 linux-glibc)
 324                         # http://www.v6.linux.or.jp/
 325                         AC_EGREP_CPP(yes, [
 326 #include <features.h>
 327 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 328 yes
 329 #endif],
 330                                 [ipv6type=$i;
 331 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 332                         ;;
 333                 linux-inet6)
 334                         # http://www.v6.linux.or.jp/
 335                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 336                                 ipv6type=$i
 337                                 ipv6lib=inet6
 338                                 ipv6libdir=/usr/inet6/lib
 339                                 ipv6trylibc=yes;
 340                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 341                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 342                         fi
 343                         ;;
 344                 solaris)
 345                         # http://www.sun.com
 346                         AC_EGREP_CPP(yes, [
 347 #include <netinet/ip6.h>
 348 #ifdef __sun
 349 yes
 350 #endif],
 351                                 [ipv6type=$i;
 352                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 353                         ;;
 354                 toshiba)
 355                         AC_EGREP_CPP(yes, [
 356 #include <sys/param.h>
 357 #ifdef _TOSHIBA_INET6
 358 yes
 359 #endif],
 360                                 [ipv6type=$i;
 361                                 ipv6lib=inet6;
 362                                 ipv6libdir=/usr/local/v6/lib;
 363                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 364                         ;;
 365                 v6d)
 366                         AC_EGREP_CPP(yes, [
 367 #include </usr/local/v6/include/sys/v6config.h>
 368 #ifdef __V6D__
 369 yes
 370 #endif],
 371                                 [ipv6type=$i;
 372                                 ipv6lib=v6;
 373                                 ipv6libdir=/usr/local/v6/lib;
 374                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 375                         ;;
 376                 zeta)
 377                         AC_EGREP_CPP(yes, [
 378 #include <sys/param.h>
 379 #ifdef _ZETA_MINAMI_INET6
 380 yes
 381 #endif],
 382                                 [ipv6type=$i;
 383                                 ipv6lib=inet6;
 384                                 ipv6libdir=/usr/local/v6/lib;
 385                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 386                         ;;
 387                 cygwin)
 388                         AC_EGREP_CPP(yes, [
 389 #include <netinet/in.h>
 390 #ifdef _CYGWIN_IN6_H
 391 yes
 392 #endif],
 393                                 [ipv6type=$i;
 394                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 395                         ;;
 396                 esac
 397                 if test "$ipv6type" != "unknown"; then
 398                         break
 399                 fi
 400         done
 401         AC_MSG_RESULT($ipv6type)
 402
 403         AC_SEARCH_LIBS(getaddrinfo, inet6)
 404 fi
 405
 406 dnl Do you want to disable use of locale functions
 407 AC_ARG_ENABLE([locale],
 408         AS_HELP_STRING([--disable-locale],[disable locale features]))
 409 AH_TEMPLATE([CONFIG_LOCALE],
 410 [Undefine if you do not want locale features.  By default this is defined.])
 411 if test x"$enable_locale" != x"no"; then
 412         AC_DEFINE(CONFIG_LOCALE)
 413 fi
 414
 415 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 416 case $host_os in
 417         *cygwin* ) AC_MSG_RESULT(yes)
 418                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 419                             [Define to 1 if sockets need to be shutdown])
 420                    ;;
 421                * ) AC_MSG_RESULT(no);;
 422 esac
 423
 424 AC_C_BIGENDIAN
 425 AC_HEADER_DIRENT
 426 AC_HEADER_TIME
 427 AC_HEADER_SYS_WAIT
 428 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 429     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 430     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 431     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 432     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 433     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 434     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 435     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h)
 436 AC_HEADER_MAJOR_FIXED
 437
 438 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 439 AC_ARG_ENABLE([openssl],
 440         AS_HELP_STRING([--disable-openssl],[disable openssl crypto library]))
 441 AH_TEMPLATE([USE_OPENSSL],
 442 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 443 if test x"$enable_openssl" != x"no"; then
 444     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 445       AC_MSG_RESULT(yes)
 446       AC_SEARCH_LIBS(MD5_Init, crypto,
 447           [AC_DEFINE(USE_OPENSSL)],
 448           [AC_MSG_ERROR(Failed to find MD5_Init function in openssl crypto lib.
 449 Use --disable-openssl to continue without openssl crypto lib support.)])
 450     else
 451         AC_MSG_RESULT(no)
 452         AC_MSG_ERROR(Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support.
 453 Use --disable-openssl to continue without it.)
 454     fi
 455 else
 456     AC_MSG_RESULT(no)
 457 fi
 458
 459 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 460 AC_ARG_ENABLE([xxhash],
 461         AS_HELP_STRING([--disable-xxhash],[disable xxhash checksums]))
 462 AH_TEMPLATE([SUPPORT_XXHASH],
 463 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 464 if test x"$enable_xxhash" != x"no"; then
 465     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 466         AC_MSG_RESULT(yes)
 467         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 468             [AC_DEFINE(SUPPORT_XXHASH)],
 469             [AC_MSG_ERROR(Failed to find XXH64_createState function in xxhash lib.
 470 Use --disable-xxhash to continue without xxhash checksums.)])
 471     else
 472         AC_MSG_RESULT(no)
 473         AC_MSG_ERROR(Failed to find xxhash.h for xxhash checksum support.
 474 Use --disable-xxhash to continue without it.)
 475     fi
 476 else
 477     AC_MSG_RESULT(no)
 478 fi
 479
 480 AC_MSG_CHECKING([whether to enable zstd compression])
 481 AC_ARG_ENABLE([zstd],
 482         AC_HELP_STRING([--disable-zstd], [disable zstd compression]))
 483 AH_TEMPLATE([SUPPORT_ZSTD],
 484 [Undefine if you do not want zstd compression.  By default this is defined.])
 485 if test x"$enable_zstd" != x"no"; then
 486     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 487         AC_MSG_RESULT(yes)
 488         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 489             [AC_DEFINE(SUPPORT_ZSTD)],
 490             [AC_MSG_ERROR(Failed to find ZSTD_minCLevel function in zstd lib.
 491 Use --disable-zstd to continue without zstd compression.)])
 492     else
 493         AC_MSG_RESULT(no)
 494         AC_MSG_ERROR(Failed to find zstd.h for zstd compression support.
 495 Use --disable-zstd to continue without it.)
 496     fi
 497 else
 498     AC_MSG_RESULT(no)
 499 fi
 500
 501 AC_MSG_CHECKING([whether to enable LZ4 compression])
 502 AC_ARG_ENABLE([lz4],
 503         AC_HELP_STRING([--disable-lz4], [disable LZ4 compression]))
 504 AH_TEMPLATE([SUPPORT_LZ4],
 505 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 506 if test x"$enable_lz4" != x"no"; then
 507     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 508         AC_MSG_RESULT(yes)
 509         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 510             [AC_DEFINE(SUPPORT_LZ4)],
 511             [AC_MSG_ERROR(Failed to find LZ4_compress_default function in lz4 lib.
 512 Use --disable-lz4 to continue without lz4 compression.)])
 513     else
 514         AC_MSG_RESULT(no)
 515         AC_MSG_ERROR(Failed to find lz4.h for lz4 compression support.
 516 Use --disable-lz4 to continue without it.)
 517     fi
 518 else
 519     AC_MSG_RESULT(no)
 520 fi
 521
 522 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 523 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 524 #include <sys/types.h>
 525 #ifdef MAJOR_IN_MKDEV
 526 #include <sys/mkdev.h>
 527 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 528 #  define makedev mkdev
 529 # endif
 530 #elif defined MAJOR_IN_SYSMACROS
 531 #include <sys/sysmacros.h>
 532 #endif
 533
 534 int main(void)
 535 {
 536         dev_t dev = makedev(0, 5, 7);
 537         if (major(dev) != 5 || minor(dev) != 7)
 538                 return 1;
 539         return 0;
 540 }
 541 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 542 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 543    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 544 fi
 545
 546 AC_CHECK_SIZEOF(int)
 547 AC_CHECK_SIZEOF(long)
 548 AC_CHECK_SIZEOF(long long)
 549 AC_CHECK_SIZEOF(short)
 550 AC_CHECK_SIZEOF(int16_t)
 551 AC_CHECK_SIZEOF(uint16_t)
 552 AC_CHECK_SIZEOF(int32_t)
 553 AC_CHECK_SIZEOF(uint32_t)
 554 AC_CHECK_SIZEOF(int64_t)
 555 AC_CHECK_SIZEOF(off_t)
 556 AC_CHECK_SIZEOF(off64_t)
 557 AC_CHECK_SIZEOF(time_t)
 558 AC_CHECK_SIZEOF(char*)
 559
 560 AC_C_INLINE
 561
 562 AC_TYPE_LONG_DOUBLE_WIDER
 563 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 564 if test $ac_cv_c_long_double = yes; then
 565   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 566 fi
 567
 568 AC_TYPE_UID_T
 569 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 570 AC_TYPE_GETGROUPS
 571 AC_CHECK_MEMBERS([struct stat.st_rdev,
 572                   struct stat.st_mtimensec,
 573                   struct stat.st_mtimespec.tv_nsec,
 574                   struct stat.st_mtim.tv_nsec],,,[
 575 #ifdef HAVE_SYS_TYPES_H
 576 #include <sys/types.h>
 577 #endif
 578 #ifdef HAVE_SYS_STAT_H
 579 #include <sys/stat.h>
 580 #endif
 581 #ifdef HAVE_UNISTD_H
 582 #include <unistd.h>
 583 #endif])
 584
 585 TYPE_SOCKLEN_T
 586
 587 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 588     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 589 if test x"$rsync_cv_errno" = x"yes"; then
 590    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 591 fi
 592
 593 # The following test taken from the cvs sources
 594 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 595 # These need checks to be before checks for any other functions that
 596 #    might be in the same libraries.
 597 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 598 # libsocket.so which has a bad implementation of gethostbyname (it
 599 # only looks in /etc/hosts), so we only look for -lsocket if we need
 600 # it.
 601 AC_CHECK_FUNCS(connect)
 602 if test x"$ac_cv_func_connect" = x"no"; then
 603     case "$LIBS" in
 604     *-lnsl*) ;;
 605     *) AC_CHECK_LIB(nsl_s, printf) ;;
 606     esac
 607     case "$LIBS" in
 608     *-lnsl*) ;;
 609     *) AC_CHECK_LIB(nsl, printf) ;;
 610     esac
 611     case "$LIBS" in
 612     *-lsocket*) ;;
 613     *) AC_CHECK_LIB(socket, connect) ;;
 614     esac
 615     case "$LIBS" in
 616     *-linet*) ;;
 617     *) AC_CHECK_LIB(inet, connect) ;;
 618     esac
 619     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 620     dnl has been cached.
 621     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 622        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 623         # ac_cv_func_connect=yes
 624         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 625         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 626     fi
 627 fi
 628
 629 AC_SEARCH_LIBS(inet_ntop, resolv)
 630
 631 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 632 # accept either iconv_open or libiconv_open, since some include files map
 633 # the former to the latter.
 634 AC_SEARCH_LIBS(iconv_open, iconv)
 635 AC_SEARCH_LIBS(libiconv_open, iconv)
 636
 637 AC_MSG_CHECKING([for iconv declaration])
 638 AC_CACHE_VAL(am_cv_proto_iconv, [
 639     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 640 #include <stdlib.h>
 641 #include <iconv.h>
 642 extern
 643 #ifdef __cplusplus
 644 "C"
 645 #endif
 646 #if defined(__STDC__) || defined(__cplusplus)
 647 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 648 #else
 649 size_t iconv();
 650 #endif
 651 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 652       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 653     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed 's/( /(/'`
 654 AC_MSG_RESULT([$]{ac_t:-
 655          }[$]am_cv_proto_iconv)
 656 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 657                    [Define as const if the declaration of iconv() needs const.])
 658
 659 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 660
 661 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 662
 663 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 664 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 665 #include <sys/socket.h>])
 666
 667 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 668 #   builtin getaddrinfo if one of the defines don't exist
 669 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 670                rsync_cv_HAVE_GETADDR_DEFINES,[
 671                         AC_EGREP_CPP(yes, [
 672                         #include <sys/types.h>
 673                         #include <sys/socket.h>
 674                         #include <netdb.h>
 675                         #ifdef AI_PASSIVE
 676                         yes
 677                         #endif],
 678                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 679                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 680 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 681         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 682         # something else so we must include <netdb.h> to get the
 683         # redefinition.
 684         AC_CHECK_FUNCS(getaddrinfo, ,
 685                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 686                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 687                 #include <sys/socket.h>
 688                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 689                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 690                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 691                         AC_LIBOBJ([getaddrinfo])])])
 692     ],[AC_LIBOBJ([getaddrinfo])])
 693
 694 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 695                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 696                 [],
 697                 [
 698 #include <sys/types.h>
 699 #include <sys/socket.h>
 700 ])
 701
 702 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 703                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 704                 [],
 705                 [
 706 #include <sys/types.h>
 707 #include <sys/socket.h>
 708 #include <netinet/in.h>
 709 ])
 710
 711 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 712                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 713                 [],
 714                 [
 715 #include <sys/types.h>
 716 #include <sys/socket.h>
 717 #include <netinet/in.h>
 718 ])
 719
 720 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 721                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 722                 [],
 723                 [
 724 #include <sys/types.h>
 725 #include <sys/socket.h>
 726 #include <netinet/in.h>
 727 ])
 728
 729 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 730 #if HAVE_SYS_TYPES_H
 731 # include <sys/types.h>
 732 #endif
 733 #if HAVE_SYS_STAT_H
 734 # include <sys/stat.h>
 735 #endif
 736 #if STDC_HEADERS
 737 # include <stdlib.h>
 738 # include <stddef.h>
 739 #else
 740 # if HAVE_STDLIB_H
 741 #  include <stdlib.h>
 742 # endif
 743 #endif
 744 ])
 745
 746 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 747 #
 748 AC_CHECK_FUNCS(strcasecmp)
 749 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 750     AC_CHECK_LIB(resolv, strcasecmp)
 751 fi
 752
 753 AC_CHECK_FUNCS(aclsort)
 754 if test x"$ac_cv_func_aclsort" = x"no"; then
 755     AC_CHECK_LIB(sec, aclsort)
 756 fi
 757
 758 dnl At the moment we don't test for a broken memcmp(), because all we
 759 dnl need to do is test for equality, not comparison, and it seems that
 760 dnl every platform has a memcmp that can do at least that.
 761 dnl AC_FUNC_MEMCMP
 762
 763 AC_FUNC_UTIME_NULL
 764 AC_FUNC_ALLOCA
 765 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 766     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 767     chflags getattrlist \
 768     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 769     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 770     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 771     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 772     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 773     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep)
 774
 775 dnl cygwin iconv.h defines iconv_open as libiconv_open
 776 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 777     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 778 fi
 779
 780 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 781
 782 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 783 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 784 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 785 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 786     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 787 fi
 788
 789 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 790 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 791         #define _GNU_SOURCE 1
 792         #include <linux/falloc.h>
 793         #ifndef FALLOC_FL_PUNCH_HOLE
 794         #error FALLOC_FL_PUNCH_HOLE is missing
 795         #endif
 796     ]])], [
 797         AC_MSG_RESULT([yes])
 798         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 799     ], [
 800         AC_MSG_RESULT([no])
 801     ]
 802 )
 803
 804 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 805 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 806         #define _GNU_SOURCE 1
 807         #include <linux/falloc.h>
 808         #ifndef FALLOC_FL_ZERO_RANGE
 809         #error FALLOC_FL_ZERO_RANGE is missing
 810         #endif
 811     ]])], [
 812         AC_MSG_RESULT([yes])
 813         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 814     ], [
 815         AC_MSG_RESULT([no])
 816     ]
 817 )
 818
 819 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 820 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 821 #include <unistd.h>
 822 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 823 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 824     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 825 fi
 826
 827 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 828     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 829     case $host_os in
 830     *cygwin*)
 831         AC_MSG_RESULT(yes)
 832         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 833                   [Define if posix_fallocate is efficient (Cygwin)])
 834         ;;
 835     *)
 836         AC_MSG_RESULT(no)
 837         ;;
 838     esac
 839 fi
 840
 841 dnl End of preallocation stuff
 842
 843 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 844 if test $ac_cv_func_getpgrp = yes; then
 845     AC_FUNC_GETPGRP
 846 fi
 847
 848 AC_ARG_ENABLE(iconv-open,
 849     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 850     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 851
 852 if test x"$enable_iconv_open" != x"no"; then
 853     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 854 fi
 855
 856 AC_ARG_ENABLE(iconv,
 857     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 858     [], [enable_iconv=$enable_iconv_open])
 859 AH_TEMPLATE([ICONV_OPTION],
 860 [Define if you want the --iconv option.  Specifying a value will set the
 861 default iconv setting (a NULL means no --iconv processing by default).])
 862 if test x"$enable_iconv" != x"no"; then
 863         if test x"$enable_iconv" = x"yes"; then
 864                 AC_DEFINE(ICONV_OPTION, NULL)
 865         else
 866                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 867         fi
 868         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 869 fi
 870
 871 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 872   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 873 #if HAVE_UNISTD_H
 874 # include <unistd.h>
 875 #endif
 876 #include <stdlib.h>
 877 #include <errno.h>
 878 int main(void) {
 879         char const *dangling_symlink = "conftest.dangle";
 880         unlink(dangling_symlink);
 881         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 882         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 883         return 0;
 884     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 885 if test $rsync_cv_chown_modifies_symlink = yes; then
 886   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 887 fi
 888
 889 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 890   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 891 #if HAVE_UNISTD_H
 892 # include <unistd.h>
 893 #endif
 894 #include <stdlib.h>
 895 #include <errno.h>
 896 #define FILENAME "conftest.dangle"
 897 int main(void) {
 898         unlink(FILENAME);
 899         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 900         unlink(FILENAME "2");
 901         if (link(FILENAME, FILENAME "2") < 0) return 1;
 902         return 0;
 903     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 904 if test $rsync_cv_can_hardlink_symlink = yes; then
 905   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 906 fi
 907
 908 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 909   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 910 #if HAVE_UNISTD_H
 911 # include <unistd.h>
 912 #endif
 913 #ifdef HAVE_SYS_STAT_H
 914 #include <sys/stat.h>
 915 #endif
 916 #include <stdlib.h>
 917 #include <errno.h>
 918 #define FILENAME "conftest.fifi"
 919 int main(void) {
 920         unlink(FILENAME);
 921         if (mkfifo(FILENAME, 0777) < 0) abort();
 922         unlink(FILENAME "2");
 923         if (link(FILENAME, FILENAME "2") < 0) return 1;
 924         return 0;
 925     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 926 if test $rsync_cv_can_hardlink_special = yes; then
 927     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 928 fi
 929
 930 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 931 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 932 #include <sys/types.h>
 933 #include <sys/socket.h>
 934
 935 int main(void) {
 936        int fd[2];
 937        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
 938 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 939 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 940     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 941 fi
 942
 943 AC_REPLACE_FUNCS([getpass])
 944
 945 if test x"$with_included_popt" != x"yes"; then
 946     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 947 fi
 948 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 949     # If the system has /usr/include/popt/popt.h, we enable the
 950     # included popt because an attempt to "#include <popt/popt.h>"
 951     # would use our included header file anyway (due to -I.), and
 952     # might conflict with the system popt.
 953     with_included_popt=yes
 954 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 955     with_included_popt=yes
 956 fi
 957
 958 AC_MSG_CHECKING([whether to use included libpopt])
 959 if test x"$with_included_popt" = x"yes"; then
 960     AC_MSG_RESULT($srcdir/popt)
 961     BUILD_POPT='$(popt_OBJS)'
 962     CFLAGS="-I$srcdir/popt $CFLAGS"
 963     if test x"$ALLOCA" != x
 964     then
 965         # this can be removed when/if we add an included alloca.c;
 966         #  see autoconf documentation on AC_FUNC_ALLOCA
 967         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 968     fi
 969 else
 970     AC_MSG_RESULT(no)
 971 fi
 972
 973 # We default to using our zlib unless --with-included-zlib=no is given.
 974 if test x"$with_included_zlib" != x"no"; then
 975     with_included_zlib=yes
 976 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
 977     with_included_zlib=yes
 978 fi
 979 if test x"$with_included_zlib" != x"yes"; then
 980     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
 981 fi
 982
 983 AC_MSG_CHECKING([whether to use included zlib])
 984 if test x"$with_included_zlib" = x"yes"; then
 985     AC_MSG_RESULT($srcdir/zlib)
 986     BUILD_ZLIB='$(zlib_OBJS)'
 987     CFLAGS="-I$srcdir/zlib $CFLAGS"
 988 else
 989     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
 990     AC_MSG_RESULT(no)
 991 fi
 992
 993 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 994 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
 995 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 996     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 997 fi
 998
 999 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
1000 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
1001 #include <dirent.h>
1002 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
1003 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
1004 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
1005 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
1006     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
1007 fi
1008
1009 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
1010 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1011 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
1012 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
1013     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
1014 fi
1015
1016 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1017 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1018 #include <unistd.h>]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1019 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1020     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1021 fi
1022
1023 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1024 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1025 #include <sys/types.h>
1026 #include <stdarg.h>
1027 #include <stdio.h>
1028 #include <stdlib.h>
1029 #include <string.h>
1030 void foo(const char *format, ...) {
1031        va_list ap;
1032        int len;
1033        static char buf[] = "12345678901234567890";
1034
1035        va_start(ap, format);
1036        len = vsnprintf(0, 0, format, ap);
1037        va_end(ap);
1038        if (len != 5) exit(1);
1039
1040        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1041 }
1042 int main(void) { foo("hello"); return 0; }
1043 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1044 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1045     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1046 fi
1047
1048
1049 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1050 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1051 #include <sys/types.h>
1052 #include <sys/stat.h>
1053 #include <unistd.h>
1054 int main(void) {
1055   struct stat st;
1056   char tpl[20]="/tmp/test.XXXXXX";
1057   int fd = mkstemp(tpl);
1058   if (fd == -1) return 1;
1059   unlink(tpl);
1060   if (fstat(fd, &st) != 0) return 1;
1061   if ((st.st_mode & 0777) != 0600) return 1;
1062   return 0;
1063 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1064 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1065     case $host_os in
1066     hpux*)
1067         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1068         dnl so we noisily skip using it.  See HP change request JAGaf34426
1069         dnl for details. (sbonds)
1070         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1071         ;;
1072     *)
1073         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1074         ;;
1075     esac
1076 fi
1077
1078
1079 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1080 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1081 #include <stdio.h>
1082 #include <sys/stat.h>
1083 #include <errno.h>
1084 #if HAVE_UNISTD_H
1085 # include <unistd.h>
1086 #endif
1087 int main(void) { int rc, ec; char *fn = "fifo-test";
1088 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1089 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1090 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1091 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1092     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1093 fi
1094
1095 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1096 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1097 #include <stdio.h>
1098 #include <sys/stat.h>
1099 #include <errno.h>
1100 #if HAVE_UNISTD_H
1101 # include <unistd.h>
1102 #endif
1103 int main(void) { int rc, ec; char *fn = "sock-test";
1104 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1105 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1106 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1107 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1108     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1109 fi
1110
1111 #
1112 # The following test was mostly taken from the tcl/tk plus patches
1113 #
1114 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1115 rm -rf conftest*
1116 cat > conftest.$ac_ext <<EOF
1117 int main(void) { return 0; }
1118 EOF
1119 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1120 if test -f conftest..o; then
1121     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1122 else
1123     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1124 fi
1125 rm -rf conftest*
1126 ])
1127 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1128     OBJ_SAVE="#"
1129     OBJ_RESTORE="#"
1130     CC_SHOBJ_FLAG='-o $@'
1131 else
1132     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1133     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1134     CC_SHOBJ_FLAG=""
1135 fi
1136
1137 AC_SUBST(OBJ_SAVE)
1138 AC_SUBST(OBJ_RESTORE)
1139 AC_SUBST(CC_SHOBJ_FLAG)
1140 AC_SUBST(BUILD_POPT)
1141 AC_SUBST(BUILD_ZLIB)
1142 AC_SUBST(MAKE_MAN)
1143
1144 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1145 #################################################
1146 # check for ACL support
1147
1148 AC_MSG_CHECKING([whether to support ACLs])
1149 AC_ARG_ENABLE(acl-support,
1150         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
1151
1152 if test x"$enable_acl_support" = x"no"; then
1153     AC_MSG_RESULT(no)
1154 else
1155     case "$host_os" in
1156     *sysv5*)
1157         AC_MSG_RESULT(Using UnixWare ACLs)
1158         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1159         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1160         ;;
1161     solaris*)
1162         AC_MSG_RESULT(Using solaris ACLs)
1163         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1164         AC_DEFINE(SUPPORT_ACLS, 1)
1165         ;;
1166     *hpux*)
1167         AC_MSG_RESULT(Using HPUX ACLs)
1168         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1169         AC_DEFINE(SUPPORT_ACLS, 1)
1170         ;;
1171     *irix*)
1172         AC_MSG_RESULT(Using IRIX ACLs)
1173         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1174         AC_DEFINE(SUPPORT_ACLS, 1)
1175         ;;
1176     *aix*)
1177         AC_MSG_RESULT(Using AIX ACLs)
1178         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1179         AC_DEFINE(SUPPORT_ACLS, 1)
1180         ;;
1181     *osf*)
1182         AC_MSG_RESULT(Using Tru64 ACLs)
1183         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1184         AC_DEFINE(SUPPORT_ACLS, 1)
1185         LIBS="$LIBS -lpacl"
1186         ;;
1187     darwin*)
1188         AC_MSG_RESULT(Using OS X ACLs)
1189         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1190         AC_DEFINE(SUPPORT_ACLS, 1)
1191         ;;
1192     *)
1193         AC_MSG_RESULT(running tests:)
1194         AC_CHECK_LIB(acl,acl_get_file)
1195         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1196             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1197 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1198         AC_MSG_CHECKING(ACL test results)
1199         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1200             AC_MSG_RESULT(Using posix ACLs)
1201             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1202             AC_DEFINE(SUPPORT_ACLS, 1)
1203             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1204                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1205 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1206             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1207                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1208             fi
1209         else
1210             if test x"$enable_acl_support" = x"yes"; then
1211                 AC_MSG_ERROR(Failed to find ACL support)
1212             else
1213                 AC_MSG_RESULT(No ACL support found)
1214             fi
1215         fi
1216         ;;
1217     esac
1218 fi
1219
1220 #################################################
1221 # check for extended attribute support
1222 AC_MSG_CHECKING(whether to support extended attributes)
1223 AC_ARG_ENABLE(xattr-support,
1224     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1225     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1226         *yes*) enable_xattr_support=maybe ;;
1227         *) enable_xattr_support=no ;;
1228         esac])
1229 AH_TEMPLATE([SUPPORT_XATTRS],
1230 [Define to 1 to add support for extended attributes])
1231 if test x"$enable_xattr_support" = x"no"; then
1232     AC_MSG_RESULT(no)
1233 else
1234     case "$host_os" in
1235     *linux*|*netbsd*)
1236         AC_MSG_RESULT(Using Linux xattrs)
1237         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1238         AC_DEFINE(SUPPORT_XATTRS, 1)
1239         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1240         AC_CHECK_LIB(attr,getxattr)
1241         ;;
1242     darwin*)
1243         AC_MSG_RESULT(Using OS X xattrs)
1244         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1245         AC_DEFINE(SUPPORT_XATTRS, 1)
1246         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1247         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1248         ;;
1249     freebsd*)
1250         AC_MSG_RESULT(Using FreeBSD extattrs)
1251         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1252         AC_DEFINE(SUPPORT_XATTRS, 1)
1253         ;;
1254     solaris*)
1255         AC_MSG_RESULT(Using Solaris xattrs)
1256         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1257         AC_DEFINE(SUPPORT_XATTRS, 1)
1258         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1259         ;;
1260     *)
1261         if test x"$enable_xattr_support" = x"yes"; then
1262             AC_MSG_ERROR(Failed to find extended attribute support)
1263         else
1264             AC_MSG_RESULT(No extended attribute support found)
1265         fi
1266         ;;
1267     esac
1268 fi
1269
1270 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1271     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1272     OLD_CFLAGS="$CFLAGS"
1273     CFLAGS="$CFLAGS -Wno-unused-parameter"
1274     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1275     AC_MSG_RESULT([$rsync_warn_flag])
1276     if test x"$rsync_warn_flag" = x"no"; then
1277         CFLAGS="$OLD_CFLAGS"
1278     fi
1279 fi
1280
1281 case "$CC" in
1282 ' checker'*|checker*)
1283     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1284     ;;
1285 esac
1286
1287 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1288 AC_OUTPUT
1289
1290 AC_MSG_RESULT()
1291 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1292 AC_MSG_RESULT()