sysdeps/powerpc/powerpc64/fpu/s_floorf.S

   1 /* float Floor function.  PowerPC64 version.
   2    Copyright (C) 2004-2013 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21         .section        ".toc","aw"
  22 .LC0:   /* 2**23 */
  23         .tc FD_4b000000_0[TC],0x4b00000000000000
  24         .section        ".text"
  25
  26 EALIGN (__floorf, 4, 0)
  27         CALL_MCOUNT 0
  28         mffs    fp11            /* Save current FPU rounding mode.  */
  29         lfs     fp13,.LC0@toc(2)
  30         fabs    fp0,fp1
  31         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  32         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  33         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  34         bnllr-  cr7
  35         mtfsfi  7,3             /* Set rounding mode toward -inf.  */
  36         ble-    cr6,.L4
  37         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  38         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  39         fabs    fp1,fp1         /* if (x == 0.0)  */
  40                                 /* x = 0.0; */
  41         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  42         blr
  43 .L4:
  44         bge-    cr6,.L9         /* if (x < 0.0)  */
  45         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  46         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  47         fnabs   fp1,fp1         /* if (x == 0.0)  */
  48                                 /* x = -0.0; */
  49 .L9:
  50         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  51         blr
  52         END (__floorf)
  53
  54 weak_alias (__floorf, floorf)
  55