configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.2.0dev],[http://rsync.samba.org/bugzilla.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_CXX
  45 AC_PROG_EGREP
  46 AC_PROG_INSTALL
  47 AC_PROG_MKDIR_P
  48 AC_PROG_CC_STDC
  49 AC_SUBST(SHELL)
  50 AC_PATH_PROG([PERL], [perl])
  51
  52 AC_DEFINE([_GNU_SOURCE], 1,
  53           [Define _GNU_SOURCE so that we get all necessary prototypes])
  54
  55 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  56         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  57 fi
  58
  59 AC_ARG_ENABLE(profile,
  60         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  61 if test x"$enable_profile" = x"yes"; then
  62         CFLAGS="$CFLAGS -pg"
  63 fi
  64
  65
  66 # Specifically, this turns on panic_action handling.
  67 AC_ARG_ENABLE(maintainer-mode,
  68         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
  69 if test x"$enable_maintainer_mode" = x"yes"; then
  70         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  71 fi
  72
  73
  74 # This is needed for our included version of popt.  Kind of silly, but
  75 # I don't want our version too far out of sync.
  76 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  77
  78 # If GCC, turn on warnings.
  79 if test x"$GCC" = x"yes"; then
  80         CFLAGS="$CFLAGS -Wall -W"
  81 fi
  82
  83 AC_ARG_WITH(included-popt,
  84         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
  85
  86 AC_ARG_WITH(included-zlib,
  87         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
  88
  89 AC_ARG_WITH(protected-args,
  90         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
  91 if test x"$with_protected_args" = x"yes"; then
  92         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
  93 fi
  94
  95 AC_ARG_WITH(rsync-path,
  96         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
  97         [ RSYNC_PATH="$with_rsync_path" ],
  98         [ RSYNC_PATH="rsync" ])
  99
 100 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 101
 102 AC_ARG_WITH(rsyncd-conf,
 103         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 104         [ if test ! -z "$with_rsyncd_conf" ; then
 105                 case $with_rsyncd_conf in
 106                         yes|no)
 107                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 108                                 ;;
 109                         /*)
 110                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 111                                 ;;
 112                         *)
 113                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 114                                 ;;
 115                 esac
 116         else
 117                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 118         fi ],
 119         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 120
 121 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 122
 123 AC_ARG_WITH(rsh,
 124         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 125
 126 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 127 if test x$HAVE_REMSH = x1; then
 128         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 129 fi
 130
 131 if test x"$with_rsh" != x; then
 132         RSYNC_RSH="$with_rsh"
 133 else
 134         RSYNC_RSH="ssh"
 135 fi
 136 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 137
 138 AC_CHECK_PROG(HAVE_YODL2MAN, yodl2man, 1, 0)
 139 if test x$HAVE_YODL2MAN = x1; then
 140     MAKE_MAN=man
 141 else
 142     MAKE_MAN=man-copy
 143 fi
 144
 145 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 146 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 147 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 148
 149 AC_ARG_WITH(nobody-group,
 150     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 151     [ NOBODY_GROUP="$with_nobody_group" ])
 152
 153 if test x"$with_nobody_group" = x; then
 154     AC_MSG_CHECKING([the group for user "nobody"])
 155     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 156         NOBODY_GROUP=nobody
 157     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 158         NOBODY_GROUP=nogroup
 159     else
 160         NOBODY_GROUP=nobody # test for others?
 161     fi
 162     AC_MSG_RESULT($NOBODY_GROUP)
 163 fi
 164
 165 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 166 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 167
 168 # SSE2+ optimizations on x86-64 require g++ support
 169 AC_MSG_CHECKING([whether to enable SSE2+ optimizations])
 170 AC_ARG_ENABLE(sse2,
 171         AS_HELP_STRING([--disable-sse2],[disable SSE2+ optimizations (req. g++ and x86-64)]))
 172
 173 if test x"$enable_sse2" = x"yes" && test x"$build_cpu" = x"x86_64" && test x"$CXX" = x"g++"; then
 174     AC_MSG_RESULT([yes])
 175         AC_DEFINE(ENABLE_SSE2, 1, [Define to 1 to enable SSE2+ optimizations (requires g++ and x86-64)])
 176         CXXOBJ="$CXXOBJ checksum_sse2.o"
 177 else
 178     AC_MSG_RESULT(no)
 179 fi
 180
 181 # We only use g++ for its target attribute dispatching, disable unneeded bulky features
 182 if test x"$CXXOBJ" != x""; then
 183     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 184 fi
 185 AC_SUBST(CXXOBJ)
 186
 187 # arrgh. libc in some old debian version screwed up the largefile
 188 # stuff, getting byte range locking wrong
 189 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 190 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 191 #define _FILE_OFFSET_BITS 64
 192 #include <stdio.h>
 193 #include <fcntl.h>
 194 #include <sys/types.h>
 195 #include <sys/wait.h>
 196 #if HAVE_UNISTD_H
 197 #include <unistd.h>
 198 #endif
 199
 200 int main(void)
 201 {
 202         struct flock lock;
 203         int status;
 204         char tpl[32] = "/tmp/locktest.XXXXXX";
 205         int fd = mkstemp(tpl);
 206         if (fd < 0) {
 207                 strcpy(tpl, "conftest.dat");
 208                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 209         }
 210
 211         lock.l_type = F_WRLCK;
 212         lock.l_whence = SEEK_SET;
 213         lock.l_start = 0;
 214         lock.l_len = 1;
 215         lock.l_pid = 0;
 216         fcntl(fd,F_SETLK,&lock);
 217         if (fork() == 0) {
 218                 lock.l_start = 1;
 219                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 220         }
 221         wait(&status);
 222         unlink(tpl);
 223         return WEXITSTATUS(status);
 224 }
 225 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 226 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 227    AC_SYS_LARGEFILE
 228 fi
 229
 230 ipv6type=unknown
 231 ipv6lib=none
 232 ipv6trylibc=yes
 233
 234 AC_ARG_ENABLE(ipv6,
 235         AS_HELP_STRING([--disable-ipv6],[do not even try to use IPv6]))
 236 if test x"$enable_ipv6" != x"no"; then
 237         AC_MSG_CHECKING([ipv6 stack type])
 238         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 239                 case $i in
 240                 inria)
 241                         # http://www.kame.net/
 242                         AC_EGREP_CPP(yes, [
 243 #include <netinet/in.h>
 244 #ifdef IPV6_INRIA_VERSION
 245 yes
 246 #endif],
 247                                 [ipv6type=$i;
 248                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 249                                 ])
 250                         ;;
 251                 kame)
 252                         # http://www.kame.net/
 253                         AC_EGREP_CPP(yes, [
 254 #include <netinet/in.h>
 255 #ifdef __KAME__
 256 yes
 257 #endif],
 258                                 [ipv6type=$i;
 259                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 260                         ;;
 261                 linux-glibc)
 262                         # http://www.v6.linux.or.jp/
 263                         AC_EGREP_CPP(yes, [
 264 #include <features.h>
 265 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 266 yes
 267 #endif],
 268                                 [ipv6type=$i;
 269 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 270                         ;;
 271                 linux-inet6)
 272                         # http://www.v6.linux.or.jp/
 273                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 274                                 ipv6type=$i
 275                                 ipv6lib=inet6
 276                                 ipv6libdir=/usr/inet6/lib
 277                                 ipv6trylibc=yes;
 278                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 279                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 280                         fi
 281                         ;;
 282                 solaris)
 283                         # http://www.sun.com
 284                         AC_EGREP_CPP(yes, [
 285 #include <netinet/ip6.h>
 286 #ifdef __sun
 287 yes
 288 #endif],
 289                                 [ipv6type=$i;
 290                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 291                         ;;
 292                 toshiba)
 293                         AC_EGREP_CPP(yes, [
 294 #include <sys/param.h>
 295 #ifdef _TOSHIBA_INET6
 296 yes
 297 #endif],
 298                                 [ipv6type=$i;
 299                                 ipv6lib=inet6;
 300                                 ipv6libdir=/usr/local/v6/lib;
 301                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 302                         ;;
 303                 v6d)
 304                         AC_EGREP_CPP(yes, [
 305 #include </usr/local/v6/include/sys/v6config.h>
 306 #ifdef __V6D__
 307 yes
 308 #endif],
 309                                 [ipv6type=$i;
 310                                 ipv6lib=v6;
 311                                 ipv6libdir=/usr/local/v6/lib;
 312                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 313                         ;;
 314                 zeta)
 315                         AC_EGREP_CPP(yes, [
 316 #include <sys/param.h>
 317 #ifdef _ZETA_MINAMI_INET6
 318 yes
 319 #endif],
 320                                 [ipv6type=$i;
 321                                 ipv6lib=inet6;
 322                                 ipv6libdir=/usr/local/v6/lib;
 323                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 324                         ;;
 325                 cygwin)
 326                         AC_EGREP_CPP(yes, [
 327 #include <netinet/in.h>
 328 #ifdef _CYGWIN_IN6_H
 329 yes
 330 #endif],
 331                                 [ipv6type=$i;
 332                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 333                         ;;
 334                 esac
 335                 if test "$ipv6type" != "unknown"; then
 336                         break
 337                 fi
 338         done
 339         AC_MSG_RESULT($ipv6type)
 340
 341         AC_SEARCH_LIBS(getaddrinfo, inet6)
 342 fi
 343
 344 dnl Do you want to disable use of locale functions
 345 AC_ARG_ENABLE([locale],
 346         AS_HELP_STRING([--disable-locale],[disable locale features]))
 347 AH_TEMPLATE([CONFIG_LOCALE],
 348 [Undefine if you do not want locale features.  By default this is defined.])
 349 if test x"$enable_locale" != x"no"; then
 350         AC_DEFINE(CONFIG_LOCALE)
 351 fi
 352
 353 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 354 case $host_os in
 355         *cygwin* ) AC_MSG_RESULT(yes)
 356                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 357                             [Define to 1 if sockets need to be shutdown])
 358                    ;;
 359                * ) AC_MSG_RESULT(no);;
 360 esac
 361
 362 AC_C_BIGENDIAN
 363 AC_HEADER_DIRENT
 364 AC_HEADER_TIME
 365 AC_HEADER_SYS_WAIT
 366 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 367     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 368     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 369     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 370     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 371     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 372     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 373     zlib.h)
 374 AC_HEADER_MAJOR_FIXED
 375
 376 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 377 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 378 #include <sys/types.h>
 379 #ifdef MAJOR_IN_MKDEV
 380 #include <sys/mkdev.h>
 381 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 382 #  define makedev mkdev
 383 # endif
 384 #elif defined MAJOR_IN_SYSMACROS
 385 #include <sys/sysmacros.h>
 386 #endif
 387
 388 int main(void)
 389 {
 390         dev_t dev = makedev(0, 5, 7);
 391         if (major(dev) != 5 || minor(dev) != 7)
 392                 return 1;
 393         return 0;
 394 }
 395 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 396 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 397    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 398 fi
 399
 400 AC_CHECK_SIZEOF(int)
 401 AC_CHECK_SIZEOF(long)
 402 AC_CHECK_SIZEOF(long long)
 403 AC_CHECK_SIZEOF(short)
 404 AC_CHECK_SIZEOF(int16_t)
 405 AC_CHECK_SIZEOF(uint16_t)
 406 AC_CHECK_SIZEOF(int32_t)
 407 AC_CHECK_SIZEOF(uint32_t)
 408 AC_CHECK_SIZEOF(int64_t)
 409 AC_CHECK_SIZEOF(off_t)
 410 AC_CHECK_SIZEOF(off64_t)
 411 AC_CHECK_SIZEOF(time_t)
 412 AC_CHECK_SIZEOF(char*)
 413
 414 AC_C_INLINE
 415
 416 AC_TYPE_LONG_DOUBLE_WIDER
 417 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 418 if test $ac_cv_c_long_double = yes; then
 419   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 420 fi
 421
 422 AC_TYPE_UID_T
 423 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 424 AC_TYPE_GETGROUPS
 425 AC_CHECK_MEMBERS([struct stat.st_rdev,
 426                   struct stat.st_mtimensec,
 427                   struct stat.st_mtimespec.tv_nsec,
 428                   struct stat.st_mtim.tv_nsec],,,[
 429 #ifdef HAVE_SYS_TYPES_H
 430 #include <sys/types.h>
 431 #endif
 432 #ifdef HAVE_SYS_STAT_H
 433 #include <sys/stat.h>
 434 #endif
 435 #ifdef HAVE_UNISTD_H
 436 #include <unistd.h>
 437 #endif])
 438
 439 TYPE_SOCKLEN_T
 440
 441 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 442     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 443 if test x"$rsync_cv_errno" = x"yes"; then
 444    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 445 fi
 446
 447 # The following test taken from the cvs sources
 448 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 449 # These need checks to be before checks for any other functions that
 450 #    might be in the same libraries.
 451 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 452 # libsocket.so which has a bad implementation of gethostbyname (it
 453 # only looks in /etc/hosts), so we only look for -lsocket if we need
 454 # it.
 455 AC_CHECK_FUNCS(connect)
 456 if test x"$ac_cv_func_connect" = x"no"; then
 457     case "$LIBS" in
 458     *-lnsl*) ;;
 459     *) AC_CHECK_LIB(nsl_s, printf) ;;
 460     esac
 461     case "$LIBS" in
 462     *-lnsl*) ;;
 463     *) AC_CHECK_LIB(nsl, printf) ;;
 464     esac
 465     case "$LIBS" in
 466     *-lsocket*) ;;
 467     *) AC_CHECK_LIB(socket, connect) ;;
 468     esac
 469     case "$LIBS" in
 470     *-linet*) ;;
 471     *) AC_CHECK_LIB(inet, connect) ;;
 472     esac
 473     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 474     dnl has been cached.
 475     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 476        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 477         # ac_cv_func_connect=yes
 478         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 479         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 480     fi
 481 fi
 482
 483 AC_SEARCH_LIBS(inet_ntop, resolv)
 484
 485 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 486 # accept either iconv_open or libiconv_open, since some include files map
 487 # the former to the latter.
 488 AC_SEARCH_LIBS(iconv_open, iconv)
 489 AC_SEARCH_LIBS(libiconv_open, iconv)
 490
 491 AC_MSG_CHECKING([for iconv declaration])
 492 AC_CACHE_VAL(am_cv_proto_iconv, [
 493     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 494 #include <stdlib.h>
 495 #include <iconv.h>
 496 extern
 497 #ifdef __cplusplus
 498 "C"
 499 #endif
 500 #if defined(__STDC__) || defined(__cplusplus)
 501 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 502 #else
 503 size_t iconv();
 504 #endif
 505 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 506       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 507     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 508 AC_MSG_RESULT([$]{ac_t:-
 509          }[$]am_cv_proto_iconv)
 510 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 511                    [Define as const if the declaration of iconv() needs const.])
 512
 513 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 514
 515 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 516
 517 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 518 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 519 #include <sys/socket.h>])
 520
 521 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 522 #   builtin getaddrinfo if one of the defines don't exist
 523 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 524                rsync_cv_HAVE_GETADDR_DEFINES,[
 525                         AC_EGREP_CPP(yes, [
 526                         #include <sys/types.h>
 527                         #include <sys/socket.h>
 528                         #include <netdb.h>
 529                         #ifdef AI_PASSIVE
 530                         yes
 531                         #endif],
 532                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 533                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 534 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 535         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 536         # something else so we must include <netdb.h> to get the
 537         # redefinition.
 538         AC_CHECK_FUNCS(getaddrinfo, ,
 539                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 540                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 541                 #include <sys/socket.h>
 542                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 543                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 544                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 545                         AC_LIBOBJ([getaddrinfo])])])
 546     ],[AC_LIBOBJ([getaddrinfo])])
 547
 548 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 549                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 550                 [],
 551                 [
 552 #include <sys/types.h>
 553 #include <sys/socket.h>
 554 ])
 555
 556 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 557                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 558                 [],
 559                 [
 560 #include <sys/types.h>
 561 #include <sys/socket.h>
 562 #include <netinet/in.h>
 563 ])
 564
 565 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 566                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 567                 [],
 568                 [
 569 #include <sys/types.h>
 570 #include <sys/socket.h>
 571 #include <netinet/in.h>
 572 ])
 573
 574 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 575                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 576                 [],
 577                 [
 578 #include <sys/types.h>
 579 #include <sys/socket.h>
 580 #include <netinet/in.h>
 581 ])
 582
 583 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 584 #if HAVE_SYS_TYPES_H
 585 # include <sys/types.h>
 586 #endif
 587 #if HAVE_SYS_STAT_H
 588 # include <sys/stat.h>
 589 #endif
 590 #if STDC_HEADERS
 591 # include <stdlib.h>
 592 # include <stddef.h>
 593 #else
 594 # if HAVE_STDLIB_H
 595 #  include <stdlib.h>
 596 # endif
 597 #endif
 598 ])
 599
 600 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 601 #
 602 AC_CHECK_FUNCS(strcasecmp)
 603 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 604     AC_CHECK_LIB(resolv, strcasecmp)
 605 fi
 606
 607 AC_CHECK_FUNCS(aclsort)
 608 if test x"$ac_cv_func_aclsort" = x"no"; then
 609     AC_CHECK_LIB(sec, aclsort)
 610 fi
 611
 612 dnl At the moment we don't test for a broken memcmp(), because all we
 613 dnl need to do is test for equality, not comparison, and it seems that
 614 dnl every platform has a memcmp that can do at least that.
 615 dnl AC_FUNC_MEMCMP
 616
 617 AC_FUNC_UTIME_NULL
 618 AC_FUNC_ALLOCA
 619 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 620     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 621     chflags getattrlist \
 622     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 623     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 624     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 625     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 626     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 627     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep)
 628
 629 dnl cygwin iconv.h defines iconv_open as libiconv_open
 630 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 631     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 632 fi
 633
 634 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 635
 636 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 637 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 638 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 639 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 640     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 641 fi
 642
 643 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 644 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 645         #define _GNU_SOURCE 1
 646         #include <linux/falloc.h>
 647         #ifndef FALLOC_FL_PUNCH_HOLE
 648         #error FALLOC_FL_PUNCH_HOLE is missing
 649         #endif
 650     ]])], [
 651         AC_MSG_RESULT([yes])
 652         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 653     ], [
 654         AC_MSG_RESULT([no])
 655     ]
 656 )
 657
 658 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 659 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 660         #define _GNU_SOURCE 1
 661         #include <linux/falloc.h>
 662         #ifndef FALLOC_FL_ZERO_RANGE
 663         #error FALLOC_FL_ZERO_RANGE is missing
 664         #endif
 665     ]])], [
 666         AC_MSG_RESULT([yes])
 667         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 668     ], [
 669         AC_MSG_RESULT([no])
 670     ]
 671 )
 672
 673 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 674 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 675 #include <unistd.h>
 676 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 677 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 678     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 679 fi
 680
 681 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 682     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 683     case $host_os in
 684     *cygwin*)
 685         AC_MSG_RESULT(yes)
 686         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 687                   [Define if posix_fallocate is efficient (Cygwin)])
 688         ;;
 689     *)
 690         AC_MSG_RESULT(no)
 691         ;;
 692     esac
 693 fi
 694
 695 dnl End of preallocation stuff
 696
 697 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 698 if test $ac_cv_func_getpgrp = yes; then
 699     AC_FUNC_GETPGRP
 700 fi
 701
 702 AC_ARG_ENABLE(iconv-open,
 703     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 704     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 705
 706 if test x"$enable_iconv_open" != x"no"; then
 707     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 708 fi
 709
 710 AC_ARG_ENABLE(iconv,
 711     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 712     [], [enable_iconv=$enable_iconv_open])
 713 AH_TEMPLATE([ICONV_OPTION],
 714 [Define if you want the --iconv option.  Specifing a value will set the
 715 default iconv setting (a NULL means no --iconv processing by default).])
 716 if test x"$enable_iconv" != x"no"; then
 717         if test x"$enable_iconv" = x"yes"; then
 718                 AC_DEFINE(ICONV_OPTION, NULL)
 719         else
 720                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 721         fi
 722         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 723 fi
 724
 725 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 726   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 727 #if HAVE_UNISTD_H
 728 # include <unistd.h>
 729 #endif
 730 #include <stdlib.h>
 731 #include <errno.h>
 732 int main(void) {
 733         char const *dangling_symlink = "conftest.dangle";
 734         unlink(dangling_symlink);
 735         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 736         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 737         return 0;
 738     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 739 if test $rsync_cv_chown_modifies_symlink = yes; then
 740   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 741 fi
 742
 743 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 744   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 745 #if HAVE_UNISTD_H
 746 # include <unistd.h>
 747 #endif
 748 #include <stdlib.h>
 749 #include <errno.h>
 750 #define FILENAME "conftest.dangle"
 751 int main(void) {
 752         unlink(FILENAME);
 753         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 754         unlink(FILENAME "2");
 755         if (link(FILENAME, FILENAME "2") < 0) return 1;
 756         return 0;
 757     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 758 if test $rsync_cv_can_hardlink_symlink = yes; then
 759   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 760 fi
 761
 762 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 763   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 764 #if HAVE_UNISTD_H
 765 # include <unistd.h>
 766 #endif
 767 #ifdef HAVE_SYS_STAT_H
 768 #include <sys/stat.h>
 769 #endif
 770 #include <stdlib.h>
 771 #include <errno.h>
 772 #define FILENAME "conftest.fifi"
 773 int main(void) {
 774         unlink(FILENAME);
 775         if (mkfifo(FILENAME, 0777) < 0) abort();
 776         unlink(FILENAME "2");
 777         if (link(FILENAME, FILENAME "2") < 0) return 1;
 778         return 0;
 779     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 780 if test $rsync_cv_can_hardlink_special = yes; then
 781     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 782 fi
 783
 784 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 785 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 786 #include <sys/types.h>
 787 #include <sys/socket.h>
 788
 789 int main(void) {
 790        int fd[2];
 791        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
 792 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 793 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 794     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 795 fi
 796
 797 AC_REPLACE_FUNCS([getpass])
 798
 799 if test x"$with_included_popt" != x"yes"; then
 800     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 801 fi
 802 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 803     # If the system has /usr/include/popt/popt.h, we enable the
 804     # included popt because an attempt to "#include <popt/popt.h>"
 805     # would use our included header file anyway (due to -I.), and
 806     # might conflict with the system popt.
 807     with_included_popt=yes
 808 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 809     with_included_popt=yes
 810 fi
 811
 812 AC_MSG_CHECKING([whether to use included libpopt])
 813 if test x"$with_included_popt" = x"yes"; then
 814     AC_MSG_RESULT($srcdir/popt)
 815     BUILD_POPT='$(popt_OBJS)'
 816     CFLAGS="-I$srcdir/popt $CFLAGS"
 817     if test x"$ALLOCA" != x
 818     then
 819         # this can be removed when/if we add an included alloca.c;
 820         #  see autoconf documentation on AC_FUNC_ALLOCA
 821         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 822     fi
 823 else
 824     AC_MSG_RESULT(no)
 825 fi
 826
 827 # We default to using our zlib unless --with-included-zlib=no is given.
 828 if test x"$with_included_zlib" != x"no"; then
 829     with_included_zlib=yes
 830 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
 831     with_included_zlib=yes
 832 fi
 833 if test x"$with_included_zlib" != x"yes"; then
 834     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
 835 fi
 836
 837 AC_MSG_CHECKING([whether to use included zlib])
 838 if test x"$with_included_zlib" = x"yes"; then
 839     AC_MSG_RESULT($srcdir/zlib)
 840     BUILD_ZLIB='$(zlib_OBJS)'
 841     CFLAGS="-I$srcdir/zlib $CFLAGS"
 842 else
 843     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
 844     AC_MSG_RESULT(no)
 845 fi
 846
 847 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 848 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
 849 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 850     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 851 fi
 852
 853 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 854 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
 855 #include <dirent.h>
 856 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 857 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 858 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
 859 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 860     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 861 fi
 862
 863 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
 864 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 865 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
 866 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
 867     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 868 fi
 869
 870 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 871 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
 872 #include <unistd.h>]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
 873 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 874     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 875 fi
 876
 877 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 878 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 879 #include <sys/types.h>
 880 #include <stdarg.h>
 881 #include <stdio.h>
 882 #include <stdlib.h>
 883 #include <string.h>
 884 void foo(const char *format, ...) {
 885        va_list ap;
 886        int len;
 887        char buf[5];
 888
 889        va_start(ap, format);
 890        len = vsnprintf(0, 0, format, ap);
 891        va_end(ap);
 892        if (len != 5) exit(1);
 893
 894        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 895 }
 896 int main(void) { foo("hello"); return 0; }
 897 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
 898 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 899     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 900 fi
 901
 902
 903 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 904 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 905 #include <sys/types.h>
 906 #include <sys/stat.h>
 907 #include <unistd.h>
 908 int main(void) {
 909   struct stat st;
 910   char tpl[20]="/tmp/test.XXXXXX";
 911   int fd = mkstemp(tpl);
 912   if (fd == -1) return 1;
 913   unlink(tpl);
 914   if (fstat(fd, &st) != 0) return 1;
 915   if ((st.st_mode & 0777) != 0600) return 1;
 916   return 0;
 917 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
 918 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 919     case $host_os in
 920     hpux*)
 921         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 922         dnl so we noisily skip using it.  See HP change request JAGaf34426
 923         dnl for details. (sbonds)
 924         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 925         ;;
 926     *)
 927         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 928         ;;
 929     esac
 930 fi
 931
 932
 933 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 934 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 935 #include <stdio.h>
 936 #include <sys/stat.h>
 937 #include <errno.h>
 938 #if HAVE_UNISTD_H
 939 # include <unistd.h>
 940 #endif
 941 int main(void) { int rc, ec; char *fn = "fifo-test";
 942 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 943 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 944 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
 945 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 946     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 947 fi
 948
 949 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 950 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 951 #include <stdio.h>
 952 #include <sys/stat.h>
 953 #include <errno.h>
 954 #if HAVE_UNISTD_H
 955 # include <unistd.h>
 956 #endif
 957 int main(void) { int rc, ec; char *fn = "sock-test";
 958 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 959 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 960 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
 961 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 962     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 963 fi
 964
 965 #
 966 # The following test was mostly taken from the tcl/tk plus patches
 967 #
 968 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 969 rm -rf conftest*
 970 cat > conftest.$ac_ext <<EOF
 971 int main(void) { return 0; }
 972 EOF
 973 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 974 if test -f conftest..o; then
 975     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 976 else
 977     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 978 fi
 979 rm -rf conftest*
 980 ])
 981 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 982     OBJ_SAVE="#"
 983     OBJ_RESTORE="#"
 984     CC_SHOBJ_FLAG='-o $@'
 985 else
 986     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 987     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 988     CC_SHOBJ_FLAG=""
 989 fi
 990
 991 AC_SUBST(OBJ_SAVE)
 992 AC_SUBST(OBJ_RESTORE)
 993 AC_SUBST(CC_SHOBJ_FLAG)
 994 AC_SUBST(BUILD_POPT)
 995 AC_SUBST(BUILD_ZLIB)
 996 AC_SUBST(MAKE_MAN)
 997
 998 AC_CHECK_FUNCS(_acl __acl _facl __facl)
 999 #################################################
1000 # check for ACL support
1001
1002 AC_MSG_CHECKING([whether to support ACLs])
1003 AC_ARG_ENABLE(acl-support,
1004         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
1005
1006 if test x"$enable_acl_support" = x"no"; then
1007     AC_MSG_RESULT(no)
1008 else
1009     case "$host_os" in
1010     *sysv5*)
1011         AC_MSG_RESULT(Using UnixWare ACLs)
1012         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1013         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1014         ;;
1015     solaris*)
1016         AC_MSG_RESULT(Using solaris ACLs)
1017         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1018         AC_DEFINE(SUPPORT_ACLS, 1)
1019         ;;
1020     *hpux*)
1021         AC_MSG_RESULT(Using HPUX ACLs)
1022         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1023         AC_DEFINE(SUPPORT_ACLS, 1)
1024         ;;
1025     *irix*)
1026         AC_MSG_RESULT(Using IRIX ACLs)
1027         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1028         AC_DEFINE(SUPPORT_ACLS, 1)
1029         ;;
1030     *aix*)
1031         AC_MSG_RESULT(Using AIX ACLs)
1032         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1033         AC_DEFINE(SUPPORT_ACLS, 1)
1034         ;;
1035     *osf*)
1036         AC_MSG_RESULT(Using Tru64 ACLs)
1037         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1038         AC_DEFINE(SUPPORT_ACLS, 1)
1039         LIBS="$LIBS -lpacl"
1040         ;;
1041     darwin*)
1042         AC_MSG_RESULT(Using OS X ACLs)
1043         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1044         AC_DEFINE(SUPPORT_ACLS, 1)
1045         ;;
1046     *)
1047         AC_MSG_RESULT(running tests:)
1048         AC_CHECK_LIB(acl,acl_get_file)
1049         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1050             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1051 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1052         AC_MSG_CHECKING(ACL test results)
1053         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1054             AC_MSG_RESULT(Using posix ACLs)
1055             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1056             AC_DEFINE(SUPPORT_ACLS, 1)
1057             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1058                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1059 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1060             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1061                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1062             fi
1063         else
1064             if test x"$enable_acl_support" = x"yes"; then
1065                 AC_MSG_ERROR(Failed to find ACL support)
1066             else
1067                 AC_MSG_RESULT(No ACL support found)
1068             fi
1069         fi
1070         ;;
1071     esac
1072 fi
1073
1074 #################################################
1075 # check for extended attribute support
1076 AC_MSG_CHECKING(whether to support extended attributes)
1077 AC_ARG_ENABLE(xattr-support,
1078     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1079     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1080         *yes*) enable_xattr_support=maybe ;;
1081         *) enable_xattr_support=no ;;
1082         esac])
1083 AH_TEMPLATE([SUPPORT_XATTRS],
1084 [Define to 1 to add support for extended attributes])
1085 if test x"$enable_xattr_support" = x"no"; then
1086     AC_MSG_RESULT(no)
1087 else
1088     case "$host_os" in
1089     *linux*|*netbsd*)
1090         AC_MSG_RESULT(Using Linux xattrs)
1091         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1092         AC_DEFINE(SUPPORT_XATTRS, 1)
1093         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1094         AC_CHECK_LIB(attr,getxattr)
1095         ;;
1096     darwin*)
1097         AC_MSG_RESULT(Using OS X xattrs)
1098         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1099         AC_DEFINE(SUPPORT_XATTRS, 1)
1100         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1101         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1102         ;;
1103     freebsd*)
1104         AC_MSG_RESULT(Using FreeBSD extattrs)
1105         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1106         AC_DEFINE(SUPPORT_XATTRS, 1)
1107         ;;
1108     solaris*)
1109         AC_MSG_RESULT(Using Solaris xattrs)
1110         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1111         AC_DEFINE(SUPPORT_XATTRS, 1)
1112         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1113         ;;
1114     *)
1115         if test x"$enable_xattr_support" = x"yes"; then
1116             AC_MSG_ERROR(Failed to find extended attribute support)
1117         else
1118             AC_MSG_RESULT(No extended attribute support found)
1119         fi
1120         ;;
1121     esac
1122 fi
1123
1124 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1125     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1126     OLD_CFLAGS="$CFLAGS"
1127     CFLAGS="$CFLAGS -Wno-unused-parameter"
1128     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1129     AC_MSG_RESULT([$rsync_warn_flag])
1130     if test x"$rsync_warn_flag" = x"no"; then
1131         CFLAGS="$OLD_CFLAGS"
1132     fi
1133 fi
1134
1135 case "$CC" in
1136 ' checker'*|checker*)
1137     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1138     ;;
1139 esac
1140
1141 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1142 AC_OUTPUT
1143
1144 AC_MSG_RESULT()
1145 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1146 AC_MSG_RESULT()
1147 if test x$HAVE_YODL2MAN != x1; then
1148     AC_MSG_RESULT([    Note that yodl2man was not found, so pre-existing manpage files will be])
1149     AC_MSG_RESULT([    used w/o change (if available) -- no .yo file changes will be used.])
1150     AC_MSG_RESULT()
1151 fi