sysdeps/i386/fpu/s_frexp.S

   1 /* ix87 specific frexp implementation for double.
   2    Copyright (C) 1997-2013 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1997.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <machine/asm.h>
  21 #include "bp-sym.h"
  22 #include "bp-asm.h"
  23
  24         .section .rodata
  25
  26         .align ALIGNARG(4)
  27         .type two54,@object
  28 two54:  .byte 0, 0, 0, 0, 0, 0, 0x50, 0x43
  29         ASM_SIZE_DIRECTIVE(two54)
  30
  31 #ifdef PIC
  32 #define MO(op) op##@GOTOFF(%edx)
  33 #else
  34 #define MO(op) op
  35 #endif
  36
  37 #define PARMS   LINKAGE         /* no space for saved regs */
  38 #define VAL0    PARMS
  39 #define VAL1    VAL0+4
  40 #define EXPP    VAL1+4
  41
  42         .text
  43 ENTRY (BP_SYM (__frexp))
  44         ENTER
  45
  46         movl    VAL0(%esp), %ecx
  47         movl    VAL1(%esp), %eax
  48         movl    %eax, %edx
  49         andl    $0x7fffffff, %eax
  50         orl     %eax, %ecx
  51         jz      1f
  52         xorl    %ecx, %ecx
  53         cmpl    $0x7ff00000, %eax
  54         jae     1f
  55
  56         cmpl    $0x00100000, %eax
  57         jae     2f
  58
  59         fldl    VAL0(%esp)
  60 #ifdef  PIC
  61         LOAD_PIC_REG (dx)
  62 #endif
  63         fmull   MO(two54)
  64         movl    $-54, %ecx
  65         fstpl   VAL0(%esp)
  66         fwait
  67         movl    VAL1(%esp), %eax
  68         movl    %eax, %edx
  69         andl    $0x7fffffff, %eax
  70
  71 2:      shrl    $20, %eax
  72         andl    $0x800fffff, %edx
  73         subl    $1022, %eax
  74         orl     $0x3fe00000, %edx
  75         addl    %eax, %ecx
  76         movl    %edx, VAL1(%esp)
  77
  78         /* Store %ecx in the variable pointed to by the second argument,
  79            get the factor from the stack and return.  */
  80 1:      movl    EXPP(%esp), %eax
  81         CHECK_BOUNDS_BOTH_WIDE (%eax, EXPP(%esp), $4)
  82         fldl    VAL0(%esp)
  83         movl    %ecx, (%eax)
  84
  85         LEAVE
  86         ret
  87 END (BP_SYM (__frexp))
  88 weak_alias (BP_SYM (__frexp), BP_SYM (frexp))