configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.2.0pre2],[http://rsync.samba.org/bugzilla.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_CXX
  45 AC_PROG_EGREP
  46 AC_PROG_INSTALL
  47 AC_PROG_MKDIR_P
  48 AC_PROG_CC_STDC
  49 AC_SUBST(SHELL)
  50 AC_PATH_PROG([PERL], [perl])
  51
  52 AC_DEFINE([_GNU_SOURCE], 1,
  53           [Define _GNU_SOURCE so that we get all necessary prototypes])
  54
  55 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  56         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  57 fi
  58
  59 AC_ARG_ENABLE(profile,
  60         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  61 if test x"$enable_profile" = x"yes"; then
  62         CFLAGS="$CFLAGS -pg"
  63 fi
  64
  65
  66 # Specifically, this turns on panic_action handling.
  67 AC_ARG_ENABLE(maintainer-mode,
  68         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
  69 if test x"$enable_maintainer_mode" = x"yes"; then
  70         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  71 fi
  72
  73
  74 # This is needed for our included version of popt.  Kind of silly, but
  75 # I don't want our version too far out of sync.
  76 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  77
  78 # If GCC, turn on warnings.
  79 if test x"$GCC" = x"yes"; then
  80         CFLAGS="$CFLAGS -Wall -W"
  81 fi
  82
  83 AC_ARG_WITH(included-popt,
  84         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
  85
  86 AC_ARG_WITH(included-zlib,
  87         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
  88
  89 AC_ARG_WITH(protected-args,
  90         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
  91 if test x"$with_protected_args" = x"yes"; then
  92         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
  93 fi
  94
  95 AC_ARG_WITH(rsync-path,
  96         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
  97         [ RSYNC_PATH="$with_rsync_path" ],
  98         [ RSYNC_PATH="rsync" ])
  99
 100 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 101
 102 AC_ARG_WITH(rsyncd-conf,
 103         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 104         [ if test ! -z "$with_rsyncd_conf" ; then
 105                 case $with_rsyncd_conf in
 106                         yes|no)
 107                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 108                                 ;;
 109                         /*)
 110                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 111                                 ;;
 112                         *)
 113                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 114                                 ;;
 115                 esac
 116         else
 117                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 118         fi ],
 119         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 120
 121 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 122
 123 AC_ARG_WITH(rsh,
 124         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 125
 126 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 127 if test x$HAVE_REMSH = x1; then
 128         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 129 fi
 130
 131 if test x"$with_rsh" != x; then
 132         RSYNC_RSH="$with_rsh"
 133 else
 134         RSYNC_RSH="ssh"
 135 fi
 136 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 137
 138 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 139 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 140 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 141
 142 AC_ARG_WITH(nobody-group,
 143     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 144     [ NOBODY_GROUP="$with_nobody_group" ])
 145
 146 if test x"$with_nobody_group" = x; then
 147     AC_MSG_CHECKING([the group for user "nobody"])
 148     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 149         NOBODY_GROUP=nobody
 150     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 151         NOBODY_GROUP=nogroup
 152     else
 153         NOBODY_GROUP=nobody # test for others?
 154     fi
 155     AC_MSG_RESULT($NOBODY_GROUP)
 156 fi
 157
 158 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 159 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 160
 161 # SIMD optimizations
 162 SIMD=
 163
 164 AC_MSG_CHECKING([whether to enable SIMD optimizations])
 165 AC_ARG_ENABLE(simd,
 166     AS_HELP_STRING([--disable-simd],[disable SIMD optimizations (requires g++)]))
 167
 168 if test x"$enable_simd" != x"no"; then
 169     # For x86-64 SIMD, g++ is also required
 170     if test x"$build_cpu" = x"x86_64" && test x"$CXX" = x"g++"; then
 171         SIMD="$SIMD x86_64"
 172     fi
 173 fi
 174
 175 if test x"$SIMD" != x""; then
 176     SIMD=`echo "$SIMD" | sed -e 's/^ *//'`
 177     AC_MSG_RESULT([yes ($SIMD)])
 178         AC_DEFINE(HAVE_SIMD, 1, [Define to 1 to enable SIMD optimizations])
 179     SIMD=`echo "$SIMD" | sed -e 's/[[^ ]]\+/$(SIMD_&)/g'`
 180 else
 181     AC_MSG_RESULT(no)
 182 fi
 183
 184 AC_SUBST(SIMD)
 185
 186 # We only use g++ for its target attribute dispatching, disable unneeded bulky features
 187 if test x"$CXXOBJ" != x""; then
 188     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 189 fi
 190
 191 # arrgh. libc in some old debian version screwed up the largefile
 192 # stuff, getting byte range locking wrong
 193 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 194 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 195 #define _FILE_OFFSET_BITS 64
 196 #include <stdio.h>
 197 #include <fcntl.h>
 198 #include <sys/types.h>
 199 #include <sys/wait.h>
 200 #if HAVE_UNISTD_H
 201 #include <unistd.h>
 202 #endif
 203
 204 int main(void)
 205 {
 206         struct flock lock;
 207         int status;
 208         char tpl[32] = "/tmp/locktest.XXXXXX";
 209         int fd = mkstemp(tpl);
 210         if (fd < 0) {
 211                 strcpy(tpl, "conftest.dat");
 212                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 213         }
 214
 215         lock.l_type = F_WRLCK;
 216         lock.l_whence = SEEK_SET;
 217         lock.l_start = 0;
 218         lock.l_len = 1;
 219         lock.l_pid = 0;
 220         fcntl(fd,F_SETLK,&lock);
 221         if (fork() == 0) {
 222                 lock.l_start = 1;
 223                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 224         }
 225         wait(&status);
 226         unlink(tpl);
 227         return WEXITSTATUS(status);
 228 }
 229 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 230 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 231    AC_SYS_LARGEFILE
 232 fi
 233
 234 ipv6type=unknown
 235 ipv6lib=none
 236 ipv6trylibc=yes
 237
 238 AC_ARG_ENABLE(ipv6,
 239         AS_HELP_STRING([--disable-ipv6],[turn off IPv6 support]))
 240 if test x"$enable_ipv6" != x"no"; then
 241         AC_MSG_CHECKING([ipv6 stack type])
 242         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 243                 case $i in
 244                 inria)
 245                         # http://www.kame.net/
 246                         AC_EGREP_CPP(yes, [
 247 #include <netinet/in.h>
 248 #ifdef IPV6_INRIA_VERSION
 249 yes
 250 #endif],
 251                                 [ipv6type=$i;
 252                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 253                                 ])
 254                         ;;
 255                 kame)
 256                         # http://www.kame.net/
 257                         AC_EGREP_CPP(yes, [
 258 #include <netinet/in.h>
 259 #ifdef __KAME__
 260 yes
 261 #endif],
 262                                 [ipv6type=$i;
 263                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 264                         ;;
 265                 linux-glibc)
 266                         # http://www.v6.linux.or.jp/
 267                         AC_EGREP_CPP(yes, [
 268 #include <features.h>
 269 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 270 yes
 271 #endif],
 272                                 [ipv6type=$i;
 273 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 274                         ;;
 275                 linux-inet6)
 276                         # http://www.v6.linux.or.jp/
 277                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 278                                 ipv6type=$i
 279                                 ipv6lib=inet6
 280                                 ipv6libdir=/usr/inet6/lib
 281                                 ipv6trylibc=yes;
 282                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 283                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 284                         fi
 285                         ;;
 286                 solaris)
 287                         # http://www.sun.com
 288                         AC_EGREP_CPP(yes, [
 289 #include <netinet/ip6.h>
 290 #ifdef __sun
 291 yes
 292 #endif],
 293                                 [ipv6type=$i;
 294                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 295                         ;;
 296                 toshiba)
 297                         AC_EGREP_CPP(yes, [
 298 #include <sys/param.h>
 299 #ifdef _TOSHIBA_INET6
 300 yes
 301 #endif],
 302                                 [ipv6type=$i;
 303                                 ipv6lib=inet6;
 304                                 ipv6libdir=/usr/local/v6/lib;
 305                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 306                         ;;
 307                 v6d)
 308                         AC_EGREP_CPP(yes, [
 309 #include </usr/local/v6/include/sys/v6config.h>
 310 #ifdef __V6D__
 311 yes
 312 #endif],
 313                                 [ipv6type=$i;
 314                                 ipv6lib=v6;
 315                                 ipv6libdir=/usr/local/v6/lib;
 316                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 317                         ;;
 318                 zeta)
 319                         AC_EGREP_CPP(yes, [
 320 #include <sys/param.h>
 321 #ifdef _ZETA_MINAMI_INET6
 322 yes
 323 #endif],
 324                                 [ipv6type=$i;
 325                                 ipv6lib=inet6;
 326                                 ipv6libdir=/usr/local/v6/lib;
 327                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 328                         ;;
 329                 cygwin)
 330                         AC_EGREP_CPP(yes, [
 331 #include <netinet/in.h>
 332 #ifdef _CYGWIN_IN6_H
 333 yes
 334 #endif],
 335                                 [ipv6type=$i;
 336                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 337                         ;;
 338                 esac
 339                 if test "$ipv6type" != "unknown"; then
 340                         break
 341                 fi
 342         done
 343         AC_MSG_RESULT($ipv6type)
 344
 345         AC_SEARCH_LIBS(getaddrinfo, inet6)
 346 fi
 347
 348 dnl Do you want to disable use of locale functions
 349 AC_ARG_ENABLE([locale],
 350         AS_HELP_STRING([--disable-locale],[disable locale features]))
 351 AH_TEMPLATE([CONFIG_LOCALE],
 352 [Undefine if you do not want locale features.  By default this is defined.])
 353 if test x"$enable_locale" != x"no"; then
 354         AC_DEFINE(CONFIG_LOCALE)
 355 fi
 356
 357 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 358 case $host_os in
 359         *cygwin* ) AC_MSG_RESULT(yes)
 360                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 361                             [Define to 1 if sockets need to be shutdown])
 362                    ;;
 363                * ) AC_MSG_RESULT(no);;
 364 esac
 365
 366 AC_C_BIGENDIAN
 367 AC_HEADER_DIRENT
 368 AC_HEADER_TIME
 369 AC_HEADER_SYS_WAIT
 370 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 371     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 372     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 373     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 374     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 375     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 376     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 377     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h)
 378 AC_HEADER_MAJOR_FIXED
 379
 380 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 381 AC_ARG_ENABLE([openssl],
 382         AS_HELP_STRING([--disable-openssl],[disable openssl crypto library]))
 383 AH_TEMPLATE([USE_OPENSSL],
 384 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 385 if test x"$enable_openssl" != x"no" && test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 386     AC_MSG_RESULT(yes)
 387     AC_SEARCH_LIBS(MD5_Init, crypto, [AC_DEFINE(USE_OPENSSL)])
 388 else
 389     AC_MSG_RESULT(no)
 390 fi
 391
 392 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 393 AC_ARG_ENABLE([xxhash],
 394         AS_HELP_STRING([--disable-xxhash],[disable xxhash checksums]))
 395 AH_TEMPLATE([SUPPORT_XXHASH],
 396 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 397 if test x"$enable_xxhash" != x"no" && test x"$ac_cv_header_xxhash_h" = x"yes"; then
 398     AC_MSG_RESULT(yes)
 399     AC_SEARCH_LIBS(XXH64_createState, xxhash, [AC_DEFINE(SUPPORT_XXHASH)])
 400 else
 401     AC_MSG_RESULT(no)
 402 fi
 403
 404 AC_MSG_CHECKING([whether to enable zstd compression])
 405 AC_ARG_ENABLE([zstd],
 406         AC_HELP_STRING([--disable-zstd], [disable zstd compression]))
 407 AH_TEMPLATE([SUPPORT_ZSTD],
 408 [Undefine if you do not want zstd compression.  By default this is defined.])
 409 if test x"$enable_zstd" != x"no" && test x"$ac_cv_header_zstd_h" = x"yes"; then
 410     AC_MSG_RESULT(yes)
 411     AC_SEARCH_LIBS(ZSTD_minCLevel, zstd, [AC_DEFINE(SUPPORT_ZSTD)])
 412 else
 413     AC_MSG_RESULT(no)
 414 fi
 415
 416 AC_MSG_CHECKING([whether to enable LZ4 compression])
 417 AC_ARG_ENABLE([lz4],
 418         AC_HELP_STRING([--disable-lz4], [disable LZ4 compression]))
 419 AH_TEMPLATE([SUPPORT_LZ4],
 420 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 421 if test x"$enable_lz4" != x"no" && test x"$ac_cv_header_lz4_h" = x"yes"; then
 422     AC_MSG_RESULT(yes)
 423     AC_SEARCH_LIBS(LZ4_compress_default, lz4, [AC_DEFINE(SUPPORT_LZ4)])
 424 else
 425     AC_MSG_RESULT(no)
 426 fi
 427
 428 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 429 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 430 #include <sys/types.h>
 431 #ifdef MAJOR_IN_MKDEV
 432 #include <sys/mkdev.h>
 433 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 434 #  define makedev mkdev
 435 # endif
 436 #elif defined MAJOR_IN_SYSMACROS
 437 #include <sys/sysmacros.h>
 438 #endif
 439
 440 int main(void)
 441 {
 442         dev_t dev = makedev(0, 5, 7);
 443         if (major(dev) != 5 || minor(dev) != 7)
 444                 return 1;
 445         return 0;
 446 }
 447 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 448 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 449    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 450 fi
 451
 452 AC_CHECK_SIZEOF(int)
 453 AC_CHECK_SIZEOF(long)
 454 AC_CHECK_SIZEOF(long long)
 455 AC_CHECK_SIZEOF(short)
 456 AC_CHECK_SIZEOF(int16_t)
 457 AC_CHECK_SIZEOF(uint16_t)
 458 AC_CHECK_SIZEOF(int32_t)
 459 AC_CHECK_SIZEOF(uint32_t)
 460 AC_CHECK_SIZEOF(int64_t)
 461 AC_CHECK_SIZEOF(off_t)
 462 AC_CHECK_SIZEOF(off64_t)
 463 AC_CHECK_SIZEOF(time_t)
 464 AC_CHECK_SIZEOF(char*)
 465
 466 AC_C_INLINE
 467
 468 AC_TYPE_LONG_DOUBLE_WIDER
 469 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 470 if test $ac_cv_c_long_double = yes; then
 471   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 472 fi
 473
 474 AC_TYPE_UID_T
 475 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 476 AC_TYPE_GETGROUPS
 477 AC_CHECK_MEMBERS([struct stat.st_rdev,
 478                   struct stat.st_mtimensec,
 479                   struct stat.st_mtimespec.tv_nsec,
 480                   struct stat.st_mtim.tv_nsec],,,[
 481 #ifdef HAVE_SYS_TYPES_H
 482 #include <sys/types.h>
 483 #endif
 484 #ifdef HAVE_SYS_STAT_H
 485 #include <sys/stat.h>
 486 #endif
 487 #ifdef HAVE_UNISTD_H
 488 #include <unistd.h>
 489 #endif])
 490
 491 TYPE_SOCKLEN_T
 492
 493 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 494     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 495 if test x"$rsync_cv_errno" = x"yes"; then
 496    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 497 fi
 498
 499 # The following test taken from the cvs sources
 500 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 501 # These need checks to be before checks for any other functions that
 502 #    might be in the same libraries.
 503 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 504 # libsocket.so which has a bad implementation of gethostbyname (it
 505 # only looks in /etc/hosts), so we only look for -lsocket if we need
 506 # it.
 507 AC_CHECK_FUNCS(connect)
 508 if test x"$ac_cv_func_connect" = x"no"; then
 509     case "$LIBS" in
 510     *-lnsl*) ;;
 511     *) AC_CHECK_LIB(nsl_s, printf) ;;
 512     esac
 513     case "$LIBS" in
 514     *-lnsl*) ;;
 515     *) AC_CHECK_LIB(nsl, printf) ;;
 516     esac
 517     case "$LIBS" in
 518     *-lsocket*) ;;
 519     *) AC_CHECK_LIB(socket, connect) ;;
 520     esac
 521     case "$LIBS" in
 522     *-linet*) ;;
 523     *) AC_CHECK_LIB(inet, connect) ;;
 524     esac
 525     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 526     dnl has been cached.
 527     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 528        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 529         # ac_cv_func_connect=yes
 530         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 531         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 532     fi
 533 fi
 534
 535 AC_SEARCH_LIBS(inet_ntop, resolv)
 536
 537 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 538 # accept either iconv_open or libiconv_open, since some include files map
 539 # the former to the latter.
 540 AC_SEARCH_LIBS(iconv_open, iconv)
 541 AC_SEARCH_LIBS(libiconv_open, iconv)
 542
 543 AC_MSG_CHECKING([for iconv declaration])
 544 AC_CACHE_VAL(am_cv_proto_iconv, [
 545     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 546 #include <stdlib.h>
 547 #include <iconv.h>
 548 extern
 549 #ifdef __cplusplus
 550 "C"
 551 #endif
 552 #if defined(__STDC__) || defined(__cplusplus)
 553 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 554 #else
 555 size_t iconv();
 556 #endif
 557 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 558       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 559     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 560 AC_MSG_RESULT([$]{ac_t:-
 561          }[$]am_cv_proto_iconv)
 562 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 563                    [Define as const if the declaration of iconv() needs const.])
 564
 565 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 566
 567 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 568
 569 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 570 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 571 #include <sys/socket.h>])
 572
 573 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 574 #   builtin getaddrinfo if one of the defines don't exist
 575 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 576                rsync_cv_HAVE_GETADDR_DEFINES,[
 577                         AC_EGREP_CPP(yes, [
 578                         #include <sys/types.h>
 579                         #include <sys/socket.h>
 580                         #include <netdb.h>
 581                         #ifdef AI_PASSIVE
 582                         yes
 583                         #endif],
 584                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 585                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 586 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 587         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 588         # something else so we must include <netdb.h> to get the
 589         # redefinition.
 590         AC_CHECK_FUNCS(getaddrinfo, ,
 591                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 592                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 593                 #include <sys/socket.h>
 594                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 595                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 596                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 597                         AC_LIBOBJ([getaddrinfo])])])
 598     ],[AC_LIBOBJ([getaddrinfo])])
 599
 600 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 601                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 602                 [],
 603                 [
 604 #include <sys/types.h>
 605 #include <sys/socket.h>
 606 ])
 607
 608 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 609                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 610                 [],
 611                 [
 612 #include <sys/types.h>
 613 #include <sys/socket.h>
 614 #include <netinet/in.h>
 615 ])
 616
 617 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 618                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 619                 [],
 620                 [
 621 #include <sys/types.h>
 622 #include <sys/socket.h>
 623 #include <netinet/in.h>
 624 ])
 625
 626 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 627                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 628                 [],
 629                 [
 630 #include <sys/types.h>
 631 #include <sys/socket.h>
 632 #include <netinet/in.h>
 633 ])
 634
 635 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 636 #if HAVE_SYS_TYPES_H
 637 # include <sys/types.h>
 638 #endif
 639 #if HAVE_SYS_STAT_H
 640 # include <sys/stat.h>
 641 #endif
 642 #if STDC_HEADERS
 643 # include <stdlib.h>
 644 # include <stddef.h>
 645 #else
 646 # if HAVE_STDLIB_H
 647 #  include <stdlib.h>
 648 # endif
 649 #endif
 650 ])
 651
 652 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 653 #
 654 AC_CHECK_FUNCS(strcasecmp)
 655 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 656     AC_CHECK_LIB(resolv, strcasecmp)
 657 fi
 658
 659 AC_CHECK_FUNCS(aclsort)
 660 if test x"$ac_cv_func_aclsort" = x"no"; then
 661     AC_CHECK_LIB(sec, aclsort)
 662 fi
 663
 664 dnl At the moment we don't test for a broken memcmp(), because all we
 665 dnl need to do is test for equality, not comparison, and it seems that
 666 dnl every platform has a memcmp that can do at least that.
 667 dnl AC_FUNC_MEMCMP
 668
 669 AC_FUNC_UTIME_NULL
 670 AC_FUNC_ALLOCA
 671 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 672     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 673     chflags getattrlist \
 674     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 675     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 676     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 677     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 678     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 679     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep)
 680
 681 dnl cygwin iconv.h defines iconv_open as libiconv_open
 682 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 683     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 684 fi
 685
 686 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 687
 688 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 689 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 690 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 691 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 692     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 693 fi
 694
 695 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 696 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 697         #define _GNU_SOURCE 1
 698         #include <linux/falloc.h>
 699         #ifndef FALLOC_FL_PUNCH_HOLE
 700         #error FALLOC_FL_PUNCH_HOLE is missing
 701         #endif
 702     ]])], [
 703         AC_MSG_RESULT([yes])
 704         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 705     ], [
 706         AC_MSG_RESULT([no])
 707     ]
 708 )
 709
 710 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 711 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 712         #define _GNU_SOURCE 1
 713         #include <linux/falloc.h>
 714         #ifndef FALLOC_FL_ZERO_RANGE
 715         #error FALLOC_FL_ZERO_RANGE is missing
 716         #endif
 717     ]])], [
 718         AC_MSG_RESULT([yes])
 719         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 720     ], [
 721         AC_MSG_RESULT([no])
 722     ]
 723 )
 724
 725 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 726 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 727 #include <unistd.h>
 728 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 729 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 730     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 731 fi
 732
 733 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 734     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 735     case $host_os in
 736     *cygwin*)
 737         AC_MSG_RESULT(yes)
 738         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 739                   [Define if posix_fallocate is efficient (Cygwin)])
 740         ;;
 741     *)
 742         AC_MSG_RESULT(no)
 743         ;;
 744     esac
 745 fi
 746
 747 dnl End of preallocation stuff
 748
 749 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 750 if test $ac_cv_func_getpgrp = yes; then
 751     AC_FUNC_GETPGRP
 752 fi
 753
 754 AC_ARG_ENABLE(iconv-open,
 755     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 756     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 757
 758 if test x"$enable_iconv_open" != x"no"; then
 759     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 760 fi
 761
 762 AC_ARG_ENABLE(iconv,
 763     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 764     [], [enable_iconv=$enable_iconv_open])
 765 AH_TEMPLATE([ICONV_OPTION],
 766 [Define if you want the --iconv option.  Specifying a value will set the
 767 default iconv setting (a NULL means no --iconv processing by default).])
 768 if test x"$enable_iconv" != x"no"; then
 769         if test x"$enable_iconv" = x"yes"; then
 770                 AC_DEFINE(ICONV_OPTION, NULL)
 771         else
 772                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 773         fi
 774         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 775 fi
 776
 777 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 778   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 779 #if HAVE_UNISTD_H
 780 # include <unistd.h>
 781 #endif
 782 #include <stdlib.h>
 783 #include <errno.h>
 784 int main(void) {
 785         char const *dangling_symlink = "conftest.dangle";
 786         unlink(dangling_symlink);
 787         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 788         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 789         return 0;
 790     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 791 if test $rsync_cv_chown_modifies_symlink = yes; then
 792   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 793 fi
 794
 795 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 796   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 797 #if HAVE_UNISTD_H
 798 # include <unistd.h>
 799 #endif
 800 #include <stdlib.h>
 801 #include <errno.h>
 802 #define FILENAME "conftest.dangle"
 803 int main(void) {
 804         unlink(FILENAME);
 805         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 806         unlink(FILENAME "2");
 807         if (link(FILENAME, FILENAME "2") < 0) return 1;
 808         return 0;
 809     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 810 if test $rsync_cv_can_hardlink_symlink = yes; then
 811   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 812 fi
 813
 814 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 815   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 816 #if HAVE_UNISTD_H
 817 # include <unistd.h>
 818 #endif
 819 #ifdef HAVE_SYS_STAT_H
 820 #include <sys/stat.h>
 821 #endif
 822 #include <stdlib.h>
 823 #include <errno.h>
 824 #define FILENAME "conftest.fifi"
 825 int main(void) {
 826         unlink(FILENAME);
 827         if (mkfifo(FILENAME, 0777) < 0) abort();
 828         unlink(FILENAME "2");
 829         if (link(FILENAME, FILENAME "2") < 0) return 1;
 830         return 0;
 831     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 832 if test $rsync_cv_can_hardlink_special = yes; then
 833     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 834 fi
 835
 836 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 837 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 838 #include <sys/types.h>
 839 #include <sys/socket.h>
 840
 841 int main(void) {
 842        int fd[2];
 843        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
 844 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 845 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 846     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 847 fi
 848
 849 AC_REPLACE_FUNCS([getpass])
 850
 851 if test x"$with_included_popt" != x"yes"; then
 852     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 853 fi
 854 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 855     # If the system has /usr/include/popt/popt.h, we enable the
 856     # included popt because an attempt to "#include <popt/popt.h>"
 857     # would use our included header file anyway (due to -I.), and
 858     # might conflict with the system popt.
 859     with_included_popt=yes
 860 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 861     with_included_popt=yes
 862 fi
 863
 864 AC_MSG_CHECKING([whether to use included libpopt])
 865 if test x"$with_included_popt" = x"yes"; then
 866     AC_MSG_RESULT($srcdir/popt)
 867     BUILD_POPT='$(popt_OBJS)'
 868     CFLAGS="-I$srcdir/popt $CFLAGS"
 869     if test x"$ALLOCA" != x
 870     then
 871         # this can be removed when/if we add an included alloca.c;
 872         #  see autoconf documentation on AC_FUNC_ALLOCA
 873         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 874     fi
 875 else
 876     AC_MSG_RESULT(no)
 877 fi
 878
 879 # We default to using our zlib unless --with-included-zlib=no is given.
 880 if test x"$with_included_zlib" != x"no"; then
 881     with_included_zlib=yes
 882 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
 883     with_included_zlib=yes
 884 fi
 885 if test x"$with_included_zlib" != x"yes"; then
 886     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
 887 fi
 888
 889 AC_MSG_CHECKING([whether to use included zlib])
 890 if test x"$with_included_zlib" = x"yes"; then
 891     AC_MSG_RESULT($srcdir/zlib)
 892     BUILD_ZLIB='$(zlib_OBJS)'
 893     CFLAGS="-I$srcdir/zlib $CFLAGS"
 894 else
 895     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
 896     AC_MSG_RESULT(no)
 897 fi
 898
 899 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 900 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
 901 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 902     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 903 fi
 904
 905 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 906 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
 907 #include <dirent.h>
 908 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 909 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 910 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
 911 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 912     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 913 fi
 914
 915 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
 916 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 917 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
 918 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
 919     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 920 fi
 921
 922 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 923 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
 924 #include <unistd.h>]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
 925 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 926     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 927 fi
 928
 929 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 930 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 931 #include <sys/types.h>
 932 #include <stdarg.h>
 933 #include <stdio.h>
 934 #include <stdlib.h>
 935 #include <string.h>
 936 void foo(const char *format, ...) {
 937        va_list ap;
 938        int len;
 939        static char buf[] = "12345678901234567890";
 940
 941        va_start(ap, format);
 942        len = vsnprintf(0, 0, format, ap);
 943        va_end(ap);
 944        if (len != 5) exit(1);
 945
 946        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 947 }
 948 int main(void) { foo("hello"); return 0; }
 949 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
 950 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 951     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 952 fi
 953
 954
 955 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 956 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 957 #include <sys/types.h>
 958 #include <sys/stat.h>
 959 #include <unistd.h>
 960 int main(void) {
 961   struct stat st;
 962   char tpl[20]="/tmp/test.XXXXXX";
 963   int fd = mkstemp(tpl);
 964   if (fd == -1) return 1;
 965   unlink(tpl);
 966   if (fstat(fd, &st) != 0) return 1;
 967   if ((st.st_mode & 0777) != 0600) return 1;
 968   return 0;
 969 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
 970 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 971     case $host_os in
 972     hpux*)
 973         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 974         dnl so we noisily skip using it.  See HP change request JAGaf34426
 975         dnl for details. (sbonds)
 976         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 977         ;;
 978     *)
 979         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 980         ;;
 981     esac
 982 fi
 983
 984
 985 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 986 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 987 #include <stdio.h>
 988 #include <sys/stat.h>
 989 #include <errno.h>
 990 #if HAVE_UNISTD_H
 991 # include <unistd.h>
 992 #endif
 993 int main(void) { int rc, ec; char *fn = "fifo-test";
 994 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 995 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 996 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
 997 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 998     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 999 fi
1000
1001 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1002 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1003 #include <stdio.h>
1004 #include <sys/stat.h>
1005 #include <errno.h>
1006 #if HAVE_UNISTD_H
1007 # include <unistd.h>
1008 #endif
1009 int main(void) { int rc, ec; char *fn = "sock-test";
1010 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1011 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1012 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1013 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1014     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1015 fi
1016
1017 #
1018 # The following test was mostly taken from the tcl/tk plus patches
1019 #
1020 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1021 rm -rf conftest*
1022 cat > conftest.$ac_ext <<EOF
1023 int main(void) { return 0; }
1024 EOF
1025 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1026 if test -f conftest..o; then
1027     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1028 else
1029     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1030 fi
1031 rm -rf conftest*
1032 ])
1033 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1034     OBJ_SAVE="#"
1035     OBJ_RESTORE="#"
1036     CC_SHOBJ_FLAG='-o $@'
1037 else
1038     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1039     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1040     CC_SHOBJ_FLAG=""
1041 fi
1042
1043 AC_SUBST(OBJ_SAVE)
1044 AC_SUBST(OBJ_RESTORE)
1045 AC_SUBST(CC_SHOBJ_FLAG)
1046 AC_SUBST(BUILD_POPT)
1047 AC_SUBST(BUILD_ZLIB)
1048 AC_SUBST(MAKE_MAN)
1049
1050 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1051 #################################################
1052 # check for ACL support
1053
1054 AC_MSG_CHECKING([whether to support ACLs])
1055 AC_ARG_ENABLE(acl-support,
1056         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
1057
1058 if test x"$enable_acl_support" = x"no"; then
1059     AC_MSG_RESULT(no)
1060 else
1061     case "$host_os" in
1062     *sysv5*)
1063         AC_MSG_RESULT(Using UnixWare ACLs)
1064         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1065         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1066         ;;
1067     solaris*)
1068         AC_MSG_RESULT(Using solaris ACLs)
1069         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1070         AC_DEFINE(SUPPORT_ACLS, 1)
1071         ;;
1072     *hpux*)
1073         AC_MSG_RESULT(Using HPUX ACLs)
1074         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1075         AC_DEFINE(SUPPORT_ACLS, 1)
1076         ;;
1077     *irix*)
1078         AC_MSG_RESULT(Using IRIX ACLs)
1079         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1080         AC_DEFINE(SUPPORT_ACLS, 1)
1081         ;;
1082     *aix*)
1083         AC_MSG_RESULT(Using AIX ACLs)
1084         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1085         AC_DEFINE(SUPPORT_ACLS, 1)
1086         ;;
1087     *osf*)
1088         AC_MSG_RESULT(Using Tru64 ACLs)
1089         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1090         AC_DEFINE(SUPPORT_ACLS, 1)
1091         LIBS="$LIBS -lpacl"
1092         ;;
1093     darwin*)
1094         AC_MSG_RESULT(Using OS X ACLs)
1095         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1096         AC_DEFINE(SUPPORT_ACLS, 1)
1097         ;;
1098     *)
1099         AC_MSG_RESULT(running tests:)
1100         AC_CHECK_LIB(acl,acl_get_file)
1101         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1102             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1103 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1104         AC_MSG_CHECKING(ACL test results)
1105         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1106             AC_MSG_RESULT(Using posix ACLs)
1107             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1108             AC_DEFINE(SUPPORT_ACLS, 1)
1109             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1110                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1111 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1112             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1113                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1114             fi
1115         else
1116             if test x"$enable_acl_support" = x"yes"; then
1117                 AC_MSG_ERROR(Failed to find ACL support)
1118             else
1119                 AC_MSG_RESULT(No ACL support found)
1120             fi
1121         fi
1122         ;;
1123     esac
1124 fi
1125
1126 #################################################
1127 # check for extended attribute support
1128 AC_MSG_CHECKING(whether to support extended attributes)
1129 AC_ARG_ENABLE(xattr-support,
1130     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1131     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1132         *yes*) enable_xattr_support=maybe ;;
1133         *) enable_xattr_support=no ;;
1134         esac])
1135 AH_TEMPLATE([SUPPORT_XATTRS],
1136 [Define to 1 to add support for extended attributes])
1137 if test x"$enable_xattr_support" = x"no"; then
1138     AC_MSG_RESULT(no)
1139 else
1140     case "$host_os" in
1141     *linux*|*netbsd*)
1142         AC_MSG_RESULT(Using Linux xattrs)
1143         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1144         AC_DEFINE(SUPPORT_XATTRS, 1)
1145         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1146         AC_CHECK_LIB(attr,getxattr)
1147         ;;
1148     darwin*)
1149         AC_MSG_RESULT(Using OS X xattrs)
1150         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1151         AC_DEFINE(SUPPORT_XATTRS, 1)
1152         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1153         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1154         ;;
1155     freebsd*)
1156         AC_MSG_RESULT(Using FreeBSD extattrs)
1157         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1158         AC_DEFINE(SUPPORT_XATTRS, 1)
1159         ;;
1160     solaris*)
1161         AC_MSG_RESULT(Using Solaris xattrs)
1162         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1163         AC_DEFINE(SUPPORT_XATTRS, 1)
1164         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1165         ;;
1166     *)
1167         if test x"$enable_xattr_support" = x"yes"; then
1168             AC_MSG_ERROR(Failed to find extended attribute support)
1169         else
1170             AC_MSG_RESULT(No extended attribute support found)
1171         fi
1172         ;;
1173     esac
1174 fi
1175
1176 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1177     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1178     OLD_CFLAGS="$CFLAGS"
1179     CFLAGS="$CFLAGS -Wno-unused-parameter"
1180     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1181     AC_MSG_RESULT([$rsync_warn_flag])
1182     if test x"$rsync_warn_flag" = x"no"; then
1183         CFLAGS="$OLD_CFLAGS"
1184     fi
1185 fi
1186
1187 case "$CC" in
1188 ' checker'*|checker*)
1189     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1190     ;;
1191 esac
1192
1193 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1194 AC_OUTPUT
1195
1196 AC_MSG_RESULT()
1197 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1198 AC_MSG_RESULT()