configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.1.2pre1],[http://rsync.samba.org/bugzilla.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_EGREP
  45 AC_PROG_INSTALL
  46 AC_PROG_MKDIR_P
  47 AC_PROG_CC_STDC
  48 AC_SUBST(SHELL)
  49 AC_PATH_PROG([PERL], [perl])
  50
  51 AC_DEFINE([_GNU_SOURCE], 1,
  52           [Define _GNU_SOURCE so that we get all necessary prototypes])
  53
  54 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  55         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  56 fi
  57
  58 AC_ARG_ENABLE(profile,
  59         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  60 if test x"$enable_profile" = x"yes"; then
  61         CFLAGS="$CFLAGS -pg"
  62 fi
  63
  64
  65 # Specifically, this turns on panic_action handling.
  66 AC_ARG_ENABLE(maintainer-mode,
  67         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
  68 if test x"$enable_maintainer_mode" = x"yes"; then
  69         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  70 fi
  71
  72
  73 # This is needed for our included version of popt.  Kind of silly, but
  74 # I don't want our version too far out of sync.
  75 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  76
  77 # If GCC, turn on warnings.
  78 if test x"$GCC" = x"yes"; then
  79         CFLAGS="$CFLAGS -Wall -W"
  80 fi
  81
  82 AC_ARG_WITH(included-popt,
  83         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
  84
  85 AC_ARG_WITH(included-zlib,
  86         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
  87
  88 AC_ARG_WITH(protected-args,
  89         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
  90 if test x"$with_protected_args" = x"yes"; then
  91         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
  92 fi
  93
  94 AC_ARG_WITH(rsync-path,
  95         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
  96         [ RSYNC_PATH="$with_rsync_path" ],
  97         [ RSYNC_PATH="rsync" ])
  98
  99 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 100
 101 AC_ARG_WITH(max-daemon-gid,
 102         AS_HELP_STRING([--with-max-daemon-gid=NUM],
 103                        [set maximum number of GIDs in the daemon "gid=LIST" config item (default: 32)]),
 104                        [ MAX_DAEMON_GID_LIST=$with_max_daemon_gid ],
 105                        [ MAX_DAEMON_GID_LIST=32 ])
 106
 107 AC_DEFINE_UNQUOTED(MAX_DAEMON_GID_LIST, $MAX_DAEMON_GID_LIST, [maximum GIDs in a daemon module gid list])
 108
 109 AC_ARG_WITH(rsyncd-conf,
 110         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 111         [ if test ! -z "$with_rsyncd_conf" ; then
 112                 case $with_rsyncd_conf in
 113                         yes|no)
 114                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 115                                 ;;
 116                         /*)
 117                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 118                                 ;;
 119                         *)
 120                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 121                                 ;;
 122                 esac
 123         else
 124                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 125         fi ],
 126         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 127
 128 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 129
 130 AC_ARG_WITH(rsh,
 131         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 132
 133 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 134 if test x$HAVE_REMSH = x1; then
 135         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 136 fi
 137
 138 if test x"$with_rsh" != x; then
 139         RSYNC_RSH="$with_rsh"
 140 else
 141         RSYNC_RSH="ssh"
 142 fi
 143 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 144
 145 AC_CHECK_PROG(HAVE_YODL2MAN, yodl2man, 1, 0)
 146 if test x$HAVE_YODL2MAN = x1; then
 147     MAKE_MAN=man
 148 else
 149     MAKE_MAN=man-copy
 150 fi
 151
 152 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 153 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 154 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 155
 156 AC_ARG_WITH(nobody-group,
 157     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 158     [ NOBODY_GROUP="$with_nobody_group" ])
 159
 160 if test x"$with_nobody_group" = x; then
 161     AC_MSG_CHECKING([the group for user "nobody"])
 162     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 163         NOBODY_GROUP=nobody
 164     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 165         NOBODY_GROUP=nogroup
 166     else
 167         NOBODY_GROUP=nobody # test for others?
 168     fi
 169     AC_MSG_RESULT($NOBODY_GROUP)
 170 fi
 171
 172 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 173 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 174
 175 # arrgh. libc in some old debian version screwed up the largefile
 176 # stuff, getting byte range locking wrong
 177 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 178 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 179 #define _FILE_OFFSET_BITS 64
 180 #include <stdio.h>
 181 #include <fcntl.h>
 182 #include <sys/types.h>
 183 #include <sys/wait.h>
 184
 185 int main(void)
 186 {
 187         struct flock lock;
 188         int status;
 189         char tpl[32] = "/tmp/locktest.XXXXXX";
 190         int fd = mkstemp(tpl);
 191         if (fd < 0) {
 192                 strcpy(tpl, "conftest.dat");
 193                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 194         }
 195
 196         lock.l_type = F_WRLCK;
 197         lock.l_whence = SEEK_SET;
 198         lock.l_start = 0;
 199         lock.l_len = 1;
 200         lock.l_pid = 0;
 201         fcntl(fd,F_SETLK,&lock);
 202         if (fork() == 0) {
 203                 lock.l_start = 1;
 204                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 205         }
 206         wait(&status);
 207         unlink(tpl);
 208         exit(WEXITSTATUS(status));
 209 }
 210 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 211 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 212    AC_SYS_LARGEFILE
 213 fi
 214
 215 ipv6type=unknown
 216 ipv6lib=none
 217 ipv6trylibc=yes
 218
 219 AC_ARG_ENABLE(ipv6,
 220         AS_HELP_STRING([--disable-ipv6],[do not even try to use IPv6]))
 221 if test x"$enable_ipv6" != x"no"; then
 222         AC_MSG_CHECKING([ipv6 stack type])
 223         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 224                 case $i in
 225                 inria)
 226                         # http://www.kame.net/
 227                         AC_EGREP_CPP(yes, [
 228 #include <netinet/in.h>
 229 #ifdef IPV6_INRIA_VERSION
 230 yes
 231 #endif],
 232                                 [ipv6type=$i;
 233                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 234                                 ])
 235                         ;;
 236                 kame)
 237                         # http://www.kame.net/
 238                         AC_EGREP_CPP(yes, [
 239 #include <netinet/in.h>
 240 #ifdef __KAME__
 241 yes
 242 #endif],
 243                                 [ipv6type=$i;
 244                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 245                         ;;
 246                 linux-glibc)
 247                         # http://www.v6.linux.or.jp/
 248                         AC_EGREP_CPP(yes, [
 249 #include <features.h>
 250 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 251 yes
 252 #endif],
 253                                 [ipv6type=$i;
 254 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 255                         ;;
 256                 linux-inet6)
 257                         # http://www.v6.linux.or.jp/
 258                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 259                                 ipv6type=$i
 260                                 ipv6lib=inet6
 261                                 ipv6libdir=/usr/inet6/lib
 262                                 ipv6trylibc=yes;
 263                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 264                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 265                         fi
 266                         ;;
 267                 solaris)
 268                         # http://www.sun.com
 269                         AC_EGREP_CPP(yes, [
 270 #include <netinet/ip6.h>
 271 #ifdef __sun
 272 yes
 273 #endif],
 274                                 [ipv6type=$i;
 275                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 276                         ;;
 277                 toshiba)
 278                         AC_EGREP_CPP(yes, [
 279 #include <sys/param.h>
 280 #ifdef _TOSHIBA_INET6
 281 yes
 282 #endif],
 283                                 [ipv6type=$i;
 284                                 ipv6lib=inet6;
 285                                 ipv6libdir=/usr/local/v6/lib;
 286                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 287                         ;;
 288                 v6d)
 289                         AC_EGREP_CPP(yes, [
 290 #include </usr/local/v6/include/sys/v6config.h>
 291 #ifdef __V6D__
 292 yes
 293 #endif],
 294                                 [ipv6type=$i;
 295                                 ipv6lib=v6;
 296                                 ipv6libdir=/usr/local/v6/lib;
 297                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 298                         ;;
 299                 zeta)
 300                         AC_EGREP_CPP(yes, [
 301 #include <sys/param.h>
 302 #ifdef _ZETA_MINAMI_INET6
 303 yes
 304 #endif],
 305                                 [ipv6type=$i;
 306                                 ipv6lib=inet6;
 307                                 ipv6libdir=/usr/local/v6/lib;
 308                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 309                         ;;
 310                 cygwin)
 311                         AC_EGREP_CPP(yes, [
 312 #include <netinet/in.h>
 313 #ifdef _CYGWIN_IN6_H
 314 yes
 315 #endif],
 316                                 [ipv6type=$i;
 317                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 318                         ;;
 319                 esac
 320                 if test "$ipv6type" != "unknown"; then
 321                         break
 322                 fi
 323         done
 324         AC_MSG_RESULT($ipv6type)
 325
 326         AC_SEARCH_LIBS(getaddrinfo, inet6)
 327 fi
 328
 329 dnl Do you want to disable use of locale functions
 330 AC_ARG_ENABLE([locale],
 331         AS_HELP_STRING([--disable-locale],[disable locale features]))
 332 AH_TEMPLATE([CONFIG_LOCALE],
 333 [Undefine if you do not want locale features.  By default this is defined.])
 334 if test x"$enable_locale" != x"no"; then
 335         AC_DEFINE(CONFIG_LOCALE)
 336 fi
 337
 338 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 339 case $host_os in
 340         *cygwin* ) AC_MSG_RESULT(yes)
 341                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 342                             [Define to 1 if sockets need to be shutdown])
 343                    ;;
 344                * ) AC_MSG_RESULT(no);;
 345 esac
 346
 347 AC_C_BIGENDIAN
 348 AC_HEADER_DIRENT
 349 AC_HEADER_TIME
 350 AC_HEADER_SYS_WAIT
 351 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 352     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 353     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 354     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 355     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 356     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 357     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 358     zlib.h)
 359 AC_HEADER_MAJOR
 360
 361 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 362 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 363 #include <sys/types.h>
 364 #ifdef MAJOR_IN_MKDEV
 365 #include <sys/mkdev.h>
 366 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 367 #  define makedev mkdev
 368 # endif
 369 #elif defined MAJOR_IN_SYSMACROS
 370 #include <sys/sysmacros.h>
 371 #endif
 372
 373 int main(void)
 374 {
 375         dev_t dev = makedev(0, 5, 7);
 376         if (major(dev) != 5 || minor(dev) != 7)
 377                 exit(1);
 378         return 0;
 379 }
 380 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 381 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 382    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 383 fi
 384
 385 AC_CHECK_SIZEOF(int)
 386 AC_CHECK_SIZEOF(long)
 387 AC_CHECK_SIZEOF(long long)
 388 AC_CHECK_SIZEOF(short)
 389 AC_CHECK_SIZEOF(int16_t)
 390 AC_CHECK_SIZEOF(uint16_t)
 391 AC_CHECK_SIZEOF(int32_t)
 392 AC_CHECK_SIZEOF(uint32_t)
 393 AC_CHECK_SIZEOF(int64_t)
 394 AC_CHECK_SIZEOF(off_t)
 395 AC_CHECK_SIZEOF(off64_t)
 396 AC_CHECK_SIZEOF(time_t)
 397
 398 AC_C_INLINE
 399
 400 AC_TYPE_LONG_DOUBLE_WIDER
 401 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 402 if test $ac_cv_c_long_double = yes; then
 403   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 404 fi
 405
 406 AC_TYPE_UID_T
 407 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 408 AC_TYPE_GETGROUPS
 409 AC_CHECK_MEMBERS([struct stat.st_rdev,
 410                   struct stat.st_mtimensec,
 411                   struct stat.st_mtim.tv_nsec],,,[
 412 #ifdef HAVE_SYS_TYPES_H
 413 #include <sys/types.h>
 414 #endif
 415 #ifdef HAVE_SYS_STAT_H
 416 #include <sys/stat.h>
 417 #endif
 418 #ifdef HAVE_UNISTD_H
 419 #include <unistd.h>
 420 #endif])
 421
 422 TYPE_SOCKLEN_T
 423
 424 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 425     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 426 if test x"$rsync_cv_errno" = x"yes"; then
 427    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 428 fi
 429
 430 # The following test taken from the cvs sources
 431 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 432 # These need checks to be before checks for any other functions that
 433 #    might be in the same libraries.
 434 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 435 # libsocket.so which has a bad implementation of gethostbyname (it
 436 # only looks in /etc/hosts), so we only look for -lsocket if we need
 437 # it.
 438 AC_CHECK_FUNCS(connect)
 439 if test x"$ac_cv_func_connect" = x"no"; then
 440     case "$LIBS" in
 441     *-lnsl*) ;;
 442     *) AC_CHECK_LIB(nsl_s, printf) ;;
 443     esac
 444     case "$LIBS" in
 445     *-lnsl*) ;;
 446     *) AC_CHECK_LIB(nsl, printf) ;;
 447     esac
 448     case "$LIBS" in
 449     *-lsocket*) ;;
 450     *) AC_CHECK_LIB(socket, connect) ;;
 451     esac
 452     case "$LIBS" in
 453     *-linet*) ;;
 454     *) AC_CHECK_LIB(inet, connect) ;;
 455     esac
 456     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 457     dnl has been cached.
 458     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 459        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 460         # ac_cv_func_connect=yes
 461         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 462         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 463     fi
 464 fi
 465
 466 AC_SEARCH_LIBS(inet_ntop, resolv)
 467
 468 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 469 # accept either iconv_open or libiconv_open, since some include files map
 470 # the former to the latter.
 471 AC_SEARCH_LIBS(iconv_open, iconv)
 472 AC_SEARCH_LIBS(libiconv_open, iconv)
 473
 474 AC_MSG_CHECKING([for iconv declaration])
 475 AC_CACHE_VAL(am_cv_proto_iconv, [
 476     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 477 #include <stdlib.h>
 478 #include <iconv.h>
 479 extern
 480 #ifdef __cplusplus
 481 "C"
 482 #endif
 483 #if defined(__STDC__) || defined(__cplusplus)
 484 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 485 #else
 486 size_t iconv();
 487 #endif
 488 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 489       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 490     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 491 AC_MSG_RESULT([$]{ac_t:-
 492          }[$]am_cv_proto_iconv)
 493 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 494                    [Define as const if the declaration of iconv() needs const.])
 495
 496 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 497
 498 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 499
 500 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 501 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 502 #include <sys/socket.h>])
 503
 504 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 505 #   builtin getaddrinfo if one of the defines don't exist
 506 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 507                rsync_cv_HAVE_GETADDR_DEFINES,[
 508                         AC_EGREP_CPP(yes, [
 509                         #include <sys/types.h>
 510                         #include <sys/socket.h>
 511                         #include <netdb.h>
 512                         #ifdef AI_PASSIVE
 513                         yes
 514                         #endif],
 515                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 516                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 517 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 518         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 519         # something else so we must include <netdb.h> to get the
 520         # redefinition.
 521         AC_CHECK_FUNCS(getaddrinfo, ,
 522                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 523                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 524                 #include <sys/socket.h>
 525                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 526                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 527                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 528                         AC_LIBOBJ([getaddrinfo])])])
 529     ],[AC_LIBOBJ([getaddrinfo])])
 530
 531 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 532                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 533                 [],
 534                 [
 535 #include <sys/types.h>
 536 #include <sys/socket.h>
 537 ])
 538
 539 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 540                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 541                 [],
 542                 [
 543 #include <sys/types.h>
 544 #include <sys/socket.h>
 545 #include <netinet/in.h>
 546 ])
 547
 548 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 549                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 550                 [],
 551                 [
 552 #include <sys/types.h>
 553 #include <sys/socket.h>
 554 #include <netinet/in.h>
 555 ])
 556
 557 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 558                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 559                 [],
 560                 [
 561 #include <sys/types.h>
 562 #include <sys/socket.h>
 563 #include <netinet/in.h>
 564 ])
 565
 566 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 567 #if HAVE_SYS_TYPES_H
 568 # include <sys/types.h>
 569 #endif
 570 #if HAVE_SYS_STAT_H
 571 # include <sys/stat.h>
 572 #endif
 573 #if STDC_HEADERS
 574 # include <stdlib.h>
 575 # include <stddef.h>
 576 #else
 577 # if HAVE_STDLIB_H
 578 #  include <stdlib.h>
 579 # endif
 580 #endif
 581 ])
 582
 583 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 584 #
 585 AC_CHECK_FUNCS(strcasecmp)
 586 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 587     AC_CHECK_LIB(resolv, strcasecmp)
 588 fi
 589
 590 AC_CHECK_FUNCS(aclsort)
 591 if test x"$ac_cv_func_aclsort" = x"no"; then
 592     AC_CHECK_LIB(sec, aclsort)
 593 fi
 594
 595 dnl At the moment we don't test for a broken memcmp(), because all we
 596 dnl need to do is test for equality, not comparison, and it seems that
 597 dnl every platform has a memcmp that can do at least that.
 598 dnl AC_FUNC_MEMCMP
 599
 600 AC_FUNC_UTIME_NULL
 601 AC_FUNC_ALLOCA
 602 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 603     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 604     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 605     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 606     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 607     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 608     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 609     initgroups utimensat posix_fallocate attropen setvbuf usleep)
 610
 611 dnl cygwin iconv.h defines iconv_open as libiconv_open
 612 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 613     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 614 fi
 615
 616 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 617
 618 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 619 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 620 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 621 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 622     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 623 fi
 624
 625 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 626 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 627 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 628 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 629     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 630 fi
 631
 632 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 633     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 634     case $host_os in
 635     *cygwin*)
 636         AC_MSG_RESULT(yes)
 637         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 638                   [Define if posix_fallocate is efficient (Cygwin)])
 639         ;;
 640     *)
 641         AC_MSG_RESULT(no)
 642         ;;
 643     esac
 644 fi
 645
 646 dnl End of preallocation stuff
 647
 648 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 649 if test $ac_cv_func_getpgrp = yes; then
 650     AC_FUNC_GETPGRP
 651 fi
 652
 653 AC_ARG_ENABLE(iconv-open,
 654     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 655     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 656
 657 if test x"$enable_iconv_open" != x"no"; then
 658     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 659 fi
 660
 661 AC_ARG_ENABLE(iconv,
 662     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 663     [], [enable_iconv=$enable_iconv_open])
 664 AH_TEMPLATE([ICONV_OPTION],
 665 [Define if you want the --iconv option.  Specifing a value will set the
 666 default iconv setting (a NULL means no --iconv processing by default).])
 667 if test x"$enable_iconv" != x"no"; then
 668         if test x"$enable_iconv" = x"yes"; then
 669                 AC_DEFINE(ICONV_OPTION, NULL)
 670         else
 671                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 672         fi
 673         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 674 fi
 675
 676 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 677   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 678 #if HAVE_UNISTD_H
 679 # include <unistd.h>
 680 #endif
 681 #include <stdlib.h>
 682 #include <errno.h>
 683     main() {
 684         char const *dangling_symlink = "conftest.dangle";
 685         unlink(dangling_symlink);
 686         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 687         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1);
 688         exit(0);
 689     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 690 if test $rsync_cv_chown_modifies_symlink = yes; then
 691   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 692 fi
 693
 694 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 695   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 696 #if HAVE_UNISTD_H
 697 # include <unistd.h>
 698 #endif
 699 #include <stdlib.h>
 700 #include <errno.h>
 701 #define FILENAME "conftest.dangle"
 702     main() {
 703         unlink(FILENAME);
 704         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 705         unlink(FILENAME "2");
 706         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 707         exit(0);
 708     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 709 if test $rsync_cv_can_hardlink_symlink = yes; then
 710   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 711 fi
 712
 713 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 714   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 715 #if HAVE_UNISTD_H
 716 # include <unistd.h>
 717 #endif
 718 #include <stdlib.h>
 719 #include <errno.h>
 720 #define FILENAME "conftest.fifi"
 721     main() {
 722         unlink(FILENAME);
 723         if (mkfifo(FILENAME, 0777) < 0) abort();
 724         unlink(FILENAME "2");
 725         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 726         exit(0);
 727     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 728 if test $rsync_cv_can_hardlink_special = yes; then
 729     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 730 fi
 731
 732 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 733 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 734 #include <sys/types.h>
 735 #include <sys/socket.h>
 736
 737 main() {
 738        int fd[2];
 739        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 740 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 741 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 742     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 743 fi
 744
 745 AC_REPLACE_FUNCS([getpass])
 746
 747 if test x"$with_included_popt" != x"yes"; then
 748     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 749 fi
 750 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 751     # If the system has /usr/include/popt/popt.h, we enable the
 752     # included popt because an attempt to "#include <popt/popt.h>"
 753     # would use our included header file anyway (due to -I.), and
 754     # might conflict with the system popt.
 755     with_included_popt=yes
 756 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 757     with_included_popt=yes
 758 fi
 759
 760 AC_MSG_CHECKING([whether to use included libpopt])
 761 if test x"$with_included_popt" = x"yes"; then
 762     AC_MSG_RESULT($srcdir/popt)
 763     BUILD_POPT='$(popt_OBJS)'
 764     CFLAGS="-I$srcdir/popt $CFLAGS"
 765     if test x"$ALLOCA" != x
 766     then
 767         # this can be removed when/if we add an included alloca.c;
 768         #  see autoconf documentation on AC_FUNC_ALLOCA
 769         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 770     fi
 771 else
 772     AC_MSG_RESULT(no)
 773 fi
 774
 775 # We default to using our zlib unless --with-included-zlib=no is given.
 776 if test x"$with_included_zlib" != x"no"; then
 777     with_included_zlib=yes
 778 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
 779     with_included_zlib=yes
 780 fi
 781 if test x"$with_included_zlib" != x"yes"; then
 782     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
 783 fi
 784
 785 AC_MSG_CHECKING([whether to use included zlib])
 786 if test x"$with_included_zlib" = x"yes"; then
 787     AC_MSG_RESULT($srcdir/zlib)
 788     BUILD_ZLIB='$(zlib_OBJS)'
 789     CFLAGS="-I$srcdir/zlib $CFLAGS"
 790 else
 791     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
 792     AC_MSG_RESULT(no)
 793 fi
 794
 795 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 796 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
 797 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 798     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 799 fi
 800
 801 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 802 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
 803 #include <dirent.h>
 804 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 805 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 806 di->d_name[0] == 0) exit(0); exit(1);} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
 807 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 808     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 809 fi
 810
 811 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
 812 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 813 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
 814 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
 815     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 816 fi
 817
 818 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 819 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
 820 #include <unistd.h>]], [[struct timeval tv; exit(gettimeofday(&tv, NULL));]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
 821 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 822     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 823 fi
 824
 825 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 826 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 827 #include <sys/types.h>
 828 #include <stdarg.h>
 829 void foo(const char *format, ...) {
 830        va_list ap;
 831        int len;
 832        char buf[5];
 833
 834        va_start(ap, format);
 835        len = vsnprintf(0, 0, format, ap);
 836        va_end(ap);
 837        if (len != 5) exit(1);
 838
 839        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 840
 841        exit(0);
 842 }
 843 main() { foo("hello"); }
 844 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
 845 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 846     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 847 fi
 848
 849
 850 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 851 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 852 #include <sys/types.h>
 853 #include <sys/stat.h>
 854 #include <unistd.h>
 855 main() {
 856   struct stat st;
 857   char tpl[20]="/tmp/test.XXXXXX";
 858   int fd = mkstemp(tpl);
 859   if (fd == -1) exit(1);
 860   unlink(tpl);
 861   if (fstat(fd, &st) != 0) exit(1);
 862   if ((st.st_mode & 0777) != 0600) exit(1);
 863   exit(0);
 864 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
 865 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 866     case $host_os in
 867     hpux*)
 868         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 869         dnl so we noisily skip using it.  See HP change request JAGaf34426
 870         dnl for details. (sbonds)
 871         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 872         ;;
 873     *)
 874         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 875         ;;
 876     esac
 877 fi
 878
 879
 880 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 881 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 882 #include <stdio.h>
 883 #include <sys/stat.h>
 884 #include <errno.h>
 885 main() { int rc, ec; char *fn = "fifo-test";
 886 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 887 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 888 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
 889 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 890     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 891 fi
 892
 893 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 894 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 895 #include <stdio.h>
 896 #include <sys/stat.h>
 897 #include <errno.h>
 898 main() { int rc, ec; char *fn = "sock-test";
 899 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 900 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 901 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
 902 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 903     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 904 fi
 905
 906 #
 907 # The following test was mostly taken from the tcl/tk plus patches
 908 #
 909 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 910 rm -rf conftest*
 911 cat > conftest.$ac_ext <<EOF
 912 int main() { return 0; }
 913 EOF
 914 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 915 if test -f conftest..o; then
 916     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 917 else
 918     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 919 fi
 920 rm -rf conftest*
 921 ])
 922 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 923     OBJ_SAVE="#"
 924     OBJ_RESTORE="#"
 925     CC_SHOBJ_FLAG='-o $@'
 926 else
 927     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 928     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 929     CC_SHOBJ_FLAG=""
 930 fi
 931
 932 AC_SUBST(OBJ_SAVE)
 933 AC_SUBST(OBJ_RESTORE)
 934 AC_SUBST(CC_SHOBJ_FLAG)
 935 AC_SUBST(BUILD_POPT)
 936 AC_SUBST(BUILD_ZLIB)
 937 AC_SUBST(MAKE_MAN)
 938
 939 AC_PATH_PROG([STUNNEL], [stunnel], [stunnel], [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 940 AC_PATH_PROG([STUNNEL4], [stunnel4], [$STUNNEL], [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 941
 942 AC_CHECK_FUNCS(_acl __acl _facl __facl)
 943 #################################################
 944 # check for ACL support
 945
 946 AC_MSG_CHECKING([whether to support ACLs])
 947 AC_ARG_ENABLE(acl-support,
 948         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
 949
 950 if test x"$enable_acl_support" = x"no"; then
 951     AC_MSG_RESULT(no)
 952 else
 953     case "$host_os" in
 954     *sysv5*)
 955         AC_MSG_RESULT(Using UnixWare ACLs)
 956         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
 957         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
 958         ;;
 959     solaris*|*cygwin*)
 960         AC_MSG_RESULT(Using solaris ACLs)
 961         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
 962         AC_DEFINE(SUPPORT_ACLS, 1)
 963         ;;
 964     *hpux*)
 965         AC_MSG_RESULT(Using HPUX ACLs)
 966         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
 967         AC_DEFINE(SUPPORT_ACLS, 1)
 968         ;;
 969     *irix*)
 970         AC_MSG_RESULT(Using IRIX ACLs)
 971         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
 972         AC_DEFINE(SUPPORT_ACLS, 1)
 973         ;;
 974     *aix*)
 975         AC_MSG_RESULT(Using AIX ACLs)
 976         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
 977         AC_DEFINE(SUPPORT_ACLS, 1)
 978         ;;
 979     *osf*)
 980         AC_MSG_RESULT(Using Tru64 ACLs)
 981         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
 982         AC_DEFINE(SUPPORT_ACLS, 1)
 983         LIBS="$LIBS -lpacl"
 984         ;;
 985     darwin*)
 986         AC_MSG_RESULT(Using OS X ACLs)
 987         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
 988         AC_DEFINE(SUPPORT_ACLS, 1)
 989         ;;
 990     *)
 991         AC_MSG_RESULT(running tests:)
 992         AC_CHECK_LIB(acl,acl_get_file)
 993         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
 994             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 995 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
 996         AC_MSG_CHECKING(ACL test results)
 997         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
 998             AC_MSG_RESULT(Using posix ACLs)
 999             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1000             AC_DEFINE(SUPPORT_ACLS, 1)
1001             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1002                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1003 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1004             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1005                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1006             fi
1007         else
1008             if test x"$enable_acl_support" = x"yes"; then
1009                 AC_MSG_ERROR(Failed to find ACL support)
1010             else
1011                 AC_MSG_RESULT(No ACL support found)
1012             fi
1013         fi
1014         ;;
1015     esac
1016 fi
1017
1018 #################################################
1019 # check for extended attribute support
1020 AC_MSG_CHECKING(whether to support extended attributes)
1021 AC_ARG_ENABLE(xattr-support,
1022     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1023     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1024         *yes*) enable_xattr_support=maybe ;;
1025         *) enable_xattr_support=no ;;
1026         esac])
1027 AH_TEMPLATE([SUPPORT_XATTRS],
1028 [Define to 1 to add support for extended attributes])
1029 if test x"$enable_xattr_support" = x"no"; then
1030     AC_MSG_RESULT(no)
1031 else
1032     case "$host_os" in
1033     *linux*)
1034         AC_MSG_RESULT(Using Linux xattrs)
1035         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs])
1036         AC_DEFINE(SUPPORT_XATTRS, 1)
1037         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1038         AC_CHECK_LIB(attr,getxattr)
1039         ;;
1040     darwin*)
1041         AC_MSG_RESULT(Using OS X xattrs)
1042         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1043         AC_DEFINE(SUPPORT_XATTRS, 1)
1044         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1045         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1046         ;;
1047     freebsd*)
1048         AC_MSG_RESULT(Using FreeBSD extattrs)
1049         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1050         AC_DEFINE(SUPPORT_XATTRS, 1)
1051         ;;
1052     solaris*)
1053         AC_MSG_RESULT(Using Solaris xattrs)
1054         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1055         AC_DEFINE(SUPPORT_XATTRS, 1)
1056         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1057         ;;
1058     *)
1059         if test x"$enable_xattr_support" = x"yes"; then
1060             AC_MSG_ERROR(Failed to find extended attribute support)
1061         else
1062             AC_MSG_RESULT(No extended attribute support found)
1063         fi
1064         ;;
1065     esac
1066 fi
1067
1068 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1069     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1070     OLD_CFLAGS="$CFLAGS"
1071     CFLAGS="$CFLAGS -Wno-unused-parameter"
1072     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1073     AC_MSG_RESULT([$rsync_warn_flag])
1074     if test x"$rsync_warn_flag" = x"no"; then
1075         CFLAGS="$OLD_CFLAGS"
1076     fi
1077 fi
1078
1079 case "$CC" in
1080 ' checker'*|checker*)
1081     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1082     ;;
1083 esac
1084
1085 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1086 AC_OUTPUT
1087
1088 AC_MSG_RESULT()
1089 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1090 AC_MSG_RESULT()
1091 if test x$HAVE_YODL2MAN != x1; then
1092     AC_MSG_RESULT([    Note that yodl2man was not found, so pre-existing manpage files will be])
1093     AC_MSG_RESULT([    used w/o change (if available) -- no .yo file changes will be used.])
1094     AC_MSG_RESULT()
1095 fi