configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.2.1dev],[http://rsync.samba.org/bugzilla.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_CXX
  45 AC_PROG_AWK
  46 AC_PROG_EGREP
  47 AC_PROG_INSTALL
  48 AC_PROG_MKDIR_P
  49 AC_PROG_CC_STDC
  50 AC_SUBST(SHELL)
  51 AC_PATH_PROG([PERL], [perl])
  52 AC_PATH_PROG([PYTHON3], [python3])
  53
  54 AC_DEFINE([_GNU_SOURCE], 1,
  55           [Define _GNU_SOURCE so that we get all necessary prototypes])
  56
  57 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  58         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  59 fi
  60
  61 AC_ARG_ENABLE(profile,
  62         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  63 if test x"$enable_profile" = x"yes"; then
  64         CFLAGS="$CFLAGS -pg"
  65 fi
  66
  67 AC_MSG_CHECKING([if md2man can create man pages])
  68 if test x"$ac_cv_path_PYTHON3" = x; then
  69     AC_MSG_RESULT(no - python3 not found)
  70     md2man_works=no
  71 else
  72     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync-ssl.1.md" 2>&1`
  73     if test $? = 0; then
  74         AC_MSG_RESULT(yes)
  75         md2man_works=yes
  76     else
  77         AC_MSG_RESULT(no)
  78         md2man_works=no
  79         echo "$md2man_out"
  80     fi
  81 fi
  82
  83 AC_MSG_CHECKING([if we require man-page building])
  84 AC_ARG_ENABLE([md2man],
  85         AS_HELP_STRING([--disable-md2man],[disable md2man for man page creation]))
  86 if test x"$enable_md2man" != x"no"; then
  87     if test -f "$srcdir/rsync.1"; then
  88         AC_MSG_RESULT(optional)
  89     else
  90         AC_MSG_RESULT(required)
  91         if test x"$md2man_works" = x"no"; then
  92             AC_MSG_ERROR(You need python3 and the cmarkgfm OR commonmark python3 lib in order to build man pages.
  93 You can specify --disable-md2man if you want to skip building them.)
  94         fi
  95     fi
  96     MAKE_MAN=man
  97 else
  98     AC_MSG_RESULT(no)
  99     MAKE_MAN=''
 100 fi
 101
 102 # Specifically, this turns on panic_action handling.
 103 AC_ARG_ENABLE(maintainer-mode,
 104         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
 105 if test x"$enable_maintainer_mode" = x"yes"; then
 106         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 107 fi
 108
 109 # This is needed for our included version of popt.  Kind of silly, but
 110 # I don't want our version too far out of sync.
 111 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 112
 113 # If GCC, turn on warnings.
 114 if test x"$GCC" = x"yes"; then
 115         CFLAGS="$CFLAGS -Wall -W"
 116 fi
 117
 118 AC_ARG_WITH(included-popt,
 119         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 120
 121 AC_ARG_WITH(included-zlib,
 122         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 123
 124 AC_ARG_WITH(protected-args,
 125         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
 126 if test x"$with_protected_args" = x"yes"; then
 127         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
 128 fi
 129
 130 AC_ARG_WITH(rsync-path,
 131         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 132         [ RSYNC_PATH="$with_rsync_path" ],
 133         [ RSYNC_PATH="rsync" ])
 134
 135 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 136
 137 AC_ARG_WITH(rsyncd-conf,
 138         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 139         [ if test ! -z "$with_rsyncd_conf" ; then
 140                 case $with_rsyncd_conf in
 141                         yes|no)
 142                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 143                                 ;;
 144                         /*)
 145                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 146                                 ;;
 147                         *)
 148                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 149                                 ;;
 150                 esac
 151         else
 152                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 153         fi ],
 154         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 155
 156 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 157
 158 AC_ARG_WITH(rsh,
 159         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 160
 161 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 162 if test x$HAVE_REMSH = x1; then
 163         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 164 fi
 165
 166 if test x"$with_rsh" != x; then
 167         RSYNC_RSH="$with_rsh"
 168 else
 169         RSYNC_RSH="ssh"
 170 fi
 171 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 172
 173 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 174 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 175 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 176
 177 AC_ARG_WITH(nobody-group,
 178     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 179     [ NOBODY_GROUP="$with_nobody_group" ])
 180
 181 if test x"$with_nobody_group" = x; then
 182     AC_MSG_CHECKING([the group for user "nobody"])
 183     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 184         NOBODY_GROUP=nobody
 185     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 186         NOBODY_GROUP=nogroup
 187     else
 188         NOBODY_GROUP=nobody # test for others?
 189     fi
 190     AC_MSG_RESULT($NOBODY_GROUP)
 191 fi
 192
 193 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 194 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 195
 196 # SIMD optimizations
 197 SIMD=
 198
 199 AC_MSG_CHECKING([whether to enable SIMD optimizations])
 200 AC_ARG_ENABLE(simd,
 201     AS_HELP_STRING([--disable-simd],[disable SIMD optimizations (requires c++)]))
 202
 203 if test x"$enable_simd" != x"no"; then
 204     # For x86-64 SIMD, g++ >=5 or clang++ >=7 is required
 205     if test x"$build_cpu" = x"x86_64"; then
 206         AC_LANG(C++)
 207         AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 208 #include <immintrin.h>
 209 __attribute__ ((target("default"))) int test_ssse3(int x) { return x; }
 210 __attribute__ ((target("default"))) int test_sse2(int x) { return x; }
 211 __attribute__ ((target("default"))) int test_avx2(int x) { return x; }
 212 __attribute__ ((target("ssse3"))) int test_ssse3(int x) { return x; }
 213 __attribute__ ((target("sse2"))) int test_sse2(int x) { return x; }
 214 __attribute__ ((target("avx2"))) int test_avx2(int x) { return x; }
 215 typedef long long __m128i_u __attribute__((__vector_size__(16), __may_alias__, __aligned__(1)));
 216 typedef long long __m256i_u __attribute__((__vector_size__(32), __may_alias__, __aligned__(1)));
 217 inline void more_testing(char* buf, int len)
 218 {
 219     int i;
 220     for (i = 0; i < (len-32); i+=32) {
 221         __m128i in8_1, in8_2;
 222         in8_1 = _mm_lddqu_si128((__m128i_u*)&buf[i]);
 223         in8_2 = _mm_lddqu_si128((__m128i_u*)&buf[i + 16]);
 224     }
 225 }
 226 ]], [[if (test_ssse3(42) != 42 || test_sse2(42) != 42 || test_avx2(42) != 42) exit(1);]])],[CXX_OK=yes],[CXX_OK=no])
 227         AC_LANG(C)
 228         if test x"$CXX_OK" = x"yes"; then
 229             # AC_MSG_RESULT() is called below.
 230             SIMD="x86_64"
 231         elif test x"$enable_simd" = x"yes"; then
 232             AC_MSG_RESULT(error)
 233             AC_MSG_ERROR(The SIMD compilation test failed.
 234 Omit --enable-simd to continue without it.)
 235         fi
 236     elif test x"$enable_simd" = x"yes"; then
 237         AC_MSG_RESULT(unavailable)
 238         AC_MSG_ERROR(The SIMD optimizations are currently x86_64 only.
 239 Omit --enable-simd to continue without it.)
 240     fi
 241 fi
 242
 243 if test x"$SIMD" != x""; then
 244     AC_MSG_RESULT([yes ($SIMD)])
 245     AC_DEFINE(HAVE_SIMD, 1, [Define to 1 to enable SIMD optimizations])
 246     SIMD='$(SIMD_'"$SIMD)"
 247     # Clag is crashing with -g -O2, so we'll get rid of -g (just for the one file).
 248     CXXFLAGS=`echo "'$CXXFLAGS'" | sed 's/-g //'`
 249     # We only use c++ for its target attribute dispatching, disable unneeded bulky features
 250     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 251 else
 252     AC_MSG_RESULT(no)
 253 fi
 254
 255 AC_SUBST(SIMD)
 256
 257 AC_MSG_CHECKING([if assembler accepts noexecstack])
 258 OLD_CFLAGS="$CFLAGS"
 259 CFLAGS="$CFLAGS -Wa,--noexecstack"
 260 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ ]], [[return 0;]])],
 261 [ NOEXECSTACK='-Wa,--noexecstack' ; AC_MSG_RESULT(yes) ],
 262 [ NOEXECSTACK='' ; AC_MSG_RESULT(no) ])
 263 CFLAGS="$OLD_CFLAGS"
 264 AC_SUBST(NOEXECSTACK)
 265
 266 ASM=
 267
 268 AC_MSG_CHECKING([whether to enable ASM optimizations])
 269 AC_ARG_ENABLE(asm,
 270     AS_HELP_STRING([--disable-asm],[disable ASM optimizations]))
 271
 272 if test x"$enable_asm" != x"no"; then
 273     if test x"$build_cpu" = x"x86_64"; then
 274         ASM="$build_cpu"
 275     elif test x"$enable_asm" = x"yes"; then
 276         AC_MSG_RESULT(unavailable)
 277         AC_MSG_ERROR(The ASM optimizations are currently x86_64 only.
 278 Omit --enable-asm to continue without it.)
 279     fi
 280 fi
 281
 282 if test x"$ASM" != x""; then
 283     AC_MSG_RESULT([yes ($ASM)])
 284     AC_DEFINE(HAVE_ASM, 1, [Define to 1 to enable ASM optimizations])
 285     ASM='$(ASM_'"$ASM)"
 286 else
 287     AC_MSG_RESULT(no)
 288 fi
 289
 290 AC_SUBST(ASM)
 291
 292 # arrgh. libc in some old debian version screwed up the largefile
 293 # stuff, getting byte range locking wrong
 294 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 295 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 296 #define _FILE_OFFSET_BITS 64
 297 #include <stdio.h>
 298 #include <fcntl.h>
 299 #include <sys/types.h>
 300 #include <sys/wait.h>
 301 #if HAVE_UNISTD_H
 302 #include <unistd.h>
 303 #endif
 304
 305 int main(void)
 306 {
 307         struct flock lock;
 308         int status;
 309         char tpl[32] = "/tmp/locktest.XXXXXX";
 310         int fd = mkstemp(tpl);
 311         if (fd < 0) {
 312                 strcpy(tpl, "conftest.dat");
 313                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 314         }
 315
 316         lock.l_type = F_WRLCK;
 317         lock.l_whence = SEEK_SET;
 318         lock.l_start = 0;
 319         lock.l_len = 1;
 320         lock.l_pid = 0;
 321         fcntl(fd,F_SETLK,&lock);
 322         if (fork() == 0) {
 323                 lock.l_start = 1;
 324                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 325         }
 326         wait(&status);
 327         unlink(tpl);
 328         return WEXITSTATUS(status);
 329 }
 330 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 331 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 332    AC_SYS_LARGEFILE
 333 fi
 334
 335 ipv6type=unknown
 336 ipv6lib=none
 337 ipv6trylibc=yes
 338
 339 AC_ARG_ENABLE(ipv6,
 340         AS_HELP_STRING([--disable-ipv6],[turn off IPv6 support]))
 341 if test x"$enable_ipv6" != x"no"; then
 342         AC_MSG_CHECKING([ipv6 stack type])
 343         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 344                 case $i in
 345                 inria)
 346                         # http://www.kame.net/
 347                         AC_EGREP_CPP(yes, [
 348 #include <netinet/in.h>
 349 #ifdef IPV6_INRIA_VERSION
 350 yes
 351 #endif],
 352                                 [ipv6type=$i;
 353                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 354                                 ])
 355                         ;;
 356                 kame)
 357                         # http://www.kame.net/
 358                         AC_EGREP_CPP(yes, [
 359 #include <netinet/in.h>
 360 #ifdef __KAME__
 361 yes
 362 #endif],
 363                                 [ipv6type=$i;
 364                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 365                         ;;
 366                 linux-glibc)
 367                         # http://www.v6.linux.or.jp/
 368                         AC_EGREP_CPP(yes, [
 369 #include <features.h>
 370 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 371 yes
 372 #endif],
 373                                 [ipv6type=$i;
 374 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 375                         ;;
 376                 linux-inet6)
 377                         # http://www.v6.linux.or.jp/
 378                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 379                                 ipv6type=$i
 380                                 ipv6lib=inet6
 381                                 ipv6libdir=/usr/inet6/lib
 382                                 ipv6trylibc=yes;
 383                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 384                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 385                         fi
 386                         ;;
 387                 solaris)
 388                         # http://www.sun.com
 389                         AC_EGREP_CPP(yes, [
 390 #include <netinet/ip6.h>
 391 #ifdef __sun
 392 yes
 393 #endif],
 394                                 [ipv6type=$i;
 395                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 396                         ;;
 397                 toshiba)
 398                         AC_EGREP_CPP(yes, [
 399 #include <sys/param.h>
 400 #ifdef _TOSHIBA_INET6
 401 yes
 402 #endif],
 403                                 [ipv6type=$i;
 404                                 ipv6lib=inet6;
 405                                 ipv6libdir=/usr/local/v6/lib;
 406                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 407                         ;;
 408                 v6d)
 409                         AC_EGREP_CPP(yes, [
 410 #include </usr/local/v6/include/sys/v6config.h>
 411 #ifdef __V6D__
 412 yes
 413 #endif],
 414                                 [ipv6type=$i;
 415                                 ipv6lib=v6;
 416                                 ipv6libdir=/usr/local/v6/lib;
 417                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 418                         ;;
 419                 zeta)
 420                         AC_EGREP_CPP(yes, [
 421 #include <sys/param.h>
 422 #ifdef _ZETA_MINAMI_INET6
 423 yes
 424 #endif],
 425                                 [ipv6type=$i;
 426                                 ipv6lib=inet6;
 427                                 ipv6libdir=/usr/local/v6/lib;
 428                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 429                         ;;
 430                 cygwin)
 431                         AC_EGREP_CPP(yes, [
 432 #include <netinet/in.h>
 433 #ifdef _CYGWIN_IN6_H
 434 yes
 435 #endif],
 436                                 [ipv6type=$i;
 437                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 438                         ;;
 439                 esac
 440                 if test "$ipv6type" != "unknown"; then
 441                         break
 442                 fi
 443         done
 444         AC_MSG_RESULT($ipv6type)
 445
 446         AC_SEARCH_LIBS(getaddrinfo, inet6)
 447 fi
 448
 449 dnl Do you want to disable use of locale functions
 450 AC_ARG_ENABLE([locale],
 451         AS_HELP_STRING([--disable-locale],[disable locale features]))
 452 AH_TEMPLATE([CONFIG_LOCALE],
 453 [Undefine if you do not want locale features.  By default this is defined.])
 454 if test x"$enable_locale" != x"no"; then
 455         AC_DEFINE(CONFIG_LOCALE)
 456 fi
 457
 458 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 459 case $host_os in
 460         *cygwin* ) AC_MSG_RESULT(yes)
 461                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 462                             [Define to 1 if sockets need to be shutdown])
 463                    ;;
 464                * ) AC_MSG_RESULT(no);;
 465 esac
 466
 467 AC_C_BIGENDIAN
 468 AC_HEADER_DIRENT
 469 AC_HEADER_TIME
 470 AC_HEADER_SYS_WAIT
 471 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 472     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 473     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 474     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 475     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 476     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 477     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 478     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h)
 479 AC_HEADER_MAJOR_FIXED
 480
 481 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 482 AC_ARG_ENABLE([openssl],
 483         AS_HELP_STRING([--disable-openssl],[disable openssl crypto library]))
 484 AH_TEMPLATE([USE_OPENSSL],
 485 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 486 if test x"$enable_openssl" != x"no"; then
 487     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 488       AC_MSG_RESULT(yes)
 489       AC_SEARCH_LIBS(MD5_Init, crypto,
 490           [AC_DEFINE(USE_OPENSSL)],
 491           [AC_MSG_ERROR(Failed to find MD5_Init function in openssl crypto lib.
 492 Use --disable-openssl to continue without openssl crypto lib support.)])
 493     else
 494         AC_MSG_RESULT(no)
 495         AC_MSG_ERROR(Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support.
 496 Use --disable-openssl to continue without it.)
 497     fi
 498 else
 499     AC_MSG_RESULT(no)
 500 fi
 501
 502 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 503 AC_ARG_ENABLE([xxhash],
 504         AS_HELP_STRING([--disable-xxhash],[disable xxhash checksums]))
 505 AH_TEMPLATE([SUPPORT_XXHASH],
 506 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 507 if test x"$enable_xxhash" != x"no"; then
 508     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 509         AC_MSG_RESULT(yes)
 510         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 511             [AC_DEFINE(SUPPORT_XXHASH)],
 512             [AC_MSG_ERROR(Failed to find XXH64_createState function in xxhash lib.
 513 Use --disable-xxhash to continue without xxhash checksums.)])
 514     else
 515         AC_MSG_RESULT(no)
 516         AC_MSG_ERROR(Failed to find xxhash.h for xxhash checksum support.
 517 Use --disable-xxhash to continue without it.)
 518     fi
 519 else
 520     AC_MSG_RESULT(no)
 521 fi
 522
 523 AC_MSG_CHECKING([whether to enable zstd compression])
 524 AC_ARG_ENABLE([zstd],
 525         AC_HELP_STRING([--disable-zstd], [disable zstd compression]))
 526 AH_TEMPLATE([SUPPORT_ZSTD],
 527 [Undefine if you do not want zstd compression.  By default this is defined.])
 528 if test x"$enable_zstd" != x"no"; then
 529     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 530         AC_MSG_RESULT(yes)
 531         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 532             [AC_DEFINE(SUPPORT_ZSTD)],
 533             [AC_MSG_ERROR(Failed to find ZSTD_minCLevel function in zstd lib.
 534 Use --disable-zstd to continue without zstd compression.)])
 535     else
 536         AC_MSG_RESULT(no)
 537         AC_MSG_ERROR(Failed to find zstd.h for zstd compression support.
 538 Use --disable-zstd to continue without it.)
 539     fi
 540 else
 541     AC_MSG_RESULT(no)
 542 fi
 543
 544 AC_MSG_CHECKING([whether to enable LZ4 compression])
 545 AC_ARG_ENABLE([lz4],
 546         AC_HELP_STRING([--disable-lz4], [disable LZ4 compression]))
 547 AH_TEMPLATE([SUPPORT_LZ4],
 548 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 549 if test x"$enable_lz4" != x"no"; then
 550     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 551         AC_MSG_RESULT(yes)
 552         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 553             [AC_DEFINE(SUPPORT_LZ4)],
 554             [AC_MSG_ERROR(Failed to find LZ4_compress_default function in lz4 lib.
 555 Use --disable-lz4 to continue without lz4 compression.)])
 556     else
 557         AC_MSG_RESULT(no)
 558         AC_MSG_ERROR(Failed to find lz4.h for lz4 compression support.
 559 Use --disable-lz4 to continue without it.)
 560     fi
 561 else
 562     AC_MSG_RESULT(no)
 563 fi
 564
 565 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 566 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 567 #include <sys/types.h>
 568 #ifdef MAJOR_IN_MKDEV
 569 #include <sys/mkdev.h>
 570 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 571 #  define makedev mkdev
 572 # endif
 573 #elif defined MAJOR_IN_SYSMACROS
 574 #include <sys/sysmacros.h>
 575 #endif
 576
 577 int main(void)
 578 {
 579         dev_t dev = makedev(0, 5, 7);
 580         if (major(dev) != 5 || minor(dev) != 7)
 581                 return 1;
 582         return 0;
 583 }
 584 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 585 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 586    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 587 fi
 588
 589 AC_CHECK_SIZEOF(int)
 590 AC_CHECK_SIZEOF(long)
 591 AC_CHECK_SIZEOF(long long)
 592 AC_CHECK_SIZEOF(short)
 593 AC_CHECK_SIZEOF(int16_t)
 594 AC_CHECK_SIZEOF(uint16_t)
 595 AC_CHECK_SIZEOF(int32_t)
 596 AC_CHECK_SIZEOF(uint32_t)
 597 AC_CHECK_SIZEOF(int64_t)
 598 AC_CHECK_SIZEOF(off_t)
 599 AC_CHECK_SIZEOF(off64_t)
 600 AC_CHECK_SIZEOF(time_t)
 601 AC_CHECK_SIZEOF(char*)
 602
 603 AC_C_INLINE
 604
 605 AC_TYPE_LONG_DOUBLE_WIDER
 606 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 607 if test $ac_cv_c_long_double = yes; then
 608   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 609 fi
 610
 611 AC_TYPE_UID_T
 612 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 613 AC_TYPE_GETGROUPS
 614 AC_CHECK_MEMBERS([struct stat.st_rdev,
 615                   struct stat.st_mtimensec,
 616                   struct stat.st_mtimespec.tv_nsec,
 617                   struct stat.st_mtim.tv_nsec],,,[
 618 #ifdef HAVE_SYS_TYPES_H
 619 #include <sys/types.h>
 620 #endif
 621 #ifdef HAVE_SYS_STAT_H
 622 #include <sys/stat.h>
 623 #endif
 624 #ifdef HAVE_UNISTD_H
 625 #include <unistd.h>
 626 #endif])
 627
 628 TYPE_SOCKLEN_T
 629
 630 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 631     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 632 if test x"$rsync_cv_errno" = x"yes"; then
 633    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 634 fi
 635
 636 # The following test taken from the cvs sources
 637 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 638 # These need checks to be before checks for any other functions that
 639 #    might be in the same libraries.
 640 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 641 # libsocket.so which has a bad implementation of gethostbyname (it
 642 # only looks in /etc/hosts), so we only look for -lsocket if we need
 643 # it.
 644 AC_CHECK_FUNCS(connect)
 645 if test x"$ac_cv_func_connect" = x"no"; then
 646     case "$LIBS" in
 647     *-lnsl*) ;;
 648     *) AC_CHECK_LIB(nsl_s, printf) ;;
 649     esac
 650     case "$LIBS" in
 651     *-lnsl*) ;;
 652     *) AC_CHECK_LIB(nsl, printf) ;;
 653     esac
 654     case "$LIBS" in
 655     *-lsocket*) ;;
 656     *) AC_CHECK_LIB(socket, connect) ;;
 657     esac
 658     case "$LIBS" in
 659     *-linet*) ;;
 660     *) AC_CHECK_LIB(inet, connect) ;;
 661     esac
 662     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 663     dnl has been cached.
 664     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 665        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 666         # ac_cv_func_connect=yes
 667         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 668         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 669     fi
 670 fi
 671
 672 AC_SEARCH_LIBS(inet_ntop, resolv)
 673
 674 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 675 # accept either iconv_open or libiconv_open, since some include files map
 676 # the former to the latter.
 677 AC_SEARCH_LIBS(iconv_open, iconv)
 678 AC_SEARCH_LIBS(libiconv_open, iconv)
 679
 680 AC_MSG_CHECKING([for iconv declaration])
 681 AC_CACHE_VAL(am_cv_proto_iconv, [
 682     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 683 #include <stdlib.h>
 684 #include <iconv.h>
 685 extern
 686 #ifdef __cplusplus
 687 "C"
 688 #endif
 689 #if defined(__STDC__) || defined(__cplusplus)
 690 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 691 #else
 692 size_t iconv();
 693 #endif
 694 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 695       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 696     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed 's/( /(/'`
 697 AC_MSG_RESULT([$]{ac_t:-
 698          }[$]am_cv_proto_iconv)
 699 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 700                    [Define as const if the declaration of iconv() needs const.])
 701
 702 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 703
 704 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 705
 706 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 707 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 708 #include <sys/socket.h>])
 709
 710 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 711 #   builtin getaddrinfo if one of the defines don't exist
 712 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 713                rsync_cv_HAVE_GETADDR_DEFINES,[
 714                         AC_EGREP_CPP(yes, [
 715                         #include <sys/types.h>
 716                         #include <sys/socket.h>
 717                         #include <netdb.h>
 718                         #ifdef AI_PASSIVE
 719                         yes
 720                         #endif],
 721                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 722                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 723 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 724         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 725         # something else so we must include <netdb.h> to get the
 726         # redefinition.
 727         AC_CHECK_FUNCS(getaddrinfo, ,
 728                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 729                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 730                 #include <sys/socket.h>
 731                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 732                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 733                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 734                         AC_LIBOBJ([getaddrinfo])])])
 735     ],[AC_LIBOBJ([getaddrinfo])])
 736
 737 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 738                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 739                 [],
 740                 [
 741 #include <sys/types.h>
 742 #include <sys/socket.h>
 743 ])
 744
 745 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 746                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 747                 [],
 748                 [
 749 #include <sys/types.h>
 750 #include <sys/socket.h>
 751 #include <netinet/in.h>
 752 ])
 753
 754 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 755                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 756                 [],
 757                 [
 758 #include <sys/types.h>
 759 #include <sys/socket.h>
 760 #include <netinet/in.h>
 761 ])
 762
 763 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 764                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 765                 [],
 766                 [
 767 #include <sys/types.h>
 768 #include <sys/socket.h>
 769 #include <netinet/in.h>
 770 ])
 771
 772 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 773 #if HAVE_SYS_TYPES_H
 774 # include <sys/types.h>
 775 #endif
 776 #if HAVE_SYS_STAT_H
 777 # include <sys/stat.h>
 778 #endif
 779 #if STDC_HEADERS
 780 # include <stdlib.h>
 781 # include <stddef.h>
 782 #else
 783 # if HAVE_STDLIB_H
 784 #  include <stdlib.h>
 785 # endif
 786 #endif
 787 ])
 788
 789 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 790 #
 791 AC_CHECK_FUNCS(strcasecmp)
 792 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 793     AC_CHECK_LIB(resolv, strcasecmp)
 794 fi
 795
 796 AC_CHECK_FUNCS(aclsort)
 797 if test x"$ac_cv_func_aclsort" = x"no"; then
 798     AC_CHECK_LIB(sec, aclsort)
 799 fi
 800
 801 dnl At the moment we don't test for a broken memcmp(), because all we
 802 dnl need to do is test for equality, not comparison, and it seems that
 803 dnl every platform has a memcmp that can do at least that.
 804 dnl AC_FUNC_MEMCMP
 805
 806 AC_FUNC_UTIME_NULL
 807 AC_FUNC_ALLOCA
 808 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 809     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 810     chflags getattrlist \
 811     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 812     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 813     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 814     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 815     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 816     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep)
 817
 818 dnl cygwin iconv.h defines iconv_open as libiconv_open
 819 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 820     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 821 fi
 822
 823 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 824
 825 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 826 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 827 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 828 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 829     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 830 fi
 831
 832 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 833 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 834         #define _GNU_SOURCE 1
 835         #include <linux/falloc.h>
 836         #ifndef FALLOC_FL_PUNCH_HOLE
 837         #error FALLOC_FL_PUNCH_HOLE is missing
 838         #endif
 839     ]])], [
 840         AC_MSG_RESULT([yes])
 841         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 842     ], [
 843         AC_MSG_RESULT([no])
 844     ]
 845 )
 846
 847 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 848 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 849         #define _GNU_SOURCE 1
 850         #include <linux/falloc.h>
 851         #ifndef FALLOC_FL_ZERO_RANGE
 852         #error FALLOC_FL_ZERO_RANGE is missing
 853         #endif
 854     ]])], [
 855         AC_MSG_RESULT([yes])
 856         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 857     ], [
 858         AC_MSG_RESULT([no])
 859     ]
 860 )
 861
 862 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 863 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 864 #include <unistd.h>
 865 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 866 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 867     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 868 fi
 869
 870 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 871     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 872     case $host_os in
 873     *cygwin*)
 874         AC_MSG_RESULT(yes)
 875         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 876                   [Define if posix_fallocate is efficient (Cygwin)])
 877         ;;
 878     *)
 879         AC_MSG_RESULT(no)
 880         ;;
 881     esac
 882 fi
 883
 884 dnl End of preallocation stuff
 885
 886 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 887 if test $ac_cv_func_getpgrp = yes; then
 888     AC_FUNC_GETPGRP
 889 fi
 890
 891 AC_ARG_ENABLE(iconv-open,
 892     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 893     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 894
 895 if test x"$enable_iconv_open" != x"no"; then
 896     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 897 fi
 898
 899 AC_ARG_ENABLE(iconv,
 900     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 901     [], [enable_iconv=$enable_iconv_open])
 902 AH_TEMPLATE([ICONV_OPTION],
 903 [Define if you want the --iconv option.  Specifying a value will set the
 904 default iconv setting (a NULL means no --iconv processing by default).])
 905 if test x"$enable_iconv" != x"no"; then
 906         if test x"$enable_iconv" = x"yes"; then
 907                 AC_DEFINE(ICONV_OPTION, NULL)
 908         else
 909                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 910         fi
 911         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 912 fi
 913
 914 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 915   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 916 #if HAVE_UNISTD_H
 917 # include <unistd.h>
 918 #endif
 919 #include <stdlib.h>
 920 #include <errno.h>
 921 int main(void) {
 922         char const *dangling_symlink = "conftest.dangle";
 923         unlink(dangling_symlink);
 924         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 925         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 926         return 0;
 927     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 928 if test $rsync_cv_chown_modifies_symlink = yes; then
 929   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 930 fi
 931
 932 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 933   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 934 #if HAVE_UNISTD_H
 935 # include <unistd.h>
 936 #endif
 937 #include <stdlib.h>
 938 #include <errno.h>
 939 #define FILENAME "conftest.dangle"
 940 int main(void) {
 941         unlink(FILENAME);
 942         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 943         unlink(FILENAME "2");
 944         if (link(FILENAME, FILENAME "2") < 0) return 1;
 945         return 0;
 946     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 947 if test $rsync_cv_can_hardlink_symlink = yes; then
 948   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 949 fi
 950
 951 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 952   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 953 #if HAVE_UNISTD_H
 954 # include <unistd.h>
 955 #endif
 956 #ifdef HAVE_SYS_STAT_H
 957 #include <sys/stat.h>
 958 #endif
 959 #include <stdlib.h>
 960 #include <errno.h>
 961 #define FILENAME "conftest.fifi"
 962 int main(void) {
 963         unlink(FILENAME);
 964         if (mkfifo(FILENAME, 0777) < 0) abort();
 965         unlink(FILENAME "2");
 966         if (link(FILENAME, FILENAME "2") < 0) return 1;
 967         return 0;
 968     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 969 if test $rsync_cv_can_hardlink_special = yes; then
 970     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 971 fi
 972
 973 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 974 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 975 #include <sys/types.h>
 976 #include <sys/socket.h>
 977
 978 int main(void) {
 979        int fd[2];
 980        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
 981 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 982 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 983     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 984 fi
 985
 986 AC_REPLACE_FUNCS([getpass])
 987
 988 if test x"$with_included_popt" != x"yes"; then
 989     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 990 fi
 991 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 992     # If the system has /usr/include/popt/popt.h, we enable the
 993     # included popt because an attempt to "#include <popt/popt.h>"
 994     # would use our included header file anyway (due to -I.), and
 995     # might conflict with the system popt.
 996     with_included_popt=yes
 997 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 998     with_included_popt=yes
 999 fi
1000
1001 AC_MSG_CHECKING([whether to use included libpopt])
1002 if test x"$with_included_popt" = x"yes"; then
1003     AC_MSG_RESULT($srcdir/popt)
1004     BUILD_POPT='$(popt_OBJS)'
1005     CFLAGS="-I$srcdir/popt $CFLAGS"
1006     if test x"$ALLOCA" != x
1007     then
1008         # this can be removed when/if we add an included alloca.c;
1009         #  see autoconf documentation on AC_FUNC_ALLOCA
1010         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
1011     fi
1012 else
1013     AC_MSG_RESULT(no)
1014 fi
1015
1016 # We default to using our zlib unless --with-included-zlib=no is given.
1017 if test x"$with_included_zlib" != x"no"; then
1018     with_included_zlib=yes
1019 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
1020     with_included_zlib=yes
1021 fi
1022 if test x"$with_included_zlib" != x"yes"; then
1023     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
1024 fi
1025
1026 AC_MSG_CHECKING([whether to use included zlib])
1027 if test x"$with_included_zlib" = x"yes"; then
1028     AC_MSG_RESULT($srcdir/zlib)
1029     BUILD_ZLIB='$(zlib_OBJS)'
1030     CFLAGS="-I$srcdir/zlib $CFLAGS"
1031 else
1032     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
1033     AC_MSG_RESULT(no)
1034 fi
1035
1036 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
1037 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
1038 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
1039     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
1040 fi
1041
1042 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
1043 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
1044 #include <dirent.h>
1045 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
1046 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
1047 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
1048 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
1049     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
1050 fi
1051
1052 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
1053 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1054 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
1055 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
1056     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
1057 fi
1058
1059 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1060 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1061 #include <unistd.h>]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1062 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1063     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1064 fi
1065
1066 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1067 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1068 #include <sys/types.h>
1069 #include <stdarg.h>
1070 #include <stdio.h>
1071 #include <stdlib.h>
1072 #include <string.h>
1073 void foo(const char *format, ...) {
1074        va_list ap;
1075        int len;
1076        static char buf[] = "12345678901234567890";
1077
1078        va_start(ap, format);
1079        len = vsnprintf(0, 0, format, ap);
1080        va_end(ap);
1081        if (len != 5) exit(1);
1082
1083        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1084 }
1085 int main(void) { foo("hello"); return 0; }
1086 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1087 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1088     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1089 fi
1090
1091
1092 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1093 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1094 #include <sys/types.h>
1095 #include <sys/stat.h>
1096 #include <unistd.h>
1097 int main(void) {
1098   struct stat st;
1099   char tpl[20]="/tmp/test.XXXXXX";
1100   int fd = mkstemp(tpl);
1101   if (fd == -1) return 1;
1102   unlink(tpl);
1103   if (fstat(fd, &st) != 0) return 1;
1104   if ((st.st_mode & 0777) != 0600) return 1;
1105   return 0;
1106 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1107 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1108     case $host_os in
1109     hpux*)
1110         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1111         dnl so we noisily skip using it.  See HP change request JAGaf34426
1112         dnl for details. (sbonds)
1113         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1114         ;;
1115     *)
1116         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1117         ;;
1118     esac
1119 fi
1120
1121
1122 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1123 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1124 #include <stdio.h>
1125 #include <sys/stat.h>
1126 #include <errno.h>
1127 #if HAVE_UNISTD_H
1128 # include <unistd.h>
1129 #endif
1130 int main(void) { int rc, ec; char *fn = "fifo-test";
1131 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1132 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1133 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1134 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1135     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1136 fi
1137
1138 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1139 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1140 #include <stdio.h>
1141 #include <sys/stat.h>
1142 #include <errno.h>
1143 #if HAVE_UNISTD_H
1144 # include <unistd.h>
1145 #endif
1146 int main(void) { int rc, ec; char *fn = "sock-test";
1147 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1148 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1149 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1150 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1151     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1152 fi
1153
1154 #
1155 # The following test was mostly taken from the tcl/tk plus patches
1156 #
1157 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1158 rm -rf conftest*
1159 cat > conftest.$ac_ext <<EOF
1160 int main(void) { return 0; }
1161 EOF
1162 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1163 if test -f conftest..o; then
1164     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1165 else
1166     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1167 fi
1168 rm -rf conftest*
1169 ])
1170 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1171     OBJ_SAVE="#"
1172     OBJ_RESTORE="#"
1173     CC_SHOBJ_FLAG='-o $@'
1174 else
1175     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1176     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1177     CC_SHOBJ_FLAG=""
1178 fi
1179
1180 AC_SUBST(OBJ_SAVE)
1181 AC_SUBST(OBJ_RESTORE)
1182 AC_SUBST(CC_SHOBJ_FLAG)
1183 AC_SUBST(BUILD_POPT)
1184 AC_SUBST(BUILD_ZLIB)
1185 AC_SUBST(MAKE_MAN)
1186
1187 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1188 #################################################
1189 # check for ACL support
1190
1191 AC_MSG_CHECKING([whether to support ACLs])
1192 AC_ARG_ENABLE(acl-support,
1193         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
1194
1195 if test x"$enable_acl_support" = x"no"; then
1196     AC_MSG_RESULT(no)
1197 else
1198     case "$host_os" in
1199     *sysv5*)
1200         AC_MSG_RESULT(Using UnixWare ACLs)
1201         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1202         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1203         ;;
1204     solaris*)
1205         AC_MSG_RESULT(Using solaris ACLs)
1206         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1207         AC_DEFINE(SUPPORT_ACLS, 1)
1208         ;;
1209     *hpux*)
1210         AC_MSG_RESULT(Using HPUX ACLs)
1211         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1212         AC_DEFINE(SUPPORT_ACLS, 1)
1213         ;;
1214     *irix*)
1215         AC_MSG_RESULT(Using IRIX ACLs)
1216         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1217         AC_DEFINE(SUPPORT_ACLS, 1)
1218         ;;
1219     *aix*)
1220         AC_MSG_RESULT(Using AIX ACLs)
1221         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1222         AC_DEFINE(SUPPORT_ACLS, 1)
1223         ;;
1224     *osf*)
1225         AC_MSG_RESULT(Using Tru64 ACLs)
1226         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1227         AC_DEFINE(SUPPORT_ACLS, 1)
1228         LIBS="$LIBS -lpacl"
1229         ;;
1230     darwin*)
1231         AC_MSG_RESULT(Using OS X ACLs)
1232         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1233         AC_DEFINE(SUPPORT_ACLS, 1)
1234         ;;
1235     *)
1236         AC_MSG_RESULT(running tests:)
1237         AC_CHECK_LIB(acl,acl_get_file)
1238         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1239             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1240 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1241         AC_MSG_CHECKING(ACL test results)
1242         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1243             AC_MSG_RESULT(Using posix ACLs)
1244             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1245             AC_DEFINE(SUPPORT_ACLS, 1)
1246             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1247                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1248 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1249             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1250                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1251             fi
1252         else
1253             if test x"$enable_acl_support" = x"yes"; then
1254                 AC_MSG_ERROR(Failed to find ACL support)
1255             else
1256                 AC_MSG_RESULT(No ACL support found)
1257             fi
1258         fi
1259         ;;
1260     esac
1261 fi
1262
1263 #################################################
1264 # check for extended attribute support
1265 AC_MSG_CHECKING(whether to support extended attributes)
1266 AC_ARG_ENABLE(xattr-support,
1267     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1268     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1269         *yes*) enable_xattr_support=maybe ;;
1270         *) enable_xattr_support=no ;;
1271         esac])
1272 AH_TEMPLATE([SUPPORT_XATTRS],
1273 [Define to 1 to add support for extended attributes])
1274 if test x"$enable_xattr_support" = x"no"; then
1275     AC_MSG_RESULT(no)
1276 else
1277     case "$host_os" in
1278     *linux*|*netbsd*)
1279         AC_MSG_RESULT(Using Linux xattrs)
1280         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1281         AC_DEFINE(SUPPORT_XATTRS, 1)
1282         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1283         AC_CHECK_LIB(attr,getxattr)
1284         ;;
1285     darwin*)
1286         AC_MSG_RESULT(Using OS X xattrs)
1287         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1288         AC_DEFINE(SUPPORT_XATTRS, 1)
1289         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1290         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1291         ;;
1292     freebsd*)
1293         AC_MSG_RESULT(Using FreeBSD extattrs)
1294         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1295         AC_DEFINE(SUPPORT_XATTRS, 1)
1296         ;;
1297     solaris*)
1298         AC_MSG_RESULT(Using Solaris xattrs)
1299         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1300         AC_DEFINE(SUPPORT_XATTRS, 1)
1301         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1302         ;;
1303     *)
1304         if test x"$enable_xattr_support" = x"yes"; then
1305             AC_MSG_ERROR(Failed to find extended attribute support)
1306         else
1307             AC_MSG_RESULT(No extended attribute support found)
1308         fi
1309         ;;
1310     esac
1311 fi
1312
1313 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1314     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1315     OLD_CFLAGS="$CFLAGS"
1316     CFLAGS="$CFLAGS -Wno-unused-parameter"
1317     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1318     AC_MSG_RESULT([$rsync_warn_flag])
1319     if test x"$rsync_warn_flag" = x"no"; then
1320         CFLAGS="$OLD_CFLAGS"
1321     fi
1322 fi
1323
1324 case "$CC" in
1325 ' checker'*|checker*)
1326     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1327     ;;
1328 esac
1329
1330 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1331 AC_OUTPUT
1332
1333 AC_MSG_RESULT()
1334 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1335 AC_MSG_RESULT()