configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.53)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT([GNU C Library], [(see version.h)], [glibc])
   5 AC_CONFIG_SRCDIR([include/features.h])
   6 AC_CONFIG_HEADERS([config.h])
   7 AC_CONFIG_AUX_DIR([scripts])
   8
   9 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
  10   AC_MSG_ERROR([you must configure in a separate build directory])
  11 fi
  12
  13 # This will get text that should go into config.make.
  14 config_vars=
  15
  16 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  17 AC_ARG_WITH([gmp],
  18             AC_HELP_STRING([--with-gmp=DIRECTORY],
  19                            [find GMP source code in DIRECTORY (not needed)]),
  20             [
  21 case "$with_gmp" in
  22 yes) AC_MSG_ERROR([--with-gmp requires an argument; use --with-gmp=DIRECTORY]) ;;
  23 ''|no) ;;
  24 *) config_vars="$config_vars
  25 gmp-srcdir = $withval" ;;
  26 esac
  27 ])
  28 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  29 AC_ARG_WITH([gd],
  30             AC_HELP_STRING([--with-gd=DIR],
  31                            [find libgd include dir and library with prefix DIR]),
  32             [dnl
  33 case "$with_gd" in
  34 yes|''|no) ;;
  35 *) libgd_include="-I$withval/include"
  36    libgd_ldflags="-L$withval/lib" ;;
  37 esac
  38 ])
  39 AC_ARG_WITH([gd-include],
  40             AC_HELP_STRING([--with-gd-include=DIR],
  41                            [find libgd include files in DIR]),
  42             [dnl
  43 case "$with_gd_include" in
  44 ''|no) ;;
  45 *) libgd_include="-I$withval" ;;
  46 esac
  47 ])
  48 AC_ARG_WITH([gd-lib],
  49             AC_HELP_STRING([--with-gd-lib=DIR],
  50                            [find libgd library files in DIR]),
  51             [dnl
  52 case "$with_gd_lib" in
  53 ''|no) ;;
  54 *) libgd_ldflags="-L$withval" ;;
  55 esac
  56 ])
  57
  58 if test -n "$libgd_include"; then
  59   config_vars="$config_vars
  60 CFLAGS-memusagestat.c = $libgd_include"
  61 fi
  62 if test -n "$libgd_ldflags"; then
  63   config_vars="$config_vars
  64 libgd-LDFLAGS = $libgd_ldflags"
  65 fi
  66
  67 dnl Arguments to specify presence of other packages/features.
  68 AC_ARG_WITH([fp],
  69             AC_HELP_STRING([--with-fp],
  70                            [if using floating-point hardware @<:@default=yes@:>@]),
  71             [with_fp=$withval],
  72             [with_fp=yes])
  73 AC_SUBST(with_fp)
  74 AC_ARG_WITH([binutils],
  75             AC_HELP_STRING([--with-binutils=PATH],
  76                            [specify location of binutils (as and ld)]),
  77             [path_binutils=$withval],
  78             [path_binutils=''])
  79 AC_ARG_WITH([elf],
  80             AC_HELP_STRING([--with-elf],
  81                            [if using the ELF object format]),
  82             [elf=$withval],
  83             [elf=no])
  84 AC_ARG_WITH([xcoff],
  85             AC_HELP_STRING([--with-xcoff],
  86                            [if using the XCOFF object format]),
  87             [xcoff=$withval],
  88             [xcoff=no])
  89 AC_ARG_WITH([cvs],
  90             AC_HELP_STRING([--without-cvs],
  91                            [if CVS should not be used]),
  92             [with_cvs=$withval],
  93             [with_cvs=yes])
  94 if test "$with_cvs" = yes; then
  95   if test -d $srcdir/CVS && grep :pserver: $srcdir/CVS/Root > /dev/null
  96   then
  97     with_cvs=no
  98   fi
  99 fi
 100 AC_SUBST(with_cvs)
 101
 102 AC_ARG_WITH([headers],
 103             AC_HELP_STRING([--with-headers=PATH],
 104                            [location of system headers to use
 105                             (for example /usr/src/linux/include)
 106                             @<:@default=compiler default@:>@]),
 107             [sysheaders=$withval],
 108             [sysheaders=''])
 109
 110 AC_ARG_ENABLE([sanity-checks],
 111               AC_HELP_STRING([--disable-sanity-checks],
 112                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 113               [enable_sanity=$enableval],
 114               [enable_sanity=yes])
 115
 116 dnl Arguments to enable or disable building the static, shared, profiled,
 117 dnl and -fomit-frame-pointer libraries.
 118 dnl I've disabled this for now since we cannot build glibc without static
 119 dnl libraries built in the moment.
 120 dnl AC_ARG_ENABLE([static],
 121 dnl               AC_HELP_STRING([--enable-static],
 122 dnl                              [build static library @<:@default=yes@:>@]),
 123 dnl               [static=$enableval],
 124 dnl               [static=yes])
 125 static=yes
 126 AC_ARG_ENABLE([shared],
 127               AC_HELP_STRING([--enable-shared],
 128                              [build shared library @<:@default=yes if GNU ld & ELF@:>@]),
 129               [shared=$enableval],
 130               [shared=default])
 131 AC_ARG_ENABLE([profile],
 132               AC_HELP_STRING([--enable-profile],
 133                              [build profiled library @<:@default=yes@:>@]),
 134               [profile=$enableval],
 135               [profile=yes])
 136 AC_ARG_ENABLE([omitfp],
 137               AC_HELP_STRING([--enable-omitfp],
 138                              [build undebuggable optimized library @<:@default=no@:>@]),
 139               [omitfp=$enableval],
 140               [omitfp=no])
 141 AC_ARG_ENABLE([bounded],
 142               AC_HELP_STRING([--enable-bounded],
 143                              [build with runtime bounds checking @<:@default=no@:>@]),
 144               [bounded=$enableval],
 145               [bounded=no])
 146 AC_ARG_ENABLE([versioning],
 147               AC_HELP_STRING([--disable-versioning],
 148                              [do not include versioning information in the library objects @<:@default=yes if supported@:>@]),
 149               [enable_versioning=$enableval],
 150               [enable_versioning=yes])
 151
 152 AC_ARG_ENABLE([oldest-abi],
 153               AC_HELP_STRING([--enable-oldest-abi=ABI],
 154                              [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
 155               [oldest_abi=$enableval],
 156               [oldest_abi=no])
 157 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
 158   oldest_abi=default
 159 else
 160   AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
 161 fi
 162 AC_SUBST(oldest_abi)
 163
 164 dnl Generic infrastructure for drop-in additions to libc.
 165 AC_ARG_ENABLE([add-ons],
 166               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 167                              [configure and build add-ons in DIR1,DIR2,...  search for add-ons if no parameter given]),
 168   [case "$enableval" in
 169     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 170          test "$add_ons" = "*" && add_ons= ;;
 171     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 172    esac],
 173   [add_ons=])
 174
 175 dnl Let the user avoid using TLS.  Don't know why but...
 176 dnl XXX For now we disable support by default.
 177 AC_ARG_WITH([tls],
 178             AC_HELP_STRING([--with-tls],
 179                            [enable support for TLS]),
 180             [usetls=$withval],
 181             [usetls=no])
 182
 183 AC_ARG_WITH([__thread],
 184             AC_HELP_STRING([--without-__thread],
 185                            [do not use TLS features even when supporting them]),
 186             [use__thread=$withval],
 187             [use__thread=yes])
 188
 189 AC_ARG_ENABLE([hidden-plt],
 190               AC_HELP_STRING([--disable-hidden-plt],
 191                              [do not hide internal function calls to avoid PLT]),
 192               [hidden=$enableval],
 193               [hidden=yes])
 194 if test "x$hidden" = xno; then
 195   AC_DEFINE(NO_HIDDEN)
 196 fi
 197
 198 AC_CONFIG_SUBDIRS([ ])dnl Bonehead new Autoconf whines if we do it cleanly.
 199 add_ons_pfx=
 200 if test x"$add_ons" != x; then
 201   for f in $add_ons; do
 202     # Some sanity checks
 203     if test "$f" = "crypt"; then
 204       AC_MSG_ERROR([
 205 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 206 *** part of glibc and using the old add-on will not work with this
 207 *** release.  Start again with fresh sources and without the old
 208 *** \`crypt' add-on.])
 209     fi
 210     if test "$f" = "localedata"; then
 211       AC_MSG_ERROR([
 212 *** It seems that you're using an old \`localedata' add-on.  localedata
 213 *** is now part of glibc and using the old add-on will not work with
 214 *** this release.  Start again with fresh sources and without the old
 215 *** \`localedata' add-on.])
 216     fi
 217     # Test whether such a subdir really exists.
 218     if test -d $srcdir/$f; then
 219       add_ons_pfx="$add_ons_pfx $f/"
 220       dnl This variable is what AC_CONFIG_SUBDIRS is supposed to set,
 221       dnl but the new Autoconf maintainers don't care about compatibility
 222       dnl so we cannot use it normally any more without complaints.
 223       subdirs="$subdirs $f"
 224     else
 225       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 226     fi
 227   done
 228 fi
 229
 230 dnl On some platforms we cannot use dynamic loading.  We must provide
 231 dnl static NSS modules.
 232 AC_ARG_ENABLE([static-nss],
 233               AC_HELP_STRING([--enable-static-nss],
 234                              [build static NSS modules @<:@default=no@:>@]),
 235               [static_nss=$enableval],
 236               [static_nss=no])
 237 dnl Enable static NSS also if we build no shared objects.
 238 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 239   static_nss=yes
 240   AC_DEFINE(DO_STATIC_NSS)
 241 fi
 242
 243 AC_ARG_ENABLE([force-install],
 244               AC_HELP_STRING([--disable-force-install],
 245                              [don't force installation of files from this package, even if they are older than the installed files]),
 246               [force_install=$enableval],
 247               [force_install=yes])
 248 AC_SUBST(force_install)
 249
 250 dnl On some platforms we allow dropping compatibility with all kernel
 251 dnl versions.
 252 AC_ARG_ENABLE([kernel],
 253               AC_HELP_STRING([--enable-kernel=VERSION],
 254                              [compile for compatibility with kernel not older than VERSION]),
 255               [minimum_kernel=$enableval],
 256               [])
 257 dnl Prevent unreasonable values.
 258 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 259   # Better nothing than this.
 260   minimum_kernel=""
 261 else
 262   if test "$minimum_kernel" = current; then
 263     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 264   fi
 265 fi
 266
 267 dnl For the development we sometimes want gcc to issue even more warnings.
 268 dnl This is not the default since many of the extra warnings are not
 269 dnl appropriate.
 270 AC_ARG_ENABLE([all-warnings],
 271               AC_HELP_STRING([--enable-all-warnings],
 272                              [enable all useful warnings gcc can issue]),
 273               [all_warnings=$enableval],
 274               [])
 275 AC_SUBST(all_warnings)
 276
 277 AC_CANONICAL_HOST
 278
 279 # The way shlib-versions is used to generate soversions.mk uses a
 280 # fairly simplistic model for name recognition that can't distinguish
 281 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 282 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 283 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 284 case "$host_os" in
 285 linux*)
 286   ;;
 287 gnu*)
 288   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 289   ;;
 290 esac
 291
 292 # We keep the original values in `$config_*' and never modify them, so we
 293 # can write them unchanged into config.make.  Everything else uses
 294 # $machine, $vendor, and $os, and changes them whenever convenient.
 295 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 296
 297 # Don't allow vendor == "unknown"
 298 test "$config_vendor" = unknown && config_vendor=
 299 config_os="`echo $config_os | sed 's/^unknown-//'`"
 300
 301 # Some configurations imply other options.
 302 case "$host_os" in
 303 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 304   # These systems always use GNU tools.
 305   gnu_ld=yes gnu_as=yes ;;
 306 esac
 307 case "$host_os" in
 308 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 309 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 310   ;;
 311 gnu* | linux* | freebsd* | netbsd* | sysv4* | solaris2* | irix6*)
 312   # These systems (almost) always use the ELF format.
 313   elf=yes
 314   ;;
 315 aix*)
 316   # These systems are always xcoff
 317   xcoff=yes
 318   elf=no
 319   ;;
 320 esac
 321
 322 machine=$config_machine
 323 vendor=$config_vendor
 324 os=$config_os
 325
 326 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 327 # Unify this here.
 328 if test "$machine" = rs6000; then
 329   machine="powerpc"
 330 fi
 331
 332 # Braindead PowerPC box with absolutely no FPU.
 333 case "$machine-$host_os" in
 334   powerpc*-*soft)
 335     with_fp=no
 336     ;;
 337 esac
 338
 339 ###
 340 ### I put this here to prevent those annoying emails from people who cannot
 341 ### read and try to compile glibc on unsupported platforms.  --drepper
 342 ###
 343 ### By using the undocumented --enable-hacker-mode option for configure
 344 ### one can skip this test to make the configuration not fail for unsupported
 345 ### platforms.
 346 ###
 347 if test -z "$enable_hacker_mode"; then
 348   case "$machine-$host_os" in
 349   *-linux* | *-gnu* | arm*-none* | powerpc-aix4.3.*)
 350     ;;
 351   *)
 352     echo "*** The GNU C library is currently not available for this platform."
 353     echo "*** So far nobody cared to port it and if there is no volunteer it"
 354     echo "*** might never happen.  So, if you have interest to see glibc on"
 355     echo "*** this platform visit"
 356     echo "***   http://www.gnu.org/software/libc/porting.html"
 357     echo "*** and join the group of porters"
 358     exit 1
 359     ;;
 360   esac
 361 fi
 362
 363 dnl We need to use [ and ] for other purposes for a while now.
 364 changequote(,)dnl
 365 # Expand the configuration machine name into a subdirectory by architecture
 366 # type and particular chip.
 367 case "$machine" in
 368 a29k | am29000) base_machine=a29k machine=a29k ;;
 369 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 370 arm*)           base_machine=arm machine=arm/arm32/$machine ;;
 371 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 372 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 373 hppa*64*)       base_machine=hppa machine=hppa/hppa64 ;;
 374 hppa*)          base_machine=hppa machine=hppa/hppa1.1 ;;
 375 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 376 ia64)           base_machine=ia64 machine=ia64 ;;
 377 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 378 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 379 m88???)         base_machine=m88k machine=m88k/$machine ;;
 380 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 381 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 382 mips*)          base_machine=mips machine=mips/$machine ;;
 383 powerpc)        base_machine=powerpc machine=powerpc/powerpc32 ;;
 384 powerpc64)      base_machine=powerpc machine=powerpc/powerpc64 ;;
 385 s390)           base_machine=s390 machine=s390/s390-32 ;;
 386 s390x)          base_machine=s390 machine=s390/s390-64 ;;
 387 sh3*)           base_machine=sh machine=sh/sh3 ;;
 388 sh4*)           base_machine=sh machine=sh/sh4 ;;
 389 sparc | sparcv[67])
 390                 base_machine=sparc machine=sparc/sparc32 ;;
 391 sparcv8 | supersparc | hypersparc)
 392                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 393 sparcv8plus | sparcv8plusa | sparcv9)
 394                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 395 sparcv8plusb | sparcv9b)
 396                 base_machine=sparc machine=sparc/sparc32/sparcv9b ;;
 397 sparc64 | ultrasparc)
 398                 base_machine=sparc machine=sparc/sparc64 ;;
 399 sparc64b | ultrasparc3)
 400                 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
 401 thumb*)         base_machine=thumb machine=arm/thumb/$machine ;;
 402 *)              base_machine=$machine ;;
 403 esac
 404 changequote([,])dnl
 405 AC_SUBST(base_machine)
 406
 407 if test "$base_machine" = "i386"; then
 408   AC_DEFINE(USE_REGPARMS)
 409 fi
 410
 411 # Compute the list of sysdep directories for this configuration.
 412 # This can take a while to compute.
 413 sysdep_dir=$srcdir/sysdeps
 414 AC_MSG_CHECKING(sysdep dirs)
 415 dnl We need to use [ and ] for other purposes for a while now.
 416 changequote(,)dnl
 417 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 418 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 419
 420 case "$os" in
 421 gnu*)
 422   base_os=mach/hurd ;;
 423 netbsd* | 386bsd* | freebsd* | bsdi*)
 424   base_os=unix/bsd/bsd4.4 ;;
 425 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 426   base_os=unix/bsd ;;
 427 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 428   base_os=unix/sysv ;;
 429 irix6*)
 430   base_os=unix/sysv/irix6/$os ;;
 431 solaris[2-9]*)
 432   base_os=unix/sysv/sysv4 ;;
 433 hpux*)
 434   base_os=unix/sysv/hpux/$os ;;
 435 aix4.3*)
 436   base_os=unix/sysv/aix/aix4.3 ;;
 437 none)
 438   base_os=standalone ;;
 439 *)
 440   base_os='' ;;
 441 esac
 442
 443 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 444 tail=$os
 445 ostry=$os
 446 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 447   ostry="$ostry /$o"
 448   tail=$o
 449 done
 450 o=`echo $tail | sed 's/[0-9]*$//'`
 451 if test $o != $tail; then
 452   ostry="$ostry /$o"
 453 fi
 454 # For linux-gnu, try linux-gnu, then linux.
 455 o=`echo $tail | sed 's/-.*$//'`
 456 if test $o != $tail; then
 457   ostry="$ostry /$o"
 458 fi
 459
 460 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 461 base=
 462 tail=$base_os
 463 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 464   set $b
 465   base="$base /$1"
 466   tail="$2"
 467 done
 468
 469 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 470 mach=
 471 tail=$machine
 472 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 473   set $m
 474   # Prepend the machine's FPU directory unless --without-fp.
 475   if test "$with_fp" = yes; then
 476     mach="$mach /$1/fpu"
 477   else
 478     mach="$mach /$1/nofpu"
 479   fi
 480   mach="$mach /$1"
 481   tail="$2"
 482 done
 483
 484 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 485 changequote([,])dnl
 486
 487 # Find what sysdep directories exist.
 488 sysnames=
 489 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 490 for d in $add_ons_pfx ''; do
 491   for b in $base ''; do
 492     for m0 in $mach ''; do
 493       for v in /$vendor ''; do
 494         test "$v" = / && continue
 495         for o in /$ostry ''; do
 496           test "$o" = / && continue
 497           for m in $mach ''; do
 498             if test "$m0$b$v$o$m"; then
 499               try="${d}sysdeps$m0$b$v$o$m"
 500               test -n "$enable_debug_configure" &&
 501               echo "$0 [DEBUG]: try $try" >&2
 502               if test -d $srcdir/$try; then
 503                 sysnames="$sysnames $try"
 504                 { test -n "$o" || test -n "$b"; } && os_used=t
 505                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 506               fi
 507             fi
 508           done
 509         done
 510       done
 511     done
 512   done
 513 done
 514 IFS="$ac_save_ifs"
 515
 516 if test -z "$os_used" && test "$os" != none; then
 517   AC_MSG_ERROR(Operating system $os is not supported.)
 518 fi
 519 if test -z "$machine_used" && test "$machine" != none; then
 520   AC_MSG_ERROR(The $machine is not supported.)
 521 fi
 522
 523 # We have now validated the configuration.
 524
 525
 526 # If using ELF, look for an `elf' subdirectory of each machine directory.
 527 # We prepend these rather than inserting them whereever the machine appears
 528 # because things specified by the machine's ELF ABI should override
 529 # OS-specific things, and should always be the same for any OS on the
 530 # machine (otherwise what's the point of an ABI?).
 531 if test "$elf" = yes; then
 532   elf_dirs=
 533   for d in $add_ons_pfx ''; do
 534     for m in $mach; do
 535       if test -d $srcdir/${d}sysdeps$m/elf; then
 536         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 537       fi
 538     done
 539   done
 540   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 541 fi
 542
 543
 544 # Expand the list of system names into a full list of directories
 545 # from each element's parent name and Implies file (if present).
 546 set $sysnames
 547 names=
 548 while test $# -gt 0; do
 549   name=$1
 550   shift
 551
 552   case " $names " in *" $name "*)
 553     # Already in the list.
 554     continue
 555   esac
 556
 557   # Report each name as we discover it, so there is no long pause in output.
 558   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 559
 560   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 561
 562   case $name in
 563     /*) xsrcdir= ;;
 564     *)  xsrcdir=$srcdir/ ;;
 565   esac
 566   test -n "$enable_debug_configure" &&
 567   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 568
 569   if test -f $xsrcdir$name/Implies; then
 570     # Collect more names from the `Implies' file (removing comments).
 571     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 572     implied=
 573     for x in $implied_candidate; do
 574       found=no
 575       if test -d $xsrcdir$name_base/$x; then
 576         implied="$implied $name_base/$x";
 577         found=yes
 578       fi
 579       for d in $add_ons_pfx ''; do
 580         try="${d}sysdeps/$x"
 581         case $d in
 582          /*) try_srcdir= ;;
 583          *) try_srcdir=$srcdir/ ;;
 584         esac
 585         test -n "$enable_debug_configure" &&
 586          echo "[DEBUG]: $name implied $x try($d) {$try_srcdir}$try" >&2
 587         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 588         then
 589           implied="$implied $try"
 590           found=yes
 591         fi
 592       done
 593       if test $found = no; then
 594         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 595       fi
 596     done
 597   else
 598     implied=
 599   fi
 600
 601   # Add NAME to the list of names.
 602   names="$names $name"
 603
 604   # Find the parent of NAME, using the empty string if it has none.
 605 changequote(,)dnl
 606   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 607 changequote([,])dnl
 608
 609   # Add the names implied by NAME, and NAME's parent (if it has one), to
 610   # the list of names to be processed (the argument list).  We prepend the
 611   # implied names to the list and append the parent.  We want implied
 612   # directories to come before further directories inferred from the
 613   # configuration components; this ensures that for sysv4, unix/common
 614   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 615   # after sysv4).
 616   sysnames="`echo $implied $* $parent`"
 617   test -n "$sysnames" && set $sysnames
 618 done
 619
 620 # Add the default directories.
 621 default_sysnames=sysdeps/generic
 622 if test "$elf" = yes; then
 623   default_sysnames="sysdeps/generic/elf $default_sysnames"
 624 fi
 625 sysnames="$names $default_sysnames"
 626 AC_SUBST(sysnames)
 627 # The other names were emitted during the scan.
 628 AC_MSG_RESULT($default_sysnames)
 629
 630
 631 ### Locate tools.
 632
 633 AC_PROG_INSTALL
 634 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 635   # The makefiles need to use a different form to find it in $srcdir.
 636   INSTALL='\$(..)./scripts/install-sh -c'
 637 fi
 638 AC_PROG_LN_S
 639
 640 # We need the physical current working directory.  We cannot use the
 641 # "pwd -P" shell builtin since that's not portable.  Instead we try to
 642 # find a pwd binary.  Note that assigning to the PWD environment
 643 # variable might have some interesting side effects, so we don't do
 644 # that.
 645 AC_PATH_PROG(PWD_P, pwd, no)
 646 if test "$PWD_P" = no; then
 647   AC_MSG_ERROR(*** A pwd binary could not be found.)
 648 fi
 649
 650 # These programs are version sensitive.
 651 AC_CHECK_TOOL_PREFIX
 652 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 653   [version \([egcygnustpi-]*[0-9.]*\)], [3.[2-9]*],
 654   critic_missing="$critic_missing gcc")
 655 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 656   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 657   [3.79* | 3.[89]*], critic_missing="$critic_missing make")
 658
 659 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 660   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 661   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 662   MSGFMT=: aux_missing="$aux_missing msgfmt")
 663 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 664   [GNU texinfo.* \([0-9][0-9.]*\)],
 665   [4.*],
 666   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 667 AC_CHECK_PROG_VER(SED, sed, --version,
 668   [GNU sed version \([0-9]*\.[0-9.]*\)],
 669   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 670   SED=: aux_missing="$aux_missing sed")
 671
 672 if test "x$with_cvs" != xyes; then
 673   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 674   case "x$AUTOCONF" in
 675   xno|x|x:) AUTOCONF=no ;;
 676   *)
 677     AC_CACHE_CHECK(dnl
 678 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 679     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.in > /dev/null 2>&1); then
 680       libc_cv_autoconf_works=yes
 681     else
 682       libc_cv_autoconf_works=no
 683     fi])
 684     test $libc_cv_autoconf_works = yes || AUTOCONF=no
 685     ;;
 686   esac
 687   test "x$AUTOCONF" != xno || aux_missing="$aux_missing autoconf"
 688 fi
 689
 690 AC_PROG_CC
 691 if test $host != $build; then
 692   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 693 fi
 694 AC_SUBST(cross_compiling)
 695 AC_PROG_CPP
 696 LIBC_PROG_BINUTILS
 697 AC_SUBST(MIG)dnl Needed by sysdeps/mach/configure.in
 698
 699 # Accept binutils 2.13 or newer.
 700 AC_CHECK_PROG_VER(AS, $AS, --version,
 701                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 702                   [2.1[3-9]*], AS=: critic_missing=t)
 703 AC_CHECK_PROG_VER(LD, $LD, --version,
 704                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 705                   [2.1[3-9]*], LD=: critic_missing=t)
 706
 707 test -n "$critic_missing" && AC_MSG_ERROR([
 708 *** These critical programs are missing or too old:$critic_missing
 709 *** Check the INSTALL file for required versions.])
 710
 711 test -n "$aux_missing" && AC_MSG_WARN([
 712 *** These auxiliary programs are missing or incompatible versions:$aux_missing
 713 *** some features will be disabled.
 714 *** Check the INSTALL file for required versions.])
 715
 716 # glibcbug.in wants to know the compiler version.
 717 CCVERSION=`$CC -v 2>&1 | sed -n 's/gcc version //p'`
 718 AC_SUBST(CCVERSION)
 719
 720 # if using special system headers, find out the compiler's sekrit
 721 # header directory and add that to the list.  NOTE: Only does the right
 722 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 723 if test -n "$sysheaders"; then
 724   ccheaders=`$CC -print-file-name=include`
 725   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 726 fi
 727 AC_SUBST(SYSINCLUDES)
 728
 729 # check if ranlib is necessary
 730 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 731 cat > conftest.c <<EOF
 732 int a;
 733 char b;
 734 void c(void) {}
 735 EOF
 736 $CC $CFLAGS -c conftest.c
 737 $AR cr conftest.a conftest.o
 738 cp conftest.a conftest2.a
 739 $RANLIB conftest.a
 740 if cmp -s conftest.a conftest2.a; then
 741   libc_cv_ranlib_necessary=no
 742 else
 743   libc_cv_ranlib_necessary=yes
 744 fi
 745 rm -rf conftest*])
 746 if test "$libc_cv_ranlib_necessary" = no; then
 747  RANLIB=:
 748 fi
 749
 750 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 751 # since this would lead to problems installing/building glibc.
 752 # LD_LIBRARY_PATH contains the current directory if one of the following
 753 # is true:
 754 # - one of the terminals (":" and ";") is the first or last sign
 755 # - two terminals occur directly after each other
 756 # - the path contains an element with a dot in it
 757 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 758 changequote(,)dnl
 759 case ${LD_LIBRARY_PATH} in
 760   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 761     ld_library_path_setting="contains current directory"
 762     ;;
 763   *)
 764     ld_library_path_setting="ok"
 765     ;;
 766 esac
 767 changequote([,])dnl
 768 AC_MSG_RESULT($ld_library_path_setting)
 769 if test "$ld_library_path_setting" != "ok"; then
 770 AC_MSG_ERROR([
 771 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 772 *** building glibc. Please change the environment variable
 773 *** and run configure again.])
 774 fi
 775
 776 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
 777 if $CC -v -static-libgcc 2>&1 | grep -q 'unrecognized option.*static-libgcc'; then
 778   libc_cv_gcc_static_libgcc=
 779 else
 780   libc_cv_gcc_static_libgcc=-static-libgcc
 781 fi])
 782 AC_SUBST(libc_cv_gcc_static_libgcc)
 783
 784 AC_PATH_PROG(BASH, bash, no)
 785 if test "$BASH" != no &&
 786    $BASH -c 'test "$BASH_VERSINFO" \
 787              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 788   libc_cv_have_bash2=yes
 789 else
 790   libc_cv_have_bash2=no
 791 fi
 792 AC_SUBST(libc_cv_have_bash2)
 793
 794 dnl We need a ksh compatible shell for tzselect.
 795 if test "$BASH" = no; then
 796   AC_PATH_PROG(KSH, ksh, no)
 797   if test "$KSH" = no; then
 798     libc_cv_have_ksh=no
 799   else
 800     libc_cv_have_ksh=yes
 801   fi
 802 else
 803   KSH="$BASH"
 804   AC_SUBST(KSH)
 805   libc_cv_have_ksh=yes
 806 fi
 807 AC_SUBST(libc_cv_have_ksh)
 808
 809 AC_PROG_AWK
 810 AC_PATH_PROG(PERL, perl, no)
 811 if test "$PERL" != no &&
 812    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
 813   PERL=no
 814 fi
 815 AC_PATH_PROG(INSTALL_INFO, install-info, no,
 816              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 817 if test "$INSTALL_INFO" != "no"; then
 818 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 819  [mkdir conftest.d
 820   # There is a hard ^_ on the next line.  I am open to better ideas.
 821   (echo '\1f'
 822   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 823   echo '* Menu:') >conftest.d/dir
 824   (echo 'INFO-DIR-SECTION i-d-s works'
 825   echo 'START-INFO-DIR-ENTRY'
 826   echo '* Prog: (prog).   Program.'
 827   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 828   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AS_MESSAGE_LOG_FD 2>&1
 829   then
 830     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 831     then libc_cv_old_debian_install_info=no
 832     else libc_cv_old_debian_install_info=yes
 833     fi
 834   else libc_cv_old_debian_install_info=no testfailed=t
 835   fi
 836   rm -fr conftest.d])
 837 if test -n "$testfailed"
 838 then AC_MSG_WARN([install-info errored out, check config.log])
 839 fi
 840 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 841 fi
 842 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 843
 844 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
 845
 846 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 847 echo '#include <stddef.h>
 848 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 849 if eval "$ac_cpp conftest.c 2>/dev/null" \
 850 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 851   libc_cv_signed_size_t=no
 852 else
 853   libc_cv_signed_size_t=yes
 854 fi
 855 rm -f conftest*])
 856 if test $libc_cv_signed_size_t = yes; then
 857   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 858   cat >> confdefs.h <<\EOF
 859 #undef __SIZE_TYPE__
 860 #define __SIZE_TYPE__ unsigned
 861 EOF
 862 fi
 863
 864 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 865 AC_TRY_COMPILE(dnl
 866 [#define __need_size_t
 867 #define __need_wchar_t
 868 #include <stddef.h>
 869 #define __need_NULL
 870 #include <stddef.h>], [size_t size; wchar_t wchar;
 871 #ifdef offsetof
 872 #error stddef.h ignored __need_*
 873 #endif
 874 if (&size == NULL || &wchar == NULL) abort ();],
 875                libc_cv_friendly_stddef=yes,
 876                libc_cv_friendly_stddef=no)])
 877 if test $libc_cv_friendly_stddef = yes; then
 878   config_vars="$config_vars
 879 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 880 fi
 881
 882 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 883                libc_cv_need_minus_P, [dnl
 884 cat > conftest.S <<EOF
 885 #include "confdefs.h"
 886 /* Nothing whatsoever.  */
 887 EOF
 888 if AC_TRY_COMMAND(${CC-cc} $CFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
 889   libc_cv_need_minus_P=no
 890 else
 891   libc_cv_need_minus_P=yes
 892 fi
 893 rm -f conftest*])
 894 if test $libc_cv_need_minus_P = yes; then
 895   config_vars="$config_vars
 896 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 897 fi
 898
 899 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 900 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 901 cat > conftest.s <<EOF
 902 .text
 903 EOF
 904 libc_cv_dot_text=
 905 if AC_TRY_COMMAND(${CC-cc} $CFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 906   libc_cv_dot_text=.text
 907 fi
 908 rm -f conftest*])
 909 if test -z "$libc_cv_dot_text"; then
 910   AC_MSG_RESULT(no)
 911 else
 912   AC_MSG_RESULT(yes)
 913 fi
 914
 915 AC_CACHE_CHECK(for assembler global-symbol directive,
 916                libc_cv_asm_global_directive, [dnl
 917 libc_cv_asm_global_directive=UNKNOWN
 918 for ac_globl in .globl .global .EXPORT; do
 919   cat > conftest.s <<EOF
 920         ${libc_cv_dot_text}
 921         ${ac_globl} foo
 922 foo:
 923 EOF
 924   if AC_TRY_COMMAND(${CC-cc} $CFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 925     libc_cv_asm_global_directive=${ac_globl}
 926   fi
 927   rm -f conftest*
 928   test $libc_cv_asm_global_directive != UNKNOWN && break
 929 done])
 930 if test $libc_cv_asm_global_directive = UNKNOWN; then
 931   AC_MSG_ERROR(cannot determine asm global directive)
 932 else
 933   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 934 fi
 935
 936 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 937 cat > conftest.s <<EOF
 938 ${libc_cv_dot_text}
 939 foo:
 940 .set glibc_conftest_frobozz,foo
 941 $libc_cv_asm_global_directive glibc_conftest_frobozz
 942 EOF
 943 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 944 # (but it doesn't work), so we must do a linking check to be sure.
 945 cat > conftest1.c <<\EOF
 946 extern int glibc_conftest_frobozz;
 947 main () { printf ("%d\n", glibc_conftest_frobozz); }
 948 EOF
 949 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 950             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 951   libc_cv_asm_set_directive=yes
 952 else
 953   libc_cv_asm_set_directive=no
 954 fi
 955 rm -f conftest*])
 956 if test $libc_cv_asm_set_directive = yes; then
 957   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 958 fi
 959
 960 AC_CACHE_CHECK(for assembler .type directive prefix,
 961                libc_cv_asm_type_prefix, [dnl
 962 libc_cv_asm_type_prefix=no
 963 for ac_try_prefix in '@' '%' '#'; do
 964   cat > conftest.s <<EOF
 965         ${libc_cv_dot_text}
 966         ${libc_cv_asm_global_directive} foo
 967         .type foo, ${ac_try_prefix}object
 968         .size foo, 1
 969 foo:
 970         .byte 1
 971 EOF
 972   if AC_TRY_COMMAND(${CC-cc} $CFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 973     libc_cv_asm_type_prefix=${ac_try_prefix}
 974   fi
 975   rm -f conftest*
 976   test "x$libc_cv_asm_type_prefix" != xno && break
 977 done])
 978 if test "x$libc_cv_asm_type_prefix" != xno; then
 979   AC_DEFINE_UNQUOTED(ASM_TYPE_DIRECTIVE_PREFIX, ${libc_cv_asm_type_prefix})
 980 fi
 981
 982 # The Aix ld uses global .symbol_names instead of symbol_names.
 983 # Unfortunately also used in the PPC64 ELF ABI.
 984 case "${os}${machine}" in
 985 aix4.3* | linux*powerpc/powerpc64*)
 986   AC_DEFINE(HAVE_ASM_GLOBAL_DOT_NAME)
 987 esac
 988
 989 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 990 [cat > conftest.s <<EOF
 991 ${libc_cv_dot_text}
 992 _sym:
 993 .symver _sym,sym@VERS
 994 EOF
 995 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 996   libc_cv_asm_symver_directive=yes
 997 else
 998   libc_cv_asm_symver_directive=no
 999 fi
1000 rm -f conftest*])
1001 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
1002 if test $libc_cv_asm_symver_directive = yes; then
1003   cat > conftest.s <<EOF
1004 ${libc_cv_dot_text}
1005 _sym:
1006 .symver _sym,sym@VERS
1007 EOF
1008   cat > conftest.map <<EOF
1009 VERS_1 {
1010         global: sym;
1011 };
1012
1013 VERS_2 {
1014         global: sym;
1015 } VERS_1;
1016 EOF
1017   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1018     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
1019                                         -nostartfiles -nostdlib
1020                                         -Wl,--version-script,conftest.map
1021                        1>&AS_MESSAGE_LOG_FD]);
1022     then
1023       libc_cv_ld_version_script_option=yes
1024     else
1025       libc_cv_ld_version_script_option=no
1026     fi
1027   else
1028     libc_cv_ld_version_script_option=no
1029   fi
1030 else
1031   libc_cv_ld_version_script_option=no
1032 fi
1033 rm -f conftest*])
1034 if test $shared != no &&
1035    test $libc_cv_asm_symver_directive = yes &&
1036    test $libc_cv_ld_version_script_option = yes &&
1037    test $enable_versioning = yes; then
1038   VERSIONING=yes
1039   AC_DEFINE(DO_VERSIONING)
1040 else
1041   VERSIONING=no
1042 fi
1043 AC_SUBST(VERSIONING)
1044
1045 if test $elf = yes && test $shared != no && test $VERSIONING = no; then
1046   echo "\
1047 *** WARNING: You should not compile GNU libc without versioning. Not using
1048 *** versioning will introduce incompatibilities so that old binaries
1049 *** will not run anymore.
1050 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
1051 fi
1052 if test $elf = yes; then
1053   AC_CACHE_CHECK(for .previous assembler directive,
1054                  libc_cv_asm_previous_directive, [dnl
1055   cat > conftest.s <<EOF
1056 .section foo_section
1057 .previous
1058 EOF
1059   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1060     libc_cv_asm_previous_directive=yes
1061   else
1062     libc_cv_asm_previous_directive=no
1063   fi
1064   rm -f conftest*])
1065   if test $libc_cv_asm_previous_directive = yes; then
1066     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1067   else
1068     AC_CACHE_CHECK(for .popsection assembler directive,
1069                    libc_cv_asm_popsection_directive, [dnl
1070     cat > conftest.s <<EOF
1071 .pushsection foo_section
1072 .popsection
1073 EOF
1074     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1075       libc_cv_asm_popsection_directive=yes
1076     else
1077       libc_cv_asm_popsection_directive=no
1078     fi
1079     rm -f conftest*])
1080     if test $libc_cv_asm_popsection_directive = yes; then
1081       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1082     fi
1083   fi
1084   AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1085                  libc_cv_asm_protected_directive, [dnl
1086   cat > conftest.s <<EOF
1087 .protected foo
1088 foo:
1089 .hidden bar
1090 bar:
1091 EOF
1092   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1093     libc_cv_asm_protected_directive=yes
1094   else
1095     libc_cv_asm_protected_directive=no
1096   fi
1097   rm -f conftest*])
1098   AC_SUBST(libc_cv_asm_protected_directive)
1099   AC_DEFINE(HAVE_PROTECTED)
1100   AC_DEFINE(HAVE_HIDDEN)
1101
1102   if test $libc_cv_asm_protected_directive = yes; then
1103     AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1104                  libc_cv_visibility_attribute,
1105                  [cat > conftest.c <<EOF
1106                   int foo __attribute__ ((visibility ("hidden"))) = 1;
1107                   int bar __attribute__ ((visibility ("protected"))) = 1;
1108 EOF
1109                   libc_cv_visibility_attribute=no
1110                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1111                     if grep '\.hidden.*foo' conftest.s >/dev/null; then
1112                       if grep '\.protected.*bar' conftest.s >/dev/null; then
1113                         libc_cv_visibility_attribute=yes
1114                       fi
1115                     fi
1116                   fi
1117                   rm -f conftest.[cs]
1118                  ])
1119     if test $libc_cv_visibility_attribute = yes; then
1120       AC_DEFINE(HAVE_VISIBILITY_ATTRIBUTE)
1121     fi
1122   fi
1123
1124   if test $libc_cv_visibility_attribute = yes; then
1125     AC_CACHE_CHECK(for broken __attribute__((visibility())),
1126                  libc_cv_broken_visibility_attribute,
1127                  [cat > conftest.c <<EOF
1128                   int foo (int x);
1129                   int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1130                   int bar (int x) { return x; }
1131 EOF
1132                   libc_cv_broken_visibility_attribute=yes
1133                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s1>&AS_MESSAGE_LOG_FD); then
1134 changequote(,)dnl
1135                     if grep '\.hidden[  _]foo' conftest.s >/dev/null; then
1136 changequote([,])dnl
1137                       libc_cv_broken_visibility_attribute=no
1138                     fi
1139                   fi
1140                   rm -f conftest.c conftest.s
1141                  ])
1142     if test $libc_cv_broken_visibility_attribute = yes; then
1143       AC_DEFINE(HAVE_BROKEN_VISIBILITY_ATTRIBUTE)
1144     fi
1145   fi
1146
1147   AC_CACHE_CHECK(for broken __attribute__((alias())),
1148                  libc_cv_broken_alias_attribute,
1149                  [cat > conftest.c <<EOF
1150                   extern int foo (int x) __asm ("xyzzy");
1151                   int bar (int x) { return x; }
1152                   extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1153                   extern int dfoo;
1154                   extern __typeof (dfoo) dfoo __asm ("abccb");
1155                   int dfoo = 1;
1156 EOF
1157                   libc_cv_broken_alias_attribute=yes
1158                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1159                     if grep 'xyzzy' conftest.s >/dev/null &&
1160                        grep 'abccb' conftest.s >/dev/null; then
1161                       libc_cv_broken_alias_attribute=no
1162                     fi
1163                   fi
1164                   rm -f conftest.c conftest.s
1165                  ])
1166   if test $libc_cv_broken_alias_attribute = yes; then
1167     AC_DEFINE(HAVE_BROKEN_ALIAS_ATTRIBUTE)
1168   fi
1169
1170   if test $libc_cv_visibility_attribute = yes -a $gnu_ld = yes; then
1171     AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1172                  libc_cv_have_sdata_section,
1173                  [echo "int i;" > conftest.c
1174                   libc_cv_have_sdata_section=no
1175                   if ${CC-cc} -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1176                      | grep '\.sdata' >/dev/null; then
1177                     libc_cv_have_sdata_section=yes
1178                   fi
1179                   rm -f conftest.c conftest.so
1180                  ])
1181     if test $libc_cv_have_sdata_section = yes; then
1182       AC_DEFINE(HAVE_SDATA_SECTION)
1183     fi
1184   fi
1185
1186   AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1187                  libc_cv_initfinit_array, [dnl
1188   cat > conftest.c <<EOF
1189 int _start (void) { return 0; }
1190 int __start (void) { return 0; }
1191 int foo (void) { return 1; }
1192 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1193 EOF
1194   if AC_TRY_COMMAND([${CC-cc} -o conftest conftest.c
1195                      -static -nostartfiles -nostdlib 1>&AS_MESSAGE_LOG_FD])
1196   then
1197     if readelf -S conftest | fgrep INIT_ARRAY > /dev/null; then
1198       libc_cv_initfinit_array=yes
1199     else
1200       libc_cv_initfinit_array=no
1201     fi
1202   else
1203     libc_cv_initfinit_array=no
1204   fi
1205   rm -f conftest*])
1206   AC_SUBST(libc_cv_initfinit_array)
1207   if test $libc_cv_initfinit_array = yes; then
1208     AC_DEFINE(HAVE_INITFINI_ARRAY)
1209   fi
1210
1211   AC_CACHE_CHECK(for -z nodelete option,
1212                  libc_cv_z_nodelete, [dnl
1213   cat > conftest.c <<EOF
1214 int _start (void) { return 42; }
1215 EOF
1216   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c
1217                      -nostartfiles -nostdlib
1218                      -Wl,--enable-new-dtags,-z,nodelete 1>&AS_MESSAGE_LOG_FD])
1219   then
1220     libc_cv_z_nodelete=yes
1221   else
1222     libc_cv_z_nodelete=no
1223   fi
1224   rm -f conftest*])
1225   AC_SUBST(libc_cv_z_nodelete)
1226
1227   AC_CACHE_CHECK(for -z nodlopen option,
1228                  libc_cv_z_nodlopen, [dnl
1229   cat > conftest.c <<EOF
1230 int _start (void) { return 42; }
1231 EOF
1232   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c
1233                         -nostartfiles -nostdlib
1234                         -Wl,--enable-new-dtags,-z,nodlopen 1>&AS_MESSAGE_LOG_FD])
1235   then
1236     libc_cv_z_nodlopen=yes
1237   else
1238     libc_cv_z_nodlopen=no
1239   fi
1240   rm -f conftest*])
1241   AC_SUBST(libc_cv_z_nodlopen)
1242
1243   AC_CACHE_CHECK(for -z initfirst option,
1244                  libc_cv_z_initfirst, [dnl
1245   cat > conftest.c <<EOF
1246 int _start (void) { return 42; }
1247 EOF
1248   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c
1249                         -nostartfiles -nostdlib
1250                         -Wl,--enable-new-dtags,-z,initfirst 1>&AS_MESSAGE_LOG_FD])
1251   then
1252     libc_cv_z_initfirst=yes
1253   else
1254     libc_cv_z_initfirst=no
1255   fi
1256   rm -f conftest*])
1257   AC_SUBST(libc_cv_z_initfirst)
1258
1259   AC_CACHE_CHECK(for -Bgroup option,
1260                  libc_cv_Bgroup, [dnl
1261   cat > conftest.c <<EOF
1262 int _start (void) { return 42; }
1263 EOF
1264   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1265   then
1266     libc_cv_Bgroup=yes
1267   else
1268     libc_cv_Bgroup=no
1269   fi
1270   rm -f conftest*])
1271   AC_SUBST(libc_cv_Bgroup)
1272
1273   AC_CACHE_CHECK(for -z combreloc,
1274                  libc_cv_z_combreloc, [dnl
1275   cat > conftest.c <<EOF
1276 extern int bar (int);
1277 extern int mumble;
1278 int foo (void) { return bar (mumble); }
1279 EOF
1280   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c
1281                         -nostdlib -nostartfiles
1282                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1283   then
1284 dnl The following test is a bit weak.  We must use a tool which can test
1285 dnl cross-platform since the gcc used can be a cross compiler.  Without
1286 dnl introducing new options this is not easily doable.  Instead use a tool
1287 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1288 dnl look for a section named .rel.dyn.
1289     if readelf -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1290       libc_cv_z_combreloc=yes
1291     else
1292       libc_cv_z_combreloc=no
1293     fi
1294   else
1295     libc_cv_z_combreloc=no
1296   fi
1297   rm -f conftest*])
1298   if test "$libc_cv_z_combreloc" = yes; then
1299     AC_DEFINE(HAVE_Z_COMBRELOC)
1300   fi
1301 fi
1302 AC_SUBST(libc_cv_z_combreloc)
1303
1304 if test $elf != yes; then
1305   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
1306                  [AC_TRY_COMPILE(, [asm (".section .init");
1307                                     asm (".section .fini");
1308                                     asm ("${libc_cv_dot_text}");],
1309                                  libc_cv_have_initfini=yes,
1310                                  libc_cv_have_initfini=no)])
1311   AC_SUBST(libc_cv_have_initfini)dnl
1312   if test $libc_cv_have_initfini = yes; then
1313     AC_DEFINE(HAVE_INITFINI)
1314   fi
1315 fi
1316
1317 if test $elf = yes -a $gnu_ld = yes; then
1318   AC_CACHE_CHECK(whether cc puts quotes around section names,
1319                  libc_cv_have_section_quotes,
1320                  [cat > conftest.c <<EOF
1321                   static const int foo
1322                   __attribute__ ((section ("bar"))) = 1;
1323 EOF
1324                   if ${CC-cc} -S conftest.c -o conftest.s; then
1325                     if grep '\.section.*"bar"' conftest.s >/dev/null; then
1326                       libc_cv_have_section_quotes=yes
1327                     else
1328                       libc_cv_have_section_quotes=no
1329                     fi
1330                   else
1331                     libc_cv_have_section_quotes=unknown
1332                   fi
1333                   rm -f conftest.[cs]
1334                  ])
1335   if test $libc_cv_have_section_quotes = yes; then
1336     AC_DEFINE(HAVE_SECTION_QUOTES)
1337   fi
1338 fi
1339
1340 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
1341 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
1342 [cat > conftest.$ac_ext <<EOF
1343 dnl This sometimes fails to find confdefs.h, for some reason.
1344 dnl [#]line __oline__ "[$]0"
1345 [#]line __oline__ "configure"
1346 #include "confdefs.h"
1347 void underscore_test(void) {
1348 return; }
1349 EOF
1350 if AC_TRY_EVAL(ac_compile); then
1351   if grep _underscore_test conftest* >/dev/null; then
1352     ifelse([$1], , :, [rm -f conftest*
1353     $1])
1354   else
1355     ifelse([$2], , , [rm -f conftest*
1356     $2])
1357   fi
1358 else
1359   echo "configure: failed program was:" >&AS_MESSAGE_LOG_FD
1360   cat conftest.$ac_ext >&AS_MESSAGE_LOG_FD
1361   ifelse([$2], , , [rm -f conftest*
1362   $2])
1363 fi
1364 rm -f conftest*])
1365
1366 if test $elf = yes; then
1367   libc_cv_asm_underscores=no
1368 else
1369   if test $ac_cv_prog_cc_works = yes; then
1370     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
1371                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
1372                                 libc_cv_asm_underscores=yes,
1373                                 libc_cv_asm_underscores=no)])
1374   else
1375     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
1376                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
1377                                             libc_cv_asm_underscores=no)])
1378   fi
1379 fi
1380 if test $libc_cv_asm_underscores = no; then
1381   AC_DEFINE(NO_UNDERSCORES)
1382 fi
1383
1384 if test $elf = yes; then
1385   libc_cv_weak_symbols=yes
1386 fi
1387
1388 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1389                [dnl
1390 cat > conftest.s <<EOF
1391 ${libc_cv_dot_text}
1392 ${libc_cv_asm_global_directive} foo
1393 foo:
1394 .weak foo
1395 .weak bar; bar = foo
1396 EOF
1397 if AC_TRY_COMMAND(${CC-cc} $CFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1398   libc_cv_asm_weak_directive=yes
1399 else
1400   libc_cv_asm_weak_directive=no
1401 fi
1402 rm -f conftest*])
1403
1404 if test $libc_cv_asm_weak_directive = no; then
1405   AC_CACHE_CHECK(for assembler .weakext directive,
1406                  libc_cv_asm_weakext_directive,
1407                  [dnl
1408 cat > conftest.s <<EOF
1409 ${libc_cv_dot_text}
1410 ${libc_cv_asm_global_directive} foo
1411 foo:
1412 .weakext bar foo
1413 .weakext baz
1414 ${libc_cv_asm_global_directive} baz
1415 baz:
1416 EOF
1417   if AC_TRY_COMMAND(${CC-cc} $CFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1418     libc_cv_asm_weakext_directive=yes
1419   else
1420     libc_cv_asm_weakext_directive=no
1421   fi
1422   rm -f conftest*])
1423
1424 fi # no .weak
1425
1426 if test $libc_cv_asm_weak_directive = yes; then
1427   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1428 elif test $libc_cv_asm_weakext_directive = yes; then
1429   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1430 fi
1431
1432 dnl The standard hppa assembler uses `;' to start comments and `!'
1433 dnl as a line separator.  CRIS uses `;' to start comments and `@' for
1434 dnl line separator.
1435 case "${host_cpu}-${host_os}" in
1436   cris*)
1437     libc_cv_asm_line_sep='@'
1438     AC_DEFINE_UNQUOTED(ASM_LINE_SEP, $libc_cv_asm_line_sep)
1439     ;;
1440   hppa*linux*)
1441   AC_CACHE_CHECK(for assembler line separator,
1442                  libc_cv_asm_line_sep, [dnl
1443   cat > conftest.s <<EOF
1444  nop ; is_old_puffin
1445 EOF
1446   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1447     libc_cv_asm_line_sep='!'
1448   else
1449     if test -z "$enable_hacker_mode"; then
1450       echo "*** You need a newer assembler to compile glibc"
1451       rm -f conftest*
1452       exit 1
1453     fi
1454     libc_cv_asm_line_sep=';'
1455   fi
1456   rm -f conftest*])
1457   AC_DEFINE_UNQUOTED(ASM_LINE_SEP, $libc_cv_asm_line_sep)
1458   ;;
1459 esac
1460
1461 AC_CACHE_CHECK(if -g produces usable source locations for assembler-with-cpp,
1462                libc_cv_cpp_asm_debuginfo, [dnl
1463 cat > conftest.S <<EOF
1464 #include "confdefs.h"
1465
1466 /* comment on
1467    two lines */
1468         ${libc_cv_dot_text}
1469         ${libc_cv_asm_global_directive} foo
1470 foo:
1471         /* Unfortunately this test only works for a real instruction,
1472            not for any of the machine-independent pseudo-ops.
1473            So we just have to assume everybody has a "nop".  */
1474         nop
1475         /* comment */
1476         nop
1477         /* comment */
1478         nop
1479 EOF
1480 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -g -c conftest.S 1>&AS_MESSAGE_LOG_FD]) &&
1481    ac_pattern='conftest\.S'
1482    AC_TRY_COMMAND([readelf --debug-dump=line conftest.o |
1483                    grep $ac_pattern 1>&AS_MESSAGE_LOG_FD]); then
1484   libc_cv_cpp_asm_debuginfo=yes
1485 else
1486   libc_cv_cpp_asm_debuginfo=no
1487 fi
1488 rm -f conftest*])AC_SUBST(libc_cv_cpp_asm_debuginfo)
1489 if test $libc_cv_cpp_asm_debuginfo = yes; then
1490   AC_DEFINE(HAVE_CPP_ASM_DEBUGINFO)
1491 fi
1492
1493 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1494 cat > conftest.c <<\EOF
1495 _start () {}
1496 int __eh_pc;
1497 __throw () {}
1498 EOF
1499 dnl No \ in command here because it ends up inside ''.
1500 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1501                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1502                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1503   libc_cv_ld_no_whole_archive=yes
1504 else
1505   libc_cv_ld_no_whole_archive=no
1506 fi
1507 rm -f conftest*])
1508 if test $libc_cv_ld_no_whole_archive = yes; then
1509   no_whole_archive=-Wl,--no-whole-archive
1510 fi
1511 AC_SUBST(no_whole_archive)dnl
1512
1513 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1514 cat > conftest.c <<\EOF
1515 _start () {}
1516 int __eh_pc;
1517 __throw () {}
1518 EOF
1519 dnl No \ in command here because it ends up inside ''.
1520 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1521                             -nostdlib -nostartfiles -fexceptions
1522                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1523   libc_cv_gcc_exceptions=yes
1524 else
1525   libc_cv_gcc_exceptions=no
1526 fi
1527 rm -f conftest*])
1528 if test $libc_cv_gcc_exceptions = yes; then
1529   exceptions=-fexceptions
1530 fi
1531 AC_SUBST(exceptions)dnl
1532
1533 if test "$host_cpu" = powerpc ; then
1534 # Check for a bug present in at least versions 2.8.x of GCC
1535 # and versions 1.0.x of EGCS.
1536 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1537 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1538                libc_cv_c_asmcr0_bug='no',
1539                libc_cv_c_asmcr0_bug='yes')])
1540 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1541   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1542 fi
1543 fi
1544
1545 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
1546 [cat > conftest.c <<EOF
1547 #line __oline__ "configure"
1548 static char *__EH_FRAME_BEGIN__;
1549 _start ()
1550 {
1551 #ifdef CHECK__register_frame
1552   __register_frame (__EH_FRAME_BEGIN__);
1553   __deregister_frame (__EH_FRAME_BEGIN__);
1554 #endif
1555 #ifdef CHECK__register_frame_info
1556   __register_frame_info (__EH_FRAME_BEGIN__);
1557   __deregister_frame_info (__EH_FRAME_BEGIN__);
1558 #endif
1559 }
1560 int __eh_pc;
1561 __throw () {}
1562 /* FIXME: this is fragile.  */
1563 malloc () {}
1564 strcmp () {}
1565 strlen () {}
1566 memcpy () {}
1567 memset () {}
1568 free () {}
1569 abort () {}
1570 __bzero () {}
1571 dl_iterate_phdr () {}
1572 EOF
1573 dnl No \ in command here because it ends up inside ''.
1574 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1575                             -nostdlib -nostartfiles
1576                             -o conftest conftest.c -lgcc >&AS_MESSAGE_LOG_FD]); then
1577   libc_cv_gcc_dwarf2_unwind_info=static
1578 else
1579   libc_cv_gcc_dwarf2_unwind_info=no
1580 fi
1581 # Some platforms' specs put -lgcc first.  The second one doesn't hurt.
1582 libc_unwind_check="${CC-cc} $CFLAGS -DCHECK__register_frame_info \
1583                             -nostdlib -nostartfiles -o conftest conftest.c \
1584                             -lgcc -lgcc_eh -lgcc"
1585 if AC_TRY_COMMAND([$libc_unwind_check >&AS_MESSAGE_LOG_FD]); then
1586   if $libc_unwind_check -v 2>&1 >/dev/null \
1587      | grep -q -- --eh-frame-hdr; then
1588     libc_cv_gcc_dwarf2_unwind_info=no_registry_needed
1589   else
1590     libc_cv_gcc_dwarf2_unwind_info=static
1591   fi
1592 else
1593   libc_cv_gcc_dwarf2_unwind_info=no
1594 fi
1595 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1596   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1597                               -nostdlib -nostartfiles
1598                               -o conftest conftest.c -lgcc >&AS_MESSAGE_LOG_FD]); then
1599     libc_cv_gcc_dwarf2_unwind_info=yes
1600   else
1601     libc_cv_gcc_dwarf2_unwind_info=no
1602   fi
1603 fi
1604 rm -f conftest*])
1605 case $libc_cv_gcc_dwarf2_unwind_info in
1606 yes)
1607   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1608   ;;
1609 static)
1610   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1611   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1612   ;;
1613 esac
1614
1615 dnl Check whether compiler understands __builtin_expect.
1616 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1617 [cat > conftest.c <<EOF
1618 #line __oline__ "configure"
1619 int foo (int a)
1620 {
1621   a = __builtin_expect (a, 10);
1622   return a == 10 ? 0 : 1;
1623 }
1624 EOF
1625 dnl No \ in command here because it ends up inside ''.
1626 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1627                             -o conftest conftest.c -lgcc >&AS_MESSAGE_LOG_FD]); then
1628   libc_cv_gcc_builtin_expect=yes
1629 else
1630   libc_cv_gcc_builtin_expect=no
1631 fi
1632 rm -f conftest*])
1633 if test "$libc_cv_gcc_builtin_expect" = yes; then
1634   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1635 fi
1636
1637 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1638 cat > conftest.c <<\EOF
1639 void zero (void *x)
1640 {
1641   __builtin_memset (x, 0, 1000);
1642 }
1643 EOF
1644 dnl
1645 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1646 then
1647   libc_cv_gcc_builtin_memset=no
1648 else
1649   libc_cv_gcc_builtin_memset=yes
1650 fi
1651 rm -f conftest* ])
1652 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1653   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1654 fi
1655
1656 dnl Check whether the compiler supports subtraction of local labels.
1657 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1658 [cat > conftest.c <<EOF
1659 changequote(,)dnl
1660 #line __oline__ "configure"
1661 int foo (int a)
1662 {
1663   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1664   void *p = &&l1 + ar[a];
1665   goto *p;
1666  l1:
1667   return 1;
1668  l2:
1669   return 2;
1670 }
1671 changequote([,])dnl
1672 EOF
1673 dnl No \ in command here because it ends up inside ''.
1674 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1675                             -o conftest conftest.c -lgcc >&AS_MESSAGE_LOG_FD]); then
1676   libc_cv_gcc_subtract_local_labels=yes
1677 else
1678   libc_cv_gcc_subtract_local_labels=no
1679 fi
1680 rm -f conftest*])
1681 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1682   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1683 fi
1684
1685 dnl Check whether the compiler supports the __thread keyword.
1686 if test "x$use__thread" != xno; then
1687   AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1688   [cat > conftest.c <<\EOF
1689 __thread int a = 42;
1690 EOF
1691   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1692     libc_cv_gcc___thread=yes
1693   else
1694     libc_cv_gcc___thread=no
1695   fi
1696   rm -f conftest*])
1697   if test "$libc_cv_gcc___thread" = yes; then
1698     AC_DEFINE(HAVE___THREAD)
1699   fi
1700 else
1701   libc_cv_gcc___thread=no
1702 fi
1703
1704 if test "$libc_cv_gcc___thread" = yes; then
1705   dnl Check whether the compiler supports the tls_model attribute.
1706   AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1707   cat > conftest.c <<\EOF
1708 extern __thread int a __attribute__((tls_model ("initial-exec")));
1709 EOF
1710   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1711     libc_cv_gcc_tls_model_attr=yes
1712   else
1713     libc_cv_gcc_tls_model_attr=no
1714   fi
1715   rm -f conftest*])
1716   if test "$libc_cv_gcc_tls_model_attr" = yes; then
1717     AC_DEFINE(HAVE_TLS_MODEL_ATTRIBUTE)
1718   fi
1719 fi
1720
1721 dnl Check whether we have the gd library available.
1722 AC_MSG_CHECKING(for libgd)
1723 if test "$with_gd" != "no"; then
1724   old_CFLAGS="$CFLAGS"
1725   CFLAGS="$CFLAGS $libgd_include"
1726   old_LDFLAGS="$LDFLAGS"
1727   LDFLAGS="$LDFLAGS $libgd_ldflags"
1728   old_LIBS="$LIBS"
1729   LIBS="$LIBS -lgd -lpng -lz -lm"
1730   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1731   CFLAGS="$old_CFLAGS"
1732   LDFLAGS="$old_LDFLAGS"
1733   LIBS="$old_LIBS"
1734 else
1735   LIBGD=no
1736 fi
1737 AC_MSG_RESULT($LIBGD)
1738 AC_SUBST(LIBGD)
1739
1740 dnl check for the size of 'long double'.
1741 AC_CHECK_SIZEOF(long double, 0)
1742 sizeof_long_double=$ac_cv_sizeof_long_double
1743 AC_SUBST(sizeof_long_double)
1744
1745 ### End of automated tests.
1746 ### Now run sysdeps configure fragments.
1747
1748 # They also can set these variables.
1749 use_ldconfig=no
1750 ldd_rewrite_script=no
1751 libc_cv_sysconfdir=$sysconfdir
1752 libc_cv_gcc_unwind_find_fde=no
1753
1754 # Iterate over all the sysdep directories we will use, running their
1755 # configure fragments, and looking for a uname implementation.
1756 uname=
1757 for dir in $sysnames; do
1758   case $dir in
1759     /*) dest=$dir ;;
1760     *)  dest=$srcdir/$dir ;;
1761   esac
1762   if test -r $dest/configure; then
1763     AC_MSG_RESULT(running configure fragment for $dir)
1764     . $dest/configure
1765   fi
1766 [
1767   if test -z "$uname"; then
1768     if test -r $dest/uname.c ||
1769        test -r $dest/uname.S ||
1770        { test -r $dest/syscalls.list &&
1771          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1772       uname=$dir
1773     fi
1774   fi
1775 ]dnl
1776 done
1777
1778 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1779   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1780 fi
1781 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1782
1783 # If we will use the generic uname implementation, we must figure out what
1784 # it will say by examining the system, and write the results in config-name.h.
1785 if test "$uname" = "sysdeps/generic"; then
1786
1787 changequote(,)dnl
1788   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1789 changequote([,])dnl
1790   if test $uname_sysname != $config_os; then
1791     config_release=`echo $config_os | sed s/$uname_sysname//`
1792   fi
1793 dnl
1794 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1795     if test -r /vmunix; then
1796       kernel_id=`strings /vmunix | grep UNIX`
1797     elif test -r /dynix; then
1798       kernel_id=`strings /dynix | grep DYNIX`
1799     else
1800       kernel_id=
1801     fi
1802 ])dnl
1803
1804   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1805 LIBC_KERNEL_ID
1806 changequote(,)dnl
1807   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1808 changequote([,])dnl
1809   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1810          != x$config_release; then
1811     # The configuration release is a substring of the kernel release.
1812     libc_cv_uname_release=$kernel_release
1813   elif test x$config_release != x; then
1814     libc_cv_uname_release=$config_release
1815   elif test x$kernel_release != x; then
1816     libc_cv_uname_release=$kernel_release
1817   else
1818     libc_cv_uname_release=unknown
1819   fi])
1820   uname_release="$libc_cv_uname_release"
1821
1822   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1823 LIBC_KERNEL_ID
1824 changequote(,)dnl
1825   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1826 changequote([,])dnl
1827   if test -n "$kernel_version"; then
1828     libc_cv_uname_version="$kernel_version"
1829   else
1830     libc_cv_uname_version=unknown
1831   fi])
1832   uname_version="$libc_cv_uname_version"
1833
1834 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1835   config_uname=config-name.h:config-name.in
1836 else
1837   # For non-generic uname, we don't need to create config-name.h at all.
1838   config_uname=
1839 fi
1840
1841 dnl This is tested by existing code and it's simpler to avoid changing it.
1842 AC_DEFINE(USE_IN_LIBIO)
1843
1844 # Test for old glibc 2.0.x headers so that they can be removed properly
1845 # Search only in includedir.
1846 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1847 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1848 then
1849   old_glibc_headers=yes
1850 else
1851   old_glibc_headers=no
1852 fi
1853 AC_MSG_RESULT($old_glibc_headers)
1854 if test ${old_glibc_headers} = yes; then
1855   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1856   AC_MSG_WARN(*** be removed.)
1857 fi
1858 AC_SUBST(old_glibc_headers)
1859
1860 AC_SUBST(libc_cv_slibdir)
1861 AC_SUBST(libc_cv_localedir)
1862 AC_SUBST(libc_cv_sysconfdir)
1863 AC_SUBST(libc_cv_rootsbindir)
1864
1865 AC_SUBST(use_ldconfig)
1866 AC_SUBST(ldd_rewrite_script)
1867
1868 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf) AC_SUBST(xcoff)
1869 if test $gnu_ld = yes; then
1870   AC_DEFINE(HAVE_GNU_LD)
1871 fi
1872 if test $gnu_as = yes; then
1873   AC_DEFINE(HAVE_GNU_AS)
1874 fi
1875 if test $elf = yes; then
1876   AC_DEFINE(HAVE_ELF)
1877 fi
1878 if test $xcoff = yes; then
1879   AC_DEFINE(HAVE_XCOFF)
1880 fi
1881
1882 AC_SUBST(static)
1883 AC_SUBST(shared)
1884 if test $shared = default; then
1885   if test $gnu_ld = yes; then
1886     shared=$elf
1887   else
1888     # For now we do not assume shared libs are available.  In future more
1889     # tests might become available.
1890     shared=no
1891   fi
1892 fi
1893
1894 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1895 [pic_default=yes
1896 cat > conftest.c <<EOF
1897 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1898 # error PIC is default.
1899 #endif
1900 EOF
1901 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1902   pic_default=no
1903 fi
1904 rm -f conftest.*])
1905 AC_SUBST(pic_default)
1906
1907 AC_SUBST(profile)
1908 AC_SUBST(omitfp)
1909 AC_SUBST(bounded)
1910 AC_SUBST(static_nss)
1911 AC_SUBST(nopic_initfini)
1912
1913 AC_SUBST(DEFINES)
1914
1915 case "$add_ons" in
1916   *door*) linux_doors=yes ;;
1917   *) linux_doors=no ;;
1918 esac
1919 AC_SUBST(linux_doors)
1920
1921 dnl See sysdeps/mach/configure.in for this variable.
1922 AC_SUBST(mach_interface_list)
1923
1924 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1925   config_makefile=
1926 else
1927   config_makefile=Makefile
1928 fi
1929
1930 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1931 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1932 AC_SUBST(VERSION)
1933 AC_SUBST(RELEASE)
1934
1935 AC_CONFIG_FILES([config.make glibcbug ${config_makefile} ${config_uname}])
1936 AC_CONFIG_COMMANDS([default],[[
1937 case $CONFIG_FILES in *config.make*)
1938 echo "$config_vars" >> config.make;;
1939 esac
1940 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1941 AC_OUTPUT