source4/heimdal/cf/aix.m4

   1 dnl
   2 dnl $Id$
   3 dnl
   4
   5 AC_DEFUN([rk_AIX],[
   6
   7 aix=no
   8 case "$host" in
   9 *-*-aix3*)
  10         aix=3
  11         ;;
  12 *-*-aix[[4-9]]*)
  13         aix=4
  14         ;;
  15 esac
  16
  17 AM_CONDITIONAL(AIX, test "$aix" != no)dnl
  18 AM_CONDITIONAL(AIX4, test "$aix" = 4)dnl
  19
  20 AC_ARG_ENABLE(dynamic-afs,
  21         AS_HELP_STRING([--disable-dynamic-afs],
  22                 [do not use loaded AFS library with AIX]))
  23
  24 if test "$aix" != no; then
  25
  26         AC_DEFINE(NEED_QSORT, 1, [if your qsort is not a stable sort])
  27
  28         if test "$enable_dynamic_afs" != no; then
  29                 AC_REQUIRE([rk_DLOPEN])
  30                 if test "$ac_cv_func_dlopen" = no; then
  31                         AC_FIND_FUNC_NO_LIBS(loadquery, ld)
  32                 fi
  33                 if test "$ac_cv_func_dlopen" != no; then
  34                         AIX_EXTRA_KAFS='$(LIB_dlopen)'
  35                 elif test "$ac_cv_func_loadquery" != no; then
  36                         AIX_EXTRA_KAFS='$(LIB_loadquery)'
  37                 else
  38                         AC_MSG_NOTICE([not using dynloaded AFS library])
  39                         AIX_EXTRA_KAFS=
  40                         enable_dynamic_afs=no
  41                 fi
  42         else
  43                 AIX_EXTRA_KAFS=
  44         fi
  45 fi
  46
  47 AM_CONDITIONAL(AIX_DYNAMIC_AFS, test "$enable_dynamic_afs" != no)dnl
  48 AC_SUBST(AIX_EXTRA_KAFS)dnl
  49
  50 if test "$aix" != no; then
  51         AC_DEFINE([_ALL_SOURCE],1,[Required for functional/sane headers on AIX])
  52 fi
  53
  54 AH_BOTTOM([#if _AIX
  55 /* XXX this is gross, but kills about a gazillion warnings */
  56 struct ether_addr;
  57 struct sockaddr;
  58 struct sockaddr_dl;
  59 struct sockaddr_in;
  60 #endif])
  61
  62 ])