configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 # We need the C++ compiler only for testing.
  54 AC_PROG_CXX
  55 AC_CHECK_TOOL(READELF, readelf, false)
  56
  57 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
  58   AC_MSG_ERROR([you must configure in a separate build directory])
  59 fi
  60
  61 # This will get text that should go into config.make.
  62 config_vars=
  63
  64 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  65 AC_ARG_WITH([gd],
  66             AC_HELP_STRING([--with-gd=DIR],
  67                            [find libgd include dir and library with prefix DIR]),
  68             [dnl
  69 case "$with_gd" in
  70 yes|''|no) ;;
  71 *) libgd_include="-I$withval/include"
  72    libgd_ldflags="-L$withval/lib" ;;
  73 esac
  74 ])
  75 AC_ARG_WITH([gd-include],
  76             AC_HELP_STRING([--with-gd-include=DIR],
  77                            [find libgd include files in DIR]),
  78             [dnl
  79 case "$with_gd_include" in
  80 ''|no) ;;
  81 *) libgd_include="-I$withval" ;;
  82 esac
  83 ])
  84 AC_ARG_WITH([gd-lib],
  85             AC_HELP_STRING([--with-gd-lib=DIR],
  86                            [find libgd library files in DIR]),
  87             [dnl
  88 case "$with_gd_lib" in
  89 ''|no) ;;
  90 *) libgd_ldflags="-L$withval" ;;
  91 esac
  92 ])
  93
  94 if test -n "$libgd_include"; then
  95   config_vars="$config_vars
  96 CFLAGS-memusagestat.c = $libgd_include"
  97 fi
  98 if test -n "$libgd_ldflags"; then
  99   config_vars="$config_vars
 100 libgd-LDFLAGS = $libgd_ldflags"
 101 fi
 102
 103 dnl Arguments to specify presence of other packages/features.
 104 AC_ARG_WITH([fp],
 105             AC_HELP_STRING([--with-fp],
 106                            [if using floating-point hardware @<:@default=yes@:>@]),
 107             [with_fp=$withval],
 108             [with_fp=yes])
 109 AC_SUBST(with_fp)
 110 AC_ARG_WITH([binutils],
 111             AC_HELP_STRING([--with-binutils=PATH],
 112                            [specify location of binutils (as and ld)]),
 113             [path_binutils=$withval],
 114             [path_binutils=''])
 115 AC_ARG_WITH([selinux],
 116             AC_HELP_STRING([--with-selinux],
 117                            [if building with SELinux support]),
 118             [with_selinux=$withval],
 119             [with_selinux=auto])
 120
 121 AC_ARG_WITH([headers],
 122             AC_HELP_STRING([--with-headers=PATH],
 123                            [location of system headers to use
 124                             (for example /usr/src/linux/include)
 125                             @<:@default=compiler default@:>@]),
 126             [sysheaders=$withval],
 127             [sysheaders=''])
 128 AC_SUBST(sysheaders)
 129
 130 AC_SUBST(use_default_link)
 131 AC_ARG_WITH([default-link],
 132             AC_HELP_STRING([--with-default-link],
 133                            [do not use explicit linker scripts]),
 134             [use_default_link=$withval],
 135             [use_default_link=default])
 136
 137 AC_ARG_ENABLE([sanity-checks],
 138               AC_HELP_STRING([--disable-sanity-checks],
 139                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 140               [enable_sanity=$enableval],
 141               [enable_sanity=yes])
 142
 143 AC_ARG_ENABLE([shared],
 144               AC_HELP_STRING([--enable-shared],
 145                              [build shared library @<:@default=yes if GNU ld@:>@]),
 146               [shared=$enableval],
 147               [shared=yes])
 148 AC_ARG_ENABLE([profile],
 149               AC_HELP_STRING([--enable-profile],
 150                              [build profiled library @<:@default=no@:>@]),
 151               [profile=$enableval],
 152               [profile=no])
 153
 154 AC_ARG_ENABLE([oldest-abi],
 155               AC_HELP_STRING([--enable-oldest-abi=ABI],
 156                              [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
 157               [oldest_abi=$enableval],
 158               [oldest_abi=no])
 159 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
 160   oldest_abi=default
 161 else
 162   AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
 163 fi
 164 AC_SUBST(oldest_abi)
 165
 166 AC_ARG_ENABLE([hardcoded-path-in-tests],
 167               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 168                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 169               [hardcoded_path_in_tests=$enableval],
 170               [hardcoded_path_in_tests=no])
 171 AC_SUBST(hardcoded_path_in_tests)
 172
 173 AC_ARG_ENABLE([stackguard-randomization],
 174               AC_HELP_STRING([--enable-stackguard-randomization],
 175                              [initialize __stack_chk_guard canary with a random number at program start]),
 176               [enable_stackguard_randomize=$enableval],
 177               [enable_stackguard_randomize=no])
 178 if test "$enable_stackguard_randomize" = yes; then
 179   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 180 fi
 181
 182 AC_ARG_ENABLE([lock-elision],
 183               AC_HELP_STRING([--enable-lock-elision[=yes/no]],
 184                              [Enable lock elision for pthread mutexes by default]),
 185               [enable_lock_elision=$enableval],
 186               [enable_lock_elision=no])
 187 if test "$enable_lock_elision" = yes ; then
 188   AC_DEFINE(ENABLE_LOCK_ELISION)
 189 fi
 190
 191 dnl Generic infrastructure for drop-in additions to libc.
 192 AC_ARG_ENABLE([add-ons],
 193               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 194                              [configure and build add-ons in DIR1,DIR2,...
 195                               search for add-ons if no parameter given]),
 196                              , [enable_add_ons=yes])
 197
 198 AC_ARG_ENABLE([hidden-plt],
 199               AC_HELP_STRING([--disable-hidden-plt],
 200                              [do not hide internal function calls to avoid PLT]),
 201               [hidden=$enableval],
 202               [hidden=yes])
 203 if test "x$hidden" = xno; then
 204   AC_DEFINE(NO_HIDDEN)
 205 fi
 206
 207 AC_ARG_ENABLE([bind-now],
 208               AC_HELP_STRING([--enable-bind-now],
 209                              [disable lazy relocations in DSOs]),
 210               [bindnow=$enableval],
 211               [bindnow=no])
 212 AC_SUBST(bindnow)
 213
 214 dnl On some platforms we cannot use dynamic loading.  We must provide
 215 dnl static NSS modules.
 216 AC_ARG_ENABLE([static-nss],
 217               AC_HELP_STRING([--enable-static-nss],
 218                              [build static NSS modules @<:@default=no@:>@]),
 219               [static_nss=$enableval],
 220               [static_nss=no])
 221 dnl Enable static NSS also if we build no shared objects.
 222 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 223   static_nss=yes
 224   AC_DEFINE(DO_STATIC_NSS)
 225 fi
 226
 227 AC_ARG_ENABLE([force-install],
 228               AC_HELP_STRING([--disable-force-install],
 229                              [don't force installation of files from this package, even if they are older than the installed files]),
 230               [force_install=$enableval],
 231               [force_install=yes])
 232 AC_SUBST(force_install)
 233
 234 AC_ARG_ENABLE([maintainer-mode],
 235               AC_HELP_STRING([--enable-maintainer-mode],
 236                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 237               [maintainer=$enableval],
 238               [maintainer=no])
 239
 240 dnl On some platforms we allow dropping compatibility with all kernel
 241 dnl versions.
 242 AC_ARG_ENABLE([kernel],
 243               AC_HELP_STRING([--enable-kernel=VERSION],
 244                              [compile for compatibility with kernel not older than VERSION]),
 245               [minimum_kernel=$enableval],
 246               [])
 247 dnl Prevent unreasonable values.
 248 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 249   # Better nothing than this.
 250   minimum_kernel=""
 251 else
 252   if test "$minimum_kernel" = current; then
 253     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 254   fi
 255 fi
 256
 257 dnl For the development we sometimes want gcc to issue even more warnings.
 258 dnl This is not the default since many of the extra warnings are not
 259 dnl appropriate.
 260 AC_ARG_ENABLE([all-warnings],
 261               AC_HELP_STRING([--enable-all-warnings],
 262                              [enable all useful warnings gcc can issue]),
 263               [all_warnings=$enableval],
 264               [])
 265 AC_SUBST(all_warnings)
 266
 267 AC_ARG_ENABLE([multi-arch],
 268               AC_HELP_STRING([--enable-multi-arch],
 269                              [enable single DSO with optimizations for multiple architectures]),
 270               [multi_arch=$enableval],
 271               [multi_arch=default])
 272
 273 AC_ARG_ENABLE([nss-crypt],
 274               AC_HELP_STRING([--enable-nss-crypt],
 275                              [enable libcrypt to use nss]),
 276               [nss_crypt=$enableval],
 277               [nss_crypt=no])
 278 if test x$nss_crypt = xyes; then
 279   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 280   if test $? -ne 0; then
 281     AC_MSG_ERROR([cannot find include directory with nss-config])
 282   fi
 283   old_CFLAGS="$CFLAGS"
 284   CFLAGS="$CFLAGS $nss_includes"
 285   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 286 #include <hasht.h>
 287 #include <nsslowhash.h>
 288 void f (void) { NSSLOW_Init (); }])],
 289              libc_cv_nss_crypt=yes,
 290              AC_MSG_ERROR([
 291 cannot find NSS headers with lowlevel hash function interfaces]))
 292   old_LIBS="$LIBS"
 293   LIBS="$LIBS -lfreebl3"
 294   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 295 #include <hasht.h>
 296 #include <nsslowhash.h>],
 297                                   [NSSLOW_Init();])],
 298                  libc_cv_nss_crypt=yes,
 299                  AC_MSG_ERROR([
 300 cannot link program using lowlevel NSS hash functions]))
 301   CFLAGS="$old_CFLAGS"
 302   LIBS="$old_LIBS"
 303 else
 304   libc_cv_nss_crypt=no
 305 fi
 306 AC_SUBST(libc_cv_nss_crypt)
 307
 308
 309 AC_ARG_ENABLE([obsolete-rpc],
 310               AC_HELP_STRING([--enable-obsolete-rpc],
 311                              [build and install the obsolete RPC code for link-time usage]),
 312               [link_obsolete_rpc=$enableval],
 313               [link_obsolete_rpc=no])
 314 AC_SUBST(link_obsolete_rpc)
 315
 316 if test "$link_obsolete_rpc" = yes; then
 317   AC_DEFINE(LINK_OBSOLETE_RPC)
 318 fi
 319
 320 AC_ARG_ENABLE([systemtap],
 321               [AS_HELP_STRING([--enable-systemtap],
 322                [enable systemtap static probe points @<:@default=no@:>@])],
 323               [systemtap=$enableval],
 324               [systemtap=no])
 325 if test "x$systemtap" != xno; then
 326   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 327   old_CFLAGS="$CFLAGS"
 328   CFLAGS="-std=gnu99 $CFLAGS"
 329   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 330 void foo (int i, void *p)
 331 {
 332   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 333        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 334 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 335   CFLAGS="$old_CFLAGS"])
 336   if test $libc_cv_sdt = yes; then
 337     AC_DEFINE([USE_STAP_PROBE])
 338   elif test "x$systemtap" != xauto; then
 339     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 340   fi
 341 fi
 342
 343 AC_ARG_ENABLE([build-nscd],
 344               [AS_HELP_STRING([--disable-build-nscd],
 345                [disable building and installing the nscd daemon])],
 346               [build_nscd=$enableval],
 347               [build_nscd=default])
 348 AC_SUBST(build_nscd)
 349
 350 # Note the use of $use_nscd is near the bottom of the file.
 351 AC_ARG_ENABLE([nscd],
 352               [AS_HELP_STRING([--disable-nscd],
 353                [library functions will not contact the nscd daemon])],
 354               [use_nscd=$enableval],
 355               [use_nscd=yes])
 356
 357 AC_ARG_ENABLE([pt_chown],
 358               [AS_HELP_STRING([--enable-pt_chown],
 359                [Enable building and installing pt_chown])],
 360               [build_pt_chown=$enableval],
 361               [build_pt_chown=no])
 362 AC_SUBST(build_pt_chown)
 363 if test "$build_pt_chown" = yes; then
 364   AC_DEFINE(HAVE_PT_CHOWN)
 365 fi
 366
 367 # The way shlib-versions is used to generate soversions.mk uses a
 368 # fairly simplistic model for name recognition that can't distinguish
 369 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 370 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 371 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 372 case "$host_os" in
 373 linux*)
 374   ;;
 375 gnu*)
 376   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 377   ;;
 378 esac
 379
 380 # We keep the original values in `$config_*' and never modify them, so we
 381 # can write them unchanged into config.make.  Everything else uses
 382 # $machine, $vendor, and $os, and changes them whenever convenient.
 383 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 384
 385 # Don't allow vendor == "unknown"
 386 test "$config_vendor" = unknown && config_vendor=
 387 config_os="`echo $config_os | sed 's/^unknown-//'`"
 388
 389 # Some configurations imply other options.
 390 elf=yes
 391
 392 # The configure fragment of an add-on port can modify these to supplement
 393 # or override the table in the case statement below.  No fragment should
 394 # ever change the config_* variables, however.
 395 machine=$config_machine
 396 vendor=$config_vendor
 397 os=$config_os
 398 base_os=''
 399
 400 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 401 # Unify this here.
 402 if test "$machine" = rs6000; then
 403   machine="powerpc"
 404 fi
 405
 406 # Braindead PowerPC box with absolutely no FPU.
 407 case "$machine-$host_os" in
 408   powerpc*-*soft)
 409     with_fp=no
 410     ;;
 411 esac
 412
 413 submachine=
 414 AC_ARG_WITH([cpu],
 415             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 416             [dnl
 417   case "$withval" in
 418   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 419   no) ;;
 420   *) submachine="$withval" ;;
 421   esac
 422 ])
 423
 424 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
 425 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 426
 427 # An add-on can set this when it wants to disable the sanity check below.
 428 libc_config_ok=no
 429
 430 dnl Having this here, though empty, makes sure that if add-ons' fragments
 431 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 432 dnl our AC_OUTPUT will actually use it.
 433 AC_CONFIG_SUBDIRS()
 434
 435 case "$enable_add_ons" in
 436 ''|no) add_ons= ;;
 437 yes|'*')
 438  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 439           sed 's@/[[^/]]*$@@' | sort | uniq`
 440          add_ons_automatic=yes
 441          ;;
 442 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 443        add_ons_automatic=no ;;
 444 esac
 445
 446 configured_add_ons=
 447 add_ons_sfx=
 448 add_ons_pfx=
 449 if test x"$add_ons" != x; then
 450   for f in $add_ons; do
 451     # Some sanity checks
 452     case "$f" in
 453     crypt)
 454       AC_MSG_ERROR([
 455 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 456 *** part of glibc and using the old add-on will not work with this
 457 *** release.  Start again with fresh sources and without the old
 458 *** \`crypt' add-on.])
 459     ;;
 460     localedata)
 461       AC_MSG_ERROR([
 462 *** It seems that you're using an old \`localedata' add-on.  localedata
 463 *** is now part of glibc and using the old add-on will not work with
 464 *** this release.  Start again with fresh sources and without the old
 465 *** \`localedata' add-on.])
 466     ;;
 467     esac
 468   done
 469
 470   # Now source each add-on's configure fragment.
 471   # The fragments can use $srcdir/$libc_add_on to find themselves,
 472   # and test $add_ons_automatic to see if they were explicitly requested.
 473   # A fragment can clear (or even change) $libc_add_on to affect
 474   # whether it goes into the list to be actually used in the build.
 475   use_add_ons=
 476   for libc_add_on in $add_ons; do
 477     # Test whether such a directory really exists.
 478     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 479     case "$libc_add_on" in
 480     /*)
 481       libc_add_on_srcdir=$libc_add_on
 482       ;;
 483     *)
 484       test -d "$srcdir/$libc_add_on" || {
 485         if test -d "$libc_add_on"; then
 486           libc_add_on="`pwd`/$libc_add_on"
 487         else
 488           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 489         fi
 490       }
 491       libc_add_on_srcdir=$srcdir/$libc_add_on
 492       ;;
 493     esac
 494
 495     libc_add_on_frag=$libc_add_on_srcdir/configure
 496     libc_add_on_canonical=
 497     libc_add_on_config_subdirs=
 498     if test -r "$libc_add_on_frag"; then
 499       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 500       libc_add_on_canonical=unknown
 501       libc_add_on_subdirs=
 502       . "$libc_add_on_frag"
 503       test -z "$libc_add_on" || {
 504         configured_add_ons="$configured_add_ons $libc_add_on"
 505         if test "x$libc_add_on_canonical" = xunknown; then
 506           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 507         fi
 508         for d in $libc_add_on_subdirs; do
 509           case "$libc_add_on" in
 510           /*) subdir_srcdir="$libc_add_on" ;;
 511           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 512           esac
 513           case "$d" in
 514           .)
 515             d="${libc_add_on_canonical:-$libc_add_on}"
 516             ;;
 517           /*)
 518             subdir_srcdir="$d"
 519             ;;
 520           *)
 521             subdir_srcdir="$subdir_srcdir/$d"
 522             ;;
 523           esac
 524           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 525           add_on_subdirs="$add_on_subdirs $d"
 526           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 527 $d-srcdir = $subdir_srcdir"
 528         done
 529         for d in $libc_add_on_config_subdirs; do
 530           case "$d" in
 531           /*) AC_MSG_ERROR(dnl
 532 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 533           esac
 534           if test ! -d "$libc_add_on_srcdir/$d"; then
 535             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 536           fi
 537           case "$libc_add_on" in
 538           /*) AC_MSG_ERROR(dnl
 539 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 540           esac
 541           subdirs="$subdirs $libc_add_on/$d"
 542         done
 543       }
 544     fi
 545     if test -n "$libc_add_on"; then
 546       LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
 547       use_add_ons="$use_add_ons $libc_add_on"
 548       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 549       test -z "$libc_add_on_canonical" ||
 550       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 551     fi
 552   done
 553   # Use echo to strip excess whitespace.
 554   add_ons="`echo $use_add_ons`"
 555 fi
 556 AC_SUBST(add_ons)
 557 AC_SUBST(add_on_subdirs)
 558
 559
 560 ###
 561 ### I put this here to prevent those annoying emails from people who cannot
 562 ### read and try to compile glibc on unsupported platforms.  --drepper
 563 ###
 564 ### By using the undocumented --enable-hacker-mode option for configure
 565 ### one can skip this test to make the configuration not fail for unsupported
 566 ### platforms.
 567 ###
 568 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 569   case "$machine-$host_os" in
 570   *-linux* | *-gnu*)
 571     ;;
 572   *)
 573     echo "*** The GNU C library is currently not available for this platform."
 574     echo "*** So far nobody cared to port it and if there is no volunteer it"
 575     echo "*** might never happen.  So, if you have interest to see glibc on"
 576     echo "*** this platform visit"
 577     echo "***   http://www.gnu.org/software/libc/porting.html"
 578     echo "*** and join the group of porters"
 579     exit 1
 580     ;;
 581   esac
 582 fi
 583
 584 dnl We need to use [ and ] for other purposes for a while now.
 585 changequote(,)dnl
 586 # Expand the configuration machine name into a subdirectory by architecture
 587 # type and particular chip.  If an add-on configure fragment already set
 588 # base_machine, we don't change it.
 589 test -n "$base_machine" || case "$machine" in
 590 i[4567]86)      base_machine=i386 machine=i386/$machine ;;
 591 powerpc64*)     base_machine=powerpc machine=powerpc/powerpc64 ;;
 592 powerpc*)       base_machine=powerpc machine=powerpc/powerpc32 ;;
 593 s390)           base_machine=s390 machine=s390/s390-32 ;;
 594 s390x)          base_machine=s390 machine=s390/s390-64 ;;
 595 sh3*)           base_machine=sh machine=sh/sh3 ;;
 596 sh4*)           base_machine=sh machine=sh/sh4 ;;
 597 sparc | sparcv[67])
 598                 base_machine=sparc machine=sparc/sparc32 ;;
 599 sparcv8 | supersparc | hypersparc)
 600                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 601 sparcv8plus | sparcv8plusa | sparcv9)
 602                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 603 sparcv8plusb | sparcv9b)
 604                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
 605 sparcv9v)
 606                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
 607 sparcv9v2)
 608                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
 609 sparc64)
 610                 base_machine=sparc machine=sparc/sparc64 ;;
 611 sparc64b)
 612                 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
 613 sparc64v)
 614                 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
 615 sparc64v2)
 616                 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
 617 *)              base_machine=$machine ;;
 618 esac
 619 changequote([,])dnl
 620 AC_SUBST(base_machine)
 621
 622 if test "$base_machine" = "i386"; then
 623   AC_DEFINE(USE_REGPARMS)
 624 fi
 625
 626 # For the multi-arch option we need support in the assembler & linker.
 627 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 628                libc_cv_ld_gnu_indirect_function, [dnl
 629 cat > conftest.S <<EOF
 630 .type foo,%gnu_indirect_function
 631 foo:
 632 .globl _start
 633 _start:
 634 .globl __start
 635 __start:
 636 .data
 637 #ifdef _LP64
 638 .quad foo
 639 #else
 640 .long foo
 641 #endif
 642 EOF
 643 libc_cv_ld_gnu_indirect_function=no
 644 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 645             -nostartfiles -nostdlib \
 646             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 647   # Do a link to see if the backend supports IFUNC relocs.
 648   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 649   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 650     libc_cv_ld_gnu_indirect_function=yes
 651   }
 652 fi
 653 rm -f conftest*])
 654
 655 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 656 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 657 cat > conftest.s <<EOF
 658 .text
 659 EOF
 660 libc_cv_dot_text=
 661 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 662   libc_cv_dot_text=.text
 663 fi
 664 rm -f conftest*])
 665 if test -z "$libc_cv_dot_text"; then
 666   AC_MSG_RESULT(no)
 667 else
 668   AC_MSG_RESULT(yes)
 669 fi
 670
 671 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 672   if test x"$multi_arch" = xyes; then
 673     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 674   else
 675     multi_arch=no
 676   fi
 677 fi
 678 multi_arch_d=
 679 if test x"$multi_arch" != xno; then
 680   multi_arch_d=/multiarch
 681 fi
 682
 683 # Compute the list of sysdep directories for this configuration.
 684 # This can take a while to compute.
 685 sysdep_dir=$srcdir/sysdeps
 686 AC_MSG_CHECKING(sysdep dirs)
 687 dnl We need to use [ and ] for other purposes for a while now.
 688 changequote(,)dnl
 689 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 690 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 691
 692 test "x$base_os" != x || case "$os" in
 693 gnu*)
 694   base_os=mach/hurd ;;
 695 linux*)
 696   base_os=unix/sysv ;;
 697 esac
 698
 699 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 700 tail=$os
 701 ostry=$os
 702 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 703   ostry="$ostry /$o"
 704   tail=$o
 705 done
 706 o=`echo $tail | sed 's/[0-9]*$//'`
 707 if test $o != $tail; then
 708   ostry="$ostry /$o"
 709 fi
 710 # For linux-gnu, try linux-gnu, then linux.
 711 o=`echo $tail | sed 's/-.*$//'`
 712 if test $o != $tail; then
 713   ostry="$ostry /$o"
 714 fi
 715
 716 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 717 base=
 718 tail=$base_os
 719 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 720   set $b
 721   base="$base /$1"
 722   tail="$2"
 723 done
 724
 725 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 726 mach=
 727 tail=$machine${submachine:+/$submachine}
 728 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 729   set $m
 730   # Prepend the machine's FPU directory unless --without-fp.
 731   if test "$with_fp" = yes; then
 732     maybe_fpu=/fpu
 733   else
 734     maybe_fpu=/nofpu
 735   fi
 736   # For each machine term, try it with and then without /multiarch.
 737   for try_fpu in $maybe_fpu ''; do
 738     for try_multi in $multi_arch_d ''; do
 739       mach="$mach /$1$try_fpu$try_multi"
 740     done
 741   done
 742   tail="$2"
 743 done
 744
 745 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 746 changequote([,])dnl
 747
 748 # Find what sysdep directories exist.
 749 sysnames_add_ons=
 750 sysnames=
 751 for b in $base ''; do
 752   for m0 in $mach ''; do
 753     for v in /$vendor ''; do
 754       test "$v" = / && continue
 755       for o in /$ostry ''; do
 756         test "$o" = / && continue
 757         for m in $mach ''; do
 758           for d in $add_ons_pfx ''; do
 759             for a in $add_ons_sfx ''; do
 760               try_suffix="$m0$b$v$o$m"
 761               if test -n "$try_suffix"; then
 762                 try_srcdir="${srcdir}/"
 763                 case "$d" in
 764                 /*) try_srcdir= ;;
 765                 esac
 766                 try="${d}sysdeps$try_suffix$a"
 767                 test -n "$enable_debug_configure" &&
 768                 echo "$0 [DEBUG]: try $try" >&2
 769                 if test -d "$try_srcdir$try"; then
 770                   sysnames="$sysnames $try"
 771                   { test -n "$o" || test -n "$b"; } && os_used=t
 772                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 773                   case x${m0:-$m} in
 774                   x*/$submachine) submachine_used=t ;;
 775                   esac
 776                   if test -n "$d"; then
 777                     case "$sysnames_add_ons" in
 778                     *" $d "*) ;;
 779                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 780                     esac
 781                   fi
 782                 fi
 783               fi
 784             done
 785           done
 786         done
 787       done
 788     done
 789   done
 790 done
 791
 792 # If the assembler supports gnu_indirect_function symbol type and the
 793 # architecture supports multi-arch, we enable multi-arch by default.
 794 case $sysnames_add_ons$sysnames in
 795 *"$multi_arch_d"*)
 796   ;;
 797 *)
 798   test x"$multi_arch" = xdefault && multi_arch=no
 799   ;;
 800 esac
 801 if test x"$multi_arch" != xno; then
 802   AC_DEFINE(USE_MULTIARCH)
 803 fi
 804 AC_SUBST(multi_arch)
 805
 806 if test -z "$os_used" && test "$os" != none; then
 807   AC_MSG_ERROR(Operating system $os is not supported.)
 808 fi
 809 if test -z "$machine_used" && test "$machine" != none; then
 810   AC_MSG_ERROR(The $machine is not supported.)
 811 fi
 812 if test -z "$submachine_used" && test -n "$submachine"; then
 813   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 814 fi
 815 AC_SUBST(submachine)
 816
 817 # We have now validated the configuration.
 818
 819 # Expand the list of system names into a full list of directories
 820 # from each element's parent name and Implies file (if present).
 821 set $sysnames
 822 names=
 823 while test $# -gt 0; do
 824   name=$1
 825   shift
 826
 827   case " $names " in *" $name "*)
 828     # Already in the list.
 829     continue
 830   esac
 831
 832   # Report each name as we discover it, so there is no long pause in output.
 833   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 834
 835   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 836
 837   case $name in
 838     /*) xsrcdir= ;;
 839     *)  xsrcdir=$srcdir/ ;;
 840   esac
 841   test -n "$enable_debug_configure" &&
 842   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 843
 844   for implies_file in Implies Implies-before Implies-after; do
 845     implies_type=`echo $implies_file | sed s/-/_/`
 846     eval ${implies_type}=
 847     if test -f $xsrcdir$name/$implies_file; then
 848       # Collect more names from the `Implies' file (removing comments).
 849       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 850       for x in $implied_candidate; do
 851         found=no
 852         if test -d $xsrcdir$name_base/$x; then
 853           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 854           found=yes
 855         fi
 856         for d in $add_ons_pfx ''; do
 857           try="${d}sysdeps/$x"
 858           case $d in
 859            /*) try_srcdir= ;;
 860            *) try_srcdir=$srcdir/ ;;
 861           esac
 862           test -n "$enable_debug_configure" &&
 863            echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
 864           if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 865           then
 866             eval "${implies_type}=\"\$${implies_type} \$try\""
 867             found=yes
 868             case "$sysnames_add_ons" in
 869             *" $d "*) ;;
 870             *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 871             esac
 872           fi
 873         done
 874         if test $found = no; then
 875           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 876         fi
 877       done
 878     fi
 879   done
 880
 881   # Add NAME to the list of names.
 882   names="$names $name"
 883
 884   # Find the parent of NAME, using the empty string if it has none.
 885 changequote(,)dnl
 886   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 887 changequote([,])dnl
 888
 889   test -n "$enable_debug_configure" &&
 890     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 891 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 892
 893   # Add the names implied by NAME, and NAME's parent (if it has one), to
 894   # the list of names to be processed (the argument list).  We prepend the
 895   # implied names to the list and append the parent.  We want implied
 896   # directories to come before further directories inferred from the
 897   # configuration components; this ensures that for sysv4, unix/common
 898   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 899   # after sysv4).
 900   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 901   test -n "$sysnames" && set $sysnames
 902 done
 903
 904 # Add the default directories.
 905 default_sysnames="sysdeps/generic"
 906 sysnames="$names $default_sysnames"
 907 AC_SUBST(sysnames)
 908 # The other names were emitted during the scan.
 909 AC_MSG_RESULT($default_sysnames)
 910
 911 # Collect the list of add-ons that supply partial sysdeps trees.
 912 sysdeps_add_ons=
 913 for add_on in $add_ons; do
 914   case "$add_on" in
 915   /*) xsrcdir= ;;
 916   *) xsrcdir="$srcdir/" ;;
 917   esac
 918
 919   test -d "$xsrcdir$add_on/sysdeps" || {
 920     case "$configured_add_ons " in
 921     *" $add_on "*) ;;
 922     *|'')
 923       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
 924       ;;
 925     esac
 926     continue
 927   }
 928
 929   sysdeps_add_ons="$sysdeps_add_ons $add_on"
 930   case "$sysnames_add_ons" in
 931   *" $add_on/ "*) ;;
 932   *|'')
 933     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
 934     continue ;;
 935   esac
 936
 937   found=no
 938   for d in $sysnames; do
 939     case "$d" in
 940     $add_on/sysdeps/*) ;;
 941     *) continue ;;
 942     esac
 943     (cd "$xsrcdir$d" && for f in *[[!~]]; do
 944        case "$f" in
 945        sys|bits)
 946          for ff in $f/*.h; do
 947            test -d "$ff" || { test -e "$ff" && exit 88; }
 948          done
 949          ;;
 950        *)
 951          test -d "$f" || { test -e "$f" && exit 88; }
 952          ;;
 953        esac
 954      done)
 955     if test $? -eq 88; then
 956       found=yes
 957       break
 958     fi
 959   done
 960   if test $found = no; then
 961     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
 962   fi
 963 done
 964 AC_SUBST(sysdeps_add_ons)
 965
 966
 967 ### Locate tools.
 968
 969 AC_PROG_INSTALL
 970 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 971   # The makefiles need to use a different form to find it in $srcdir.
 972   INSTALL='\$(..)./scripts/install-sh -c'
 973 fi
 974 AC_PROG_LN_S
 975
 976 LIBC_PROG_BINUTILS
 977
 978 # Accept binutils 2.20 or newer.
 979 AC_CHECK_PROG_VER(AS, $AS, --version,
 980                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 981                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
 982 AC_CHECK_PROG_VER(LD, $LD, --version,
 983                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 984                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
 985
 986 # These programs are version sensitive.
 987 AC_CHECK_TOOL_PREFIX
 988 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 989   [version \([egcygnustpi-]*[0-9.]*\)], [4.[4-9].* | 4.[1-9][0-9].* | [5-9].* ],
 990   critic_missing="$critic_missing gcc")
 991 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 992   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 993   [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
 994
 995 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 996   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 997   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 998   MSGFMT=: aux_missing="$aux_missing msgfmt")
 999 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1000   [GNU texinfo.* \([0-9][0-9.]*\)],
1001   [4.[5-9]*|4.[1-9][0-9]*|[5-9].*],
1002   MAKEINFO=: aux_missing="$aux_missing makeinfo")
1003 AC_CHECK_PROG_VER(SED, sed, --version,
1004   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
1005   [3.0[2-9]*|3.[1-9]*|[4-9]*],
1006   SED=: aux_missing="$aux_missing sed")
1007 AC_CHECK_PROG_VER(AWK, gawk, --version,
1008   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
1009   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
1010
1011 AC_CHECK_TOOL(NM, nm, false)
1012
1013 if test "x$maintainer" = "xyes"; then
1014   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1015   case "x$AUTOCONF" in
1016   xno|x|x:) AUTOCONF=no ;;
1017   *)
1018     AC_CACHE_CHECK(dnl
1019   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1020     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1021       libc_cv_autoconf_works=yes
1022     else
1023       libc_cv_autoconf_works=no
1024     fi])
1025     test $libc_cv_autoconf_works = yes || AUTOCONF=no
1026     ;;
1027   esac
1028   if test "x$AUTOCONF" = xno; then
1029     aux_missing="$aux_missing autoconf"
1030   fi
1031 else
1032   AUTOCONF=no
1033 fi
1034
1035 test -n "$critic_missing" && AC_MSG_ERROR([
1036 *** These critical programs are missing or too old:$critic_missing
1037 *** Check the INSTALL file for required versions.])
1038
1039 test -n "$aux_missing" && AC_MSG_WARN([
1040 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1041 *** some features will be disabled.
1042 *** Check the INSTALL file for required versions.])
1043
1044 # if using special system headers, find out the compiler's sekrit
1045 # header directory and add that to the list.  NOTE: Only does the right
1046 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1047 if test -n "$sysheaders"; then
1048   SYSINCLUDES=-nostdinc
1049   for d in include include-fixed; do
1050     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1051     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1052   done
1053   SYSINCLUDES="$SYSINCLUDES \
1054 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1055   if test -n "$CXX"; then
1056     CXX_SYSINCLUDES=
1057     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1058     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1059       test "x$cxxheaders" != x &&
1060       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1061     done
1062   fi
1063 fi
1064 AC_SUBST(SYSINCLUDES)
1065 AC_SUBST(CXX_SYSINCLUDES)
1066
1067 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1068 # since this would lead to problems installing/building glibc.
1069 # LD_LIBRARY_PATH contains the current directory if one of the following
1070 # is true:
1071 # - one of the terminals (":" and ";") is the first or last sign
1072 # - two terminals occur directly after each other
1073 # - the path contains an element with a dot in it
1074 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1075 changequote(,)dnl
1076 case ${LD_LIBRARY_PATH} in
1077   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1078     ld_library_path_setting="contains current directory"
1079     ;;
1080   *)
1081     ld_library_path_setting="ok"
1082     ;;
1083 esac
1084 changequote([,])dnl
1085 AC_MSG_RESULT($ld_library_path_setting)
1086 if test "$ld_library_path_setting" != "ok"; then
1087 AC_MSG_ERROR([
1088 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1089 *** building glibc. Please change the environment variable
1090 *** and run configure again.])
1091 fi
1092
1093 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1094 if $CC -v -static-libgcc 2>&1 | grep 'unrecognized option.*static-libgcc' >/dev/null; then
1095   libc_cv_gcc_static_libgcc=
1096 else
1097   libc_cv_gcc_static_libgcc=-static-libgcc
1098 fi])
1099 AC_SUBST(libc_cv_gcc_static_libgcc)
1100
1101 AC_PATH_PROG(BASH_SHELL, bash, no)
1102 if test "$BASH_SHELL" != no &&
1103    $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1104              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1105   libc_cv_have_bash2=yes
1106 else
1107   libc_cv_have_bash2=no
1108 fi
1109 AC_SUBST(libc_cv_have_bash2)
1110
1111 dnl We need a ksh compatible shell for tzselect.
1112 if test "$BASH_SHELL" = no; then
1113   AC_PATH_PROG(KSH, ksh, no)
1114   if test "$KSH" = no; then
1115     libc_cv_have_ksh=no
1116   else
1117     libc_cv_have_ksh=yes
1118   fi
1119 else
1120   KSH="$BASH_SHELL"
1121   AC_SUBST(KSH)
1122   libc_cv_have_ksh=yes
1123 fi
1124 AC_SUBST(libc_cv_have_ksh)
1125
1126 AC_PATH_PROG(PERL, perl, no)
1127 if test "$PERL" != no &&
1128    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1129   PERL=no
1130 fi
1131 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1132              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1133 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1134
1135 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1136 AC_TRY_COMPILE(dnl
1137 [#define __need_size_t
1138 #define __need_wchar_t
1139 #include <stddef.h>
1140 #define __need_NULL
1141 #include <stddef.h>], [size_t size; wchar_t wchar;
1142 #ifdef offsetof
1143 #error stddef.h ignored __need_*
1144 #endif
1145 if (&size == NULL || &wchar == NULL) abort ();],
1146                libc_cv_friendly_stddef=yes,
1147                libc_cv_friendly_stddef=no)])
1148 if test $libc_cv_friendly_stddef = yes; then
1149   config_vars="$config_vars
1150 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1151 fi
1152
1153 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1154                libc_cv_need_minus_P, [dnl
1155 cat > conftest.S <<EOF
1156 #include "confdefs.h"
1157 /* Nothing whatsoever.  */
1158 EOF
1159 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1160   libc_cv_need_minus_P=no
1161 else
1162   libc_cv_need_minus_P=yes
1163 fi
1164 rm -f conftest*])
1165 if test $libc_cv_need_minus_P = yes; then
1166   config_vars="$config_vars
1167 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1168 fi
1169
1170 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1171 cat > conftest.s <<EOF
1172 ${libc_cv_dot_text}
1173 foo:
1174 .set glibc_conftest_frobozz,foo
1175 .globl glibc_conftest_frobozz
1176 EOF
1177 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1178 # (but it doesn't work), so we must do a linking check to be sure.
1179 cat > conftest1.c <<\EOF
1180 extern int glibc_conftest_frobozz;
1181 void _start() { glibc_conftest_frobozz = 1; }
1182 EOF
1183 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1184             -nostartfiles -nostdlib \
1185             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1186   libc_cv_asm_set_directive=yes
1187 else
1188   libc_cv_asm_set_directive=no
1189 fi
1190 rm -f conftest*])
1191 if test $libc_cv_asm_set_directive = yes; then
1192   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1193 fi
1194
1195 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1196                libc_cv_asm_unique_object, [dnl
1197 cat > conftest.s <<EOF
1198 ${libc_cv_dot_text}
1199 _sym:
1200 .type _sym, %gnu_unique_object
1201 EOF
1202 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1203   libc_cv_asm_unique_object=yes
1204 else
1205   libc_cv_asm_unique_object=no
1206 fi
1207 rm -f conftest*])
1208 if test $libc_cv_asm_unique_object = yes; then
1209   AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1210 fi
1211
1212 AC_CACHE_CHECK(for .previous assembler directive,
1213                libc_cv_asm_previous_directive, [dnl
1214 cat > conftest.s <<EOF
1215 .section foo_section
1216 .previous
1217 EOF
1218 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1219   libc_cv_asm_previous_directive=yes
1220 else
1221   libc_cv_asm_previous_directive=no
1222 fi
1223 rm -f conftest*])
1224 if test $libc_cv_asm_previous_directive = yes; then
1225   AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1226 else
1227   AC_CACHE_CHECK(for .popsection assembler directive,
1228                  libc_cv_asm_popsection_directive, [dnl
1229   cat > conftest.s <<EOF
1230 .pushsection foo_section
1231 .popsection
1232 EOF
1233   if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1234     libc_cv_asm_popsection_directive=yes
1235   else
1236     libc_cv_asm_popsection_directive=no
1237   fi
1238   rm -f conftest*])
1239   if test $libc_cv_asm_popsection_directive = yes; then
1240     AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1241   fi
1242 fi
1243 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1244                libc_cv_asm_protected_directive, [dnl
1245 cat > conftest.s <<EOF
1246 .protected foo
1247 foo:
1248 .hidden bar
1249 bar:
1250 EOF
1251 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1252   libc_cv_asm_protected_directive=yes
1253 else
1254   AC_MSG_ERROR(assembler support for symbol visibility is required)
1255 fi
1256 rm -f conftest*])
1257
1258 if test $libc_cv_asm_protected_directive = yes; then
1259   AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1260                  libc_cv_visibility_attribute,
1261                  [cat > conftest.c <<EOF
1262                   int foo __attribute__ ((visibility ("hidden"))) = 1;
1263                   int bar __attribute__ ((visibility ("protected"))) = 1;
1264 EOF
1265                   libc_cv_visibility_attribute=no
1266                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1267                     if grep '\.hidden.*foo' conftest.s >/dev/null; then
1268                       if grep '\.protected.*bar' conftest.s >/dev/null; then
1269                         libc_cv_visibility_attribute=yes
1270                       fi
1271                     fi
1272                   fi
1273                   rm -f conftest.{c,s}
1274                  ])
1275   if test $libc_cv_visibility_attribute != yes; then
1276     AC_MSG_ERROR(compiler support for visibility attribute is required)
1277   fi
1278 fi
1279
1280 if test $libc_cv_visibility_attribute = yes; then
1281   AC_CACHE_CHECK(for broken __attribute__((visibility())),
1282                  libc_cv_broken_visibility_attribute,
1283                  [cat > conftest.c <<EOF
1284                   int foo (int x);
1285                   int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1286                   int bar (int x) { return x; }
1287 EOF
1288                   libc_cv_broken_visibility_attribute=yes
1289                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1290 changequote(,)dnl
1291                     if grep '\.hidden[  _]foo' conftest.s >/dev/null; then
1292 changequote([,])dnl
1293                       libc_cv_broken_visibility_attribute=no
1294                     fi
1295                   fi
1296                   rm -f conftest.c conftest.s
1297                  ])
1298   if test $libc_cv_broken_visibility_attribute = yes; then
1299     AC_MSG_ERROR(working compiler support for visibility attribute is required)
1300   fi
1301 fi
1302
1303 AC_CACHE_CHECK(for broken __attribute__((alias())),
1304                libc_cv_broken_alias_attribute,
1305                [cat > conftest.c <<EOF
1306                extern int foo (int x) __asm ("xyzzy");
1307                int bar (int x) { return x; }
1308                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1309                extern int dfoo;
1310                extern __typeof (dfoo) dfoo __asm ("abccb");
1311                int dfoo = 1;
1312 EOF
1313                libc_cv_broken_alias_attribute=yes
1314                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1315                  if grep 'xyzzy' conftest.s >/dev/null &&
1316                     grep 'abccb' conftest.s >/dev/null; then
1317                    libc_cv_broken_alias_attribute=no
1318                  fi
1319                fi
1320                rm -f conftest.c conftest.s
1321                ])
1322 if test $libc_cv_broken_alias_attribute = yes; then
1323   AC_MSG_ERROR(working alias attribute support required)
1324 fi
1325
1326 if test $libc_cv_visibility_attribute = yes; then
1327   AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1328                  libc_cv_have_sdata_section,
1329                  [echo "int i;" > conftest.c
1330                   libc_cv_have_sdata_section=no
1331                   if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1332                      | grep '\.sdata' >/dev/null; then
1333                     libc_cv_have_sdata_section=yes
1334                   fi
1335                   rm -f conftest.c conftest.so
1336                  ])
1337   if test $libc_cv_have_sdata_section = yes; then
1338     AC_DEFINE(HAVE_SDATA_SECTION)
1339   fi
1340 fi
1341
1342 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1343                libc_cv_initfini_array, [dnl
1344 LIBC_TRY_LINK_STATIC([
1345 int foo (void) { return 1; }
1346 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1347 ],
1348   [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1349     libc_cv_initfini_array=yes
1350   else
1351     libc_cv_initfini_array=no
1352   fi],
1353   [libc_cv_initfini_array=no])
1354 ])
1355 if test $libc_cv_initfini_array != yes; then
1356   AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1357 fi
1358
1359 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1360                libc_cv_ctors_header, [dnl
1361   libc_cv_ctors_header=yes
1362   LIBC_TRY_LINK_STATIC([
1363 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1364 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1365 ],
1366               [dnl
1367       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1368         { gsub(/\@<:@ */, "@<:@") }
1369         $2 == ".ctors" || $2 == ".dtors" {
1370           size = strtonum("0x" $6)
1371           align = strtonum("0x" $NF)
1372           seen@<:@$2@:>@ = 1
1373           stub@<:@$2@:>@ = size == align * 2
1374         }
1375         END {
1376           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1377           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1378           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1379         }
1380       '], [libc_cv_ctors_header=no])
1381     ], [dnl
1382       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1383     ])
1384 ])
1385 if test $libc_cv_ctors_header = no; then
1386   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1387 fi
1388
1389 AC_CACHE_CHECK(for libunwind-support in compiler,
1390                libc_cv_cc_with_libunwind, [
1391   cat > conftest.c <<EOF
1392 int main (void) { return 0; }
1393 EOF
1394   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1395      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1396     libc_cv_cc_with_libunwind=yes
1397   else
1398     libc_cv_cc_with_libunwind=no
1399   fi
1400   rm -f conftest*])
1401 AC_SUBST(libc_cv_cc_with_libunwind)
1402 if test $libc_cv_cc_with_libunwind = yes; then
1403   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1404 fi
1405
1406 LIBC_LINKER_FEATURE([-z nodelete], [-Wl,--enable-new-dtags,-z,nodelete],
1407                     [libc_cv_z_nodelete=yes],
1408                     [AC_MSG_ERROR(linker with -z nodelete support required)])
1409
1410 LIBC_LINKER_FEATURE([-z nodlopen], [-Wl,--enable-new-dtags,-z,nodlopen],
1411                     [libc_cv_z_nodlopen=yes],
1412                     [AC_MSG_ERROR(linker with -z nodlopen support required)])
1413
1414 LIBC_LINKER_FEATURE([-z initfirst], [-Wl,--enable-new-dtags,-z,initfirst],
1415                     [libc_cv_z_initfirst=yes],
1416                     [AC_MSG_ERROR(linker with -z initfirst support required)])
1417
1418 # Add-on fragments can set these for other machines.
1419 libc_commonpagesize=${libc_commonpagesize:-no}
1420 libc_relro_required=${libc_relro_required:-no}
1421 case "$base_machine" in
1422   i[[34567]]86 | x86_64 | powerpc* | s390*)
1423     libc_commonpagesize=0x1000
1424     libc_relro_required=yes
1425     ;;
1426   sparc*)
1427     libc_commonpagesize=0x2000
1428     libc_relro_required=yes
1429     ;;
1430 esac
1431
1432 if test $libc_commonpagesize != no; then
1433   AC_CACHE_CHECK(for -z relro option,
1434                  libc_cv_z_relro, [dnl
1435   libc_cv_z_relro=no
1436   AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1437 int _start (void) { return 42; }
1438 extern void _exit (int);
1439 /* Since these pointers are const, they should go in rodata.
1440    Since they refer to functions that have to be resolved by
1441    dynamic linking, they should instead go in RELRO data.  */
1442 const void *const relro[] = { &_start, &_exit, 0 };
1443 /* GNU ld fails to produce RELRO data when it's very small and there is no
1444    normal writable data following it, or if only uninitialized (.bss) data
1445    follows it, or only very small writable data.  */
1446 int data[0x10000] = { 1, };
1447 ]])])
1448   cat > conftest.awk <<\EOF
1449 BEGIN {
1450   result = "no"
1451   commonpagesize = strtonum(commonpagesize)
1452 }
1453 { print "LINE:", $0 > "/dev/stderr" }
1454 $1 == "GNU_RELRO" {
1455   vaddr = strtonum($3)
1456   memsz = strtonum($6)
1457   end = vaddr + memsz
1458   printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1459     vaddr, memsz, end, commonpagesize > "/dev/stderr"
1460   result = (end % commonpagesize == 0) ? "yes" : "broken"
1461 }
1462 END { print result }
1463 EOF
1464   AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1465                     -fPIC -shared -o conftest.so conftest.c
1466                     -nostartfiles -nostdlib
1467                     -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1468   AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1469   AC_TRY_COMMAND([
1470       $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1471            conftest.ph > conftest.cps
1472     ]) &&
1473   libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1474   rm -f conftest*])
1475   if { test "x$libc_relro_required" = xyes &&
1476        test "x$libc_cv_z_relro" != xyes
1477      }
1478   then
1479     AC_MSG_ERROR(linker with -z relro support required)
1480   fi
1481 else
1482   AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1483 fi
1484
1485 AC_CACHE_CHECK(for -Bgroup option,
1486                libc_cv_Bgroup, [dnl
1487 cat > conftest.c <<EOF
1488 int _start (void) { return 42; }
1489 EOF
1490 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1491                             -fPIC -shared -o conftest.so conftest.c
1492                             -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1493 then
1494   libc_cv_Bgroup=yes
1495 else
1496   libc_cv_Bgroup=no
1497 fi
1498 rm -f conftest*])
1499 AC_SUBST(libc_cv_Bgroup)
1500
1501 ASFLAGS_config=
1502 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1503                libc_cv_as_noexecstack, [dnl
1504 cat > conftest.c <<EOF
1505 void foo (void) { }
1506 EOF
1507 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1508                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1509    && grep .note.GNU-stack conftest.s >/dev/null \
1510    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1511                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1512 then
1513   libc_cv_as_noexecstack=yes
1514 else
1515   libc_cv_as_noexecstack=no
1516 fi
1517 rm -f conftest*])
1518 if test $libc_cv_as_noexecstack = yes; then
1519   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1520 fi
1521 AC_SUBST(ASFLAGS_config)
1522
1523 AC_CACHE_CHECK(for -z combreloc,
1524                libc_cv_z_combreloc, [dnl
1525 cat > conftest.c <<EOF
1526 extern int bar (int);
1527 extern int mumble;
1528 int foo (void) { return bar (mumble); }
1529 EOF
1530 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1531                         -fPIC -shared -o conftest.so conftest.c
1532                         -nostdlib -nostartfiles
1533                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1534 then
1535 dnl The following test is a bit weak.  We must use a tool which can test
1536 dnl cross-platform since the gcc used can be a cross compiler.  Without
1537 dnl introducing new options this is not easily doable.  Instead use a tool
1538 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1539 dnl look for a section named .rel.dyn.
1540   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1541     libc_cv_z_combreloc=yes
1542   else
1543     libc_cv_z_combreloc=no
1544   fi
1545 else
1546   libc_cv_z_combreloc=no
1547 fi
1548 rm -f conftest*])
1549 if test "$libc_cv_z_combreloc" = yes; then
1550   AC_DEFINE(HAVE_Z_COMBRELOC)
1551 fi
1552 AC_SUBST(libc_cv_z_combreloc)
1553
1554 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1555                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1556 AC_SUBST(libc_cv_z_execstack)
1557
1558 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1559 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1560 ])
1561
1562 AC_SUBST(libc_cv_fpie)
1563
1564 AC_CACHE_CHECK(for --hash-style option,
1565                libc_cv_hashstyle, [dnl
1566 cat > conftest.c <<EOF
1567 int _start (void) { return 42; }
1568 EOF
1569 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1570                             -fPIC -shared -o conftest.so conftest.c
1571                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1572 then
1573   libc_cv_hashstyle=yes
1574 else
1575   libc_cv_hashstyle=no
1576 fi
1577 rm -f conftest*])
1578 AC_SUBST(libc_cv_hashstyle)
1579
1580 # The linker's default -shared behavior is good enough if it
1581 # does these things that our custom linker scripts ensure that
1582 # all allocated NOTE sections come first.
1583 if test "$use_default_link" = default; then
1584   AC_CACHE_CHECK([for sufficient default -shared layout],
1585                   libc_cv_use_default_link, [dnl
1586   libc_cv_use_default_link=no
1587   cat > conftest.s <<\EOF
1588           .section .note.a,"a",%note
1589           .balign 4
1590           .long 4,4,9
1591           .string "GNU"
1592           .string "foo"
1593           .section .note.b,"a",%note
1594           .balign 4
1595           .long 4,4,9
1596           .string "GNU"
1597           .string "bar"
1598 EOF
1599   if AC_TRY_COMMAND([dnl
1600   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1601        ac_try=`$READELF -S conftest.so | sed -n \
1602          ['${x;p;}
1603           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1604           t a
1605           b
1606           : a
1607           H']`
1608   then
1609     libc_seen_a=no libc_seen_b=no
1610     set -- $ac_try
1611     while test $# -ge 2 -a "$1" = NOTE; do
1612       case "$2" in
1613       .note.a) libc_seen_a=yes ;;
1614       .note.b) libc_seen_b=yes ;;
1615       esac
1616       shift 2
1617     done
1618     case "$libc_seen_a$libc_seen_b" in
1619     yesyes)
1620       libc_cv_use_default_link=yes
1621       ;;
1622     *)
1623       echo >&AS_MESSAGE_LOG_FD "\
1624 $libc_seen_a$libc_seen_b from:
1625 $ac_try"
1626       ;;
1627     esac
1628   fi
1629   rm -f conftest*])
1630   use_default_link=$libc_cv_use_default_link
1631 fi
1632
1633 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1634 if libc_cv_output_format=`
1635 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1636 then
1637   :
1638 else
1639   libc_cv_output_format=
1640 fi
1641 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1642 AC_SUBST(libc_cv_output_format)
1643
1644 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1645 cat > conftest.c <<EOF
1646 int foo;
1647 EOF
1648 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1649                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1650 then
1651   libc_cv_fno_toplevel_reorder=yes
1652 else
1653   libc_cv_fno_toplevel_reorder=no
1654 fi
1655 rm -f conftest*])
1656 if test $libc_cv_fno_toplevel_reorder = yes; then
1657   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1658 else
1659   fno_unit_at_a_time=-fno-unit-at-a-time
1660 fi
1661 AC_SUBST(fno_unit_at_a_time)
1662
1663 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1664 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1665                    [libc_cv_ssp=yes],
1666                    [libc_cv_ssp=no])
1667 ])
1668 AC_SUBST(libc_cv_ssp)
1669
1670 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1671 cat > conftest.c <<EOF
1672 int foo;
1673 #ifdef __GNUC_GNU_INLINE__
1674 main () { return 0;}
1675 #else
1676 #error
1677 #endif
1678 EOF
1679 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1680                             -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1681 then
1682   libc_cv_gnu89_inline=yes
1683 else
1684   libc_cv_gnu89_inline=no
1685 fi
1686 rm -f conftest*])
1687 if test $libc_cv_gnu89_inline = yes; then
1688   gnu89_inline=-fgnu89-inline
1689 else
1690   gnu89_inline=
1691 fi
1692 AC_SUBST(gnu89_inline)
1693
1694 AC_CACHE_CHECK(whether cc puts quotes around section names,
1695                libc_cv_have_section_quotes,
1696                [cat > conftest.c <<EOF
1697                 static const int foo
1698                 __attribute__ ((section ("bar"))) = 1;
1699 EOF
1700                 if ${CC-cc} -S conftest.c -o conftest.s; then
1701                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1702                     libc_cv_have_section_quotes=yes
1703                   else
1704                     libc_cv_have_section_quotes=no
1705                   fi
1706                 else
1707                   libc_cv_have_section_quotes=unknown
1708                 fi
1709                 rm -f conftest.{c,s}
1710                 ])
1711 if test $libc_cv_have_section_quotes = yes; then
1712   AC_DEFINE(HAVE_SECTION_QUOTES)
1713 fi
1714
1715 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1716                [dnl
1717 cat > conftest.s <<EOF
1718 ${libc_cv_dot_text}
1719 .globl foo
1720 foo:
1721 .weak foo
1722 .weak bar; bar = foo
1723 EOF
1724 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1725   libc_cv_asm_weak_directive=yes
1726 else
1727   libc_cv_asm_weak_directive=no
1728 fi
1729 rm -f conftest*])
1730
1731 if test $libc_cv_asm_weak_directive = no; then
1732   AC_CACHE_CHECK(for assembler .weakext directive,
1733                  libc_cv_asm_weakext_directive,
1734                  [dnl
1735 cat > conftest.s <<EOF
1736 ${libc_cv_dot_text}
1737 .globl foo
1738 foo:
1739 .weakext bar foo
1740 .weakext baz
1741 .globl baz
1742 baz:
1743 EOF
1744   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1745     libc_cv_asm_weakext_directive=yes
1746   else
1747     libc_cv_asm_weakext_directive=no
1748   fi
1749   rm -f conftest*])
1750
1751 fi # no .weak
1752
1753 if test $libc_cv_asm_weak_directive = yes; then
1754   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1755 elif test $libc_cv_asm_weakext_directive = yes; then
1756   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1757 fi
1758
1759 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1760 case $machine in
1761   sparc/sparc64*) cfi_offset=2047;;
1762   *) cfi_offset=0;;
1763 esac
1764 cat > conftest.s <<EOF
1765         .text
1766         .type   func,%function
1767 func:
1768         .cfi_startproc
1769         .cfi_remember_state
1770         .cfi_rel_offset 1, $cfi_offset
1771         .cfi_endproc
1772 EOF
1773 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1774   libc_cv_asm_cfi_directives=yes
1775 else
1776   libc_cv_asm_cfi_directives=no
1777 fi
1778 rm -f conftest*])
1779 if test $libc_cv_asm_cfi_directives = yes; then
1780   AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1781 fi
1782
1783 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1784 cat > conftest.c <<\EOF
1785 _start () {}
1786 int __eh_pc;
1787 __throw () {}
1788 EOF
1789 dnl No \ in command here because it ends up inside ''.
1790 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1791                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1792                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1793   libc_cv_ld_no_whole_archive=yes
1794 else
1795   libc_cv_ld_no_whole_archive=no
1796 fi
1797 rm -f conftest*])
1798 if test $libc_cv_ld_no_whole_archive = no; then
1799   AC_MSG_ERROR([support for --no-whole-archive is needed])
1800 fi
1801
1802 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1803 cat > conftest.c <<\EOF
1804 _start () {}
1805 int __eh_pc;
1806 __throw () {}
1807 EOF
1808 dnl No \ in command here because it ends up inside ''.
1809 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1810                             -nostdlib -nostartfiles -fexceptions
1811                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1812   libc_cv_gcc_exceptions=yes
1813 else
1814   libc_cv_gcc_exceptions=no
1815 fi
1816 rm -f conftest*])
1817 if test $libc_cv_gcc_exceptions = yes; then
1818   exceptions=-fexceptions
1819 fi
1820 AC_SUBST(exceptions)dnl
1821
1822 if test "$host_cpu" = powerpc ; then
1823 # Check for a bug present in at least versions 2.8.x of GCC
1824 # and versions 1.0.x of EGCS.
1825 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1826 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1827                libc_cv_c_asmcr0_bug='no',
1828                libc_cv_c_asmcr0_bug='yes')])
1829 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1830   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1831 fi
1832 fi
1833
1834 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1835 cat > conftest.c <<\EOF
1836 void zero (void *x)
1837 {
1838   __builtin_memset (x, 0, 1000);
1839 }
1840 EOF
1841 dnl
1842 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1843 then
1844   libc_cv_gcc_builtin_memset=no
1845 else
1846   libc_cv_gcc_builtin_memset=yes
1847 fi
1848 rm -f conftest* ])
1849 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1850   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1851 fi
1852
1853 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1854 cat > conftest.c <<\EOF
1855 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1856 char *foo (const char *a, const char *b)
1857 {
1858   return __builtin_strstr (a, b);
1859 }
1860 EOF
1861 dnl
1862 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1863 then
1864   libc_cv_gcc_builtin_redirection=yes
1865 else
1866   libc_cv_gcc_builtin_redirection=no
1867 fi
1868 rm -f conftest* ])
1869 if test "$libc_cv_gcc_builtin_redirection" = no; then
1870   AC_MSG_ERROR([support for the symbol redirection needed])
1871 fi
1872
1873 dnl Check whether the compiler supports the __thread keyword.
1874 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1875 [cat > conftest.c <<\EOF
1876 __thread int a = 42;
1877 EOF
1878 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1879   libc_cv_gcc___thread=yes
1880 else
1881   libc_cv_gcc___thread=no
1882 fi
1883 rm -f conftest*])
1884 if test "$libc_cv_gcc___thread" = no; then
1885   AC_MSG_ERROR([support for the __thread keyword is required])
1886 fi
1887
1888 dnl Check whether the compiler supports the tls_model attribute.
1889 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1890 cat > conftest.c <<\EOF
1891 extern __thread int a __attribute__((tls_model ("initial-exec")));
1892 EOF
1893 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1894   libc_cv_gcc_tls_model_attr=yes
1895 else
1896   libc_cv_gcc_tls_model_attr=no
1897 fi
1898 rm -f conftest*])
1899 if test "$libc_cv_gcc_tls_model_attr" = no; then
1900   AC_MSG_ERROR([support for the tls_model attribute is required])
1901 fi
1902
1903 dnl Determine how to disable generation of FMA instructions.
1904 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1905                libc_cv_cc_nofma, [dnl
1906 libc_cv_cc_nofma=
1907 for opt in -ffp-contract=off -mno-fused-madd; do
1908   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1909 done])
1910 AC_SUBST(libc_cv_cc_nofma)
1911
1912 if test -n "$submachine"; then
1913   AC_CACHE_CHECK([for compiler option for CPU variant],
1914                  libc_cv_cc_submachine, [dnl
1915   libc_cv_cc_submachine=no
1916   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1917     LIBC_TRY_CC_OPTION([$opt], [
1918       libc_cv_cc_submachine="$opt"
1919       break], [])
1920   done])
1921   if test "x$libc_cv_cc_submachine" = xno; then
1922     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1923   fi
1924 fi
1925 AC_SUBST(libc_cv_cc_submachine)
1926
1927 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1928 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1929 cat > conftest.c <<EOF
1930 void
1931 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1932 foo (void) {}
1933 EOF
1934 libc_cv_cc_loop_to_function=no
1935 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1936 then
1937   libc_cv_cc_loop_to_function=yes
1938 fi
1939 rm -f conftest*])
1940 if test $libc_cv_cc_loop_to_function = yes; then
1941   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1942 fi
1943 AC_SUBST(libc_cv_cc_loop_to_function)
1944
1945 dnl Check whether we have the gd library available.
1946 AC_MSG_CHECKING(for libgd)
1947 if test "$with_gd" != "no"; then
1948   old_CFLAGS="$CFLAGS"
1949   CFLAGS="$CFLAGS $libgd_include"
1950   old_LDFLAGS="$LDFLAGS"
1951   LDFLAGS="$LDFLAGS $libgd_ldflags"
1952   old_LIBS="$LIBS"
1953   LIBS="$LIBS -lgd -lpng -lz -lm"
1954   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1955   CFLAGS="$old_CFLAGS"
1956   LDFLAGS="$old_LDFLAGS"
1957   LIBS="$old_LIBS"
1958 else
1959   LIBGD=no
1960 fi
1961 AC_MSG_RESULT($LIBGD)
1962 AC_SUBST(LIBGD)
1963
1964 # SELinux detection
1965 if test x$with_selinux = xno ; then
1966   have_selinux=no;
1967 else
1968   # See if we have the SELinux library
1969   AC_CHECK_LIB(selinux, is_selinux_enabled,
1970                have_selinux=yes, have_selinux=no)
1971   # See if we have the SELinux header with the NSCD permissions in it.
1972   if test x$have_selinux = xyes ; then
1973     AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
1974     AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
1975                     [#ifdef NSCD__SHMEMHOST
1976                      return 0;
1977                      #else
1978                      #error NSCD__SHMEMHOST not defined
1979                      #endif],
1980                     have_selinux=yes, have_selinux=no)
1981     AC_MSG_RESULT($have_selinux)
1982   fi
1983
1984   if test x$with_selinux = xyes ; then
1985     if test x$have_selinux = xno ; then
1986       AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
1987     fi
1988   fi
1989 fi
1990 # Check if we're building with SELinux support.
1991 if test "x$have_selinux" = xyes; then
1992   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1993
1994   # See if we have the libaudit library
1995   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1996                have_libaudit=yes, have_libaudit=no)
1997   if test "x$have_libaudit" = xyes; then
1998     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1999   fi
2000   AC_SUBST(have_libaudit)
2001
2002   # See if we have the libcap library
2003   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2004   if test "x$have_libcap" = xyes; then
2005     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2006   fi
2007   AC_SUBST(have_libcap)
2008 fi
2009 AC_SUBST(have_selinux)
2010
2011 dnl check for the size of 'long double'.
2012 AC_CHECK_SIZEOF(long double, 0)
2013 sizeof_long_double=$ac_cv_sizeof_long_double
2014 AC_SUBST(sizeof_long_double)
2015
2016 CPPUNDEFS=
2017 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
2018 dnl Since we are building the implementations of the fortified functions here,
2019 dnl having the macro defined interacts very badly.
2020 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
2021 [AC_TRY_COMPILE([], [
2022 #ifdef _FORTIFY_SOURCE
2023 # error bogon
2024 #endif],
2025                 [libc_cv_predef_fortify_source=no],
2026                 [libc_cv_predef_fortify_source=yes])])
2027 if test $libc_cv_predef_fortify_source = yes; then
2028   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
2029 fi
2030 AC_SUBST(CPPUNDEFS)
2031
2032 dnl Check for silly hacked compilers inserting -fstack-protector.
2033 dnl This breaks badly for the early startup code we compile, since
2034 dnl the compiled code can refer to a magic machine-dependent location
2035 dnl for the canary value before we have sufficient setup for that to
2036 dnl work.  It's also questionable to build all of libc with this flag
2037 dnl even when you're doing that for most applications you build, since
2038 dnl libc's code is so heavily-used and performance-sensitive.  If we
2039 dnl ever really want to make that work, it should be enabled explicitly
2040 dnl in the libc build, not inherited from implicit compiler settings.
2041 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
2042                libc_cv_predef_stack_protector, [
2043 AC_TRY_COMPILE([extern void foobar (char *);],
2044                [char large_array[2048]; foobar (large_array);], [
2045 libc_undefs=`$NM -u conftest.o |
2046   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
2047     2>&AS_MESSAGE_LOG_FD` || {
2048   AC_MSG_ERROR([confusing output from $NM -u])
2049 }
2050 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
2051 # On some architectures, there are architecture-specific undefined
2052 # symbols (resolved by the linker), so filter out unknown symbols.
2053 # This will fail to produce the correct result if the compiler
2054 # defaults to -fstack-protector but this produces an undefined symbol
2055 # other than __stack_chk_fail.  However, compilers like that have not
2056 # been encountered in practice.
2057 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
2058 case "$libc_undefs" in
2059 foobar) libc_cv_predef_stack_protector=no ;;
2060 '__stack_chk_fail
2061 foobar') libc_cv_predef_stack_protector=yes ;;
2062 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
2063 esac],
2064                [AC_MSG_ERROR([test compilation failed])])
2065 ])
2066 libc_extra_cflags=
2067 if test $libc_cv_predef_stack_protector = yes; then
2068   libc_extra_cflags=-fno-stack-protector
2069 fi
2070 AC_SUBST(libc_extra_cflags)
2071
2072 ### End of automated tests.
2073 ### Now run sysdeps configure fragments.
2074
2075 # They also can set these variables.
2076 use_ldconfig=no
2077 ldd_rewrite_script=no
2078 libc_cv_sysconfdir=$sysconfdir
2079 libc_cv_localstatedir=$localstatedir
2080 libc_cv_gcc_unwind_find_fde=no
2081 libc_cv_idn=no
2082
2083 # Iterate over all the sysdep directories we will use, running their
2084 # configure fragments.
2085 for dir in $sysnames; do
2086   case $dir in
2087     /*) dest=$dir ;;
2088     *)  dest=$srcdir/$dir ;;
2089   esac
2090   if test -r $dest/configure; then
2091     AC_MSG_RESULT(running configure fragment for $dir)
2092     . $dest/configure
2093   fi
2094 done
2095
2096 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2097   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2098 fi
2099 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2100
2101 # A sysdeps configure fragment can reset this if IFUNC is not actually
2102 # usable even though the assembler knows how to generate the symbol type.
2103 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
2104   AC_DEFINE(HAVE_IFUNC)
2105 fi
2106
2107 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
2108 # configure fragment can override the value to prevent this AC_DEFINE.
2109 AC_SUBST(use_nscd)
2110 if test "x$use_nscd" != xno; then
2111   AC_DEFINE([USE_NSCD])
2112 fi
2113 if test "x$build_nscd" = xdefault; then
2114   build_nscd=$use_nscd
2115 fi
2116
2117 # Test for old glibc 2.0.x headers so that they can be removed properly
2118 # Search only in includedir.
2119 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2120 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2121 then
2122   old_glibc_headers=yes
2123 else
2124   old_glibc_headers=no
2125 fi
2126 AC_MSG_RESULT($old_glibc_headers)
2127 if test ${old_glibc_headers} = yes; then
2128   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2129   AC_MSG_WARN(*** be removed.)
2130 fi
2131 AC_SUBST(old_glibc_headers)
2132
2133 AC_SUBST(libc_cv_slibdir)
2134 AC_SUBST(libc_cv_rtlddir)
2135 AC_SUBST(libc_cv_localedir)
2136 AC_SUBST(libc_cv_sysconfdir)
2137 AC_SUBST(libc_cv_localstatedir)
2138 AC_SUBST(libc_cv_rootsbindir)
2139 AC_SUBST(libc_cv_forced_unwind)
2140
2141 if test x$use_ldconfig = xyes; then
2142   AC_DEFINE(USE_LDCONFIG)
2143 fi
2144 AC_SUBST(use_ldconfig)
2145 AC_SUBST(ldd_rewrite_script)
2146
2147 AC_SUBST(static)
2148 AC_SUBST(shared)
2149
2150 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2151 [libc_cv_pic_default=yes
2152 cat > conftest.c <<EOF
2153 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2154 # error PIC is default.
2155 #endif
2156 EOF
2157 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2158   libc_cv_pic_default=no
2159 fi
2160 rm -f conftest.*])
2161 AC_SUBST(libc_cv_pic_default)
2162
2163 AC_SUBST(profile)
2164 AC_SUBST(static_nss)
2165
2166 AC_SUBST(DEFINES)
2167
2168 dnl See sysdeps/mach/configure.ac for this variable.
2169 AC_SUBST(mach_interface_list)
2170
2171 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2172 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2173 AC_SUBST(VERSION)
2174 AC_SUBST(RELEASE)
2175
2176 AC_CONFIG_FILES([config.make Makefile])
2177 AC_CONFIG_COMMANDS([default],[[
2178 case $CONFIG_FILES in *config.make*)
2179 echo "$config_vars" >> config.make;;
2180 esac
2181 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2182 AC_OUTPUT